configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [205],
  24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
  37 AM_SILENT_RULES([yes])
  38 AC_CANONICAL_HOST
  39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  43
  44 LT_PREREQ(2.2)
  45 LT_INIT([disable-static])
  46
  47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  49
  50 # i18n stuff for the PolicyKit policy files
  51 IT_PROG_INTLTOOL([0.40.0])
  52
  53 GETTEXT_PACKAGE=systemd
  54 AC_SUBST(GETTEXT_PACKAGE)
  55
  56 AC_PROG_MKDIR_P
  57 AC_PROG_LN_S
  58 AC_PROG_SED
  59 AC_PROG_GREP
  60 AC_PROG_AWK
  61
  62 AC_PROG_CC
  63 AC_PROG_CC_C99
  64 AM_PROG_CC_C_O
  65 AC_PROG_GCC_TRADITIONAL
  66
  67 AC_PATH_PROG([M4], [m4])
  68 AC_PATH_PROG([XSLTPROC], [xsltproc])
  69
  70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
  71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
  72
  73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
  74
  75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
  76
  77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
  78
  79 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
  80 m4_ifdef([GTK_DOC_CHECK], [
  81 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
  82          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
  83           enable_gtk_doc=no])
  84
  85 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
  86         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
  87 ])
  88
  89 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
  90 GOBJECT_INTROSPECTION_CHECK([1.31.1])
  91 ], [
  92    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
  93    enable_introspection=no])
  94
  95 AC_CHECK_TOOL(OBJCOPY, objcopy)
  96 AC_CHECK_TOOL(STRINGS, strings)
  97 AC_CHECK_TOOL(GPERF, gperf)
  98 if test -z "$GPERF" ; then
  99         AC_MSG_ERROR([*** gperf not found])
 100 fi
 101
 102 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 103         -pipe \
 104         -Wall \
 105         -Wextra \
 106         -Wno-inline \
 107         -Wundef \
 108         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 109         -Wlogical-op \
 110         -Wsign-compare \
 111         -Wmissing-include-dirs \
 112         -Wold-style-definition \
 113         -Wpointer-arith \
 114         -Winit-self \
 115         -Wdeclaration-after-statement \
 116         -Wfloat-equal \
 117         -Wmissing-prototypes \
 118         -Wstrict-prototypes \
 119         -Wredundant-decls \
 120         -Wmissing-declarations \
 121         -Wmissing-noreturn \
 122         -Wshadow \
 123         -Wendif-labels \
 124         -Wcast-align \
 125         -Wstrict-aliasing=2 \
 126         -Wwrite-strings \
 127         -Wno-long-long \
 128         -Wno-overlength-strings \
 129         -Wno-unused-parameter \
 130         -Wno-missing-field-initializers \
 131         -Wno-unused-result \
 132         -Werror=overflow \
 133         -ffast-math \
 134         -fno-common \
 135         -fdiagnostics-show-option \
 136         -fdiagnostics-color \
 137         -fno-strict-aliasing \
 138         -fvisibility=hidden \
 139         -ffunction-sections \
 140         -fdata-sections \
 141         -fstack-protector \
 142         --param=ssp-buffer-size=4])
 143 AC_SUBST([OUR_CFLAGS], $with_cflags)
 144
 145 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*], [
 146         CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 147                -Wp,-D_FORTIFY_SOURCE=2])], [
 148         python_extra_cflags=-Wp,-U_FORTIFY_SOURCE
 149         AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 150 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
 151
 152 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 153         -Wl,--as-needed \
 154         -Wl,--no-undefined \
 155         -Wl,--gc-sections \
 156         -Wl,-z,relro \
 157         -Wl,-z,now])
 158 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
 159
 160 # ------------------------------------------------------------------------------
 161 # we use python to build the man page index, and for systemd-python
 162 have_python=no
 163 have_python_devel=no
 164
 165 AC_ARG_WITH([python],
 166         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 167
 168 AS_IF([test "x$with_python" != "xno"], [
 169         AM_PATH_PYTHON(,, [:])
 170         AS_IF([test "$PYTHON" != :], [have_python=yes])
 171 ])
 172 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 173 AS_IF([test "x$PYTHON_BINARY" = "x"],
 174       [AS_IF([test "x$have_python" = "xyes"],
 175              [PYTHON_BINARY="$(which "$PYTHON")"],
 176              [PYTHON_BINARY=/usr/bin/python])])
 177 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
 178
 179 AS_IF([test "x$with_python" != "xno"], [
 180         AC_PATH_PROG(PYTHON_CONFIG, python${PYTHON_VERSION}-config)
 181         AS_IF([test -n "$PYTHON_CONFIG"], [
 182               have_python_devel=yes
 183               PYTHON_CFLAGS="$($PYTHON_CONFIG --cflags) $python_extra_cflags"
 184               PYTHON_LIBS="$($PYTHON_CONFIG --ldflags)"
 185               AC_SUBST(PYTHON_CFLAGS)
 186               AC_SUBST(PYTHON_LIBS)
 187               AC_PATH_PROGS(SPHINX_BUILD, sphinx-build-${PYTHON_VERSION} sphinx-build)
 188         ])
 189 ])
 190 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
 191
 192 # ------------------------------------------------------------------------------
 193
 194 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 195 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 196
 197 save_LIBS="$LIBS"
 198 LIBS=
 199 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 200 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 201 CAP_LIBS="$LIBS"
 202 LIBS="$save_LIBS"
 203 AC_SUBST(CAP_LIBS)
 204
 205 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
 206 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 207 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
 208 #include <unistd.h>
 209 #include <sys/mount.h>
 210 #include <fcntl.h>]])
 211
 212 # This makes sure pkg.m4 is available.
 213 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 214
 215 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
 216
 217 # ------------------------------------------------------------------------------
 218 have_coverage=no
 219 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 220 if test "x$enable_coverage" = "xyes" ; then
 221         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 222         if test "x$lcov_found" = xno ; then
 223                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 224         else
 225                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 226                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 227                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 228                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 229                 else
 230                         have_coverage=yes
 231                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 232                         -fprofile-arcs \
 233                         -ftest-coverage])
 234                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 235                 fi
 236         fi
 237 fi
 238 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 239
 240 # ------------------------------------------------------------------------------
 241 have_kmod=no
 242 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 243 if test "x$enable_kmod" != "xno"; then
 244         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 245         if test "x$have_kmod" = "xyes"; then
 246                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
 247                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 248                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
 249         fi
 250         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 251                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 252         fi
 253 fi
 254 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 255
 256 # ------------------------------------------------------------------------------
 257 have_blkid=no
 258 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 259 if test "x$enable_blkid" != "xno"; then
 260         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
 261                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 262         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 263                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 264         fi
 265 fi
 266 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 267
 268 # ------------------------------------------------------------------------------
 269 have_ima=yes
 270 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 271                 [case "${enableval}" in
 272                         yes) have_ima=yes ;;
 273                         no) have_ima=no ;;
 274                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 275                 esac],
 276                 [have_ima=yes])
 277
 278 if test "x${have_ima}" != xno ; then
 279         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 280 fi
 281
 282 # ------------------------------------------------------------------------------
 283 have_chkconfig=yes
 284 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
 285                 [case "${enableval}" in
 286                         yes) have_chkconfig=yes ;;
 287                         no) have_chkconfig=no ;;
 288                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
 289                 esac],
 290                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
 291                 if test -z "$CHKCONFIG"; then
 292                         have_chkconfig=no
 293                 else
 294                         have_chkconfig=yes
 295                 fi])
 296
 297 if test "x${have_chkconfig}" != xno ; then
 298         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
 299 fi
 300
 301 # ------------------------------------------------------------------------------
 302 have_selinux=no
 303 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 304 if test "x$enable_selinux" != "xno"; then
 305         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 306                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 307         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 308                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 309         fi
 310 fi
 311 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 312
 313 AC_ARG_WITH(debug-shell,
 314         AS_HELP_STRING([--with-debug-shell=PATH],
 315                 [Path to debug shell binary]),
 316         [SUSHELL="$withval"],[
 317         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 318
 319 AC_SUBST(SUSHELL)
 320
 321 AC_ARG_WITH([debug-tty],
 322         AS_HELP_STRING([--with-debug-tty=PATH],
 323                 [Specify the tty device for debug shell]),
 324         [DEBUGTTY="$withval"],
 325         [DEBUGTTY=/dev/tty9])
 326
 327 AC_SUBST(DEBUGTTY)
 328
 329 # ------------------------------------------------------------------------------
 330 have_xz=no
 331 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 332 if test "x$enable_xz" != "xno"; then
 333         PKG_CHECK_MODULES(XZ, [ liblzma ],
 334                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
 335         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
 336                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
 337         fi
 338 fi
 339 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 340
 341 # ------------------------------------------------------------------------------
 342 AC_ARG_ENABLE([tcpwrap],
 343         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 344                 [case "${enableval}" in
 345                         yes) have_tcpwrap=yes ;;
 346                         no) have_tcpwrap=no ;;
 347                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 348                 esac],
 349                 [have_tcpwrap=auto])
 350
 351 if test "x${have_tcpwrap}" != xno ; then
 352         ACX_LIBWRAP
 353         if test "x${LIBWRAP_LIBS}" = x ; then
 354                 if test "x$have_tcpwrap" = xyes ; then
 355                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 356                 fi
 357                 have_tcpwrap=no
 358         else
 359                 have_tcpwrap=yes
 360         fi
 361 else
 362         LIBWRAP_LIBS=
 363 fi
 364 AC_SUBST(LIBWRAP_LIBS)
 365
 366 # ------------------------------------------------------------------------------
 367 AC_ARG_ENABLE([pam],
 368         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 369                 [case "${enableval}" in
 370                         yes) have_pam=yes ;;
 371                         no) have_pam=no ;;
 372                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 373                 esac],
 374                 [have_pam=auto])
 375
 376 if test "x${have_pam}" != xno ; then
 377         AC_CHECK_HEADERS(
 378                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 379                 [have_pam=yes],
 380                 [if test "x$have_pam" = xyes ; then
 381                         AC_MSG_ERROR([*** PAM headers not found.])
 382                 fi])
 383
 384         AC_CHECK_LIB(
 385                 [pam],
 386                 [pam_syslog],
 387                 [have_pam=yes],
 388                 [if test "x$have_pam" = xyes ; then
 389                         AC_MSG_ERROR([*** libpam not found.])
 390                 fi])
 391
 392         if test "x$have_pam" = xyes ; then
 393                 PAM_LIBS="-lpam -lpam_misc"
 394                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 395         else
 396                 have_pam=no
 397         fi
 398 else
 399         PAM_LIBS=
 400 fi
 401 AC_SUBST(PAM_LIBS)
 402 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 403
 404 # ------------------------------------------------------------------------------
 405 AC_ARG_ENABLE([acl],
 406         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 407                 [case "${enableval}" in
 408                         yes) have_acl=yes ;;
 409                         no) have_acl=no ;;
 410                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 411                 esac],
 412                 [have_acl=auto])
 413
 414 if test "x${have_acl}" != xno ; then
 415         AC_CHECK_HEADERS(
 416                 [sys/acl.h acl/libacl.h],
 417                 [have_acl=yes],
 418                 [if test "x$have_acl" = xyes ; then
 419                         AC_MSG_ERROR([*** ACL headers not found.])
 420                 fi])
 421
 422         AC_CHECK_LIB(
 423                 [acl],
 424                 [acl_get_file],
 425                 [have_acl=yes],
 426                 [if test "x$have_acl" = xyes ; then
 427                         AC_MSG_ERROR([*** libacl not found.])
 428                 fi])
 429
 430         if test "x$have_acl" = xyes ; then
 431                 ACL_LIBS="-lacl"
 432                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 433         else
 434                 have_acl=no
 435         fi
 436 else
 437         ACL_LIBS=
 438 fi
 439 AC_SUBST(ACL_LIBS)
 440 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 441
 442 # ------------------------------------------------------------------------------
 443 AC_ARG_ENABLE([xattr],
 444         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
 445                 [case "${enableval}" in
 446                         yes) have_xattr=yes ;;
 447                         no) have_xattr=no ;;
 448                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
 449                 esac],
 450                 [have_xattr=auto])
 451
 452 if test "x${have_xattr}" != xno ; then
 453         AC_CHECK_HEADERS(
 454                 [attr/xattr.h],
 455                 [have_xattr=yes],
 456                 [if test "x$have_xattr" = xyes ; then
 457                         AC_MSG_ERROR([*** XATTR headers not found.])
 458                 fi])
 459
 460         AC_CHECK_LIB(
 461                 [attr],
 462                 [fsetxattr],
 463                 [have_xattr=yes],
 464                 [if test "x$have_xattr" = xyes ; then
 465                         AC_MSG_ERROR([*** libattr not found.])
 466                 fi])
 467
 468         if test "x$have_xattr" = xyes ; then
 469                 XATTR_LIBS="-lattr"
 470                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
 471         else
 472                 have_xattr=no
 473         fi
 474 else
 475         XATTR_LIBS=
 476 fi
 477 AC_SUBST(XATTR_LIBS)
 478 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
 479
 480 # ------------------------------------------------------------------------------
 481 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 482                 [case "${enableval}" in
 483                         yes) have_smack=yes ;;
 484                         no) have_smack=no ;;
 485                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 486                 esac],
 487                 [have_smack=auto])
 488
 489 if test "x${have_xattr}" = xno; then
 490         if test "x${have_smack}" = xyes; then
 491                 AC_MSG_ERROR(SMACK requires xattr support)
 492         else
 493                 have_smack=no
 494         fi
 495 else
 496         if test "x${have_smack}" = xauto; then
 497                 have_smack=yes
 498         fi
 499 fi
 500
 501 if test "x${have_smack}" = xyes ; then
 502         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 503 fi
 504
 505 # ------------------------------------------------------------------------------
 506 AC_ARG_ENABLE([gcrypt],
 507         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 508                 [case "${enableval}" in
 509                         yes) have_gcrypt=yes ;;
 510                         no) have_gcrypt=no ;;
 511                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 512                 esac],
 513                 [have_gcrypt=auto])
 514
 515 if test "x${have_gcrypt}" != xno ; then
 516         AM_PATH_LIBGCRYPT(
 517                 [1.4.5],
 518                 [have_gcrypt=yes],
 519                 [if test "x$have_gcrypt" = xyes ; then
 520                         AC_MSG_ERROR([*** GCRYPT headers not found.])
 521                 fi])
 522
 523         if test "x$have_gcrypt" = xyes ; then
 524                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
 525                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
 526                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 527         else
 528                 have_gcrypt=no
 529         fi
 530 else
 531         GCRYPT_LIBS=
 532         GCRYPT_CFLAGS=
 533 fi
 534 AC_SUBST(GCRYPT_LIBS)
 535 AC_SUBST(GCRYPT_CFLAGS)
 536 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 537
 538 # ------------------------------------------------------------------------------
 539 AC_ARG_ENABLE([audit],
 540         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 541                 [case "${enableval}" in
 542                         yes) have_audit=yes ;;
 543                         no) have_audit=no ;;
 544                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 545                 esac],
 546                 [have_audit=auto])
 547
 548 if test "x${have_audit}" != xno ; then
 549         AC_CHECK_HEADERS(
 550                 [libaudit.h],
 551                 [have_audit=yes],
 552                 [if test "x$have_audit" = xyes ; then
 553                         AC_MSG_ERROR([*** AUDIT headers not found.])
 554                 fi])
 555
 556         AC_CHECK_LIB(
 557                 [audit],
 558                 [audit_open],
 559                 [have_audit=yes],
 560                 [if test "x$have_audit" = xyes ; then
 561                         AC_MSG_ERROR([*** libaudit not found.])
 562                 fi])
 563
 564         if test "x$have_audit" = xyes ; then
 565                 AUDIT_LIBS="-laudit"
 566                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 567         else
 568                 have_audit=no
 569         fi
 570 else
 571         AUDIT_LIBS=
 572 fi
 573 AC_SUBST(AUDIT_LIBS)
 574
 575 # ------------------------------------------------------------------------------
 576 have_libcryptsetup=no
 577 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 578 if test "x$enable_libcryptsetup" != "xno"; then
 579         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.4.2 ],
 580                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 581         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 582                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 583         fi
 584 fi
 585 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 586
 587 # ------------------------------------------------------------------------------
 588 have_qrencode=no
 589 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 590 if test "x$enable_qrencode" != "xno"; then
 591         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 592                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 593         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 594                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 595         fi
 596 fi
 597 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 598
 599 # ------------------------------------------------------------------------------
 600 have_microhttpd=no
 601 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 602 if test "x$enable_microhttpd" != "xno"; then
 603         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
 604                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
 605         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 606                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 607         fi
 608 fi
 609 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 610
 611 # ------------------------------------------------------------------------------
 612 have_binfmt=no
 613 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 614 if test "x$enable_binfmt" != "xno"; then
 615         have_binfmt=yes
 616 fi
 617 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 618
 619 # ------------------------------------------------------------------------------
 620 have_vconsole=no
 621 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 622 if test "x$enable_vconsole" != "xno"; then
 623         have_vconsole=yes
 624 fi
 625 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 626
 627 # ------------------------------------------------------------------------------
 628 have_readahead=no
 629 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
 630 if test "x$enable_readahead" != "xno"; then
 631         have_readahead=yes
 632 fi
 633 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
 634
 635 # ------------------------------------------------------------------------------
 636 have_bootchart=no
 637 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
 638 if test "x$enable_bootchart" != "xno"; then
 639         have_bootchart=yes
 640 fi
 641 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
 642
 643 # ------------------------------------------------------------------------------
 644 have_quotacheck=no
 645 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 646 if test "x$enable_quotacheck" != "xno"; then
 647         have_quotacheck=yes
 648 fi
 649 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 650
 651 # ------------------------------------------------------------------------------
 652 have_tmpfiles=no
 653 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 654 if test "x$enable_tmpfiles" != "xno"; then
 655         have_tmpfiles=yes
 656 fi
 657 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 658
 659 # ------------------------------------------------------------------------------
 660 have_randomseed=no
 661 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
 662 if test "x$enable_randomseed" != "xno"; then
 663         have_randomseed=yes
 664 fi
 665 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
 666
 667 # ------------------------------------------------------------------------------
 668 have_logind=no
 669 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
 670 if test "x$enable_logind" != "xno"; then
 671         have_logind=yes
 672 fi
 673 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
 674 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
 675
 676 # ------------------------------------------------------------------------------
 677 have_machined=no
 678 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
 679 if test "x$enable_machined" != "xno"; then
 680         have_machined=yes
 681 fi
 682 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
 683 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
 684
 685 # ------------------------------------------------------------------------------
 686 have_hostnamed=no
 687 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
 688 if test "x$enable_hostnamed" != "xno"; then
 689         have_hostnamed=yes
 690 fi
 691 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
 692
 693 # ------------------------------------------------------------------------------
 694 have_timedated=no
 695 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
 696 if test "x$enable_timedated" != "xno"; then
 697         have_timedated=yes
 698 fi
 699 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
 700
 701 # ------------------------------------------------------------------------------
 702 have_localed=no
 703 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
 704 if test "x$enable_localed" != "xno"; then
 705         have_localed=yes
 706 fi
 707 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
 708
 709 # ------------------------------------------------------------------------------
 710 have_coredump=no
 711 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
 712 if test "x$enable_coredump" != "xno"; then
 713         have_coredump=yes
 714 fi
 715 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
 716
 717 # ------------------------------------------------------------------------------
 718 have_polkit=no
 719 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
 720 if test "x$enable_polkit" != "xno"; then
 721         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
 722         have_polkit=yes
 723 fi
 724 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
 725
 726 # ------------------------------------------------------------------------------
 727 have_efi=no
 728 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
 729 if test "x$enable_efi" != "xno"; then
 730         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
 731         have_efi=yes
 732 fi
 733 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
 734
 735 # ------------------------------------------------------------------------------
 736 AC_ARG_WITH(rc-local-script-path-start,
 737         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
 738                 [Path to /etc/rc.local]),
 739         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
 740         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
 741
 742 AC_ARG_WITH(rc-local-script-path-stop,
 743         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
 744                 [Path to /usr/sbin/halt.local]),
 745         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
 746         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
 747
 748 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
 749 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
 750
 751 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
 752 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
 753
 754 # ------------------------------------------------------------------------------
 755 AC_ARG_WITH(kbd-loadkeys,
 756         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
 757                 [Path to loadkeys]),
 758         [KBD_LOADKEYS="$withval"],
 759         [KBD_LOADKEYS="/usr/bin/loadkeys"])
 760
 761 AC_ARG_WITH(kbd-setfont,
 762         AS_HELP_STRING([--with-kbd-setfont=PATH],
 763                 [Path to setfont]),
 764         [KBD_SETFONT="$withval"],
 765         [KBD_SETFONT="/usr/bin/setfont"])
 766
 767 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
 768 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
 769
 770 AC_SUBST(KBD_LOADKEYS)
 771 AC_SUBST(KBD_SETFONT)
 772
 773 AC_ARG_WITH(telinit,
 774         AS_HELP_STRING([--with-telinit=PATH],
 775                 [Path to telinit]),
 776         [TELINIT="$withval"],
 777         [TELINIT="/lib/upstart/telinit"])
 778
 779 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
 780
 781 AC_SUBST(TELINIT)
 782
 783 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
 784
 785 # ------------------------------------------------------------------------------
 786 have_myhostname=no
 787 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
 788 if test "x$enable_myhostname" != "xno"; then
 789         AC_HEADER_STDC
 790         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
 791
 792         AC_C_CONST
 793         AC_TYPE_SIZE_T
 794         AC_HEADER_TIME
 795
 796         AC_FUNC_MALLOC
 797         AC_FUNC_SELECT_ARGTYPES
 798         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
 799
 800         have_myhostname=yes
 801 fi
 802 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
 803
 804 # ------------------------------------------------------------------------------
 805 AC_ARG_WITH(firmware-path,
 806        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
 807           [Firmware search path (default="")]),
 808        [], [with_firmware_path=""])
 809 OLD_IFS=$IFS
 810 IFS=:
 811 for i in $with_firmware_path; do
 812        if test "x${FIRMWARE_PATH}" = "x"; then
 813               FIRMWARE_PATH="\\\"${i}/\\\""
 814        else
 815               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
 816        fi
 817 done
 818 IFS=$OLD_IFS
 819 AC_SUBST(FIRMWARE_PATH)
 820 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
 821 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
 822
 823 # ------------------------------------------------------------------------------
 824 AC_ARG_ENABLE([gudev],
 825        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
 826        [], [enable_gudev=yes])
 827 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
 828 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
 829 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
 830
 831 # ------------------------------------------------------------------------------
 832 AC_ARG_ENABLE([keymap],
 833        AS_HELP_STRING([--disable-keymap], [disable keymap fixup support @<:@default=enabled@:>@]),
 834        [], [enable_keymap=yes])
 835 AS_IF([test "x$enable_keymap" = "xyes"], [
 836        AC_PATH_PROG([GPERF], [gperf])
 837        if test -z "$GPERF"; then
 838               AC_MSG_ERROR([gperf is needed])
 839        fi
 840
 841        AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 842        AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 843 ])
 844 AM_CONDITIONAL([ENABLE_KEYMAP], [test "x$enable_keymap" = "xyes"])
 845
 846 # ------------------------------------------------------------------------------
 847 have_manpages=no
 848 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
 849 AS_IF([test "x$enable_manpages" != xno], [
 850         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
 851                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
 852         ])
 853         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
 854 ])
 855 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
 856
 857 # ------------------------------------------------------------------------------
 858
 859 # Location of the init scripts as mandated by LSB
 860 SYSTEM_SYSVINIT_PATH=/etc/init.d
 861 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 862 M4_DEFINES=
 863
 864 AC_ARG_WITH([sysvinit-path],
 865         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 866                 [Specify the path to where the SysV init scripts are located])],
 867         [SYSTEM_SYSVINIT_PATH="$withval"],
 868         [])
 869
 870 AC_ARG_WITH([sysvrcnd-path],
 871         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
 872                 [Specify the path to the base directory for the SysV rcN.d directories])],
 873         [SYSTEM_SYSVRCND_PATH="$withval"],
 874         [])
 875
 876 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 877         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 878         SYSTEM_SYSV_COMPAT="yes"
 879         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 880 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 881         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 882 else
 883         SYSTEM_SYSV_COMPAT="no"
 884 fi
 885
 886 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 887 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 888 AC_SUBST(M4_DEFINES)
 889
 890 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 891
 892 AC_ARG_WITH([tty-gid],
 893         [AS_HELP_STRING([--with-tty-gid=GID],
 894                 [Specify the numeric GID of the 'tty' group])],
 895         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 896         [])
 897
 898 AC_ARG_WITH([dbuspolicydir],
 899         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 900         [],
 901         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
 902
 903 AC_ARG_WITH([dbussessionservicedir],
 904         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 905         [],
 906         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
 907
 908 AC_ARG_WITH([dbussystemservicedir],
 909         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 910         [],
 911         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
 912
 913 AC_ARG_WITH([dbusinterfacedir],
 914         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 915         [],
 916         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
 917
 918 AC_ARG_WITH([bashcompletiondir],
 919         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
 920         [],
 921         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
 922                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
 923         ] , [
 924                 with_bashcompletiondir=${datadir}/bash-completion/completions
 925         ])])
 926
 927 AC_ARG_WITH([rootprefix],
 928         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
 929         [], [with_rootprefix=${ac_default_prefix}])
 930
 931 AC_ARG_WITH([rootlibdir],
 932         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 933         [],
 934         [with_rootlibdir=${libdir}])
 935
 936 AC_ARG_WITH([pamlibdir],
 937         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
 938         [],
 939         [with_pamlibdir=${with_rootlibdir}/security])
 940
 941 AC_ARG_ENABLE([split-usr],
 942         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
 943         [],
 944         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
 945                 enable_split_usr=yes
 946         ], [
 947                 enable_split_usr=no
 948         ])])
 949
 950 AS_IF([test "x${enable_split_usr}" = "xyes"], [
 951         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
 952 ])
 953
 954 # Work around intltoolize and gtk-doc problems in VPATH builds
 955 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
 956                                        [Define to do gtk-doc tests])
 957 AS_IF([test "x$0" != "x./configure"], [
 958         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
 959 ])
 960
 961 AC_ARG_ENABLE(tests,
 962        [AC_HELP_STRING([--disable-tests], [disable tests])],
 963        enable_tests=$enableval, enable_tests=yes)
 964 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
 965
 966 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 967 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 968 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 969 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 970 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
 971 AC_SUBST([pamlibdir], [$with_pamlibdir])
 972 AC_SUBST([rootprefix], [$with_rootprefix])
 973 AC_SUBST([rootlibdir], [$with_rootlibdir])
 974
 975 AC_CONFIG_FILES([
 976         Makefile po/Makefile.in
 977         docs/libudev/Makefile
 978         docs/libudev/version.xml
 979         docs/gudev/Makefile
 980         docs/gudev/version.xml
 981 ])
 982
 983 AC_OUTPUT
 984 AC_MSG_RESULT([
 985         $PACKAGE_NAME $VERSION
 986
 987         libcryptsetup:           ${have_libcryptsetup}
 988         tcpwrap:                 ${have_tcpwrap}
 989         PAM:                     ${have_pam}
 990         AUDIT:                   ${have_audit}
 991         IMA:                     ${have_ima}
 992         SELinux:                 ${have_selinux}
 993         SMACK:                   ${have_smack}
 994         XZ:                      ${have_xz}
 995         ACL:                     ${have_acl}
 996         XATTR:                   ${have_xattr}
 997         GCRYPT:                  ${have_gcrypt}
 998         QRENCODE:                ${have_qrencode}
 999         MICROHTTPD:              ${have_microhttpd}
1000         CHKCONFIG:               ${have_chkconfig}
1001         binfmt:                  ${have_binfmt}
1002         vconsole:                ${have_vconsole}
1003         readahead:               ${have_readahead}
1004         bootchart:               ${have_bootchart}
1005         quotacheck:              ${have_quotacheck}
1006         tmpfiles:                ${have_tmpfiles}
1007         randomseed:              ${have_randomseed}
1008         logind:                  ${have_logind}
1009         machined:                ${have_machined}
1010         hostnamed:               ${have_hostnamed}
1011         timedated:               ${have_timedated}
1012         localed:                 ${have_localed}
1013         coredump:                ${have_coredump}
1014         polkit:                  ${have_polkit}
1015         efi:                     ${have_efi}
1016         kmod:                    ${have_kmod}
1017         blkid:                   ${have_blkid}
1018         nss-myhostname:          ${have_myhostname}
1019         gudev:                   ${enable_gudev}
1020         gintrospection:          ${enable_introspection}
1021         keymap:                  ${enable_keymap}
1022         Python:                  ${have_python}
1023         Python Headers:          ${have_python_devel}
1024         man pages:               ${have_manpages}
1025         gtk-doc:                 ${enable_gtk_doc}
1026         test coverage:           ${have_coverage}
1027         Split /usr:              ${enable_split_usr}
1028         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1029
1030         prefix:                  ${prefix}
1031         rootprefix:              ${with_rootprefix}
1032         sysconf dir:             ${sysconfdir}
1033         datarootdir:             ${datarootdir}
1034         includedir:              ${includedir}
1035         include_prefix:          ${INCLUDE_PREFIX}
1036         lib dir:                 ${libdir}
1037         rootlib dir:             ${with_rootlibdir}
1038         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1039         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1040         Build Python:            ${PYTHON}
1041         Installation Python:     ${PYTHON_BINARY}
1042         firmware path:           ${FIRMWARE_PATH}
1043         PAM modules dir:         ${with_pamlibdir}
1044         D-Bus policy dir:        ${with_dbuspolicydir}
1045         D-Bus session dir:       ${with_dbussessionservicedir}
1046         D-Bus system dir:        ${with_dbussystemservicedir}
1047         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1048         Bash completions dir:    ${with_bashcompletiondir}
1049         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1050         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1051         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1052
1053         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1054         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1055         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1056         PYTHON_CFLAGS:           ${PYTHON_CFLAGS}
1057         PYTHON_LIBS:             ${PYTHON_LIBS}
1058 ])