configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[11],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24
  25 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  26
  27 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  28
  29 AC_CANONICAL_HOST
  30 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  31
  32 AM_SILENT_RULES([yes])
  33
  34 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  35
  36 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  37         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  38         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  39 ])
  40
  41 AC_PROG_MKDIR_P
  42 AC_PROG_LN_S
  43 AC_PROG_SED
  44
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47 AM_PROG_CC_C_O
  48 AC_PROG_GCC_TRADITIONAL
  49 AC_USE_SYSTEM_EXTENSIONS
  50
  51 CC_CHECK_CFLAGS_APPEND([ \
  52         -pipe \
  53         -Wall \
  54         -W \
  55         -Wextra \
  56         -Wno-inline \
  57         -Wvla \
  58         -Wundef \
  59         -Wformat=2 \
  60         -Wlogical-op \
  61         -Wsign-compare \
  62         -Wformat-security \
  63         -Wmissing-include-dirs \
  64         -Wformat-nonliteral \
  65         -Wold-style-definition \
  66         -Wpointer-arith \
  67         -Winit-self \
  68         -Wdeclaration-after-statement \
  69         -Wfloat-equal \
  70         -Wmissing-prototypes \
  71         -Wstrict-prototypes \
  72         -Wredundant-decls \
  73         -Wmissing-declarations \
  74         -Wmissing-noreturn \
  75         -Wshadow \
  76         -Wendif-labels \
  77         -Wcast-align \
  78         -Wstrict-aliasing=2 \
  79         -Wwrite-strings \
  80         -Wno-long-long \
  81         -Wno-overlength-strings \
  82         -Wno-unused-parameter \
  83         -Wno-missing-field-initializers \
  84         -Wno-unused-result \
  85         -Wp,-D_FORTIFY_SOURCE=2 \
  86         -ffast-math \
  87         -fno-common \
  88         -fdiagnostics-show-option \
  89         -fno-strict-aliasing \
  90         -fvisibility=hidden \
  91         -ffunction-sections \
  92         -fdata-sections \
  93         -Wl,--as-needed \
  94         -Wl,--gc-sections])
  95
  96 LT_PREREQ(2.2)
  97 LT_INIT
  98
  99 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 100 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 101 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 102 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 103
 104 # This makes sure pkg.m4 is available.
 105 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 106
 107 PKG_CHECK_MODULES(UDEV, [ libudev >= 160 ])
 108 AC_SUBST(UDEV_CFLAGS)
 109 AC_SUBST(UDEV_LIBS)
 110
 111 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 112 AC_SUBST(DBUS_CFLAGS)
 113 AC_SUBST(DBUS_LIBS)
 114
 115 PKG_CHECK_MODULES(DBUSGLIB, [ dbus-glib-1 ])
 116 AC_SUBST(DBUSGLIB_CFLAGS)
 117 AC_SUBST(DBUSGLIB_LIBS)
 118
 119 have_selinux=no
 120 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 121 if test "x$enable_selinux" != "xno"; then
 122         # not using PKG_CHECK_MODULES as for some reason libselinux didn't
 123         # install any pkg-config modules here
 124         AC_SEARCH_LIBS([getcon], [selinux],
 125                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELINUX is available]) have_selinux=yes],
 126                 have_selinux=no)
 127         AC_SUBST(SELINUX_CFLAGS)
 128         AC_SUBST(SELINUX_LIBS)
 129         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 130                 AC_MSG_ERROR([*** selinux support requested but libraries not found])
 131         fi
 132 fi
 133 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 134
 135 AC_ARG_ENABLE([tcpwrap],
 136         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 137                 [case "${enableval}" in
 138                         yes) have_tcpwrap=yes ;;
 139                         no) have_tcpwrap=no ;;
 140                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 141                 esac],
 142                 [have_tcpwrap=auto])
 143
 144 if test "x${have_tcpwrap}" != xno ; then
 145         ACX_LIBWRAP
 146         if test "x${LIBWRAP_LIBS}" = x ; then
 147                 if test "x$have_tcpwrap" = xyes ; then
 148                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 149                 fi
 150                 have_tcpwrap=no
 151         else
 152                 have_tcpwrap=yes
 153         fi
 154 else
 155         LIBWRAP_LIBS=
 156 fi
 157 AC_SUBST(LIBWRAP_LIBS)
 158
 159 AC_ARG_ENABLE([pam],
 160         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 161                 [case "${enableval}" in
 162                         yes) have_pam=yes ;;
 163                         no) have_pam=no ;;
 164                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 165                 esac],
 166                 [have_pam=auto])
 167
 168 if test "x${have_pam}" != xno ; then
 169         AC_CHECK_HEADERS(
 170                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 171                 [have_pam=yes],
 172                 [if test "x$have_pam" = xyes ; then
 173                         AC_MSG_ERROR([*** PAM headers not found.])
 174                 fi])
 175
 176         AC_CHECK_LIB(
 177                 [pam],
 178                 [pam_syslog],
 179                 [have_pam=yes],
 180                 [if test "x$have_pam" = xyes ; then
 181                         AC_MSG_ERROR([*** libpam not found.])
 182                 fi])
 183
 184         if test "x$have_pam" = xyes ; then
 185                 PAM_LIBS="-lpam -lpam_misc"
 186                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 187         else
 188                 have_pam=no
 189         fi
 190 else
 191         PAM_LIBS=
 192 fi
 193 AC_SUBST(PAM_LIBS)
 194 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 195
 196 AC_ARG_ENABLE([audit],
 197         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 198                 [case "${enableval}" in
 199                         yes) have_audit=yes ;;
 200                         no) have_audit=no ;;
 201                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 202                 esac],
 203                 [have_audit=auto])
 204
 205 if test "x${have_audit}" != xno ; then
 206         AC_CHECK_HEADERS(
 207                 [libaudit.h],
 208                 [have_audit=yes],
 209                 [if test "x$have_audit" = xyes ; then
 210                         AC_MSG_ERROR([*** AUDIT headers not found.])
 211                 fi])
 212
 213         AC_CHECK_LIB(
 214                 [audit],
 215                 [audit_open],
 216                 [have_audit=yes],
 217                 [if test "x$have_audit" = xyes ; then
 218                         AC_MSG_ERROR([*** libaudit not found.])
 219                 fi])
 220
 221         if test "x$have_audit" = xyes ; then
 222                 AUDIT_LIBS="-laudit"
 223                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 224         else
 225                 have_audit=no
 226         fi
 227 else
 228         AUDIT_LIBS=
 229 fi
 230 AC_SUBST(AUDIT_LIBS)
 231
 232 have_gtk=no
 233 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 234 if test "x$enable_gtk" != "xno"; then
 235         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 gio-unix-2.0 libnotify ],
 236                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 237         AC_SUBST(GTK_CFLAGS)
 238         AC_SUBST(GTK_LIBS)
 239         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 240              AC_MSG_ERROR([*** gtk support requested but libraries not found])
 241         fi
 242 fi
 243 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 244
 245 AM_PROG_VALAC([0.9])
 246 AC_SUBST(VAPIDIR)
 247 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 248
 249 AC_PATH_PROG([XSLTPROC], [xsltproc])
 250 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 251
 252 AC_PATH_PROG([M4], [m4])
 253
 254 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware or other]))
 255 if test "z$with_distro" = "z"; then
 256         if test "$cross_compiling" = yes; then
 257                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 258         else
 259                 AC_CHECK_FILE(/etc/redhat-release,with_distro="fedora")
 260                 AC_CHECK_FILE(/etc/SuSE-release,with_distro="suse")
 261                 AC_CHECK_FILE(/etc/debian_version,with_distro="debian")
 262                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 263                         with_distro="ubuntu"
 264                 fi
 265                 AC_CHECK_FILE(/etc/arch-release,with_distro="arch")
 266                 AC_CHECK_FILE(/etc/gentoo-release,with_distro="gentoo")
 267                 AC_CHECK_FILE(/etc/slackware-version,with_distro="slackware")
 268         fi
 269         if test "z$with_distro" = "z"; then
 270                 with_distro=`uname -s`
 271         fi
 272 fi
 273 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 274 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 275
 276 # Default generic names
 277 SPECIAL_SYSLOG_SERVICE=syslog.service
 278
 279 # Location of the init scripts as mandated by LSB
 280 SYSTEM_SYSVINIT_PATH=/etc/init.d
 281
 282 M4_DISTRO_FLAG=
 283
 284 case $with_distro in
 285         fedora)
 286                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 287                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 288
 289                 # A little background why we define this special unit
 290                 # names here in configure.ac: SysV services currently
 291                 # cannot have aliases. As long as syslog is started
 292                 # via a SysV init script we hence define this name to
 293                 # the actual SysV name here. Later on when SysV init
 294                 # scripts are not used anymore it is advisable to use
 295                 # the generic name instead and use symlinks in the
 296                 # unit directories to point to the right native unit
 297                 # file.
 298
 299                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 300                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 301                 M4_DISTRO_FLAG=-DTARGET_FEDORA=1
 302                 ;;
 303         suse)
 304                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 305                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 306                 M4_DISTRO_FLAG=-DTARGET_SUSE=1
 307                 ;;
 308         debian)
 309                 SYSTEM_SYSVRCND_PATH=/etc
 310                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 311                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 312                 M4_DISTRO_FLAG=-DTARGET_DEBIAN=1
 313                 ;;
 314         ubuntu)
 315                 SYSTEM_SYSVRCND_PATH=/etc
 316                 SPECIAL_SYSLOG_SERVICE=rsyslog.service
 317                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 318                 M4_DISTRO_FLAG=-DTARGET_UBUNTU=1
 319                 ;;
 320         arch)
 321                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 322                 SYSTEM_SYSVRCND_PATH=/etc
 323                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 324                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 325                 M4_DISTRO_FLAG=-DTARGET_ARCH=1
 326                 ;;
 327         gentoo)
 328                 SYSTEM_SYSVINIT_PATH=
 329                 SYSTEM_SYSVRCND_PATH=
 330                 SPECIAL_SYSLOG_SERVICE=syslog-ng.service
 331                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 332                 M4_DISTRO_FLAG=-DTARGET_GENTOO=1
 333                 ;;
 334         slackware)
 335                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 336                 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 337                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 338                 M4_DISTRO_FLAG=-DTARGET_SLACKWARE=1
 339                 ;;
 340         other)
 341                 AS_IF([test "x$with_syslog_service" = "x"],
 342                         [AC_MSG_ERROR([With --distro=other, you must pass --with-syslog-service= to configure])])
 343                 ;;
 344         *)
 345                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 346                 ;;
 347 esac
 348
 349 AC_ARG_WITH([sysvinit-path],
 350         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 351                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 352         [SYSTEM_SYSVINIT_PATH="$withval"],
 353         [])
 354
 355 AC_ARG_WITH([sysvrcd-path],
 356         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 357                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 358         [SYSTEM_SYSVRCND_PATH="$withval"],
 359         [])
 360
 361 AC_ARG_WITH([syslog-service],
 362         [AS_HELP_STRING([--with-syslog-service=UNIT],
 363                 [Specify the name of the special syslog service @<:@default=based on distro@:>@])],
 364         [SPECIAL_SYSLOG_SERVICE="$withval"],
 365         [])
 366
 367 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 368 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 369 AC_SUBST(SPECIAL_SYSLOG_SERVICE)
 370 AC_SUBST(M4_DISTRO_FLAG)
 371
 372 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 373         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 374         SYSTEM_SYSV_COMPAT="yes"
 375 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 376         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 377 else
 378         SYSTEM_SYSV_COMPAT="no"
 379 fi
 380
 381 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 382 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 383 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 384 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 385 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 386 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 387 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 388 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 389
 390 AC_DEFINE_UNQUOTED(SPECIAL_SYSLOG_SERVICE, ["$SPECIAL_SYSLOG_SERVICE"], [Syslog service name])
 391
 392 AC_ARG_WITH([dbuspolicydir],
 393         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 394         [],
 395         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 396
 397 AC_ARG_WITH([dbussessionservicedir],
 398         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 399         [],
 400         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 401
 402 AC_ARG_WITH([dbussystemservicedir],
 403         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 404         [],
 405         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 406
 407 AC_ARG_WITH([dbusinterfacedir],
 408         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 409         [],
 410         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 411
 412 AC_ARG_WITH([udevrulesdir],
 413         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 414         [],
 415         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 416
 417 AC_ARG_WITH([pamlibdir],
 418         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 419         [],
 420         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 421
 422 AC_ARG_WITH([rootdir],
 423         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 424         [],
 425         [with_rootdir=${ac_default_prefix}])
 426
 427 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 428 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 429 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 430 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 431 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 432 AC_SUBST([pamlibdir], [$with_pamlibdir])
 433 AC_SUBST([rootdir], [$with_rootdir])
 434
 435 AC_CONFIG_FILES([Makefile])
 436 AC_OUTPUT
 437
 438 echo "
 439         $PACKAGE_NAME $VERSION
 440
 441         Distribution:            ${with_distro}
 442         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 443         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 444         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 445         Syslog service:          ${SPECIAL_SYSLOG_SERVICE}
 446         Gtk:                     ${have_gtk}
 447         tcpwrap:                 ${have_tcpwrap}
 448         PAM:                     ${have_pam}
 449         AUDIT:                   ${have_audit}
 450         SELinux:                 ${have_selinux}
 451         prefix:                  ${prefix}
 452         root dir:                ${with_rootdir}
 453         udev rules dir:          ${with_udevrulesdir}
 454         pam modules dir:         ${with_pamlibdir}
 455         dbus policy dir:         ${with_dbuspolicydir}
 456         dbus session dir:        ${with_dbussessionservicedir}
 457         dbus system dir:         ${with_dbussystemservicedir}
 458         dbus interfaces dir:     ${with_dbusinterfacedir}
 459 "