configure.ac

   1 AC_INIT([udev],
   2         [142],
   3         [linux-hotplug@vger.kernel.org])
   4 AC_PREREQ(2.60)
   5 AM_INIT_AUTOMAKE([check-news foreign 1.9 dist-bzip2])
   6 AC_DISABLE_STATIC
   7 AC_USE_SYSTEM_EXTENSIONS
   8 AC_SYS_LARGEFILE
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AC_PROG_LIBTOOL
  11
  12 dnl /* prefix is /usr, exec_prefix is /, if overridden exec_prefix follows prefix */
  13 AC_PREFIX_DEFAULT([/usr])
  14 test "$prefix" = NONE && test "$exec_prefix" = NONE && exec_prefix=
  15
  16 dnl /* libudev version */
  17 LIBUDEV_LT_CURRENT=3
  18 LIBUDEV_LT_REVISION=0
  19 LIBUDEV_LT_AGE=3
  20 AC_SUBST(LIBUDEV_LT_CURRENT)
  21 AC_SUBST(LIBUDEV_LT_REVISION)
  22 AC_SUBST(LIBUDEV_LT_AGE)
  23
  24 AC_PATH_PROG([XSLTPROC], [xsltproc])
  25
  26 AC_CHECK_LIB(c, inotify_init,
  27         [AC_DEFINE([HAVE_INOTIFY], 1, [inotify available])],
  28         [AC_MSG_WARN([inotify support disabled])])
  29
  30 AC_ARG_WITH(udev-prefix,
  31         AS_HELP_STRING([--with-udev-prefix=DIR], [add prefix to internal udev path names]),
  32         [], [with_udev_prefix='${exec_prefix}'])
  33 udev_prefix=$with_udev_prefix
  34 AC_SUBST(udev_prefix)
  35
  36 AC_ARG_WITH(libdir-name,
  37         AS_HELP_STRING([--with-libdir-name=DIR], [name of the arch lib directory]),
  38         [], [with_libdir_name=lib])
  39 libdir_name=$with_libdir_name
  40 AC_SUBST(libdir_name)
  41
  42 AC_ARG_WITH(selinux,
  43         AS_HELP_STRING([--with-selinux], [compile with SELinux support]),
  44         [], with_selinux=no)
  45 if test "x$with_selinux" = xyes; then
  46         LIBS_save=$LIBS
  47         AC_CHECK_LIB(selinux, getprevcon,
  48                 [],
  49                 AC_MSG_ERROR([SELinux selected but libselinux not found]))
  50         LIBS=$LIBS_save
  51         AC_DEFINE(USE_SELINUX, [1] ,[compile with SELinux support])
  52         SELINUX_LIBS="-lselinux -lsepol"
  53 fi
  54 AC_SUBST([SELINUX_LIBS])
  55 AM_CONDITIONAL(USE_SELINUX, [test "x$with_selinux" = xyes], [compile with SELinux support])
  56
  57 AC_ARG_ENABLE(debug,
  58         AS_HELP_STRING([--enable-debug], [turn on debugging]),
  59         [], enable_debug=no)
  60 if test "x$enable_debug" = "xyes"; then
  61         AC_DEFINE(DEBUG, [1] ,[Compile in debug messages])
  62         DEBUG_CFLAGS="-DDEBUG"
  63 fi
  64 AC_SUBST(DEBUG_CFLAGS)
  65
  66 AC_ARG_ENABLE(logging,
  67         AS_HELP_STRING([--disable-logging], [turn off logging/syslog]),
  68         [], enable_logging=yes)
  69 if test "x$enable_logging" != "xno"; then
  70         AC_DEFINE(USE_LOG, [1] ,[Use logging/syslog])
  71 fi
  72
  73 AC_CONFIG_HEADERS(config.h)
  74 AC_CONFIG_FILES([
  75         Makefile
  76         udev/Makefile
  77         udev/lib/Makefile
  78         udev/lib/libudev.pc
  79         rules/Makefile
  80         extras/Makefile
  81         extras/ata_id/Makefile
  82         extras/cdrom_id/Makefile
  83         extras/edd_id/Makefile
  84         extras/path_id/Makefile
  85         extras/firmware/Makefile
  86         extras/collect/Makefile
  87         extras/floppy/Makefile
  88         extras/fstab_import/Makefile
  89         extras/rule_generator/Makefile
  90         extras/scsi_id/Makefile
  91         extras/usb_id/Makefile
  92 ])
  93
  94 AC_OUTPUT
  95 AC_MSG_RESULT([
  96         udev $VERSION
  97         ========
  98
  99         prefix:                 ${prefix}
 100         exec_prefix:            ${exec_prefix}
 101         udev_prefix:            ${udev_prefix}
 102         libdir_name:            ${libdir_name}
 103         datarootdir:            ${datarootdir}
 104         mandir:                 ${mandir}
 105         includedir:             ${includedir}
 106
 107         logging:                ${enable_logging}
 108         debug:                  ${enable_debug}
 109         selinux:                ${with_selinux}
 110
 111         compiler:               ${CC}
 112         cflags:                 ${CFLAGS}
 113         ldflags:                ${LDFLAGS}
 114
 115         xsltproc:               ${XSLTPROC}
 116 ])