git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> <orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] launder         # prints breakwater tip etc.
  32 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  33 #
  34 #    git-debrebase [<options>] gbp2debrebase-v0 \
  35 #             <upstream>
  36
  37 # problems / outstanding questions:
  38 #
  39 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  40 #     fixup.  Usually this involves recommitting the whole patch
  41 #     series, one at a time, with dpkg-source --commit.  This is
  42 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  43 #
  44 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  45 #    git-debrebase stripped out the previous pseudomerge and could
  46 #    have remembeed the HEAD.  But it's not quite clear what history
  47 #    ought to be preserved and what should be discarded.  For now
  48 #    the user will have to tell dgit --overwrite.
  49 #
  50 #    To fix this, do we need a new push hook for dgit ?
  51 #
  52 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  53 #    There's not even a guide.
  54 #
  55 #  * There are no tests.
  56 #
  57 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  58 #    runic command lines.
  59 #
  60 #    One consequence of the lack of richness it can need --force in
  61 #    fairly sensible situations and there is no way to tell it what
  62 #    you are really trying to do, other than just --force.  There
  63 #    should be an interface with some default branch names.
  64 #
  65 #  * There should be a standard convention for the version number,
  66 #    and unfinalised or not changelog, after new-upstream.
  67 #
  68 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  69 #    be broken.  They may be not recognised, improperly converted, or
  70 #    their conversion may be unrecognised.
  71 #
  72 #  * Docs need writing and updating.  Even README.git-debrebase
  73 #    describes a design but may not reflect the implementation.
  74 #
  75 #  * We need to develop a plausible model that works for derivatives,
  76 #    who probably want to maintain their stack on top of Debian's.
  77 #    downstream-rebase-launder-v0 may be a starting point?
  78
  79 use strict;
  80
  81 use Debian::Dgit qw(:DEFAULT :playground);
  82 setup_sigwarn();
  83
  84 use Memoize;
  85 use Carp;
  86 use POSIX;
  87 use Data::Dumper;
  88 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  89 use Dpkg::Version;
  90
  91 our ($opt_force);
  92
  93 sub badusage ($) {
  94     my ($m) = @_;
  95     die "bad usage: $m\n";
  96 }
  97
  98 sub cfg ($) {
  99     my ($k) = @_;
 100     $/ = "\0";
 101     my @cmd = qw(git config -z);
 102     push @cmd, qw(--get-all) if wantarray;
 103     push @cmd, $k;
 104     my $out = cmdoutput @cmd;
 105     return split /\0/, $out;
 106 }
 107
 108 memoize('cfg');
 109
 110 sub dd ($) {
 111     my ($v) = @_;
 112     my $dd = new Data::Dumper [ $v ];
 113     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 114     return Dump $dd;
 115 }
 116
 117 sub get_commit ($) {
 118     my ($objid) = @_;
 119     my $data = (git_cat_file $objid, 'commit');
 120     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 121     return ($`,$');
 122 }
 123
 124 sub D_UPS ()      { 0x02; } # upstream files
 125 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 126 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 127 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 128 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 129 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 130
 131 our $playprefix = 'debrebase';
 132 our $rd;
 133 our $workarea;
 134
 135 our @git = qw(git);
 136
 137 sub in_workarea ($) {
 138     my ($sub) = @_;
 139     changedir $workarea;
 140     my $r = eval { $sub->(); };
 141     { local $@; changedir $maindir; }
 142     die $@ if $@;
 143 }
 144
 145 sub fresh_workarea () {
 146     $workarea = fresh_playground "$playprefix/work";
 147     in_workarea sub { playtree_setup };
 148 }
 149
 150 sub get_differs ($$) {
 151     my ($x,$y) = @_;
 152     # This resembles quiltify_trees_differ, in dgit, a bit.
 153     # But we don't care about modes, or dpkg-source-unrepresentable
 154     # changes, and we don't need the plethora of different modes.
 155     # Conversely we need to distinguish different kinds of changes to
 156     # debian/ and debian/patches/.
 157
 158     my $differs = 0;
 159
 160     my $rundiff = sub {
 161         my ($opts, $limits, $fn) = @_;
 162         my @cmd = (@git, qw(diff-tree -z --no-renames));
 163         push @cmd, @$opts;
 164         push @cmd, "$_:" foreach $x, $y;
 165         push @cmd, '--', @$limits;
 166         my $diffs = cmdoutput @cmd;
 167         foreach (split /\0/, $diffs) { $fn->(); }
 168     };
 169
 170     $rundiff->([qw(--name-only)], [], sub {
 171         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 172     });
 173
 174     if ($differs & DS_DEB) {
 175         $differs &= ~DS_DEB;
 176         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 177             $differs |=
 178                 m{^debian/patches/}      ? D_PAT_OTH  :
 179                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 180                                            D_DEB_OTH;
 181         });
 182         die "mysterious debian changes $x..$y"
 183             unless $differs & (D_PAT_OTH|DS_DEB);
 184     }
 185
 186     if ($differs & D_PAT_OTH) {
 187         my $mode;
 188         $differs &= ~D_PAT_OTH;
 189         my $pat_oth = sub {
 190             $differs |= D_PAT_OTH;
 191             no warnings qw(exiting);  last;
 192         };
 193         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 194             no warnings qw(exiting);
 195             if (!defined $mode) {
 196                 $mode = $_;  next;
 197             }
 198             die unless s{^debian/patches/}{};
 199             my $ok;
 200             if ($mode eq 'A' && !m/\.series$/s) {
 201                 $ok = 1;
 202             } elsif ($mode eq 'M' && $_ eq 'series') {
 203                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 204                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 205                 chomp $x_s;  $x_s .= "\n";
 206                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 207             } else {
 208                 # nope
 209             }
 210             $mode = undef;
 211             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 212         });
 213         die "mysterious debian/patches changes $x..$y"
 214             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 215     }
 216
 217     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 218
 219     return $differs;
 220 }
 221
 222 sub commit_pr_info ($) {
 223     my ($r) = @_;
 224     return Data::Dumper->dump([$r], [qw(commit)]);
 225 }
 226
 227 sub calculate_committer_authline () {
 228     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 229         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 230     my ($h,$m) = get_commit $c;
 231     $h =~ m/^committer .*$/m or confess "($h) ?";
 232     return $&;
 233 }
 234
 235 sub rm_subdir_cached ($) {
 236     my ($subdir) = @_;
 237     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 238 }
 239
 240 sub read_tree_subdir ($$) {
 241     my ($subdir, $new_tree_object) = @_;
 242     rm_subdir_cached $subdir;
 243     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 244 }
 245
 246 sub make_commit ($$) {
 247     my ($parents, $message_paras) = @_;
 248     my $tree = cmdoutput @git, qw(write-tree);
 249     my @cmd = (@git, qw(commit-tree), $tree);
 250     push @cmd, qw(-p), $_ foreach @$parents;
 251     push @cmd, qw(-m), $_ foreach @$message_paras;
 252     return cmdoutput @cmd;
 253 }
 254
 255 our $fproblems;
 256 sub fproblem ($) {
 257     my ($msg) = @_;
 258     $fproblems++;
 259     print STDERR "git-debrebase: safety catch tripped: $msg\n";
 260 }
 261 sub fproblems_maybe_bail () {
 262     if ($fproblems) {
 263         if ($opt_force) {
 264             printf STDERR
 265                 "safety catch trips (%d) overriden by --force\n",
 266                 $fproblems;
 267         } else {
 268             fail sprintf
 269                 "safety catch trips (%d) (you could --force)",
 270                 $fproblems;
 271         }
 272     }
 273 }
 274
 275 # classify returns an info hash like this
 276 #   CommitId => $objid
 277 #   Hdr => # commit headers, including 1 final newline
 278 #   Msg => # commit message (so one newline is dropped)
 279 #   Tree => $treeobjid
 280 #   Type => (see below)
 281 #   Parents = [ {
 282 #       Ix => $index # ie 0, 1, 2, ...
 283 #       CommitId
 284 #       Differs => return value from get_differs
 285 #       IsOrigin
 286 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 287 #     } ...]
 288 #   NewMsg => # commit message, but with any [dgit import ...] edited
 289 #             # to say "[was: ...]"
 290 #
 291 # Types:
 292 #   Packaging
 293 #   Changelog
 294 #   Upstream
 295 #   AddPatches
 296 #   Mixed
 297 #   Unknown
 298 #
 299 #   Pseudomerge
 300 #     has additional entres in classification result
 301 #       Overwritten = [ subset of Parents ]
 302 #       Contributor = $the_remaining_Parent
 303 #
 304 #   DgitImportUnpatched
 305 #     has additional entry in classification result
 306 #       OrigParents = [ subset of Parents ]
 307 #
 308 #   BreakwaterUpstreamMerge
 309 #     has additional entry in classification result
 310 #       OrigParents = [ subset of Parents ]  # singleton list
 311
 312 sub parsecommit ($;$) {
 313     my ($objid, $p_ref) = @_;
 314     # => hash with                   CommitId Hdr Msg Tree Parents
 315     #    Parents entries have only   Ix CommitId
 316     #    $p_ref, if provided, must be [] and is used as a base for Parents
 317
 318     $p_ref //= [];
 319     die if @$p_ref;
 320
 321     my ($h,$m) = get_commit $objid;
 322
 323     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 324     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 325
 326     my $r = {
 327         CommitId => $objid,
 328         Hdr => $h,
 329         Msg => $m,
 330         Tree => $t,
 331         Parents => $p_ref,
 332     };
 333
 334     foreach my $ph (@ph) {
 335         push @$p_ref, {
 336             Ix => scalar @$p_ref,
 337             CommitId => $ph,
 338         };
 339     }
 340
 341     return $r;
 342 }
 343
 344 sub classify ($) {
 345     my ($objid) = @_;
 346
 347     my @p;
 348     my $r = parsecommit($objid, \@p);
 349     my $t = $r->{Tree};
 350
 351     foreach my $p (@p) {
 352         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 353     }
 354
 355     printdebug "classify $objid \$t=$t \@p",
 356         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 357         "\n";
 358
 359     my $classify = sub {
 360         my ($type, @rest) = @_;
 361         $r = { %$r, Type => $type, @rest };
 362         if ($debuglevel) {
 363             printdebug " = $type ".(dd $r)."\n";
 364         }
 365         return $r;
 366     };
 367     my $unknown = sub {
 368         my ($why) = @_;
 369         $r = { %$r, Type => qw(Unknown) };
 370         printdebug " ** Unknown\n";
 371         return $r;
 372     };
 373
 374     if (@p == 1) {
 375         my $d = $r->{Parents}[0]{Differs};
 376         if ($d == D_PAT_ADD) {
 377             return $classify->(qw(AddPatches));
 378         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 379             return $unknown->("edits debian/patches");
 380         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 381             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 382             if ($ty eq 'tree') {
 383                 if ($d == D_DEB_CLOG) {
 384                     return $classify->(qw(Changelog));
 385                 } else {
 386                     return $classify->(qw(Packaging));
 387                 }
 388             } elsif ($ty eq 'missing') {
 389                 return $classify->(qw(BreakwaterStart));
 390             } else {
 391                 return $unknown->("parent's debian is not a directory");
 392             }
 393         } elsif ($d == D_UPS) {
 394             return $classify->(qw(Upstream));
 395         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 396             return $classify->(qw(Mixed));
 397         } elsif ($d == 0) {
 398             return $unknown->("no changes");
 399         } else {
 400             confess "internal error $objid ?";
 401         }
 402     }
 403     if (!@p) {
 404         return $unknown->("origin commit");
 405     }
 406
 407     my @identical = grep { !$_->{Differs} } @p;
 408     if (@p == 2 && @identical == 1) {
 409         my @overwritten = grep { $_->{Differs} } @p;
 410         confess "internal error $objid ?" unless @overwritten==1;
 411         return $classify->(qw(Pseudomerge),
 412                            Overwritten => $overwritten[0],
 413                            Contributor => $identical[0]);
 414     }
 415     if (@p == 2 && @identical == 2) {
 416         my @bytime = nsort_by {
 417             my ($ph,$pm) = get_commit $_->{CommitId};
 418             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 419             $1;
 420         } @p;
 421         return $classify->(qw(Pseudomerge),
 422                            SubType => qw(Ambiguous),
 423                            Overwritten => $bytime[0],
 424                            Contributor => $bytime[1]);
 425     }
 426     foreach my $p (@p) {
 427         my ($p_h, $p_m) = get_commit $p->{CommitId};
 428         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 429         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 430     }
 431     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 432     my $m2 = $r->{Msg};
 433     if (!(grep { !$_->{IsOrigin} } @p) and
 434         (@orig_ps >= @p - 1) and
 435         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 436         $r->{NewMsg} = $m2;
 437         return $classify->(qw(DgitImportUnpatched),
 438                            OrigParents => \@orig_ps);
 439     }
 440
 441     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 442     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 443
 444     # How to decide about l/r ordering of breakwater merges ?  git
 445     # --topo-order prefers to expand 2nd parent first.  There's
 446     # already an easy rune to look for debian/ history anyway (git log
 447     # debian/) so debian breakwater branch should be 1st parent; that
 448     # way also there's also an easy rune to look for the upstream
 449     # patches (--topo-order).
 450
 451     # The above tells us which way *we* will generate them.  But we
 452     # might encounter ad-hoc breakwater merges generated manually,
 453     # which might be the other way around.  In principle, in some odd
 454     # situations, a breakwater merge might have two identical parents.
 455     # In that case we guess which way round it is (ie, which parent
 456     # has the upstream history).  The order of the 2-iteration loop
 457     # controls which guess we make.
 458
 459     foreach my $prevbrw (qw(0 1)) {
 460         if (@p == 2 &&
 461             !$haspatches &&
 462             !$p[$prevbrw]{IsOrigin} && # breakwater never starts with an origin
 463             !($p[!$prevbrw]{Differs} & ~DS_DEB) && # no non-debian changess
 464             !($p[$prevbrw]{Differs} & ~D_UPS)) { # no non-upstream changes
 465             return $classify->(qw(BreakwaterUpstreamMerge),
 466                                OrigParents => [ $p[!$prevbrw] ]);
 467         }
 468     }
 469
 470     # multi-orig upstreams are represented with a breakwater merge
 471     # from a single upstream commit which combines the orig tarballs
 472
 473     return $unknown->("complex merge");
 474 }
 475
 476 sub walk ($;$$);
 477 sub walk ($;$$) {
 478     my ($input,
 479         $nogenerate,$report) = @_;
 480     # => ($tip, $breakwater_tip, $last_upstream_merge_in_breakwater)
 481     # (or nothing, if $nogenerate)
 482
 483     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 484
 485     # go through commits backwards
 486     # we generate two lists of commits to apply:
 487     # breakwater branch and upstream patches
 488     my (@brw_cl, @upp_cl, @processed);
 489     my %found;
 490     my $upp_limit;
 491     my @pseudomerges;
 492
 493     my $cl;
 494     my $xmsg = sub {
 495         my ($prose, $info) = @_;
 496         my $ms = $cl->{Msg};
 497         chomp $ms;
 498         $info //= '';
 499         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 500         return (Msg => $ms);
 501     };
 502     my $rewrite_from_here = sub {
 503         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 504         push @brw_cl, $sp_cl;
 505         push @processed, $sp_cl;
 506     };
 507     my $cur = $input;
 508
 509     my $prdelim = "";
 510     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 511
 512     my $prline = sub {
 513         return unless $report;
 514         print $report $prdelim, @_;
 515         $prdelim = "\n";
 516     };
 517
 518     my $bomb = sub { # usage: return $bomb->();
 519         print $report " Unprocessable" if $report;
 520         $prprdelim->();
 521         if ($nogenerate) {
 522             return (undef,undef);
 523         }
 524         die "commit $cur: Cannot cope with this commit (d.".
 525             (join ' ', map { sprintf "%#x", $_->{Differs} }
 526              @{ $cl->{Parents} }). ")";
 527     };
 528
 529     my $build;
 530     my $breakwater;
 531
 532     my $build_start = sub {
 533         my ($msg, $parent) = @_;
 534         $prline->(" $msg");
 535         $build = $parent;
 536         no warnings qw(exiting); last;
 537     };
 538
 539     my $last_upstream_update;
 540
 541     for (;;) {
 542         $cl = classify $cur;
 543         my $ty = $cl->{Type};
 544         my $st = $cl->{SubType};
 545         $prline->("$cl->{CommitId} $cl->{Type}");
 546         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 547         push @processed, $cl;
 548         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 549         if ($ty eq 'AddPatches') {
 550             $cur = $p0;
 551             $rewrite_from_here->();
 552             next;
 553         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 554             push @brw_cl, $cl;
 555             $cur = $p0;
 556             next;
 557         } elsif ($ty eq 'BreakwaterStart') {
 558             $last_upstream_update = $cur;
 559             $build_start->('FirstPackaging', $cur);
 560         } elsif ($ty eq 'Upstream') {
 561             push @upp_cl, $cl;
 562             $cur = $p0;
 563             next;
 564         } elsif ($ty eq 'Mixed') {
 565             my $queue = sub {
 566                 my ($q, $wh) = @_;
 567                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 568                 push @$q, $cls;
 569             };
 570             $queue->(\@brw_cl, "debian");
 571             $queue->(\@upp_cl, "upstream");
 572             $rewrite_from_here->();
 573             $cur = $p0;
 574             next;
 575         } elsif ($ty eq 'Pseudomerge') {
 576             my $contrib = $cl->{Contributor}{CommitId};
 577             print $report " Contributor=$contrib" if $report;
 578             push @pseudomerges, $cl;
 579             $rewrite_from_here->();
 580             $cur = $contrib;
 581             next;
 582         } elsif ($ty eq 'BreakwaterUpstreamMerge') {
 583             $last_upstream_update = $cur;
 584             $build_start->("PreviousBreakwater", $cur);
 585         } elsif ($ty eq 'DgitImportUnpatched') {
 586             my $pm = $pseudomerges[-1];
 587             if (defined $pm) {
 588                 # To an extent, this is heuristic.  Imports don't have
 589                 # a useful history of the debian/ branch.  We assume
 590                 # that the first pseudomerge after an import has a
 591                 # useful history of debian/, and ignore the histories
 592                 # from later pseudomerges.  Often the first pseudomerge
 593                 # will be the dgit import of the upload to the actual
 594                 # suite intended by the non-dgit NMUer, and later
 595                 # pseudomerges may represent in-archive copies.
 596                 my $ovwrs = $pm->{Overwritten};
 597                 printf $report " PM=%s \@Overwr:%d", $pm, (scalar @$ovwrs)
 598                     if $report;
 599                 if (@$ovwrs != 1) {
 600                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 601                     return $bomb->();
 602                 }
 603                 my $ovwr = $ovwrs->[0]{CommitId};
 604                 printf $report " Overwr=%s", $ovwr if $report;
 605                 # This import has a tree which is just like a
 606                 # breakwater tree, but it has the wrong history.  It
 607                 # ought to have the previous breakwater (which the
 608                 # pseudomerge overwrote) as an ancestor.  That will
 609                 # make the history of the debian/ files correct.  As
 610                 # for the upstream version: either it's the same as
 611                 # was ovewritten (ie, same as the previous
 612                 # breakwater), in which case that history is precisely
 613                 # right; or, otherwise, it was a non-gitish upload of a
 614                 # new upstream version.  We can tell these apart by
 615                 # looking at the tree of the supposed upstream.
 616                 push @brw_cl, {
 617                     %$cl,
 618                     SpecialMethod => 'DgitImportDebianUpdate',
 619                     $xmsg->("convert dgit import: debian changes")
 620                 };
 621                 my $differs = (get_differs $ovwr, $cl->{Tree});
 622                 printf $report " Differs=%#x", $differs if $report;
 623                 if ($differs & D_UPS) {
 624                     printf $report " D_UPS" if $report;
 625                     # This will also trigger if a non-dgit git-based NMU
 626                     # deleted .gitignore (which is a thing that some of
 627                     # the existing git tools do if the user doesn't
 628                     # somehow tell them not to).  Ah well.
 629                     push @brw_cl, {
 630                         %$cl,
 631                         SpecialMethod => 'DgitImportUpstreamUpdate',
 632                         $xmsg->("convert dgit import: upstream changes",
 633                                 " breakwater")
 634                     };
 635                 }
 636                 $prline->(" Import");
 637                 $rewrite_from_here->();
 638                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 639                 die 'BUG $upp_limit is not used anywhere?';
 640                 $cur = $ovwr;
 641                 next;
 642             } else {
 643                 # Everything is from this import.  This kind of import
 644                 # is already in valid breakwater format, with the
 645                 # patches as commits.
 646                 printf $report " NoPM" if $report;
 647                 # last thing we processed will have been the first patch,
 648                 # if there is one; which is fine, so no need to rewrite
 649                 # on account of this import
 650                 $build_start->("ImportOrigin", $cur);
 651             }
 652             die "$ty ?";
 653         } else {
 654             printdebug "*** WALK BOMB unrecognised\n";
 655             return $bomb->();
 656         }
 657     }
 658     $prprdelim->();
 659
 660     printdebug "*** WALK prep done cur=$cur".
 661         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 662
 663     return if $nogenerate;
 664
 665     # Now we build it back up again
 666
 667     fresh_workarea();
 668
 669     my $rewriting = 0;
 670
 671     my $read_tree_debian = sub {
 672         my ($treeish) = @_;
 673         read_tree_subdir 'debian', "$treeish:debian";
 674         rm_subdir_cached 'debian/patches';
 675     };
 676     my $read_tree_upstream = sub {
 677         my ($treeish) = @_;
 678         runcmd @git, qw(read-tree), $treeish;
 679         $read_tree_debian->($build);
 680     };
 681
 682     my $committer_authline = calculate_committer_authline();
 683
 684     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 685
 686     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 687
 688     in_workarea sub {
 689         mkdir $rd or $!==EEXIST or die $!;
 690         my $current_method;
 691         runcmd @git, qw(read-tree), $build;
 692         foreach my $cl (qw(Debian), (reverse @brw_cl),
 693                         { SpecialMethod => 'RecordBreakwaterTip' },
 694                         qw(Upstream), (reverse @upp_cl)) {
 695             if (!ref $cl) {
 696                 $current_method = $cl;
 697                 next;
 698             }
 699             my $method = $cl->{SpecialMethod} // $current_method;
 700             my @parents = ($build);
 701             my $cltree = $cl->{CommitId};
 702             printdebug "WALK BUILD ".($cltree//'undef').
 703                 " $method (rewriting=$rewriting)\n";
 704             if ($method eq 'Debian') {
 705                 $read_tree_debian->($cltree);
 706             } elsif ($method eq 'Upstream') {
 707                 $read_tree_upstream->($cltree);
 708             } elsif ($method eq 'StartRewrite') {
 709                 $rewriting = 1;
 710                 next;
 711             } elsif ($method eq 'RecordBreakwaterTip') {
 712                 $breakwater = $build;
 713                 next;
 714             } elsif ($method eq 'DgitImportDebianUpdate') {
 715                 $read_tree_debian->($cltree);
 716                 rm_subdir_cached qw(debian/patches);
 717             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 718                 $read_tree_upstream->($cltree);
 719                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 720             } else {
 721                 confess "$method ?";
 722             }
 723             if (!$rewriting) {
 724                 my $procd = (pop @processed) // 'UNDEF';
 725                 if ($cl ne $procd) {
 726                     $rewriting = 1;
 727                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 728                 }
 729             }
 730             my $newtree = cmdoutput @git, qw(write-tree);
 731             my $ch = $cl->{Hdr};
 732             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 733             $ch =~ s{^parent .*\n}{}m;
 734             $ch =~ s{(?=^author)}{
 735                 join '', map { "parent $_\n" } @parents
 736             }me or confess "$ch ?";
 737             if ($rewriting) {
 738                 $ch =~ s{^committer .*$}{$committer_authline}m
 739                     or confess "$ch ?";
 740             }
 741             my $cf = "$rd/m$rewriting";
 742             open CD, ">", $cf or die $!;
 743             print CD $ch, "\n", $cl->{Msg} or die $!;
 744             close CD or die $!;
 745             my @cmd = (@git, qw(hash-object));
 746             push @cmd, qw(-w) if $rewriting;
 747             push @cmd, qw(-t commit), $cf;
 748             my $newcommit = cmdoutput @cmd;
 749             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 750             $build = $newcommit;
 751             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 752                 $last_upstream_update = $cur;
 753             }
 754         }
 755     };
 756
 757     my $final_check = get_differs $build, $input;
 758     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 759         if $final_check & ~D_PAT_ADD;
 760
 761     my @r = ($build, $breakwater, $last_upstream_update);
 762     printdebug "*** WALK RETURN @r\n";
 763     return @r
 764 }
 765
 766 sub get_head () { return git_rev_parse qw(HEAD); }
 767
 768 sub update_head ($$$) {
 769     my ($old, $new, $mrest) = @_;
 770     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 771 }
 772
 773 sub update_head_checkout ($$$) {
 774     my ($old, $new, $mrest) = @_;
 775     update_head $old, $new, $mrest;
 776     runcmd @git, qw(reset --hard);
 777 }
 778
 779 sub update_head_postlaunder ($$$) {
 780     my ($old, $tip, $reflogmsg) = @_;
 781     return if $tip eq $old;
 782     print "git-debrebase: laundered (head was $old)\n";
 783     update_head $old, $tip, $reflogmsg;
 784     # no tree changes except debian/patches
 785     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 786 }
 787
 788 sub cmd_launder () {
 789     badusage "no arguments to launder allowed" if @ARGV;
 790     my $old = get_head();
 791     my ($tip,$breakwater,$last_upstream_merge) = walk $old;
 792     update_head_postlaunder $old, $tip, 'launder';
 793     printf "# breakwater tip\n%s\n", $breakwater;
 794     printf "# working tip\n%s\n", $tip;
 795     printf "# last upstream merge\n%s\n", $last_upstream_merge;
 796 }
 797
 798 sub defaultcmd_rebase () {
 799     my $old = get_head();
 800     my ($tip,$breakwater) = walk $old;
 801     update_head_postlaunder $old, $tip, 'launder for rebase';
 802     @ARGV = qw(-i) unless @ARGV; # make configurable
 803     runcmd @git, qw(rebase), @ARGV, $breakwater;
 804 }
 805
 806 sub cmd_analyse () {
 807     die if ($ARGV[0]//'') =~ m/^-/;
 808     badusage "too many arguments to analyse" if @ARGV>1;
 809     my ($old) = @ARGV;
 810     if (defined $old) {
 811         $old = git_rev_parse $old;
 812     } else {
 813         $old = get_head();
 814     }
 815     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 816     STDOUT->error and die $!;
 817 }
 818
 819 sub cmd_new_upstream_v0 () {
 820     # tree should be clean and this is not checked
 821     # automatically and unconditionally launders before rebasing
 822     # if rebase --abort is used, laundering has still been done
 823
 824     my %pieces;
 825
 826     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
 827
 828     # parse args - low commitment
 829     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
 830     my $new_upstream_version = $new_version->version();
 831
 832     my $new_upstream = git_rev_parse shift @ARGV;
 833
 834     my $piece = sub {
 835         my ($n, @x) = @_; # may be ''
 836         my $pc = $pieces{$n} //= {
 837             Name => $n,
 838             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
 839         };
 840         while (my $k = shift @x) { $pc->{$k} = shift @x; }
 841         $pc;
 842     };
 843
 844     my @newpieces;
 845     my $newpiece = sub {
 846         my ($n, @x) = @_; # may be ''
 847         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
 848         push @newpieces, $pc;
 849     };
 850
 851     $newpiece->('',
 852         OldIx => 0,
 853         New => $new_upstream,
 854     );
 855     while (@ARGV && $ARGV[0] !~ m{^-}) {
 856         my $n = shift @ARGV;
 857
 858         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
 859             unless @ARGV && $ARGV[0] !~ m{^-};
 860
 861         my $c = git_rev_parse shift @ARGV;
 862         die unless $n =~ m/^$extra_orig_namepart_re$/;
 863         $newpiece->($n, New => $c);
 864     }
 865
 866     # now we need to investigate the branch this generates the
 867     # laundered version but we don't switch to it yet
 868     my $old_head = get_head();
 869     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
 870
 871     my $old_bw_cl = classify $old_bw;
 872     my $old_upstream_update_cl = classify $old_upstream_update;
 873     confess unless $old_upstream_update_cl->{OrigParents};
 874     my $old_upstream = parsecommit
 875         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
 876
 877     $piece->('', Old => $old_upstream->{CommitId});
 878
 879     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
 880         if ($old_upstream->{Msg} =~
 881  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
 882            ) {
 883             my @oldpieces = ('', split / /, $1);
 884             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
 885             foreach my $i (0..$#oldpieces) {
 886                 my $n = $oldpieces[$i];
 887                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
 888             }
 889         } else {
 890             fproblem "previous upstream $old_upstream->{CommitId} is from".
 891                  " git-debrebase but not an \`upstream-combine' commit";
 892         }
 893     }
 894
 895     foreach my $pc (values %pieces) {
 896         if (!$pc->{Old}) {
 897             fproblem "introducing upstream piece \`$pc->{Name}'";
 898         } elsif (!$pc->{New}) {
 899             fproblem "dropping upstream piece \`$pc->{Name}'";
 900         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
 901             fproblem "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
 902         }
 903     }
 904
 905     printdebug "%pieces = ", (dd \%pieces), "\n";
 906     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
 907
 908     fproblems_maybe_bail();
 909
 910     my $new_bw;
 911
 912     fresh_workarea();
 913     in_workarea sub {
 914         my @upstream_merge_parents;
 915
 916         if (!$fproblems) {
 917             push @upstream_merge_parents, $old_upstream->{CommitId};
 918         }
 919
 920         foreach my $pc (@newpieces) { # always has '' first
 921             if ($pc->{Name}) {
 922                 read_tree_subdir $pc->{Name}, $pc->{New};
 923             } else {
 924                 runcmd @git, qw(read-tree), $pc->{New};
 925             }
 926             push @upstream_merge_parents, $pc->{New};
 927         }
 928
 929         # index now contains the new upstream
 930
 931         if (@newpieces > 1) {
 932             # need to make the upstream subtree merge commit
 933             $new_upstream = make_commit \@upstream_merge_parents,
 934                 [ "Combine upstreams for $new_upstream_version",
 935  ("[git-debrebase upstream-combine . ".
 936  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
 937  ": new upstream]"),
 938                 ];
 939         }
 940
 941         # $new_upstream is either the single upstream commit, or the
 942         # combined commit we just made.  Either way it will be the
 943         # "upstream" parent of the breakwater special merge.
 944
 945         read_tree_subdir 'debian', "$old_bw:debian";
 946
 947         # index now contains the breakwater merge contents
 948         $new_bw = make_commit [ $old_bw, $new_upstream ],
 949             [ "Update to upstream $new_upstream_version",
 950  "[git-debrebase breakwater: new upstream $new_upstream_version, merge]",
 951             ];
 952
 953         # Now we have to add a changelog stanza so the Debian version
 954         # is right.
 955         die if unlink "debian";
 956         die $! unless $!==ENOENT or $!==ENOTEMPTY;
 957         unlink "debian/changelog" or $!==ENOENT or die $!;
 958         mkdir "debian" or die $!;
 959         open CN, ">", "debian/changelog" or die $!;
 960         my $oldclog = git_cat_file ":debian/changelog";
 961         $oldclog =~ m/^($package_re) \(\S+\) / or
 962             fail "cannot parse old changelog to get package name";
 963         my $p = $1;
 964         print CN <<END, $oldclog or die $!;
 965 $p ($new_version) UNRELEASED; urgency=medium
 966
 967   * Update to new upstream version $new_upstream_version.
 968
 969  --
 970
 971 END
 972         close CN or die $!;
 973         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
 974
 975         # Now we have the final new breakwater branch in the index
 976         $new_bw = make_commit [ $new_bw ],
 977             [ "Update changelog for new upstream $new_upstream_version",
 978               "[git-debrebase: new upstream $new_upstream_version, changelog]",
 979             ];
 980     };
 981
 982     # we have constructed the new breakwater. we now need to commit to
 983     # the laundering output, because git-rebase can't easily be made
 984     # to make a replay list which is based on some other branch
 985
 986     update_head_postlaunder $old_head, $old_laundered_tip,
 987         'launder for new upstream';
 988
 989     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
 990     runcmd @cmd;
 991     # now it's for the user to sort out
 992 }
 993
 994 sub cmd_gbp2debrebase () {
 995     badusage "needs 1 optional argument, the upstream" unless @ARGV<=1;
 996     my ($upstream_spec) = @ARGV;
 997     $upstream_spec //= 'refs/heads/upstream';
 998     my $upstream = git_rev_parse $upstream_spec;
 999     my $old_head = get_head();
1000
1001     my $upsdiff = get_differs $upstream, $old_head;
1002     if ($upsdiff & D_UPS) {
1003         runcmd @git, qw(--no-pager diff),
1004             $upstream, $old_head,
1005             qw( -- :!/debian :/);
1006  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1007     }
1008
1009     if (!is_fast_fwd $upstream, $old_head) {
1010         fproblem "upstream ($upstream) is not an ancestor of HEAD";
1011     } else {
1012         my $wrong = cmdoutput
1013             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1014              qw(-- :/ :!/debian));
1015         if (length $wrong) {
1016             fproblem "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1017             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1018         }
1019     }
1020
1021     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1022         fproblem "upstream ($upstream) contains debian/ directory";
1023     }
1024
1025     fproblems_maybe_bail();
1026
1027     my $work;
1028
1029     fresh_workarea();
1030     in_workarea sub {
1031         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1032         # make a branch out of the patch queue - we'll want this in a mo
1033         runcmd qw(gbp pq import);
1034         # strip the patches out
1035         runcmd @git, qw(checkout -q gdr-internal~0);
1036         rm_subdir_cached 'debian/patches';
1037         $work = make_commit ['HEAD'], [
1038  'git-debrebase import: drop patch queue',
1039  'Delete debian/patches, as part of converting to git-debrebase format.',
1040  '[git-debrebase: gbp2debrebase, drop patches]'
1041                               ];
1042         # make the breakwater pseudomerge
1043         # the tree is already exactly right
1044         $work = make_commit [$work, $upstream], [
1045  'git-debrebase import: declare upstream',
1046  'First breakwater merge.',
1047  '[git-debrebase breakwater: declare upstream]'
1048                               ];
1049
1050         # rebase the patch queue onto the new breakwater
1051         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1052         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1053         $work = get_head();
1054     };
1055
1056     update_head_checkout $old_head, $work, 'gbp2debrebase';
1057 }
1058
1059 sub cmd_downstream_rebase_launder_v0 () {
1060     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1061     my ($base) = @ARGV;
1062     $base = git_rev_parse $base;
1063     my $old_head = get_head();
1064     my $current = $old_head;
1065     my $topmost_keep;
1066     for (;;) {
1067         if ($current eq $base) {
1068             $topmost_keep //= $current;
1069             print " $current BASE stop\n";
1070             last;
1071         }
1072         my $cl = classify $current;
1073         print " $current $cl->{Type}";
1074         my $keep = 0;
1075         my $p0 = $cl->{Parents}[0]{CommitId};
1076         my $next;
1077         if ($cl->{Type} eq 'Pseudomerge') {
1078             print " ^".($cl->{Contributor}{Ix}+1);
1079             $next = $cl->{Contributor}{CommitId};
1080         } elsif ($cl->{Type} eq 'AddPatches' or
1081                  $cl->{Type} eq 'Changelog') {
1082             print " strip";
1083             $next = $p0;
1084         } else {
1085             print " keep";
1086             $next = $p0;
1087             $keep = 1;
1088         }
1089         print "\n";
1090         if ($keep) {
1091             $topmost_keep //= $current;
1092         } else {
1093             die "to-be stripped changes not on top of the branch\n"
1094                 if $topmost_keep;
1095         }
1096         $current = $next;
1097     }
1098     if ($topmost_keep eq $old_head) {
1099         print "unchanged\n";
1100     } else {
1101         print "updating to $topmost_keep\n";
1102         update_head_checkout
1103             $old_head, $topmost_keep,
1104             'downstream-rebase-launder-v0';
1105     }
1106 }
1107
1108 GetOptions("D+" => \$debuglevel,
1109            'force!') or die badusage "bad options\n";
1110 initdebug('git-debrebase ');
1111 enabledebug if $debuglevel;
1112
1113 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1114 chdir $toplevel or die "chdir $toplevel: $!";
1115
1116 $rd = fresh_playground "$playprefix/misc";
1117
1118 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1119     defaultcmd_rebase();
1120 } else {
1121     my $cmd = shift @ARGV;
1122     my $cmdfn = $cmd;
1123     $cmdfn =~ y/-/_/;
1124     $cmdfn = ${*::}{"cmd_$cmdfn"};
1125
1126     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1127     $cmdfn->();
1128 }