configure.ac

   1 AC_INIT([udev], [161], [linux-hotplug@vger.kernel.org])
   2 AC_PREREQ(2.60)
   3 AM_INIT_AUTOMAKE([check-news foreign 1.10 dist-bzip2 subdir-objects])
   4 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   5 AC_DISABLE_STATIC
   6 AC_USE_SYSTEM_EXTENSIONS
   7 AC_SYS_LARGEFILE
   8 AC_CONFIG_MACRO_DIR([m4])
   9 LT_INIT
  10 AC_PROG_AWK
  11 GTK_DOC_CHECK(1.10)
  12 AC_PREFIX_DEFAULT([/usr])
  13 AC_PATH_PROG([XSLTPROC], [xsltproc])
  14
  15 AC_ARG_WITH([rootlibdir],
  16         AS_HELP_STRING([--with-rootlibdir=DIR], [rootfs directory to install shared libraries]),
  17         [], [with_rootlibdir=$libdir])
  18 AC_SUBST([rootlib_execdir], [$with_rootlibdir])
  19
  20 AC_ARG_WITH([selinux],
  21         AS_HELP_STRING([--with-selinux], [enable SELinux support]),
  22         [], [with_selinux=no])
  23 if test "x$with_selinux" = xyes; then
  24         LIBS_save=$LIBS
  25         AC_CHECK_LIB(selinux, getprevcon,
  26                 [],
  27                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  28         LIBS=$LIBS_save
  29         SELINUX_LIBS="-lselinux -lsepol"
  30         AC_DEFINE(WITH_SELINUX, [1] ,[SELinux support.])
  31 fi
  32 AC_SUBST([SELINUX_LIBS])
  33 AM_CONDITIONAL(WITH_SELINUX, [test "x$with_selinux" = xyes])
  34
  35 AC_ARG_ENABLE([debug],
  36         AS_HELP_STRING([--enable-debug], [enable debug messages]),
  37         [], [enable_debug=no])
  38 if test "x$enable_debug" = "xyes"; then
  39         AC_DEFINE(ENABLE_DEBUG, [1], [Debug messages.])
  40 fi
  41
  42 AC_ARG_ENABLE([logging],
  43         AS_HELP_STRING([--disable-logging], [disable system logging]),
  44         [], enable_logging=yes)
  45 if test "x$enable_logging" = "xyes"; then
  46         AC_DEFINE(ENABLE_LOGGING, [1], [System logging.])
  47 fi
  48
  49 AC_ARG_WITH(firmware-path,
  50         AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
  51            [Firmware search path (default=/lib/firmware/updates:/lib/firmware)]),
  52         [], [with_firmware_path="/lib/firmware/updates:/lib/firmware"])
  53 OLD_IFS=$IFS
  54 IFS=:
  55 for i in $with_firmware_path
  56 do
  57         if test "x${FIRMWARE_PATH}" = "x"; then
  58                 FIRMWARE_PATH="\\\"${i}/\\\""
  59         else
  60                 FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
  61         fi
  62 done
  63 IFS=$OLD_IFS
  64 AC_SUBST([FIRMWARE_PATH], [$FIRMWARE_PATH])
  65
  66 AC_ARG_WITH([systemdsystemunitdir],
  67         AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
  68         [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
  69 AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
  70 AM_CONDITIONAL(WITH_SYSTEMD, [test -n "$with_systemdsystemunitdir"])
  71
  72 AC_ARG_ENABLE([extras],
  73         AS_HELP_STRING([--disable-extras], [disable extras with external dependencies]),
  74         [], [enable_extras=yes])
  75 if test "x$enable_extras" = xyes; then
  76         AC_PATH_PROG([GPERF], [gperf])
  77         if test -z "$GPERF"; then
  78                 AC_MSG_ERROR([gperf is needed])
  79         fi
  80
  81         PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.7.0 gobject-2.0 >= 2.7.0])
  82         AC_SUBST([GLIB_CFLAGS])
  83         AC_SUBST([GLIB_LIBS])
  84
  85         AC_CHECK_LIB([acl], [acl_init], [:], AC_MSG_ERROR([libacl not found]))
  86         AC_CHECK_HEADER([acl/libacl.h], [:], AC_MSG_ERROR([libacl header not found]))
  87
  88         PKG_CHECK_MODULES(LIBUSB, libusb >= 0.1.12)
  89         AC_SUBST(LIBUSB_CFLAGS)
  90         AC_SUBST(LIBUSB_LIBS)
  91
  92         PKG_CHECK_MODULES(USBUTILS, usbutils >= 0.82)
  93         AC_SUBST([USB_DATABASE], [$($PKG_CONFIG --variable=usbids usbutils)])
  94
  95         if test "x$cross_compiling" = "xno" ; then
  96                 AC_CHECK_FILES([/usr/share/pci.ids], [pciids=/usr/share/pci.ids])
  97                 AC_CHECK_FILES([/usr/share/hwdata/pci.ids], [pciids=/usr/share/hwdata/pci.ids])
  98                 AC_CHECK_FILES([/usr/share/misc/pci.ids], [pciids=/usr/share/misc/pci.ids])
  99         fi
 100         AC_ARG_WITH(pci-ids-path,
 101                 [AS_HELP_STRING([--with-pci-ids-path=DIR], [Path to pci.ids file])],
 102                 [PCI_DATABASE=${withval}],
 103                 [if test -n "$pciids" ; then
 104                         PCI_DATABASE="$pciids"
 105                 else
 106                         AC_MSG_ERROR([pci.ids not found, try --with-pci-ids-path=])
 107                 fi])
 108         AC_MSG_CHECKING([for PCI database location])
 109         AC_MSG_RESULT([$PCI_DATABASE])
 110         AC_SUBST(PCI_DATABASE)
 111
 112         AC_CHECK_HEADER([linux/input.h], [:], AC_MSG_ERROR([kernel headers not found]))
 113         AC_SUBST([INCLUDE_PREFIX], [$(echo '#include <linux/input.h>' | eval $ac_cpp -E - | sed -n '/linux\/input.h/ {s:.*"\(.*\)/linux/input.h".*:\1:; p; q}')])
 114 fi
 115 AM_CONDITIONAL([ENABLE_EXTRAS], [test "x$enable_extras" = xyes])
 116
 117 AC_ARG_ENABLE([introspection],
 118         AS_HELP_STRING([--disable-introspection], [disable GObject introspection]),
 119         [], [enable_introspection=yes])
 120 if test "x$enable_introspection" = xyes; then
 121         PKG_CHECK_MODULES([INTROSPECTION], [gobject-introspection-1.0 >= 0.6.2])
 122         AC_DEFINE([ENABLE_INTROSPECTION], [1], [enable GObject introspection support])
 123         AC_SUBST([G_IR_SCANNER], [$($PKG_CONFIG --variable=g_ir_scanner gobject-introspection-1.0)])
 124         AC_SUBST([G_IR_COMPILER], [$($PKG_CONFIG --variable=g_ir_compiler gobject-introspection-1.0)])
 125         AC_SUBST([G_IR_GENERATE], [$($PKG_CONFIG --variable=g_ir_generate gobject-introspection-1.0)])
 126         AC_SUBST([GIRDIR], [$($PKG_CONFIG --define-variable=datadir=${datadir} --variable=girdir gobject-introspection-1.0)])
 127         AC_SUBST([GIRTYPELIBDIR], [$($PKG_CONFIG --define-variable=libdir=${libdir} --variable=typelibdir gobject-introspection-1.0)])
 128 fi
 129 AM_CONDITIONAL([ENABLE_INTROSPECTION], [test "x$enable_introspection" = xyes])
 130
 131 AC_CONFIG_HEADERS(config.h)
 132 AC_CONFIG_FILES([
 133         Makefile
 134         udev/udev.pc
 135         init/udev.service
 136         init/udev-settle.service
 137         init/udev-retry.service
 138         libudev/libudev.pc
 139         libudev/docs/Makefile
 140         libudev/docs/version.xml
 141         extras/gudev/gudev-1.0.pc
 142         extras/gudev/docs/Makefile
 143         extras/gudev/docs/version.xml
 144 ])
 145
 146 AC_OUTPUT
 147 AC_MSG_RESULT([
 148         udev $VERSION
 149         ========
 150
 151         prefix:                 ${prefix}
 152         sysconfdir:             ${sysconfdir}
 153         sbindir:                ${sbindir}
 154         libdir:                 ${libdir}
 155         rootlibdir:             ${rootlib_execdir}
 156         libexecdir:             ${libexecdir}
 157
 158         datarootdir:            ${datarootdir}
 159         mandir:                 ${mandir}
 160         includedir:             ${includedir}
 161
 162         include_prefix:         ${INCLUDE_PREFIX}
 163
 164         systemdsystemunitdir:   ${systemdsystemunitdir}
 165
 166         logging:                ${enable_logging}
 167         debug:                  ${enable_debug}
 168         selinux:                ${with_selinux}
 169
 170         compiler:               ${CC}
 171         cflags:                 ${CFLAGS}
 172         ldflags:                ${LDFLAGS}
 173
 174         extras:                 ${enable_extras}
 175         gintrospection:         ${enable_introspection}
 176
 177         usb.ids:                ${USB_DATABASE}
 178         pci.ids:                ${PCI_DATABASE}
 179         firmware path:          ${FIRMWARE_PATH}
 180
 181         xsltproc:               ${XSLTPROC}
 182         gperf:                  ${GPERF}
 183 ])