git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea (;$) {
 132     my ($subdir) = @_;
 133     $subdir //= 'work';
 134     $workarea = fresh_playground "$playprefix/$subdir";
 135     in_workarea sub { playtree_setup };
 136 }
 137
 138 sub run_ref_updates_now ($$) {
 139     my ($mrest, $updates) = @_;
 140     # @$updates is a list of lines for git-update-ref, without \ns
 141
 142     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 143     debugcmd '>|', @upd_cmd;
 144     open U, "|-", @upd_cmd or die $!;
 145     foreach (@$updates) {
 146         printdebug ">= ", $_, "\n";
 147         print U $_, "\n" or die $!;
 148     }
 149     printdebug ">\$\n";
 150     close U or failedcmd @upd_cmd;
 151 }
 152
 153 our $snags_forced = 0;
 154 our $snags_tripped = 0;
 155 our $snags_summarised = 0;
 156 our @deferred_updates;
 157 our @deferred_update_messages;
 158
 159 sub merge_wreckage_cleaning ($) {
 160     my ($updates) = @_;
 161     git_for_each_ref("$wrecknoteprefix/*", sub {
 162         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 163         push @$updates, "delete $fullrefname";
 164     });
 165 }
 166
 167 sub all_snags_summarised () {
 168     $snags_forced + $snags_tripped == $snags_summarised;
 169 }
 170 sub run_deferred_updates ($) {
 171     my ($mrest) = @_;
 172
 173     confess 'dangerous internal error' unless all_snags_summarised();
 174
 175     merge_wreckage_cleaning \@deferred_updates;
 176     run_ref_updates_now $mrest, \@deferred_updates;
 177     print $_, "\n" foreach @deferred_update_messages;
 178
 179     @deferred_updates = ();
 180     @deferred_update_messages = ();
 181 }
 182
 183 sub get_differs ($$) {
 184     my ($x,$y) = @_;
 185     # This resembles quiltify_trees_differ, in dgit, a bit.
 186     # But we don't care about modes, or dpkg-source-unrepresentable
 187     # changes, and we don't need the plethora of different modes.
 188     # Conversely we need to distinguish different kinds of changes to
 189     # debian/ and debian/patches/.
 190
 191     my $differs = 0;
 192
 193     my $rundiff = sub {
 194         my ($opts, $limits, $fn) = @_;
 195         my @cmd = (@git, qw(diff-tree -z --no-renames));
 196         push @cmd, @$opts;
 197         push @cmd, "$_:" foreach $x, $y;
 198         push @cmd, '--', @$limits;
 199         my $diffs = cmdoutput @cmd;
 200         foreach (split /\0/, $diffs) { $fn->(); }
 201     };
 202
 203     $rundiff->([qw(--name-only)], [], sub {
 204         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 205     });
 206
 207     if ($differs & DS_DEB) {
 208         $differs &= ~DS_DEB;
 209         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 210             $differs |=
 211                 m{^debian/patches/}      ? D_PAT_OTH  :
 212                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 213                                            D_DEB_OTH;
 214         });
 215         die "mysterious debian changes $x..$y"
 216             unless $differs & (D_PAT_OTH|DS_DEB);
 217     }
 218
 219     if ($differs & D_PAT_OTH) {
 220         my $mode;
 221         $differs &= ~D_PAT_OTH;
 222         my $pat_oth = sub {
 223             $differs |= D_PAT_OTH;
 224             no warnings qw(exiting);  last;
 225         };
 226         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 227             no warnings qw(exiting);
 228             if (!defined $mode) {
 229                 $mode = $_;  next;
 230             }
 231             die unless s{^debian/patches/}{};
 232             my $ok;
 233             if ($mode eq 'A' && !m/\.series$/s) {
 234                 $ok = 1;
 235             } elsif ($mode eq 'M' && $_ eq 'series') {
 236                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 237                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 238                 chomp $x_s;  $x_s .= "\n";
 239                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 240             } else {
 241                 # nope
 242             }
 243             $mode = undef;
 244             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 245         });
 246         die "mysterious debian/patches changes $x..$y"
 247             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 248     }
 249
 250     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 251
 252     return $differs;
 253 }
 254
 255 sub commit_pr_info ($) {
 256     my ($r) = @_;
 257     return Data::Dumper->dump([$r], [qw(commit)]);
 258 }
 259
 260 sub calculate_committer_authline () {
 261     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 262         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 263     my ($h,$m) = get_commit $c;
 264     $h =~ m/^committer .*$/m or confess "($h) ?";
 265     return $&;
 266 }
 267
 268 sub rm_subdir_cached ($) {
 269     my ($subdir) = @_;
 270     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 271 }
 272
 273 sub read_tree_subdir ($$) {
 274     my ($subdir, $new_tree_object) = @_;
 275     rm_subdir_cached $subdir;
 276     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 277 }
 278
 279 sub read_tree_debian ($) {
 280     my ($treeish) = @_;
 281     read_tree_subdir 'debian', "$treeish:debian";
 282     rm_subdir_cached 'debian/patches';
 283 }
 284
 285 sub read_tree_upstream ($;$$) {
 286     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 287     # if $tree_with_debian is supplied, will use that for debian/
 288     # otherwise will save and restore it.
 289     my $debian =
 290         $tree_with_debian ? "$tree_with_debian:debian"
 291         : cmdoutput @git, qw(write-tree --prefix=debian/);
 292     runcmd @git, qw(read-tree), $treeish;
 293     read_tree_subdir 'debian', $debian;
 294     rm_subdir_cached 'debian/patches' unless $keep_patches;
 295 };
 296
 297 sub make_commit ($$) {
 298     my ($parents, $message_paras) = @_;
 299     my $tree = cmdoutput @git, qw(write-tree);
 300     my @cmd = (@git, qw(commit-tree), $tree);
 301     push @cmd, qw(-p), $_ foreach @$parents;
 302     push @cmd, qw(-m), $_ foreach @$message_paras;
 303     return cmdoutput @cmd;
 304 }
 305
 306 our @snag_force_opts;
 307 sub snag ($$;@) {
 308     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 309     if (grep { $_ eq $tag } @snag_force_opts) {
 310         $snags_forced++;
 311         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 312     } else {
 313         $snags_tripped++;
 314         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 315     }
 316 }
 317
 318 # Important: all mainline code must call snags_maybe_bail after
 319 # any point where snag might be called, but before making changes
 320 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 321 # may be called more than once if necessary (but this is not ideal
 322 # because then the messages about number of snags may be confusing).
 323 sub snags_maybe_bail () {
 324     return if all_snags_summarised();
 325     if ($snags_forced) {
 326         printf STDERR
 327             "%s: snags: %d overriden by individual -f options\n",
 328             $us, $snags_forced;
 329     }
 330     if ($snags_tripped) {
 331         if ($opt_force) {
 332             printf STDERR
 333                 "%s: snags: %d overriden by global --force\n",
 334                 $us, $snags_tripped;
 335         } else {
 336             fail sprintf
 337   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 338                 $us, $snags_tripped;
 339         }
 340     }
 341     $snags_summarised = $snags_forced + $snags_tripped;
 342 }
 343 sub snags_maybe_bail_early () {
 344     # useful to bail out early without doing a lot of work;
 345     # not a substitute for snags_maybe_bail.
 346     snags_maybe_bail() if $snags_tripped && !$opt_force;
 347 }
 348 sub any_snags () {
 349     return $snags_forced || $snags_tripped;
 350 }
 351
 352 sub gbp_pq_export ($$$) {
 353     my ($bname, $base, $tip) = @_;
 354     # must be run in a workarea.  $bname and patch-queue/$bname
 355     # ought not to exist.  Leaves you on patch-queue/$bname with
 356     # the patches staged but not committed.
 357     printdebug "gbp_pq_export $bname $base $tip\n";
 358     runcmd @git, qw(checkout -q -b), $bname, $base;
 359     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 360     my @gbp_cmd = (qw(gbp pq export));
 361     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 362     if ($r) {
 363         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 364         failedcmd @gbp_cmd;
 365     }
 366     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 367 }
 368
 369
 370 # xxx allow merge resolution separately from laundering, before git merge
 371 #
 372 # xxx general gdr docs highlight forbidden things
 373 # xxx general gdr docs list allowable things ?
 374 # xxx general gdr docs explicitly forbid some rebase
 375 #
 376 # xxx provide a way for the user to help
 377 # xxx (eg, provide wreckage provide way to continue)
 378
 379 # later/rework?
 380 #  use git-format-patch?
 381 #  our own patch identification algorithm?
 382 #  this is an alternative strategy
 383
 384 sub merge_failed ($$;@) {
 385     my ($wrecknotes, $emsg, @xmsgs) = @_;
 386     my @m;
 387     push @m, "Merge resolution failed: $emsg";
 388     push @m, @xmsgs;
 389
 390     changedir $maindir;
 391
 392     my @updates;
 393     merge_wreckage_cleaning \@updates;
 394     run_ref_updates_now "merge failed", \@updates;
 395
 396     @updates = ();
 397     keys %$wrecknotes;
 398     while (my ($k,$v) = each %$wrecknotes) {
 399         push @updates, "create $wrecknoteprefix/$k $v";
 400     }
 401     run_ref_updates_now "merge failed", \@updates;
 402     push @m, "Wreckage left in $wrecknoteprefix/*.";
 403
 404     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 405
 406     # use finish rather than fail, in case we are within an eval
 407     # (that can happen inside walk!)
 408     print STDERR "\n";
 409     print STDERR "$us: $_\n" foreach @m;
 410     finish 15;
 411 }
 412
 413 sub mwrecknote ($$$) {
 414     my ($wrecknotes, $reftail, $commitish) = @_;
 415     confess unless defined $commitish;
 416     printdebug "mwrecknote $reftail $commitish\n";
 417     $wrecknotes->{$reftail} = $commitish;
 418 }
 419
 420 sub merge_attempt_cmd {
 421     my $wrecknotes = shift @_;
 422     debugcmd '+', @_;
 423     $!=0; $?=-1;
 424     if (system @_) {
 425         merge_failed $wrecknotes,
 426             failedcmd_waitstatus(),
 427             "failed command: @_";
 428     }
 429 }
 430
 431 sub merge_series ($$$;@) {
 432     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 433     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 434     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 435     # ^ specifies several patch series (currently we only support exactly 2)
 436     # return value is a commit which is the result of
 437     # merging the two versions of the same topic branch
 438     #   $input_q[0] and $input_q[1]
 439     # with respect to the old version
 440     #   $base_q
 441     # all onto $newbase.
 442
 443     # Creates, in *_q, a key MR for its private use
 444
 445     printdebug "merge_series newbase=$newbase\n";
 446
 447     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 448     $base_q->{MR}{S} = 'base';
 449
 450     my %prereq;
 451     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 452     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 453     # $prereq{<patch filename>}               exists or not (even later)
 454
 455     my $result;
 456     my $merged_pq;
 457
 458     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 459
 460     my $attempt_cmd = sub { &merge_attempt_cmd($wrecknotes, @_); };
 461
 462     local $workarea;
 463     fresh_workarea "merge";
 464     my $seriesfile = "debian/patches/series";
 465     in_workarea sub {
 466         playtree_setup();
 467         foreach my $q ($base_q, reverse @input_qs) {
 468             my $s = $q->{MR}{S};
 469             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 470             my @earlier;
 471             if (open S, $seriesfile) {
 472                 while (my $patch = <S>) {
 473                     chomp $patch or die $!;
 474                     $prereq{$patch} //= {};
 475                     foreach my $earlier (@earlier) {
 476                         $prereq{$patch}{$earlier}{$s}++ and die;
 477                     }
 478                     push @earlier, $patch;
 479                     stat "debian/patches/$patch" or die "$patch ?";
 480                 }
 481                 S->error and die "$seriesfile $!";
 482                 close S;
 483             } else {
 484                 die "$seriesfile $!" unless $!==ENOENT;
 485             }
 486             read_tree_upstream $newbase, 1;
 487             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 488                 "Convert $s to patch queue for merging",
 489                 "[git-debrebase merge-innards patch-queue import:".
 490                 " $q->{SeriesTip}]"
 491             ];
 492             printdebug "merge_series  pec $pec ";
 493             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 494             $pec = make_commit [ $pec ], [
 495                 "Drop series file from $s to avoid merge trouble",
 496                 "[git-debrebase merge-innards patch-queue prep:".
 497                 " $q->{SeriesTip}]"
 498             ];
 499
 500             read_tree_debian $newbase;
 501             if (@earlier) {
 502                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 503             } else {
 504                 rm_subdir_cached 'debian/patches';
 505             }
 506             $pec = make_commit [ $pec ], [
 507  "Update debian/ (excluding patches) to final to avoid re-merging",
 508  "debian/ was already merged and we need to just take that.",
 509                 "[git-debrebase merge-innards patch-queue packaging:".
 510                 " $q->{SeriesTip}]"
 511             ];
 512
 513             printdebug "pec' $pec\n";
 514             runcmd @git, qw(reset -q --hard), $pec;
 515             $q->{MR}{PEC} = $pec;
 516             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 517         }
 518         # now, because of reverse, we are on $input_q->{MR}{OQC}
 519         runcmd @git, qw(checkout -q -b merge);
 520         printdebug "merge_series merging...\n";
 521         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 522
 523         $attempt_cmd->(@mergecmd);
 524
 525         printdebug "merge_series merge ok, series...\n";
 526         # We need to construct a new series file
 527         # Firstly, resolve prereq
 528         foreach my $f (sort keys %prereq) {
 529             printdebug "merge_series  patch\t$f\t";
 530             if (!stat_exists "debian/patches/$f") {
 531                 print DEBUG " drop\n" if $debuglevel;
 532                 # git merge deleted it; that's how we tell it's not wanted
 533                 delete $prereq{$f};
 534                 next;
 535             }
 536             print DEBUG " keep\n" if $debuglevel;
 537             foreach my $g (sort keys %{ $prereq{$f} }) {
 538                 my $gfp = $prereq{$f}{$g};
 539                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 540                 if (!!$gfp->{0} == !!$gfp->{1}
 541                     ? $gfp->{0}
 542                     : !$gfp->{base}) {
 543                     print DEBUG "\tkeep\n" if $debuglevel;
 544                 } else {
 545                     print DEBUG "\tdrop\n" if $debuglevel;
 546                     delete $prereq{$f}{$g};
 547                 }
 548             }
 549         }
 550
 551         my $unsat = sub {
 552             my ($f) = @_;
 553             return scalar keys %{ $prereq{$f} };
 554         };
 555
 556         my $nodate = time + 1;
 557         my %authordate;
 558         # $authordate{<patch filename>};
 559         my $authordate = sub {
 560             my ($f) = @_;
 561             $authordate{$f} //= do {
 562                 open PF, "<", "debian/patches/$f" or die "$f $!";
 563                 while (<PF>) {
 564                     return $nodate if m/^$/;
 565                     last if s{^Date: }{};
 566                 }
 567                 chomp;
 568                 return cmdoutput qw(date +%s -d), $_;
 569             };
 570         };
 571
 572         open NS, '>', $seriesfile or die $!;
 573
 574         while (keys %prereq) {
 575             my $best;
 576             foreach my $try (sort keys %prereq) {
 577                 if ($best) {
 578                     next if (
 579                              $unsat->($try) <=> $unsat->($best) or
 580                              $authordate->($try) <=> $authordate->($best) or
 581                              $try cmp $best
 582                             ) >= 0;
 583                 }
 584                 $best = $try;
 585             }
 586             printdebug "merge_series series next $best\n";
 587             print NS "$best\n" or die $!;
 588             delete $prereq{$best};
 589             foreach my $gp (values %prereq) {
 590                 delete $gp->{$best};
 591             }
 592         }
 593
 594         runcmd @git, qw(add), $seriesfile;
 595         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 596         $merged_pq = git_rev_parse 'HEAD';
 597         $mwrecknote->('merged-patchqueue', $merged_pq);
 598
 599         printdebug "merge_series series gbp pq import\n";
 600         runcmd @git, qw(checkout -q -b mergec), $merged_pq;
 601
 602         merge_attempt_cmd($wrecknotes, qw(gbp pq import));
 603
 604         # OK now we are on patch-queue/merge, and we need to rebase
 605         # onto the intended parent and drop the patches from each one
 606
 607         printdebug "merge_series series ok, building...\n";
 608         my $build = $newbase;
 609         my @lcmd = (@git, qw(rev-list --reverse mergec..patch-queue/mergec));
 610         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 611             my $commit = git_cat_file $c, 'commit';
 612             printdebug "merge_series series ok, building $c\n";
 613             read_tree_upstream $c, 0, $newbase;
 614             my $tree = cmdoutput @git, qw(write-tree);
 615             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 616             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 617             open C, ">", "../mcommit" or die $!;
 618             print C $commit or die $!;
 619             close C or die $!;
 620             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 621         }
 622         $result = $build;
 623         mwrecknote($wrecknotes, 'merged-result', $result);
 624
 625         runcmd @git, qw(update-ref refs/heads/result), $result;
 626
 627         runcmd @git, qw(checkout -q -b debug);
 628         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 629         runcmd @git, qw(add .);
 630         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 631         my $mdebug = git_rev_parse 'HEAD';
 632         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 633         mwrecknote($wrecknotes, 'merged-debug', $mdebug);
 634     };
 635     printdebug "merge_series returns $result\n";
 636     return $result;
 637 }
 638
 639 # classify returns an info hash like this
 640 #   CommitId => $objid
 641 #   Hdr => # commit headers, including 1 final newline
 642 #   Msg => # commit message (so one newline is dropped)
 643 #   Tree => $treeobjid
 644 #   Type => (see below)
 645 #   Parents = [ {
 646 #       Ix => $index # ie 0, 1, 2, ...
 647 #       CommitId
 648 #       Differs => return value from get_differs
 649 #       IsOrigin
 650 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 651 #     } ...]
 652 #   NewMsg => # commit message, but with any [dgit import ...] edited
 653 #             # to say "[was: ...]"
 654 #
 655 # Types:
 656 #   Packaging
 657 #   Changelog
 658 #   Upstream
 659 #   AddPatches
 660 #   Mixed
 661 #
 662 #   Pseudomerge
 663 #     has additional entres in classification result
 664 #       Overwritten = [ subset of Parents ]
 665 #       Contributor = $the_remaining_Parent
 666 #
 667 #   DgitImportUnpatched
 668 #     has additional entry in classification result
 669 #       OrigParents = [ subset of Parents ]
 670 #
 671 #   Anchor
 672 #     has additional entry in classification result
 673 #       OrigParents = [ subset of Parents ]  # singleton list
 674 #
 675 #   TreatAsAnchor
 676 #
 677 #   BreakwaterStart
 678 #
 679 #   Unknown
 680 #     has additional entry in classification result
 681 #       Why => "prose"
 682
 683 sub parsecommit ($;$) {
 684     my ($objid, $p_ref) = @_;
 685     # => hash with                   CommitId Hdr Msg Tree Parents
 686     #    Parents entries have only   Ix CommitId
 687     #    $p_ref, if provided, must be [] and is used as a base for Parents
 688
 689     $p_ref //= [];
 690     die if @$p_ref;
 691
 692     my ($h,$m) = get_commit $objid;
 693
 694     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 695     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 696
 697     my $r = {
 698         CommitId => $objid,
 699         Hdr => $h,
 700         Msg => $m,
 701         Tree => $t,
 702         Parents => $p_ref,
 703     };
 704
 705     foreach my $ph (@ph) {
 706         push @$p_ref, {
 707             Ix => scalar @$p_ref,
 708             CommitId => $ph,
 709         };
 710     }
 711
 712     return $r;
 713 }
 714
 715 sub classify ($) {
 716     my ($objid) = @_;
 717
 718     my @p;
 719     my $r = parsecommit($objid, \@p);
 720     my $t = $r->{Tree};
 721
 722     foreach my $p (@p) {
 723         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 724     }
 725
 726     printdebug "classify $objid \$t=$t \@p",
 727         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 728         "\n";
 729
 730     my $classify = sub {
 731         my ($type, @rest) = @_;
 732         $r = { %$r, Type => $type, @rest };
 733         if ($debuglevel) {
 734             printdebug " = $type ".(dd $r)."\n";
 735         }
 736         return $r;
 737     };
 738     my $unknown = sub {
 739         my ($why) = @_;
 740         $r = { %$r, Type => qw(Unknown), Why => $why };
 741         printdebug " ** Unknown\n";
 742         return $r;
 743     };
 744
 745     if (grep { $_ eq $objid } @opt_anchors) {
 746         return $classify->('TreatAsAnchor');
 747     }
 748
 749     my @identical = grep { !$_->{Differs} } @p;
 750     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 751     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 752
 753     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 754         # multi-orig upstreams are represented with an anchor merge
 755         # from a single upstream commit which combines the orig tarballs
 756
 757         # Every anchor tagged this way must be a merge.
 758         # We are relying on the
 759         #     [git-debrebase anchor: ...]
 760         # commit message annotation in "declare" anchor merges (which
 761         # do not have any upstream changes), to distinguish those
 762         # anchor merges from ordinary pseudomerges (which we might
 763         # just try to strip).
 764         #
 765         # However, the user is going to be doing git-rebase a lot.  We
 766         # really don't want them to rewrite an anchor commit.
 767         # git-rebase trips up on merges, so that is a useful safety
 768         # catch.
 769         #
 770         # BreakwaterStart commits are also anchors in the terminology
 771         # of git-debrebase(5), but they are untagged (and always
 772         # manually generated).
 773         #
 774         # We cannot not tolerate any tagged linear commit (ie,
 775         # BreakwaterStart commits tagged `[anchor:') because such a
 776         # thing could result from an erroneous linearising raw git
 777         # rebase of a merge anchor.  That would represent a corruption
 778         # of the branch. and we want to detect and reject the results
 779         # of such corruption before it makes it out anywhere.  If we
 780         # reject it here then we avoid making the pseudomerge which
 781         # would be needed to push it.
 782
 783         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 784         @p == 2 or return $badanchor->("has other than two parents");
 785         $haspatches and return $badanchor->("contains debian/patches");
 786
 787         # How to decide about l/r ordering of anchors ?  git
 788         # --topo-order prefers to expand 2nd parent first.  There's
 789         # already an easy rune to look for debian/ history anyway (git log
 790         # debian/) so debian breakwater branch should be 1st parent; that
 791         # way also there's also an easy rune to look for the upstream
 792         # patches (--topo-order).
 793
 794         # Also this makes --first-parent be slightly more likely to
 795         # be useful - it makes it provide a linearised breakwater history.
 796
 797         # Of course one can say somthing like
 798         #  gitk -- ':/' ':!/debian'
 799         # to get _just_ the commits touching upstream files, and by
 800         # the TREESAME logic in git-rev-list this will leave the
 801         # breakwater into upstream at the first anchor.  But that
 802         # doesn't report debian/ changes at all.
 803
 804         # Other observations about gitk: by default, gitk seems to
 805         # produce output in a different order to git-rev-list.  I
 806         # can't seem to find this documented anywhere.  gitk
 807         # --date-order DTRT.  But, gitk always seems to put the
 808         # parents from left to right, in order, so it's easy to see
 809         # which way round a pseudomerge is.
 810
 811         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 812         $p[1]{Differs} & ~DS_DEB and
 813             $badanchor->("upstream files differ from left parent");
 814         $p[0]{Differs} & ~D_UPS and
 815             $badanchor->("debian/ differs from right parent");
 816
 817         return $classify->(qw(Anchor),
 818                            OrigParents => [ $p[1] ]);
 819     }
 820
 821     if (@p == 1) {
 822         my $d = $r->{Parents}[0]{Differs};
 823         if ($d == D_PAT_ADD) {
 824             return $classify->(qw(AddPatches));
 825         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 826             return $unknown->("edits debian/patches");
 827         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 828             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 829             if ($ty eq 'tree') {
 830                 if ($d == D_DEB_CLOG) {
 831                     return $classify->(qw(Changelog));
 832                 } else {
 833                     return $classify->(qw(Packaging));
 834                 }
 835             } elsif ($ty eq 'missing') {
 836                 return $classify->(qw(BreakwaterStart));
 837             } else {
 838                 return $unknown->("parent's debian is not a directory");
 839             }
 840         } elsif ($d == D_UPS) {
 841             return $classify->(qw(Upstream));
 842         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 843             return $classify->(qw(Mixed));
 844         } elsif ($d == 0) {
 845             return $unknown->("no changes");
 846         } else {
 847             confess "internal error $objid ?";
 848         }
 849     }
 850     if (!@p) {
 851         return $unknown->("origin commit");
 852     }
 853
 854     if (@p == 2 && @identical == 1) {
 855         my @overwritten = grep { $_->{Differs} } @p;
 856         confess "internal error $objid ?" unless @overwritten==1;
 857         return $classify->(qw(Pseudomerge),
 858                            Overwritten => [ $overwritten[0] ],
 859                            Contributor => $identical[0]);
 860     }
 861     if (@p == 2 && @identical == 2) {
 862         my $get_t = sub {
 863             my ($ph,$pm) = get_commit $_[0]{CommitId};
 864             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 865             $1;
 866         };
 867         my @bytime = @p;
 868         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 869         if ($order > 0) { # newer first
 870         } elsif ($order < 0) {
 871             @bytime = reverse @bytime;
 872         } else {
 873             # same age, default to order made by -s ours
 874             # that is, commit was made by someone who preferred L
 875         }
 876         return $classify->(qw(Pseudomerge),
 877                            SubType => qw(Ambiguous),
 878                            Contributor => $bytime[0],
 879                            Overwritten => [ $bytime[1] ]);
 880     }
 881     foreach my $p (@p) {
 882         my ($p_h, $p_m) = get_commit $p->{CommitId};
 883         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 884         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 885     }
 886     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 887     my $m2 = $r->{Msg};
 888     if (!(grep { !$_->{IsOrigin} } @p) and
 889         (@orig_ps >= @p - 1) and
 890         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 891         $r->{NewMsg} = $m2;
 892         return $classify->(qw(DgitImportUnpatched),
 893                            OrigParents => \@orig_ps);
 894     }
 895
 896     if (@p == 2 and
 897         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 898         # xxx ^ metadata tag needs adding to (5)
 899         return $classify->("MergedBreakwaters");
 900     }
 901     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 902         return $unknown->("unknown kind of merge from $1");
 903     }
 904     if (@p > 2) {
 905         return $unknown->("octopus merge");
 906     }
 907
 908     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 909         return $unknown->("general two-parent merge");
 910     }
 911
 912     return $classify->("VanillaMerge");
 913 }
 914
 915 sub keycommits ($;$$$$$);
 916
 917 sub mergedbreakwaters_anchor ($) {
 918     my ($cl) = @_;
 919     my $best_anchor;
 920     foreach my $p (@{ $cl->{Parents} }) {
 921         my ($panchor, $pbw) = keycommits $p->{CommitId},
 922             undef,undef,undef,undef, 1;
 923         $best_anchor = $panchor
 924             if !defined $best_anchor
 925             or is_fast_fwd $best_anchor, $panchor;
 926         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 927             unless is_fast_fwd $panchor, $best_anchor;
 928     }
 929     return $best_anchor;
 930 }
 931
 932 sub keycommits ($;$$$$$) {
 933     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 934     # => ($anchor, $breakwater)
 935
 936     # $unclean->("unclean-$tagsfx", $msg, $cl)
 937     # $furniture->("unclean-$tagsfx", $msg, $cl)
 938     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 939     #   is callled for each situation or commit that
 940     #   wouldn't be found in a laundered branch
 941     # $furniture is for furniture commits such as might be found on an
 942     #   interchange branch (pseudomerge, d/patches, changelog)
 943     # $trouble is for things whnich prevent the return of
 944     #   anchor and breakwater information; if that is ignored,
 945     #   then keycommits returns (undef, undef) instead.
 946     # $fatal is for unprocessable commits, and should normally cause
 947     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 948     #
 949     # If $claimed_bw, this is supposed to be a breakwater commit.
 950     #
 951     # If a callback is undef, fail is called instead.
 952     # If a callback is defined but false, the situation is ignored.
 953     # Callbacks may say:
 954     #   no warnings qw(exiting); last;
 955     # if the answer is no longer wanted.
 956
 957     my ($anchor, $breakwater);
 958     $breakwater = $head if $claimed_bw;
 959     my $clogonly;
 960     my $cl;
 961     my $found_pm;
 962     $fatal //= sub { fail $_[1]; };
 963     my $x = sub {
 964         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 965         my $why = $mainwhy.$xwhy;
 966         my $m = "branch needs laundering (run git-debrebase): $why";
 967         fail $m unless defined $cb;
 968         return unless $cb;
 969         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 970     };
 971     my $found_anchor = sub {
 972         ($anchor) = @_;
 973         $breakwater //= $clogonly;
 974         $breakwater //= $head;
 975         no warnings qw(exiting);
 976         last;
 977     };
 978     for (;;) {
 979         $cl = classify $head;
 980         my $ty = $cl->{Type};
 981         if ($ty eq 'Packaging') {
 982             $breakwater //= $clogonly;
 983             $breakwater //= $head;
 984         } elsif ($ty eq 'Changelog') {
 985             # this is going to count as the tip of the breakwater
 986             # only if it has no upstream stuff before it
 987             $clogonly //= $head;
 988         } elsif ($ty eq 'Anchor' or
 989                  $ty eq 'TreatAsAnchor' or
 990                  $ty eq 'BreakwaterStart') {
 991             $found_anchor->($head);
 992         } elsif ($ty eq 'Upstream') {
 993             $x->($unclean, 'ordering',
 994  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 995                 if defined $breakwater;
 996             $clogonly = undef;
 997             $breakwater = undef;
 998         } elsif ($ty eq 'Mixed') {
 999             $x->($unclean, 'mixed',
1000                  "found mixed upstream/packaging commit"," ($head)");
1001             $clogonly = undef;
1002             $breakwater = undef;
1003         } elsif ($ty eq 'Pseudomerge' or
1004                  $ty eq 'AddPatches') {
1005             my $found_pm = 1;
1006             $x->($furniture, (lc $ty),
1007                  "found interchange bureaucracy commit ($ty)"," ($head)");
1008         } elsif ($ty eq 'DgitImportUnpatched') {
1009             if ($found_pm) {
1010                 $x->($trouble, 'dgitimport',
1011                      "found dgit dsc import"," ($head)");
1012                 return (undef,undef);
1013             } else {
1014                 $x->($fatal, 'unprocessable',
1015                      "found bare dgit dsc import with no prior history",
1016                      " ($head)");
1017                 return (undef,undef);
1018             }
1019         } elsif ($ty eq 'VanillaMerge') {
1020             $x->($trouble, 'vanillamerge',
1021                  "found vanilla merge"," ($head)");
1022             return (undef,undef);
1023         } elsif ($ty eq 'MergedBreakwaters') {
1024             $found_anchor->(mergedbreakwaters_anchor $cl);
1025         } else {
1026             $x->($fatal, 'unprocessable',
1027                  "found unprocessable commit, cannot cope: $cl->{Why}",
1028                  " ($head)");
1029             return (undef,undef);
1030         }
1031         $head = $cl->{Parents}[0]{CommitId};
1032     }
1033     return ($anchor, $breakwater);
1034 }
1035
1036 sub walk ($;$$$);
1037 sub walk ($;$$$) {
1038     my ($input,
1039         $nogenerate,$report, $report_lprefix) = @_;
1040     # => ($tip, $breakwater_tip, $last_anchor)
1041     # (or nothing, if $nogenerate)
1042
1043     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1044     $report_lprefix //= '';
1045
1046     # go through commits backwards
1047     # we generate two lists of commits to apply:
1048     # breakwater branch and upstream patches
1049     my (@brw_cl, @upp_cl, @processed);
1050     my %found;
1051     my $upp_limit;
1052     my @pseudomerges;
1053
1054     my $cl;
1055     my $xmsg = sub {
1056         my ($prose, $info) = @_;
1057         my $ms = $cl->{Msg};
1058         chomp $ms;
1059         $info //= '';
1060         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1061         return (Msg => $ms);
1062     };
1063     my $rewrite_from_here = sub {
1064         my ($cl) = @_;
1065         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1066         push @$cl, $sp_cl;
1067         push @processed, $sp_cl;
1068     };
1069     my $cur = $input;
1070
1071     my $prdelim = "";
1072     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1073
1074     my $prline = sub {
1075         return unless $report;
1076         print $report $prdelim, $report_lprefix, @_;
1077         $prdelim = "\n";
1078     };
1079
1080     my $bomb = sub { # usage: return $bomb->();
1081         print $report " Unprocessable" if $report;
1082         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1083         $prprdelim->();
1084         if ($nogenerate) {
1085             return (undef,undef);
1086         }
1087         fail "found unprocessable commit, cannot cope".
1088             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1089             " (commit $cur) (d.".
1090             (join ' ', map { sprintf "%#x", $_->{Differs} }
1091              @{ $cl->{Parents} }).
1092                  ")";
1093     };
1094
1095     my $build;
1096     my $breakwater;
1097
1098     my $build_start = sub {
1099         my ($msg, $parent) = @_;
1100         $prline->(" $msg");
1101         $build = $parent;
1102         no warnings qw(exiting); last;
1103     };
1104
1105     my $nomerge = sub {
1106         my ($emsg) = @_;
1107         merge_failed $cl->{MergeWreckNotes}, $emsg;
1108     };
1109
1110     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1111
1112     my $last_anchor;
1113
1114     for (;;) {
1115         $cl = classify $cur;
1116         $cl->{MergeWreckNotes} //= {};
1117         my $ty = $cl->{Type};
1118         my $st = $cl->{SubType};
1119         $prline->("$cl->{CommitId} $cl->{Type}");
1120         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1121         push @processed, $cl;
1122         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1123         if ($ty eq 'AddPatches') {
1124             $cur = $p0;
1125             $rewrite_from_here->(\@upp_cl);
1126             next;
1127         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1128             push @brw_cl, $cl;
1129             $cur = $p0;
1130             next;
1131         } elsif ($ty eq 'BreakwaterStart') {
1132             $last_anchor = $cur;
1133             $build_start->('FirstPackaging', $cur);
1134         } elsif ($ty eq 'Upstream') {
1135             push @upp_cl, $cl;
1136             $cur = $p0;
1137             next;
1138         } elsif ($ty eq 'Mixed') {
1139             my $queue = sub {
1140                 my ($q, $wh) = @_;
1141                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1142                 push @$q, $cls;
1143             };
1144             $queue->(\@brw_cl, "debian");
1145             $queue->(\@upp_cl, "upstream");
1146             $rewrite_from_here->(\@brw_cl);
1147             $cur = $p0;
1148             next;
1149         } elsif ($ty eq 'Pseudomerge') {
1150             my $contrib = $cl->{Contributor}{CommitId};
1151             print $report " Contributor=$contrib" if $report;
1152             push @pseudomerges, $cl;
1153             $rewrite_from_here->(\@upp_cl);
1154             $cur = $contrib;
1155             next;
1156         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1157             $last_anchor = $cur;
1158             $build_start->("Anchor", $cur);
1159         } elsif ($ty eq 'DgitImportUnpatched') {
1160             my $pm = $pseudomerges[-1];
1161             if (defined $pm) {
1162                 # To an extent, this is heuristic.  Imports don't have
1163                 # a useful history of the debian/ branch.  We assume
1164                 # that the first pseudomerge after an import has a
1165                 # useful history of debian/, and ignore the histories
1166                 # from later pseudomerges.  Often the first pseudomerge
1167                 # will be the dgit import of the upload to the actual
1168                 # suite intended by the non-dgit NMUer, and later
1169                 # pseudomerges may represent in-archive copies.
1170                 my $ovwrs = $pm->{Overwritten};
1171                 printf $report " PM=%s \@Overwr:%d",
1172                     $pm->{CommitId}, (scalar @$ovwrs)
1173                     if $report;
1174                 if (@$ovwrs != 1) {
1175                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1176                     return $bomb->();
1177                 }
1178                 my $ovwr = $ovwrs->[0]{CommitId};
1179                 printf $report " Overwr=%s", $ovwr if $report;
1180                 # This import has a tree which is just like a
1181                 # breakwater tree, but it has the wrong history.  It
1182                 # ought to have the previous breakwater (which the
1183                 # pseudomerge overwrote) as an ancestor.  That will
1184                 # make the history of the debian/ files correct.  As
1185                 # for the upstream version: either it's the same as
1186                 # was ovewritten (ie, same as the previous
1187                 # breakwater), in which case that history is precisely
1188                 # right; or, otherwise, it was a non-gitish upload of a
1189                 # new upstream version.  We can tell these apart by
1190                 # looking at the tree of the supposed upstream.
1191                 push @brw_cl, {
1192                     %$cl,
1193                     SpecialMethod => 'DgitImportDebianUpdate',
1194                     $xmsg->("convert dgit import: debian changes")
1195                 }, {
1196                     %$cl,
1197                     SpecialMethod => 'DgitImportUpstreamUpdate',
1198                     $xmsg->("convert dgit import: upstream update",
1199                             " anchor")
1200                 };
1201                 $prline->(" Import");
1202                 $rewrite_from_here->(\@brw_cl);
1203                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1204                 $cur = $ovwr;
1205                 next;
1206             } else {
1207                 # Everything is from this import.  This kind of import
1208                 # is already nearly in valid breakwater format, with the
1209                 # patches as commits.  Unfortunately it contains
1210                 # debian/patches/.
1211                 printdebug "*** WALK BOMB bare dgit import\n";
1212                 $cl->{Why} = "bare dgit dsc import";
1213                 return $bomb->();
1214             }
1215             die "$ty ?";
1216         } elsif ($ty eq 'MergedBreakwaters') {
1217             $last_anchor = mergedbreakwaters_anchor $cl;
1218             $build_start->(' MergedBreakwaters', $cur);
1219             last;
1220         } elsif ($ty eq 'VanillaMerge') {
1221             # User may have merged unstitched branch(es).  We will
1222             # have now lost what ffq-prev was then (since the later
1223             # pseudomerge may introduce further changes).  The effect
1224             # of resolving such a merge is that we may have to go back
1225             # further in history to find a merge base, since the one
1226             # which was reachable via ffq-prev is no longer findable.
1227             # This is suboptimal, but if it all works we'll have done
1228             # the right thing.
1229             # xxx we should warn the user in the docs about this
1230
1231             my $ok=1;
1232             my $best_anchor;
1233             # We expect to find a dominating anchor amongst the
1234             # inputs' anchors.  That will be the new anchor.
1235             #
1236             # More complicated is finding a merge base for the
1237             # breakwaters.  We need a merge base that is a breakwater
1238             # commit.  The ancestors of breakwater commits are more
1239             # breakwater commits and possibly upstream commits and the
1240             # ancestors of those upstream.  Upstreams might have
1241             # arbitrary ancestors.  But any upstream commit U is
1242             # either included in both anchors, in which case the
1243             # earlier anchor is a better merge base than any of U's
1244             # ancestors; or U is not included in the older anchor, in
1245             # which case U is not an ancestor of the vanilla merge at
1246             # all.  So no upstream commit, nor any ancestor thereof,
1247             # is a best merge base.  As for non-breakwater Debian
1248             # commits: these are never ancestors of any breakwater.
1249             #
1250             # So any best merge base as found by git-merge-base
1251             # is a suitable breakwater anchor.  Usually there will
1252             # be only one.
1253
1254             printdebug "*** MERGE\n";
1255
1256             my @bwbcmd = (@git, qw(merge-base));
1257             my @ibcmd = (@git, qw(merge-base --all));
1258             my $might_be_in_bw = 1;
1259
1260             my $ps = $cl->{Parents};
1261
1262             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1263
1264             foreach my $p (@$ps) {
1265                 $prline->(" VanillaMerge ".$p->{Ix});
1266                 $prprdelim->();
1267                 my ($ptip, $pbw, $panchor) =
1268                     walk $p->{CommitId}, 0, $report,
1269                          $report_lprefix.'  ';
1270                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1271                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1272                 $p->{Anchor} = $panchor;
1273
1274                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1275                 $mwrecknote->("$lr-input", $p->{CommitId});
1276
1277                 my $mwrecknote_parent = sub {
1278                     my ($which) = @_;
1279                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1280                 };
1281                 $mwrecknote_parent->('Laundered');
1282                 $mwrecknote_parent->('Breakwater');
1283                 $mwrecknote_parent->('Anchor');
1284
1285                 $best_anchor = $panchor if
1286                     !defined $best_anchor or
1287                     is_fast_fwd $best_anchor, $panchor;
1288
1289                 printdebug " MERGE BA best=".($best_anchor//'-').
1290                     " p=$panchor\n";
1291             }
1292
1293             $mwrecknote->('result-anchor', $best_anchor);
1294
1295             foreach my $p (@$ps) {
1296                 $prline->(" VanillaMerge ".$p->{Ix});
1297                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1298                     $nomerge->('divergent anchors');
1299                 } elsif ($p->{Anchor} eq $best_anchor) {
1300                     print $report " SameAnchor" if $report;
1301                 } else {
1302                     print $report " SupersededAnchor" if $report;
1303                 }
1304                 if ($p->{Breakwater} eq $p->{CommitId}) {
1305                     # this parent commit was its own breakwater,
1306                     # ie it is part of the breakwater
1307                     print $report " Breakwater" if $report;
1308                 } else {
1309                     $might_be_in_bw = 0;
1310                 }
1311                 push @bwbcmd, $p->{Breakwater};
1312                 push @ibcmd, $p->{CommitId};
1313             }
1314
1315             if ($ok && $might_be_in_bw) {
1316                 # We could rewrite this to contaion the metadata
1317                 # declaring it to be MergedBreakwaters, but
1318                 # unnecessarily rewriting a merge seems unhelpful.
1319                 $prline->(" VanillaMerge MergedBreakwaters");
1320                 $last_anchor = $best_anchor;
1321                 $build_start->('MergedBreakwaters', $cur);
1322             }
1323
1324             my $bwb = cmdoutput @bwbcmd;
1325
1326             # OK, now we have a breakwater base, but we need the merge
1327             # base for the interchange branch because we need the delta
1328             # queue.
1329             #
1330             # This a the best merge base of our inputs which has the
1331             # breakwater merge base as an ancestor.
1332
1333             my @ibs =
1334                 grep /./,
1335                 split /\n/,
1336                 cmdoutput @ibcmd;
1337
1338             @ibs or confess 'internal error, expected anchor at least ?';
1339
1340             my $ib;
1341             my $ibleaf;
1342             foreach my $tibix (0..$#ibs) {
1343                 my $tib = $ibs[$tibix];
1344                 my $ff = is_fast_fwd $bwb, $tib;
1345                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1346                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1347                 $mwrecknote->($tibleaf, $tib);
1348                 next unless $ff;
1349                 next if $ib;
1350                 $ib = $tib;
1351                 $ibleaf = $tibleaf;
1352             }
1353
1354             $ib or $nomerge->("no suitable interchange merge base");
1355
1356             $prline->("  VanillaMerge Base");
1357             $prprdelim->();
1358             my ($btip, $bbw, $banchor) = eval {
1359                 walk $ib, 0, $report, $report_lprefix.'  ';
1360             };
1361             $nomerge->("walking interchange branch merge base ($ibleaf):\n".
1362                        $@)
1363                 if length $@;
1364
1365             $mwrecknote->("mergebase-laundered", $btip);
1366             $mwrecknote->("mergebase-breakwater", $bbw);
1367             $mwrecknote->("mergebase-anchor", $banchor);
1368
1369             my $ibinfo = { SeriesTip => $btip,
1370                            SeriesBase => $bbw,
1371                            Anchor => $banchor,
1372                            LeftRight => 'mergebase' };
1373
1374             $bbw eq $bwb
1375                 or $nomerge->("interchange merge-base ($ib)'s".
1376                               " breakwater ($bbw)".
1377                               " != breakwaters' merge-base ($bwb)");
1378
1379             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1380                  or $nomerge->("interchange merge-base ($ib)'s".
1381                                " anchor ($ibinfo->{SeriesBase})".
1382                                " != any merge input's anchor (".
1383                                (join ' ', map { $_->{Anchor} } @$ps).
1384                                ")");
1385
1386             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1387             $cl->{MergeBestAnchor} = $best_anchor;
1388             push @brw_cl, {
1389                 %$cl,
1390                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1391                 $xmsg->('constructed from vanilla merge',
1392                         ' merged-breakwater'),
1393             };
1394             push @upp_cl, {
1395                 %$cl,
1396                 SpecialMethod => 'MergeMergeSeries',
1397             };
1398             $build_start->('MergeBreakwaters', $cur);
1399         } else {
1400             printdebug "*** WALK BOMB unrecognised\n";
1401             return $bomb->();
1402         }
1403     }
1404     $prprdelim->();
1405
1406     printdebug "*** WALK prep done cur=$cur".
1407         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1408
1409     return if $nogenerate;
1410
1411     # Now we build it back up again
1412
1413     fresh_workarea();
1414
1415     my $rewriting = 0;
1416
1417     my $read_tree_upstream = sub {
1418         my ($treeish) = @_;
1419         read_tree_upstream $treeish, 0, $build;
1420     };
1421
1422     $#upp_cl = $upp_limit if defined $upp_limit;
1423
1424     my $committer_authline = calculate_committer_authline();
1425
1426     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1427
1428     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1429
1430     in_workarea sub {
1431         mkdir $rd or $!==EEXIST or die $!;
1432         my $current_method;
1433         runcmd @git, qw(read-tree), $build;
1434         foreach my $cl (qw(Debian), (reverse @brw_cl),
1435                         { SpecialMethod => 'RecordBreakwaterTip' },
1436                         qw(Upstream), (reverse @upp_cl)) {
1437             if (!ref $cl) {
1438                 $current_method = $cl;
1439                 next;
1440             }
1441             my $method = $cl->{SpecialMethod} // $current_method;
1442             my @parents = ($build);
1443             my $cltree = $cl->{CommitId};
1444             printdebug "WALK BUILD ".($cltree//'undef').
1445                 " $method (rewriting=$rewriting)\n";
1446             if ($method eq 'Debian') {
1447                 read_tree_debian($cltree);
1448             } elsif ($method eq 'Upstream') {
1449                 $read_tree_upstream->($cltree);
1450             } elsif ($method eq 'StartRewrite') {
1451                 $rewriting = 1;
1452                 next;
1453             } elsif ($method eq 'RecordBreakwaterTip') {
1454                 $breakwater = $build;
1455                 next;
1456             } elsif ($method eq 'DgitImportDebianUpdate') {
1457                 read_tree_debian($cltree);
1458             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1459                 confess unless $rewriting;
1460                 my $differs = (get_differs $build, $cltree);
1461                 next unless $differs & D_UPS;
1462                 $read_tree_upstream->($cltree);
1463                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1464             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1465                 print "Found a general merge, will try to tidy it up.\n";
1466                 $rewriting = 1;
1467                 $read_tree_upstream->($cl->{MergeBestAnchor});
1468                 $read_tree_upstream->($cl->{MergeBestAnchor});
1469                 read_tree_debian($cltree);
1470                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1471             } elsif ($method eq 'MergeMergeSeries') {
1472                 print "Running merge resolution for $cl->{CommitId}...\n";
1473                 $mwrecknote->('new-base', $build);
1474                 $build = merge_series
1475                     $build, $cl->{MergeWreckNotes},
1476                     $cl->{MergeInterchangeBaseInfo},
1477                     @{ $cl->{Parents} };
1478                 $last_anchor = $cl->{MergeBestAnchor};
1479
1480                 # Check for mismerges:
1481                 my $check = sub {
1482                     my ($against, $allow, $what) = @_;
1483                     my $differs = get_differs $build, $against;
1484                     $nomerge->(sprintf
1485        "merge misresolved: %s are not the same (%s %s d.%#x)",
1486                                $what, $against, $build, $differs)
1487                         if $differs & ~($allow | D_PAT_ADD);
1488                 };
1489
1490                 # Breakwater changes which were in each side of the
1491                 # merge will have been incorporated into the
1492                 # MergeCreateMergedBreakwaters output.  Because the
1493                 # upstream series was rebased onto the new breakwater,
1494                 # so should all of the packaging changes which were in
1495                 # the input.
1496                 $check->($input, D_UPS, 'debian files');
1497
1498                 # Upstream files are merge_series, which ought to
1499                 # have been identical to the original merge.
1500                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1501
1502                 print "Merge resolution successful.\n";
1503                 next;
1504             } else {
1505                 confess "$method ?";
1506             }
1507             if (!$rewriting) {
1508                 my $procd = (pop @processed) // 'UNDEF';
1509                 if ($cl ne $procd) {
1510                     $rewriting = 1;
1511                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1512                 }
1513             }
1514             my $newtree = cmdoutput @git, qw(write-tree);
1515             my $ch = $cl->{Hdr};
1516             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1517             $ch =~ s{^parent .*\n}{}mg;
1518             $ch =~ s{(?=^author)}{
1519                 join '', map { "parent $_\n" } @parents
1520             }me or confess "$ch ?";
1521             if ($rewriting) {
1522                 $ch =~ s{^committer .*$}{$committer_authline}m
1523                     or confess "$ch ?";
1524             }
1525             my $cf = "$rd/m$rewriting";
1526             open CD, ">", $cf or die $!;
1527             print CD $ch, "\n", $cl->{Msg} or die $!;
1528             close CD or die $!;
1529             my @cmd = (@git, qw(hash-object));
1530             push @cmd, qw(-w) if $rewriting;
1531             push @cmd, qw(-t commit), $cf;
1532             my $newcommit = cmdoutput @cmd;
1533             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1534             $build = $newcommit;
1535             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1536                 $last_anchor = $cur;
1537             }
1538         }
1539     };
1540
1541     my $final_check = get_differs $build, $input;
1542     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1543         if $final_check & ~D_PAT_ADD;
1544
1545     my @r = ($build, $breakwater, $last_anchor);
1546     printdebug "*** WALK RETURN @r\n";
1547     return @r
1548 }
1549
1550 sub get_head () {
1551     git_check_unmodified();
1552     return git_rev_parse qw(HEAD);
1553 }
1554
1555 sub update_head ($$$) {
1556     my ($old, $new, $mrest) = @_;
1557     push @deferred_updates, "update HEAD $new $old";
1558     run_deferred_updates $mrest;
1559 }
1560
1561 sub update_head_checkout ($$$) {
1562     my ($old, $new, $mrest) = @_;
1563     update_head $old, $new, $mrest;
1564     runcmd @git, qw(reset --hard);
1565 }
1566
1567 sub update_head_postlaunder ($$$) {
1568     my ($old, $tip, $reflogmsg) = @_;
1569     return if $tip eq $old;
1570     print "git-debrebase: laundered (head was $old)\n";
1571     update_head $old, $tip, $reflogmsg;
1572     # no tree changes except debian/patches
1573     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1574 }
1575
1576 sub currently_rebasing() {
1577     foreach (qw(rebase-merge rebase-apply)) {
1578         return 1 if stat_exists "$maindir_gitdir/$_";
1579     }
1580     return 0;
1581 }
1582
1583 sub bail_if_rebasing() {
1584     fail "you are in the middle of a git-rebase already"
1585         if currently_rebasing();
1586 }
1587
1588 sub do_launder_head ($) {
1589     my ($reflogmsg) = @_;
1590     my $old = get_head();
1591     record_ffq_auto();
1592     my ($tip,$breakwater) = walk $old;
1593     snags_maybe_bail();
1594     update_head_postlaunder $old, $tip, $reflogmsg;
1595     return ($tip,$breakwater);
1596 }
1597
1598 sub cmd_launder_v0 () {
1599     badusage "no arguments to launder-v0 allowed" if @ARGV;
1600     my $old = get_head();
1601     my ($tip,$breakwater,$last_anchor) = walk $old;
1602     update_head_postlaunder $old, $tip, 'launder';
1603     printf "# breakwater tip\n%s\n", $breakwater;
1604     printf "# working tip\n%s\n", $tip;
1605     printf "# last anchor\n%s\n", $last_anchor;
1606 }
1607
1608 sub defaultcmd_rebase () {
1609     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1610     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1611     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1612 }
1613
1614 sub cmd_analyse () {
1615     badusage "analyse does not support any options"
1616         if @ARGV and $ARGV[0] =~ m/^-/;
1617     badusage "too many arguments to analyse" if @ARGV>1;
1618     my ($old) = @ARGV;
1619     if (defined $old) {
1620         $old = git_rev_parse $old;
1621     } else {
1622         $old = git_rev_parse 'HEAD';
1623     }
1624     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1625     STDOUT->error and die $!;
1626 }
1627
1628 sub ffq_prev_branchinfo () {
1629     my $current = git_get_symref();
1630     return gdr_ffq_prev_branchinfo($current);
1631 }
1632
1633 sub ffq_check ($;$$) {
1634     # calls $ff and/or $notff zero or more times
1635     # then returns either (status,message) where status is
1636     #    exists
1637     #    detached
1638     #    weird-symref
1639     #    notbranch
1640     # or (undef,undef, $ffq_prev,$gdrlast)
1641     # $ff and $notff are called like this:
1642     #   $ff->("message for stdout\n");
1643     #   $notff->('snag-name', $message);
1644     # normally $currentval should be HEAD
1645     my ($currentval, $ff, $notff) =@_;
1646
1647     $ff //= sub { print $_[0] or die $!; };
1648     $notff //= \&snag;
1649
1650     my ($status, $message, $current, $ffq_prev, $gdrlast)
1651         = ffq_prev_branchinfo();
1652     return ($status, $message) unless $status eq 'branch';
1653
1654     my $exists = git_get_ref $ffq_prev;
1655     return ('exists',"$ffq_prev already exists") if $exists;
1656
1657     return ('not-branch', 'HEAD symref is not to refs/heads/')
1658         unless $current =~ m{^refs/heads/};
1659     my $branch = $';
1660
1661     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1662     my %checked;
1663
1664     printdebug "ffq check_specs @check_specs\n";
1665
1666     my $check = sub {
1667         my ($lrref, $desc) = @_;
1668         printdebug "ffq might check $lrref ($desc)\n";
1669         my $invert;
1670         for my $chk (@check_specs) {
1671             my $glob = $chk;
1672             $invert = $glob =~ s{^[!^]}{};
1673             last if fnmatch $glob, $lrref;
1674         }
1675         return if $invert;
1676         my $lrval = git_get_ref $lrref;
1677         return unless length $lrval;
1678
1679         if (is_fast_fwd $lrval, $currentval) {
1680             $ff->("OK, you are ahead of $lrref\n");
1681             $checked{$lrref} = 1;
1682         } elsif (is_fast_fwd $currentval, $lrval) {
1683             $checked{$lrref} = -1;
1684             $notff->('behind', "you are behind $lrref, divergence risk");
1685         } else {
1686             $checked{$lrref} = -1;
1687             $notff->('diverged', "you have diverged from $lrref");
1688         }
1689     };
1690
1691     my $merge = cfg "branch.$branch.merge",1;
1692     if (defined $merge and $merge =~ m{^refs/heads/}) {
1693         my $rhs = $';
1694         printdebug "ffq merge $rhs\n";
1695         my $check_remote = sub {
1696             my ($remote, $desc) = @_;
1697             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1698             return unless defined $remote;
1699             $check->("refs/remotes/$remote/$rhs", $desc);
1700         };
1701         $check_remote->((scalar cfg "branch.$branch.remote",1),
1702                         'remote fetch/merge branch');
1703         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1704                         (scalar cfg "branch.$branch.pushDefault",1),
1705                         'remote push branch');
1706     }
1707     if ($branch =~ m{^dgit/}) {
1708         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1709     } elsif ($branch =~ m{^master$}) {
1710         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1711     }
1712     return (undef, undef, $ffq_prev, $gdrlast);
1713 }
1714
1715 sub record_ffq_prev_deferred () {
1716     # => ('status', "message")
1717     # 'status' may be
1718     #    deferred          message is undef
1719     #    exists
1720     #    detached
1721     #    weird-symref
1722     #    notbranch
1723     # if not ff from some branch we should be ff from, is an snag
1724     # if "deferred", will have added something about that to
1725     #   @deferred_update_messages, and also maybe printed (already)
1726     #   some messages about ff checks
1727     bail_if_rebasing();
1728     my $currentval = get_head();
1729
1730     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1731     return ($status,$message) if defined $status;
1732
1733     snags_maybe_bail();
1734
1735     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1736     push @deferred_updates, "delete $gdrlast";
1737     push @deferred_update_messages, "Recorded previous head for preservation";
1738     return ('deferred', undef);
1739 }
1740
1741 sub record_ffq_auto () {
1742     my ($status, $message) = record_ffq_prev_deferred();
1743     if ($status eq 'deferred' || $status eq 'exists') {
1744     } else {
1745         snag $status, "could not record ffq-prev: $message";
1746         snags_maybe_bail();
1747     }
1748 }
1749
1750 sub ffq_prev_info () {
1751     bail_if_rebasing();
1752     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1753     my ($status, $message, $current, $ffq_prev, $gdrlast)
1754         = ffq_prev_branchinfo();
1755     if ($status ne 'branch') {
1756         snag $status, "could not check ffq-prev: $message";
1757         snags_maybe_bail();
1758     }
1759     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1760     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1761 }
1762
1763 sub stitch ($$$$$) {
1764     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1765
1766     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1767
1768     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1769         my $differs = get_differs $old_head, $ffq_prev_commitish;
1770         unless ($differs & ~D_PAT_ADD) {
1771             # ffq-prev is ahead of us, and the only tree changes it has
1772             # are possibly addition of things in debian/patches/.
1773             # Just wind forwards rather than making a pointless pseudomerge.
1774             push @deferred_updates,
1775                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1776             update_head_checkout $old_head, $ffq_prev_commitish,
1777                 "stitch (fast forward)";
1778             return;
1779         }
1780     }
1781     fresh_workarea();
1782     # We make pseudomerges with L as the contributing parent.
1783     # This makes git rev-list --first-parent work properly.
1784     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1785         'Declare fast forward / record previous work',
1786         "[git-debrebase pseudomerge: $prose]",
1787     ];
1788     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1789     update_head $old_head, $new_head, "stitch: $prose";
1790 }
1791
1792 sub do_stitch ($;$) {
1793     my ($prose, $unclean) = @_;
1794
1795     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1796     if (!$ffq_prev_commitish) {
1797         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1798         return;
1799     }
1800     my $dangling_head = get_head();
1801
1802     keycommits $dangling_head, $unclean,$unclean,$unclean;
1803     snags_maybe_bail();
1804
1805     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1806 }
1807
1808 sub upstream_commitish_search ($$) {
1809     my ($upstream_version, $tried) = @_;
1810     # todo: at some point maybe use git-deborig to do this
1811     foreach my $tagpfx ('', 'v', 'upstream/') {
1812         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1813         my $new_upstream = git_get_ref "refs/tags/$tag";
1814         push @$tried, $tag;
1815         return $new_upstream if length $new_upstream;
1816     }
1817 }
1818
1819 sub resolve_upstream_version ($$) {
1820     my ($new_upstream, $upstream_version) = @_;
1821
1822     if (!defined $new_upstream) {
1823         my @tried;
1824         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1825         if (!length $new_upstream) {
1826             fail "Could not determine appropriate upstream commitish.\n".
1827                 " (Tried these tags: @tried)\n".
1828                 " Check version, and specify upstream commitish explicitly.";
1829         }
1830     }
1831     $new_upstream = git_rev_parse $new_upstream;
1832
1833     return $new_upstream;
1834 }
1835
1836 sub cmd_new_upstream () {
1837     # automatically and unconditionally launders before rebasing
1838     # if rebase --abort is used, laundering has still been done
1839
1840     my %pieces;
1841
1842     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1843
1844     # parse args - low commitment
1845     my $spec_version = shift @ARGV;
1846     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1847     fail "bad version number \`$spec_version'" unless defined $new_version;
1848     if ($new_version->is_native()) {
1849         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1850     }
1851
1852     my $new_upstream = shift @ARGV;
1853     my $new_upstream_version = upstreamversion  $new_version;
1854     $new_upstream =
1855         resolve_upstream_version $new_upstream, $new_upstream_version;
1856
1857     record_ffq_auto();
1858
1859     my $piece = sub {
1860         my ($n, @x) = @_; # may be ''
1861         my $pc = $pieces{$n} //= {
1862             Name => $n,
1863             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1864         };
1865         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1866         $pc;
1867     };
1868
1869     my @newpieces;
1870     my $newpiece = sub {
1871         my ($n, @x) = @_; # may be ''
1872         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1873         push @newpieces, $pc;
1874     };
1875
1876     $newpiece->('',
1877         OldIx => 0,
1878         New => $new_upstream,
1879     );
1880     while (@ARGV && $ARGV[0] !~ m{^-}) {
1881         my $n = shift @ARGV;
1882
1883         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1884             unless @ARGV && $ARGV[0] !~ m{^-};
1885
1886         my $c = git_rev_parse shift @ARGV;
1887         die unless $n =~ m/^$extra_orig_namepart_re$/;
1888         $newpiece->($n, New => $c);
1889     }
1890
1891     # now we need to investigate the branch this generates the
1892     # laundered version but we don't switch to it yet
1893     my $old_head = get_head();
1894     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1895
1896     my $old_bw_cl = classify $old_bw;
1897     my $old_anchor_cl = classify $old_anchor;
1898     my $old_upstream;
1899     if (!$old_anchor_cl->{OrigParents}) {
1900         snag 'anchor-treated',
1901             'old anchor is recognised due to --anchor, cannot check upstream';
1902     } else {
1903         $old_upstream = parsecommit
1904             $old_anchor_cl->{OrigParents}[0]{CommitId};
1905         $piece->('', Old => $old_upstream->{CommitId});
1906     }
1907
1908     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1909         if ($old_upstream->{Msg} =~
1910  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1911            ) {
1912             my @oldpieces = (split / /, $1);
1913             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1914             if ($old_n_parents != @oldpieces &&
1915                 $old_n_parents != @oldpieces + 1) {
1916                 snag 'upstream-confusing', sprintf
1917                     "previous upstream combine %s".
1918                     " mentions %d pieces (each implying one parent)".
1919                     " but has %d parents".
1920                     " (one per piece plus maybe a previous combine)",
1921                     $old_upstream->{CommitId},
1922                     (scalar @oldpieces),
1923                     $old_n_parents;
1924             } elsif ($oldpieces[0] ne '.') {
1925                 snag 'upstream-confusing', sprintf
1926                     "previous upstream combine %s".
1927                     " first piece is not \`.'",
1928                     $oldpieces[0];
1929             } else {
1930                 $oldpieces[0] = '';
1931                 foreach my $i (0..$#oldpieces) {
1932                     my $n = $oldpieces[$i];
1933                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1934                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1935                 }
1936             }
1937         } else {
1938             snag 'upstream-confusing',
1939                 "previous upstream $old_upstream->{CommitId} is from".
1940                " git-debrebase but not an \`upstream-combine' commit";
1941         }
1942     }
1943
1944     foreach my $pc (values %pieces) {
1945         if (!$old_upstream) {
1946             # we have complained already
1947         } elsif (!$pc->{Old}) {
1948             snag 'upstream-new-piece',
1949                 "introducing upstream piece \`$pc->{Name}'";
1950         } elsif (!$pc->{New}) {
1951             snag 'upstream-rm-piece',
1952                 "dropping upstream piece \`$pc->{Name}'";
1953         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1954             snag 'upstream-not-ff',
1955                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1956         }
1957     }
1958
1959     printdebug "%pieces = ", (dd \%pieces), "\n";
1960     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1961
1962     snags_maybe_bail();
1963
1964     my $new_bw;
1965
1966     fresh_workarea();
1967     in_workarea sub {
1968         my @upstream_merge_parents;
1969
1970         if (!any_snags()) {
1971             push @upstream_merge_parents, $old_upstream->{CommitId};
1972         }
1973
1974         foreach my $pc (@newpieces) { # always has '' first
1975             if ($pc->{Name}) {
1976                 read_tree_subdir $pc->{Name}, $pc->{New};
1977             } else {
1978                 runcmd @git, qw(read-tree), $pc->{New};
1979             }
1980             push @upstream_merge_parents, $pc->{New};
1981         }
1982
1983         # index now contains the new upstream
1984
1985         if (@newpieces > 1) {
1986             # need to make the upstream subtree merge commit
1987             $new_upstream = make_commit \@upstream_merge_parents,
1988                 [ "Combine upstreams for $new_upstream_version",
1989  ("[git-debrebase upstream-combine . ".
1990  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1991  ": new upstream]"),
1992                 ];
1993         }
1994
1995         # $new_upstream is either the single upstream commit, or the
1996         # combined commit we just made.  Either way it will be the
1997         # "upstream" parent of the anchor merge.
1998
1999         read_tree_subdir 'debian', "$old_bw:debian";
2000
2001         # index now contains the anchor merge contents
2002         $new_bw = make_commit [ $old_bw, $new_upstream ],
2003             [ "Update to upstream $new_upstream_version",
2004  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
2005             ];
2006
2007         my $clogsignoff = cmdoutput qw(git show),
2008             '--pretty=format:%an <%ae>  %aD',
2009             $new_bw;
2010
2011         # Now we have to add a changelog stanza so the Debian version
2012         # is right.
2013         die if unlink "debian";
2014         die $! unless $!==ENOENT or $!==ENOTEMPTY;
2015         unlink "debian/changelog" or $!==ENOENT or die $!;
2016         mkdir "debian" or die $!;
2017         open CN, ">", "debian/changelog" or die $!;
2018         my $oldclog = git_cat_file ":debian/changelog";
2019         $oldclog =~ m/^($package_re) \(\S+\) / or
2020             fail "cannot parse old changelog to get package name";
2021         my $p = $1;
2022         print CN <<END, $oldclog or die $!;
2023 $p ($new_version) UNRELEASED; urgency=medium
2024
2025   * Update to new upstream version $new_upstream_version.
2026
2027  -- $clogsignoff
2028
2029 END
2030         close CN or die $!;
2031         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2032
2033         # Now we have the final new breakwater branch in the index
2034         $new_bw = make_commit [ $new_bw ],
2035             [ "Update changelog for new upstream $new_upstream_version",
2036               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2037             ];
2038     };
2039
2040     # we have constructed the new breakwater. we now need to commit to
2041     # the laundering output, because git-rebase can't easily be made
2042     # to make a replay list which is based on some other branch
2043
2044     update_head_postlaunder $old_head, $old_laundered_tip,
2045         'launder for new upstream';
2046
2047     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2048     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2049         "debrebase new-upstream $new_version: rebase";
2050     runcmd @cmd;
2051     # now it's for the user to sort out
2052 }
2053
2054 sub cmd_record_ffq_prev () {
2055     badusage "no arguments allowed" if @ARGV;
2056     my ($status, $msg) = record_ffq_prev_deferred();
2057     if ($status eq 'exists' && $opt_noop_ok) {
2058         print "Previous head already recorded\n" or die $!;
2059     } elsif ($status eq 'deferred') {
2060         run_deferred_updates 'record-ffq-prev';
2061     } else {
2062         fail "Could not preserve: $msg";
2063     }
2064 }
2065
2066 sub cmd_anchor () {
2067     badusage "no arguments allowed" if @ARGV;
2068     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2069     print "$bw\n" or die $!;
2070 }
2071
2072 sub cmd_breakwater () {
2073     badusage "no arguments allowed" if @ARGV;
2074     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2075     print "$bw\n" or die $!;
2076 }
2077
2078 sub cmd_status () {
2079     badusage "no arguments allowed" if @ARGV;
2080
2081     # todo: gdr status should print divergence info
2082     # todo: gdr status should print upstream component(s) info
2083     # todo: gdr should leave/maintain some refs with this kind of info ?
2084
2085     my $oldest = { Badness => 0 };
2086     my $newest;
2087     my $note = sub {
2088         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2089         if ($oldest->{Badness} < $badness) {
2090             $oldest = $newest = undef;
2091         }
2092         $oldest = {
2093                    Badness => $badness,
2094                    CommitId => $cl->{CommitId},
2095                    OurMsg => $ourmsg,
2096                    KcMsg => $kcmsg,
2097                   };
2098         $newest //= $oldest;
2099     };
2100     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2101         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2102         sub { $note->(2, 'branch is unlaundered', @_); },
2103         sub { $note->(3, 'branch needs laundering', @_); },
2104         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2105
2106     my $prcommitinfo = sub {
2107         my ($cid) = @_;
2108         flush STDOUT or die $!;
2109         runcmd @git, qw(--no-pager log -n1),
2110             '--pretty=format:    %h %s%n',
2111             $cid;
2112     };
2113
2114     print "current branch contents, in git-debrebase terms:\n";
2115     if (!$oldest->{Badness}) {
2116         print "  branch is laundered\n";
2117     } else {
2118         print "  $oldest->{OurMsg}\n";
2119         my $printed = '';
2120         foreach my $info ($oldest, $newest) {
2121             my $cid = $info->{CommitId};
2122             next if $cid eq $printed;
2123             $printed = $cid;
2124             print "  $info->{KcMsg}\n";
2125             $prcommitinfo->($cid);
2126         }
2127     }
2128
2129     my $prab = sub {
2130         my ($cid, $what) = @_;
2131         if (!defined $cid) {
2132             print "  $what is not well-defined\n";
2133         } else {
2134             print "  $what\n";
2135             $prcommitinfo->($cid);
2136         }
2137     };
2138     print "key git-debrebase commits:\n";
2139     $prab->($anchor, 'anchor');
2140     $prab->($bw, 'breakwater');
2141
2142     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2143         ffq_prev_branchinfo();
2144
2145     print "branch and ref status, in git-debrebase terms:\n";
2146     if ($ffq_msg) {
2147         print "  $ffq_msg\n";
2148     } else {
2149         $ffq_prev = git_get_ref $ffq_prev;
2150         $gdrlast = git_get_ref $gdrlast;
2151         if ($ffq_prev) {
2152             print "  unstitched; previous tip was:\n";
2153             $prcommitinfo->($ffq_prev);
2154         } elsif (!$gdrlast) {
2155             print "  stitched? (no record of git-debrebase work)\n";
2156         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2157             print "  stitched\n";
2158         } else {
2159             print "  not git-debrebase (diverged since last stitch)\n"
2160         }
2161     }
2162     print "you are currently rebasing\n" if currently_rebasing();
2163 }
2164
2165 sub cmd_stitch () {
2166     my $prose = 'stitch';
2167     getoptions("stitch",
2168                'prose=s', \$prose);
2169     badusage "no arguments allowed" if @ARGV;
2170     do_stitch $prose, 0;
2171 }
2172 sub cmd_prepush () { cmd_stitch(); }
2173
2174 sub cmd_quick () {
2175     badusage "no arguments allowed" if @ARGV;
2176     do_launder_head 'launder for git-debrebase quick';
2177     do_stitch 'quick';
2178 }
2179
2180 sub cmd_conclude () {
2181     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2182     if (!$ffq_prev_commitish) {
2183         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2184         return;
2185     }
2186     my $dangling_head = get_head();
2187
2188     badusage "no arguments allowed" if @ARGV;
2189     do_launder_head 'launder for git-debrebase quick';
2190     do_stitch 'quick';
2191 }
2192
2193 sub cmd_scrap () {
2194     if (currently_rebasing()) {
2195         runcmd @git, qw(rebase --abort);
2196     }
2197     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2198     if (!$ffq_prev_commitish) {
2199         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2200         finish 0;
2201     }
2202     my $scrapping_head = get_head();
2203     badusage "no arguments allowed" if @ARGV;
2204     push @deferred_updates,
2205         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2206         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2207     snags_maybe_bail();
2208     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2209 }
2210
2211 sub make_patches_staged ($) {
2212     my ($head) = @_;
2213     # Produces the patches that would result from $head if it were
2214     # laundered.
2215     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2216     fresh_workarea();
2217     in_workarea sub {
2218         gbp_pq_export 'bw', $secret_bw, $secret_head;
2219     };
2220 }
2221
2222 sub make_patches ($) {
2223     my ($head) = @_;
2224     keycommits $head, 0, \&snag;
2225     make_patches_staged $head;
2226     my $out;
2227     in_workarea sub {
2228         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2229         runcmd @git, qw(read-tree), $head;
2230         read_tree_subdir 'debian/patches', $ptree;
2231         $out = make_commit [$head], [
2232             'Commit patch queue (exported by git-debrebase)',
2233             '[git-debrebase: export and commit patches]',
2234         ];
2235     };
2236     return $out;
2237 }
2238
2239 sub cmd_make_patches () {
2240     my $opt_quiet_would_amend;
2241     getoptions("make-patches",
2242                'quiet-would-amend!', \$opt_quiet_would_amend);
2243     badusage "no arguments allowed" if @ARGV;
2244     bail_if_rebasing();
2245     my $old_head = get_head();
2246     my $new = make_patches $old_head;
2247     my $d = get_differs $old_head, $new;
2248     if ($d == 0) {
2249         fail "No (more) patches to export." unless $opt_noop_ok;
2250         return;
2251     } elsif ($d == D_PAT_ADD) {
2252         snags_maybe_bail();
2253         update_head_checkout $old_head, $new, 'make-patches';
2254     } else {
2255         print STDERR failmsg
2256             "Patch export produced patch amendments".
2257             " (abandoned output commit $new).".
2258             "  Try laundering first."
2259             unless $opt_quiet_would_amend;
2260         finish 7;
2261     }
2262 }
2263
2264 sub cmd_convert_from_gbp () {
2265     badusage "want only 1 optional argument, the upstream git commitish"
2266         unless @ARGV<=1;
2267
2268     my $clogp = parsechangelog();
2269     my $version = $clogp->{'Version'}
2270         // die "missing Version from changelog";
2271
2272     my ($upstream_spec) = @ARGV;
2273
2274     my $upstream_version = upstreamversion $version;
2275     my $upstream =
2276         resolve_upstream_version($upstream_spec, $upstream_version);
2277
2278     my $old_head = get_head();
2279
2280     my $upsdiff = get_differs $upstream, $old_head;
2281     if ($upsdiff & D_UPS) {
2282         runcmd @git, qw(--no-pager diff --stat),
2283             $upstream, $old_head,
2284             qw( -- :!/debian :/);
2285         fail <<END;
2286 upstream ($upstream_spec) and HEAD are not
2287 identical in upstream files.  See diffstat above, or run
2288   git diff $upstream_spec HEAD -- :!/debian :/
2289 END
2290     }
2291
2292     if (!is_fast_fwd $upstream, $old_head) {
2293         snag 'upstream-not-ancestor',
2294             "upstream ($upstream) is not an ancestor of HEAD";
2295     } else {
2296         my $wrong = cmdoutput
2297             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2298              qw(-- :/ :!/debian));
2299         if (length $wrong) {
2300             snag 'unexpected-upstream-changes',
2301                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2302             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2303         }
2304     }
2305
2306     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2307         snag 'upstream-has-debian',
2308             "upstream ($upstream) contains debian/ directory";
2309     }
2310
2311     my $previous_dgit_view = eval {
2312         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2313         my ($lvsn, $suite);
2314         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2315             my ($stz, $desc) = @_;
2316             no warnings qw(exiting);
2317             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2318             next unless $stz->{Date};
2319             next unless $stz->{Distribution} ne 'UNRELEASED';
2320             $lvsn = $stz->{Version};
2321             $suite = $stz->{Distribution};
2322             last;
2323         };
2324         die "neither of the first two changelog entries are released\n"
2325             unless defined $lvsn;
2326         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2327         my $mtag_pat = debiantag_maintview $lvsn, '*';
2328         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2329             $mtag_pat;
2330         die "could not find suitable maintainer view tag $mtag_pat\n"
2331             unless $mtag_pat =~ m{/};
2332         is_fast_fwd $mtag, 'HEAD' or
2333             die "HEAD is not FF from maintainer tag $mtag!";
2334         my $dtag = "archive/$mtag";
2335         is_fast_fwd $mtag, $dtag or
2336             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2337         print "will stitch in dgit view, $dtag\n";
2338         git_rev_parse $dtag;
2339     };
2340     if (!$previous_dgit_view) {
2341         $@ =~ s/^\n+//;
2342         chomp $@;
2343         print STDERR "cannot stitch in dgit view: $@\n";
2344     }
2345
2346     snags_maybe_bail_early();
2347
2348     my $work;
2349
2350     fresh_workarea();
2351     in_workarea sub {
2352         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2353         # make a branch out of the patch queue - we'll want this in a mo
2354         runcmd qw(gbp pq import);
2355         # strip the patches out
2356         runcmd @git, qw(checkout -q gdr-internal~0);
2357         rm_subdir_cached 'debian/patches';
2358         $work = make_commit ['HEAD'], [
2359  'git-debrebase convert-from-gbp: drop patches from tree',
2360  'Delete debian/patches, as part of converting to git-debrebase format.',
2361  '[git-debrebase convert-from-gbp: drop patches from tree]'
2362                               ];
2363         # make the anchor merge
2364         # the tree is already exactly right
2365         $work = make_commit [$work, $upstream], [
2366  'git-debrebase import: declare upstream',
2367  'First breakwater merge.',
2368  '[git-debrebase anchor: declare upstream]'
2369                               ];
2370
2371         # rebase the patch queue onto the new breakwater
2372         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2373         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2374         $work = git_rev_parse 'HEAD';
2375
2376         if ($previous_dgit_view) {
2377             $work = make_commit [$work, $previous_dgit_view], [
2378  'git-debrebase import: declare ff from dgit archive view',
2379  '[git-debrebase pseudomerge: import-from-gbp]',
2380             ];
2381         }
2382     };
2383
2384     ffq_check $work;
2385     snags_maybe_bail();
2386     update_head_checkout $old_head, $work, 'convert-from-gbp';
2387 }
2388
2389 sub cmd_convert_to_gbp () {
2390     badusage "no arguments allowed" if @ARGV;
2391     my $head = get_head();
2392     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2393     keycommits $head, 0;
2394     my $out;
2395     make_patches_staged $head;
2396     in_workarea sub {
2397         $out = make_commit ['HEAD'], [
2398             'Commit patch queue (converted from git-debrebase format)',
2399             '[git-debrebase convert-to-gbp: commit patches]',
2400         ];
2401     };
2402     if (defined $ffq) {
2403         push @deferred_updates, "delete $ffq";
2404         push @deferred_updates, "delete $gdrlast";
2405     }
2406     snags_maybe_bail();
2407     update_head_checkout $head, $out, "convert to gbp (v0)";
2408     print <<END or die $!;
2409 git-debrebase: converted to git-buildpackage branch format
2410 git-debrebase: WARNING: do not now run "git-debrebase" any more
2411 git-debrebase: WARNING: doing so would drop all upstream patches!
2412 END
2413 }
2414
2415 sub cmd_convert_from_dgit_view () {
2416     my $clogp = parsechangelog();
2417
2418     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2419     my $do_origs = 1;
2420     my $do_tags = 1;
2421     my $always = 0;
2422     my $diagnose = 0;
2423
2424     getoptions("convert-from-dgit-view",
2425                'diagnose!', \$diagnose,
2426                'build-products-dir:s', \$bpd,
2427                'origs!', \$do_origs,
2428                'tags!', \$do_tags,
2429                'always-convert-anyway!', \$always);
2430     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2431
2432     my @upstreams;
2433
2434     if (@ARGV) {
2435         my $spec = shift @ARGV;
2436         my $commit = git_rev_parse "$spec^{commit}";
2437         push @upstreams, { Commit => $commit,
2438                            Source => "$ARGV[0], from command line",
2439                            Only => 1,
2440                          };
2441     }
2442
2443     my $head = get_head();
2444
2445     if (!$always) {
2446         my $troubles = 0;
2447         my $trouble = sub { $troubles++; };
2448         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2449         printdebug "troubles=$troubles\n";
2450         if (!$troubles) {
2451             print STDERR <<END;
2452 $us: Branch already seems to be in git-debrebase format!
2453 $us: --always-convert-anyway would do the conversion operation anyway
2454 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2455 END
2456             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2457             finish 0;
2458         }
2459     }
2460
2461     snags_maybe_bail_early();
2462
2463     my $version = upstreamversion $clogp->{Version};
2464     print STDERR "Considering possible commits corresponding to upstream:\n";
2465
2466     if (!@upstreams) {
2467         if ($do_tags) {
2468             my @tried;
2469             my $ups_tag = upstream_commitish_search $version, \@tried;
2470             if ($ups_tag) {
2471                 my $this = "git tag $tried[-1]";
2472                 push @upstreams, { Commit => $ups_tag,
2473                                    Source => $this,
2474                                  };
2475             } else {
2476                 printf STDERR
2477                     " git tag: no suitable tag found (tried %s)\n",
2478                     "@tried";
2479             }
2480         }
2481         if ($do_origs) {
2482             my $p = $clogp->{'Source'};
2483             # we do a quick check to see if there are plausible origs
2484             my $something=0;
2485             if (!opendir BPD, $bpd) {
2486                 die "$bpd: opendir: $!" unless $!==ENOENT;
2487             } else {
2488                 while ($!=0, my $f = readdir BPD) {
2489                     next unless is_orig_file_of_p_v $f, $p, $version;
2490                     printf STDERR
2491                         " orig: found what looks like a .orig, %s\n",
2492                         "$bpd/$f";
2493                     $something=1;
2494                     last;
2495                 }
2496                 die "read $bpd: $!" if $!;
2497                 closedir BPD;
2498             }
2499             if ($something) {
2500                 my $tree = cmdoutput
2501                     @dgit, qw(--build-products-dir), $bpd,
2502                     qw(print-unapplied-treeish);
2503                 fresh_workarea();
2504                 in_workarea sub {
2505                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2506                     rm_subdir_cached 'debian';
2507                     $tree = cmdoutput @git, qw(write-tree);
2508                     my $ups_synth = make_commit [], [ <<END, <<END,
2509 Import effective orig tree for upstream version $version
2510 END
2511 This includes the contents of the .orig(s), minus any debian/ directory.
2512
2513 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2514 END
2515                                                     ];
2516                     push @upstreams, { Commit => $ups_synth,
2517                                        Source => "orig(s) imported via dgit",
2518                                      };
2519                 }
2520             } else {
2521                 printf STDERR
2522                     " orig: no suitable origs found (looked for %s in %s)\n",
2523                     "${p}_".(stripeoch $version)."...", $bpd;
2524             }
2525         }
2526     }
2527
2528     my $some_patches = stat_exists 'debian/patches/series';
2529
2530     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2531
2532     my $result;
2533     foreach my $u (@upstreams) {
2534         my $work = $head;
2535         fresh_workarea();
2536         in_workarea sub {
2537             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2538             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2539             runcmd @git, qw(clean -xdff);
2540             runcmd @git, qw(checkout), $head, qw(-- debian);
2541             if ($some_patches) {
2542                 rm_subdir_cached 'debian/patches';
2543                 $work = make_commit [ $work ], [
2544  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2545  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2546  "to git-debrebase format.  Upstream changes will appear as commits.",
2547  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2548                                            ];
2549             }
2550             $work = make_commit [ $work, $u->{Commit} ], [
2551  'git-debrebase convert-from-dgit-view: declare upstream',
2552  '(Re)constructed breakwater merge.',
2553  '[git-debrebase anchor: declare upstream]'
2554                                                          ];
2555             runcmd @git, qw(checkout --quiet -b mk), $work;
2556             if ($some_patches) {
2557                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2558                 runcmd @git, qw(reset --quiet);
2559                 my @gbp_cmd = (qw(gbp pq import));
2560                 if (!$diagnose) {
2561                     my $gbp_err = "../gbp-pq-err";
2562                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2563                 }
2564                 my $r = system @gbp_cmd;
2565                 if ($r) {
2566                     printf STDERR
2567                         " %s: couldn't apply patches: gbp pq %s",
2568                         $u->{Source}, waitstatusmsg();
2569                     return;
2570                 }
2571             }
2572             my $work = git_rev_parse qw(HEAD);
2573             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2574             if (length $diffout) {
2575                 print STDERR
2576                     " $u->{Source}: applying patches gives different tree\n";
2577                 print STDERR $diffout if $diagnose;
2578                 return;
2579             }
2580             # OMG!
2581             $u->{Result} = $work;
2582             $result = $u;
2583         };
2584         last if $result;
2585     }
2586
2587     if (!$result) {
2588         fail <<END;
2589 Could not find or construct a suitable upstream commit.
2590 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2591 upstream commmit explicitly or provide suitable origs.
2592 END
2593     }
2594
2595     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2596
2597     ffq_check $result->{Result};
2598     snags_maybe_bail();
2599     update_head_checkout $head, $result->{Result},
2600         'convert-from-dgit-view';
2601 }
2602
2603 sub cmd_downstream_rebase_launder_v0 () {
2604     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2605     my ($base) = @ARGV;
2606     $base = git_rev_parse $base;
2607     my $old_head = get_head();
2608     my $current = $old_head;
2609     my $topmost_keep;
2610     for (;;) {
2611         if ($current eq $base) {
2612             $topmost_keep //= $current;
2613             print " $current BASE stop\n";
2614             last;
2615         }
2616         my $cl = classify $current;
2617         print " $current $cl->{Type}";
2618         my $keep = 0;
2619         my $p0 = $cl->{Parents}[0]{CommitId};
2620         my $next;
2621         if ($cl->{Type} eq 'Pseudomerge') {
2622             print " ^".($cl->{Contributor}{Ix}+1);
2623             $next = $cl->{Contributor}{CommitId};
2624         } elsif ($cl->{Type} eq 'AddPatches' or
2625                  $cl->{Type} eq 'Changelog') {
2626             print " strip";
2627             $next = $p0;
2628         } else {
2629             print " keep";
2630             $next = $p0;
2631             $keep = 1;
2632         }
2633         print "\n";
2634         if ($keep) {
2635             $topmost_keep //= $current;
2636         } else {
2637             die "to-be stripped changes not on top of the branch\n"
2638                 if $topmost_keep;
2639         }
2640         $current = $next;
2641     }
2642     if ($topmost_keep eq $old_head) {
2643         print "unchanged\n";
2644     } else {
2645         print "updating to $topmost_keep\n";
2646         update_head_checkout
2647             $old_head, $topmost_keep,
2648             'downstream-rebase-launder-v0';
2649     }
2650 }
2651
2652 getoptions_main
2653           ("bad options\n",
2654            "D+" => \$debuglevel,
2655            'noop-ok', => \$opt_noop_ok,
2656            'f=s' => \@snag_force_opts,
2657            'anchor=s' => \@opt_anchors,
2658            '--dgit=s' => \($dgit[0]),
2659            'force!',
2660            '-i:s' => sub {
2661                my ($opt,$val) = @_;
2662                badusage "git-debrebase: no cuddling to -i for git-rebase"
2663                    if length $val;
2664                die if $opt_defaultcmd_interactive; # should not happen
2665                $opt_defaultcmd_interactive = [ qw(-i) ];
2666                # This access to @ARGV is excessive familiarity with
2667                # Getopt::Long, but there isn't another sensible
2668                # approach.  '-i=s{0,}' does not work with bundling.
2669                push @$opt_defaultcmd_interactive, @ARGV;
2670                @ARGV=();
2671            },
2672            'help' => sub { print $usage_message or die $!; finish 0; },
2673            );
2674
2675 initdebug('git-debrebase ');
2676 enabledebug if $debuglevel;
2677
2678 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2679 chdir $toplevel or die "chdir $toplevel: $!";
2680
2681 $rd = fresh_playground "$playprefix/misc";
2682
2683 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2684
2685 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2686     defaultcmd_rebase();
2687 } else {
2688     my $cmd = shift @ARGV;
2689     my $cmdfn = $cmd;
2690     $cmdfn =~ y/-/_/;
2691     $cmdfn = ${*::}{"cmd_$cmdfn"};
2692
2693     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2694     $cmdfn->();
2695 }
2696
2697 finish 0;