infra/dgit-repos-policy-debian

   1 #!/usr/bin/perl -w
   2 # dgit repos policy hook script for Debian
   3
   4 use strict;
   5 $SIG{__WARN__} = sub { die $_[0]; };
   6
   7 use POSIX;
   8 use JSON;
   9 use File::Temp qw(tempfile);
  10 use DBI;
  11 use IPC::Open2;
  12 use Data::Dumper;
  13
  14 use Debian::Dgit qw(:DEFAULT :policyflags);
  15 use Debian::Dgit::Policy::Debian;
  16
  17 initdebug('%');
  18 enabledebuglevel $ENV{'DGIT_DRS_DEBUG'};
  19
  20 END { $? = 127; } # deliberate exit uses _exit
  21
  22 our $distro = shift @ARGV // die "need DISTRO";
  23 our $repos = shift @ARGV // die "need DGIT-REPOS-DIR";
  24 our $dgitlive = shift @ARGV // die "need DGIT-LIVE-DIR";
  25 our $distrodir = shift @ARGV // die "need DISTRO-DIR";
  26 our $action = shift @ARGV // die "need ACTION";
  27
  28 our $publicmode = 02775;
  29 our $new_upload_propagation_slop = 3600*4 + 100;# fixme config;
  30
  31 our $poldbh;
  32 our $pkg;
  33 our $pkgdir;
  34 our ($pkg_exists,$pkg_secret);
  35
  36 our $stderr;
  37
  38 our ($version,$suite,$tagname);
  39 our %deliberately;
  40
  41 # We assume that it is not possible for NEW to have a version older
  42 # than sid.
  43
  44 # Whenever pushing, we check for
  45 #   source-package-local tainted history
  46 #   global tainted history
  47 #   can be overridden by --deliberately except for an admin prohib taint
  48 #
  49 # ALL of the following apply only if history is secret:
  50 #
  51 # if NEW has no version, or a version which is not in our history[1]
  52 #   (always)
  53 #   check all suites
  54 #   if any suite's version is in our history[1], publish our history
  55 #   otherwise discard our history,
  56 #     tainting --deliberately-include-questionable-history
  57 #
  58 # if NEW has a version which is in our history[1]
  59 #   (on push only)
  60 #   require explicit specification of one of
  61 #     --deliberately-include-questionable-history
  62 #     --deliberately-not-fast-forward
  63 #       (latter will taint old NEW version --d-i-q-h)
  64 #   (otherwise)
  65 #   leave it be
  66 #
  67 # [1] looking for the relevant git tag for the version number and not
  68 #    caring what that tag refers to.
  69 #
  70 # A wrinkle: if we approved a push recently, we treat NEW as having
  71 # a version which is in our history.  This is because the package may
  72 # still be being uploaded.  (We record this using the timestamp of the
  73 # package's git repo directory.)
  74
  75 # We aim for the following invariants and properties:
  76 #
  77 # - .dsc of published dgit package will have corresponding publicly
  78 #   visible dgit-repo (soon)
  79 #
  80 # - when a new package is rejected we help maintainer avoid
  81 #   accidentally including bad objects in published dgit history
  82 #
  83 # - .dsc of NEW dgit package has corresponding dgit-repo but not
  84 #   publicly readable
  85
  86 sub apiquery ($) {
  87     my ($subpath) = @_;
  88     local $/=undef;
  89     my $cmd = "$dgitlive/dgit -d$distro \$DGIT_TEST_OPTS";
  90     $cmd .= " -".("D" x $debuglevel) if $debuglevel;
  91     $cmd .= " archive-api-query $subpath";
  92     printdebug "apiquery $cmd\n";
  93     $!=0; $?=0; my $json = `$cmd`;
  94     defined $json && !$? or die "$subpath $! $?";
  95     my $r = decode_json $json;
  96     my $d = new Data::Dumper([$r], [qw(r)]);
  97     printdebug "apiquery $subpath | ", $d->Dump() if $debuglevel>=2;
  98     return $r;
  99 }
 100
 101 sub specific_suite_has_vsn_in_our_history ($) {
 102     my ($suite) = @_;
 103     my $in_suite = apiquery "dsc_in_suite/$suite/$pkg";
 104     foreach my $entry (@$in_suite) {
 105         my $vsn = $entry->{version};
 106         die "$pkg ?" unless defined $vsn;
 107         my $tagref = "refs/tags/".debiantag $vsn;
 108         printdebug " checking history suite=$suite vsn=$vsn tagref=$tagref\n";
 109         $?=0; my $r = system qw(git show-ref --verify --quiet), $tagref;
 110         return 1 if !$r;
 111         next if $r==256;
 112         die "$pkg tagref $tagref $? $!";
 113     }
 114     return 0;
 115 }
 116
 117 sub new_has_vsn_in_our_history () {
 118     return specific_suite_has_vsn_in_our_history('new');
 119 }
 120
 121 sub good_suite_has_vsn_in_our_history () {
 122     my $suites = apiquery "suites";
 123     foreach my $suitei (@$suites) {
 124         my $suite = $suitei->{name};
 125         die unless defined $suite;
 126         next if $suite =~ m/\bnew$/;
 127         return 1 if specific_suite_has_vsn_in_our_history($suite);
 128     }
 129     return 0;
 130 }
 131
 132 sub statpackage () {
 133     $pkgdir = "$repos/$pkg.git";
 134     if (!stat_exists $pkgdir) {
 135         printdebug "statpackage $pkg => ENOENT\n";
 136         $pkg_exists = 0;
 137     } else {
 138         $pkg_exists = 1;
 139         $pkg_secret = !!(~(stat _)[2] & 05);
 140         printdebug "statpackage $pkg => exists, secret=$pkg_secret.\n";
 141     }
 142 }
 143
 144 sub getpackage () {
 145     die unless @ARGV >= 1;
 146     $pkg = shift @ARGV;
 147     die unless $pkg =~ m/^$package_re$/;
 148
 149     statpackage();
 150 }
 151
 152 sub add_taint ($$) {
 153     my ($refobj, $reason) = @_;
 154
 155     printdebug "TAINTING $refobj\n",
 156         (map { "\%| $_" } split "\n", $reason),
 157         "\n";
 158
 159     my $tf = new File::Temp or die $!;
 160     print $tf "$refobj^0\n" or die $!;
 161     flush $tf or die $!;
 162     seek $tf,0,0 or die $!;
 163
 164     my $gcfpid = open GCF, "-|";
 165     defined $gcfpid or die $!;
 166     if (!$gcfpid) {
 167         open STDIN, "<&", $tf or die $!;
 168         exec 'git', 'cat-file', '--batch';
 169         die $!;
 170     }
 171
 172     close $tf or die $!;
 173     $_ = <GCF>;
 174     defined $_ or die;
 175     m/^(\w+) (\w+) (\d+)\n/ or die "$_ ?";
 176     my $gitobjid = $1;
 177     my $gitobjtype = $2;
 178     my $bytes = $3;
 179
 180     my $gitobjdata;
 181     if ($gitobjtype eq 'commit' or $gitobjtype eq 'tag') {
 182         $!=0; read GCF, $gitobjdata, $bytes == $bytes
 183             or die "$gitobjid $bytes $!";
 184     }
 185     close GCF;
 186
 187     $poldbh->do("INSERT INTO taints".
 188                 " (package, gitobjid, gitobjtype, gitobjdata, time, comment)".
 189                 " VALUES (?,?,?,?,?,?)", {},
 190                 $pkg, $gitobjid, $gitobjtype, $gitobjdata, time, $reason);
 191
 192     my $taint_id = $poldbh->last_insert_id(undef,undef,"taints","taint_id");
 193     die unless defined $taint_id;
 194
 195     $poldbh->do("INSERT INTO taintoverrides".
 196                 " (taint_id, deliberately)".
 197                 " VALUES (?, '--deliberately-include-questionable-history')",
 198                 {}, $taint_id);
 199 }
 200
 201 sub add_taint_by_tag ($$) {
 202     my ($tagname,$refobjid) = @_;
 203     add_taint($refobjid,
 204               "tag $tagname referred to this object in git tree but all".
 205               " previously pushed versions were found to have been".
 206               " removed from NEW (ie, rejected) (or never arrived)");
 207 }
 208
 209 sub check_package () {
 210     return 0 unless $pkg_exists;
 211     return 0 unless $pkg_secret;
 212
 213     printdebug "check_package\n";
 214
 215     chdir $pkgdir or die "$pkgdir $!";
 216
 217     stat '.' or die "$pkgdir $!";
 218     my $mtime = ((stat _)[9]);
 219     my $age = time -  $mtime;
 220     printdebug "check_package age=$age\n";
 221
 222     return 0 if $age < $new_upload_propagation_slop;
 223
 224     return 0 if new_has_vsn_in_our_history();
 225
 226     if (good_suite_has_vsn_in_our_history) {
 227         chmod $publicmode, "." or die $!;
 228         return 0;
 229     }
 230
 231     printdebug "check_package secret, deleted, tainting\n";
 232
 233     git_for_each_ref('refs/tags', sub {
 234         my ($objid,$objtype,$fullrefname,$tagname) = @_;
 235         add_taint_by_tag($tagname,$objid);
 236     });
 237
 238     return FRESHREPO;
 239 }
 240
 241 sub action_check_package () {
 242     getpackage();
 243     return check_package();
 244 }
 245
 246 sub getpushinfo () {
 247     die unless @ARGV >= 4;
 248     $version = shift @ARGV;
 249     $suite = shift @ARGV;
 250     $tagname = shift @ARGV;
 251     my $delibs = shift @ARGV;
 252     foreach my $delib (split /\,/, $delibs) {
 253         $deliberately{$delib} = 1;
 254     }
 255 }
 256
 257 sub deliberately ($) { return $deliberately{"--deliberately-$_[0]"}; }
 258
 259 sub action_push () {
 260     getpackage();
 261     getpushinfo();
 262
 263     return 0 unless $pkg_exists;
 264     return 0 unless $pkg_secret;
 265
 266     # we suppose that NEW has a version which is already in our
 267     # history, as otherwise the repo would have been blown away
 268
 269     if (deliberately('not-fast-forward')) {
 270         add_taint(server_ref($suite),
 271                   "rewound suite $suite; --deliberately-not-fast-forward".
 272                   " specified in signed tag $tagname for upload of".
 273                   " version $version");
 274         return NOFFCHECK|FRESHREPO;
 275     }
 276     if (deliberately('include-questionable-history')) {
 277         return 0;
 278     }
 279     die "Package is in NEW and has not been accepted or rejected yet;".
 280         " use a --deliberately option to specify whether you are".
 281         " keeping or discarding the previously pushed history. ".
 282         " Please RTFM dgit(1).\n";
 283 }
 284
 285 sub action_push_confirm () {
 286     getpackage();
 287     getpushinfo();
 288     die unless @ARGV >= 1;
 289     my $freshrepo = shift @ARGV;
 290
 291     my $initq = $poldbh->prepare(<<END);
 292         SELECT taint_id, gitobjid FROM taints t
 293             WHERE (package = ? OR package = '')
 294 END
 295     $initq->execute($pkg);
 296
 297     my @objscatcmd = qw(git);
 298     push @objscatcmd, qw(--git-dir), $freshrepo if length $freshrepo;
 299     push @objscatcmd, qw(cat-file --batch);
 300     debugcmd '|',@objscatcmd if $debuglevel>=2;
 301
 302     my @taintids;
 303     my $chkinput = tempfile();
 304     while (my $taint = $initq->fetchrow_hashref()) {
 305         push @taintids, $taint->{taint_id};
 306         print $chkinput $taint->{gitobjid}, "\n" or die $!;
 307         printdebug '|> ', $taint->{gitobjid}, "\n" if $debuglevel>=2;
 308     }
 309     flush $chkinput or die $!;
 310     seek $chkinput,0,0 or die $!;
 311
 312     my $checkpid = open CHKOUT, "-|" // die $!;
 313     if (!$checkpid) {
 314         open STDIN, "<&", $chkinput or die $!;
 315         exec @objscatcmd or die $!;
 316     }
 317
 318     my ($taintinfoq,$overridesanyq,$untaintq,$overridesq);
 319
 320     my $overridesstmt = <<END;
 321         SELECT deliberately FROM taintoverrides WHERE (
 322             1=0
 323 END
 324     my @overridesv = sort keys %deliberately;
 325     $overridesstmt .= <<END foreach @overridesv;
 326             OR deliberately = ?
 327 END
 328     $overridesstmt .= <<END;
 329         ) AND taint_id = ?
 330         ORDER BY deliberately ASC
 331 END
 332
 333     my $mustreject=0;
 334
 335     while (my $taintid = shift @taintids) {
 336         # git cat-file prints a spurious newline after it gets EOF
 337         # This is not documented.  I guess it might go away.  So we
 338         # just read what we expect and then let it get SIGPIPE.
 339         $!=0; $_ = <CHKOUT>;
 340         die "$? $!" unless defined $_;
 341         printdebug "|< ", $_ if $debuglevel>=2;
 342
 343         next if m/^\w+ missing$/;
 344         die unless m/^(\w+) (\w+) (\d+)\s/;
 345         my ($objid,$objtype,$nbytes) = ($1,$2,$3);
 346
 347         my $drop;
 348         (read CHKOUT, $drop, $nbytes) == $nbytes or die;
 349
 350         $taintinfoq ||= $poldbh->prepare(<<END);
 351             SELECT package, time, comment FROM taints WHERE taint_id =  ?
 352 END
 353         $taintinfoq->execute($taintid);
 354
 355         my $ti = $taintinfoq->fetchrow_hashref();
 356         die unless $ti;
 357
 358         my $timeshow = defined $ti->{time}
 359             ? " at time ".strftime("%Y-%m-%d %H:%M:%S Z", gmtime $ti->{time})
 360             : "";
 361         my $pkgshow = length $ti->{package}
 362             ? "package $ti->{package}"
 363             : "any package";
 364
 365         $stderr .= <<END;
 366
 367 History contains tainted $objtype $objid
 368 Taint recorded$timeshow for $pkgshow
 369 Reason: $ti->{comment}
 370 END
 371
 372         printdebug "SQL overrides: @overridesv $taintid /\n$overridesstmt\n";
 373
 374         $overridesq ||= $poldbh->prepare($overridesstmt);
 375         $overridesq->execute(@overridesv, $taintid);
 376         my ($ovwhy) = $overridesq->fetchrow_array();
 377         if (!defined $ovwhy) {
 378             $overridesanyq ||= $poldbh->prepare(<<END);
 379                 SELECT 1 FROM taintoverrides WHERE taint_id = ? LIMIT 1
 380 END
 381             $overridesanyq->execute($taintid);
 382             my ($ovany) = $overridesanyq->fetchrow_array();
 383             $stderr .= $ovany ? <<END : <<END;
 384 Could be forced using --deliberately.  Consult documentation.
 385 END
 386 Uncorrectable error.  If confused, consult administrator.
 387 END
 388             $mustreject = 1;
 389         } else {
 390             $stderr .= <<END;
 391 Forcing due to --deliberately-$ovwhy
 392 END
 393             $untaintq ||= $poldbh->prepare(<<END);
 394                 DELETE FROM taints WHERE taint_id = ?
 395 END
 396             $untaintq->execute($taintid);
 397         }
 398     }
 399     close CHKOUT;
 400
 401     if ($mustreject) {
 402         $stderr .= <<END;
 403
 404 Rejecting push due to questionable history.
 405 END
 406         return 1;
 407     }
 408
 409     if (length $freshrepo) {
 410         if (!good_suite_has_vsn_in_our_history()) {
 411             stat $freshrepo or die "$freshrepo $!";
 412             my $oldmode = ((stat _)[2]);
 413             my $oldwrites = $oldmode & 0222;
 414             # remove r and x bits which have corresponding w bits clear
 415             my $newmode = $oldmode &
 416                 (~0555 | ($oldwrites << 1) | ($oldwrites >> 1));
 417             printdebug sprintf "chmod %#o (was %#o) %s\n",
 418                 $newmode, $oldmode, $freshrepo;
 419             chmod $newmode, $freshrepo or die $!;
 420             utime undef, undef, $freshrepo or die $!;
 421         }
 422     }
 423
 424     return 0;
 425 }
 426
 427 sub action_check_list () {
 428     opendir L, "$repos" or die "$repos $!";
 429     while (defined (my $dent = readdir L)) {
 430         next unless $dent =~ m/^($package_re)\.git$/;
 431         $pkg = $1;
 432         statpackage();
 433         next unless $pkg_exists;
 434         next unless $pkg_secret;
 435         print "$pkg\n" or die $!;
 436     }
 437     closedir L or die $!;
 438     close STDOUT or die $!;
 439     return 0;
 440 }
 441
 442 $action =~ y/-/_/;
 443 my $fn = ${*::}{"action_$action"};
 444 if (!$fn) {
 445     printdebug "dgit-repos-policy-debian: unknown action $action\n";
 446     exit 0;
 447 }
 448
 449 my $sleepy=0;
 450 my $rcode;
 451
 452 for (;;) {
 453     poldb_setup(poldb_path($repos));
 454     $stderr = '';
 455
 456     $rcode = $fn->();
 457     die unless defined $rcode;
 458
 459     eval { $poldbh->commit; };
 460     last unless length $@;
 461
 462     die if $sleepy >= 20;
 463     print STDERR "[policy database busy, retrying]\n";
 464     sleep ++$sleepy;
 465
 466     $poldbh->rollback;
 467 }
 468
 469 print STDERR $stderr or die $!;
 470 flush STDERR or die $!;
 471 _exit $rcode;