infra/dgit-repos-server

   1 #!/usr/bin/perl -w
   2 # dgit-repos-server
   3 #
   4 # usages:
   5 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --ssh
   6 #   dgit-repos-server DISTRO DISTRO-DIR AUTH-SPEC [<settings>] --cron
   7 # settings
   8 #   --repos=GIT-REPOS-DIR      default DISTRO-DIR/repos/
   9 #   --suites=SUITES-FILE       default DISTRO-DIR/suites
  10 #   --policy-hook=POLICY-HOOK  default DISTRO-DIR/policy-hook
  11 #   --dgit-live=DGIT-LIVE-DIR  default DISTRO-DIR/dgit-live
  12 # (DISTRO-DIR is not used other than as default and to pass to policy hook)
  13 # internal usage:
  14 #  .../dgit-repos-server --pre-receive-hook PACKAGE
  15 #
  16 # Invoked as the ssh restricted command
  17 #
  18 # Works like git-receive-pack
  19 #
  20 # SUITES is the name of a file which lists the permissible suites
  21 # one per line (#-comments and blank lines ignored)
  22 #
  23 # AUTH-SPEC is a :-separated list of
  24 #   KEYRING.GPG,AUTH-SPEC
  25 # where AUTH-SPEC is one of
  26 #   a
  27 #   mDM.TXT
  28 # (With --cron AUTH-SPEC is not used and may be the empty string.)
  29
  30 use strict;
  31 $SIG{__WARN__} = sub { die $_[0]; };
  32
  33 # DGIT-REPOS-DIR contains:
  34 # git tree (or other object)      lock (in acquisition order, outer first)
  35 #
  36 #  _tmp/PACKAGE_prospective       ! } SAME.lock, held during receive-pack
  37 #
  38 #  _tmp/PACKAGE_incoming$$        ! } SAME.lock, held during receive-pack
  39 #  _tmp/PACKAGE_incoming$$_fresh  ! }
  40 #
  41 #  PACKAGE.git                      } PACKAGE.git.lock
  42 #  PACKAGE_garbage                  }   (also covers executions of
  43 #  PACKAGE_garbage-old              }    policy hook script for PACKAGE)
  44 #  PACKAGE_garbage-tmp              }
  45 #  policy*                          } (for policy hook script, covered by
  46 #                                   }  lock only when invoked for a package)
  47 #
  48 # leaf locks, held during brief operaton only:
  49 #
  50 #  _empty                           } SAME.lock
  51 #  _empty.new                       }
  52 #
  53 #  _template                        } SAME.lock
  54 #
  55 # locks marked ! may be held during client data transfer
  56
  57 # What we do on push is this:
  58 #  - extract the destination repo name
  59 #  - make a hardlink clone of the destination repo
  60 #  - provide the destination with a stunt pre-receive hook
  61 #  - run actual git-receive-pack with that new destination
  62 #   as a result of this the stunt pre-receive hook runs; it does this:
  63 #    + understand what refs we are allegedly updating and
  64 #      check some correspondences:
  65 #        * we are updating only refs/tags/DISTRO/* and refs/dgit/*
  66 #        * and only one of each
  67 #        * and the tag does not already exist
  68 #      and
  69 #        * recover the suite name from the destination refs/dgit/ ref
  70 #    + disassemble the signed tag into its various fields and signature
  71 #      including:
  72 #        * parsing the first line of the tag message to recover
  73 #          the package name, version and suite
  74 #        * checking that the package name corresponds to the dest repo name
  75 #        * checking that the suite name is as recovered above
  76 #    + verify the signature on the signed tag
  77 #      and if necessary check that the keyid and package are listed in dm.txt
  78 #    + check various correspondences:
  79 #        * the signed tag must refer to a commit
  80 #        * the signed tag commit must be the refs/dgit value
  81 #        * the name in the signed tag must correspond to its ref name
  82 #        * the tag name must be debian/<version> (massaged as needed)
  83 #        * the suite is one of those permitted
  84 #        * the signed tag has a suitable name
  85 #        * run the "push" policy hook
  86 #        * replay prevention for --deliberately-not-fast-forward
  87 #        * check the commit is a fast forward
  88 #        * handle a request from the policy hook for a fresh repo
  89 #    + push the signed tag and new dgit branch to the actual repo
  90 #
  91 # If the destination repo does not already exist, we need to make
  92 # sure that we create it reasonably atomically, and also that
  93 # we don't every have a destination repo containing no refs at all
  94 # (because such a thing causes git-fetch-pack to barf).  So then we
  95 # do as above, except:
  96 #  - before starting, we take out our own lock for the destination repo
  97 #  - we create a prospective new destination repo by making a copy
  98 #    of _template
  99 #  - we use the prospective new destination repo instead of the
 100 #    actual new destination repo (since the latter doesn't exist)
 101 #  - after git-receive-pack exits, we
 102 #    + check that the prospective repo contains a tag and head
 103 #    + rename the prospective destination repo into place
 104 #
 105 # Cleanup strategy:
 106 #  - We are crash-only
 107 #  - Temporary working trees and their locks are cleaned up
 108 #    opportunistically by a program which tries to take each lock and
 109 #    if successful deletes both the tree and the lockfile
 110 #  - Prospective working trees and their locks are cleaned up by
 111 #    a program which tries to take each lock and if successful
 112 #    deletes any prospective working tree and the lock (but not
 113 #    of course any actual tree)
 114 #  - It is forbidden to _remove_ the lockfile without removing
 115 #    the corresponding temporary tree, as the lockfile is also
 116 #    a stampfile whose presence indicates that there may be
 117 #    cleanup to do
 118 #
 119 # Policy hook script is invoked like this:
 120 #   POLICY-HOOK-SCRIPT DISTRO DGIT-REPOS-DIR DGIT-LIVE-DIR DISTRO-DIR ACTION...
 121 # ie.
 122 #   POLICY-HOOK-SCRIPT ... check-list [...]
 123 #   POLICY-HOOK-SCRIPT ... check-package PACKAGE [...]
 124 #   POLICY-HOOK-SCRIPT ... push PACKAGE \
 125 #         VERSION SUITE TAGNAME DELIBERATELIES [...]
 126 #   POLICY-HOOK-SCRIPT ... push-confirm PACKAGE \
 127 #         VERSION SUITE TAGNAME DELIBERATELIES FRESH-REPO|'' [...]
 128 #
 129 # DELIBERATELIES is like this: --deliberately-foo,--deliberately-bar,...
 130 #
 131 # Exit status is a bitmask.  Bit weight constants are defined in Dgit.pm.
 132 #    NOFFCHECK   (2)
 133 #         suppress dgit-repos-server's fast-forward check ("push" only)
 134 #    FRESHREPO   (4)
 135 #         blow away repo right away (ie, as if before push or fetch)
 136 #         ("check-package" and "push" only)
 137 # any unexpected bits mean failure, and then known set bits are ignored
 138 # if no unexpected bits set, operation continues (subject to meaning
 139 # of any expected bits set).  So, eg, exit 0 means "continue normally"
 140 # and would be appropriate for an unknown action.
 141 #
 142 # cwd for push and push-confirm is a temporary repo where the incoming
 143 # objects have been received; TAGNAME is the version-based tag.
 144 #
 145 # FRESH-REPO is '' iff the repo for this package already existed, or
 146 # the pathname of the newly-created repo which will be renamed into
 147 # place if everything goes well.  (NB that this is generally not the
 148 # same repo as the cwd, because the objects are first received into a
 149 # temporary repo so they can be examined.)  In this case FRESH-REPO
 150 # contains exactly the objects and refs that will appear in the
 151 # destination if push-confirm approves.
 152 #
 153 # if push requested FRESHREPO, push-confirm happens in the old working
 154 # repo and FRESH-REPO is guaranteed not to be ''.
 155 #
 156 # policy hook for a particular package will be invoked only once at
 157 # a time - (see comments about DGIT-REPOS-DIR, above)
 158 #
 159 # check-list and check-package are invoked via the --cron option.
 160 # First, without any locking, check-list is called.  It should produce
 161 # a list of package names (one per line).  Then check-package will be
 162 # invoked for each named package, in each case after taking an
 163 # appropriate lock.
 164 #
 165 # If policy hook wants to run dgit (or something else in the dgit
 166 # package), it should use DGIT-LIVE-DIR/dgit (etc.), or if that is
 167 # ENOENT, use the installed version.
 168
 169
 170 use POSIX;
 171 use Fcntl qw(:flock);
 172 use File::Path qw(rmtree);
 173 use File::Temp qw(tempfile);
 174
 175 use Debian::Dgit qw(:DEFAULT :policyflags);
 176
 177 initdebug('');
 178
 179 our $func;
 180 our $dgitrepos;
 181 our $package;
 182 our $distro;
 183 our $suitesfile;
 184 our $policyhook;
 185 our $dgitlive;
 186 our $distrodir;
 187 our $destrepo;
 188 our $workrepo;
 189 our $keyrings;
 190 our @lockfhs;
 191
 192 our @deliberatelies;
 193 our %previously;
 194 our $policy;
 195 our @policy_args;
 196
 197 #----- utilities -----
 198
 199 sub realdestrepo () { "$dgitrepos/$package.git"; }
 200
 201 sub acquirelock ($$) {
 202     my ($lock, $must) = @_;
 203     my $fh;
 204     printdebug sprintf "locking %s %d\n", $lock, $must;
 205     for (;;) {
 206         close $fh if $fh;
 207         $fh = new IO::File $lock, ">" or die "open $lock: $!";
 208         my $ok = flock $fh, $must ? LOCK_EX : (LOCK_EX|LOCK_NB);
 209         if (!$ok) {
 210             die "flock $lock: $!" if $must;
 211             printdebug " locking $lock failed\n";
 212             return undef;
 213         }
 214         next unless stat_exists $lock;
 215         my $want = (stat _)[1];
 216         stat $fh or die $!;
 217         my $got = (stat _)[1];
 218         last if $got == $want;
 219     }
 220     return $fh;
 221 }
 222
 223 sub acquirermtree ($$) {
 224     my ($tree, $must) = @_;
 225     my $fh = acquirelock("$tree.lock", $must);
 226     if ($fh) {
 227         push @lockfhs, $fh;
 228         rmtree $tree;
 229     }
 230     return $fh;
 231 }
 232
 233 sub locksometree ($) {
 234     my ($tree) = @_;
 235     acquirelock("$tree.lock", 1);
 236 }
 237
 238 sub lockrealtree () {
 239     locksometree(realdestrepo);
 240 }
 241
 242 sub mkrepotmp () { ensuredir "$dgitrepos/_tmp" };
 243
 244 sub removedtagsfile () { "$dgitrepos/_removed-tags/$package"; }
 245
 246 sub recorderror ($) {
 247     my ($why) = @_;
 248     my $w = $ENV{'DGIT_DRS_WORK'}; # we are in stunthook
 249     if (defined $w) {
 250         chomp $why;
 251         open ERR, ">", "$w/drs-error" or die $!;
 252         print ERR $why, "\n" or die $!;
 253         close ERR or die $!;
 254         return 1;
 255     }
 256     return 0;
 257 }
 258
 259 sub reject ($) {
 260     my ($why) = @_;
 261     recorderror "reject: $why";
 262     die "dgit-repos-server: reject: $why\n";
 263 }
 264
 265 sub runcmd {
 266     debugcmd '+',@_;
 267     $!=0; $?=0;
 268     my $r = system @_;
 269     die (shellquote @_)." $? $!" if $r;
 270 }
 271
 272 sub policyhook {
 273     my ($policyallowbits, @polargs) = @_;
 274     # => ($exitstatuspolicybitmap);
 275     die if $policyallowbits & ~0x3e;
 276     my @cmd = ($policyhook,$distro,$dgitrepos,$dgitlive,$distrodir,@polargs);
 277     debugcmd '+',@cmd;
 278     my $r = system @cmd;
 279     die "system: $!" if $r < 0;
 280     die "dgit-repos-server: policy hook failed (or rejected) ($?)\n"
 281         if $r & ~($policyallowbits << 8);
 282     printdebug sprintf "hook => %#x\n", $r;
 283     return $r >> 8;
 284 }
 285
 286 sub mkemptyrepo ($$) {
 287     my ($dir,$sharedperm) = @_;
 288     runcmd qw(git init --bare --quiet), "--shared=$sharedperm", $dir;
 289 }
 290
 291 sub mkrepo_fromtemplate ($) {
 292     my ($dir) = @_;
 293     my $template = "$dgitrepos/_template";
 294     my $templatelock = locksometree($template);
 295     printdebug "copy template $template -> $dir\n";
 296     my $r = system qw(cp -a --), $template, $dir;
 297     !$r or die "create new repo $dir failed: $r $!";
 298     close $templatelock;
 299 }
 300
 301 sub movetogarbage () {
 302     # realdestrepo must have been locked
 303
 304     my $real = realdestrepo;
 305     return unless stat_exists $real;
 306
 307     my $garbagerepo = "$dgitrepos/${package}_garbage";
 308     # We arrange to always keep at least one old tree, for recovery
 309     # from mistakes.  This is either $garbage or $garbage-old.
 310     if (stat_exists "$garbagerepo") {
 311         printdebug "movetogarbage: rmtree $garbagerepo-tmp\n";
 312         rmtree "$garbagerepo-tmp";
 313         if (rename "$garbagerepo-old", "$garbagerepo-tmp") {
 314             printdebug "movetogarbage: $garbagerepo-old -> -tmp, rmtree\n";
 315             rmtree "$garbagerepo-tmp";
 316         } else {
 317             die "$garbagerepo $!" unless $!==ENOENT;
 318             printdebug "movetogarbage: $garbagerepo-old -> -tmp\n";
 319         }
 320         printdebug "movetogarbage: $garbagerepo -> -old\n";
 321         rename "$garbagerepo", "$garbagerepo-old" or die "$garbagerepo $!";
 322     }
 323
 324     ensuredir "$dgitrepos/_removed-tags";
 325     open PREVIOUS, ">>", removedtagsfile or die removedtagsfile." $!";
 326     git_for_each_ref('refs/tags/'.debiantag('*',$distro), sub {
 327         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 328         print PREVIOUS "\n$objid $reftail .\n" or die $!;
 329     }, $real);
 330     close PREVIOUS or die $!;
 331
 332     printdebug "movetogarbage: $real -> $garbagerepo\n";
 333     rename $real, $garbagerepo
 334         or $! == ENOENT
 335         or die "$garbagerepo $!";
 336 }
 337
 338 sub policy_checkpackage () {
 339     my $lfh = lockrealtree();
 340
 341     $policy = policyhook(FRESHREPO,'check-package',$package);
 342     if ($policy & FRESHREPO) {
 343         movetogarbage();
 344     }
 345
 346     close $lfh;
 347 }
 348
 349 #----- git-receive-pack -----
 350
 351 sub fixmissing__git_receive_pack () {
 352     mkrepotmp();
 353     $destrepo = "$dgitrepos/_tmp/${package}_prospective";
 354     acquirermtree($destrepo, 1);
 355     mkrepo_fromtemplate($destrepo);
 356 }
 357
 358 sub makeworkingclone () {
 359     mkrepotmp();
 360     $workrepo = "$dgitrepos/_tmp/${package}_incoming$$";
 361     acquirermtree($workrepo, 1);
 362     my $lfh = lockrealtree();
 363     runcmd qw(git clone -l -q --mirror), $destrepo, $workrepo;
 364     close $lfh;
 365     rmtree "${workrepo}_fresh";
 366 }
 367
 368 sub setupstunthook () {
 369     my $prerecv = "$workrepo/hooks/pre-receive";
 370     my $fh = new IO::File $prerecv, O_WRONLY|O_CREAT|O_TRUNC, 0777
 371         or die "$prerecv: $!";
 372     print $fh <<END or die "$prerecv: $!";
 373 #!/bin/sh
 374 set -e
 375 exec $0 --pre-receive-hook $package
 376 END
 377     close $fh or die "$prerecv: $!";
 378     $ENV{'DGIT_DRS_WORK'}= $workrepo;
 379     $ENV{'DGIT_DRS_DEST'}= $destrepo;
 380     printdebug " stunt hook set up $prerecv\n";
 381 }
 382
 383 sub dealwithfreshrepo () {
 384     my $freshrepo = "${workrepo}_fresh";
 385     return unless stat_exists $freshrepo;
 386     $destrepo = $freshrepo;
 387 }
 388
 389 sub maybeinstallprospective () {
 390     return if $destrepo eq realdestrepo;
 391
 392     if (open REJ, "<", "$workrepo/drs-error") {
 393         local $/ = undef;
 394         my $msg = <REJ>;
 395         REJ->error and die $!;
 396         print STDERR $msg;
 397         exit 1;
 398     } else {
 399         $!==&ENOENT or die $!;
 400     }
 401
 402     printdebug " show-ref ($destrepo) ...\n";
 403
 404     my $child = open SR, "-|";
 405     defined $child or die $!;
 406     if (!$child) {
 407         chdir $destrepo or die $!;
 408         exec qw(git show-ref);
 409         die $!;
 410     }
 411     my %got = qw(tag 0 head 0);
 412     while (<SR>) {
 413         chomp or die;
 414         printdebug " show-refs| $_\n";
 415         s/^\S*[1-9a-f]\S* (\S+)$/$1/ or die;
 416         my $wh =
 417             m{^refs/tags/} ? 'tag' :
 418             m{^refs/dgit/} ? 'head' :
 419             die;
 420         die if $got{$wh}++;
 421     }
 422     $!=0; $?=0; close SR or $?==256 or die "$? $!";
 423
 424     printdebug "installprospective ?\n";
 425     die Dumper(\%got)." -- missing refs in new repo"
 426         if grep { !$_ } values %got;
 427
 428     lockrealtree();
 429
 430     if ($destrepo eq "${workrepo}_fresh") {
 431         movetogarbage;
 432     }
 433
 434     printdebug "install $destrepo => ".realdestrepo."\n";
 435     rename $destrepo, realdestrepo or die $!;
 436     remove realdestrepo.".lock" or die $!;
 437 }
 438
 439 sub main__git_receive_pack () {
 440     makeworkingclone();
 441     setupstunthook();
 442     runcmd qw(git receive-pack), $workrepo;
 443     dealwithfreshrepo();
 444     maybeinstallprospective();
 445 }
 446
 447 #----- stunt post-receive hook -----
 448
 449 our ($tagname, $tagval, $suite, $oldcommit, $commit);
 450 our ($version, %tagh);
 451
 452 our ($tagexists_error);
 453
 454 sub readupdates () {
 455     printdebug " updates ...\n";
 456     while (<STDIN>) {
 457         chomp or die;
 458         printdebug " upd.| $_\n";
 459         m/^(\S+) (\S+) (\S+)$/ or die "$_ ?";
 460         my ($old, $sha1, $refname) = ($1, $2, $3);
 461         if ($refname =~ m{^refs/tags/(?=$distro/)}) {
 462             reject "pushing multiple tags!" if defined $tagname;
 463             $tagname = $'; #';
 464             $tagval = $sha1;
 465             $tagexists_error= "tag $tagname already exists -".
 466                 " not replacing previously-pushed version"
 467                 if $old =~ m/[^0]/;
 468         } elsif ($refname =~ m{^refs/dgit/}) {
 469             reject "pushing multiple heads!" if defined $suite;
 470             $suite = $'; #';
 471             $oldcommit = $old;
 472             $commit = $sha1;
 473         } else {
 474             reject "pushing unexpected ref!";
 475         }
 476     }
 477     STDIN->error and die $!;
 478
 479     reject "push is missing tag ref update" unless defined $tagname;
 480     reject "push is missing head ref update" unless defined $suite;
 481     printdebug " updates ok.\n";
 482 }
 483
 484 sub parsetag () {
 485     printdebug " parsetag...\n";
 486     open PT, ">dgit-tmp/plaintext" or die $!;
 487     open DS, ">dgit-tmp/plaintext.asc" or die $!;
 488     open T, "-|", qw(git cat-file tag), $tagval or die $!;
 489     for (;;) {
 490         $!=0; $_=<T>; defined or die $!;
 491         print PT or die $!;
 492         if (m/^(\S+) (.*)/) {
 493             push @{ $tagh{$1} }, $2;
 494         } elsif (!m/\S/) {
 495             last;
 496         } else {
 497             die;
 498         }
 499     }
 500     $!=0; $_=<T>; defined or die $!;
 501     m/^($package_re) release (\S+) for \S+ \((\S+)\) \[dgit\]$/ or
 502         reject "tag message not in expected format";
 503
 504     die unless $1 eq $package;
 505     $version = $2;
 506     die "$3 != $suite " unless $3 eq $suite;
 507
 508     my $copyl = $_;
 509     for (;;) {
 510         print PT $copyl or die $!;
 511         $!=0; $_=<T>; defined or die "missing signature? $!";
 512         $copyl = $_;
 513         if (m/^\[dgit ([^"].*)\]$/) { # [dgit "something"] is for future
 514             $_ = $1." ";
 515             while (length) {
 516                 if (s/^distro\=(\S+) //) {
 517                     die "$1 != $distro" unless $1 eq $distro;
 518                 } elsif (s/^(--deliberately-$deliberately_re) //) {
 519                     push @deliberatelies, $1;
 520                 } elsif (s/^previously:(\S+)=(\w+) //) {
 521                     die "previously $1 twice" if defined $previously{$1};
 522                     $previously{$1} = $2;
 523                 } elsif (s/^[-+.=0-9a-z]\S* //) {
 524                 } else {
 525                     die "unknown dgit info in tag ($_)";
 526                 }
 527             }
 528             next;
 529         }
 530         last if m/^-----BEGIN PGP/;
 531     }
 532     $_ = $copyl;
 533     for (;;) {
 534         print DS or die $!;
 535         $!=0; $_=<T>;
 536         last if !defined;
 537     }
 538     T->error and die $!;
 539     close PT or die $!;
 540     close DS or die $!;
 541     printdebug " parsetag ok.\n";
 542 }
 543
 544 sub checksig_keyring ($) {
 545     my ($keyringfile) = @_;
 546     # returns primary-keyid if signed by a key in this keyring
 547     # or undef if not
 548     # or dies on other errors
 549
 550     my $ok = undef;
 551
 552     printdebug " checksig keyring $keyringfile...\n";
 553
 554     our @cmd = (qw(gpgv --status-fd=1 --keyring),
 555                    $keyringfile,
 556                    qw(dgit-tmp/plaintext.asc dgit-tmp/plaintext));
 557     debugcmd '|',@cmd;
 558
 559     open P, "-|", @cmd
 560         or die $!;
 561
 562     while (<P>) {
 563         next unless s/^\[GNUPG:\] //;
 564         chomp or die;
 565         printdebug " checksig| $_\n";
 566         my @l = split / /, $_;
 567         if ($l[0] eq 'NO_PUBKEY') {
 568             last;
 569         } elsif ($l[0] eq 'VALIDSIG') {
 570             my $sigtype = $l[9];
 571             $sigtype eq '00' or reject "signature is not of type 00!";
 572             $ok = $l[10];
 573             die unless defined $ok;
 574             last;
 575         }
 576     }
 577     close P;
 578
 579     printdebug sprintf " checksig ok=%d\n", !!$ok;
 580
 581     return $ok;
 582 }
 583
 584 sub dm_txt_check ($$) {
 585     my ($keyid, $dmtxtfn) = @_;
 586     printdebug " dm_txt_check $keyid $dmtxtfn\n";
 587     open DT, '<', $dmtxtfn or die "$dmtxtfn $!";
 588     while (<DT>) {
 589         m/^fingerprint:\s+$keyid$/oi
 590             ..0 or next;
 591         if (s/^allow:/ /i..0) {
 592         } else {
 593             m/^./
 594                 or reject "key $keyid missing Allow section in permissions!";
 595             next;
 596         }
 597         # in right stanza...
 598         s/^[ \t]+//
 599             or reject "package $package not allowed for key $keyid";
 600         # in allow field...
 601         s/\([^()]+\)//;
 602         s/\,//;
 603         chomp or die;
 604         printdebug " dm_txt_check allow| $_\n";
 605         foreach my $p (split /\s+/) {
 606             if ($p eq $package) {
 607                 # yay!
 608                 printdebug " dm_txt_check ok\n";
 609                 return;
 610             }
 611         }
 612     }
 613     DT->error and die $!;
 614     close DT or die $!;
 615     reject "key $keyid not in permissions list although in keyring!";
 616 }
 617
 618 sub verifytag () {
 619     foreach my $kas (split /:/, $keyrings) {
 620         printdebug "verifytag $kas...\n";
 621         $kas =~ s/^([^,]+),// or die;
 622         my $keyid = checksig_keyring $1;
 623         if (defined $keyid) {
 624             if ($kas =~ m/^a$/) {
 625                 printdebug "verifytag a ok\n";
 626                 return; # yay
 627             } elsif ($kas =~ m/^m([^,]+)$/) {
 628                 dm_txt_check($keyid, $1);
 629                 printdebug "verifytag m ok\n";
 630                 return;
 631             } else {
 632                 die;
 633             }
 634         }
 635     }
 636     reject "key not found in keyrings";
 637 }
 638
 639 sub checksuite () {
 640     printdebug "checksuite ($suitesfile)\n";
 641     open SUITES, "<", $suitesfile or die $!;
 642     while (<SUITES>) {
 643         chomp;
 644         next unless m/\S/;
 645         next if m/^\#/;
 646         s/\s+$//;
 647         return if $_ eq $suite;
 648     }
 649     die $! if SUITES->error;
 650     reject "unknown suite";
 651 }
 652
 653 sub checktagnoreplay () {
 654     # We need to prevent a replay attack using an earlier signed tag.
 655     # We also want to archive in the history the object ids of
 656     # anything we remove, even if we get rid of the actual objects.
 657     #
 658     # So, we check that the signed tag mentions the name and tag
 659     # object id of:
 660     #
 661     # (a) In the case of FRESHREPO: all tags and refs/heads/* in
 662     #     the repo.  That is, effectively, all the things we are
 663     #     deleting.
 664     #
 665     #     This prevents any tag implying a FRESHREPO push
 666     #     being replayed into a different state of the repo.
 667     #
 668     #     There is still the folowing risk: If a non-ff push is of a
 669     #     head which is an ancestor of a previous ff-only push, the
 670     #     previous push can be replayed.
 671     #
 672     #     So we keep a separate list, as a file in the repo, of all
 673     #     the tag object ids we have ever seen and removed.  Any such
 674     #     tag object id will be rejected even for ff-only pushes.
 675     #
 676     # (b) In the case of just NOFFCHECK: all tags referring to the
 677     #     current head for the suite (there must be at least one).
 678     #
 679     #     This prevents any tag implying a NOFFCHECK push being
 680     #     replayed to rewind from a different head.
 681     #
 682     #     The possibility of an earlier ff-only push being replayed is
 683     #     eliminated as follows: the tag from such a push would still
 684     #     be in our repo, and therefore the replayed push would be
 685     #     rejected because the set of refs being updated would be
 686     #     wrong.
 687
 688     if (!open PREVIOUS, "<", removedtagsfile) {
 689         die removedtagsfile." $!" unless $!==ENOENT;
 690     } else {
 691         # Protocol for updating this file is to append to it, not
 692         # write-new-and-rename.  So all updates are prefixed with \n
 693         # and suffixed with " .\n" so that partial writes can be
 694         # ignored.
 695         while (<PREVIOUS>) {
 696             next unless m/^(\w+) (.*) \.\n/;
 697             next unless $1 eq $tagval;
 698             reject "Replay of previously-rewound upload ($tagval $2)";
 699         }
 700         die removedtagsfile." $!" if PREVIOUS->error;
 701         close PREVIOUS;
 702     }
 703
 704     return unless $policy & (FRESHREPO|NOFFCHECK);
 705
 706     my $garbagerepo = "$dgitrepos/${package}_garbage";
 707     lockrealtree();
 708
 709     my $nchecked = 0;
 710     my @problems;
 711
 712     my $check_ref_previously= sub {
 713         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 714         my $supkey = $fullrefname;
 715         $supkey =~ s{^refs/}{} or die "$supkey $objid ?";
 716         my $supobjid = $previously{$supkey};
 717         if (!defined $supobjid) {
 718             printdebug "checktagnoreply - missing\n";
 719             push @problems, "does not declare previously $supkey";
 720         } elsif ($supobjid ne $objid) {
 721             push @problems, "declared previously $supkey=$supobjid".
 722                 " but actually previously $supkey=$objid";
 723         } else {
 724             $nchecked++;
 725         }
 726     };
 727
 728     if ($policy & FRESHREPO) {
 729         foreach my $kind (qw(tags heads)) {
 730             git_for_each_ref("refs/$kind", $check_ref_previously);
 731         }
 732     } else {
 733         my $branch= server_branch($suite);
 734         my $branchhead= git_get_ref(server_ref($suite));
 735         if (!length $branchhead) {
 736             # No such branch - NOFFCHECK was unnecessary.  Oh well.
 737             printdebug "checktagnoreplay - not FRESHREPO, new branch, ok\n";
 738         } else {
 739             printdebug "checktagnoreplay - not FRESHREPO,".
 740                 " checking for overwriting refs/$branch=$branchhead\n";
 741             git_for_each_tag_referring($branchhead, sub {
 742                 my ($tagobjid,$refobjid,$fullrefname,$tagname) = @_;
 743                 $check_ref_previously->($tagobjid,undef,$fullrefname,undef);
 744             });
 745             printdebug "checktagnoreplay - not FRESHREPO, nchecked=$nchecked";
 746             push @problems, "does not declare previously any tag".
 747                 " referring to branch head $branch=$branchhead"
 748                 unless $nchecked;
 749         }
 750     }
 751
 752     if (@problems) {
 753         reject "replay attack prevention check failed:".
 754             " signed tag for $version: ".
 755             join("; ", @problems).
 756             "\n";
 757     }
 758     printdebug "checktagnoreplay - all ok ($tagval)\n"
 759 }
 760
 761 sub tagh1 ($) {
 762     my ($tag) = @_;
 763     my $vals = $tagh{$tag};
 764     reject "missing header $tag in signed tag object" unless $vals;
 765     reject "multiple headers $tag in signed tag object" unless @$vals == 1;
 766     return $vals->[0];
 767 }
 768
 769 sub checks () {
 770     printdebug "checks\n";
 771
 772     tagh1('type') eq 'commit' or reject "tag refers to wrong kind of object";
 773     tagh1('object') eq $commit or reject "tag refers to wrong commit";
 774     tagh1('tag') eq $tagname or reject "tag name in tag is wrong";
 775
 776     my $expecttagname = debiantag $version, $distro;
 777     printdebug "expected tag $expecttagname\n";
 778     $tagname eq $expecttagname or die;
 779
 780     lockrealtree();
 781
 782     @policy_args = ($package,$version,$suite,$tagname,
 783                     join(",",@deliberatelies));
 784     $policy = policyhook(NOFFCHECK|FRESHREPO, 'push', @policy_args);
 785
 786     if (defined $tagexists_error) {
 787         if ($policy & FRESHREPO) {
 788             printdebug "ignoring tagexists_error: $tagexists_error\n";
 789         } else {
 790             reject $tagexists_error;
 791         }
 792     }
 793
 794     checktagnoreplay();
 795     checksuite();
 796
 797     # check that our ref is being fast-forwarded
 798     printdebug "oldcommit $oldcommit\n";
 799     if (!($policy & NOFFCHECK) && $oldcommit =~ m/[^0]/) {
 800         $?=0; $!=0; my $mb = `git merge-base $commit $oldcommit`;
 801         chomp $mb;
 802         $mb eq $oldcommit or reject "not fast forward on dgit branch";
 803     }
 804     if ($policy & FRESHREPO) {
 805         # It's a bit late to be discovering this here, isn't it ?
 806         #
 807         # What we do is: Generate a fresh destination repo right now,
 808         # and arrange to treat it from now on as if it were a
 809         # prospective repo.
 810         #
 811         # The presence of this fresh destination repo is detected by
 812         # the parent, which responds by making a fresh master repo
 813         # from the template.  (If the repo didn't already exist then
 814         # $destrepo was _prospective, and we change it here.  This is
 815         # OK because the parent's check for _fresh persuades it not to
 816         # use _prospective.)
 817         #
 818         $destrepo = "${workrepo}_fresh"; # workrepo lock covers
 819         mkrepo_fromtemplate $destrepo;
 820     }
 821 }
 822
 823 sub onwardpush () {
 824     my @cmd = (qw(git send-pack), $destrepo);
 825     push @cmd, qw(--force) if $policy & NOFFCHECK;
 826     push @cmd, "$commit:refs/dgit/$suite",
 827                "$tagval:refs/tags/$tagname";
 828     debugcmd '+',@cmd;
 829     $!=0;
 830     my $r = system @cmd;
 831     !$r or die "onward push to $destrepo failed: $r $!";
 832 }
 833
 834 sub finalisepush () {
 835     if ($destrepo eq realdestrepo) {
 836         policyhook(0, 'push-confirm', @policy_args, '');
 837         onwardpush();
 838     } else {
 839         # We are to receive the push into a new repo (perhaps
 840         # because the policy push hook asked us to with FRESHREPO, or
 841         # perhaps because the repo didn't exist before).
 842         #
 843         # We want to provide the policy push-confirm hook with a repo
 844         # which looks like the one which is going to be installed.
 845         # The working repo is no good because it might contain
 846         # previous history.
 847         #
 848         # So we push the objects into the prospective new repo right
 849         # away.  If the hook declines, we decline, and the prospective
 850         # repo is never installed.
 851         onwardpush();
 852         policyhook(0, 'push-confirm', @policy_args, $destrepo);
 853     }
 854 }
 855
 856 sub stunthook () {
 857     printdebug "stunthook in $workrepo\n";
 858     chdir $workrepo or die "chdir $workrepo: $!";
 859     mkdir "dgit-tmp" or $!==EEXIST or die $!;
 860     readupdates();
 861     parsetag();
 862     verifytag();
 863     checks();
 864     finalisepush();
 865     printdebug "stunthook done.\n";
 866 }
 867
 868 #----- git-upload-pack -----
 869
 870 sub fixmissing__git_upload_pack () {
 871     $destrepo = "$dgitrepos/_empty";
 872     my $lfh = locksometree($destrepo);
 873     return if stat_exists $destrepo;
 874     rmtree "$destrepo.new";
 875     mkemptyrepo "$destrepo.new", "0644";
 876     rename "$destrepo.new", $destrepo or die $!;
 877     unlink "$destrepo.lock" or die $!;
 878     close $lfh;
 879 }
 880
 881 sub main__git_upload_pack () {
 882     my $lfh = locksometree($destrepo);
 883     printdebug "git-upload-pack in $destrepo\n";
 884     chdir $destrepo or die "$destrepo: $!";
 885     close $lfh;
 886     runcmd qw(git upload-pack), ".";
 887 }
 888
 889 #----- arg parsing and main program -----
 890
 891 sub argval () {
 892     die unless @ARGV;
 893     my $v = shift @ARGV;
 894     die if $v =~ m/^-/;
 895     return $v;
 896 }
 897
 898 our %indistrodir = (
 899     # keys are used for DGIT_DRS_XXX too
 900     'repos' => \$dgitrepos,
 901     'suites' => \$suitesfile,
 902     'policy-hook' => \$policyhook,
 903     'dgit-live' => \$dgitlive,
 904     );
 905
 906 our @hookenvs = qw(distro suitesfile policyhook
 907                    dgitlive keyrings dgitrepos distrodir);
 908
 909 # workrepo and destrepo handled ad-hoc
 910
 911 sub mode_ssh () {
 912     die if @ARGV;
 913
 914     my $cmd = $ENV{'SSH_ORIGINAL_COMMAND'};
 915     $cmd =~ m{
 916         ^
 917         (?: \S* / )?
 918         ( [-0-9a-z]+ )
 919         \s+
 920         '? (?: \S* / )?
 921         ($package_re) \.git
 922         '?$
 923     }ox
 924     or reject "command string not understood";
 925     my $method = $1;
 926     $package = $2;
 927
 928     my $funcn = $method;
 929     $funcn =~ y/-/_/;
 930     my $mainfunc = $main::{"main__$funcn"};
 931
 932     reject "unknown method" unless $mainfunc;
 933
 934     policy_checkpackage();
 935
 936     if (stat_exists realdestrepo) {
 937         $destrepo = realdestrepo;
 938     } else {
 939         printdebug " fixmissing $funcn\n";
 940         my $fixfunc = $main::{"fixmissing__$funcn"};
 941         &$fixfunc;
 942     }
 943
 944     printdebug " running main $funcn\n";
 945     &$mainfunc;
 946 }
 947
 948 sub mode_cron () {
 949     die if @ARGV;
 950
 951     my $listfh = tempfile();
 952     open STDOUT, ">&", $listfh or die $!;
 953     policyhook(0,'check-list');
 954     open STDOUT, ">&STDERR" or die $!;
 955
 956     seek $listfh, 0, 0 or die $!;
 957     while (<$listfh>) {
 958         chomp or die;
 959         next if m/^\s*\#/;
 960         next unless m/\S/;
 961         die unless m/^($package_re)$/;
 962
 963         $package = $1;
 964         policy_checkpackage();
 965     }
 966     die $! if $listfh->error;
 967 }
 968
 969 sub parseargsdispatch () {
 970     die unless @ARGV;
 971
 972     delete $ENV{'GIT_DIR'}; # if not run via ssh, our parent git process
 973     delete $ENV{'GIT_PREFIX'}; # sets these and they mess things up
 974
 975     if ($ENV{'DGIT_DRS_DEBUG'}) {
 976         enabledebug();
 977     }
 978
 979     if ($ARGV[0] eq '--pre-receive-hook') {
 980         if ($debuglevel) {
 981             $debugprefix.="=";
 982             printdebug "in stunthook ".(shellquote @ARGV)."\n";
 983             foreach my $k (sort keys %ENV) {
 984                 printdebug "$k=$ENV{$k}\n" if $k =~  m/^DGIT/;
 985             }
 986         }
 987         shift @ARGV;
 988         @ARGV == 1 or die;
 989         $package = shift @ARGV;
 990         ${ $main::{$_} } = $ENV{"DGIT_DRS_\U$_"} foreach @hookenvs;
 991         defined($workrepo = $ENV{'DGIT_DRS_WORK'}) or die;
 992         defined($destrepo = $ENV{'DGIT_DRS_DEST'}) or die;
 993         open STDOUT, ">&STDERR" or die $!;
 994         eval {
 995             stunthook();
 996         };
 997         if ($@) {
 998             recorderror "$@" or die;
 999             die $@;
1000         }
1001         exit 0;
1002     }
1003
1004     $distro    = argval();
1005     $distrodir = argval();
1006     $keyrings  = argval();
1007
1008     foreach my $dk (keys %indistrodir) {
1009         ${ $indistrodir{$dk} } = "$distrodir/$dk";
1010     }
1011
1012     while (@ARGV && $ARGV[0] =~ m/^--([-0-9a-z]+)=/ && $indistrodir{$1}) {
1013         ${ $indistrodir{$1} } = $'; #';
1014         shift @ARGV;
1015     }
1016
1017     $ENV{"DGIT_DRS_\U$_"} = ${ $main::{$_} } foreach @hookenvs;
1018
1019     die unless @ARGV==1;
1020
1021     my $mode = shift @ARGV;
1022     die unless $mode =~ m/^--(\w+)$/;
1023     my $fn = ${*::}{"mode_$1"};
1024     die unless $fn;
1025     $fn->();
1026 }
1027
1028 sub unlockall () {
1029     while (my $fh = pop @lockfhs) { close $fh; }
1030 }
1031
1032 sub cleanup () {
1033     unlockall();
1034     if (!chdir "$dgitrepos/_tmp") {
1035         $!==ENOENT or die $!;
1036         return;
1037     }
1038     foreach my $lf (<*.lock>) {
1039         my $tree = $lf;
1040         $tree =~ s/\.lock$//;
1041         next unless acquirermtree($tree, 0);
1042         remove $lf or warn $!;
1043         unlockall();
1044     }
1045 }
1046
1047 parseargsdispatch();
1048 cleanup();