chiark / gitweb /
cryptsetup-generator: Split main() into more functions and use hasmaps
[elogind.git] / shell-completion / zsh / _systemctl.in
1 #compdef systemctl
2
3 (( $+functions[_systemctl_command] )) || _systemctl_command()
4 {
5   local -a _systemctl_cmds
6   _systemctl_cmds=(
7     "list-sockets:List sockets"
8     "list-timers:List timers"
9     "list-units:List units"
10     "start:Start (activate) one or more units"
11     "stop:Stop (deactivate) one or more units"
12     "reload:Reload one or more units"
13     "restart:Start or restart one or more units"
14     "condrestart:Restart one or more units if active"
15     "try-restart:Restart one or more units if active"
16     "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
17     "force-reload:Reload one or more units if possible, otherwise restart if active"
18     "hibernate:Hibernate the system"
19     "hybrid-sleep:Hibernate and suspend the system"
20     "reload-or-try-restart:Reload one or more units if possible, otherwise restart if active"
21     "isolate:Start one unit and stop all others"
22     "kill:Send signal to processes of a unit"
23     "is-active:Check whether units are active"
24     "is-failed:Check whether units are failed"
25     "status:Show runtime status of one or more units"
26     "show:Show properties of one or more units/jobs or the manager"
27     "cat:Show the source unit files and drop-ins"
28     "reset-failed:Reset failed state for all, one, or more units"
29     "list-unit-files:List installed unit files"
30     "enable:Enable one or more unit files"
31     "disable:Disable one or more unit files"
32     "reenable:Reenable one or more unit files"
33     "preset:Enable/disable one or more unit files based on preset configuration"
34     "set-default:Set the default target"
35     "get-default:Query the default target"
36     "is-system-running:Query overall status of the system"
37     "help:Show documentation for specified units"
38     "list-dependencies:Show unit dependency tree"
39     "mask:Mask one or more units"
40     "unmask:Unmask one or more units"
41     "link:Link one or more units files into the search path"
42     "is-enabled:Check whether unit files are enabled"
43     "list-jobs:List jobs"
44     "cancel:Cancel all, one, or more jobs"
45     "snapshot:Create a snapshot"
46     "delete:Remove one or more snapshots"
47     "show-environment:Dump environment"
48     "set-environment:Set one or more environment variables"
49     "unset-environment:Unset one or more environment variables"
50     "daemon-reload:Reload systemd manager configuration"
51     "daemon-reexec:Reexecute systemd manager"
52     "default:Enter system default mode"
53     "rescue:Enter system rescue mode"
54     "emergency:Enter system emergency mode"
55     "halt:Shut down and halt the system"
56     "suspend:Suspend the system"
57     "poweroff:Shut down and power-off the system"
58     "reboot:Shut down and reboot the system"
59     "kexec:Shut down and reboot the system with kexec"
60     "exit:Ask for user instance termination"
61   )
62
63   if (( CURRENT == 1 )); then
64     _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
65   else
66     local curcontext="$curcontext"
67
68     cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
69     # Deal with any aliases
70     case $cmd in
71       condrestart) cmd="try-restart";;
72       force-reload) cmd="reload-or-try-restart";;
73     esac
74
75     if (( $#cmd )); then
76       curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
77
78       local update_policy
79       zstyle -s ":completion:${curcontext}:" cache-policy update_policy
80       if [[ -z "$update_policy" ]]; then
81         zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
82       fi
83
84       _call_function ret _systemctl_$cmd || _message 'no more arguments'
85     else
86       _message "unknown systemctl command: $words[1]"
87     fi
88     return ret
89   fi
90 }
91
92 __systemctl()
93 {
94   local -a _modes
95   _modes=("--user" "--system")
96   systemctl ${words:*_modes} --full --no-legend --no-pager "$@"
97 }
98
99
100 # Fills the unit list
101 _systemctl_all_units()
102 {
103   if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS ) &&
104     ! _retrieve_cache SYS_ALL_UNITS;
105   then
106     _sys_all_units=( $(__systemctl list-units --all | { while read -r a b; do echo -E - " $a"; done; }) )
107     _store_cache SYS_ALL_UNITS _sys_all_units
108   fi
109 }
110
111 # Fills the unit list including all file units
112 _systemctl_really_all_units()
113 {
114   local -a all_unit_files;
115   local -a really_all_units;
116   if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS ) &&
117     ! _retrieve_cache SYS_REALLY_ALL_UNITS;
118   then
119     all_unit_files=( $(__systemctl list-unit-files | { while read -r a b; do echo -E - " $a"; done; }) )
120     _systemctl_all_units
121     really_all_units=($_sys_all_units $all_unit_files)
122     _sys_really_all_units=(${(u)really_all_units})
123     _store_cache SYS_REALLY_ALL_UNITS _sys_really_all_units
124   fi
125 }
126
127 _filter_units_by_property() {
128   local property=$1 value=$2 ; shift ; shift
129   local -a units ; units=($*)
130   local prop unit
131   for ((i=1; $i <= ${#units[*]}; i++)); do
132     # FIXME: "Failed to issue method call: Unknown unit" errors are ignored for
133     # now (related to DBUS_ERROR_UNKNOWN_OBJECT). in the future, we need to
134     # revert to calling 'systemctl show' once for all units, which is way
135     # faster
136     unit=${units[i]}
137     prop=${(f)"$(_call_program units "$service show --no-pager --property="$property" ${unit} 2>/dev/null")"}
138     if [[ "${prop}" = "$property=$value" ]]; then
139       echo " ${unit}"
140     fi
141   done
142 }
143
144 _systemctl_all_units() { { __systemctl list-unit-files; __systemctl list-units --all; } | { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; } }
145 _systemctl_get_template_names() { __systemctl list-unit-files | { while read -r a b; do  [[ $a =~ @\. ]] && echo -E - " ${a%%@.*}@"; done; } }
146
147
148 _systemctl_active_units()  {_sys_active_units=(  $(__systemctl list-units          | { while read -r a b; do echo -E - " $a"; done; }) )}
149
150 _systemctl_startable_units(){
151     _sys_startable_units=(_filter_units_by_property ActiveState inactive $(
152                           _filter_units_by_property CanStart yes $(
153                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
154                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
155                           __systemctl $mode list-units --state inactive,failed | \
156                                { while read -r a b; do echo -E - " $a"; done; } )))
157 }
158
159 _systemctl_restartable_units(){
160     _sys_restartable_units=(_filter_units_by_property CanStart yes $(
161                           __systemctl $mode list-unit-files --state enabled,disabled,static | \
162                                { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
163                           __systemctl $mode list-units | \
164                                { while read -r a b; do echo -E - " $a"; done; } ))
165 }
166
167 _systemctl_failed_units()  {_sys_failed_units=(  $(__systemctl list-units --failed | { while read -r a b; do echo -E - " $a"; done; }) )}
168 _systemctl_enabled_units() {_sys_enabled_units=( $(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "enabled" ]] && echo -E - " $a"; done; }) )}
169 _systemctl_disabled_units(){_sys_disabled_units=($(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "disabled" ]] && echo -E - " $a"; done; }) )}
170 _systemctl_masked_units()  {_sys_masked_units=(  $(__systemctl list-unit-files     | { while read -r a b; do [[ $b == "masked" ]] && echo -E - " $a"; done; }) )}
171
172 # Completion functions for ALL_UNITS
173 for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies ; do
174   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
175   {
176     _systemctl_really_all_units
177     compadd "$@" -a - _sys_really_all_units
178   }
179 done
180
181 # Completion functions for ENABLED_UNITS
182 (( $+functions[_systemctl_disable] )) || _systemctl_disable()
183 {
184     _systemctl_enabled_units
185     compadd "$@" -a - _sys_enabled_units
186 }
187
188 (( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
189 {
190     _systemctl_enabled_units
191     _systemctl_disabled_units
192     compadd "$@" -a - _sys_enabled_units _sys_disabled_units $(_systemctl_get_template_names)
193 }
194
195 # Completion functions for DISABLED_UNITS
196 (( $+functions[_systemctl_enable] )) || _systemctl_enable()
197 {
198   _systemctl_disabled_units
199   compadd "$@" -a - _sys_disabled_units $(_systemctl_get_template_names)
200 }
201
202 # Completion functions for FAILED_UNITS
203 (( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
204 {
205   _systemctl_failed_units
206   compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
207 }
208
209 # Completion functions for STARTABLE_UNITS
210 (( $+functions[_systemctl_start] )) || _systemctl_start()
211 {
212    _systemctl_startable_units
213    compadd "$@" - ${_sys_startable_units[*]} $(_systemctl_get_template_names)
214 }
215
216 # Completion functions for STOPPABLE_UNITS
217 for fun in stop kill try-restart condrestart ; do
218   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
219   {
220     _systemctl_active_units
221     compadd "$@" - $( _filter_units_by_property CanStop yes \
222       ${_sys_active_units[*]} )
223   }
224 done
225
226 # Completion functions for ISOLATABLE_UNITS
227 (( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
228 {
229   _systemctl_all_units
230   compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
231     ${_sys_all_units[*]} )
232 }
233
234 # Completion functions for RELOADABLE_UNITS
235 for fun in reload reload-or-try-restart force-reload ; do
236   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
237   {
238     _systemctl_active_units
239     compadd "$@" - $( _filter_units_by_property CanReload yes \
240       ${_sys_active_units[*]} )
241   }
242 done
243
244 # Completion functions for RESTARTABLE_UNITS
245 for fun in restart reload-or-restart ; do
246   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
247   {
248     _systemctl_restartable_units
249     compadd "$@" - ${_sys_restartable_units[*]} $(_systemctl_get_template_names)
250   }
251 done
252
253 # Completion functions for MASKED_UNITS
254 (( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
255 {
256   _systemctl_masked_units
257   compadd "$@" -a - _sys_masked_units || _message "no masked units found"
258 }
259
260 # Completion functions for JOBS
261 (( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
262 {
263   compadd "$@" - $(__systemctl list-jobs \
264     | cut -d' ' -f1  2>/dev/null ) || _message "no jobs found"
265 }
266
267 # Completion functions for SNAPSHOTS
268 (( $+functions[_systemctl_delete] )) || _systemctl_delete()
269 {
270   compadd "$@" - $(__systemctl list-units --type snapshot --all \
271     | cut -d' ' -f1  2>/dev/null ) || _message "no snapshots found"
272 }
273
274 # Completion functions for TARGETS
275 (( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
276 {
277   compadd "$@" - $(__systemctl list-unit-files --type target --all \
278     | cut -d' ' -f1  2>/dev/null ) || _message "no targets found"
279 }
280
281 # Completion functions for ENVS
282 for fun in set-environment unset-environment ; do
283   (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
284   {
285     local fun=$0 ; fun=${fun##_systemctl_}
286     local suf
287     if [[ "${fun}" = "set-environment" ]]; then
288       suf='-S='
289     fi
290
291     compadd "$@" ${suf} - $(systemctl show-environment \
292       | while read line; do echo " ${line%%\=}";done )
293   }
294 done
295
296 (( $+functions[_systemctl_link] )) || _systemctl_link() {
297    _sd_unit_files
298 }
299
300 # no systemctl completion for:
301 #    [STANDALONE]='daemon-reexec daemon-reload default
302 #                  emergency exit halt kexec list-jobs list-units
303 #                  list-unit-files poweroff reboot rescue show-environment'
304 #         [NAME]='snapshot'
305
306 _systemctl_caching_policy()
307 {
308   local _sysunits
309   local -a oldcache
310
311   # rebuild if cache is more than a day old
312   oldcache=( "$1"(mh+1) )
313   (( $#oldcache )) && return 0
314
315   _sysunits=($(__systemctl --all | cut -d' ' -f1))
316
317   if (( $#_sysunits )); then
318     for unit in $_sysunits; do
319       [[ "$unit" -nt "$1" ]] && return 0
320     done
321   fi
322
323   return 1
324 }
325
326 _unit_states() {
327     local -a _states
328     _states=(loaded failed active inactive not-found listening running waiting plugged mounted exited dead masked)
329     _values -s , "${_states[@]}"
330 }
331
332 _unit_types() {
333     local -a _types
334     _types=(automount busname device mount path service snapshot socket swap target timer)
335     _values -s , "${_types[@]}"
336 }
337
338 _unit_properties() {
339   if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES ) &&
340     ! _retrieve_cache SYS_ALL_PROPERTIES;
341   then
342     _sys_all_properties=( $( {__systemctl show --all;
343        @rootlibexecdir@/systemd --dump-configuration-items; } | {
344        while IFS='=' read -r a b; do [ -n "$b" ] && echo "$a"; done
345     }) )
346     _store_cache SYS_ALL_PROPRTIES _sys_all_properties
347   fi
348   _values -s , "${_sys_all_properties[@]}"
349 }
350
351 _arguments -s \
352     {-h,--help}'[Show help]' \
353     '--version[Show package version]' \
354     {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
355     '--state=[Display units in the specifyied state]:unit state:_unit_states' \
356     {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
357     {-a,--all}'[Show all units/properties, including dead/empty ones]' \
358     '--reverse[Show reverse dependencies]' \
359     '--after[Show units ordered after]' \
360     '--before[Show units ordered before]' \
361     '--failed[Show only failed units]' \
362     {-l,--full}"[Don't ellipsize unit names on output]" \
363     '--fail[When queueing a new job, fail if conflicting jobs are pending]' \
364     '--show-types[When showing sockets, show socket type]' \
365     '--irreversible[Mark transactions as irreversible]' \
366     '--ignore-dependencies[When queueing a new job, ignore all its dependencies]' \
367     {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
368     {-q,--quiet}'[Suppress output]' \
369     '--no-block[Do not wait until operation finished]' \
370     '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
371     '--no-pager[Do not pipe output into a pager]' \
372     '--system[Connect to system manager]' \
373     '--user[Connect to user service manager]' \
374     "--no-wall[Don't send wall message before halt/power-off/reboot]" \
375     '--global[Enable/disable unit files globally]' \
376     "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
377     '--no-ask-password[Do not ask for system passwords]' \
378     '--kill-who=[Who to send signal to]:killwho:(main control all)' \
379     {-s+,--signal=}'[Which signal to send]:signal:_signals' \
380     {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
381     '--root=[Enable unit files in the specified root directory]:directory:_directories' \
382     '--runtime[Enable unit files only temporarily until next reboot]' \
383     {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
384     {-P,--privileged}'[Acquire privileges before execution]' \
385     {-n+,--lines=}'[Journal entries to show]:number of entries' \
386     {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
387     '--plain[When used with list-dependencies, print output as a list]' \
388     '*::systemctl command:_systemctl_command'