configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 # FIXME: Update to proper web page
  23 AC_INIT([elogind],
  24         [219],
  25         [http://bugs.freedesktop.org/enter_bug.cgi?product=elogind],
  26         [elogind],
  27         [http://www.freedesktop.org/wiki/Software/elogind])
  28
  29 AC_CONFIG_SRCDIR([src/login/logind.c])
  30 AC_CONFIG_MACRO_DIR([m4])
  31 AC_CONFIG_HEADERS([config.h])
  32 AC_CONFIG_AUX_DIR([build-aux])
  33
  34 AC_USE_SYSTEM_EXTENSIONS
  35 AC_SYS_LARGEFILE
  36 AC_PREFIX_DEFAULT([/usr])
  37 AM_MAINTAINER_MODE([enable])
  38 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  39 AM_SILENT_RULES([yes])
  40 AC_CANONICAL_HOST
  41 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  42 LT_PREREQ(2.2)
  43 LT_INIT([disable-static])
  44
  45 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by elogind])])
  46 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by elogind])])
  47
  48 SET_ARCH(X86_64, x86_64*)
  49 SET_ARCH(IA32, i*86*)
  50 SET_ARCH(MIPS, mips*)
  51
  52 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  53 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  54 AS_IF([test x"$intltool_found" != xyes],
  55       [AS_IF([test x"$enable_nls" = xyes],
  56              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  57              [AS_IF([test x"$enable_nls" != xno],
  58                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  59                      enable_nls=no])
  60              ])
  61       ])
  62
  63 AM_NLS
  64 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  65     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  66 IT_PROG_INTLTOOL([0.40.0])
  67 ])
  68
  69 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  70     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  71     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  72     AC_SUBST(INTLTOOL_POLICY_RULE)
  73 ])
  74
  75 GETTEXT_PACKAGE=elogind
  76 AC_SUBST(GETTEXT_PACKAGE)
  77 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [elogind])
  78
  79 AC_PROG_MKDIR_P
  80 AC_PROG_LN_S
  81 AC_PROG_SED
  82 AC_PROG_GREP
  83 AC_PROG_AWK
  84
  85 AC_PROG_CC_C99
  86
  87 AC_PATH_PROG([M4], [m4])
  88 AC_PATH_PROG([XSLTPROC], [xsltproc])
  89
  90 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
  91
  92 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
  93
  94 M4_DEFINES=
  95
  96 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  97 m4_ifdef([GTK_DOC_CHECK], [
  98 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  99          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
 100           enable_gtk_doc=no])
 101
 102 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
 103         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
 104 ])
 105
 106 AC_CHECK_TOOL(GPERF, gperf)
 107 if test -z "$GPERF" ; then
 108         AC_MSG_ERROR([*** gperf not found])
 109 fi
 110
 111 # ------------------------------------------------------------------------------
 112 address_sanitizer_cflags=
 113 address_sanitizer_cppflags=
 114 address_sanitizer_ldflags=
 115 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 116 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 117             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 118             AS_IF([test -z "$with_as_cflags"],
 119                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 120             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 121             address_sanitizer_cppflags="-DVALGRIND=1"
 122             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 123       ])
 124
 125 undefined_sanitizer_cflags=
 126 undefined_sanitizer_cppflags=
 127 undefined_sanitizer_ldflags=
 128 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 129 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 131             AS_IF([test -z "$with_us_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 133             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             undefined_sanitizer_cppflags="-DVALGRIND=1"
 135             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 136       ])
 137
 138 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 139 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 140 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 141
 142 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 143         -pipe \
 144         -Wall \
 145         -Wextra \
 146         -Wno-inline \
 147         -Wundef \
 148         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 149         -Wlogical-op \
 150         -Wsign-compare \
 151         -Wmissing-include-dirs \
 152         -Wold-style-definition \
 153         -Wpointer-arith \
 154         -Winit-self \
 155         -Wdeclaration-after-statement \
 156         -Wfloat-equal \
 157         -Wsuggest-attribute=noreturn \
 158         -Wmissing-prototypes \
 159         -Wstrict-prototypes \
 160         -Wredundant-decls \
 161         -Wmissing-declarations \
 162         -Wmissing-noreturn \
 163         -Wshadow \
 164         -Wendif-labels \
 165         -Wstrict-aliasing=2 \
 166         -Wwrite-strings \
 167         -Wno-long-long \
 168         -Wno-overlength-strings \
 169         -Wno-unused-parameter \
 170         -Wno-missing-field-initializers \
 171         -Wno-unused-result \
 172         -Wno-format-signedness \
 173         -Werror=overflow \
 174         -Wdate-time \
 175         -Wnested-externs \
 176         -ffast-math \
 177         -fno-common \
 178         -fdiagnostics-show-option \
 179         -fno-strict-aliasing \
 180         -fvisibility=hidden \
 181         -ffunction-sections \
 182         -fdata-sections \
 183         -fstack-protector \
 184         -fstack-protector-strong \
 185         -fPIE \
 186         --param=ssp-buffer-size=4])
 187
 188 AS_CASE([$CC], [*clang*],
 189         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 190                -Wno-typedef-redefinition \
 191                -Wno-gnu-variable-sized-type-not-at-end \
 192         ])])
 193
 194 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 195         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 196                -flto -ffat-lto-objects])],
 197         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 198 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 199
 200 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 201         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 202                -Wp,-D_FORTIFY_SOURCE=2])],
 203         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 204 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 205
 206 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 207         -Wl,--as-needed \
 208         -Wl,--no-undefined \
 209         -Wl,--gc-sections \
 210         -Wl,-z,relro \
 211         -Wl,-z,now \
 212         -pie \
 213         -Wl,-fuse-ld=gold])
 214 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 215
 216 AC_CHECK_SIZEOF(pid_t)
 217 AC_CHECK_SIZEOF(uid_t)
 218 AC_CHECK_SIZEOF(gid_t)
 219 AC_CHECK_SIZEOF(time_t)
 220 AC_CHECK_SIZEOF(dev_t)
 221 AC_CHECK_SIZEOF(rlim_t,,[
 222        #include <sys/time.h>
 223        #include <sys/resource.h>
 224 ])
 225
 226 # ------------------------------------------------------------------------------
 227
 228 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 229 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 230 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 231
 232 # unconditionally pull-in librt with old glibc versions
 233 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 234
 235 save_LIBS="$LIBS"
 236 LIBS=
 237 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 238 CAP_LIBS="$LIBS"
 239 AC_SUBST(CAP_LIBS)
 240
 241 AC_CHECK_FUNCS([memfd_create])
 242 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 243 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at, setns, getrandom, renameat2, kcmp, LO_FLAGS_PARTSCAN],
 244                [], [], [[
 245 #include <sys/types.h>
 246 #include <unistd.h>
 247 #include <sys/mount.h>
 248 #include <fcntl.h>
 249 #include <sched.h>
 250 #include <linux/loop.h>
 251 #include <linux/random.h>
 252 ]])
 253
 254 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 255                 IFLA_MACVLAN_FLAGS,
 256                 IFLA_IPVLAN_MODE,
 257                 IFLA_VTI_REMOTE,
 258                 IFLA_PHYS_PORT_ID,
 259                 IFLA_BOND_AD_INFO,
 260                 IFLA_VLAN_PROTOCOL,
 261                 IFLA_VXLAN_LOCAL6,
 262                 IFLA_IPTUN_6RD_RELAY_PREFIXLEN,
 263                 IFLA_BRIDGE_VLAN_INFO,
 264                 IFLA_BRPORT_UNICAST_FLOOD,
 265                 NDA_IFINDEX],
 266 [], [], [[
 267 #include <inttypes.h>
 268 #include <netinet/in.h>
 269 #include <netinet/ether.h>
 270 #include <linux/rtnetlink.h>
 271 #include <net/if.h>
 272 #include <linux/ip.h>
 273 #include <linux/if_tunnel.h>
 274 #include <linux/if_link.h>
 275 #include <linux/if_bridge.h>
 276 #include <linux/neighbour.h>
 277 ]])
 278
 279 # This makes sure pkg.m4 is available.
 280 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 281
 282 # ------------------------------------------------------------------------------
 283 have_dbus=no
 284 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 285 AS_IF([test "x$enable_dbus" != "xno"], [
 286         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 287                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 288                 [have_dbus=no])
 289         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 290                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 291 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 292
 293 # ------------------------------------------------------------------------------
 294 PKG_CHECK_MODULES(UDEV, [libudev])
 295
 296 # ------------------------------------------------------------------------------
 297 have_coverage=no
 298 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 299 if test "x$enable_coverage" = "xyes" ; then
 300         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 301         if test "x$lcov_found" = xno ; then
 302                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 303         else
 304                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 305                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 306                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 307                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 308                 else
 309                         have_coverage=yes
 310                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 311                         -fprofile-arcs \
 312                         -ftest-coverage])
 313                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 314                 fi
 315         fi
 316 fi
 317 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 318
 319 # ------------------------------------------------------------------------------
 320 have_blkid=no
 321 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 322 if test "x$enable_blkid" != "xno"; then
 323         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 324                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 325         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 326                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 327         fi
 328 fi
 329 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 330
 331 # ------------------------------------------------------------------------------
 332 have_seccomp=no
 333 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 334 if test "x$enable_seccomp" != "xno"; then
 335         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 336                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 337                 have_seccomp=yes
 338                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 339                [have_seccomp=no])
 340         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 341                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 342         fi
 343 fi
 344 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 345
 346 # ------------------------------------------------------------------------------
 347 have_selinux=no
 348 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 349 if test "x$enable_selinux" != "xno"; then
 350         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 351                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 352                  have_selinux=yes
 353                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 354                 [have_selinux=no])
 355         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 356                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 357         fi
 358 fi
 359 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 360
 361 have_apparmor=no
 362 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 363 if test "x$enable_apparmor" != "xno"; then
 364         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 365                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 366                  have_apparmor=yes
 367                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 368                 [have_apparmor=no])
 369         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 370                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 371         fi
 372 fi
 373 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 374
 375
 376 AC_ARG_WITH([certificate-root],
 377         AS_HELP_STRING([--with-certificate-root=PATH],
 378                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 379         [CERTIFICATEROOT="$withval"],
 380         [CERTIFICATEROOT="/etc/ssl"])
 381
 382 AC_SUBST(CERTIFICATEROOT)
 383
 384 # ------------------------------------------------------------------------------
 385 AC_ARG_ENABLE([pam],
 386         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 387                 [case "${enableval}" in
 388                         yes) have_pam=yes ;;
 389                         no) have_pam=no ;;
 390                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 391                 esac],
 392                 [have_pam=auto])
 393
 394 if test "x${have_pam}" != xno ; then
 395         AC_CHECK_HEADERS(
 396                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 397                 [have_pam=yes],
 398                 [if test "x$have_pam" = xyes ; then
 399                         AC_MSG_ERROR([*** PAM headers not found.])
 400                 fi])
 401
 402         AC_CHECK_LIB(
 403                 [pam],
 404                 [pam_syslog],
 405                 [have_pam=yes],
 406                 [if test "x$have_pam" = xyes ; then
 407                         AC_MSG_ERROR([*** libpam not found.])
 408                 fi])
 409
 410         if test "x$have_pam" = xyes ; then
 411                 PAM_LIBS="-lpam -lpam_misc"
 412                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 413                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 414         else
 415                 have_pam=no
 416         fi
 417 else
 418         PAM_LIBS=
 419 fi
 420 AC_SUBST(PAM_LIBS)
 421 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 422
 423 # ------------------------------------------------------------------------------
 424 AC_ARG_ENABLE([acl],
 425         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 426                 [case "${enableval}" in
 427                         yes) have_acl=yes ;;
 428                         no) have_acl=no ;;
 429                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 430                 esac],
 431                 [have_acl=auto])
 432
 433 if test "x${have_acl}" != xno ; then
 434         AC_CHECK_HEADERS(
 435                 [sys/acl.h acl/libacl.h],
 436                 [have_acl=yes],
 437                 [if test "x$have_acl" = xyes ; then
 438                         AC_MSG_ERROR([*** ACL headers not found.])
 439                 fi])
 440
 441         AC_CHECK_LIB(
 442                 [acl],
 443                 [acl_get_file],
 444                 [have_acl=yes],
 445                 [if test "x$have_acl" = xyes ; then
 446                         AC_MSG_ERROR([*** libacl not found.])
 447                 fi])
 448
 449         if test "x$have_acl" = xyes ; then
 450                 ACL_LIBS="-lacl"
 451                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 452                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 453         else
 454                 have_acl=no
 455         fi
 456 else
 457         ACL_LIBS=
 458 fi
 459 AC_SUBST(ACL_LIBS)
 460 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 461
 462 # ------------------------------------------------------------------------------
 463 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 464                 [case "${enableval}" in
 465                         yes) have_smack=yes ;;
 466                         no) have_smack=no ;;
 467                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 468                 esac],
 469                 [have_smack=auto])
 470
 471 if test "x${have_smack}" = xauto; then
 472         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 473         have_smack=yes
 474 fi
 475
 476 AC_ARG_WITH(smack-run-label,
 477 AS_HELP_STRING([--with-smack-run-label=STRING],
 478         [run systemd --system with a specific SMACK label]),
 479         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run with a smack label])],
 480         [])
 481
 482 if test "x${have_smack}" = xyes ; then
 483         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 484 fi
 485
 486 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 487
 488 # ------------------------------------------------------------------------------
 489 AC_ARG_WITH(system-uid-max,
 490         AS_HELP_STRING([--with-system-uid-max=UID]
 491                 [Maximum UID for system users]),
 492         [SYSTEM_UID_MAX="$withval"],
 493         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
 494
 495 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
 496 AC_SUBST(SYSTEM_UID_MAX)
 497
 498 # ------------------------------------------------------------------------------
 499 AC_ARG_WITH(system-gid-max,
 500         AS_HELP_STRING([--with-system-gid-max=GID]
 501                 [Maximum GID for system groups]),
 502         [SYSTEM_GID_MAX="$withval"],
 503         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
 504
 505 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
 506 AC_SUBST(SYSTEM_GID_MAX)
 507
 508 # ------------------------------------------------------------------------------
 509 have_localed=no
 510 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 511 if test "x$enable_localed" != "xno"; then
 512         have_localed=yes
 513 fi
 514 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 515
 516 # ------------------------------------------------------------------------------
 517 have_coredump=no
 518 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 519 if test "x$enable_coredump" != "xno"; then
 520         have_coredump=yes
 521 fi
 522 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 523
 524 # ------------------------------------------------------------------------------
 525 have_polkit=no
 526 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 527 if test "x$enable_polkit" != "xno"; then
 528         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 529         have_polkit=yes
 530 fi
 531 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 532
 533 # ------------------------------------------------------------------------------
 534 have_resolved=no
 535 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
 536 if test "x$enable_resolved" != "xno"; then
 537         have_resolved=yes
 538         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
 539 fi
 540 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
 541
 542 AC_ARG_WITH(dns-servers,
 543         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
 544                 [Space-separated list of default DNS servers]),
 545         [DNS_SERVERS="$withval"],
 546         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
 547
 548 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
 549 AC_SUBST(DNS_SERVERS)
 550
 551 # ------------------------------------------------------------------------------
 552 have_networkd=no
 553 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
 554 AS_IF([test "x$enable_networkd" != "xno"], [
 555         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
 556         have_networkd=yes
 557         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
 558 ])
 559 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
 560
 561 # ------------------------------------------------------------------------------
 562 have_efi=no
 563 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 564 if test "x$enable_efi" != "xno"; then
 565         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 566         have_efi=yes
 567 fi
 568 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 569
 570 # ------------------------------------------------------------------------------
 571 EFI_CC=gcc
 572 AC_SUBST([EFI_CC])
 573
 574 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
 575
 576 AM_COND_IF(ARCH_IA32, [
 577         EFI_ARCH=ia32
 578         EFI_MACHINE_TYPE_NAME=ia32])
 579
 580 AM_COND_IF(ARCH_X86_64, [
 581         EFI_MACHINE_TYPE_NAME=x64])
 582
 583 AC_SUBST([EFI_ARCH])
 584 AC_SUBST([EFI_MACHINE_TYPE_NAME])
 585
 586 have_gnuefi=no
 587 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Disable optional gnuefi support]))
 588 AS_IF([test "x$enable_gnuefi" != "xno"], [
 589         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
 590                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
 591                  have_gnuefi=yes],
 592                 [AS_IF([test "x$enable_gnuefi" = xyes],
 593                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
 594         ])
 595
 596         efiroot=$(echo $(cd /usr/lib/$(gcc -print-multi-os-directory); pwd))
 597
 598         EFI_LIB_DIR="$efiroot"
 599         AC_ARG_WITH(efi-libdir,
 600                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
 601                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
 602         )
 603         AC_SUBST([EFI_LIB_DIR])
 604
 605         have_efi_lds=no
 606         AC_ARG_WITH(efi-ldsdir,
 607                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
 608                 [EFI_LDS_DIR="$withval" && AC_CHECK_FILE([${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds],
 609                         [have_efi_lds=yes])],
 610                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${efiroot}/gnuefi" "${efiroot}"],
 611                         [AC_CHECK_FILE([${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds],
 612                                        [have_efi_lds=yes && break])])])
 613         AS_IF([test "x$have_efi_lds" = xyes],
 614               [AC_SUBST([EFI_LDS_DIR])],
 615               [AS_IF([test "x$enable_gnuefi" = xyes],
 616                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
 617                      [have_gnuefi=no])])
 618
 619         AC_ARG_WITH(efi-includedir,
 620                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
 621                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
 622         )
 623         AC_SUBST([EFI_INC_DIR])
 624 ])
 625 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
 626
 627 # ------------------------------------------------------------------------------
 628 have_kdbus=no
 629 AC_ARG_ENABLE(kdbus, AS_HELP_STRING([--enable-kdbus], [do connect to kdbus by default]))
 630 if test "x$enable_kdbus" = "xyes"; then
 631         AC_DEFINE(ENABLE_KDBUS, 1, [Define if kdbus support is to be enabled])
 632         have_kdbus=yes
 633         M4_DEFINES="$M4_DEFINES -DENABLE_KDBUS"
 634 fi
 635 AM_CONDITIONAL(ENABLE_KDBUS, [test "$have_kdbus" = "yes"])
 636
 637 # ------------------------------------------------------------------------------
 638 AC_ARG_WITH(rc-local-script-path-start,
 639         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 640                 [Path to /etc/rc.local]),
 641         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 642         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 643
 644 AC_ARG_WITH(rc-local-script-path-stop,
 645         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 646                 [Path to /usr/sbin/halt.local]),
 647         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 648         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 649
 650 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 651 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 652
 653 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 654 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 655
 656 # ------------------------------------------------------------------------------
 657 AC_ARG_WITH(kbd-loadkeys,
 658         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 659                 [Path to loadkeys]),
 660         [KBD_LOADKEYS="$withval"],
 661         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 662
 663 AC_ARG_WITH(kbd-setfont,
 664         AS_HELP_STRING([--with-kbd-setfont=PATH],
 665                 [Path to setfont]),
 666         [KBD_SETFONT="$withval"],
 667         [KBD_SETFONT="/usr/bin/setfont"])
 668
 669 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 670 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 671
 672 AC_SUBST(KBD_LOADKEYS)
 673 AC_SUBST(KBD_SETFONT)
 674
 675 AC_ARG_WITH(telinit,
 676         AS_HELP_STRING([--with-telinit=PATH],
 677                 [Path to telinit]),
 678         [TELINIT="$withval"],
 679         [TELINIT="/lib/sysvinit/telinit"])
 680
 681 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 682
 683 AC_SUBST(TELINIT)
 684
 685 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
 686
 687 # ------------------------------------------------------------------------------
 688 have_myhostname=no
 689 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 690 if test "x$enable_myhostname" != "xno"; then
 691         AC_HEADER_STDC
 692         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
 693
 694         AC_C_CONST
 695         AC_TYPE_SIZE_T
 696         AC_HEADER_TIME
 697
 698         AC_FUNC_MALLOC
 699         AC_FUNC_SELECT_ARGTYPES
 700         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 701
 702         have_myhostname=yes
 703 fi
 704 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 705
 706 # ------------------------------------------------------------------------------
 707 AC_ARG_ENABLE([gudev],
 708        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 709        [], [enable_gudev=yes])
 710 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 711 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 712 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 713
 714 # ------------------------------------------------------------------------------
 715 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
 716        enable_hwdb=$enableval, enable_hwdb=yes)
 717 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
 718
 719 # ------------------------------------------------------------------------------
 720 have_manpages=no
 721 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 722 AS_IF([test "x$enable_manpages" != xno], [have_manpages=yes])
 723 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 724
 725 # ------------------------------------------------------------------------------
 726 AC_ARG_ENABLE(hibernate,
 727        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
 728        enable_hibernate=$enableval, enable_hibernate=yes)
 729 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
 730
 731 # ------------------------------------------------------------------------------
 732 AC_ARG_ENABLE(ldconfig,
 733        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
 734        enable_ldconfig=$enableval, enable_ldconfig=yes)
 735 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
 736
 737 AC_SUBST(M4_DEFINES)
 738
 739 AC_ARG_WITH([tty-gid],
 740         [AS_HELP_STRING([--with-tty-gid=GID],
 741                 [Specify the numeric GID of the 'tty' group])],
 742         [TTY_GID="$withval"],
 743         [TTY_GID="5"])
 744
 745 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
 746 AC_SUBST(TTY_GID)
 747
 748 AC_ARG_WITH([dbuspolicydir],
 749         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 750         [],
 751         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
 752
 753 AC_ARG_WITH([dbussessionservicedir],
 754         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 755         [],
 756         [with_dbussessionservicedir=${datadir}/dbus-1/services])
 757
 758 AC_ARG_WITH([dbussystemservicedir],
 759         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 760         [],
 761         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
 762
 763 AC_ARG_WITH([bashcompletiondir],
 764         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 765         [],
 766         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 767                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 768         ] , [
 769                 with_bashcompletiondir=${datadir}/bash-completion/completions
 770         ])])
 771
 772 AC_ARG_WITH([zshcompletiondir],
 773         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
 774         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
 775
 776 AC_ARG_WITH([rootprefix],
 777         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 778         [], [with_rootprefix=${ac_default_prefix}])
 779
 780 AC_ARG_WITH([rootlibdir],
 781         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 782         [],
 783         [with_rootlibdir=${libdir}])
 784
 785 AC_ARG_WITH([pamlibdir],
 786         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 787         [],
 788         [with_pamlibdir=${with_rootlibdir}/security])
 789
 790 AC_ARG_WITH([pamconfdir],
 791         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
 792         [],
 793         [with_pamconfdir=${sysconfdir}/pam.d])
 794
 795 AC_ARG_ENABLE([split-usr],
 796         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 797         [],
 798         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 799                 enable_split_usr=yes
 800         ], [
 801                 enable_split_usr=no
 802         ])])
 803
 804 AC_ARG_WITH([dkr-index-url],
 805         [AS_HELP_STRING([--dkr-index-url=URL], [Specify the default index URL to use for image downloads])],
 806         [DEFAULT_DKR_INDEX_URL="\"$withval\""],
 807         [DEFAULT_DKR_INDEX_URL="NULL"])
 808
 809 AC_DEFINE_UNQUOTED(DEFAULT_DKR_INDEX_URL, [$DEFAULT_DKR_INDEX_URL], [Default index URL to use for image downloads])
 810 AC_SUBST(DEFAULT_DKR_INDEX_URL)
 811
 812 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 813         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 814 ])
 815
 816 # Work around intltoolize and gtk-doc problems in VPATH builds
 817 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 818                                        [Define to do gtk-doc tests])
 819 AS_IF([test "x$0" != "x./configure"], [
 820         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 821 ])
 822
 823 # QEMU and OVMF UEFI firmware
 824 AS_IF([test x"$cross_compiling" = "xyes"], [], [
 825         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
 826         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
 827                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
 828         AC_SUBST([QEMU_BIOS])
 829 ])
 830
 831 AC_ARG_ENABLE(tests,
 832         [AC_HELP_STRING([--disable-tests], [disable tests])],
 833         enable_tests=$enableval, enable_tests=yes)
 834 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 835
 836 AC_ARG_ENABLE(debug,
 837         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
 838         [if test "x$enableval" = "xyes"; then
 839                 enableval="hashmap,mmap-cache"
 840         fi
 841         saved_ifs="$IFS"
 842         IFS="$IFS$PATH_SEPARATOR,"
 843         for name in $enableval; do
 844                 case $name in
 845                 hashmap)
 846                         enable_debug_hashmap=yes
 847                         ;;
 848                 mmap-cache)
 849                         enable_debug_mmap_cache=yes
 850                         ;;
 851                 esac
 852         done
 853         IFS="$saved_ifs"],[])
 854
 855 enable_debug=""
 856 AS_IF([test x$enable_debug_hashmap = xyes], [
 857         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
 858         enable_debug="hashmap $enable_debug"
 859 ])
 860 AS_IF([test x$enable_debug_mmap_cache = xyes], [
 861         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
 862         enable_debug="mmap-cache $enable_debug"
 863 ])
 864 test -z "$enable_debug" && enable_debug="none"
 865
 866 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 867 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 868 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 869 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 870 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
 871 AC_SUBST([pamlibdir], [$with_pamlibdir])
 872 AC_SUBST([pamconfdir], [$with_pamconfdir])
 873 AC_SUBST([rootprefix], [$with_rootprefix])
 874 AC_SUBST([rootlibdir], [$with_rootlibdir])
 875
 876 AC_CONFIG_FILES([
 877         Makefile po/Makefile.in
 878 ])
 879
 880 AC_OUTPUT
 881 AC_MSG_RESULT([
 882         $PACKAGE_NAME $VERSION
 883
 884         PAM:                     ${have_pam}
 885         AppArmor:                ${have_apparmor}
 886         SELinux:                 ${have_selinux}
 887         SECCOMP:                 ${have_seccomp}
 888         SMACK:                   ${have_smack}
 889         ACL:                     ${have_acl}
 890         localed:                 ${have_localed}
 891         networkd:                ${have_networkd}
 892         resolved:                ${have_resolved}
 893         default DNS servers:     ${DNS_SERVERS}
 894         coredump:                ${have_coredump}
 895         polkit:                  ${have_polkit}
 896         efi:                     ${have_efi}
 897         gnuefi:                  ${have_gnuefi}
 898         efi arch:                ${EFI_ARCH}
 899         EFI machine type:        ${EFI_MACHINE_TYPE_NAME}
 900         EFI CC                   ${EFI_CC}
 901         EFI libdir:              ${EFI_LIB_DIR}
 902         EFI ldsdir:              ${EFI_LDS_DIR}
 903         EFI includedir:          ${EFI_INC_DIR}
 904         blkid:                   ${have_blkid}
 905         dbus:                    ${have_dbus}
 906         nss-myhostname:          ${have_myhostname}
 907         gudev:                   ${enable_gudev}
 908         hwdb:                    ${enable_hwdb}
 909         kdbus:                   ${have_kdbus}
 910         Python:                  ${have_python}
 911         Python Headers:          ${have_python_devel}
 912         man pages:               ${have_manpages}
 913         gtk-doc:                 ${enable_gtk_doc}
 914         test coverage:           ${have_coverage}
 915         Split /usr:              ${enable_split_usr}
 916         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 917         ldconfig support:        ${enable_ldconfig}
 918         hibernate support:       ${enable_hibernate}
 919         extra debugging:         ${enable_debug}
 920
 921         prefix:                  ${prefix}
 922         rootprefix:              ${with_rootprefix}
 923         sysconf dir:             ${sysconfdir}
 924         datarootdir:             ${datarootdir}
 925         includedir:              ${includedir}
 926         include_prefix:          ${INCLUDE_PREFIX}
 927         lib dir:                 ${libdir}
 928         rootlib dir:             ${with_rootlibdir}
 929         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 930         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 931         Build Python:            ${PYTHON}
 932         Installation Python:     ${PYTHON_BINARY}
 933         sphinx binary:           ${SPHINX_BUILD}
 934         PAM modules dir:         ${with_pamlibdir}
 935         PAM configuration dir:   ${with_pamconfdir}
 936         D-Bus policy dir:        ${with_dbuspolicydir}
 937         D-Bus session dir:       ${with_dbussessionservicedir}
 938         D-Bus system dir:        ${with_dbussystemservicedir}
 939         Bash completions dir:    ${with_bashcompletiondir}
 940         Zsh completions dir:     ${with_zshcompletiondir}
 941         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
 942         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
 943         TTY GID:                 ${TTY_GID}
 944         Maximum System UID:      ${SYSTEM_UID_MAX}
 945         Maximum System GID:      ${SYSTEM_GID_MAX}
 946         Certificate root:        ${CERTIFICATEROOT}
 947         Default dkr Index        ${DEFAULT_DKR_INDEX_URL}
 948
 949         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
 950         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
 951         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
 952         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
 953         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
 954 ])