infra/dgit-repos-policy-debian

   1 #!/usr/bin/perl -w
   2 # dgit repos policy hook script for Debian
   3
   4 use strict;
   5 $SIG{__WARN__} = sub { die $_[0]; };
   6
   7 use POSIX;
   8 use JSON;
   9 use File::Temp qw(tempfile);
  10 use DBI;
  11 use IPC::Open2;
  12 use Data::Dumper;
  13
  14 use Debian::Dgit qw(:DEFAULT :policyflags);
  15 use Debian::Dgit::Policy::Debian;
  16
  17 initdebug('%');
  18 enabledebuglevel $ENV{'DGIT_DRS_DEBUG'};
  19
  20 END { $? = 127; } # deliberate exit uses _exit
  21
  22 our $distro = shift @ARGV // die "need DISTRO";
  23 our $repos = shift @ARGV // die "need DGIT-REPOS-DIR";
  24 our $dgitlive = shift @ARGV // die "need DGIT-LIVE-DIR";
  25 our $distrodir = shift @ARGV // die "need DISTRO-DIR";
  26 our $action = shift @ARGV // die "need ACTION";
  27
  28 our $publicmode = 02775;
  29 our $new_upload_propagation_slop = 3600*4 + 100;# fixme config;
  30
  31 our $poldbh;
  32 our $pkg;
  33 our $pkgdir;
  34 our ($pkg_exists,$pkg_secret);
  35
  36 our $stderr;
  37
  38 our ($version,$suite,$tagname);
  39 our %deliberately;
  40
  41 # We assume that it is not possible for NEW to have a version older
  42 # than sid.
  43
  44 # Whenever pushing, we check for
  45 #   source-package-local tainted history
  46 #   global tainted history
  47 #   can be overridden by --deliberately except for an admin prohib taint
  48 #
  49 # ALL of the following apply only if history is secret:
  50 #
  51 # if NEW has no version, or a version which is not in our history[1]
  52 #   (always)
  53 #   check all suites
  54 #   if any suite's version is in our history[1], publish our history
  55 #   otherwise discard our history,
  56 #     tainting --deliberately-include-questionable-history
  57 #
  58 # if NEW has a version which is in our history[1]
  59 #   (on push only)
  60 #   require explicit specification of one of
  61 #     --deliberately-include-questionable-history
  62 #     --deliberately-not-fast-forward
  63 #       (latter will taint old NEW version --d-i-q-h)
  64 #   (otherwise)
  65 #   leave it be
  66 #
  67 # [1] looking for the relevant git tag for the version number and not
  68 #    caring what that tag refers to.
  69 #
  70 # A wrinkle: if we approved a push recently, we treat NEW as having
  71 # a version which is in our history.  This is because the package may
  72 # still be being uploaded.  (We record this using the timestamp of the
  73 # package's git repo directory.)
  74
  75 # We aim for the following invariants and properties:
  76 #
  77 # - .dsc of published dgit package will have corresponding publicly
  78 #   visible dgit-repo (soon)
  79 #
  80 # - when a new package is rejected we help maintainer avoid
  81 #   accidentally including bad objects in published dgit history
  82 #
  83 # - .dsc of NEW dgit package has corresponding dgit-repo but not
  84 #   publicly readable
  85
  86 sub apiquery ($) {
  87     my ($subpath) = @_;
  88     local $/=undef;
  89     my $cmd = "$dgitlive/dgit -d$distro \$DGIT_TEST_OPTS";
  90     $cmd .= " -".("D" x $debuglevel) if $debuglevel;
  91     $cmd .= " archive-api-query $subpath";
  92     printdebug "apiquery $cmd\n";
  93     $!=0; $?=0; my $json = `$cmd`;
  94     defined $json && !$? or die "$subpath $! $?";
  95     my $r = decode_json $json;
  96     my $d = new Data::Dumper([$r], [qw(r)]);
  97     printdebug "apiquery $subpath | ", $d->Dump() if $debuglevel>=2;
  98     return $r;
  99 }
 100
 101 sub specific_suite_has_vsn_in_our_history ($) {
 102     my ($suite) = @_;
 103     my $in_suite = apiquery "dsc_in_suite/$suite/$pkg";
 104     foreach my $entry (@$in_suite) {
 105         my $vsn = $entry->{version};
 106         die "$pkg ?" unless defined $vsn;
 107         my $tagref = "refs/tags/".debiantag $vsn;
 108         printdebug " checking history suite=$suite vsn=$vsn tagref=$tagref\n";
 109         $?=0; my $r = system qw(git show-ref --verify --quiet), $tagref;
 110         return 1 if !$r;
 111         next if $r==256;
 112         die "$pkg tagref $tagref $? $!";
 113     }
 114     return 0;
 115 }
 116
 117 sub new_has_vsn_in_our_history () {
 118     return specific_suite_has_vsn_in_our_history('new');
 119 }
 120
 121 sub good_suite_has_vsn_in_our_history () {
 122     my $suites = apiquery "suites";
 123     foreach my $suitei (@$suites) {
 124         my $suite = $suitei->{name};
 125         die unless defined $suite;
 126         next if $suite =~ m/\bnew$/;
 127         return 1 if specific_suite_has_vsn_in_our_history($suite);
 128     }
 129     return 0;
 130 }
 131
 132 sub statpackage () {
 133     $pkgdir = "$repos/$pkg.git";
 134     if (!stat_exists $pkgdir) {
 135         printdebug "statpackage $pkg => ENOENT\n";
 136         $pkg_exists = 0;
 137     } else {
 138         $pkg_exists = 1;
 139         $pkg_secret = !!(~(stat _)[2] & 05);
 140         printdebug "statpackage $pkg => exists, secret=$pkg_secret.\n";
 141     }
 142 }
 143
 144 sub getpackage () {
 145     die unless @ARGV >= 1;
 146     $pkg = shift @ARGV;
 147     die unless $pkg =~ m/^$package_re$/;
 148
 149     statpackage();
 150 }
 151
 152 sub add_taint ($$) {
 153     my ($refobj, $reason) = @_;
 154
 155     printdebug "TAINTING $refobj\n",
 156         (map { "\%| $_" } split "\n", $reason),
 157         "\n";
 158
 159     my $tf = new File::Temp or die $!;
 160     print $tf "$refobj^0\n" or die $!;
 161     flush $tf or die $!;
 162     seek $tf,0,0 or die $!;
 163
 164     my $gcfpid = open GCF, "-|";
 165     defined $gcfpid or die $!;
 166     if (!$gcfpid) {
 167         open STDIN, "<&", $tf or die $!;
 168         exec 'git', 'cat-file', '--batch';
 169         die $!;
 170     }
 171
 172     close $tf or die $!;
 173     $_ = <GCF>;
 174     defined $_ or die;
 175     m/^(\w+) (\w+) (\d+)\n/ or die "$_ ?";
 176     my $gitobjid = $1;
 177     my $gitobjtype = $2;
 178     my $bytes = $3;
 179
 180     my $gitobjdata;
 181     if ($gitobjtype eq 'commit' or $gitobjtype eq 'tag') {
 182         $!=0; read GCF, $gitobjdata, $bytes == $bytes
 183             or die "$gitobjid $bytes $!";
 184     }
 185     close GCF;
 186
 187     $poldbh->do("INSERT INTO taints".
 188                 " (package, gitobjid, gitobjtype, gitobjdata, time, comment)".
 189                 " VALUES (?,?,?,?,?,?)", {},
 190                 $pkg, $gitobjid, $gitobjtype, $gitobjdata, time, $reason);
 191
 192     my $taint_id = $poldbh->last_insert_id(undef,undef,"taints","taint_id");
 193     die unless defined $taint_id;
 194
 195     $poldbh->do("INSERT INTO taintoverrides".
 196                 " (taint_id, deliberately)".
 197                 " VALUES (?, '--deliberately-include-questionable-history')",
 198                 {}, $taint_id);
 199 }
 200
 201 sub add_taint_by_tag ($$) {
 202     my ($tagname,$refobjid) = @_;
 203     add_taint($refobjid,
 204               "tag $tagname referred to this object in git tree but all".
 205               " previously pushed versions were found to have been".
 206               " removed from NEW (ie, rejected) (or never arrived)");
 207 }
 208
 209 sub check_package () {
 210     return 0 unless $pkg_exists;
 211     return 0 unless $pkg_secret;
 212
 213     printdebug "check_package\n";
 214
 215     chdir $pkgdir or die "$pkgdir $!";
 216
 217     stat '.' or die "$pkgdir $!";
 218     my $mtime = ((stat _)[9]);
 219     my $age = time -  $mtime;
 220     printdebug "check_package age=$age\n";
 221
 222     if (good_suite_has_vsn_in_our_history) {
 223         chmod $publicmode, "." or die $!;
 224         $pkg_secret = 0;
 225         return 0;
 226     }
 227
 228     return 0 if $age < $new_upload_propagation_slop;
 229
 230     return 0 if new_has_vsn_in_our_history();
 231
 232     printdebug "check_package secret, deleted, tainting\n";
 233
 234     git_for_each_ref('refs/tags', sub {
 235         my ($objid,$objtype,$fullrefname,$tagname) = @_;
 236         add_taint_by_tag($tagname,$objid);
 237     });
 238
 239     return FRESHREPO;
 240 }
 241
 242 sub action_check_package () {
 243     getpackage();
 244     return check_package();
 245 }
 246
 247 sub getpushinfo () {
 248     die unless @ARGV >= 4;
 249     $version = shift @ARGV;
 250     $suite = shift @ARGV;
 251     $tagname = shift @ARGV;
 252     my $delibs = shift @ARGV;
 253     foreach my $delib (split /\,/, $delibs) {
 254         $deliberately{$delib} = 1;
 255     }
 256 }
 257
 258 sub deliberately ($) { return $deliberately{"--deliberately-$_[0]"}; }
 259
 260 sub action_push () {
 261     getpackage();
 262     getpushinfo();
 263
 264     check_package(); # might make package public, or might add taints
 265
 266     return 0 unless $pkg_exists;
 267     return 0 unless $pkg_secret;
 268
 269     # we suppose that NEW has a version which is already in our
 270     # history, as otherwise the repo would have been blown away
 271
 272     if (deliberately('not-fast-forward')) {
 273         add_taint(server_ref($suite),
 274                   "rewound suite $suite; --deliberately-not-fast-forward".
 275                   " specified in signed tag $tagname for upload of".
 276                   " version $version");
 277         return NOFFCHECK|FRESHREPO;
 278     }
 279     if (deliberately('include-questionable-history')) {
 280         return 0;
 281     }
 282     die "Package is in NEW and has not been accepted or rejected yet;".
 283         " use a --deliberately option to specify whether you are".
 284         " keeping or discarding the previously pushed history. ".
 285         " Please RTFM dgit(1).\n";
 286 }
 287
 288 sub action_push_confirm () {
 289     getpackage();
 290     getpushinfo();
 291     die unless @ARGV >= 1;
 292     my $freshrepo = shift @ARGV;
 293
 294     my $initq = $poldbh->prepare(<<END);
 295         SELECT taint_id, gitobjid FROM taints t
 296             WHERE (package = ? OR package = '')
 297 END
 298     $initq->execute($pkg);
 299
 300     my @objscatcmd = qw(git);
 301     push @objscatcmd, qw(--git-dir), $freshrepo if length $freshrepo;
 302     push @objscatcmd, qw(cat-file --batch);
 303     debugcmd '|',@objscatcmd if $debuglevel>=2;
 304
 305     my @taintids;
 306     my $chkinput = tempfile();
 307     while (my $taint = $initq->fetchrow_hashref()) {
 308         push @taintids, $taint->{taint_id};
 309         print $chkinput $taint->{gitobjid}, "\n" or die $!;
 310         printdebug '|> ', $taint->{gitobjid}, "\n" if $debuglevel>=2;
 311     }
 312     flush $chkinput or die $!;
 313     seek $chkinput,0,0 or die $!;
 314
 315     my $checkpid = open CHKOUT, "-|" // die $!;
 316     if (!$checkpid) {
 317         open STDIN, "<&", $chkinput or die $!;
 318         exec @objscatcmd or die $!;
 319     }
 320
 321     my ($taintinfoq,$overridesanyq,$untaintq,$overridesq);
 322
 323     my $overridesstmt = <<END;
 324         SELECT deliberately FROM taintoverrides WHERE (
 325             1=0
 326 END
 327     my @overridesv = sort keys %deliberately;
 328     $overridesstmt .= <<END foreach @overridesv;
 329             OR deliberately = ?
 330 END
 331     $overridesstmt .= <<END;
 332         ) AND taint_id = ?
 333         ORDER BY deliberately ASC
 334 END
 335
 336     my $mustreject=0;
 337
 338     while (my $taintid = shift @taintids) {
 339         # git cat-file prints a spurious newline after it gets EOF
 340         # This is not documented.  I guess it might go away.  So we
 341         # just read what we expect and then let it get SIGPIPE.
 342         $!=0; $_ = <CHKOUT>;
 343         die "$? $!" unless defined $_;
 344         printdebug "|< ", $_ if $debuglevel>=2;
 345
 346         next if m/^\w+ missing$/;
 347         die unless m/^(\w+) (\w+) (\d+)\s/;
 348         my ($objid,$objtype,$nbytes) = ($1,$2,$3);
 349
 350         my $drop;
 351         (read CHKOUT, $drop, $nbytes) == $nbytes or die;
 352
 353         $taintinfoq ||= $poldbh->prepare(<<END);
 354             SELECT package, time, comment FROM taints WHERE taint_id =  ?
 355 END
 356         $taintinfoq->execute($taintid);
 357
 358         my $ti = $taintinfoq->fetchrow_hashref();
 359         die unless $ti;
 360
 361         my $timeshow = defined $ti->{time}
 362             ? " at time ".strftime("%Y-%m-%d %H:%M:%S Z", gmtime $ti->{time})
 363             : "";
 364         my $pkgshow = length $ti->{package}
 365             ? "package $ti->{package}"
 366             : "any package";
 367
 368         $stderr .= <<END;
 369
 370 History contains tainted $objtype $objid
 371 Taint recorded$timeshow for $pkgshow
 372 Reason: $ti->{comment}
 373 END
 374
 375         printdebug "SQL overrides: @overridesv $taintid /\n$overridesstmt\n";
 376
 377         $overridesq ||= $poldbh->prepare($overridesstmt);
 378         $overridesq->execute(@overridesv, $taintid);
 379         my ($ovwhy) = $overridesq->fetchrow_array();
 380         if (!defined $ovwhy) {
 381             $overridesanyq ||= $poldbh->prepare(<<END);
 382                 SELECT 1 FROM taintoverrides WHERE taint_id = ? LIMIT 1
 383 END
 384             $overridesanyq->execute($taintid);
 385             my ($ovany) = $overridesanyq->fetchrow_array();
 386             $stderr .= $ovany ? <<END : <<END;
 387 Could be forced using --deliberately.  Consult documentation.
 388 END
 389 Uncorrectable error.  If confused, consult administrator.
 390 END
 391             $mustreject = 1;
 392         } else {
 393             $stderr .= <<END;
 394 Forcing due to --deliberately-$ovwhy
 395 END
 396             $untaintq ||= $poldbh->prepare(<<END);
 397                 DELETE FROM taints WHERE taint_id = ?
 398 END
 399             $untaintq->execute($taintid);
 400         }
 401     }
 402     close CHKOUT;
 403
 404     if ($mustreject) {
 405         $stderr .= <<END;
 406
 407 Rejecting push due to questionable history.
 408 END
 409         return 1;
 410     }
 411
 412     if (length $freshrepo) {
 413         if (!good_suite_has_vsn_in_our_history()) {
 414             stat $freshrepo or die "$freshrepo $!";
 415             my $oldmode = ((stat _)[2]);
 416             my $oldwrites = $oldmode & 0222;
 417             # remove r and x bits which have corresponding w bits clear
 418             my $newmode = $oldmode &
 419                 (~0555 | ($oldwrites << 1) | ($oldwrites >> 1));
 420             printdebug sprintf "chmod %#o (was %#o) %s\n",
 421                 $newmode, $oldmode, $freshrepo;
 422             chmod $newmode, $freshrepo or die $!;
 423             utime undef, undef, $freshrepo or die $!;
 424         }
 425     }
 426
 427     return 0;
 428 }
 429
 430 sub action_check_list () {
 431     opendir L, "$repos" or die "$repos $!";
 432     while (defined (my $dent = readdir L)) {
 433         next unless $dent =~ m/^($package_re)\.git$/;
 434         $pkg = $1;
 435         statpackage();
 436         next unless $pkg_exists;
 437         next unless $pkg_secret;
 438         print "$pkg\n" or die $!;
 439     }
 440     closedir L or die $!;
 441     close STDOUT or die $!;
 442     return 0;
 443 }
 444
 445 $action =~ y/-/_/;
 446 my $fn = ${*::}{"action_$action"};
 447 if (!$fn) {
 448     printdebug "dgit-repos-policy-debian: unknown action $action\n";
 449     exit 0;
 450 }
 451
 452 my $sleepy=0;
 453 my $rcode;
 454
 455 my $db_busy_exception= 'Debian::Dgit::Policy::Debian::DB_BUSY';
 456
 457 my @orgargv = @ARGV;
 458
 459 for (;;) {
 460     @ARGV = @orgargv;
 461     eval {
 462         poldb_setup(poldb_path($repos));
 463         $stderr = '';
 464
 465         eval ($ENV{'DGIT_DRS_RPD_TEST_DBLOOP_HOOK'}//'');
 466         die $@ if length $@;
 467         # used by tests/tests/debpolicy-dbretry
 468
 469         $poldbh->{HandleError} = sub {
 470             return 0 unless $poldbh->err == 5; # SQLITE_BUSY, not in .pm :-(
 471             die bless { }, $db_busy_exception;
 472         };
 473
 474         $rcode = $fn->();
 475         die unless defined $rcode;
 476
 477         $poldbh->commit;
 478     };
 479     last unless length $@;
 480     die $@ unless ref $@ eq $db_busy_exception;
 481
 482     die if $sleepy >= 20;
 483     $sleepy++;
 484     print STDERR "[policy database busy, retrying (${sleepy}s)]\n";
 485
 486     eval { $poldbh->rollback; };
 487 }
 488
 489 print STDERR $stderr or die $!;
 490 flush STDERR or die $!;
 491 _exit $rcode;