configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [197],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 # i18n stuff for the PolicyKit policy files
  48 IT_PROG_INTLTOOL([0.40.0])
  49
  50 GETTEXT_PACKAGE=systemd
  51 AC_SUBST(GETTEXT_PACKAGE)
  52
  53 AC_PROG_MKDIR_P
  54 AC_PROG_LN_S
  55 AC_PROG_SED
  56 AC_PROG_GREP
  57 AC_PROG_AWK
  58
  59 AC_PROG_CC
  60 AC_PROG_CC_C99
  61 AM_PROG_CC_C_O
  62 AC_PROG_GCC_TRADITIONAL
  63
  64 AC_PATH_PROG([M4], [m4])
  65 AC_PATH_PROG([XSLTPROC], [xsltproc])
  66
  67 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  68 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  69
  70 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  71
  72 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  73
  74 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  75 m4_ifdef([GTK_DOC_CHECK], [
  76 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])
  77 ], [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])])
  78
  79 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  80         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  81 ])
  82
  83 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  84 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  85 ], [
  86    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  87    enable_introspection=no])
  88
  89 AC_PATH_TOOL(OBJCOPY, objcopy)
  90 AC_PATH_TOOL(STRINGS, strings)
  91 AC_PATH_TOOL(GPERF, gperf)
  92 if test -z "$GPERF" ; then
  93         AC_MSG_ERROR([*** gperf not found])
  94 fi
  95
  96 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
  97         -pipe \
  98         -Wall \
  99         -Wextra \
 100         -Wno-inline \
 101         -Wundef \
 102         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 103         -Wlogical-op \
 104         -Wsign-compare \
 105         -Wmissing-include-dirs \
 106         -Wold-style-definition \
 107         -Wpointer-arith \
 108         -Winit-self \
 109         -Wdeclaration-after-statement \
 110         -Wfloat-equal \
 111         -Wmissing-prototypes \
 112         -Wstrict-prototypes \
 113         -Wredundant-decls \
 114         -Wmissing-declarations \
 115         -Wmissing-noreturn \
 116         -Wshadow \
 117         -Wendif-labels \
 118         -Wcast-align \
 119         -Wstrict-aliasing=2 \
 120         -Wwrite-strings \
 121         -Wno-long-long \
 122         -Wno-overlength-strings \
 123         -Wno-unused-parameter \
 124         -Wno-missing-field-initializers \
 125         -Wno-unused-result \
 126         -Werror=overflow \
 127         -ffast-math \
 128         -fno-common \
 129         -fdiagnostics-show-option \
 130         -fno-strict-aliasing \
 131         -fvisibility=hidden \
 132         -ffunction-sections \
 133         -fdata-sections \
 134         -fstack-protector \
 135         --param=ssp-buffer-size=4])
 136 AC_SUBST([OUR_CFLAGS], $with_cflags)
 137
 138 AS_CASE([$CFLAGS], [*-O[[12345\ ]]*], [
 139         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 140                -Wp,-D_FORTIFY_SOURCE=2])], [
 141         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 142         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 143 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 144
 145 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 146         -Wl,--as-needed \
 147         -Wl,--gc-sections \
 148         -Wl,-z,relro \
 149         -Wl,-z,now])
 150 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 151
 152 # ------------------------------------------------------------------------------
 153 # we use python to build the man page index, and for systemd-python
 154 have_python=no
 155 have_python_devel=no
 156
 157 AC_ARG_WITH([python],
 158         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 159
 160 AS_IF([test "x$with_python" != "xno"], [
 161         AM_PATH_PYTHON(,, [:])
 162         AS_IF([test "$PYTHON" != :], [have_python=yes])
 163 ])
 164 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 165 AS_IF([test "x$PYTHON_BINARY" = "x"],
 166       [AS_IF([test "x$have_python" = "xyes"],
 167              [PYTHON_BINARY="`which "$PYTHON"`"],
 168              [PYTHON_BINARY=/usr/bin/python])])
 169 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 170
 171 AS_IF([test "x$with_python" != "xno"], [
 172         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 173         AS_IF([test -n "$PYTHON_CONFIG"], [
 174               have_python_devel=yes
 175               PYTHON_CFLAGS="`$PYTHON_CONFIG --cflags` $python_extra_cflags"
 176               PYTHON_LIBS="`$PYTHON_CONFIG --ldflags`"
 177               AC_SUBST(PYTHON_CFLAGS)
 178               AC_SUBST(PYTHON_LIBS)
 179         ])
 180 ])
 181 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 182
 183 AC_ARG_ENABLE(sphinx, AS_HELP_STRING([--enable-sphinx],
 184               [use sphinx to build documentation for python-systemd]))
 185 AS_IF([test "x$enable_sphinx" = "xyes"], [
 186         AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 187         AS_IF([test -z "$SPHINX_BUILD"], [
 188               AC_MSG_ERROR([*** sphinx build requested, but sphinx-build not found])
 189         ])
 190         AS_IF([test "x$have_python_devel" != "xyes"], [
 191               AC_MSG_ERROR([*** sphinx build requested, but python support not enabled])
 192         ])
 193 ])
 194 AM_CONDITIONAL(ENABLE_SPHINX, [test "x$enable_sphinx" = "xyes"])
 195
 196 # ------------------------------------------------------------------------------
 197
 198 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 199 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 200
 201 save_LIBS="$LIBS"
 202 LIBS=
 203 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 204 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 205 CAP_LIBS="$LIBS"
 206 LIBS="$save_LIBS"
 207 AC_SUBST(CAP_LIBS)
 208
 209 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 210 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 211 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 212 #include <unistd.h>
 213 #include <sys/mount.h>
 214 #include <fcntl.h>]])
 215
 216 # This makes sure pkg.m4 is available.
 217 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 218
 219 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 220
 221 # ------------------------------------------------------------------------------
 222 have_kmod=no
 223 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 224 if test "x$enable_kmod" != "xno"; then
 225         PKG_CHECK_MODULES(KMOD, [ libkmod >= 5 ],
 226                 [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available]) have_kmod=yes], have_kmod=no)
 227         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 228                 AC_MSG_ERROR([*** kmod support requested but libraries not found])
 229         fi
 230 fi
 231 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 232
 233 # ------------------------------------------------------------------------------
 234 have_blkid=no
 235 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 236 if test "x$enable_blkid" != "xno"; then
 237         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 238                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 239         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 240                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 241         fi
 242 fi
 243 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 244
 245 # ------------------------------------------------------------------------------
 246 have_ima=yes
 247 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 248                 [case "${enableval}" in
 249                         yes) have_ima=yes ;;
 250                         no) have_ima=no ;;
 251                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 252                 esac],
 253                 [have_ima=yes])
 254
 255 if test "x${have_ima}" != xno ; then
 256         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 257 fi
 258
 259 # ------------------------------------------------------------------------------
 260 have_chkconfig=yes
 261 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 262                 [case "${enableval}" in
 263                         yes) have_chkconfig=yes ;;
 264                         no) have_chkconfig=no ;;
 265                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 266                 esac],
 267                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 268                 if test -z "$CHKCONFIG"; then
 269                         have_chkconfig=no
 270                 else
 271                         have_chkconfig=yes
 272                 fi])
 273
 274 if test "x${have_chkconfig}" != xno ; then
 275         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 276 fi
 277
 278 # ------------------------------------------------------------------------------
 279 have_selinux=no
 280 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 281 if test "x$enable_selinux" != "xno"; then
 282         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 283                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 284         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 285                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 286         fi
 287 fi
 288 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 289 if test "x${have_selinux}" != xno ; then
 290         sushell=/sbin/sushell
 291 else
 292         sushell=/bin/bash
 293 fi
 294 AC_SUBST(sushell)
 295
 296 # ------------------------------------------------------------------------------
 297 have_xz=no
 298 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 299 if test "x$enable_xz" != "xno"; then
 300         PKG_CHECK_MODULES(XZ, [ liblzma ],
 301                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 302         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 303                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 304         fi
 305 fi
 306 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 307
 308 # ------------------------------------------------------------------------------
 309 AC_ARG_ENABLE([tcpwrap],
 310         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 311                 [case "${enableval}" in
 312                         yes) have_tcpwrap=yes ;;
 313                         no) have_tcpwrap=no ;;
 314                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 315                 esac],
 316                 [have_tcpwrap=auto])
 317
 318 if test "x${have_tcpwrap}" != xno ; then
 319         ACX_LIBWRAP
 320         if test "x${LIBWRAP_LIBS}" = x ; then
 321                 if test "x$have_tcpwrap" = xyes ; then
 322                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 323                 fi
 324                 have_tcpwrap=no
 325         else
 326                 have_tcpwrap=yes
 327         fi
 328 else
 329         LIBWRAP_LIBS=
 330 fi
 331 AC_SUBST(LIBWRAP_LIBS)
 332
 333 # ------------------------------------------------------------------------------
 334 AC_ARG_ENABLE([pam],
 335         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 336                 [case "${enableval}" in
 337                         yes) have_pam=yes ;;
 338                         no) have_pam=no ;;
 339                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 340                 esac],
 341                 [have_pam=auto])
 342
 343 if test "x${have_pam}" != xno ; then
 344         AC_CHECK_HEADERS(
 345                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 346                 [have_pam=yes],
 347                 [if test "x$have_pam" = xyes ; then
 348                         AC_MSG_ERROR([*** PAM headers not found.])
 349                 fi])
 350
 351         AC_CHECK_LIB(
 352                 [pam],
 353                 [pam_syslog],
 354                 [have_pam=yes],
 355                 [if test "x$have_pam" = xyes ; then
 356                         AC_MSG_ERROR([*** libpam not found.])
 357                 fi])
 358
 359         if test "x$have_pam" = xyes ; then
 360                 PAM_LIBS="-lpam -lpam_misc"
 361                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 362         else
 363                 have_pam=no
 364         fi
 365 else
 366         PAM_LIBS=
 367 fi
 368 AC_SUBST(PAM_LIBS)
 369 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 370
 371 # ------------------------------------------------------------------------------
 372 AC_ARG_ENABLE([acl],
 373         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 374                 [case "${enableval}" in
 375                         yes) have_acl=yes ;;
 376                         no) have_acl=no ;;
 377                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 378                 esac],
 379                 [have_acl=auto])
 380
 381 if test "x${have_acl}" != xno ; then
 382         AC_CHECK_HEADERS(
 383                 [sys/acl.h acl/libacl.h],
 384                 [have_acl=yes],
 385                 [if test "x$have_acl" = xyes ; then
 386                         AC_MSG_ERROR([*** ACL headers not found.])
 387                 fi])
 388
 389         AC_CHECK_LIB(
 390                 [acl],
 391                 [acl_get_file],
 392                 [have_acl=yes],
 393                 [if test "x$have_acl" = xyes ; then
 394                         AC_MSG_ERROR([*** libacl not found.])
 395                 fi])
 396
 397         if test "x$have_acl" = xyes ; then
 398                 ACL_LIBS="-lacl"
 399                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 400         else
 401                 have_acl=no
 402         fi
 403 else
 404         ACL_LIBS=
 405 fi
 406 AC_SUBST(ACL_LIBS)
 407 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 408
 409 # ------------------------------------------------------------------------------
 410 AC_ARG_ENABLE([xattr],
 411         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 412                 [case "${enableval}" in
 413                         yes) have_xattr=yes ;;
 414                         no) have_xattr=no ;;
 415                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 416                 esac],
 417                 [have_xattr=auto])
 418
 419 if test "x${have_xattr}" != xno ; then
 420         AC_CHECK_HEADERS(
 421                 [attr/xattr.h],
 422                 [have_xattr=yes],
 423                 [if test "x$have_xattr" = xyes ; then
 424                         AC_MSG_ERROR([*** XATTR headers not found.])
 425                 fi])
 426
 427         AC_CHECK_LIB(
 428                 [attr],
 429                 [fsetxattr],
 430                 [have_xattr=yes],
 431                 [if test "x$have_xattr" = xyes ; then
 432                         AC_MSG_ERROR([*** libattr not found.])
 433                 fi])
 434
 435         if test "x$have_xattr" = xyes ; then
 436                 XATTR_LIBS="-lattr"
 437                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 438         else
 439                 have_xattr=no
 440         fi
 441 else
 442         XATTR_LIBS=
 443 fi
 444 AC_SUBST(XATTR_LIBS)
 445 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 446
 447 # ------------------------------------------------------------------------------
 448 AC_ARG_ENABLE([gcrypt],
 449         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 450                 [case "${enableval}" in
 451                         yes) have_gcrypt=yes ;;
 452                         no) have_gcrypt=no ;;
 453                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 454                 esac],
 455                 [have_gcrypt=auto])
 456
 457 if test "x${have_gcrypt}" != xno ; then
 458         AM_PATH_LIBGCRYPT(
 459                 [1.4.5],
 460                 [have_gcrypt=yes],
 461                 [if test "x$have_gcrypt" = xyes ; then
 462                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 463                 fi])
 464
 465         if test "x$have_gcrypt" = xyes ; then
 466                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 467                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 468                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 469         else
 470                 have_gcrypt=no
 471         fi
 472 else
 473         GCRYPT_LIBS=
 474         GCRYPT_CFLAGS=
 475 fi
 476 AC_SUBST(GCRYPT_LIBS)
 477 AC_SUBST(GCRYPT_CFLAGS)
 478 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 479
 480 # ------------------------------------------------------------------------------
 481 AC_ARG_ENABLE([audit],
 482         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 483                 [case "${enableval}" in
 484                         yes) have_audit=yes ;;
 485                         no) have_audit=no ;;
 486                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 487                 esac],
 488                 [have_audit=auto])
 489
 490 if test "x${have_audit}" != xno ; then
 491         AC_CHECK_HEADERS(
 492                 [libaudit.h],
 493                 [have_audit=yes],
 494                 [if test "x$have_audit" = xyes ; then
 495                         AC_MSG_ERROR([*** AUDIT headers not found.])
 496                 fi])
 497
 498         AC_CHECK_LIB(
 499                 [audit],
 500                 [audit_open],
 501                 [have_audit=yes],
 502                 [if test "x$have_audit" = xyes ; then
 503                         AC_MSG_ERROR([*** libaudit not found.])
 504                 fi])
 505
 506         if test "x$have_audit" = xyes ; then
 507                 AUDIT_LIBS="-laudit"
 508                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 509         else
 510                 have_audit=no
 511         fi
 512 else
 513         AUDIT_LIBS=
 514 fi
 515 AC_SUBST(AUDIT_LIBS)
 516
 517 # ------------------------------------------------------------------------------
 518 have_libcryptsetup=no
 519 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 520 if test "x$enable_libcryptsetup" != "xno"; then
 521         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 522                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 523         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 524                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 525         fi
 526 fi
 527 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 528
 529 # ------------------------------------------------------------------------------
 530 have_qrencode=no
 531 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 532 if test "x$enable_qrencode" != "xno"; then
 533         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 534                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 535         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 536                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 537         fi
 538 fi
 539 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 540
 541 # ------------------------------------------------------------------------------
 542 have_microhttpd=no
 543 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 544 if test "x$enable_microhttpd" != "xno"; then
 545         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 546                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 547         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 548                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 549         fi
 550 fi
 551 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 552
 553 # ------------------------------------------------------------------------------
 554 have_binfmt=no
 555 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 556 if test "x$enable_binfmt" != "xno"; then
 557         have_binfmt=yes
 558 fi
 559 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 560
 561 # ------------------------------------------------------------------------------
 562 have_vconsole=no
 563 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 564 if test "x$enable_vconsole" != "xno"; then
 565         have_vconsole=yes
 566 fi
 567 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 568
 569 # ------------------------------------------------------------------------------
 570 have_readahead=no
 571 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 572 if test "x$enable_readahead" != "xno"; then
 573         have_readahead=yes
 574 fi
 575 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 576
 577 # ------------------------------------------------------------------------------
 578 have_bootchart=no
 579 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 580 if test "x$enable_bootchart" != "xno"; then
 581         have_bootchart=yes
 582 fi
 583 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 584
 585 # ------------------------------------------------------------------------------
 586 have_quotacheck=no
 587 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 588 if test "x$enable_quotacheck" != "xno"; then
 589         have_quotacheck=yes
 590 fi
 591 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 592
 593 # ------------------------------------------------------------------------------
 594 have_randomseed=no
 595 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 596 if test "x$enable_randomseed" != "xno"; then
 597         have_randomseed=yes
 598 fi
 599 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 600
 601 # ------------------------------------------------------------------------------
 602 have_logind=no
 603 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 604 if test "x$enable_logind" != "xno"; then
 605         have_logind=yes
 606 fi
 607 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 608 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 609
 610 # ------------------------------------------------------------------------------
 611 have_hostnamed=no
 612 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 613 if test "x$enable_hostnamed" != "xno"; then
 614         have_hostnamed=yes
 615 fi
 616 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 617
 618 # ------------------------------------------------------------------------------
 619 have_timedated=no
 620 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 621 if test "x$enable_timedated" != "xno"; then
 622         have_timedated=yes
 623 fi
 624 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 625
 626 # ------------------------------------------------------------------------------
 627 have_localed=no
 628 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 629 if test "x$enable_localed" != "xno"; then
 630         have_localed=yes
 631 fi
 632 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 633
 634 # ------------------------------------------------------------------------------
 635 have_coredump=no
 636 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 637 if test "x$enable_coredump" != "xno"; then
 638         have_coredump=yes
 639 fi
 640 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 641
 642 # ------------------------------------------------------------------------------
 643 have_polkit=no
 644 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 645 if test "x$enable_polkit" != "xno"; then
 646         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 647         have_polkit=yes
 648 fi
 649 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 650
 651 # ------------------------------------------------------------------------------
 652 have_efi=no
 653 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 654 if test "x$enable_efi" != "xno"; then
 655         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 656         have_efi=yes
 657 fi
 658 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 659
 660 # ------------------------------------------------------------------------------
 661 AC_ARG_WITH(rc-local-script-path-start,
 662         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 663                 [Path to /etc/rc.local]),
 664         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 665         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 666
 667 AC_ARG_WITH(rc-local-script-path-stop,
 668         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 669                 [Path to /usr/sbin/halt.local]),
 670         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 671         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 672
 673 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 674 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 675
 676 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 677 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 678
 679 # ------------------------------------------------------------------------------
 680 AC_ARG_WITH(kbd-loadkeys,
 681         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 682                 [Path to loadkeys]),
 683         [KBD_LOADKEYS="$withval"],
 684         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 685
 686 AC_ARG_WITH(kbd-setfont,
 687         AS_HELP_STRING([--with-kbd-setfont=PATH],
 688                 [Path to setfont]),
 689         [KBD_SETFONT="$withval"],
 690         [KBD_SETFONT="/usr/bin/setfont"])
 691
 692 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 693 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 694
 695 AC_SUBST(KBD_LOADKEYS)
 696 AC_SUBST(KBD_SETFONT)
 697
 698 # ------------------------------------------------------------------------------
 699 have_myhostname=no
 700 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 701 if test "x$enable_myhostname" != "xno"; then
 702         AC_HEADER_STDC
 703         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 704
 705         AC_C_CONST
 706         AC_TYPE_SIZE_T
 707         AC_HEADER_TIME
 708
 709         AC_FUNC_MALLOC
 710         AC_FUNC_SELECT_ARGTYPES
 711         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 712
 713         have_myhostname=yes
 714 fi
 715 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 716
 717 # ------------------------------------------------------------------------------
 718 AC_ARG_WITH(firmware-path,
 719        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 720           [Firmware search path (default=ROOTPREFIX/lib/firmware/updates:ROOTPREFIX/lib/firmware)]),
 721        [], [with_firmware_path="$rootprefix/lib/firmware/updates:$rootprefix/lib/firmware"])
 722 OLD_IFS=$IFS
 723 IFS=:
 724 for i in $with_firmware_path; do
 725        if test "x${FIRMWARE_PATH}" = "x"; then
 726               FIRMWARE_PATH="\\\"${i}/\\\""
 727        else
 728               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 729        fi
 730 done
 731 IFS=$OLD_IFS
 732 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
 733
 734 # ------------------------------------------------------------------------------
 735 AC_ARG_ENABLE([gudev],
 736        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 737        [], [enable_gudev=yes])
 738 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0]) ])
 739 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 740
 741 # ------------------------------------------------------------------------------
 742 AC_ARG_ENABLE([keymap],
 743        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 744        [], [enable_keymap=yes])
 745 AS_IF([test "x$enable_keymap" = "xyes"], [
 746        AC_PATH_PROG([GPERF], [gperf])
 747        if test -z "$GPERF"; then
 748               AC_MSG_ERROR([gperf is needed])
 749        fi
 750
 751        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 752        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 753 ])
 754 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 755
 756 # ------------------------------------------------------------------------------
 757 have_manpages=no
 758 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 759 AS_IF([test "x$enable_manpages" != xno], [
 760         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 761                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 762         ])
 763         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 764 ])
 765 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 766
 767 # ------------------------------------------------------------------------------
 768
 769 # Location of the init scripts as mandated by LSB
 770 SYSTEM_SYSVINIT_PATH=/etc/init.d
 771 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 772 M4_DEFINES=
 773
 774 AC_ARG_WITH([sysvinit-path],
 775         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 776                 [Specify the path to where the SysV init scripts are located])],
 777         [SYSTEM_SYSVINIT_PATH="$withval"],
 778         [])
 779
 780 AC_ARG_WITH([sysvrcnd-path],
 781         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 782                 [Specify the path to the base directory for the SysV rcN.d directories])],
 783         [SYSTEM_SYSVRCND_PATH="$withval"],
 784         [])
 785
 786 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 787         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 788         SYSTEM_SYSV_COMPAT="yes"
 789         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 790 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 791         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 792 else
 793         SYSTEM_SYSV_COMPAT="no"
 794 fi
 795
 796 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 797 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 798 AC_SUBST(M4_DEFINES)
 799
 800 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 801
 802 AC_ARG_WITH([tty-gid],
 803         [AS_HELP_STRING([--with-tty-gid=GID],
 804                 [Specify the numeric GID of the 'tty' group])],
 805         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 806         [])
 807
 808 AC_ARG_WITH([dbuspolicydir],
 809         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 810         [],
 811         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 812
 813 AC_ARG_WITH([dbussessionservicedir],
 814         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 815         [],
 816         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 817
 818 AC_ARG_WITH([dbussystemservicedir],
 819         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 820         [],
 821         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 822
 823 AC_ARG_WITH([dbusinterfacedir],
 824         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 825         [],
 826         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 827
 828 AC_ARG_WITH([rootprefix],
 829         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 830         [], [with_rootprefix=${ac_default_prefix}])
 831
 832 AC_ARG_WITH([rootlibdir],
 833         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 834         [],
 835         [with_rootlibdir=${libdir}])
 836
 837 AC_ARG_WITH([pamlibdir],
 838         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 839         [],
 840         [with_pamlibdir=${with_rootlibdir}/security])
 841
 842 AC_ARG_ENABLE([split-usr],
 843         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 844         [],
 845         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 846                 enable_split_usr=yes
 847         ], [
 848                 enable_split_usr=no
 849         ])])
 850
 851 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 852         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 853 ])
 854
 855 # Work around intltoolize and gtk-doc problems in VPATH builds
 856 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 857                                        [Define to do gtk-doc tests])
 858 AS_IF([test "x$0" != "x./configure"], [
 859         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 860 ])
 861
 862 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 863 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 864 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 865 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 866 AC_SUBST([pamlibdir], [$with_pamlibdir])
 867 AC_SUBST([rootprefix], [$with_rootprefix])
 868 AC_SUBST([rootlibdir], [$with_rootlibdir])
 869
 870 AC_CONFIG_FILES([
 871         Makefile po/Makefile.in
 872         docs/libudev/Makefile
 873         docs/libudev/version.xml
 874         docs/gudev/Makefile
 875         docs/gudev/version.xml
 876 ])
 877
 878 AC_OUTPUT
 879 AC_MSG_RESULT([
 880         $PACKAGE_NAME $VERSION
 881
 882         libcryptsetup:           ${have_libcryptsetup}
 883         tcpwrap:                 ${have_tcpwrap}
 884         PAM:                     ${have_pam}
 885         AUDIT:                   ${have_audit}
 886         IMA:                     ${have_ima}
 887         SELinux:                 ${have_selinux}
 888         XZ:                      ${have_xz}
 889         ACL:                     ${have_acl}
 890         XATTR:                   ${have_xattr}
 891         GCRYPT:                  ${have_gcrypt}
 892         QRENCODE:                ${have_qrencode}
 893         MICROHTTPD:              ${have_microhttpd}
 894         CHKCONFIG:               ${have_chkconfig}
 895         binfmt:                  ${have_binfmt}
 896         vconsole:                ${have_vconsole}
 897         readahead:               ${have_readahead}
 898         bootchart:               ${have_bootchart}
 899         quotacheck:              ${have_quotacheck}
 900         randomseed:              ${have_randomseed}
 901         logind:                  ${have_logind}
 902         hostnamed:               ${have_hostnamed}
 903         timedated:               ${have_timedated}
 904         localed:                 ${have_localed}
 905         coredump:                ${have_coredump}
 906         polkit:                  ${have_polkit}
 907         efi:                     ${have_efi}
 908         kmod:                    ${have_kmod}
 909         blkid:                   ${have_blkid}
 910         nss-myhostname:          ${have_myhostname}
 911         gudev:                   ${enable_gudev}
 912         gintrospection:          ${enable_introspection}
 913         keymap:                  ${enable_keymap}
 914         Python:                  ${have_python}
 915         Python Headers:          ${have_python_devel}
 916         man pages:               ${have_manpages}
 917         gtk-doc:                 ${enable_gtk_doc}
 918         sphinx documentation:    ${enable_sphinx}
 919         Split /usr:              ${enable_split_usr}
 920         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 921
 922         prefix:                  ${prefix}
 923         rootprefix:              ${with_rootprefix}
 924         sysconf dir:             ${sysconfdir}
 925         datarootdir:             ${datarootdir}
 926         includedir:              ${includedir}
 927         include_prefix:          ${INCLUDE_PREFIX}
 928         lib dir:                 ${libdir}
 929         rootlib dir:             ${with_rootlibdir}
 930         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 931         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 932         Build Python:            ${PYTHON}
 933         Installation Python:     ${PYTHON_BINARY}
 934         firmware path:           ${FIRMWARE_PATH}
 935         PAM modules dir:         ${with_pamlibdir}
 936         D-Bus policy dir:        ${with_dbuspolicydir}
 937         D-Bus session dir:       ${with_dbussessionservicedir}
 938         D-Bus system dir:        ${with_dbussystemservicedir}
 939         D-Bus interfaces dir:    ${with_dbusinterfacedir}
 940         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
 941         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
 942
 943         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 944         CPPLAGS:                 ${OUR_CPPFLAGS} ${CPPFLAGS}
 945         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 946         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
 947         PYTHON_LIBS:             ${PYTHON_LIBS}
 948 ])