configure.ac

   1 #
   2 #  This file is part of elogind.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  elogind is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  elogind is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([elogind],
  23         [226],
  24         [https://github.com/elogind/elogind/issues],
  25         [elogind],
  26         [https://github.com/elogind/elogind])
  27
  28 AC_CONFIG_SRCDIR([src/login/logind.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=elogind
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96 AC_PATH_PROG([XSLTPROC], [xsltproc])
  97
  98 AC_PATH_PROG([HALT], [halt], [halt])
  99 AC_PATH_PROG([REBOOT], [reboot], [reboot])
 100 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 101
 102 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 103
 104 M4_DEFINES=
 105
 106 AC_CHECK_TOOL(OBJCOPY, objcopy)
 107 AC_CHECK_TOOL(GPERF, gperf)
 108 if test -z "$GPERF" ; then
 109         AC_MSG_ERROR([*** gperf not found])
 110 fi
 111
 112 # ------------------------------------------------------------------------------
 113 address_sanitizer_cflags=
 114 address_sanitizer_cppflags=
 115 address_sanitizer_ldflags=
 116 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 117 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 118             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 119             AS_IF([test -z "$with_as_cflags"],
 120                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 121             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 122             address_sanitizer_cppflags="-DVALGRIND=1"
 123             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 124       ])
 125
 126 undefined_sanitizer_cflags=
 127 undefined_sanitizer_cppflags=
 128 undefined_sanitizer_ldflags=
 129 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 130 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 131             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 132             AS_IF([test -z "$with_us_cflags"],
 133                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 134             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 135             undefined_sanitizer_cppflags="-DVALGRIND=1"
 136             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 137       ])
 138
 139 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 140 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 141 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 142
 143 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 144         -pipe \
 145         -Wall \
 146         -Wextra \
 147         -Wundef \
 148         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 149         -Wlogical-op \
 150         -Wmissing-include-dirs \
 151         -Wold-style-definition \
 152         -Wpointer-arith \
 153         -Winit-self \
 154         -Wdeclaration-after-statement \
 155         -Wfloat-equal \
 156         -Wsuggest-attribute=noreturn \
 157         -Werror=missing-prototypes \
 158         -Werror=implicit-function-declaration \
 159         -Werror=missing-declarations \
 160         -Werror=return-type \
 161         -Werror=shadow \
 162         -Wstrict-prototypes \
 163         -Wredundant-decls \
 164         -Wmissing-noreturn \
 165         -Wshadow \
 166         -Wendif-labels \
 167         -Wstrict-aliasing=2 \
 168         -Wwrite-strings \
 169         -Wno-unused-parameter \
 170         -Wno-missing-field-initializers \
 171         -Wno-unused-result \
 172         -Wno-format-signedness \
 173         -Werror=overflow \
 174         -Wdate-time \
 175         -Wnested-externs \
 176         -ffast-math \
 177         -fno-common \
 178         -fdiagnostics-show-option \
 179         -fno-strict-aliasing \
 180         -fvisibility=hidden \
 181         -fstack-protector \
 182         -fstack-protector-strong \
 183         -fPIE \
 184         --param=ssp-buffer-size=4])
 185
 186 AS_CASE([$CC], [*clang*],
 187         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 188                -Wno-typedef-redefinition \
 189                -Wno-gnu-variable-sized-type-not-at-end \
 190         ])])
 191
 192 dnl AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 193 dnl         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 194 dnl                -flto])],
 195 dnl         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 196 dnl AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 197
 198 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 199         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 200                -Wp,-D_FORTIFY_SOURCE=2])],
 201         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 202 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 203
 204 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 205         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 206                -Wl,--gc-sections])],
 207         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 208 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 209
 210 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 211         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 212                -ffunction-sections -fdata-sections])],
 213         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 214 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 215
 216 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 217         -Wl,--as-needed \
 218         -Wl,--no-undefined \
 219         -Wl,-z,relro \
 220         -Wl,-z,now \
 221         -pie \
 222         -Wl,-fuse-ld=gold])
 223 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 224
 225 AC_CHECK_SIZEOF(pid_t)
 226 AC_CHECK_SIZEOF(uid_t)
 227 AC_CHECK_SIZEOF(gid_t)
 228 AC_CHECK_SIZEOF(time_t)
 229 AC_CHECK_SIZEOF(dev_t)
 230 AC_CHECK_SIZEOF(rlim_t,,[
 231        #include <sys/time.h>
 232        #include <sys/resource.h>
 233 ])
 234
 235 GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
 236
 237 AC_COMPILE_IFELSE(
 238         [AC_LANG_PROGRAM([
 239                 #include <string.h>
 240                 const char * in_word_set(const char *, size_t);
 241                 $GPERF_TEST]
 242         )],
 243         [GPERF_LEN_TYPE=size_t],
 244         [AC_COMPILE_IFELSE(
 245                 [AC_LANG_PROGRAM([
 246                         #include <string.h>
 247                         const char * in_word_set(const char *, unsigned);
 248                         $GPERF_TEST]
 249                 )],
 250                 [GPERF_LEN_TYPE=unsigned],
 251                 [AC_MSG_ERROR([** unable to determine gperf len type])]
 252         )]
 253 )
 254
 255 AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
 256
 257 # ------------------------------------------------------------------------------
 258 # we use python to build the man page index
 259 have_python=no
 260 AC_ARG_WITH([python],
 261         [AS_HELP_STRING([--without-python], [Disable building the man page index (default: test)])])
 262
 263 have_lxml=no
 264 AS_IF([test "x$with_python" != "xno"], [
 265         AM_PATH_PYTHON(,, [:])
 266         AS_IF([test "x$PYTHON" != "x:"], [
 267                 AC_MSG_CHECKING([for python lxml module])
 268                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 269                 AC_MSG_RESULT([$have_lxml])
 270                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 271                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 272         ])
 273 ])
 274 AS_IF([test "$have_python" != "yes"], [
 275       AS_IF([test "$with_python" = "yes"],
 276             [AC_MSG_ERROR([*** python support requested but python support not found])])
 277       AS_IF([test "$with_python" != "no"],
 278             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 279 ])
 280
 281 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 282
 283 # ------------------------------------------------------------------------------
 284
 285 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 286 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 287 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 288
 289 # unconditionally pull-in librt with old glibc versions
 290 dnl AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 291 dnl AC_SEARCH_LIBS([mq_unlink], [rt], [], [])
 292
 293 AC_ARG_WITH([libcap],
 294             AS_HELP_STRING([--with-libcap=DIR], [Prefix for libcap]),
 295             [CAP_LDFLAGS="-L$with_libcap/lib"],
 296             [CAP_LDFLAGS=""])
 297 save_LIBS="$LIBS"
 298 save_LDFLAGS="$LDFLAGS"
 299 LIBS=
 300 LDFLAGS="$LDFLAGS $CAP_LDFLAGS"
 301 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 302 CAP_LIBS="$LIBS"
 303 AC_SUBST(CAP_LIBS)
 304 AC_SUBST(CAP_LDFLAGS)
 305 LIBS="$save_LIBS"
 306 LDFLAGS="$save_LDFLAGS"
 307
 308 AC_CHECK_FUNCS([memfd_create])
 309 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 310 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 311                [], [], [[
 312 #include <sys/types.h>
 313 #include <unistd.h>
 314 #include <sys/mount.h>
 315 #include <fcntl.h>
 316 #include <sched.h>
 317 #include <linux/loop.h>
 318 #include <linux/random.h>
 319 ]])
 320
 321 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 322                 IFLA_MACVLAN_FLAGS,
 323                 IFLA_IPVLAN_MODE,
 324                 IFLA_VTI_REMOTE,
 325                 IFLA_PHYS_PORT_ID,
 326                 IFLA_BOND_AD_INFO,
 327                 IFLA_VLAN_PROTOCOL,
 328                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 329                 IFLA_VXLAN_LOCAL6,
 330                 IFLA_IPTUN_ENCAP_DPORT,
 331                 IFLA_GRE_ENCAP_DPORT,
 332                 IFLA_BRIDGE_VLAN_INFO,
 333                 IFLA_BRPORT_LEARNING_SYNC,
 334                 NDA_IFINDEX,
 335                 IFA_FLAGS],
 336 [], [], [[
 337 #include <inttypes.h>
 338 #include <netinet/in.h>
 339 #include <netinet/ether.h>
 340 #include <linux/rtnetlink.h>
 341 #include <net/if.h>
 342 #include <linux/ip.h>
 343 #include <linux/if_tunnel.h>
 344 #include <linux/if_link.h>
 345 #include <linux/if_bridge.h>
 346 #include <linux/if_addr.h>
 347 #include <linux/neighbour.h>
 348 ]])
 349
 350 # This makes sure pkg.m4 is available.
 351 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 352
 353
 354 # ------------------------------------------------------------------------------
 355 PKG_CHECK_MODULES(UDEV, [libudev])
 356 dnl
 357 AC_ARG_WITH([udevrulesdir],
 358             AS_HELP_STRING([--with-udevrulesdir=DIR], [Directory for udev rules files]),
 359             [],
 360             [with_udevrulesdir=$($PKG_CONFIG --variable=udevdir udev)/rules.d])
 361 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 362
 363 AC_ARG_WITH([udevbindir],
 364             AS_HELP_STRING([--with-udevbindir=DIR], [Directory for udev binary files]),
 365             [],
 366             [with_udevbindir=$($PKG_CONFIG --variable=udevdir udev)])
 367 AC_SUBST([udevbindir], [$with_udevbindir])
 368
 369 # ------------------------------------------------------------------------------
 370 have_coverage=no
 371 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 372 if test "x$enable_coverage" = "xyes" ; then
 373         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 374         if test "x$lcov_found" = xno ; then
 375                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 376         else
 377                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 378                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 379                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 380                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 381                 else
 382                         have_coverage=yes
 383                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 384                         -fprofile-arcs \
 385                         -ftest-coverage])
 386                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 387                 fi
 388         fi
 389 fi
 390 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 391
 392 # ------------------------------------------------------------------------------
 393 have_selinux=no
 394 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 395 if test "x$enable_selinux" != "xno"; then
 396         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 397                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 398                  have_selinux=yes
 399                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 400                 [have_selinux=no])
 401         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 402                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 403         fi
 404 fi
 405 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 406
 407 # ------------------------------------------------------------------------------
 408 AC_ARG_ENABLE([pam],
 409         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 410                 [case "${enableval}" in
 411                         yes) have_pam=yes ;;
 412                         no) have_pam=no ;;
 413                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 414                 esac],
 415                 [have_pam=auto])
 416
 417 if test "x${have_pam}" != xno ; then
 418         AC_CHECK_HEADERS(
 419                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 420                 [have_pam=yes],
 421                 [if test "x$have_pam" = xyes ; then
 422                         AC_MSG_ERROR([*** PAM headers not found.])
 423                 fi])
 424
 425         AC_CHECK_LIB(
 426                 [pam],
 427                 [pam_syslog],
 428                 [have_pam=yes],
 429                 [if test "x$have_pam" = xyes ; then
 430                         AC_MSG_ERROR([*** libpam not found.])
 431                 fi])
 432
 433         if test "x$have_pam" = xyes ; then
 434                 PAM_LIBS="-lpam -lpam_misc"
 435                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 436                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 437         else
 438                 have_pam=no
 439         fi
 440 else
 441         PAM_LIBS=
 442 fi
 443 AC_SUBST(PAM_LIBS)
 444 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 445
 446 # ------------------------------------------------------------------------------
 447 AC_ARG_ENABLE([acl],
 448         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 449                 [case "${enableval}" in
 450                         yes) have_acl=yes ;;
 451                         no) have_acl=no ;;
 452                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 453                 esac],
 454                 [have_acl=auto])
 455
 456 if test "x${have_acl}" != xno ; then
 457         AC_CHECK_HEADERS(
 458                 [sys/acl.h acl/libacl.h],
 459                 [have_acl=yes],
 460                 [if test "x$have_acl" = xyes ; then
 461                         AC_MSG_ERROR([*** ACL headers not found.])
 462                 fi])
 463
 464         AC_CHECK_LIB(
 465                 [acl],
 466                 [acl_get_file],
 467                 [have_acl=yes],
 468                 [if test "x$have_acl" = xyes ; then
 469                         AC_MSG_ERROR([*** libacl not found.])
 470                 fi])
 471
 472         if test "x$have_acl" = xyes ; then
 473                 ACL_LIBS="-lacl"
 474                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 475                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 476         else
 477                 have_acl=no
 478         fi
 479 else
 480         ACL_LIBS=
 481 fi
 482 AC_SUBST(ACL_LIBS)
 483 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 484
 485 # ------------------------------------------------------------------------------
 486 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 487                 [case "${enableval}" in
 488                         yes) have_smack=yes ;;
 489                         no) have_smack=no ;;
 490                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 491                 esac],
 492                 [have_smack=auto])
 493
 494 if test "x${have_smack}" = xauto; then
 495         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 496         have_smack=yes
 497 fi
 498
 499 AC_ARG_WITH(smack-run-label,
 500 AS_HELP_STRING([--with-smack-run-label=STRING],
 501         [run elogind --system itself with a specific SMACK label]),
 502         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run elogind itself with SMACK label])],
 503         [])
 504
 505 AC_ARG_WITH(smack-default-process-label,
 506 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 507         [default SMACK label for executed processes]),
 508         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 509         [])
 510
 511 if test "x${have_smack}" = xyes ; then
 512         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 513 fi
 514
 515 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 516
 517 # ------------------------------------------------------------------------------
 518 AC_ARG_WITH(system-uid-max,
 519         AS_HELP_STRING([--with-system-uid-max=UID]
 520                 [Maximum UID for system users]),
 521         [SYSTEM_UID_MAX="$withval"],
 522         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 523
 524 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 525 AC_SUBST(SYSTEM_UID_MAX)
 526
 527 # ------------------------------------------------------------------------------
 528 AC_ARG_WITH(system-gid-max,
 529         AS_HELP_STRING([--with-system-gid-max=GID]
 530                 [Maximum GID for system groups]),
 531         [SYSTEM_GID_MAX="$withval"],
 532         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 533
 534 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 535 AC_SUBST(SYSTEM_GID_MAX)
 536
 537 # ------------------------------------------------------------------------------
 538 have_polkit=no
 539 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 540 if test "x$enable_polkit" != "xno"; then
 541         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 542         have_polkit=yes
 543 fi
 544 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 545
 546 # ------------------------------------------------------------------------------
 547 have_kdbus=no
 548 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--disable-kdbus], [do not connect to kdbus by default]))
 549 if test "x$enable_kdbus" != "xno"; then
 550         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus is to be connected to by default])
 551         have_kdbus=yes
 552         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 553 fi
 554 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 555
 556 # ------------------------------------------------------------------------------
 557 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 558
 559 # ------------------------------------------------------------------------------
 560 PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0],
 561                   [have_glib=yes], [have_glib=no])
 562 AS_IF([test "x$have_glib" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 563
 564 # ------------------------------------------------------------------------------
 565 have_manpages=no
 566 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 567 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 568 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 569
 570 # ------------------------------------------------------------------------------
 571 AC_SUBST(M4_DEFINES)
 572
 573 AC_ARG_WITH([dbuspolicydir],
 574         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 575         [],
 576         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 577 AX_NORMALIZE_PATH([with_dbuspolicydir])
 578
 579 AC_ARG_WITH([dbussystemservicedir],
 580         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 581         [],
 582         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 583 AX_NORMALIZE_PATH([with_dbussystemservicedir])
 584
 585 AC_ARG_WITH([bashcompletiondir],
 586         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 587         [],
 588         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 589                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 590         ] , [
 591                 with_bashcompletiondir=${datadir}/bash-completion/completions
 592         ])])
 593 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
 594 AX_NORMALIZE_PATH([with_bashcompletiondir])
 595
 596 AC_ARG_WITH([zshcompletiondir],
 597         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 598         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 599 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
 600 AX_NORMALIZE_PATH([with_zshcompletiondir])
 601
 602 AC_ARG_WITH([rootprefix],
 603         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 604         [], [with_rootprefix=${ac_default_prefix}])
 605 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
 606 # defaults those to ".", solve that here for now until we can find a suitable
 607 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
 608 # See: https://github.com/systemd/systemd/issues/54
 609 if test "x${with_rootprefix}" = "x"; then
 610         with_rootprefix="/"
 611 fi
 612 AX_NORMALIZE_PATH([with_rootprefix])
 613
 614 AC_ARG_WITH([rootlibdir],
 615         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 616         [],
 617         [with_rootlibdir=${libdir}])
 618 AX_NORMALIZE_PATH([with_rootlibdir])
 619
 620 AC_ARG_WITH([pamlibdir],
 621         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 622         [],
 623         [with_pamlibdir=${with_rootlibdir}/security])
 624 AX_NORMALIZE_PATH([with_pamlibdir])
 625
 626 AC_ARG_WITH([pamconfdir],
 627         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 628         [],
 629         [with_pamconfdir=${sysconfdir}/pam.d])
 630 AX_NORMALIZE_PATH([with_pamconfdir])
 631
 632 AC_ARG_ENABLE([split-usr],
 633         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 634         [],
 635         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 636                 enable_split_usr=yes
 637         ], [
 638                 enable_split_usr=no
 639         ])])
 640
 641 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 642         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 643 ])
 644 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
 645
 646 # work around intltool-update issues during 'make distcheck'
 647 AS_IF([test "x$0" != "x./configure"], [
 648         AC_SUBST([INTLTOOL_UPDATE], [/usr/bin/env true])
 649 ])
 650
 651 AC_ARG_ENABLE(tests,
 652         [AC_HELP_STRING([--disable-tests], [disable tests])],
 653         enable_tests=$enableval, enable_tests=yes)
 654 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 655
 656 AC_ARG_ENABLE(debug,
 657         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 658         [if test "x$enableval" = "xyes"; then
 659                 enableval="hashmap,mmap-cache"
 660         fi
 661         saved_ifs="$IFS"
 662         IFS="$IFS$PATH_SEPARATOR,"
 663         for name in $enableval; do
 664                 case $name in
 665                 hashmap)
 666                         enable_debug_hashmap=yes
 667                         ;;
 668                 mmap-cache)
 669                         enable_debug_mmap_cache=yes
 670                         ;;
 671                 esac
 672         done
 673         IFS="$saved_ifs"],[])
 674
 675 enable_debug=""
 676 AS_IF([test x$enable_debug_hashmap = xyes], [
 677         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 678         enable_debug="hashmap $enable_debug"
 679 ])
 680 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 681         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 682         enable_debug="mmap-cache $enable_debug"
 683 ])
 684 test -z "$enable_debug" && enable_debug="none"
 685
 686 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 687 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 688 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 689 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 690 AC_SUBST([pamlibdir], [$with_pamlibdir])
 691 AC_SUBST([pamconfdir], [$with_pamconfdir])
 692 AC_SUBST([rootprefix], [$with_rootprefix])
 693 AC_SUBST([rootlibdir], [$with_rootlibdir])
 694
 695 AC_CONFIG_FILES([
 696         Makefile
 697         po/Makefile.in
 698 ])
 699
 700 AC_OUTPUT
 701 AC_MSG_RESULT([
 702         $PACKAGE_NAME $VERSION
 703
 704         PAM:                     ${have_pam}
 705         SELinux:                 ${have_selinux}
 706         SMACK:                   ${have_smack}
 707         ACL:                     ${have_acl}
 708         polkit:                  ${have_polkit}
 709         kdbus:                   ${have_kdbus}
 710         Python:                  ${have_python}
 711         man pages:               ${have_manpages}
 712         test coverage:           ${have_coverage}
 713         Split /usr:              ${enable_split_usr}
 714         extra debugging:         ${enable_debug}
 715
 716         prefix:                  ${prefix}
 717         rootprefix:              ${with_rootprefix}
 718         sysconf dir:             ${sysconfdir}
 719         datarootdir:             ${datarootdir}
 720         includedir:              ${includedir}
 721         lib dir:                 ${libdir}
 722         rootlib dir:             ${with_rootlibdir}
 723         PAM modules dir:         ${with_pamlibdir}
 724         PAM configuration dir:   ${with_pamconfdir}
 725         D-Bus policy dir:        ${with_dbuspolicydir}
 726         D-Bus system dir:        ${with_dbussystemservicedir}
 727         Bash completions dir:    ${with_bashcompletiondir}
 728         Zsh completions dir:     ${with_zshcompletiondir}
 729         Maximum System UID:      ${SYSTEM_UID_MAX}
 730         Maximum System GID:      ${SYSTEM_GID_MAX}
 731
 732         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 733         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 734         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 735 ])