git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # usages:
  23 #
  24 #    git-debrebase [<options>] new-upstream-v0 \
  25 #             <new-version> <orig-commitish> \
  26 #            [<extra-orig-name> <extra-orig-commitish> ...] \
  27 #            [<git-rebase options>...]
  28 #
  29 #    git-debrebase [<options> --] [<git-rebase options...>]
  30 #    git-debrebase [<options>] analyse
  31 #    git-debrebase [<options>] breakwater      # prints breakwater tip only
  32 #    git-debrebase [<options>] stitch [--prose=<for commit message>]
  33 #    git-debrebase [<options>] launder-v0      # prints breakwater tip etc.
  34 #    git-debrebase [<options>] downstream-rebase-launder-v0  # experimental
  35 #
  36 #    git-debrebase [<options>] convert-from-gbp [<upstream-git-rev>]
  37 #    git-debrebase [<options>] convert-to-gbp
  38
  39 # problems / outstanding questions:
  40 #
  41 #  *  dgit push with a `3.0 (quilt)' package means doing quilt
  42 #     fixup.  Usually this involves recommitting the whole patch
  43 #     series, one at a time, with dpkg-source --commit.  This is
  44 #     terribly terribly slow.  (Maybe this should be fixed in dgit.)
  45 #
  46 #  * dgit push usually needs to (re)make a pseudomerge.  The "first"
  47 #    git-debrebase stripped out the previous pseudomerge and could
  48 #    have remembeed the HEAD.  But it's not quite clear what history
  49 #    ought to be preserved and what should be discarded.  For now
  50 #    the user will have to tell dgit --overwrite.
  51 #
  52 #    To fix this, do we need a new push hook for dgit ?
  53 #
  54 #  * Workflow is currently clumsy.  Lots of spurious runes to type.
  55 #    There's not even a guide.
  56 #
  57 #  * There are no tests.
  58 #
  59 #  * new-upstream-v0 has a terrible UI.  You end up with giant
  60 #    runic command lines.
  61 #
  62 #    One consequence of the lack of richness it can need --force in
  63 #    fairly sensible situations and there is no way to tell it what
  64 #    you are really trying to do, other than just --force.  There
  65 #    should be an interface with some default branch names.
  66 #
  67 #  * There should be a standard convention for the version number,
  68 #    and unfinalised or not changelog, after new-upstream.
  69 #
  70 #  * Handing of multi-orig dgit new-upstream .dsc imports is known to
  71 #    be broken.  They may be not recognised, improperly converted, or
  72 #    their conversion may be unrecognised.
  73 #
  74 #  * Docs need writing and updating.  Even README.git-debrebase
  75 #    describes a design but may not reflect the implementation.
  76 #
  77 #  * We need to develop a plausible model that works for derivatives,
  78 #    who probably want to maintain their stack on top of Debian's.
  79 #    downstream-rebase-launder-v0 may be a starting point?
  80
  81 use strict;
  82
  83 use Debian::Dgit qw(:DEFAULT :playground);
  84 setup_sigwarn();
  85
  86 use Memoize;
  87 use Carp;
  88 use POSIX;
  89 use Data::Dumper;
  90 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  91 use Dpkg::Version;
  92 use File::FnMatch qw(:fnmatch);
  93
  94 our ($opt_force, $opt_noop_ok);
  95
  96 our $us = qw(git-debrebase);
  97
  98 sub badusage ($) {
  99     my ($m) = @_;
 100     die "bad usage: $m\n";
 101 }
 102
 103 sub cfg ($;$) {
 104     my ($k, $optional) = @_;
 105     local $/ = "\0";
 106     my @cmd = qw(git config -z);
 107     push @cmd, qw(--get-all) if wantarray;
 108     push @cmd, $k;
 109     my $out = cmdoutput_errok @cmd;
 110     if (!defined $out) {
 111         fail "missing required git config $k" unless $optional;
 112         return ();
 113     }
 114     my @l = split /\0/, $out;
 115     return wantarray ? @l : $l[0];
 116 }
 117
 118 memoize('cfg');
 119
 120 sub dd ($) {
 121     my ($v) = @_;
 122     my $dd = new Data::Dumper [ $v ];
 123     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
 124     return Dump $dd;
 125 }
 126
 127 sub get_commit ($) {
 128     my ($objid) = @_;
 129     my $data = (git_cat_file $objid, 'commit');
 130     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 131     return ($`,$');
 132 }
 133
 134 sub D_UPS ()      { 0x02; } # upstream files
 135 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 136 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 137 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 138 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 139 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 140
 141 our $playprefix = 'debrebase';
 142 our $rd;
 143 our $workarea;
 144
 145 our @git = qw(git);
 146
 147 sub in_workarea ($) {
 148     my ($sub) = @_;
 149     changedir $workarea;
 150     my $r = eval { $sub->(); };
 151     { local $@; changedir $maindir; }
 152     die $@ if $@;
 153 }
 154
 155 sub fresh_workarea () {
 156     $workarea = fresh_playground "$playprefix/work";
 157     in_workarea sub { playtree_setup };
 158 }
 159
 160 sub get_differs ($$) {
 161     my ($x,$y) = @_;
 162     # This resembles quiltify_trees_differ, in dgit, a bit.
 163     # But we don't care about modes, or dpkg-source-unrepresentable
 164     # changes, and we don't need the plethora of different modes.
 165     # Conversely we need to distinguish different kinds of changes to
 166     # debian/ and debian/patches/.
 167
 168     my $differs = 0;
 169
 170     my $rundiff = sub {
 171         my ($opts, $limits, $fn) = @_;
 172         my @cmd = (@git, qw(diff-tree -z --no-renames));
 173         push @cmd, @$opts;
 174         push @cmd, "$_:" foreach $x, $y;
 175         push @cmd, '--', @$limits;
 176         my $diffs = cmdoutput @cmd;
 177         foreach (split /\0/, $diffs) { $fn->(); }
 178     };
 179
 180     $rundiff->([qw(--name-only)], [], sub {
 181         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 182     });
 183
 184     if ($differs & DS_DEB) {
 185         $differs &= ~DS_DEB;
 186         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 187             $differs |=
 188                 m{^debian/patches/}      ? D_PAT_OTH  :
 189                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 190                                            D_DEB_OTH;
 191         });
 192         die "mysterious debian changes $x..$y"
 193             unless $differs & (D_PAT_OTH|DS_DEB);
 194     }
 195
 196     if ($differs & D_PAT_OTH) {
 197         my $mode;
 198         $differs &= ~D_PAT_OTH;
 199         my $pat_oth = sub {
 200             $differs |= D_PAT_OTH;
 201             no warnings qw(exiting);  last;
 202         };
 203         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 204             no warnings qw(exiting);
 205             if (!defined $mode) {
 206                 $mode = $_;  next;
 207             }
 208             die unless s{^debian/patches/}{};
 209             my $ok;
 210             if ($mode eq 'A' && !m/\.series$/s) {
 211                 $ok = 1;
 212             } elsif ($mode eq 'M' && $_ eq 'series') {
 213                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 214                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 215                 chomp $x_s;  $x_s .= "\n";
 216                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 217             } else {
 218                 # nope
 219             }
 220             $mode = undef;
 221             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 222         });
 223         die "mysterious debian/patches changes $x..$y"
 224             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 225     }
 226
 227     printdebug sprintf "get_differs %s, %s = %#x\n", $x, $y, $differs;
 228
 229     return $differs;
 230 }
 231
 232 sub commit_pr_info ($) {
 233     my ($r) = @_;
 234     return Data::Dumper->dump([$r], [qw(commit)]);
 235 }
 236
 237 sub calculate_committer_authline () {
 238     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 239         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 240     my ($h,$m) = get_commit $c;
 241     $h =~ m/^committer .*$/m or confess "($h) ?";
 242     return $&;
 243 }
 244
 245 sub rm_subdir_cached ($) {
 246     my ($subdir) = @_;
 247     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 248 }
 249
 250 sub read_tree_subdir ($$) {
 251     my ($subdir, $new_tree_object) = @_;
 252     rm_subdir_cached $subdir;
 253     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 254 }
 255
 256 sub make_commit ($$) {
 257     my ($parents, $message_paras) = @_;
 258     my $tree = cmdoutput @git, qw(write-tree);
 259     my @cmd = (@git, qw(commit-tree), $tree);
 260     push @cmd, qw(-p), $_ foreach @$parents;
 261     push @cmd, qw(-m), $_ foreach @$message_paras;
 262     return cmdoutput @cmd;
 263 }
 264
 265 our @fproblem_force_opts;
 266 our $fproblems_forced;
 267 our $fproblems_tripped;
 268 sub fproblem ($$) {
 269     my ($tag,$msg) = @_;
 270     if (grep { $_ eq $tag } @fproblem_force_opts) {
 271         $fproblems_forced++;
 272         print STDERR "git-debrebase: safety catch overridden (-f$tag): $msg\n";
 273     } else {
 274         $fproblems_tripped++;
 275         print STDERR "git-debrebase: safety catch tripped (-f$tag): $msg\n";
 276     }
 277 }
 278
 279 sub fproblems_maybe_bail () {
 280     if ($fproblems_forced) {
 281         printf STDERR
 282             "%s: safety catch trips: %d overriden by individual -f options\n",
 283             $us, $fproblems_forced;
 284     }
 285     if ($fproblems_tripped) {
 286         if ($opt_force) {
 287             printf STDERR
 288                 "%s: safety catch trips: %d overriden by global --force\n",
 289                 $us, $fproblems_tripped;
 290         } else {
 291             fail sprintf
 292   "%s: safety catch trips: %d blockers (you could -f<tag>, or --force)",
 293                 $us, $fproblems_tripped;
 294         }
 295     }
 296 }
 297 sub any_fproblems () {
 298     return $fproblems_forced || $fproblems_tripped;
 299 }
 300
 301 # classify returns an info hash like this
 302 #   CommitId => $objid
 303 #   Hdr => # commit headers, including 1 final newline
 304 #   Msg => # commit message (so one newline is dropped)
 305 #   Tree => $treeobjid
 306 #   Type => (see below)
 307 #   Parents = [ {
 308 #       Ix => $index # ie 0, 1, 2, ...
 309 #       CommitId
 310 #       Differs => return value from get_differs
 311 #       IsOrigin
 312 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 313 #     } ...]
 314 #   NewMsg => # commit message, but with any [dgit import ...] edited
 315 #             # to say "[was: ...]"
 316 #
 317 # Types:
 318 #   Packaging
 319 #   Changelog
 320 #   Upstream
 321 #   AddPatches
 322 #   Mixed
 323 #
 324 #   Pseudomerge
 325 #     has additional entres in classification result
 326 #       Overwritten = [ subset of Parents ]
 327 #       Contributor = $the_remaining_Parent
 328 #
 329 #   DgitImportUnpatched
 330 #     has additional entry in classification result
 331 #       OrigParents = [ subset of Parents ]
 332 #
 333 #   Anchor
 334 #     has additional entry in classification result
 335 #       OrigParents = [ subset of Parents ]  # singleton list
 336 #
 337 #   BreakwaterStart
 338 #
 339 #   Unknown
 340 #     has additional entry in classification result
 341 #       Why => "prose"
 342
 343 sub parsecommit ($;$) {
 344     my ($objid, $p_ref) = @_;
 345     # => hash with                   CommitId Hdr Msg Tree Parents
 346     #    Parents entries have only   Ix CommitId
 347     #    $p_ref, if provided, must be [] and is used as a base for Parents
 348
 349     $p_ref //= [];
 350     die if @$p_ref;
 351
 352     my ($h,$m) = get_commit $objid;
 353
 354     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 355     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 356
 357     my $r = {
 358         CommitId => $objid,
 359         Hdr => $h,
 360         Msg => $m,
 361         Tree => $t,
 362         Parents => $p_ref,
 363     };
 364
 365     foreach my $ph (@ph) {
 366         push @$p_ref, {
 367             Ix => scalar @$p_ref,
 368             CommitId => $ph,
 369         };
 370     }
 371
 372     return $r;
 373 }
 374
 375 sub classify ($) {
 376     my ($objid) = @_;
 377
 378     my @p;
 379     my $r = parsecommit($objid, \@p);
 380     my $t = $r->{Tree};
 381
 382     foreach my $p (@p) {
 383         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 384     }
 385
 386     printdebug "classify $objid \$t=$t \@p",
 387         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 388         "\n";
 389
 390     my $classify = sub {
 391         my ($type, @rest) = @_;
 392         $r = { %$r, Type => $type, @rest };
 393         if ($debuglevel) {
 394             printdebug " = $type ".(dd $r)."\n";
 395         }
 396         return $r;
 397     };
 398     my $unknown = sub {
 399         my ($why) = @_;
 400         $r = { %$r, Type => qw(Unknown), Why => $why };
 401         printdebug " ** Unknown\n";
 402         return $r;
 403     };
 404
 405     my @identical = grep { !$_->{Differs} } @p;
 406     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 407     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 408
 409     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 410         # multi-orig upstreams are represented with an anchor merge
 411         # from a single upstream commit which combines the orig tarballs
 412
 413         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 414         @p == 2 or return $badanchor->("has other than two parents");
 415         $haspatches and return $badanchor->("contains debian/patches");
 416
 417         # How to decide about l/r ordering of anchors ?  git
 418         # --topo-order prefers to expand 2nd parent first.  There's
 419         # already an easy rune to look for debian/ history anyway (git log
 420         # debian/) so debian breakwater branch should be 1st parent; that
 421         # way also there's also an easy rune to look for the upstream
 422         # patches (--topo-order).
 423
 424         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 425         $p[1]{Differs} & ~DS_DEB and
 426             $badanchor->("upstream files differ from left parent");
 427         $p[0]{Differs} & ~D_UPS and
 428             $badanchor->("debian/ differs from right parent");
 429
 430         return $classify->(qw(Anchor),
 431                            OrigParents => [ $p[1] ]);
 432     }
 433
 434     if (@p == 1) {
 435         my $d = $r->{Parents}[0]{Differs};
 436         if ($d == D_PAT_ADD) {
 437             return $classify->(qw(AddPatches));
 438         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 439             return $unknown->("edits debian/patches");
 440         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 441             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 442             if ($ty eq 'tree') {
 443                 if ($d == D_DEB_CLOG) {
 444                     return $classify->(qw(Changelog));
 445                 } else {
 446                     return $classify->(qw(Packaging));
 447                 }
 448             } elsif ($ty eq 'missing') {
 449                 return $classify->(qw(BreakwaterStart));
 450             } else {
 451                 return $unknown->("parent's debian is not a directory");
 452             }
 453         } elsif ($d == D_UPS) {
 454             return $classify->(qw(Upstream));
 455         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 456             return $classify->(qw(Mixed));
 457         } elsif ($d == 0) {
 458             return $unknown->("no changes");
 459         } else {
 460             confess "internal error $objid ?";
 461         }
 462     }
 463     if (!@p) {
 464         return $unknown->("origin commit");
 465     }
 466
 467     if (@p == 2 && @identical == 1) {
 468         my @overwritten = grep { $_->{Differs} } @p;
 469         confess "internal error $objid ?" unless @overwritten==1;
 470         return $classify->(qw(Pseudomerge),
 471                            Overwritten => [ $overwritten[0] ],
 472                            Contributor => $identical[0]);
 473     }
 474     if (@p == 2 && @identical == 2) {
 475         my $get_t = sub {
 476             my ($ph,$pm) = get_commit $_[0]{CommitId};
 477             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 478             $1;
 479         };
 480         my @bytime = @p;
 481         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 482         if ($order > 0) { # newer first
 483         } elsif ($order < 0) {
 484             @bytime = reverse @bytime;
 485         } else {
 486             # same age, default to order made by -s ours
 487             # that is, commit was made by someone who preferred L
 488         }
 489         return $classify->(qw(Pseudomerge),
 490                            SubType => qw(Ambiguous),
 491                            Contributor => $bytime[0],
 492                            Overwritten => [ $bytime[1] ]);
 493     }
 494     foreach my $p (@p) {
 495         my ($p_h, $p_m) = get_commit $p->{CommitId};
 496         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 497         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 498     }
 499     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 500     my $m2 = $r->{Msg};
 501     if (!(grep { !$_->{IsOrigin} } @p) and
 502         (@orig_ps >= @p - 1) and
 503         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 504         $r->{NewMsg} = $m2;
 505         return $classify->(qw(DgitImportUnpatched),
 506                            OrigParents => \@orig_ps);
 507     }
 508
 509     return $unknown->("complex merge");
 510 }
 511
 512 sub breakwater_of ($) {
 513     my ($head) = @_; # must be laundered
 514     my $breakwater;
 515     my $unclean = sub {
 516         my ($why) = @_;
 517         fail "branch needs laundering (run git-debrebase): $why";
 518     };
 519     for (;;) {
 520         my $cl = classify $head;
 521         my $ty = $cl->{Type};
 522         if ($ty eq 'Packaging' or
 523             $ty eq 'Changelog') {
 524             $breakwater //= $head;
 525         } elsif ($ty eq 'Anchor' or
 526                  $ty eq 'BreakwaterStart') {
 527             $breakwater //= $head;
 528             last;
 529         } elsif ($ty eq 'Upstream') {
 530             $unclean->("packaging change ($breakwater)".
 531                        " follows upstream change (eg $head)")
 532                 if defined $breakwater;
 533         } elsif ($ty eq 'Mixed') {
 534             $unclean->('found mixed upstream/packaging commit ($head)');
 535         } elsif ($ty eq 'Pseudomerge' or
 536                  $ty eq 'AddPatches') {
 537             $unclean->("found interchange conversion commit ($ty, $head)");
 538         } elsif ($ty eq 'DgitImportUnpatched') {
 539             $unclean->("found dgit dsc import ($head)");
 540         } else {
 541             fail "found unprocessable commit, cannot cope: $head; $cl->{Why}";
 542         }
 543         $head = $cl->{Parents}[0]{CommitId};
 544     }
 545     return $breakwater;
 546 }
 547
 548 sub walk ($;$$);
 549 sub walk ($;$$) {
 550     my ($input,
 551         $nogenerate,$report) = @_;
 552     # => ($tip, $breakwater_tip, $last_anchor)
 553     # (or nothing, if $nogenerate)
 554
 555     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 556
 557     # go through commits backwards
 558     # we generate two lists of commits to apply:
 559     # breakwater branch and upstream patches
 560     my (@brw_cl, @upp_cl, @processed);
 561     my %found;
 562     my $upp_limit;
 563     my @pseudomerges;
 564
 565     my $cl;
 566     my $xmsg = sub {
 567         my ($prose, $info) = @_;
 568         my $ms = $cl->{Msg};
 569         chomp $ms;
 570         $info //= '';
 571         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 572         return (Msg => $ms);
 573     };
 574     my $rewrite_from_here = sub {
 575         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 576         push @brw_cl, $sp_cl;
 577         push @processed, $sp_cl;
 578     };
 579     my $cur = $input;
 580
 581     my $prdelim = "";
 582     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 583
 584     my $prline = sub {
 585         return unless $report;
 586         print $report $prdelim, @_;
 587         $prdelim = "\n";
 588     };
 589
 590     my $bomb = sub { # usage: return $bomb->();
 591         print $report " Unprocessable" if $report;
 592         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 593         $prprdelim->();
 594         if ($nogenerate) {
 595             return (undef,undef);
 596         }
 597         die "commit $cur: Cannot cope with this commit (d.".
 598             (join ' ', map { sprintf "%#x", $_->{Differs} }
 599              @{ $cl->{Parents} }).
 600             (defined $cl->{Why} ? "; $cl->{Why}": '').
 601                  ")";
 602     };
 603
 604     my $build;
 605     my $breakwater;
 606
 607     my $build_start = sub {
 608         my ($msg, $parent) = @_;
 609         $prline->(" $msg");
 610         $build = $parent;
 611         no warnings qw(exiting); last;
 612     };
 613
 614     my $last_anchor;
 615
 616     for (;;) {
 617         $cl = classify $cur;
 618         my $ty = $cl->{Type};
 619         my $st = $cl->{SubType};
 620         $prline->("$cl->{CommitId} $cl->{Type}");
 621         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 622         push @processed, $cl;
 623         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 624         if ($ty eq 'AddPatches') {
 625             $cur = $p0;
 626             $rewrite_from_here->();
 627             next;
 628         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
 629             push @brw_cl, $cl;
 630             $cur = $p0;
 631             next;
 632         } elsif ($ty eq 'BreakwaterStart') {
 633             $last_anchor = $cur;
 634             $build_start->('FirstPackaging', $cur);
 635         } elsif ($ty eq 'Upstream') {
 636             push @upp_cl, $cl;
 637             $cur = $p0;
 638             next;
 639         } elsif ($ty eq 'Mixed') {
 640             my $queue = sub {
 641                 my ($q, $wh) = @_;
 642                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
 643                 push @$q, $cls;
 644             };
 645             $queue->(\@brw_cl, "debian");
 646             $queue->(\@upp_cl, "upstream");
 647             $rewrite_from_here->();
 648             $cur = $p0;
 649             next;
 650         } elsif ($ty eq 'Pseudomerge') {
 651             my $contrib = $cl->{Contributor}{CommitId};
 652             print $report " Contributor=$contrib" if $report;
 653             push @pseudomerges, $cl;
 654             $rewrite_from_here->();
 655             $cur = $contrib;
 656             next;
 657         } elsif ($ty eq 'Anchor') {
 658             $last_anchor = $cur;
 659             $build_start->("Anchor", $cur);
 660         } elsif ($ty eq 'DgitImportUnpatched') {
 661             my $pm = $pseudomerges[-1];
 662             if (defined $pm) {
 663                 # To an extent, this is heuristic.  Imports don't have
 664                 # a useful history of the debian/ branch.  We assume
 665                 # that the first pseudomerge after an import has a
 666                 # useful history of debian/, and ignore the histories
 667                 # from later pseudomerges.  Often the first pseudomerge
 668                 # will be the dgit import of the upload to the actual
 669                 # suite intended by the non-dgit NMUer, and later
 670                 # pseudomerges may represent in-archive copies.
 671                 my $ovwrs = $pm->{Overwritten};
 672                 printf $report " PM=%s \@Overwr:%d",
 673                     $pm->{CommitId}, (scalar @$ovwrs)
 674                     if $report;
 675                 if (@$ovwrs != 1) {
 676                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
 677                     return $bomb->();
 678                 }
 679                 my $ovwr = $ovwrs->[0]{CommitId};
 680                 printf $report " Overwr=%s", $ovwr if $report;
 681                 # This import has a tree which is just like a
 682                 # breakwater tree, but it has the wrong history.  It
 683                 # ought to have the previous breakwater (which the
 684                 # pseudomerge overwrote) as an ancestor.  That will
 685                 # make the history of the debian/ files correct.  As
 686                 # for the upstream version: either it's the same as
 687                 # was ovewritten (ie, same as the previous
 688                 # breakwater), in which case that history is precisely
 689                 # right; or, otherwise, it was a non-gitish upload of a
 690                 # new upstream version.  We can tell these apart by
 691                 # looking at the tree of the supposed upstream.
 692                 push @brw_cl, {
 693                     %$cl,
 694                     SpecialMethod => 'DgitImportDebianUpdate',
 695                     $xmsg->("convert dgit import: debian changes")
 696                 }, {
 697                     %$cl,
 698                     SpecialMethod => 'DgitImportUpstreamUpdate',
 699                     $xmsg->("convert dgit import: upstream update",
 700                             " anchor")
 701                 };
 702                 $prline->(" Import");
 703                 $rewrite_from_here->();
 704                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
 705                 $cur = $ovwr;
 706                 next;
 707             } else {
 708                 # Everything is from this import.  This kind of import
 709                 # is already in valid breakwater format, with the
 710                 # patches as commits.
 711                 printf $report " NoPM" if $report;
 712                 # last thing we processed will have been the first patch,
 713                 # if there is one; which is fine, so no need to rewrite
 714                 # on account of this import
 715                 $build_start->("ImportOrigin", $cur);
 716             }
 717             die "$ty ?";
 718         } else {
 719             printdebug "*** WALK BOMB unrecognised\n";
 720             return $bomb->();
 721         }
 722     }
 723     $prprdelim->();
 724
 725     printdebug "*** WALK prep done cur=$cur".
 726         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
 727
 728     return if $nogenerate;
 729
 730     # Now we build it back up again
 731
 732     fresh_workarea();
 733
 734     my $rewriting = 0;
 735
 736     my $read_tree_debian = sub {
 737         my ($treeish) = @_;
 738         read_tree_subdir 'debian', "$treeish:debian";
 739         rm_subdir_cached 'debian/patches';
 740     };
 741     my $read_tree_upstream = sub {
 742         my ($treeish) = @_;
 743         runcmd @git, qw(read-tree), $treeish;
 744         $read_tree_debian->($build);
 745     };
 746
 747     $#upp_cl = $upp_limit if defined $upp_limit;
 748
 749     my $committer_authline = calculate_committer_authline();
 750
 751     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
 752
 753     confess "internal error" unless $build eq (pop @processed)->{CommitId};
 754
 755     in_workarea sub {
 756         mkdir $rd or $!==EEXIST or die $!;
 757         my $current_method;
 758         runcmd @git, qw(read-tree), $build;
 759         foreach my $cl (qw(Debian), (reverse @brw_cl),
 760                         { SpecialMethod => 'RecordBreakwaterTip' },
 761                         qw(Upstream), (reverse @upp_cl)) {
 762             if (!ref $cl) {
 763                 $current_method = $cl;
 764                 next;
 765             }
 766             my $method = $cl->{SpecialMethod} // $current_method;
 767             my @parents = ($build);
 768             my $cltree = $cl->{CommitId};
 769             printdebug "WALK BUILD ".($cltree//'undef').
 770                 " $method (rewriting=$rewriting)\n";
 771             if ($method eq 'Debian') {
 772                 $read_tree_debian->($cltree);
 773             } elsif ($method eq 'Upstream') {
 774                 $read_tree_upstream->($cltree);
 775             } elsif ($method eq 'StartRewrite') {
 776                 $rewriting = 1;
 777                 next;
 778             } elsif ($method eq 'RecordBreakwaterTip') {
 779                 $breakwater = $build;
 780                 next;
 781             } elsif ($method eq 'DgitImportDebianUpdate') {
 782                 $read_tree_debian->($cltree);
 783             } elsif ($method eq 'DgitImportUpstreamUpdate') {
 784                 confess unless $rewriting;
 785                 my $differs = (get_differs $build, $cltree);
 786                 next unless $differs & D_UPS;
 787                 $read_tree_upstream->($cltree);
 788                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
 789             } else {
 790                 confess "$method ?";
 791             }
 792             if (!$rewriting) {
 793                 my $procd = (pop @processed) // 'UNDEF';
 794                 if ($cl ne $procd) {
 795                     $rewriting = 1;
 796                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
 797                 }
 798             }
 799             my $newtree = cmdoutput @git, qw(write-tree);
 800             my $ch = $cl->{Hdr};
 801             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
 802             $ch =~ s{^parent .*\n}{}mg;
 803             $ch =~ s{(?=^author)}{
 804                 join '', map { "parent $_\n" } @parents
 805             }me or confess "$ch ?";
 806             if ($rewriting) {
 807                 $ch =~ s{^committer .*$}{$committer_authline}m
 808                     or confess "$ch ?";
 809             }
 810             my $cf = "$rd/m$rewriting";
 811             open CD, ">", $cf or die $!;
 812             print CD $ch, "\n", $cl->{Msg} or die $!;
 813             close CD or die $!;
 814             my @cmd = (@git, qw(hash-object));
 815             push @cmd, qw(-w) if $rewriting;
 816             push @cmd, qw(-t commit), $cf;
 817             my $newcommit = cmdoutput @cmd;
 818             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
 819             $build = $newcommit;
 820             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
 821                 $last_anchor = $cur;
 822             }
 823         }
 824     };
 825
 826     my $final_check = get_differs $build, $input;
 827     die sprintf "internal error %#x %s %s", $final_check, $build, $input
 828         if $final_check & ~D_PAT_ADD;
 829
 830     my @r = ($build, $breakwater, $last_anchor);
 831     printdebug "*** WALK RETURN @r\n";
 832     return @r
 833 }
 834
 835 sub get_head () {
 836     git_check_unmodified();
 837     return git_rev_parse qw(HEAD);
 838 }
 839
 840 sub update_head ($$$) {
 841     my ($old, $new, $mrest) = @_;
 842     runcmd @git, qw(update-ref -m), "debrebase: $mrest", 'HEAD', $new, $old;
 843 }
 844
 845 sub update_head_checkout ($$$) {
 846     my ($old, $new, $mrest) = @_;
 847     update_head $old, $new, $mrest;
 848     runcmd @git, qw(reset --hard);
 849 }
 850
 851 sub update_head_postlaunder ($$$) {
 852     my ($old, $tip, $reflogmsg) = @_;
 853     return if $tip eq $old;
 854     print "git-debrebase: laundered (head was $old)\n";
 855     update_head $old, $tip, $reflogmsg;
 856     # no tree changes except debian/patches
 857     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
 858 }
 859
 860 sub cmd_launder_v0 () {
 861     badusage "no arguments to launder-v0 allowed" if @ARGV;
 862     my $old = get_head();
 863     my ($tip,$breakwater,$last_anchor) = walk $old;
 864     update_head_postlaunder $old, $tip, 'launder';
 865     printf "# breakwater tip\n%s\n", $breakwater;
 866     printf "# working tip\n%s\n", $tip;
 867     printf "# last anchor\n%s\n", $last_anchor;
 868 }
 869
 870 sub defaultcmd_rebase () {
 871     my $old = get_head();
 872     my ($status, $message) = record_ffq_prev();
 873     if ($status eq 'written' || $status eq 'exists') {
 874     } else {
 875         fproblem $status, "could not record ffq-prev: $message";
 876         fproblems_maybe_bail();
 877     }
 878     my ($tip,$breakwater) = walk $old;
 879     update_head_postlaunder $old, $tip, 'launder for rebase';
 880     runcmd @git, qw(rebase), @ARGV, $breakwater;
 881 }
 882
 883 sub cmd_analyse () {
 884     die if ($ARGV[0]//'') =~ m/^-/;
 885     badusage "too many arguments to analyse" if @ARGV>1;
 886     my ($old) = @ARGV;
 887     if (defined $old) {
 888         $old = git_rev_parse $old;
 889     } else {
 890         $old = git_rev_parse 'HEAD';
 891     }
 892     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
 893     STDOUT->error and die $!;
 894 }
 895
 896 sub ffq_prev_branchinfo () {
 897     # => ('status', "message", [$current, $ffq_prev])
 898     # 'status' may be
 899     #    branch         message is undef
 900     #    weird-symref   } no $current,
 901     #    notbranch      }  no $ffq_prev
 902     my $current = git_get_symref();
 903     return ('detached', 'detached HEAD') unless defined $current;
 904     return ('weird-symref', 'HEAD symref is not to refs/')
 905         unless $current =~ m{^refs/};
 906     my $ffq_prev = "refs/$ffq_refprefix/$'";
 907     printdebug "ffq_prev_branchinfo branch current $current\n";
 908     return ('branch', undef, $current, $ffq_prev);
 909 }
 910
 911 sub record_ffq_prev () {
 912     # => ('status', "message")
 913     # 'status' may be
 914     #    written          message is undef
 915     #    exists
 916     #    detached
 917     #    weird-symref
 918     #    notbranch
 919     # if not ff from some branch we should be ff from, is an fproblem
 920     # if "written", will have printed something about that to stdout,
 921     #   and also some messages about ff checks
 922     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
 923     return ($status, $message) unless $status eq 'branch';
 924
 925     my $currentval = get_head();
 926
 927     my $exists = git_get_ref $ffq_prev;
 928     return ('exists',"$ffq_prev already exists") if $exists;
 929
 930     return ('not-branch', 'HEAD symref is not to refs/heads/')
 931         unless $current =~ m{^refs/heads/};
 932     my $branch = $';
 933
 934     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
 935     my %checked;
 936
 937     printdebug "ffq check_specs @check_specs\n";
 938
 939     my $check = sub {
 940         my ($lrref, $desc) = @_;
 941         printdebug "ffq might check $lrref ($desc)\n";
 942         my $invert;
 943         for my $chk (@check_specs) {
 944             my $glob = $chk;
 945             $invert = $glob =~ s{^[!^]}{};
 946             last if fnmatch $glob, $lrref;
 947         }
 948         return if $invert;
 949         my $lrval = git_get_ref $lrref;
 950         return unless defined $lrval;
 951
 952         if (is_fast_fwd $lrval, $currentval) {
 953             print "OK, you are ahead of $lrref\n" or die $!;
 954             $checked{$lrref} = 1;
 955         } elsif (is_fast_fwd $currentval, $lrval) {
 956             $checked{$lrref} = -1;
 957             fproblem 'behind', "you are behind $lrref, divergence risk";
 958         } else {
 959             $checked{$lrref} = -1;
 960             fproblem 'diverged', "you have diverged from $lrref";
 961         }
 962     };
 963
 964     my $merge = cfg "branch.$branch.merge",1;
 965     if (defined $merge and $merge =~ m{^refs/heads/}) {
 966         my $rhs = $';
 967         printdebug "ffq merge $rhs\n";
 968         my $check_remote = sub {
 969             my ($remote, $desc) = @_;
 970             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
 971             return unless defined $remote;
 972             $check->("refs/remotes/$remote/$rhs", $desc);
 973         };
 974         $check_remote->((scalar cfg "branch.$branch.remote",1),
 975                         'remote fetch/merge branch');
 976         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
 977                         (scalar cfg "branch.$branch.pushDefault",1),
 978                         'remote push branch');
 979     }
 980     if ($branch =~ m{^dgit/}) {
 981         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
 982     } elsif ($branch =~ m{^master$}) {
 983         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
 984     }
 985
 986     fproblems_maybe_bail();
 987     runcmd @git, qw(update-ref -m), "record current head for preservation",
 988         $ffq_prev, $currentval, $git_null_obj;
 989     print "Recorded current head for preservation\n" or die $!;
 990     return ('written', undef);
 991 }
 992
 993 sub cmd_new_upstream_v0 () {
 994     # automatically and unconditionally launders before rebasing
 995     # if rebase --abort is used, laundering has still been done
 996
 997     my %pieces;
 998
 999     badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
1000
1001     # parse args - low commitment
1002     my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
1003     my $new_upstream_version = $new_version->version();
1004
1005     my $new_upstream = git_rev_parse shift @ARGV;
1006
1007     my $piece = sub {
1008         my ($n, @x) = @_; # may be ''
1009         my $pc = $pieces{$n} //= {
1010             Name => $n,
1011             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1012         };
1013         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1014         $pc;
1015     };
1016
1017     my @newpieces;
1018     my $newpiece = sub {
1019         my ($n, @x) = @_; # may be ''
1020         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1021         push @newpieces, $pc;
1022     };
1023
1024     $newpiece->('',
1025         OldIx => 0,
1026         New => $new_upstream,
1027     );
1028     while (@ARGV && $ARGV[0] !~ m{^-}) {
1029         my $n = shift @ARGV;
1030
1031         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1032             unless @ARGV && $ARGV[0] !~ m{^-};
1033
1034         my $c = git_rev_parse shift @ARGV;
1035         die unless $n =~ m/^$extra_orig_namepart_re$/;
1036         $newpiece->($n, New => $c);
1037     }
1038
1039     # now we need to investigate the branch this generates the
1040     # laundered version but we don't switch to it yet
1041     my $old_head = get_head();
1042     my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
1043
1044     my $old_bw_cl = classify $old_bw;
1045     my $old_upstream_update_cl = classify $old_upstream_update;
1046     confess unless $old_upstream_update_cl->{OrigParents};
1047     my $old_upstream = parsecommit
1048         $old_upstream_update_cl->{OrigParents}[0]{CommitId};
1049
1050     $piece->('', Old => $old_upstream->{CommitId});
1051
1052     if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1053         if ($old_upstream->{Msg} =~
1054  m{^\[git-debrebase upstream-combine \.((?: $extra_orig_namepart_re)+)\:.*\]$}m
1055            ) {
1056             my @oldpieces = ('', split / /, $1);
1057             my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
1058             foreach my $i (0..$#oldpieces) {
1059                 my $n = $oldpieces[$i];
1060                 $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
1061             }
1062         } else {
1063             fproblem 'upstream-confusing',
1064                 "previous upstream $old_upstream->{CommitId} is from".
1065                " git-debrebase but not an \`upstream-combine' commit";
1066         }
1067     }
1068
1069     foreach my $pc (values %pieces) {
1070         if (!$pc->{Old}) {
1071             fproblem 'upstream-new-piece',
1072                 "introducing upstream piece \`$pc->{Name}'";
1073         } elsif (!$pc->{New}) {
1074             fproblem 'upstream-rm-piece',
1075                 "dropping upstream piece \`$pc->{Name}'";
1076         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1077             fproblem 'upstream-not-ff',
1078                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1079         }
1080     }
1081
1082     printdebug "%pieces = ", (dd \%pieces), "\n";
1083     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1084
1085     fproblems_maybe_bail();
1086
1087     my $new_bw;
1088
1089     fresh_workarea();
1090     in_workarea sub {
1091         my @upstream_merge_parents;
1092
1093         if (!any_fproblems()) {
1094             push @upstream_merge_parents, $old_upstream->{CommitId};
1095         }
1096
1097         foreach my $pc (@newpieces) { # always has '' first
1098             if ($pc->{Name}) {
1099                 read_tree_subdir $pc->{Name}, $pc->{New};
1100             } else {
1101                 runcmd @git, qw(read-tree), $pc->{New};
1102             }
1103             push @upstream_merge_parents, $pc->{New};
1104         }
1105
1106         # index now contains the new upstream
1107
1108         if (@newpieces > 1) {
1109             # need to make the upstream subtree merge commit
1110             $new_upstream = make_commit \@upstream_merge_parents,
1111                 [ "Combine upstreams for $new_upstream_version",
1112  ("[git-debrebase upstream-combine . ".
1113  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1114  ": new upstream]"),
1115                 ];
1116         }
1117
1118         # $new_upstream is either the single upstream commit, or the
1119         # combined commit we just made.  Either way it will be the
1120         # "upstream" parent of the anchor merge.
1121
1122         read_tree_subdir 'debian', "$old_bw:debian";
1123
1124         # index now contains the anchor merge contents
1125         $new_bw = make_commit [ $old_bw, $new_upstream ],
1126             [ "Update to upstream $new_upstream_version",
1127  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1128             ];
1129
1130         # Now we have to add a changelog stanza so the Debian version
1131         # is right.
1132         die if unlink "debian";
1133         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1134         unlink "debian/changelog" or $!==ENOENT or die $!;
1135         mkdir "debian" or die $!;
1136         open CN, ">", "debian/changelog" or die $!;
1137         my $oldclog = git_cat_file ":debian/changelog";
1138         $oldclog =~ m/^($package_re) \(\S+\) / or
1139             fail "cannot parse old changelog to get package name";
1140         my $p = $1;
1141         print CN <<END, $oldclog or die $!;
1142 $p ($new_version) UNRELEASED; urgency=medium
1143
1144   * Update to new upstream version $new_upstream_version.
1145
1146  --
1147
1148 END
1149         close CN or die $!;
1150         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1151
1152         # Now we have the final new breakwater branch in the index
1153         $new_bw = make_commit [ $new_bw ],
1154             [ "Update changelog for new upstream $new_upstream_version",
1155               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1156             ];
1157     };
1158
1159     # we have constructed the new breakwater. we now need to commit to
1160     # the laundering output, because git-rebase can't easily be made
1161     # to make a replay list which is based on some other branch
1162
1163     update_head_postlaunder $old_head, $old_laundered_tip,
1164         'launder for new upstream';
1165
1166     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1167     runcmd @cmd;
1168     # now it's for the user to sort out
1169 }
1170
1171 sub cmd_record_ffq_prev () {
1172     badusage "no arguments allowed" if @ARGV;
1173     my ($status, $msg) = record_ffq_prev();
1174     if ($status eq 'exists' && $opt_noop_ok) {
1175         print "Previous head already recorded\n" or die $!;
1176     } elsif ($status eq 'written') {
1177     } else {
1178         fail "Could not preserve: $msg";
1179     }
1180 }
1181
1182 sub cmd_breakwater () {
1183     badusage "no arguments allowed" if @ARGV;
1184     my $bw = breakwater_of git_rev_parse 'HEAD';
1185     print "$bw\n" or die $!;
1186 }
1187
1188 sub cmd_stitch () {
1189     my $prose = '';
1190     GetOptions('prose=s', \$prose) or die badusage("bad options to stitch");
1191     badusage "no arguments allowed" if @ARGV;
1192     my ($status, $message, $current, $ffq_prev) = ffq_prev_branchinfo();
1193     if ($status ne 'branch') {
1194         fproblem $status, "could not check ffq-prev: $message";
1195         fproblems_maybe_bail();
1196     }
1197     my $prev = $ffq_prev && git_get_ref $ffq_prev;
1198     if (!$prev) {
1199         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1200     }
1201     fresh_workarea();
1202     my $old_head = get_head();
1203     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1204         'Declare fast forward / record previous work',
1205         "[git-debrebase pseudomerge: stitch$prose]",
1206     ];
1207     my @upd_cmd = (@git, qw(update-ref --stdin));
1208     debugcmd '>|', @upd_cmd;
1209     open U, "|-", @upd_cmd or die $!;
1210     my $u = <<END;
1211 update HEAD $new_head $old_head
1212 delete $ffq_prev $prev
1213 END
1214     printdebug ">= ", $_, "\n" foreach split /\n/, $u;
1215     print U $u;
1216     printdebug ">\$\n";
1217     close U or failedcmd @upd_cmd;
1218 }
1219
1220 sub cmd_convert_from_gbp () {
1221     badusage "needs 1 optional argument, the upstream git rev"
1222         unless @ARGV<=1;
1223     my ($upstream_spec) = @ARGV;
1224     $upstream_spec //= 'refs/heads/upstream';
1225     my $upstream = git_rev_parse $upstream_spec;
1226     my $old_head = get_head();
1227
1228     my $upsdiff = get_differs $upstream, $old_head;
1229     if ($upsdiff & D_UPS) {
1230         runcmd @git, qw(--no-pager diff),
1231             $upstream, $old_head,
1232             qw( -- :!/debian :/);
1233  fail "upstream ($upstream_spec) and HEAD are not identical in upstream files";
1234     }
1235
1236     if (!is_fast_fwd $upstream, $old_head) {
1237         fproblem 'upstream-not-ancestor',
1238             "upstream ($upstream) is not an ancestor of HEAD";
1239     } else {
1240         my $wrong = cmdoutput
1241             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
1242              qw(-- :/ :!/debian));
1243         if (length $wrong) {
1244             fproblem 'unexpected-upstream-changes',
1245                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
1246             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
1247         }
1248     }
1249
1250     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
1251         fproblem 'upstream-has-debian',
1252             "upstream ($upstream) contains debian/ directory";
1253     }
1254
1255     fproblems_maybe_bail();
1256
1257     my $work;
1258
1259     fresh_workarea();
1260     in_workarea sub {
1261         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
1262         # make a branch out of the patch queue - we'll want this in a mo
1263         runcmd qw(gbp pq import);
1264         # strip the patches out
1265         runcmd @git, qw(checkout -q gdr-internal~0);
1266         rm_subdir_cached 'debian/patches';
1267         $work = make_commit ['HEAD'], [
1268  'git-debrebase convert-from-gbp: drop patches from tree',
1269  'Delete debian/patches, as part of converting to git-debrebase format.',
1270  '[git-debrebase convert-from-gbp: drop patches from tree]'
1271                               ];
1272         # make the anchor merge
1273         # the tree is already exactly right
1274         $work = make_commit [$work, $upstream], [
1275  'git-debrebase import: declare upstream',
1276  'First breakwater merge.',
1277  '[git-debrebase anchor: declare upstream]'
1278                               ];
1279
1280         # rebase the patch queue onto the new breakwater
1281         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
1282         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
1283         $work = git_rev_parse 'HEAD';
1284     };
1285
1286     update_head_checkout $old_head, $work, 'convert-from-gbp';
1287 }
1288
1289 sub cmd_convert_to_gbp () {
1290     badusage "no arguments allowed" if @ARGV;
1291     my $head = get_head();
1292     my $ffq = (ffq_prev_branchinfo())[3];
1293     my $bw = breakwater_of $head;
1294     fresh_workarea();
1295     my $out;
1296     in_workarea sub {
1297         runcmd @git, qw(checkout -q -b bw), $bw;
1298         runcmd @git, qw(checkout -q -b patch-queue/bw), $head;
1299         runcmd qw(gbp pq export);
1300         runcmd @git, qw(add debian/patches);
1301         $out = make_commit ['HEAD'], [
1302             'Commit patch queue (converted from git-debrebase format)',
1303             '[git-debrebase convert-to-gbp: commit patches]',
1304         ];
1305     };
1306     if (defined $ffq) {
1307         runcmd @git, qw(update-ref -m),
1308             "debrebase: converting corresponding main branch to gbp format",
1309             $ffq, $git_null_obj;
1310     }
1311     update_head_checkout $head, $out, "convert to gbp (v0)";
1312     print <<END or die $!;
1313 git-debrebase: converted to git-buildpackage branch format
1314 git-debrebase: WARNING: do not now run "git-debrebase" any more
1315 git-debrebase: WARNING: doing so would drop all upstream patches!
1316 END
1317 }
1318
1319 sub cmd_downstream_rebase_launder_v0 () {
1320     badusage "needs 1 argument, the baseline" unless @ARGV==1;
1321     my ($base) = @ARGV;
1322     $base = git_rev_parse $base;
1323     my $old_head = get_head();
1324     my $current = $old_head;
1325     my $topmost_keep;
1326     for (;;) {
1327         if ($current eq $base) {
1328             $topmost_keep //= $current;
1329             print " $current BASE stop\n";
1330             last;
1331         }
1332         my $cl = classify $current;
1333         print " $current $cl->{Type}";
1334         my $keep = 0;
1335         my $p0 = $cl->{Parents}[0]{CommitId};
1336         my $next;
1337         if ($cl->{Type} eq 'Pseudomerge') {
1338             print " ^".($cl->{Contributor}{Ix}+1);
1339             $next = $cl->{Contributor}{CommitId};
1340         } elsif ($cl->{Type} eq 'AddPatches' or
1341                  $cl->{Type} eq 'Changelog') {
1342             print " strip";
1343             $next = $p0;
1344         } else {
1345             print " keep";
1346             $next = $p0;
1347             $keep = 1;
1348         }
1349         print "\n";
1350         if ($keep) {
1351             $topmost_keep //= $current;
1352         } else {
1353             die "to-be stripped changes not on top of the branch\n"
1354                 if $topmost_keep;
1355         }
1356         $current = $next;
1357     }
1358     if ($topmost_keep eq $old_head) {
1359         print "unchanged\n";
1360     } else {
1361         print "updating to $topmost_keep\n";
1362         update_head_checkout
1363             $old_head, $topmost_keep,
1364             'downstream-rebase-launder-v0';
1365     }
1366 }
1367
1368 GetOptions("D+" => \$debuglevel,
1369            'noop-ok', => \$opt_noop_ok,
1370            'f=s' => \@fproblem_force_opts,
1371            'force!') or die badusage "bad options\n";
1372 initdebug('git-debrebase ');
1373 enabledebug if $debuglevel;
1374
1375 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
1376 chdir $toplevel or die "chdir $toplevel: $!";
1377
1378 $rd = fresh_playground "$playprefix/misc";
1379
1380 if (!@ARGV || $ARGV[0] =~ m{^-}) {
1381     defaultcmd_rebase();
1382 } else {
1383     my $cmd = shift @ARGV;
1384     my $cmdfn = $cmd;
1385     $cmdfn =~ y/-/_/;
1386     $cmdfn = ${*::}{"cmd_$cmdfn"};
1387
1388     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
1389     $cmdfn->();
1390 }