configure.ac

   1 AC_INIT([udev],
   2         [143],
   3         [linux-hotplug@vger.kernel.org])
   4 AC_PREREQ(2.60)
   5 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
   6 AC_DISABLE_STATIC
   7 AC_USE_SYSTEM_EXTENSIONS
   8 dnl AM_SILENT_RULES
   9 AC_SYS_LARGEFILE
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AC_PROG_LIBTOOL
  12
  13 dnl /* prefix is /usr, exec_prefix is /, if overridden exec_prefix follows prefix */
  14 AC_PREFIX_DEFAULT([/usr])
  15 test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=
  16
  17 dnl /* libudev version */
  18 LIBUDEV_LT_CURRENT=4
  19 LIBUDEV_LT_REVISION=0
  20 LIBUDEV_LT_AGE=4
  21 AC_SUBST(LIBUDEV_LT_CURRENT)
  22 AC_SUBST(LIBUDEV_LT_REVISION)
  23 AC_SUBST(LIBUDEV_LT_AGE)
  24
  25 AC_PATH_PROG([XSLTPROC], [xsltproc])
  26
  27 AC_ARG_WITH(udev-prefix,
  28         AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
  29         [], [with_udev_prefix='${exec_prefix}'])
  30 udev_prefix=$with_udev_prefix
  31 AC_SUBST(udev_prefix)
  32
  33 AC_ARG_WITH(libdir-name,
  34         AS_HELP_STRING([--with-libdir-name=DIR], [name of the arch lib directory]),
  35         [], [with_libdir_name=lib])
  36 libdir_name=$with_libdir_name
  37 AC_SUBST(libdir_name)
  38
  39 AC_ARG_WITH(selinux,
  40         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  41         [], with_selinux=no)
  42 if test "x$with_selinux" = xyes; then
  43         LIBS_save=$LIBS
  44         AC_CHECK_LIB(selinux, getprevcon,
  45                 [],
  46                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  47         LIBS=$LIBS_save
  48         SELINUX_LIBS="-lselinux -lsepol"
  49         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  50 fi
  51 AC_SUBST([SELINUX_LIBS])
  52 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  53
  54 AC_ARG_ENABLE(debug,
  55         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  56         [], enable_debug=no)
  57 if test "x$enable_debug" = "xyes"; then
  58         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  59 fi
  60
  61 AC_ARG_ENABLE(logging,
  62         AS_HELP_STRING([--disable-logging], [disable system logging]),
  63         [], enable_logging=yes)
  64 if test "x$enable_logging" = "xyes"; then
  65         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  66 fi
  67
  68 AC_CONFIG_HEADERS(config.h)
  69 AC_CONFIG_FILES([
  70         Makefile
  71         libudev/Makefile
  72         libudev/libudev.pc
  73         udev/Makefile
  74         rules/Makefile
  75         extras/Makefile
  76         extras/ata_id/Makefile
  77         extras/cdrom_id/Makefile
  78         extras/edd_id/Makefile
  79         extras/path_id/Makefile
  80         extras/firmware/Makefile
  81         extras/collect/Makefile
  82         extras/floppy/Makefile
  83         extras/fstab_import/Makefile
  84         extras/rule_generator/Makefile
  85         extras/scsi_id/Makefile
  86         extras/usb_id/Makefile
  87 ])
  88
  89 AC_OUTPUT
  90 AC_MSG_RESULT([
  91         udev $VERSION
  92         ========
  93
  94         prefix:                 ${prefix}
  95         exec_prefix:            ${exec_prefix}
  96         udev_prefix:            ${udev_prefix}
  97         libdir_name:            ${libdir_name}
  98         datarootdir:            ${datarootdir}
  99         mandir:                 ${mandir}
 100         includedir:             ${includedir}
 101
 102         logging:                ${enable_logging}
 103         debug:                  ${enable_debug}
 104         selinux:                ${with_selinux}
 105
 106         compiler:               ${CC}
 107         cflags:                 ${CFLAGS}
 108         ldflags:                ${LDFLAGS}
 109
 110         xsltproc:               ${XSLTPROC}
 111 ])