man/custom-html.xsl

   1 <?xml version='1.0'?> <!--*-nxml-*-->
   2
   3 <!--
   4   This file is part of systemd.
   5
   6   Copyright 2011 Lennart Poettering
   7
   8   systemd is free software; you can redistribute it and/or modify it
   9   under the terms of the GNU Lesser General Public License as published by
  10   the Free Software Foundation; either version 2.1 of the License, or
  11   (at your option) any later version.
  12
  13   systemd is distributed in the hope that it will be useful, but
  14   WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16   Lesser General Public License for more details.
  17
  18   You should have received a copy of the GNU Lesser General Public License
  19   along with systemd; If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  23
  24 <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/html/docbook.xsl"/>
  25
  26 <!-- translate man page references to links to html pages -->
  27 <xsl:template match="citerefentry[not(@project)]">
  28   <a>
  29     <xsl:attribute name="href">
  30       <xsl:value-of select="refentrytitle"/><xsl:text>.html</xsl:text>
  31     </xsl:attribute>
  32     <xsl:call-template name="inline.charseq"/>
  33   </a>
  34 </xsl:template>
  35
  36 <xsl:template match="citerefentry[@project='man-pages'] | citerefentry[manvolnum='2'] | citerefentry[manvolnum='4']">
  37   <a>
  38     <xsl:attribute name="href">
  39       <xsl:text>http://man7.org/linux/man-pages/man</xsl:text>
  40       <xsl:value-of select="manvolnum"/>
  41       <xsl:text>/</xsl:text>
  42       <xsl:value-of select="refentrytitle"/>
  43       <xsl:text>.</xsl:text>
  44       <xsl:value-of select="manvolnum"/>
  45       <xsl:text>.html</xsl:text>
  46     </xsl:attribute>
  47     <xsl:call-template name="inline.charseq"/>
  48   </a>
  49 </xsl:template>
  50
  51 <xsl:template match="citerefentry[@project='die-net']">
  52   <a>
  53     <xsl:attribute name="href">
  54       <xsl:text>http://linux.die.net/man/</xsl:text>
  55       <xsl:value-of select="manvolnum"/>
  56       <xsl:text>/</xsl:text>
  57       <xsl:value-of select="refentrytitle"/>
  58     </xsl:attribute>
  59     <xsl:call-template name="inline.charseq"/>
  60   </a>
  61 </xsl:template>
  62
  63 <xsl:template match="citerefentry[@project='mankier']">
  64   <a>
  65     <xsl:attribute name="href">
  66       <xsl:text>https://www.mankier.com/</xsl:text>
  67       <xsl:value-of select="manvolnum"/>
  68       <xsl:text>/</xsl:text>
  69       <xsl:value-of select="refentrytitle"/>
  70     </xsl:attribute>
  71     <xsl:call-template name="inline.charseq"/>
  72   </a>
  73 </xsl:template>
  74
  75 <xsl:template match="citerefentry[@project='archlinux']">
  76   <a>
  77     <xsl:attribute name="href">
  78       <xsl:text>https://www.archlinux.org/</xsl:text>
  79       <xsl:value-of select="refentrytitle"/>
  80       <xsl:text>/</xsl:text>
  81       <xsl:value-of select="refentrytitle"/>
  82       <xsl:text>.</xsl:text>
  83       <xsl:value-of select="manvolnum"/>
  84       <xsl:text>.html</xsl:text>
  85     </xsl:attribute>
  86     <xsl:call-template name="inline.charseq"/>
  87   </a>
  88 </xsl:template>
  89
  90 <xsl:template match="refsect1/title|refsect1/info/title">
  91   <!-- the ID is output in the block.object call for refsect1 -->
  92   <h2>
  93     <xsl:attribute name="id">
  94       <xsl:call-template name="inline.charseq"/>
  95     </xsl:attribute>
  96     <xsl:apply-templates/>
  97     <a>
  98       <xsl:attribute name="class">
  99         <xsl:text>headerlink</xsl:text>
 100       </xsl:attribute>
 101       <xsl:attribute name="title">
 102         <xsl:text>Permalink to this headline</xsl:text>
 103       </xsl:attribute>
 104       <xsl:attribute name="href">
 105         <xsl:text>#</xsl:text>
 106         <xsl:call-template name="inline.charseq"/>
 107       </xsl:attribute>
 108       <xsl:text>¶</xsl:text>
 109     </a>
 110   </h2>
 111 </xsl:template>
 112
 113 <xsl:template match="refsect2/title|refsect2/info/title">
 114   <h3>
 115     <xsl:attribute name="id">
 116       <xsl:call-template name="inline.charseq"/>
 117     </xsl:attribute>
 118     <xsl:apply-templates/>
 119     <a>
 120       <xsl:attribute name="class">
 121         <xsl:text>headerlink</xsl:text>
 122       </xsl:attribute>
 123       <xsl:attribute name="title">
 124         <xsl:text>Permalink to this headline</xsl:text>
 125       </xsl:attribute>
 126       <xsl:attribute name="href">
 127         <xsl:text>#</xsl:text>
 128         <xsl:call-template name="inline.charseq"/>
 129       </xsl:attribute>
 130       <xsl:text>¶</xsl:text>
 131     </a>
 132   </h3>
 133 </xsl:template>
 134
 135 <xsl:template match="varlistentry">
 136   <dt>
 137     <xsl:attribute name="id">
 138       <xsl:call-template name="inline.charseq">
 139         <xsl:with-param name="content">
 140           <xsl:copy-of select="term[position()=1]" />
 141         </xsl:with-param>
 142       </xsl:call-template>
 143     </xsl:attribute>
 144     <xsl:apply-templates select="term"/>
 145     <a>
 146       <xsl:attribute name="class">
 147         <xsl:text>headerlink</xsl:text>
 148       </xsl:attribute>
 149       <xsl:attribute name="title">
 150         <xsl:text>Permalink to this term</xsl:text>
 151       </xsl:attribute>
 152       <xsl:attribute name="href">
 153         <!--        <xsl:call-template name="href.target.uri" /> -->
 154         <xsl:text>#</xsl:text>
 155         <xsl:call-template name="inline.charseq">
 156           <xsl:with-param name="content">
 157             <xsl:copy-of select="term[position()=1]" />
 158           </xsl:with-param>
 159         </xsl:call-template>
 160       </xsl:attribute>
 161       <xsl:text>¶</xsl:text>
 162     </a>
 163   </dt>
 164   <dd>
 165     <xsl:apply-templates select="listitem"/>
 166   </dd>
 167 </xsl:template>
 168
 169
 170 <!-- add Index link at top of page -->
 171 <xsl:template name="user.header.content">
 172   <style>
 173     a.headerlink {
 174       color: #c60f0f;
 175       font-size: 0.8em;
 176       padding: 0 4px 0 4px;
 177       text-decoration: none;
 178       visibility: hidden;
 179     }
 180
 181     a.headerlink:hover {
 182       background-color: #c60f0f;
 183       color: white;
 184     }
 185
 186     h1:hover > a.headerlink, h2:hover > a.headerlink, h3:hover > a.headerlink, dt:hover > a.headerlink {
 187       visibility: visible;
 188     }
 189   </style>
 190
 191   <a>
 192     <xsl:attribute name="href">
 193       <xsl:text>index.html</xsl:text>
 194     </xsl:attribute>
 195     <xsl:text>Index </xsl:text>
 196   </a>·
 197   <a>
 198     <xsl:attribute name="href">
 199       <xsl:text>systemd.directives.html</xsl:text>
 200     </xsl:attribute>
 201     <xsl:text>Directives </xsl:text>
 202   </a>·
 203   <a>
 204     <xsl:attribute name="href">
 205       <xsl:text>../python-systemd/index.html</xsl:text>
 206     </xsl:attribute>
 207     <xsl:text>Python </xsl:text>
 208   </a>·
 209   <a>
 210     <xsl:attribute name="href">
 211       <xsl:text>../libudev/index.html</xsl:text>
 212     </xsl:attribute>
 213     <xsl:text>libudev </xsl:text>
 214   </a>·
 215   <a>
 216     <xsl:attribute name="href">
 217       <xsl:text>../libudev/index.html</xsl:text>
 218     </xsl:attribute>
 219     <xsl:text>gudev </xsl:text>
 220   </a>
 221
 222   <span style="float:right">
 223     <xsl:text>systemd </xsl:text>
 224     <xsl:value-of select="$systemd.version"/>
 225   </span>
 226   <hr/>
 227 </xsl:template>
 228
 229 <xsl:template match="literal">
 230   <xsl:text>"</xsl:text>
 231   <xsl:call-template name="inline.monoseq"/>
 232   <xsl:text>"</xsl:text>
 233 </xsl:template>
 234
 235 <!-- Switch things to UTF-8, ISO-8859-1 is soo yesteryear -->
 236 <xsl:output method="html" encoding="UTF-8" indent="no"/>
 237
 238 </xsl:stylesheet>