chiark / gitweb /
completion/systemctl: add missing list-sockets verb
[elogind.git] / configure.ac
1 #
2 #  This file is part of systemd.
3 #
4 #  Copyright 2010-2012 Lennart Poettering
5 #  Copyright 2010-2012 Kay Sievers
6 #
7 #  systemd is free software; you can redistribute it and/or modify it
8 #  under the terms of the GNU Lesser General Public License as published by
9 #  the Free Software Foundation; either version 2.1 of the License, or
10 #  (at your option) any later version.
11 #
12 #  systemd is distributed in the hope that it will be useful, but
13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15 #  Lesser General Public License for more details.
16 #
17 #  You should have received a copy of the GNU Lesser General Public License
18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
19
20 AC_PREREQ([2.64])
21
22 AC_INIT([systemd],
23         [207],
24         [http://bugs.freedesktop.org/enter_bug.cgi?product=systemd],
25         [systemd],
26         [http://www.freedesktop.org/wiki/Software/systemd])
27
28 AC_CONFIG_SRCDIR([src/core/main.c])
29 AC_CONFIG_MACRO_DIR([m4])
30 AC_CONFIG_HEADERS([config.h])
31 AC_CONFIG_AUX_DIR([build-aux])
32
33 AC_USE_SYSTEM_EXTENSIONS
34 AC_SYS_LARGEFILE
35 AC_PREFIX_DEFAULT([/usr])
36 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects check-news])
37 AM_SILENT_RULES([yes])
38 AC_CANONICAL_HOST
39 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
40 AS_IF([test "x$host_cpu" = "xmips" || test "x$host_cpu" = "xmipsel" ||
41        test "x$host_cpu" = "xmips64" || test "x$host_cpu" = "xmips64el"],
42       [AC_DEFINE(ARCH_MIPS, [], [Whether on mips arch])])
43
44 LT_PREREQ(2.2)
45 LT_INIT([disable-static])
46
47 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
48 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
49
50 # i18n stuff for the PolicyKit policy files
51 IT_PROG_INTLTOOL([0.40.0])
52
53 GETTEXT_PACKAGE=systemd
54 AC_SUBST(GETTEXT_PACKAGE)
55
56 AC_PROG_MKDIR_P
57 AC_PROG_LN_S
58 AC_PROG_SED
59 AC_PROG_GREP
60 AC_PROG_AWK
61
62 AC_PROG_CC
63 AC_PROG_CC_C99
64 AM_PROG_CC_C_O
65 AC_PROG_GCC_TRADITIONAL
66
67 AC_PATH_PROG([M4], [m4])
68 AC_PATH_PROG([XSLTPROC], [xsltproc])
69
70 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon])
71 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck])
72
73 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap])
74
75 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill])
76
77 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod])
78
79 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec])
80
81 # gtkdocize greps for '^GTK_DOC_CHECK', so it needs to be on its own line
82 m4_ifdef([GTK_DOC_CHECK], [
83 GTK_DOC_CHECK([1.18],[--flavour no-tmpl])],
84          [AM_CONDITIONAL([ENABLE_GTK_DOC], [false])
85           enable_gtk_doc=no])
86
87 AS_IF([test "x$enable_gtk_doc" = "xyes" -a "x$XSLTPROC" = x], [
88         AC_MSG_ERROR([*** GTK doc requested but xsltproc not found])
89 ])
90
91 m4_ifdef([GOBJECT_INTROSPECTION_CHECK], [
92 GOBJECT_INTROSPECTION_CHECK([1.31.1])
93 ], [
94    AM_CONDITIONAL([HAVE_INTROSPECTION], [false])
95    enable_introspection=no])
96
97 AC_CHECK_TOOL(OBJCOPY, objcopy)
98 AC_CHECK_TOOL(STRINGS, strings)
99 AC_CHECK_TOOL(GPERF, gperf)
100 if test -z "$GPERF" ; then
101         AC_MSG_ERROR([*** gperf not found])
102 fi
103
104 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
105         -pipe \
106         -Wall \
107         -Wextra \
108         -Wno-inline \
109         -Wundef \
110         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
111         -Wlogical-op \
112         -Wsign-compare \
113         -Wmissing-include-dirs \
114         -Wold-style-definition \
115         -Wpointer-arith \
116         -Winit-self \
117         -Wdeclaration-after-statement \
118         -Wfloat-equal \
119         -Wmissing-prototypes \
120         -Wstrict-prototypes \
121         -Wredundant-decls \
122         -Wmissing-declarations \
123         -Wmissing-noreturn \
124         -Wshadow \
125         -Wendif-labels \
126         -Wcast-align \
127         -Wstrict-aliasing=2 \
128         -Wwrite-strings \
129         -Wno-long-long \
130         -Wno-overlength-strings \
131         -Wno-unused-parameter \
132         -Wno-missing-field-initializers \
133         -Wno-unused-result \
134         -Werror=overflow \
135         -ffast-math \
136         -fno-common \
137         -fdiagnostics-show-option \
138         -fdiagnostics-color \
139         -fno-strict-aliasing \
140         -fvisibility=hidden \
141         -ffunction-sections \
142         -fdata-sections \
143         -fstack-protector \
144         --param=ssp-buffer-size=4])
145 AC_SUBST([OUR_CFLAGS], $with_cflags)
146
147 AS_CASE([$CFLAGS], [*-O[[12345g\ ]]*],
148         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
149                -Wp,-D_FORTIFY_SOURCE=2])],
150         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
151 AC_SUBST([OUR_CPPFLAGS], $with_cppflags)
152
153 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
154         -Wl,--as-needed \
155         -Wl,--no-undefined \
156         -Wl,--gc-sections \
157         -Wl,-z,relro \
158         -Wl,-z,now])
159 AC_SUBST([OUR_LDFLAGS], $with_ldflags)
160
161 # ------------------------------------------------------------------------------
162 # we use python to build the man page index, and for systemd-python
163 have_python=no
164 AC_ARG_WITH([python],
165         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
166
167 AS_IF([test "x$with_python" != "xno"], [
168         AM_PATH_PYTHON(,, [:])
169         AS_IF([test "$PYTHON" != :], [have_python=yes])
170 ])
171 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
172 AS_IF([test "x$PYTHON_BINARY" = "x"],
173       [AS_IF([test "x$have_python" = "xyes"],
174              [PYTHON_BINARY="$(which "$PYTHON")"],
175              [PYTHON_BINARY=/usr/bin/python])])
176 AC_ARG_VAR(PYTHON_BINARY, [Python binary used to launch installed scripts])
177
178 AS_IF([test "x$have_python" != "xyes" -a "x$enable_python_devel" = "xyes"],
179       [AC_MSG_ERROR([*** python-devel support requires --with-python])])
180
181 have_python_devel=no
182 AC_ARG_ENABLE(python_devel, AS_HELP_STRING([--disable-python-devel], [Do not build python modules]))
183 AS_IF([test "x$have_python" = "xyes" -a "x$enable_python_devel" != "xno"], [
184       PKG_CHECK_MODULES([PYTHON_DEVEL], [python-${PYTHON_VERSION}],
185             [have_python_devel=yes],
186             [PKG_CHECK_MODULES([PYTHON_DEVEL], [python],
187                   [have_python_devel=yes],
188                   [have_python_devel=no])])
189       AS_IF([test "x$have_python_devel" = xno -a "x$enable_python_devel" = xyes],
190             [AC_MSG_ERROR([*** python-devel support requested but libraries not found])])
191 ])
192 AM_CONDITIONAL([HAVE_PYTHON_DEVEL], [test "$have_python_devel" = "yes"])
193
194 # ------------------------------------------------------------------------------
195
196 AC_SEARCH_LIBS([dlsym], [dl], [], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
197 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
198 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
199
200 # unconditionally pull-in librt with old glibc versions
201 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
202
203 save_LIBS="$LIBS"
204 LIBS=
205 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
206 CAP_LIBS="$LIBS"
207 AC_SUBST(CAP_LIBS)
208
209 LIBS=
210 AC_SEARCH_LIBS([mq_open], [rt], [], [AC_MSG_ERROR([*** POSIX RT library not found])])
211 RT_LIBS="$LIBS"
212 AC_SUBST(RT_LIBS)
213 LIBS="$save_LIBS"
214
215 AC_CHECK_FUNCS([fanotify_init fanotify_mark])
216 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
217 AC_CHECK_DECLS([gettid, pivot_root, name_to_handle_at], [], [], [[#include <sys/types.h>
218 #include <unistd.h>
219 #include <sys/mount.h>
220 #include <fcntl.h>]])
221
222 # This makes sure pkg.m4 is available.
223 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
224
225 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2])
226
227
228 # ------------------------------------------------------------------------------
229 have_coverage=no
230 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
231 if test "x$enable_coverage" = "xyes" ; then
232         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
233         if test "x$lcov_found" = xno ; then
234                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
235         else
236                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
237                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
238                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
239                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
240                 else
241                         have_coverage=yes
242                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
243                         -fprofile-arcs \
244                         -ftest-coverage])
245                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
246                 fi
247         fi
248 fi
249 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
250
251 # ------------------------------------------------------------------------------
252 have_kmod=no
253 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
254 if test "x$enable_kmod" != "xno"; then
255         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
256         if test "x$have_kmod" = "xyes"; then
257                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 14 ],
258                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
259                         AC_MSG_ERROR([*** kmod version >= 14 not found]))
260         fi
261         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
262                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
263         fi
264 fi
265 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
266
267 # ------------------------------------------------------------------------------
268 have_blkid=no
269 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
270 if test "x$enable_blkid" != "xno"; then
271         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.20 ],
272                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
273         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
274                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
275         fi
276 fi
277 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
278
279 # ------------------------------------------------------------------------------
280 have_ima=yes
281 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
282                 [case "${enableval}" in
283                         yes) have_ima=yes ;;
284                         no) have_ima=no ;;
285                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
286                 esac],
287                 [have_ima=yes])
288
289 if test "x${have_ima}" != xno ; then
290         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
291 fi
292
293 # ------------------------------------------------------------------------------
294 have_chkconfig=yes
295 AC_ARG_ENABLE([chkconfig], AS_HELP_STRING([--disable-chkconfig],[Disable optional chkconfig support]),
296                 [case "${enableval}" in
297                         yes) have_chkconfig=yes ;;
298                         no) have_chkconfig=no ;;
299                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-chkconfig) ;;
300                 esac],
301                 [AC_PATH_PROG(CHKCONFIG, chkconfig)
302                 if test -z "$CHKCONFIG"; then
303                         have_chkconfig=no
304                 else
305                         have_chkconfig=yes
306                 fi])
307
308 if test "x${have_chkconfig}" != xno ; then
309         AC_DEFINE(HAVE_CHKCONFIG, 1, [Define if CHKCONFIG is available])
310 fi
311
312 # ------------------------------------------------------------------------------
313 have_selinux=no
314 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
315 if test "x$enable_selinux" != "xno"; then
316         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
317                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available]) have_selinux=yes], have_selinux=no)
318         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
319                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
320         fi
321 fi
322 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
323
324 AC_ARG_WITH(debug-shell,
325         AS_HELP_STRING([--with-debug-shell=PATH],
326                 [Path to debug shell binary]),
327         [SUSHELL="$withval"],[
328         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
329
330 AC_SUBST(SUSHELL)
331
332 AC_ARG_WITH([debug-tty],
333         AS_HELP_STRING([--with-debug-tty=PATH],
334                 [Specify the tty device for debug shell]),
335         [DEBUGTTY="$withval"],
336         [DEBUGTTY=/dev/tty9])
337
338 AC_SUBST(DEBUGTTY)
339
340 # ------------------------------------------------------------------------------
341 have_xz=no
342 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
343 if test "x$enable_xz" != "xno"; then
344         PKG_CHECK_MODULES(XZ, [ liblzma ],
345                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available]) have_xz=yes], have_xz=no)
346         if test "x$have_xz" = xno -a "x$enable_xz" = xyes; then
347                 AC_MSG_ERROR([*** Xz support requested but libraries not found])
348         fi
349 fi
350 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
351
352 # ------------------------------------------------------------------------------
353 AC_ARG_ENABLE([tcpwrap],
354         AS_HELP_STRING([--disable-tcpwrap],[Disable optional TCP wrappers support]),
355                 [case "${enableval}" in
356                         yes) have_tcpwrap=yes ;;
357                         no) have_tcpwrap=no ;;
358                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-tcpwrap) ;;
359                 esac],
360                 [have_tcpwrap=auto])
361
362 if test "x${have_tcpwrap}" != xno ; then
363         ACX_LIBWRAP
364         if test "x${LIBWRAP_LIBS}" = x ; then
365                 if test "x$have_tcpwrap" = xyes ; then
366                         AC_MSG_ERROR([*** TCP wrappers support not found.])
367                 fi
368                 have_tcpwrap=no
369         else
370                 have_tcpwrap=yes
371         fi
372 else
373         LIBWRAP_LIBS=
374 fi
375 AC_SUBST(LIBWRAP_LIBS)
376
377 # ------------------------------------------------------------------------------
378 AC_ARG_ENABLE([pam],
379         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
380                 [case "${enableval}" in
381                         yes) have_pam=yes ;;
382                         no) have_pam=no ;;
383                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
384                 esac],
385                 [have_pam=auto])
386
387 if test "x${have_pam}" != xno ; then
388         AC_CHECK_HEADERS(
389                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
390                 [have_pam=yes],
391                 [if test "x$have_pam" = xyes ; then
392                         AC_MSG_ERROR([*** PAM headers not found.])
393                 fi])
394
395         AC_CHECK_LIB(
396                 [pam],
397                 [pam_syslog],
398                 [have_pam=yes],
399                 [if test "x$have_pam" = xyes ; then
400                         AC_MSG_ERROR([*** libpam not found.])
401                 fi])
402
403         if test "x$have_pam" = xyes ; then
404                 PAM_LIBS="-lpam -lpam_misc"
405                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
406         else
407                 have_pam=no
408         fi
409 else
410         PAM_LIBS=
411 fi
412 AC_SUBST(PAM_LIBS)
413 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
414
415 # ------------------------------------------------------------------------------
416 AC_ARG_ENABLE([acl],
417         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
418                 [case "${enableval}" in
419                         yes) have_acl=yes ;;
420                         no) have_acl=no ;;
421                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
422                 esac],
423                 [have_acl=auto])
424
425 if test "x${have_acl}" != xno ; then
426         AC_CHECK_HEADERS(
427                 [sys/acl.h acl/libacl.h],
428                 [have_acl=yes],
429                 [if test "x$have_acl" = xyes ; then
430                         AC_MSG_ERROR([*** ACL headers not found.])
431                 fi])
432
433         AC_CHECK_LIB(
434                 [acl],
435                 [acl_get_file],
436                 [have_acl=yes],
437                 [if test "x$have_acl" = xyes ; then
438                         AC_MSG_ERROR([*** libacl not found.])
439                 fi])
440
441         if test "x$have_acl" = xyes ; then
442                 ACL_LIBS="-lacl"
443                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
444         else
445                 have_acl=no
446         fi
447 else
448         ACL_LIBS=
449 fi
450 AC_SUBST(ACL_LIBS)
451 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
452
453 # ------------------------------------------------------------------------------
454 AC_ARG_ENABLE([xattr],
455         AS_HELP_STRING([--disable-xattr],[Disable optional XATTR support]),
456                 [case "${enableval}" in
457                         yes) have_xattr=yes ;;
458                         no) have_xattr=no ;;
459                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-xattr) ;;
460                 esac],
461                 [have_xattr=auto])
462
463 if test "x${have_xattr}" != xno ; then
464         AC_CHECK_HEADERS(
465                 [attr/xattr.h],
466                 [have_xattr=yes],
467                 [if test "x$have_xattr" = xyes ; then
468                         AC_MSG_ERROR([*** XATTR headers not found.])
469                 fi])
470
471         AC_CHECK_LIB(
472                 [attr],
473                 [fsetxattr],
474                 [have_xattr=yes],
475                 [if test "x$have_xattr" = xyes ; then
476                         AC_MSG_ERROR([*** libattr not found.])
477                 fi])
478
479         if test "x$have_xattr" = xyes ; then
480                 XATTR_LIBS="-lattr"
481                 AC_DEFINE(HAVE_XATTR, 1, [XATTR available])
482         else
483                 have_xattr=no
484         fi
485 else
486         XATTR_LIBS=
487 fi
488 AC_SUBST(XATTR_LIBS)
489 AM_CONDITIONAL([HAVE_XATTR], [test "x$have_xattr" != xno])
490
491 # ------------------------------------------------------------------------------
492 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
493                 [case "${enableval}" in
494                         yes) have_smack=yes ;;
495                         no) have_smack=no ;;
496                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
497                 esac],
498                 [have_smack=auto])
499
500 if test "x${have_xattr}" = xno; then
501         if test "x${have_smack}" = xyes; then
502                 AC_MSG_ERROR(SMACK requires xattr support)
503         else
504                 have_smack=no
505         fi
506 else
507         if test "x${have_smack}" = xauto; then
508                 have_smack=yes
509         fi
510 fi
511
512 if test "x${have_smack}" = xyes ; then
513         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
514 fi
515
516 # ------------------------------------------------------------------------------
517 AC_ARG_ENABLE([gcrypt],
518         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
519                 [case "${enableval}" in
520                         yes) have_gcrypt=yes ;;
521                         no) have_gcrypt=no ;;
522                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
523                 esac],
524                 [have_gcrypt=auto])
525
526 if test "x${have_gcrypt}" != xno ; then
527         AM_PATH_LIBGCRYPT(
528                 [1.4.5],
529                 [have_gcrypt=yes],
530                 [if test "x$have_gcrypt" = xyes ; then
531                         AC_MSG_ERROR([*** GCRYPT headers not found.])
532                 fi])
533
534         if test "x$have_gcrypt" = xyes ; then
535                 GCRYPT_LIBS="$LIBGCRYPT_LIBS"
536                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS"
537                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
538         else
539                 have_gcrypt=no
540         fi
541 else
542         GCRYPT_LIBS=
543         GCRYPT_CFLAGS=
544 fi
545 AC_SUBST(GCRYPT_LIBS)
546 AC_SUBST(GCRYPT_CFLAGS)
547 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
548
549 # ------------------------------------------------------------------------------
550 AC_ARG_ENABLE([audit],
551         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
552                 [case "${enableval}" in
553                         yes) have_audit=yes ;;
554                         no) have_audit=no ;;
555                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
556                 esac],
557                 [have_audit=auto])
558
559 if test "x${have_audit}" != xno ; then
560         AC_CHECK_HEADERS(
561                 [libaudit.h],
562                 [have_audit=yes],
563                 [if test "x$have_audit" = xyes ; then
564                         AC_MSG_ERROR([*** AUDIT headers not found.])
565                 fi])
566
567         AC_CHECK_LIB(
568                 [audit],
569                 [audit_open],
570                 [have_audit=yes],
571                 [if test "x$have_audit" = xyes ; then
572                         AC_MSG_ERROR([*** libaudit not found.])
573                 fi])
574
575         if test "x$have_audit" = xyes ; then
576                 AUDIT_LIBS="-laudit"
577                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
578         else
579                 have_audit=no
580         fi
581 else
582         AUDIT_LIBS=
583 fi
584 AC_SUBST(AUDIT_LIBS)
585
586 # ------------------------------------------------------------------------------
587 have_libcryptsetup=no
588 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
589 if test "x$enable_libcryptsetup" != "xno"; then
590         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
591                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
592         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
593                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
594         fi
595 fi
596 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
597
598 # ------------------------------------------------------------------------------
599 have_qrencode=no
600 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
601 if test "x$enable_qrencode" != "xno"; then
602         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
603                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
604         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
605                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
606         fi
607 fi
608 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
609
610 # ------------------------------------------------------------------------------
611 have_microhttpd=no
612 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
613 if test "x$enable_microhttpd" != "xno"; then
614         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.5],
615                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available]) have_microhttpd=yes], have_microhttpd=no)
616         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
617                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
618         fi
619 fi
620 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
621
622 # ------------------------------------------------------------------------------
623 have_binfmt=no
624 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
625 if test "x$enable_binfmt" != "xno"; then
626         have_binfmt=yes
627 fi
628 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
629
630 # ------------------------------------------------------------------------------
631 have_vconsole=no
632 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
633 if test "x$enable_vconsole" != "xno"; then
634         have_vconsole=yes
635 fi
636 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
637
638 # ------------------------------------------------------------------------------
639 have_readahead=no
640 AC_ARG_ENABLE(readahead, AS_HELP_STRING([--disable-readahead], [disable readahead tools]))
641 if test "x$enable_readahead" != "xno"; then
642         have_readahead=yes
643 fi
644 AM_CONDITIONAL(ENABLE_READAHEAD, [test "$have_readahead" = "yes"])
645
646 # ------------------------------------------------------------------------------
647 have_bootchart=no
648 AC_ARG_ENABLE(bootchart, AS_HELP_STRING([--disable-bootchart], [disable bootchart tool]))
649 if test "x$enable_bootchart" != "xno"; then
650         have_bootchart=yes
651 fi
652 AM_CONDITIONAL(ENABLE_BOOTCHART, [test "$have_bootchart" = "yes"])
653
654 # ------------------------------------------------------------------------------
655 have_quotacheck=no
656 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
657 if test "x$enable_quotacheck" != "xno"; then
658         have_quotacheck=yes
659 fi
660 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
661
662 # ------------------------------------------------------------------------------
663 have_tmpfiles=no
664 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
665 if test "x$enable_tmpfiles" != "xno"; then
666         have_tmpfiles=yes
667 fi
668 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
669
670 # ------------------------------------------------------------------------------
671 have_randomseed=no
672 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
673 if test "x$enable_randomseed" != "xno"; then
674         have_randomseed=yes
675 fi
676 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
677
678 # ------------------------------------------------------------------------------
679 have_backlight=no
680 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
681 if test "x$enable_backlight" != "xno"; then
682         have_backlight=yes
683 fi
684 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
685
686 # ------------------------------------------------------------------------------
687 have_logind=no
688 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
689 if test "x$enable_logind" != "xno"; then
690         have_logind=yes
691 fi
692 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
693 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
694
695 # ------------------------------------------------------------------------------
696 have_machined=no
697 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
698 if test "x$enable_machined" != "xno"; then
699         have_machined=yes
700 fi
701 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
702 AS_IF([test "$have_machined" = "yes"], [ AC_DEFINE(HAVE_MACHINED, [1], [Machined support available]) ])
703
704 # ------------------------------------------------------------------------------
705 have_hostnamed=no
706 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
707 if test "x$enable_hostnamed" != "xno"; then
708         have_hostnamed=yes
709 fi
710 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
711
712 # ------------------------------------------------------------------------------
713 have_timedated=no
714 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
715 if test "x$enable_timedated" != "xno"; then
716         have_timedated=yes
717 fi
718 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
719
720 # ------------------------------------------------------------------------------
721 have_localed=no
722 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
723 if test "x$enable_localed" != "xno"; then
724         have_localed=yes
725 fi
726 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
727
728 # ------------------------------------------------------------------------------
729 have_coredump=no
730 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
731 if test "x$enable_coredump" != "xno"; then
732         have_coredump=yes
733 fi
734 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
735
736 # ------------------------------------------------------------------------------
737 have_polkit=no
738 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
739 if test "x$enable_polkit" != "xno"; then
740         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
741         have_polkit=yes
742 fi
743 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
744
745 # ------------------------------------------------------------------------------
746 have_efi=no
747 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
748 if test "x$enable_efi" != "xno"; then
749         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
750         have_efi=yes
751 fi
752 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
753
754 # ------------------------------------------------------------------------------
755 AC_ARG_WITH(rc-local-script-path-start,
756         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
757                 [Path to /etc/rc.local]),
758         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
759         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
760
761 AC_ARG_WITH(rc-local-script-path-stop,
762         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
763                 [Path to /usr/sbin/halt.local]),
764         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
765         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
766
767 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
768 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
769
770 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
771 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
772
773 # ------------------------------------------------------------------------------
774 AC_ARG_WITH(kbd-loadkeys,
775         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
776                 [Path to loadkeys]),
777         [KBD_LOADKEYS="$withval"],
778         [KBD_LOADKEYS="/usr/bin/loadkeys"])
779
780 AC_ARG_WITH(kbd-setfont,
781         AS_HELP_STRING([--with-kbd-setfont=PATH],
782                 [Path to setfont]),
783         [KBD_SETFONT="$withval"],
784         [KBD_SETFONT="/usr/bin/setfont"])
785
786 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
787 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
788
789 AC_SUBST(KBD_LOADKEYS)
790 AC_SUBST(KBD_SETFONT)
791
792 AC_ARG_WITH(telinit,
793         AS_HELP_STRING([--with-telinit=PATH],
794                 [Path to telinit]),
795         [TELINIT="$withval"],
796         [TELINIT="/lib/upstart/telinit"])
797
798 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
799
800 AC_SUBST(TELINIT)
801
802 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h])
803
804 # ------------------------------------------------------------------------------
805 have_myhostname=no
806 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
807 if test "x$enable_myhostname" != "xno"; then
808         AC_HEADER_STDC
809         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h])
810
811         AC_C_CONST
812         AC_TYPE_SIZE_T
813         AC_HEADER_TIME
814
815         AC_FUNC_MALLOC
816         AC_FUNC_SELECT_ARGTYPES
817         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
818
819         have_myhostname=yes
820 fi
821 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
822
823 # ------------------------------------------------------------------------------
824 AC_ARG_WITH(firmware-path,
825        AS_HELP_STRING([--with-firmware-path=DIR[[[:DIR[...]]]]],
826           [Firmware search path (default="")]),
827        [], [with_firmware_path=""])
828 OLD_IFS=$IFS
829 IFS=:
830 for i in $with_firmware_path; do
831        if test "x${FIRMWARE_PATH}" = "x"; then
832               FIRMWARE_PATH="\\\"${i}/\\\""
833        else
834               FIRMWARE_PATH="${FIRMWARE_PATH}, \\\"${i}/\\\""
835        fi
836 done
837 IFS=$OLD_IFS
838 AC_SUBST(FIRMWARE_PATH)
839 AS_IF([test "x${FIRMWARE_PATH}" != "x"], [ AC_DEFINE(HAVE_FIRMWARE, 1, [Define if FIRMWARE is available]) ])
840 AM_CONDITIONAL(ENABLE_FIRMWARE, [test "x${FIRMWARE_PATH}" != "x"])
841
842 # ------------------------------------------------------------------------------
843 AC_ARG_ENABLE([gudev],
844        AS_HELP_STRING([--disable-gudev], [disable Gobject libudev support @<:@default=enabled@:>@]),
845        [], [enable_gudev=yes])
846 AS_IF([test "x$enable_gudev" = "xyes"], [ PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.22.0 gobject-2.0 >= 2.22.0 gio-2.0]) ])
847 AM_CONDITIONAL([ENABLE_GUDEV], [test "x$enable_gudev" = "xyes"])
848 AS_IF([test "x$enable_gudev" = "xyes"], [ AC_DEFINE(HAVE_GLIB, 1, [Define if glib is available]) ])
849
850 # ------------------------------------------------------------------------------
851 have_manpages=no
852 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
853 AS_IF([test "x$enable_manpages" != xno], [
854         AS_IF([test "x$enable_manpages" = xyes -a "x$XSLTPROC" = x], [
855                 AC_MSG_ERROR([*** Manpages requested but xsltproc not found])
856         ])
857         AS_IF([test "x$XSLTPROC" != x], [have_manpages=yes])
858 ])
859 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
860
861 # ------------------------------------------------------------------------------
862
863 # Location of the init scripts as mandated by LSB
864 SYSTEM_SYSVINIT_PATH=/etc/init.d
865 SYSTEM_SYSVRCND_PATH=/etc/rc.d
866 M4_DEFINES=
867
868 AC_ARG_WITH([sysvinit-path],
869         [AS_HELP_STRING([--with-sysvinit-path=PATH],
870                 [Specify the path to where the SysV init scripts are located])],
871         [SYSTEM_SYSVINIT_PATH="$withval"],
872         [])
873
874 AC_ARG_WITH([sysvrcnd-path],
875         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
876                 [Specify the path to the base directory for the SysV rcN.d directories])],
877         [SYSTEM_SYSVRCND_PATH="$withval"],
878         [])
879
880 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
881         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
882         SYSTEM_SYSV_COMPAT="yes"
883         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
884 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
885         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
886 else
887         SYSTEM_SYSV_COMPAT="no"
888 fi
889
890 AC_SUBST(SYSTEM_SYSVINIT_PATH)
891 AC_SUBST(SYSTEM_SYSVRCND_PATH)
892 AC_SUBST(M4_DEFINES)
893
894 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
895
896 AC_ARG_WITH([tty-gid],
897         [AS_HELP_STRING([--with-tty-gid=GID],
898                 [Specify the numeric GID of the 'tty' group])],
899         [AC_DEFINE_UNQUOTED(TTY_GID, [$withval], [GID of the 'tty' group])],
900         [])
901
902 AC_ARG_WITH([dbuspolicydir],
903         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
904         [],
905         [with_dbuspolicydir=$($PKG_CONFIG --variable=sysconfdir dbus-1)/dbus-1/system.d])
906
907 AC_ARG_WITH([dbussessionservicedir],
908         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
909         [],
910         [with_dbussessionservicedir=$($PKG_CONFIG --variable=session_bus_services_dir dbus-1)])
911
912 AC_ARG_WITH([dbussystemservicedir],
913         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
914         [],
915         [with_dbussystemservicedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../system-services)])
916
917 AC_ARG_WITH([dbusinterfacedir],
918         AS_HELP_STRING([--with-dbusinterfacedir=DIR], [D-Bus interface directory]),
919         [],
920         [with_dbusinterfacedir=$(readlink -m $($PKG_CONFIG --variable=session_bus_services_dir dbus-1)/../interfaces)])
921
922 AC_ARG_WITH([bashcompletiondir],
923         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
924         [],
925         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
926                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
927         ] , [
928                 with_bashcompletiondir=${datadir}/bash-completion/completions
929         ])])
930
931 AC_ARG_WITH([zshcompletiondir],
932         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
933         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
934
935 AC_ARG_WITH([rootprefix],
936         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
937         [], [with_rootprefix=${ac_default_prefix}])
938
939 AC_ARG_WITH([rootlibdir],
940         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
941         [],
942         [with_rootlibdir=${libdir}])
943
944 AC_ARG_WITH([pamlibdir],
945         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
946         [],
947         [with_pamlibdir=${with_rootlibdir}/security])
948
949 AC_ARG_WITH([pamconfdir],
950         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
951         [],
952         [with_pamconfdir=${sysconfdir}/pam.d])
953
954 AC_ARG_ENABLE([split-usr],
955         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
956         [],
957         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
958                 enable_split_usr=yes
959         ], [
960                 enable_split_usr=no
961         ])])
962
963 AS_IF([test "x${enable_split_usr}" = "xyes"], [
964         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
965 ])
966
967 # Work around intltoolize and gtk-doc problems in VPATH builds
968 AM_CONDITIONAL([ENABLE_GTK_DOC_TESTS], [test "x$0" = "x./configure"],
969                                        [Define to do gtk-doc tests])
970 AS_IF([test "x$0" != "x./configure"], [
971         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
972 ])
973
974 AC_ARG_ENABLE(tests,
975        [AC_HELP_STRING([--disable-tests], [disable tests])],
976        enable_tests=$enableval, enable_tests=yes)
977 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes])
978
979 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
980 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
981 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
982 AC_SUBST([dbusinterfacedir], [$with_dbusinterfacedir])
983 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
984 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
985 AC_SUBST([pamlibdir], [$with_pamlibdir])
986 AC_SUBST([pamconfdir], [$with_pamconfdir])
987 AC_SUBST([rootprefix], [$with_rootprefix])
988 AC_SUBST([rootlibdir], [$with_rootlibdir])
989
990 AC_CONFIG_FILES([
991         Makefile po/Makefile.in
992         docs/libudev/Makefile
993         docs/libudev/version.xml
994         docs/gudev/Makefile
995         docs/gudev/version.xml
996 ])
997
998 AC_OUTPUT
999 AC_MSG_RESULT([
1000         $PACKAGE_NAME $VERSION
1001
1002         libcryptsetup:           ${have_libcryptsetup}
1003         tcpwrap:                 ${have_tcpwrap}
1004         PAM:                     ${have_pam}
1005         AUDIT:                   ${have_audit}
1006         IMA:                     ${have_ima}
1007         SELinux:                 ${have_selinux}
1008         SMACK:                   ${have_smack}
1009         XZ:                      ${have_xz}
1010         ACL:                     ${have_acl}
1011         XATTR:                   ${have_xattr}
1012         GCRYPT:                  ${have_gcrypt}
1013         QRENCODE:                ${have_qrencode}
1014         MICROHTTPD:              ${have_microhttpd}
1015         CHKCONFIG:               ${have_chkconfig}
1016         binfmt:                  ${have_binfmt}
1017         vconsole:                ${have_vconsole}
1018         readahead:               ${have_readahead}
1019         bootchart:               ${have_bootchart}
1020         quotacheck:              ${have_quotacheck}
1021         tmpfiles:                ${have_tmpfiles}
1022         randomseed:              ${have_randomseed}
1023         backlight:               ${have_backlight}
1024         logind:                  ${have_logind}
1025         machined:                ${have_machined}
1026         hostnamed:               ${have_hostnamed}
1027         timedated:               ${have_timedated}
1028         localed:                 ${have_localed}
1029         coredump:                ${have_coredump}
1030         polkit:                  ${have_polkit}
1031         efi:                     ${have_efi}
1032         kmod:                    ${have_kmod}
1033         blkid:                   ${have_blkid}
1034         nss-myhostname:          ${have_myhostname}
1035         gudev:                   ${enable_gudev}
1036         gintrospection:          ${enable_introspection}
1037         Python:                  ${have_python}
1038         Python Headers:          ${have_python_devel}
1039         man pages:               ${have_manpages}
1040         gtk-doc:                 ${enable_gtk_doc}
1041         test coverage:           ${have_coverage}
1042         Split /usr:              ${enable_split_usr}
1043         SysV compatibility:      ${SYSTEM_SYSV_COMPAT}
1044
1045         prefix:                  ${prefix}
1046         rootprefix:              ${with_rootprefix}
1047         sysconf dir:             ${sysconfdir}
1048         datarootdir:             ${datarootdir}
1049         includedir:              ${includedir}
1050         include_prefix:          ${INCLUDE_PREFIX}
1051         lib dir:                 ${libdir}
1052         rootlib dir:             ${with_rootlibdir}
1053         SysV init scripts:       ${SYSTEM_SYSVINIT_PATH}
1054         SysV rc?.d directories:  ${SYSTEM_SYSVRCND_PATH}
1055         Build Python:            ${PYTHON}
1056         Installation Python:     ${PYTHON_BINARY}
1057         firmware path:           ${FIRMWARE_PATH}
1058         PAM modules dir:         ${with_pamlibdir}
1059         PAM configuration dir:   ${with_pamconfdir}
1060         D-Bus policy dir:        ${with_dbuspolicydir}
1061         D-Bus session dir:       ${with_dbussessionservicedir}
1062         D-Bus system dir:        ${with_dbussystemservicedir}
1063         D-Bus interfaces dir:    ${with_dbusinterfacedir}
1064         Bash completions dir:    ${with_bashcompletiondir}
1065         Zsh completions dir:     ${with_zshcompletiondir}
1066         Extra start script:      ${RC_LOCAL_SCRIPT_PATH_START}
1067         Extra stop script:       ${RC_LOCAL_SCRIPT_PATH_STOP}
1068         Debug shell:             ${SUSHELL} @ ${DEBUGTTY}
1069
1070         CFLAGS:                  ${OUR_CFLAGS} ${CFLAGS}
1071         CPPFLAGS:                ${OUR_CPPFLAGS} ${CPPFLAGS}
1072         LDFLAGS:                 ${OUR_LDFLAGS} ${LDFLAGS}
1073         PYTHON_CFLAGS:           ${PYTHON_DEVEL_CFLAGS}
1074         PYTHON_LIBS:             ${PYTHON_DEVEL_LIBS}
1075 ])