configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[2],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30
  31 AM_SILENT_RULES([yes])
  32
  33 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  34
  35 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  36         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  37         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  38 ])
  39
  40 AC_PROG_MKDIR_P
  41 AC_PROG_LN_S
  42 AC_PROG_SED
  43
  44 AC_PROG_CC
  45 AC_PROG_CC_C99
  46 AM_PROG_CC_C_O
  47 AC_PROG_GCC_TRADITIONAL
  48 AC_USE_SYSTEM_EXTENSIONS
  49
  50 CC_CHECK_CFLAGS_APPEND([ \
  51         -pipe \
  52         -Wall \
  53         -W \
  54         -Wextra \
  55         -Wno-inline \
  56         -Wvla \
  57         -Wundef \
  58         -Wformat=2 \
  59         -Wlogical-op \
  60         -Wsign-compare \
  61         -Wformat-security \
  62         -Wmissing-include-dirs \
  63         -Wformat-nonliteral \
  64         -Wold-style-definition \
  65         -Wpointer-arith \
  66         -Winit-self \
  67         -Wdeclaration-after-statement \
  68         -Wfloat-equal \
  69         -Wmissing-prototypes \
  70         -Wstrict-prototypes \
  71         -Wredundant-decls \
  72         -Wmissing-declarations \
  73         -Wmissing-noreturn \
  74         -Wshadow \
  75         -Wendif-labels \
  76         -Wcast-align \
  77         -Wstrict-aliasing=2 \
  78         -Wwrite-strings \
  79         -Wno-long-long \
  80         -Wno-overlength-strings \
  81         -Wno-unused-parameter \
  82         -Wno-missing-field-initializers \
  83         -Wno-unused-result \
  84         -Wp,-D_FORTIFY_SOURCE=2 \
  85         -ffast-math \
  86         -fno-common \
  87         -fdiagnostics-show-option \
  88         -fno-strict-aliasing])
  89
  90 LT_PREREQ(2.2)
  91 LT_INIT
  92
  93 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
  94 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
  95 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
  96
  97 # This makes sure pkg.m4 is available.
  98 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
  99
 100 PKG_CHECK_MODULES(UDEV, [ libudev >= 154 ])
 101 AC_SUBST(UDEV_CFLAGS)
 102 AC_SUBST(UDEV_LIBS)
 103
 104 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 105 AC_SUBST(DBUS_CFLAGS)
 106 AC_SUBST(DBUS_LIBS)
 107
 108 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 109 AC_SUBST(DBUSGLIB_CFLAGS)
 110 AC_SUBST(DBUSGLIB_LIBS)
 111
 112 PKG_CHECK_MODULES(CGROUP, [ libcgroup >= 0.36 ])
 113 AC_SUBST(CGROUP_CFLAGS)
 114 AC_SUBST(CGROUP_LIBS)
 115
 116 AC_ARG_ENABLE([tcpwrap],
 117         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 118                 [case "${enableval}" in
 119                         yes) have_tcpwrap=yes ;;
 120                         no) have_tcpwrap=no ;;
 121                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 122                 esac],
 123                 [have_tcpwrap=auto])
 124
 125 if test "x${have_tcpwrap}" != xno ; then
 126         ACX_LIBWRAP
 127         if test "x${LIBWRAP_LIBS}" = x ; then
 128                 if test "x$have_tcpwrap" = xyes ; then
 129                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 130                 fi
 131                 have_tcpwrap=no
 132         else
 133                 have_tcpwrap=yes
 134         fi
 135 else
 136         LIBWRAP_LIBS=
 137 fi
 138 AC_SUBST(LIBWRAP_LIBS)
 139
 140 AC_ARG_ENABLE([pam],
 141         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 142                 [case "${enableval}" in
 143                         yes) have_pam=yes ;;
 144                         no) have_pam=no ;;
 145                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 146                 esac],
 147                 [have_pam=auto])
 148
 149 if test "x${have_pam}" != xno ; then
 150         AC_CHECK_HEADERS(
 151                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 152                 [have_pam=yes],
 153                 [if test "x$have_pam" = xyes ; then
 154                         AC_MSG_ERROR([*** PAM headers not found.])
 155                 fi])
 156
 157         AC_CHECK_LIB(
 158                 [pam],
 159                 [pam_syslog],
 160                 [have_pam=yes],
 161                 [if test "x$have_pam" = xyes ; then
 162                         AC_MSG_ERROR([*** libpam not found.])
 163                 fi])
 164
 165         if test "x$have_pam" = xyes ; then
 166                 PAM_LIBS="-lpam -lpam_misc"
 167                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 168         else
 169                 have_pam=no
 170         fi
 171 else
 172         PAM_LIBS=
 173 fi
 174 AC_SUBST(PAM_LIBS)
 175 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 176
 177 have_gtk=no
 178 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 179 if test "x$enable_gtk" != "xno"; then
 180         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 ],
 181                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 182         AC_SUBST(GTK_CFLAGS)
 183         AC_SUBST(GTK_LIBS)
 184         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 185              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 186         fi
 187 fi
 188 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 189
 190 AM_PROG_VALAC([0.8])
 191 AC_SUBST(VAPIDIR)
 192 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 193
 194 AC_PATH_PROG([XSLTPROC], [xsltproc])
 195 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 196
 197 AC_PATH_PROG([M4], [m4])
 198
 199 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, arch, gentoo, slackware or other]))
 200 if test "z$with_distro" = "z"; then
 201         if test "$cross_compiling" = yes; then
 202                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 203         else
 204                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 205                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 206                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 207                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 208                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 209                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 210         fi
 211         if test "z$with_distro" = "z"; then
 212                 with_distro=`uname -s`
 213         fi
 214 fi
 215 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 216
 217 # Default generic names
 218 SPECIAL_SYSLOG_SERVICE=syslog.service
 219
 220 # Location of the init scripts as mandated by LSB
 221 SYSTEM_SYSVINIT_PATH=/etc/init.d
 222
 223 M4_DISTRO_FLAG=
 224
 225 case $with_distro in
 226         fedora)
 227                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 228                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 229
 230                 # A little background why we define this special unit
 231                 # names here in configure.ac: SysV services currently
 232                 # cannot have aliases. As long as syslog is started
 233                 # via a SysV init script we hence define this name to
 234                 # the actual SysV name here. Later on when SysV init
 235                 # scripts are not used anymore it is advisable to use
 236                 # the generic name instead and use symlinks in the
 237                 # unit directories to point to the right native unit
 238                 # file.
 239
 240                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 241                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 242                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 243                 ;;
 244         suse)
 245                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 246                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 247                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 248                 ;;
 249         debian)
 250                 SYSTEM_SYSVRCND_PATH=/etc
 251                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 252                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian/Ubuntu])
 253                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 254                 ;;
 255         arch)
 256                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 257                 SYSTEM_SYSVRCND_PATH=/etc
 258                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 259                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 260                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 261                 ;;
 262         gentoo)
 263                 SYSTEM_SYSVRCND_PATH=/etc
 264                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 265                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 266                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 267                 ;;
 268         slackware)
 269                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 270                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 271                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 272                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 273                 ;;
 274         other)
 275                 AS_IF([test "x$with_sysvinit_path" = "x"],
 276                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvinit-path= to configure])])
 277                 AS_IF([test "x$with_sysvrcd_path" = "x"],
 278                         [AC_MSG_ERROR([With --distro=other, you must pass --with-sysvrcd-path= to configure])])
 279                 AS_IF([test "x$with_syslog_service" = "x"],
 280                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 281                 ;;
 282         *)
 283                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 284                 ;;
 285 esac
 286
 287 AC_ARG_WITH([sysvinit-path],
 288         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 289                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 290         [SYSTEM_SYSVINIT_PATH="$withval"],
 291         [])
 292
 293 AC_ARG_WITH([sysvrcd-path],
 294         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 295                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 296         [SYSTEM_SYSVRCND_PATH="$withval"],
 297         [])
 298
 299 AC_ARG_WITH([syslog-service],
 300         [AS_HELP_STRING([--with-syslog-service=UNIT],
 301                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 302         [SPECIAL_SYSLOG_SERVICE="$withval"],
 303         [])
 304
 305 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 306 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 307 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 308 AC_SUBST(M4_DISTRO_FLAG)
 309
 310 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 311 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 312 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 313 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 314 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 315 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 316
 317 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 318
 319 AC_ARG_WITH([dbuspolicydir],
 320         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 321         [],
 322         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 323
 324 AC_ARG_WITH([dbussessionservicedir],
 325         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 326         [],
 327         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 328
 329 AC_ARG_WITH([dbussystemservicedir],
 330         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 331         [],
 332         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 333
 334 AC_ARG_WITH([dbusinterfacedir],
 335         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 336         [],
 337         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 338
 339 AC_ARG_WITH([udevrulesdir],
 340         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 341         [],
 342         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 343
 344 AC_ARG_WITH([pamlibdir],
 345         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 346         [],
 347         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 348
 349 AC_ARG_WITH([rootdir],
 350         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 351         [],
 352         [with_rootdir=${ac_default_prefix}])
 353
 354 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 355 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 356 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 357 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 358 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 359 AC_SUBST([pamlibdir], [$with_pamlibdir])
 360 AC_SUBST([rootdir], [$with_rootdir])
 361
 362 AC_CONFIG_FILES([Makefile])
 363 AC_OUTPUT
 364
 365 echo "
 366         $PACKAGE_NAME $VERSION
 367
 368         Distribution:            ${with_distro}
 369         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 370         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 371         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 372         Gtk:                     ${have_gtk}
 373         tcpwrap:                 ${have_tcpwrap}
 374         PAM:                     ${have_pam}
 375         prefix:                  ${prefix}
 376         root dir:                ${with_rootdir}
 377         udev rules dir:          ${with_udevrulesdir}
 378         pam modules dir:         ${with_pamlibdir}
 379         dbus policy dir:         ${with_dbuspolicydir}
 380         dbus session dir:        ${with_dbussessionservicedir}
 381         dbus system dir:         ${with_dbussystemservicedir}
 382         dbus interfaces dir:     ${with_dbusinterfacedir}
 383 "