configure.ac

   1 AC_INIT([udev],
   2         [140],
   3         [linux-hotplug@vger.kernel.org])
   4 AC_PREREQ(2.60)
   5 AC_CONFIG_SRCDIR([udev/udevd.c])
   6 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
   7 AC_DISABLE_STATIC
   8 AC_USE_SYSTEM_EXTENSIONS
   9 AC_SYS_LARGEFILE
  10 AC_PROG_LIBTOOL
  11 AC_CONFIG_MACRO_DIR([m4])
  12
  13 dnl /* prefix is /usr, exec_prefix is /, if overridden exec_prefix follows prefix */
  14 AC_PREFIX_DEFAULT([/usr])
  15 test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=
  16
  17 dnl /* libudev version */
  18 LIBUDEV_LT_CURRENT=0
  19 LIBUDEV_LT_REVISION=10
  20 LIBUDEV_LT_AGE=0
  21 AC_SUBST(LIBUDEV_LT_CURRENT)
  22 AC_SUBST(LIBUDEV_LT_REVISION)
  23 AC_SUBST(LIBUDEV_LT_AGE)
  24
  25 dnl /* libvolume_id version */
  26 VOLID_LT_CURRENT=2
  27 VOLID_LT_REVISION=0
  28 VOLID_LT_AGE=1
  29 AC_SUBST(VOLID_LT_CURRENT)
  30 AC_SUBST(VOLID_LT_REVISION)
  31 AC_SUBST(VOLID_LT_AGE)
  32
  33 AC_PATH_PROG([XSLTPROC], [xsltproc])
  34
  35 AC_CHECK_LIB(c, inotify_init,
  36         [AC_DEFINE([HAVE_INOTIFY], 1, [inotify available])],
  37         [AC_MSG_WARN([inotify support disabled])])
  38
  39 AC_ARG_WITH(udev-prefix,
  40         AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
  41         [], [with_udev_prefix='${exec_prefix}'])
  42 udev_prefix=$with_udev_prefix
  43 AC_SUBST(udev_prefix)
  44
  45 AC_ARG_WITH(libdir-name,
  46         AS_HELP_STRING([--with-libdir-name=DIR], [name of the arch lib directory]),
  47         [], [with_libdir_name=lib])
  48 libdir_name=$with_libdir_name
  49 AC_SUBST(libdir_name)
  50
  51 AC_ARG_WITH(selinux,
  52         AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
  53         [], with_selinux=no)
  54 if test "x$with_selinux" = xyes; then
  55         LIBS_save=$LIBS
  56         AC_CHECK_LIB(selinux, getprevcon,
  57                 [],
  58                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  59         LIBS=$LIBS_save
  60         AC_DEFINE(USE_SELINUX, [1] ,[compile with SELinux support])
  61         SELINUX_LIBS="-lselinux -lsepol"
  62 fi
  63 AC_SUBST([SELINUX_LIBS])
  64 AM_CONDITIONAL(USE_SELINUX, [test "x$with_selinux" = xyes], [compile with SELinux support])
  65
  66 AC_ARG_ENABLE(debug,
  67         AS_HELP_STRING([--enable-debug], [turn on debugging]),
  68         [], enable_debug=no)
  69 if test "x$enable_debug" = "xyes"; then
  70         AC_DEFINE(DEBUG, [1] ,[Compile in debug messages])
  71         DEBUG_CFLAGS="-DDEBUG"
  72 fi
  73 AC_SUBST(DEBUG_CFLAGS)
  74
  75 AC_ARG_ENABLE(logging,
  76         AS_HELP_STRING([--disable-logging], [turn off logging/syslog]),
  77         [], enable_logging=yes)
  78 if test "x$enable_logging" != "xno"; then
  79         AC_DEFINE(USE_LOG, [1] ,[Use logging/syslog])
  80 fi
  81
  82 AC_CONFIG_HEADERS(config.h)
  83 AC_CONFIG_FILES([
  84         Makefile
  85         udev/Makefile
  86         udev/lib/Makefile
  87         udev/lib/libudev.pc
  88         rules/Makefile
  89         extras/Makefile
  90         extras/ata_id/Makefile
  91         extras/cdrom_id/Makefile
  92         extras/edd_id/Makefile
  93         extras/path_id/Makefile
  94         extras/firmware/Makefile
  95         extras/collect/Makefile
  96         extras/floppy/Makefile
  97         extras/fstab_import/Makefile
  98         extras/rule_generator/Makefile
  99         extras/scsi_id/Makefile
 100         extras/usb_id/Makefile
 101         extras/volume_id/Makefile
 102         extras/volume_id/lib/Makefile
 103         extras/volume_id/lib/libvolume_id.pc
 104 ])
 105 AC_OUTPUT
 106
 107 echo "
 108         udev $VERSION
 109         ========
 110
 111         prefix:                 ${prefix}
 112         exec_prefix:            ${exec_prefix}
 113         udev_prefix:            ${udev_prefix}
 114         libdir_name:            ${libdir_name}
 115         datarootdir:            ${datarootdir}
 116         mandir:                 ${mandir}
 117         includedir:             ${includedir}
 118
 119         logging:                ${enable_logging}
 120         debug:                  ${enable_debug}
 121         selinux:                ${with_selinux}
 122
 123         compiler:               ${CC}
 124         cflags:                 ${CFLAGS}
 125         ldflags:                ${LDFLAGS}
 126
 127         xsltproc:               ${XSLTPROC}
 128 "