configure.ac

   1 #  This file is part of systemd.
   2 #
   3 #  Copyright 2010 Lennart Poettering
   4 #
   5 #  systemd is free software; you can redistribute it and/or modify it
   6 #  under the terms of the GNU General Public License as published by
   7 #  the Free Software Foundation; either version 2 of the License, or
   8 #  (at your option) any later version.
   9 #
  10 #  systemd is distributed in the hope that it will be useful, but
  11 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  12 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 #  General Public License for more details.
  14 #
  15 #  You should have received a copy of the GNU General Public License
  16 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ(2.63)
  19
  20 AC_INIT([systemd],[32],[systemd-devel@lists.freedesktop.org])
  21 AC_CONFIG_SRCDIR([src/main.c])
  22 AC_CONFIG_MACRO_DIR([m4])
  23 AC_CONFIG_HEADERS([config.h])
  24 AC_USE_SYSTEM_EXTENSIONS
  25 AC_SYS_LARGEFILE
  26
  27 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax subdir-objects dist-bzip2])
  28
  29 AC_SUBST(PACKAGE_URL, [http://www.freedesktop.org/wiki/Software/systemd])
  30
  31 AC_CANONICAL_HOST
  32 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  33 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
  34        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
  35       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
  36
  37 AM_SILENT_RULES([yes])
  38
  39 AC_CHECK_PROG([STOW], [stow], [yes], [no])
  40
  41 AS_IF([test "x$STOW" = "xyes" && test -d /usr/local/stow], [
  42         AC_MSG_NOTICE([*** Found /usr/local/stow: default install prefix set to /usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION} ***])
  43         ac_default_prefix="/usr/local/stow/${PACKAGE_NAME}-${PACKAGE_VERSION}"
  44 ])
  45
  46 # i18n stuff for the PolicyKit policy files
  47 IT_PROG_INTLTOOL([0.40.0])
  48
  49 GETTEXT_PACKAGE=systemd
  50 AC_SUBST(GETTEXT_PACKAGE)
  51
  52 AC_PROG_MKDIR_P
  53 AC_PROG_LN_S
  54 AC_PROG_SED
  55 AC_PROG_AWK
  56
  57 AC_PROG_CC
  58 AC_PROG_CC_C99
  59 AM_PROG_CC_C_O
  60 AC_PROG_GCC_TRADITIONAL
  61
  62 AC_CHECK_TOOL(OBJCOPY, objcopy)
  63 AC_CHECK_TOOL(STRINGS, strings)
  64 AC_CHECK_TOOL(GPERF, gperf)
  65
  66 CC_CHECK_CFLAGS_APPEND([ \
  67         -pipe \
  68         -Wall \
  69         -W \
  70         -Wextra \
  71         -Wno-inline \
  72         -Wvla \
  73         -Wundef \
  74         -Wformat=2 \
  75         -Wlogical-op \
  76         -Wsign-compare \
  77         -Wformat-security \
  78         -Wmissing-include-dirs \
  79         -Wformat-nonliteral \
  80         -Wold-style-definition \
  81         -Wpointer-arith \
  82         -Winit-self \
  83         -Wdeclaration-after-statement \
  84         -Wfloat-equal \
  85         -Wmissing-prototypes \
  86         -Wstrict-prototypes \
  87         -Wredundant-decls \
  88         -Wmissing-declarations \
  89         -Wmissing-noreturn \
  90         -Wshadow \
  91         -Wendif-labels \
  92         -Wcast-align \
  93         -Wstrict-aliasing=2 \
  94         -Wwrite-strings \
  95         -Wno-long-long \
  96         -Wno-overlength-strings \
  97         -Wno-unused-parameter \
  98         -Wno-missing-field-initializers \
  99         -Wno-unused-result \
 100         -Wp,-D_FORTIFY_SOURCE=2 \
 101         -ffast-math \
 102         -fno-common \
 103         -fdiagnostics-show-option \
 104         -fno-strict-aliasing \
 105         -fvisibility=hidden \
 106         -ffunction-sections \
 107         -fdata-sections \
 108         -Wl,--as-needed \
 109         -Wl,--gc-sections])
 110
 111 LT_PREREQ(2.2)
 112 LT_INIT
 113
 114 AC_SEARCH_LIBS([clock_gettime], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
 115 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
 116
 117 save_LIBS="$LIBS"
 118 LIBS=
 119 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 120 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 121 CAP_LIBS="$LIBS"
 122 LIBS="$save_LIBS"
 123 AC_SUBST(CAP_LIBS)
 124
 125 # This makes sure pkg.m4 is available.
 126 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 127
 128 PKG_CHECK_MODULES(UDEV, [ libudev >= 172 ])
 129 AC_SUBST(UDEV_CFLAGS)
 130 AC_SUBST(UDEV_LIBS)
 131
 132 PKG_CHECK_MODULES(DBUS, [ dbus-1 >= 1.3.2 ])
 133 AC_SUBST(DBUS_CFLAGS)
 134 AC_SUBST(DBUS_LIBS)
 135
 136 have_selinux=no
 137 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 138 if test "x$enable_selinux" != "xno"; then
 139         PKG_CHECK_MODULES(SELINUX, [ libselinux ],
 140                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
 141         AC_SUBST(SELINUX_CFLAGS)
 142         AC_SUBST(SELINUX_LIBS)
 143         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 144                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 145         fi
 146 fi
 147 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 148
 149 AC_ARG_ENABLE([tcpwrap],
 150         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
 151                 [case "${enableval}" in
 152                         yes) have_tcpwrap=yes ;;
 153                         no) have_tcpwrap=no ;;
 154                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
 155                 esac],
 156                 [have_tcpwrap=auto])
 157
 158 if test "x${have_tcpwrap}" != xno ; then
 159         ACX_LIBWRAP
 160         if test "x${LIBWRAP_LIBS}" = x ; then
 161                 if test "x$have_tcpwrap" = xyes ; then
 162                         AC_MSG_ERROR([*** TCP wrappers support not found.])
 163                 fi
 164                 have_tcpwrap=no
 165         else
 166                 have_tcpwrap=yes
 167         fi
 168 else
 169         LIBWRAP_LIBS=
 170 fi
 171 AC_SUBST(LIBWRAP_LIBS)
 172
 173 AC_ARG_ENABLE([pam],
 174         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 175                 [case "${enableval}" in
 176                         yes) have_pam=yes ;;
 177                         no) have_pam=no ;;
 178                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 179                 esac],
 180                 [have_pam=auto])
 181
 182 if test "x${have_pam}" != xno ; then
 183         AC_CHECK_HEADERS(
 184                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 185                 [have_pam=yes],
 186                 [if test "x$have_pam" = xyes ; then
 187                         AC_MSG_ERROR([*** PAM headers not found.])
 188                 fi])
 189
 190         AC_CHECK_LIB(
 191                 [pam],
 192                 [pam_syslog],
 193                 [have_pam=yes],
 194                 [if test "x$have_pam" = xyes ; then
 195                         AC_MSG_ERROR([*** libpam not found.])
 196                 fi])
 197
 198         if test "x$have_pam" = xyes ; then
 199                 PAM_LIBS="-lpam -lpam_misc"
 200                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 201         else
 202                 have_pam=no
 203         fi
 204 else
 205         PAM_LIBS=
 206 fi
 207 AC_SUBST(PAM_LIBS)
 208 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 209
 210 AC_ARG_ENABLE([acl],
 211         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 212                 [case "${enableval}" in
 213                         yes) have_acl=yes ;;
 214                         no) have_acl=no ;;
 215                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 216                 esac],
 217                 [have_acl=auto])
 218
 219 if test "x${have_acl}" != xno ; then
 220         AC_CHECK_HEADERS(
 221                 [sys/acl.h acl/libacl.h],
 222                 [have_acl=yes],
 223                 [if test "x$have_acl" = xyes ; then
 224                         AC_MSG_ERROR([*** ACL headers not found.])
 225                 fi])
 226
 227         AC_CHECK_LIB(
 228                 [acl],
 229                 [acl_get_file],
 230                 [have_acl=yes],
 231                 [if test "x$have_acl" = xyes ; then
 232                         AC_MSG_ERROR([*** libacl not found.])
 233                 fi])
 234
 235         if test "x$have_acl" = xyes ; then
 236                 ACL_LIBS="-lacl"
 237                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 238         else
 239                 have_acl=no
 240         fi
 241 else
 242         ACL_LIBS=
 243 fi
 244 AC_SUBST(ACL_LIBS)
 245 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 246
 247 AC_ARG_ENABLE([audit],
 248         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 249                 [case "${enableval}" in
 250                         yes) have_audit=yes ;;
 251                         no) have_audit=no ;;
 252                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 253                 esac],
 254                 [have_audit=auto])
 255
 256 if test "x${have_audit}" != xno ; then
 257         AC_CHECK_HEADERS(
 258                 [libaudit.h],
 259                 [have_audit=yes],
 260                 [if test "x$have_audit" = xyes ; then
 261                         AC_MSG_ERROR([*** AUDIT headers not found.])
 262                 fi])
 263
 264         AC_CHECK_LIB(
 265                 [audit],
 266                 [audit_open],
 267                 [have_audit=yes],
 268                 [if test "x$have_audit" = xyes ; then
 269                         AC_MSG_ERROR([*** libaudit not found.])
 270                 fi])
 271
 272         if test "x$have_audit" = xyes ; then
 273                 AUDIT_LIBS="-laudit"
 274                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 275         else
 276                 have_audit=no
 277         fi
 278 else
 279         AUDIT_LIBS=
 280 fi
 281 AC_SUBST(AUDIT_LIBS)
 282
 283 have_libcryptsetup=no
 284 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 285 if test "x$enable_libcryptsetup" != "xno"; then
 286         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup ],
 287                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 288         AC_SUBST(LIBCRYPTSETUP_CFLAGS)
 289         AC_SUBST(LIBCRYPTSETUP_LIBS)
 290         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 291                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 292         fi
 293 fi
 294 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 295
 296 have_binfmt=no
 297 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 298 if test "x$enable_binfmt" != "xno"; then
 299         have_binfmt=yes
 300 fi
 301 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 302
 303 have_gtk=no
 304 AC_ARG_ENABLE(gtk, AS_HELP_STRING([--disable-gtk], [disable GTK tools]))
 305 if test "x$enable_gtk" != "xno"; then
 306         PKG_CHECK_MODULES(GTK, [ gtk+-2.0 glib-2.0 > 2.26 gio-unix-2.0 ],
 307                 [AC_DEFINE(HAVE_GTK, 1, [Define if GTK is available]) have_gtk=yes], have_gtk=no)
 308         AC_SUBST(GTK_CFLAGS)
 309         AC_SUBST(GTK_LIBS)
 310         if test "x$have_gtk" = xno -a "x$enable_gtk" = xyes; then
 311                 AC_MSG_ERROR([*** gtk support requested but libraries not found])
 312         fi
 313 fi
 314 AM_CONDITIONAL(HAVE_GTK, [test "$have_gtk" = "yes"])
 315
 316 if test "$have_gtk" = "yes"; then
 317         PKG_CHECK_MODULES(LIBNOTIFY, [ libnotify ])
 318         PKG_CHECK_EXISTS([ libnotify >= 0.7.0 ], [ libnotify07=yes ])
 319
 320         AC_SUBST(LIBNOTIFY_CFLAGS)
 321         AC_SUBST(LIBNOTIFY_LIBS)
 322 fi
 323 AM_CONDITIONAL(LIBNOTIFY07, [ test "$libnotify07" = "yes" ])
 324
 325 AM_PROG_VALAC([0.10])
 326 AC_SUBST(VAPIDIR)
 327 AM_CONDITIONAL(HAVE_VALAC, test x"$VALAC" != x)
 328
 329 AC_PATH_PROG([XSLTPROC], [xsltproc])
 330 AM_CONDITIONAL(HAVE_XSLTPROC, test x"$XSLTPROC" != x)
 331
 332 AC_PATH_PROG([M4], [m4])
 333
 334 AC_ARG_WITH(distro, AS_HELP_STRING([--with-distro=DISTRO],[Specify the distribution to target: One of fedora, suse, debian, ubuntu, arch, gentoo, slackware, altlinux or other]))
 335 if test "z$with_distro" = "z"; then
 336         if test "$cross_compiling" = yes; then
 337                 AC_MSG_WARN([Target distribution cannot be reliably detected when cross-compiling. You should specify it with --with-distro (see $0 --help for recognized distros)])
 338         else
 339                 test -f "/etc/redhat-release" && with_distro="fedora"
 340                 test -f "/etc/SuSE-release" && with_distro="suse"
 341                 test -f "/etc/debian_version" &&  with_distro="debian"
 342                 test -f "/etc/arch-release" && with_distro="arch"
 343                 test -f "/etc/gentoo-release" && with_distro="gentoo"
 344                 test -f "/etc/slackware-version" && with_distro="slackware"
 345                 test -f "/etc/frugalware-release" && with_distro="frugalware"
 346                 test -f "/etc/altlinux-release" && with_distro="altlinux"
 347                 test -f "/etc/mandriva-release" && with_distro="mandriva"
 348                 test -f "/etc/meego-release" && with_distro="meego"
 349                 test -f "/etc/angstrom-version" && with_distro="angstrom"
 350                 if test "x`lsb_release -is 2>/dev/null`" = "xUbuntu"; then
 351                         with_distro="ubuntu"
 352                 fi
 353         fi
 354         if test "z$with_distro" = "z"; then
 355                 with_distro=`uname -s`
 356         fi
 357 fi
 358 with_distro=`echo ${with_distro} | tr '[[:upper:]]' '[[:lower:]]' `
 359 AC_DEFINE_UNQUOTED(DISTRIBUTION, ["${with_distro}"], [Target Distribution])
 360
 361 # Location of the init scripts as mandated by LSB
 362 SYSTEM_SYSVINIT_PATH=/etc/init.d
 363 SYSTEM_SYSVRCND_PATH=/etc/rc.d
 364
 365 M4_DEFINES=
 366 have_plymouth=no
 367
 368 case $with_distro in
 369         fedora)
 370                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 371                 AC_DEFINE(TARGET_FEDORA, [], [Target is Fedora/RHEL])
 372                 M4_DEFINES=-DTARGET_FEDORA=1
 373                 have_plymouth=yes
 374                 ;;
 375         suse)
 376                 SYSTEM_SYSVRCND_PATH=/etc/init.d
 377                 AC_DEFINE(TARGET_SUSE, [], [Target is openSUSE/SLE])
 378                 M4_DEFINES=-DTARGET_SUSE=1
 379                 have_plymouth=yes
 380                 ;;
 381         debian)
 382                 SYSTEM_SYSVRCND_PATH=/etc
 383                 AC_DEFINE(TARGET_DEBIAN, [], [Target is Debian])
 384                 M4_DEFINES=-DTARGET_DEBIAN=1
 385                 ;;
 386         ubuntu)
 387                 SYSTEM_SYSVRCND_PATH=/etc
 388                 AC_DEFINE(TARGET_UBUNTU, [], [Target is Ubuntu])
 389                 M4_DEFINES=-DTARGET_UBUNTU=1
 390                 ;;
 391         arch)
 392                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 393                 SYSTEM_SYSVRCND_PATH=/etc
 394                 AC_DEFINE(TARGET_ARCH, [], [Target is ArchLinux])
 395                 M4_DEFINES=-DTARGET_ARCH=1
 396                 ;;
 397         gentoo)
 398                 SYSTEM_SYSVINIT_PATH=
 399                 SYSTEM_SYSVRCND_PATH=
 400                 AC_DEFINE(TARGET_GENTOO, [], [Target is Gentoo])
 401                 M4_DEFINES=-DTARGET_GENTOO=1
 402                 ;;
 403         slackware)
 404                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 405                 AC_DEFINE(TARGET_SLACKWARE, [], [Target is Slackware])
 406                 M4_DEFINES=-DTARGET_SLACKWARE=1
 407                 ;;
 408         frugalware)
 409                 SYSTEM_SYSVINIT_PATH=/etc/rc.d
 410                 AC_DEFINE(TARGET_FRUGALWARE, [], [Target is Frugalware])
 411                 M4_DEFINES=-DTARGET_FRUGALWARE=1
 412                 have_plymouth=yes
 413                 ;;
 414         altlinux)
 415                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 416                 AC_DEFINE(TARGET_ALTLINUX, [], [Target is ALTLinux])
 417                 M4_DEFINES=-DTARGET_ALTLINUX=1
 418                 have_plymouth=yes
 419                 ;;
 420         mandriva)
 421                 SYSTEM_SYSVINIT_PATH=/etc/rc.d/init.d
 422                 AC_DEFINE(TARGET_MANDRIVA, [], [Target is Mandriva])
 423                 M4_DEFINES=-DTARGET_MANDRIVA=1
 424                 have_plymouth=yes
 425                 ;;
 426         meego)
 427                 SYSTEM_SYSVINIT_PATH=
 428                 SYSTEM_SYSVRCND_PATH=
 429                 AC_DEFINE(TARGET_MEEGO, [], [Target is MeeGo])
 430                 M4_DEFINES=-DTARGET_MEEGO=1
 431                 ;;
 432         angstrom)
 433                 SYSTEM_SYSVRCND_PATH=/etc
 434                 AC_DEFINE(TARGET_ANGSTROM, [], [Target is Ångström])
 435                 M4_DEFINES=-DTARGET_ANGSTROM=1
 436                 ;;
 437         other)
 438                 ;;
 439         *)
 440                 AC_MSG_ERROR([Your distribution (${with_distro}) is not yet supported, SysV init scripts could not be found! (patches welcome); you can specify --with-distro=other to skip this check])
 441                 ;;
 442 esac
 443
 444 AC_ARG_WITH([sysvinit-path],
 445         [AS_HELP_STRING([--with-sysvinit-path=PATH],
 446                 [Specify the path to where the SysV init scripts are located @<:@default=based on distro@:>@])],
 447         [SYSTEM_SYSVINIT_PATH="$withval"],
 448         [])
 449
 450 AC_ARG_WITH([sysvrcd-path],
 451         [AS_HELP_STRING([--with-sysvrcd-path=PATH],
 452                 [Specify the path to the base directory for the SysV rcN.d directories @<:@default=based on distro@:>@])],
 453         [SYSTEM_SYSVRCND_PATH="$withval"],
 454         [])
 455
 456 AC_SUBST(SYSTEM_SYSVINIT_PATH)
 457 AC_SUBST(SYSTEM_SYSVRCND_PATH)
 458 AC_SUBST(M4_DEFINES)
 459
 460 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 461         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
 462         SYSTEM_SYSV_COMPAT="yes"
 463         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
 464 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
 465         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
 466 else
 467         SYSTEM_SYSV_COMPAT="no"
 468 fi
 469
 470 AC_ARG_WITH([tty-gid],
 471         [AS_HELP_STRING([--with-tty-gid=GID],
 472                 [Specify the numeric GID of the 'tty' group])],
 473         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
 474         [])
 475
 476 AC_ARG_ENABLE(plymouth, AS_HELP_STRING([--enable-plymouth], [enable plymouth support]))
 477 if test -n "$enable_plymouth"; then
 478         have_plymouth="$enable_plymouth"
 479 fi
 480
 481 AM_CONDITIONAL(TARGET_FEDORA, test x"$with_distro" = xfedora)
 482 AM_CONDITIONAL(TARGET_SUSE, test x"$with_distro" = xsuse)
 483 AM_CONDITIONAL(TARGET_DEBIAN, test x"$with_distro" = xdebian)
 484 AM_CONDITIONAL(TARGET_UBUNTU, test x"$with_distro" = xubuntu)
 485 AM_CONDITIONAL(TARGET_DEBIAN_OR_UBUNTU, test x"$with_distro" = xdebian -o x"$with_distro" = xubuntu)
 486 AM_CONDITIONAL(TARGET_ARCH, test x"$with_distro" = xarch)
 487 AM_CONDITIONAL(TARGET_GENTOO, test x"$with_distro" = xgentoo)
 488 AM_CONDITIONAL(TARGET_SLACKWARE, test x"$with_distro" = xslackware)
 489 AM_CONDITIONAL(TARGET_FRUGALWARE, test x"$with_distro" = xfrugalware)
 490 AM_CONDITIONAL(TARGET_ALTLINUX, test x"$with_distro" = xaltlinux)
 491 AM_CONDITIONAL(TARGET_MANDRIVA, test x"$with_distro" = xmandriva)
 492 AM_CONDITIONAL(TARGET_MEEGO, test x"$with_distro" = xmeego)
 493 AM_CONDITIONAL(TARGET_ANGSTROM, test x"$with_distro" = xangstrom)
 494
 495 AM_CONDITIONAL(HAVE_PLYMOUTH, test "$have_plymouth" = "yes")
 496 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
 497
 498 AC_ARG_WITH([dbuspolicydir],
 499         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
 500         [],
 501         [with_dbuspolicydir=`pkg-config --variable=sysconfdir dbus-1`/dbus-1/system.d])
 502
 503 AC_ARG_WITH([dbussessionservicedir],
 504         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
 505         [],
 506         [with_dbussessionservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`])
 507
 508 AC_ARG_WITH([dbussystemservicedir],
 509         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
 510         [],
 511         [with_dbussystemservicedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../system-services])
 512
 513 AC_ARG_WITH([dbusinterfacedir],
 514         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
 515         [],
 516         [with_dbusinterfacedir=`pkg-config --variable=session_bus_services_dir dbus-1`/../interfaces])
 517
 518 AC_ARG_WITH([udevrulesdir],
 519         AS_HELP_STRING([--with-udevrulesdir=DIR], [Diectory for udev rules]),
 520         [],
 521         [with_udevrulesdir=`pkg-config --variable=udevdir udev`/rules.d])
 522
 523 AC_ARG_WITH([pamlibdir],
 524         AS_HELP_STRING([--with-pamlibdir=DIR], [Diectory for PAM modules]),
 525         [],
 526         [with_pamlibdir=/lib/`$CC -print-multi-os-directory`/security])
 527
 528 AC_ARG_WITH([rootdir],
 529         AS_HELP_STRING([--with-rootdir=DIR], [Root directory for files necessary for boot]),
 530         [],
 531         [with_rootdir=${ac_default_prefix}])
 532
 533 AC_ARG_WITH([rootlibdir],
 534         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
 535         [],
 536         [with_rootlibdir=${libdir}])
 537
 538 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
 539 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
 540 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
 541 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
 542 AC_SUBST([udevrulesdir], [$with_udevrulesdir])
 543 AC_SUBST([pamlibdir], [$with_pamlibdir])
 544 AC_SUBST([rootdir], [$with_rootdir])
 545 AC_SUBST([rootlibdir], [$with_rootlibdir])
 546
 547 AC_CONFIG_FILES([Makefile po/Makefile.in])
 548 AC_OUTPUT
 549 AC_MSG_RESULT([
 550         $PACKAGE_NAME $VERSION
 551
 552         Distribution:            ${with_distro}
 553         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
 554         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
 555         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
 556         Gtk:                     ${have_gtk}
 557         libcryptsetup:           ${have_libcryptsetup}
 558         tcpwrap:                 ${have_tcpwrap}
 559         PAM:                     ${have_pam}
 560         AUDIT:                   ${have_audit}
 561         SELinux:                 ${have_selinux}
 562         ACL:                     ${have_acl}
 563         binfmt:                  ${have_binfmt}
 564         plymouth:                ${have_plymouth}
 565         prefix:                  ${prefix}
 566         root dir:                ${with_rootdir}
 567         lib dir:                 ${libdir}
 568         rootlib dir:             ${with_rootlibdir}
 569         pam modules dir:         ${with_pamlibdir}
 570         udev rules dir:          ${with_udevrulesdir}
 571         dbus policy dir:         ${with_dbuspolicydir}
 572         dbus session dir:        ${with_dbussessionservicedir}
 573         dbus system dir:         ${with_dbussystemservicedir}
 574         dbus interfaces dir:     ${with_dbusinterfacedir}
 575 ])