src/systemadm.vala

   1 /***
   2   This file is part of systemd.
   3
   4   Copyright 2010 Lennart Poettering
   5
   6   systemd is free software; you can redistribute it and/or modify it
   7   under the terms of the GNU General Public License as published by
   8   the Free Software Foundation; either version 2 of the License, or
   9   (at your option) any later version.
  10
  11   systemd is distributed in the hope that it will be useful, but
  12   WITHOUT ANY WARRANTY; without even the implied warranty of
  13   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  14   General Public License for more details.
  15
  16   You should have received a copy of the GNU General Public License
  17   along with systemd; If not, see <http://www.gnu.org/licenses/>.
  18 ***/
  19
  20 using Gtk;
  21 using GLib;
  22 using Pango;
  23
  24 static bool user = false;
  25
  26 public string format_time(uint64 time_ns) {
  27         if (time_ns <= 0)
  28                 return "";
  29         Time timestamp = Time.local((time_t) (time_ns / 1000000));
  30         return timestamp.format("%a, %d %b %Y %H:%M:%S");
  31 }
  32
  33 public void new_column(TreeView view, int column_id, string title) {
  34         TreeViewColumn col;
  35         col = new TreeViewColumn.with_attributes(title, new CellRendererText(), "text", column_id);
  36         col.set_sort_column_id(column_id);
  37         view.insert_column(col, -1);
  38 }
  39
  40 public class LeftLabel : Label {
  41         public LeftLabel(string? text = null) {
  42                 if (text != null)
  43                         set_markup("<b>%s</b>".printf(text));
  44                 set_alignment(0, 0);
  45                 set_padding(6, 0);
  46         }
  47 }
  48
  49 public class RightLabel : WrapLabel {
  50
  51         public RightLabel(string? text = null) {
  52                 set_selectable(true);
  53                 set_text_or_na(text);
  54         }
  55
  56         public void set_text_or_na(string? text = null) {
  57                 if (text == null || text == "")
  58                         set_markup("<i>n/a</i>");
  59                 else
  60                         set_text(text);
  61         }
  62
  63         public void set_markup_or_na(string? text = null) {
  64                 if (text == null || text == "")
  65                         set_markup("<i>n/a</i>");
  66                 else
  67                         set_markup(text);
  68         }
  69 }
  70
  71 public class MainWindow : Window {
  72
  73         private string? current_unit_id;
  74         private uint32 current_job_id;
  75
  76         private TreeView unit_view;
  77         private TreeView job_view;
  78
  79         private ListStore unit_model;
  80         private ListStore job_model;
  81
  82         private Gee.HashMap<string, Unit> unit_map;
  83
  84         private Button start_button;
  85         private Button stop_button;
  86         private Button restart_button;
  87         private Button reload_button;
  88         private Button cancel_button;
  89
  90         private Entry unit_load_entry;
  91         private Button unit_load_button;
  92
  93         private Button server_snapshot_button;
  94         private Button server_reload_button;
  95
  96         private Manager manager;
  97
  98         private RightLabel unit_id_label;
  99         private RightLabel unit_aliases_label;
 100         private RightLabel unit_dependency_label;
 101         private RightLabel unit_description_label;
 102         private RightLabel unit_load_state_label;
 103         private RightLabel unit_active_state_label;
 104         private RightLabel unit_sub_state_label;
 105         private RightLabel unit_fragment_path_label;
 106         private RightLabel unit_active_enter_timestamp_label;
 107         private RightLabel unit_active_exit_timestamp_label;
 108         private RightLabel unit_can_start_label;
 109         private RightLabel unit_can_reload_label;
 110         private RightLabel unit_cgroup_label;
 111
 112         private RightLabel job_id_label;
 113         private RightLabel job_state_label;
 114         private RightLabel job_type_label;
 115
 116         private ComboBox unit_type_combo_box;
 117         private CheckButton inactive_checkbox;
 118
 119         public MainWindow() throws IOError {
 120                 title = user ? "systemd User Service Manager" : "systemd System Manager";
 121                 set_position(WindowPosition.CENTER);
 122                 set_default_size(1000, 700);
 123                 set_border_width(12);
 124                 destroy.connect(Gtk.main_quit);
 125
 126                 Notebook notebook = new Notebook();
 127                 add(notebook);
 128
 129                 Box unit_vbox = new VBox(false, 12);
 130                 notebook.append_page(unit_vbox, new Label("Units"));
 131                 unit_vbox.set_border_width(12);
 132
 133                 Box job_vbox = new VBox(false, 12);
 134                 notebook.append_page(job_vbox, new Label("Jobs"));
 135                 job_vbox.set_border_width(12);
 136
 137                 unit_type_combo_box = new ComboBox.text();
 138                 Box type_hbox = new HBox(false, 6);
 139                 type_hbox.pack_start(unit_type_combo_box, false, false, 0);
 140                 unit_vbox.pack_start(type_hbox, false, false, 0);
 141
 142                 unit_type_combo_box.append_text("All unit types");
 143                 unit_type_combo_box.append_text("Targets");
 144                 unit_type_combo_box.append_text("Services");
 145                 unit_type_combo_box.append_text("Devices");
 146                 unit_type_combo_box.append_text("Mounts");
 147                 unit_type_combo_box.append_text("Automounts");
 148                 unit_type_combo_box.append_text("Swaps");
 149                 unit_type_combo_box.append_text("Sockets");
 150                 unit_type_combo_box.append_text("Paths");
 151                 unit_type_combo_box.append_text("Timers");
 152                 unit_type_combo_box.append_text("Snapshots");
 153                 unit_type_combo_box.set_active(0); // Show All
 154                 unit_type_combo_box.changed.connect(unit_type_changed);
 155
 156                 inactive_checkbox = new CheckButton.with_label("inactive too");
 157                 inactive_checkbox.toggled.connect(unit_type_changed);
 158                 type_hbox.pack_start(inactive_checkbox, false, false, 0);
 159
 160                 unit_load_entry = new Entry();
 161                 unit_load_button = new Button.with_mnemonic("_Load");
 162                 unit_load_button.set_sensitive(false);
 163
 164                 unit_load_entry.changed.connect(on_unit_load_entry_changed);
 165                 unit_load_entry.activate.connect(on_unit_load);
 166                 unit_load_button.clicked.connect(on_unit_load);
 167
 168                 Box unit_load_hbox = new HBox(false, 6);
 169                 unit_load_hbox.pack_start(unit_load_entry, false, true, 0);
 170                 unit_load_hbox.pack_start(unit_load_button, false, true, 0);
 171
 172                 server_snapshot_button = new Button.with_mnemonic("Take S_napshot");
 173                 server_reload_button = new Button.with_mnemonic("Reload _Configuration");
 174
 175                 server_snapshot_button.clicked.connect(on_server_snapshot);
 176                 server_reload_button.clicked.connect(on_server_reload);
 177
 178                 type_hbox.pack_end(server_snapshot_button, false, true, 0);
 179                 type_hbox.pack_end(server_reload_button, false, true, 0);
 180                 type_hbox.pack_end(unit_load_hbox, false, true, 24);
 181
 182                 unit_model = new ListStore(7, typeof(string), typeof(string), typeof(string), typeof(string), typeof(string), typeof(string), typeof(Unit));
 183                 job_model = new ListStore(6, typeof(string), typeof(string), typeof(string), typeof(string), typeof(Job), typeof(uint32));
 184
 185                 unit_map = new Gee.HashMap<string, Unit>();
 186
 187                 TreeModelFilter unit_model_filter;
 188                 unit_model_filter = new TreeModelFilter(unit_model, null);
 189                 unit_model_filter.set_visible_func(unit_filter);
 190
 191                 TreeModelSort unit_model_sort = new TreeModelSort.with_model(unit_model_filter);
 192
 193                 unit_view = new TreeView.with_model(unit_model_sort);
 194                 job_view = new TreeView.with_model(job_model);
 195
 196                 unit_view.cursor_changed.connect(unit_changed);
 197                 job_view.cursor_changed.connect(job_changed);
 198
 199                 new_column(unit_view, 2, "Load State");
 200                 new_column(unit_view, 3, "Active State");
 201                 new_column(unit_view, 4, "Unit State");
 202                 new_column(unit_view, 0, "Unit");
 203                 new_column(unit_view, 5, "Job");
 204
 205                 new_column(job_view, 0, "Job");
 206                 new_column(job_view, 1, "Unit");
 207                 new_column(job_view, 2, "Type");
 208                 new_column(job_view, 3, "State");
 209
 210                 ScrolledWindow scroll = new ScrolledWindow(null, null);
 211                 scroll.set_policy(PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
 212                 scroll.set_shadow_type(ShadowType.IN);
 213                 scroll.add(unit_view);
 214                 unit_vbox.pack_start(scroll, true, true, 0);
 215
 216                 scroll = new ScrolledWindow(null, null);
 217                 scroll.set_policy(PolicyType.AUTOMATIC, PolicyType.AUTOMATIC);
 218                 scroll.set_shadow_type(ShadowType.IN);
 219                 scroll.add(job_view);
 220                 job_vbox.pack_start(scroll, true, true, 0);
 221
 222                 unit_id_label = new RightLabel();
 223                 unit_aliases_label = new RightLabel();
 224                 unit_dependency_label = new RightLabel();
 225                 unit_description_label = new RightLabel();
 226                 unit_load_state_label = new RightLabel();
 227                 unit_active_state_label = new RightLabel();
 228                 unit_sub_state_label = new RightLabel();
 229                 unit_fragment_path_label = new RightLabel();
 230                 unit_active_enter_timestamp_label = new RightLabel();
 231                 unit_active_exit_timestamp_label = new RightLabel();
 232                 unit_can_start_label = new RightLabel();
 233                 unit_can_reload_label = new RightLabel();
 234                 unit_cgroup_label = new RightLabel();
 235
 236                 job_id_label = new RightLabel();
 237                 job_state_label = new RightLabel();
 238                 job_type_label = new RightLabel();
 239
 240                 unit_dependency_label.set_track_visited_links(false);
 241                 unit_dependency_label.set_selectable(false);
 242                 unit_dependency_label.activate_link.connect(on_activate_link);
 243
 244                 unit_fragment_path_label.set_track_visited_links(false);
 245
 246                 Table unit_table = new Table(8, 6, false);
 247                 unit_table.set_row_spacings(6);
 248                 unit_table.set_border_width(0);
 249                 unit_vbox.pack_start(unit_table, false, true, 0);
 250
 251                 Table job_table = new Table(2, 2, false);
 252                 job_table.set_row_spacings(6);
 253                 job_table.set_border_width(0);
 254                 job_vbox.pack_start(job_table, false, true, 0);
 255
 256                 unit_table.attach(new LeftLabel("Id:"),                     0, 1, 0, 1, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 257                 unit_table.attach(unit_id_label,                            1, 6, 0, 1, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 258                 unit_table.attach(new LeftLabel("Aliases:"),                0, 1, 1, 2, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 259                 unit_table.attach(unit_aliases_label,                       1, 6, 1, 2, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 260                 unit_table.attach(new LeftLabel("Description:"),            0, 1, 2, 3, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 261                 unit_table.attach(unit_description_label,                   1, 6, 2, 3, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 262                 unit_table.attach(new LeftLabel("Dependencies:"),           0, 1, 3, 4, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 263                 unit_table.attach(unit_dependency_label,                    1, 6, 3, 4, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 264                 unit_table.attach(new LeftLabel("Fragment Path:"),          0, 1, 4, 5, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 265                 unit_table.attach(unit_fragment_path_label,                 1, 6, 4, 5, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 266                 unit_table.attach(new LeftLabel("Control Group:"),          0, 1, 5, 6, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 267                 unit_table.attach(unit_cgroup_label,                        1, 6, 5, 6, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 268
 269                 unit_table.attach(new LeftLabel("Load State:"),             0, 1, 6, 7, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 270                 unit_table.attach(unit_load_state_label,                    1, 2, 6, 7, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 271                 unit_table.attach(new LeftLabel("Active State:"),           0, 1, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 272                 unit_table.attach(unit_active_state_label,                  1, 2, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 273                 unit_table.attach(new LeftLabel("Unit State:"),             0, 1, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 274                 unit_table.attach(unit_sub_state_label,                     1, 2, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 275
 276                 unit_table.attach(new LeftLabel("Active Enter Timestamp:"), 2, 3, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 277                 unit_table.attach(unit_active_enter_timestamp_label,        3, 4, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 278                 unit_table.attach(new LeftLabel("Active Exit Timestamp:"),  2, 3, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 279                 unit_table.attach(unit_active_exit_timestamp_label,         3, 4, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 280
 281                 unit_table.attach(new LeftLabel("Can Start/Stop:"),         4, 5, 7, 8, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 282                 unit_table.attach(unit_can_start_label,                     5, 6, 7, 8, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 283                 unit_table.attach(new LeftLabel("Can Reload:"),             4, 5, 8, 9, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 284                 unit_table.attach(unit_can_reload_label,                    5, 6, 8, 9, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 285
 286                 job_table.attach(new LeftLabel("Id:"),                      0, 1, 0, 1, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 287                 job_table.attach(job_id_label,                              1, 2, 0, 1, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 288                 job_table.attach(new LeftLabel("State:"),                   0, 1, 1, 2, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 289                 job_table.attach(job_state_label,                           1, 2, 1, 2, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 290                 job_table.attach(new LeftLabel("Type:"),                    0, 1, 2, 3, AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 291                 job_table.attach(job_type_label,                            1, 2, 2, 3, AttachOptions.EXPAND|AttachOptions.FILL, AttachOptions.FILL, 0, 0);
 292
 293                 ButtonBox bbox = new HButtonBox();
 294                 bbox.set_layout(ButtonBoxStyle.START);
 295                 bbox.set_spacing(6);
 296                 unit_vbox.pack_start(bbox, false, true, 0);
 297
 298                 start_button = new Button.with_mnemonic("_Start");
 299                 stop_button = new Button.with_mnemonic("Sto_p");
 300                 reload_button = new Button.with_mnemonic("_Reload");
 301                 restart_button = new Button.with_mnemonic("Res_tart");
 302
 303                 start_button.clicked.connect(on_start);
 304                 stop_button.clicked.connect(on_stop);
 305                 reload_button.clicked.connect(on_reload);
 306                 restart_button.clicked.connect(on_restart);
 307
 308                 bbox.pack_start(start_button, false, true, 0);
 309                 bbox.pack_start(stop_button, false, true, 0);
 310                 bbox.pack_start(restart_button, false, true, 0);
 311                 bbox.pack_start(reload_button, false, true, 0);
 312
 313                 bbox = new HButtonBox();
 314                 bbox.set_layout(ButtonBoxStyle.START);
 315                 bbox.set_spacing(6);
 316                 job_vbox.pack_start(bbox, false, true, 0);
 317
 318                 cancel_button = new Button.with_mnemonic("_Cancel");
 319
 320                 cancel_button.clicked.connect(on_cancel);
 321
 322                 bbox.pack_start(cancel_button, false, true, 0);
 323
 324                 manager = Bus.get_proxy_sync(
 325                                 user ? BusType.SESSION : BusType.SYSTEM,
 326                                 "org.freedesktop.systemd1",
 327                                 "/org/freedesktop/systemd1");
 328
 329                 manager.unit_new.connect(on_unit_new);
 330                 manager.job_new.connect(on_job_new);
 331                 manager.unit_removed.connect(on_unit_removed);
 332                 manager.job_removed.connect(on_job_removed);
 333
 334                 manager.subscribe();
 335
 336                 clear_unit();
 337                 clear_job();
 338                 populate_unit_model();
 339                 populate_job_model();
 340         }
 341
 342         public void populate_unit_model() throws IOError {
 343                 unit_model.clear();
 344
 345                 var list = manager.list_units();
 346
 347                 foreach (var i in list) {
 348                         TreeIter iter;
 349
 350                         Properties p = Bus.get_proxy_sync(
 351                                         user ? BusType.SESSION : BusType.SYSTEM,
 352                                         "org.freedesktop.systemd1",
 353                                         i.unit_path);
 354
 355                         p.properties_changed.connect(on_unit_changed);
 356
 357                         Unit u = Bus.get_proxy_sync(
 358                                         user ? BusType.SESSION : BusType.SYSTEM,
 359                                         "org.freedesktop.systemd1",
 360                                         i.unit_path);
 361
 362                         unit_map[i.id] = u;
 363
 364                         unit_model.append(out iter);
 365                         unit_model.set(iter,
 366                                        0, i.id,
 367                                        1, i.description,
 368                                        2, i.load_state,
 369                                        3, i.active_state,
 370                                        4, i.sub_state,
 371                                        5, i.job_type != "" ? "→ %s".printf(i.job_type) : "",
 372                                        6, u);
 373                 }
 374         }
 375
 376         public void populate_job_model() throws IOError {
 377                 job_model.clear();
 378
 379                 var list = manager.list_jobs();
 380
 381                 foreach (var i in list) {
 382                         TreeIter iter;
 383
 384                         Properties p = Bus.get_proxy_sync(
 385                                         user ? BusType.SESSION : BusType.SYSTEM,
 386                                         "org.freedesktop.systemd1",
 387                                         i.job_path);
 388
 389                         p.properties_changed.connect(on_job_changed);
 390
 391                         Job j = Bus.get_proxy_sync(
 392                                         user ? BusType.SESSION : BusType.SYSTEM,
 393                                         "org.freedesktop.systemd1",
 394                                         i.job_path);
 395
 396                         job_model.append(out iter);
 397                         job_model.set(iter,
 398                                       0, "%u".printf(i.id),
 399                                       1, i.name,
 400                                       2, "→ %s".printf(i.type),
 401                                       3, i.state,
 402                                       4, j,
 403                                       5, i.id);
 404                 }
 405         }
 406
 407         public Unit? get_current_unit() {
 408                 TreePath p;
 409                 unit_view.get_cursor(out p, null);
 410
 411                 if (p == null)
 412                         return null;
 413
 414                 TreeModel model = unit_view.get_model();
 415                 TreeIter iter;
 416                 Unit u;
 417
 418                 model.get_iter(out iter, p);
 419                 model.get(iter, 6, out u);
 420
 421                 return u;
 422         }
 423
 424         public Unit? get_unit(string id) {
 425                 return this.unit_map[id];
 426         }
 427
 428         public void unit_changed() {
 429                 Unit u = get_current_unit();
 430
 431                 if (u == null)
 432                         clear_unit();
 433                 else
 434                         show_unit(u);
 435         }
 436
 437         public void clear_unit() {
 438                 current_unit_id = null;
 439
 440                 start_button.set_sensitive(false);
 441                 stop_button.set_sensitive(false);
 442                 reload_button.set_sensitive(false);
 443                 restart_button.set_sensitive(false);
 444
 445                 unit_id_label.set_text_or_na();
 446                 unit_aliases_label.set_text_or_na();
 447                 unit_description_label.set_text_or_na();
 448                 unit_description_label.set_text_or_na();
 449                 unit_load_state_label.set_text_or_na();
 450                 unit_active_state_label.set_text_or_na();
 451                 unit_sub_state_label.set_text_or_na();
 452                 unit_fragment_path_label.set_text_or_na();
 453                 unit_active_enter_timestamp_label.set_text_or_na();
 454                 unit_active_exit_timestamp_label.set_text_or_na();
 455                 unit_can_reload_label.set_text_or_na();
 456                 unit_can_start_label.set_text_or_na();
 457                 unit_cgroup_label.set_text_or_na();
 458         }
 459
 460         public string make_dependency_string(string? prefix, string word, string[] dependencies) {
 461                 Gee.Collection<unowned string> sorted = new Gee.TreeSet<string>();
 462                 foreach (string i in dependencies)
 463                         sorted.add(i);
 464
 465                 bool first = true;
 466                 string r;
 467
 468                 if (prefix == null)
 469                         r = "";
 470                 else
 471                         r = prefix;
 472
 473                 foreach (string i in sorted) {
 474                         if (r != "")
 475                                 r += first ? "\n" : ",";
 476
 477                         if (first) {
 478                                 r += word;
 479                                 first = false;
 480                         }
 481
 482                         r += " <a href=\"" + i + "\">" + i + "</a>";
 483                 }
 484
 485                 return r;
 486         }
 487
 488         public void show_unit(Unit unit) {
 489                 current_unit_id = unit.id;
 490
 491                 unit_id_label.set_text_or_na(current_unit_id);
 492
 493                 string a = "";
 494                 foreach (string i in unit.names) {
 495                         if (i == current_unit_id)
 496                                 continue;
 497
 498                         if (a == "")
 499                                 a = i;
 500                         else
 501                                 a += "\n" + i;
 502                 }
 503
 504                 unit_aliases_label.set_text_or_na(a);
 505
 506                 string[]
 507                         requires = unit.requires,
 508                         requires_overridable = unit.requires_overridable,
 509                         requisite = unit.requisite,
 510                         requisite_overridable = unit.requisite_overridable,
 511                         wants = unit.wants,
 512                         required_by = unit.required_by,
 513                         required_by_overridable = unit.required_by_overridable,
 514                         wanted_by = unit.wanted_by,
 515                         conflicts = unit.conflicts,
 516                         before = unit.before,
 517                         after = unit.after;
 518
 519                 unit_dependency_label.set_markup_or_na(
 520                                 make_dependency_string(
 521                                 make_dependency_string(
 522                                 make_dependency_string(
 523                                 make_dependency_string(
 524                                 make_dependency_string(
 525                                 make_dependency_string(
 526                                 make_dependency_string(
 527                                 make_dependency_string(
 528                                 make_dependency_string(
 529                                 make_dependency_string(
 530                                 make_dependency_string(null,
 531                                 "requires", requires),
 532                                 "overridable requires", requires_overridable),
 533                                 "requisite", requisite),
 534                                 "overridable requisite", requisite_overridable),
 535                                 "wants", wants),
 536                                 "conflicts", conflicts),
 537                                 "required by", required_by),
 538                                 "overridable required by", required_by_overridable),
 539                                 "wanted by", wanted_by),
 540                                 "after", after),
 541                                 "before", before));
 542
 543                 unit_description_label.set_text_or_na(unit.description);
 544                 unit_load_state_label.set_text_or_na(unit.load_state);
 545                 unit_active_state_label.set_text_or_na(unit.active_state);
 546                 unit_sub_state_label.set_text_or_na(unit.sub_state);
 547
 548                 string fp = unit.fragment_path;
 549                 if (fp != "")
 550                         unit_fragment_path_label.set_markup_or_na("<a href=\"file://" + fp +"\">" + fp + "</a>" );
 551                 else
 552                         unit_fragment_path_label.set_text_or_na();
 553
 554
 555                 unit_active_enter_timestamp_label.set_text_or_na(format_time(unit.active_enter_timestamp));
 556
 557                 unit_active_exit_timestamp_label.set_text_or_na(format_time(unit.active_exit_timestamp));
 558
 559                 bool b = unit.can_start;
 560                 start_button.set_sensitive(b);
 561                 stop_button.set_sensitive(b);
 562                 restart_button.set_sensitive(b);
 563                 unit_can_start_label.set_text_or_na(b ? "Yes" : "No");
 564
 565                 b = unit.can_reload;
 566                 reload_button.set_sensitive(b);
 567                 unit_can_reload_label.set_text_or_na(b ? "Yes" : "No");
 568
 569                 unit_cgroup_label.set_text_or_na(unit.default_control_group);
 570         }
 571
 572         public Job? get_current_job() {
 573                 TreePath p;
 574                 job_view.get_cursor(out p, null);
 575
 576                 if (p == null)
 577                         return null;
 578
 579                 TreeIter iter;
 580                 TreeModel model = job_view.get_model();
 581                 Job *j;
 582
 583                 model.get_iter(out iter, p);
 584                 model.get(iter, 4, out j);
 585
 586                 return j;
 587         }
 588
 589         public void job_changed() {
 590                 Job j = get_current_job();
 591
 592                 if (j == null)
 593                         clear_job();
 594                 else
 595                         show_job(j);
 596         }
 597
 598         public void clear_job() {
 599                 current_job_id = 0;
 600
 601                 job_id_label.set_text_or_na();
 602                 job_state_label.set_text_or_na();
 603                 job_type_label.set_text_or_na();
 604
 605                 cancel_button.set_sensitive(false);
 606         }
 607
 608         public void show_job(Job job) {
 609                 current_job_id = job.id;
 610
 611                 job_id_label.set_text_or_na("%u".printf(current_job_id));
 612                 job_state_label.set_text_or_na(job.state);
 613                 job_type_label.set_text_or_na(job.job_type);
 614
 615                 cancel_button.set_sensitive(true);
 616         }
 617
 618         public void on_start() {
 619                 Unit u = get_current_unit();
 620
 621                 if (u == null)
 622                         return;
 623
 624                 try {
 625                         u.start("replace");
 626                 } catch (IOError e) {
 627                         show_error(e.message);
 628                 }
 629         }
 630
 631         public void on_stop() {
 632                 Unit u = get_current_unit();
 633
 634                 if (u == null)
 635                         return;
 636
 637                 try {
 638                         u.stop("replace");
 639                 } catch (IOError e) {
 640                         show_error(e.message);
 641                 }
 642         }
 643
 644         public void on_reload() {
 645                 Unit u = get_current_unit();
 646
 647                 if (u == null)
 648                         return;
 649
 650                 try {
 651                         u.reload("replace");
 652                 } catch (IOError e) {
 653                         show_error(e.message);
 654                 }
 655         }
 656
 657         public void on_restart() {
 658                 Unit u = get_current_unit();
 659
 660                 if (u == null)
 661                         return;
 662
 663                 try {
 664                         u.restart("replace");
 665                 } catch (IOError e) {
 666                         show_error(e.message);
 667                 }
 668         }
 669
 670         public void on_cancel() {
 671                 Job j = get_current_job();
 672
 673                 if (j == null)
 674                         return;
 675
 676                 try {
 677                         j.cancel();
 678                 } catch (IOError e) {
 679                         show_error(e.message);
 680                 }
 681         }
 682
 683         public void update_unit_iter(TreeIter iter, string id, Unit u) {
 684
 685                 try  {
 686                         string t = "";
 687                         Unit.JobLink jl = u.job;
 688
 689                         if (jl.id != 0) {
 690                                 Job j = Bus.get_proxy_sync(
 691                                                 user ? BusType.SESSION : BusType.SYSTEM,
 692                                                 "org.freedesktop.systemd1",
 693                                                 jl.path);
 694
 695                                 t = j.job_type;
 696                         }
 697
 698                         unit_model.set(iter,
 699                                        0, id,
 700                                        1, u.description,
 701                                        2, u.load_state,
 702                                        3, u.active_state,
 703                                        4, u.sub_state,
 704                                        5, t != "" ? "→ %s".printf(t) : "",
 705                                        6, u);
 706                 } catch (IOError e) {
 707                         show_error(e.message);
 708                 }
 709         }
 710
 711         public void on_unit_new(string id, ObjectPath path) {
 712                 try {
 713
 714                         Properties p = Bus.get_proxy_sync(
 715                                         user ? BusType.SESSION : BusType.SYSTEM,
 716                                         "org.freedesktop.systemd1",
 717                                         path);
 718
 719                         p.properties_changed.connect(on_unit_changed);
 720
 721                         TreeIter iter;
 722                         unit_model.append(out iter);
 723
 724                         Unit u = Bus.get_proxy_sync(
 725                                         user ? BusType.SESSION : BusType.SYSTEM,
 726                                         "org.freedesktop.systemd1",
 727                                         path);
 728
 729                         unit_map[id] = u;
 730
 731                         update_unit_iter(iter, id, u);
 732                 } catch (IOError e) {
 733                         show_error(e.message);
 734                 }
 735         }
 736
 737         public void update_job_iter(TreeIter iter, uint32 id, Job j) {
 738                 job_model.set(iter,
 739                               0, "%u".printf(id),
 740                               1, j.unit.id,
 741                               2, "→ %s".printf(j.job_type),
 742                               3, j.state,
 743                               4, j,
 744                               5, id);
 745         }
 746
 747         public void on_job_new(uint32 id, ObjectPath path) {
 748
 749                 try  {
 750
 751                         Properties p = Bus.get_proxy_sync(
 752                                         user ? BusType.SESSION : BusType.SYSTEM,
 753                                         "org.freedesktop.systemd1",
 754                                         path);
 755
 756                         p.properties_changed.connect(on_job_changed);
 757
 758                         TreeIter iter;
 759                         job_model.append(out iter);
 760
 761                         Job j = Bus.get_proxy_sync(
 762                                         user ? BusType.SESSION : BusType.SYSTEM,
 763                                         "org.freedesktop.systemd1",
 764                                         path);
 765
 766                         update_job_iter(iter, id, j);
 767
 768                 } catch (IOError e) {
 769                         show_error(e.message);
 770                 }
 771         }
 772
 773         public void on_unit_removed(string id, ObjectPath path) {
 774                 TreeIter iter;
 775                 if (!(unit_model.get_iter_first(out iter)))
 776                         return;
 777
 778                 do {
 779                         string name;
 780
 781                         unit_model.get(iter, 0, out name);
 782
 783                         if (id == name) {
 784                                 if (current_unit_id == name)
 785                                         clear_unit();
 786
 787                                 unit_model.remove(iter);
 788                                 break;
 789                         }
 790
 791                 } while (unit_model.iter_next(ref iter));
 792
 793                 unit_map.unset(id);
 794         }
 795
 796         public void on_job_removed(uint32 id, ObjectPath path, string res) {
 797                 TreeIter iter;
 798                 if (!(job_model.get_iter_first(out iter)))
 799                         return;
 800
 801                 do {
 802                         uint32 j;
 803
 804                         job_model.get(iter, 5, out j);
 805
 806                         if (id == j) {
 807                                 if (current_job_id == j)
 808                                         clear_job();
 809
 810                                 job_model.remove(iter);
 811
 812                                 break;
 813                         }
 814
 815                 } while (job_model.iter_next(ref iter));
 816         }
 817
 818         public void on_unit_changed(Properties p, string iface, HashTable<string, Value?> changed_properties, string[] invalidated_properties) {
 819
 820                 try {
 821                         TreeIter iter;
 822                         string id;
 823
 824                         Unit u = Bus.get_proxy_sync(
 825                                         user ? BusType.SESSION : BusType.SYSTEM,
 826                                         p.get_name(),
 827                                         p.get_object_path());
 828
 829                         if (!(unit_model.get_iter_first(out iter)))
 830                                 return;
 831
 832                         id = u.id;
 833
 834                         do {
 835                                 string name;
 836
 837                                 unit_model.get(iter, 0, out name);
 838
 839                                 if (id == name) {
 840                                         update_unit_iter(iter, id, u);
 841
 842                                         if (current_unit_id == id)
 843                                                 show_unit(u);
 844
 845                                         break;
 846                                 }
 847
 848                         } while (unit_model.iter_next(ref iter));
 849
 850                 } catch (IOError e) {
 851                         show_error(e.message);
 852                 }
 853         }
 854
 855         public void on_job_changed(Properties p, string iface, HashTable<string, Value?> changed_properties, string[] invalidated_properties) {
 856                 try {
 857                         TreeIter iter;
 858                         uint32 id;
 859
 860                         Job j = Bus.get_proxy_sync(
 861                                         user ? BusType.SESSION : BusType.SYSTEM,
 862                                         p.get_name(),
 863                                         p.get_object_path());
 864
 865                         if (!(job_model.get_iter_first(out iter)))
 866                                 return;
 867
 868                         id = j.id;
 869
 870                         do {
 871                                 uint32 k;
 872
 873                                 job_model.get(iter, 5, out k);
 874
 875                                 if (id == k) {
 876                                         update_job_iter(iter, id, j);
 877
 878                                         if (current_job_id == id)
 879                                                 show_job(j);
 880
 881                                         break;
 882                                 }
 883
 884                         } while (job_model.iter_next(ref iter));
 885
 886                 } catch (IOError e) {
 887                         show_error(e.message);
 888                 }
 889         }
 890
 891         public bool unit_filter(TreeModel model, TreeIter iter) {
 892                 string id, active_state, job;
 893
 894                 model.get(iter, 0, out id, 3, out active_state, 5, out job);
 895
 896                 if (id == null)
 897                         return false;
 898
 899                 if (!inactive_checkbox.get_active()
 900                     && active_state == "inactive" && job == "")
 901                         return false;
 902
 903                 switch (unit_type_combo_box.get_active()) {
 904                 case 0:
 905                         return true;
 906                 case 1:
 907                         return id.has_suffix(".target");
 908                 case 2:
 909                         return id.has_suffix(".service");
 910                 case 3:
 911                         return id.has_suffix(".device");
 912                 case 4:
 913                         return id.has_suffix(".mount");
 914                 case 5:
 915                         return id.has_suffix(".automount");
 916                 case 6:
 917                         return id.has_suffix(".swap");
 918                 case 7:
 919                         return id.has_suffix(".socket");
 920                 case 8:
 921                         return id.has_suffix(".path");
 922                 case 9:
 923                         return id.has_suffix(".timer");
 924                 case 10:
 925                         return id.has_suffix(".snapshot");
 926                 default:
 927                         assert(false);
 928                         return false;
 929                 }
 930         }
 931
 932         public void unit_type_changed() {
 933                 TreeModelFilter model = (TreeModelFilter) ((TreeModelSort) unit_view.get_model()).get_model();
 934
 935                 model.refilter();
 936         }
 937
 938         public void on_server_reload() {
 939                 try {
 940                         manager.reload();
 941                 } catch (IOError e) {
 942                         show_error(e.message);
 943                 }
 944         }
 945
 946         public void on_server_snapshot() {
 947                 try {
 948                         manager.create_snapshot();
 949
 950                         if (unit_type_combo_box.get_active() != 0)
 951                                 unit_type_combo_box.set_active(8);
 952
 953                 } catch (IOError e) {
 954                         show_error(e.message);
 955                 }
 956         }
 957
 958         public void on_unit_load() {
 959                 string t = unit_load_entry.get_text();
 960
 961                 if (t == "")
 962                         return;
 963
 964                 try {
 965                         var path = manager.load_unit(t);
 966
 967                         Unit u = Bus.get_proxy_sync(
 968                                         user ? BusType.SESSION : BusType.SYSTEM,
 969                                         "org.freedesktop.systemd1",
 970                                         path);
 971
 972                         var m = new MessageDialog(this,
 973                                                   DialogFlags.DESTROY_WITH_PARENT,
 974                                                   MessageType.INFO,
 975                                                   ButtonsType.CLOSE,
 976                                                   "Unit available as id %s", u.id);
 977                         m.title = "Unit";
 978                         m.run();
 979                         m.destroy();
 980
 981                         show_unit(u);
 982                 } catch (IOError e) {
 983                         show_error(e.message);
 984                 }
 985         }
 986
 987         public void on_unit_load_entry_changed() {
 988                 unit_load_button.set_sensitive(unit_load_entry.get_text() != "");
 989         }
 990
 991         public bool on_activate_link(string uri) {
 992
 993                 try {
 994                         string path = manager.get_unit(uri);
 995
 996                         Unit u = Bus.get_proxy_sync(
 997                                         user ? BusType.SESSION : BusType.SYSTEM,
 998                                         "org.freedesktop.systemd1",
 999                                         path);
1000
1001                         show_unit(u);
1002                 } catch (IOError e) {
1003                         show_error(e.message);
1004                 }
1005
1006                 return true;
1007         }
1008
1009         public void show_error(string e) {
1010                 var m = new MessageDialog(this,
1011                                           DialogFlags.DESTROY_WITH_PARENT,
1012                                           MessageType.ERROR,
1013                                           ButtonsType.CLOSE, "%s", e);
1014                 m.title = "Error";
1015                 m.run();
1016                 m.destroy();
1017         }
1018
1019 }
1020
1021 static const OptionEntry entries[] = {
1022         { "user",    0,   0,                   OptionArg.NONE, out user, "Connect to user service manager", null },
1023         { "system",  0,   OptionFlags.REVERSE, OptionArg.NONE, out user, "Connect to system manager",       null },
1024         { null }
1025 };
1026
1027 void show_error(string e) {
1028         var m = new MessageDialog(null, 0, MessageType.ERROR, ButtonsType.CLOSE, "%s", e);
1029         m.run();
1030         m.destroy();
1031 }
1032
1033 int main(string[] args) {
1034
1035         try {
1036                 Gtk.init_with_args(ref args, "[OPTION...]", entries, "systemadm");
1037
1038                 MainWindow window = new MainWindow();
1039                 window.show_all();
1040
1041                 Gtk.main();
1042         } catch (IOError e) {
1043                 show_error(e.message);
1044         } catch (GLib.Error e) {
1045                 stderr.printf("%s\n", e.message);
1046         }
1047
1048         return 0;
1049 }