git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$) {
 267     my ($treeish, $keep_patches) = @_;
 268     my $save = cmdoutput @git, qw(write-tree --prefix=debian/);
 269     runcmd @git, qw(read-tree), $treeish;
 270     read_tree_subdir 'debian', $save;
 271     rm_subdir_cached 'debian/patches' unless $keep_patches;
 272 };
 273
 274 sub make_commit ($$) {
 275     my ($parents, $message_paras) = @_;
 276     my $tree = cmdoutput @git, qw(write-tree);
 277     my @cmd = (@git, qw(commit-tree), $tree);
 278     push @cmd, qw(-p), $_ foreach @$parents;
 279     push @cmd, qw(-m), $_ foreach @$message_paras;
 280     return cmdoutput @cmd;
 281 }
 282
 283 our @snag_force_opts;
 284 sub snag ($$;@) {
 285     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 286     if (grep { $_ eq $tag } @snag_force_opts) {
 287         $snags_forced++;
 288         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 289     } else {
 290         $snags_tripped++;
 291         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 292     }
 293 }
 294
 295 # Important: all mainline code must call snags_maybe_bail after
 296 # any point where snag might be called, but before making changes
 297 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 298 # may be called more than once if necessary (but this is not ideal
 299 # because then the messages about number of snags may be confusing).
 300 sub snags_maybe_bail () {
 301     return if all_snags_summarised();
 302     if ($snags_forced) {
 303         printf STDERR
 304             "%s: snags: %d overriden by individual -f options\n",
 305             $us, $snags_forced;
 306     }
 307     if ($snags_tripped) {
 308         if ($opt_force) {
 309             printf STDERR
 310                 "%s: snags: %d overriden by global --force\n",
 311                 $us, $snags_tripped;
 312         } else {
 313             fail sprintf
 314   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 315                 $us, $snags_tripped;
 316         }
 317     }
 318     $snags_summarised = $snags_forced + $snags_tripped;
 319 }
 320 sub snags_maybe_bail_early () {
 321     # useful to bail out early without doing a lot of work;
 322     # not a substitute for snags_maybe_bail.
 323     snags_maybe_bail() if $snags_tripped && !$opt_force;
 324 }
 325 sub any_snags () {
 326     return $snags_forced || $snags_tripped;
 327 }
 328
 329 sub gbp_pq_export ($$$) {
 330     my ($bname, $base, $tip) = @_;
 331     # must be run in a workarea.  $bname and patch-queue/$bname
 332     # ought not to exist.  Leaves you on patch-queue/$bname with
 333     # the patches staged but not committed.
 334     printdebug "gbp_pq_export $bname $base $tip\n";
 335     runcmd @git, qw(checkout -q -b), $bname, $base;
 336     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 337     my @gbp_cmd = (qw(gbp pq export));
 338     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 339     if ($r) {
 340         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 341         failedcmd @gbp_cmd;
 342     }
 343     runcmd @git, qw(add -f debian/patches);
 344 }
 345
 346
 347 # xxx allow merge resolution separately from laundering, before git merge
 348 #
 349 # xxx general gdr docs highlight forbidden things
 350 # xxx general gdr docs list allowable things ?
 351 # xxx general gdr docs explicitly forbid some rebase
 352 #
 353 # xxx provide a way for the user to help
 354 # xxx (eg, provide wreckage provide way to continue)
 355
 356 # later/rework?
 357 #  use git-format-patch?
 358 #  our own patch identification algorithm?
 359 #  this is an alternative strategy
 360
 361 sub merge_series ($$;@) {
 362     my ($newbase, $base_q, @input_qs) = @_;
 363     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 364     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 365     # ^ specifies several patch series (currently we only support exactly 2)
 366     # return value is a commit which is the result of
 367     # merging the two versions of the same topic branch
 368     #   $input_q[0] and $input_q[1]
 369     # with respect to the old version
 370     #   $base_q
 371     # all onto $newbase.
 372
 373     # Creates, in *_q, a key MR for its private use
 374
 375     printdebug "merge_series newbase=$newbase\n";
 376
 377     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 378     $base_q->{MR}{S} = 'base';
 379
 380     my %prereq;
 381     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 382     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 383     # $prereq{<patch filename>}               exists or not (even later)
 384
 385     my $result;
 386
 387     local $workarea = fresh_playground "$playprefix/merge";
 388     my $seriesfile = "debian/patches/series";
 389     in_workarea sub {
 390         playtree_setup();
 391         foreach my $q ($base_q, reverse @input_qs) {
 392             my $s = $q->{MR}{S};
 393             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 394             if (open S, $seriesfile) {
 395                 my @earlier;
 396                 while (my $patch = <S>) {
 397                     chomp $patch or die $!;
 398                     $prereq{$patch} //= {};
 399                     foreach my $earlier (@earlier) {
 400                         $prereq{$patch}{$earlier}{$s}++ and die;
 401                     }
 402                     push @earlier, $patch;
 403                     stat "debian/patches/$patch" or die "$patch ?";
 404                 }
 405                 S->error and die "$seriesfile $!";
 406                 close S;
 407             } else {
 408                 die "$seriesfile $!" unless $!==ENOENT;
 409             }
 410             read_tree_upstream $newbase, 1;
 411             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 412                 "Convert $s to patch queue for merging",
 413                 "[git-debrebase merge-innards patch-queue import:".
 414                 " $q->{SeriesTip}]"
 415             ];
 416             printdebug "merge_series  pec $pec ";
 417             runcmd @git, qw(rm -q --cached), $seriesfile;
 418             $pec = make_commit [ $pec ], [
 419                 "Drop series file from $s to avoid merge trouble",
 420                 "[git-debrebase merge-innards patch-queue prep:".
 421                 " $q->{SeriesTip}]"
 422             ];
 423             printdebug "pec' $pec\n";
 424             runcmd @git, qw(reset -q --hard), $pec;
 425             $q->{MR}{PEC} = $pec;
 426         }
 427         # now, because of reverse, we are on $input_q->{MR}{OQC}
 428         runcmd @git, qw(checkout -q -b merge);
 429         printdebug "merge_series merging...\n";
 430         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 431         debugcmd '+', @mergecmd;
 432         $!=0; $?=-1;
 433         if (system @mergecmd) {
 434             failedcmd @mergecmd;
 435         }
 436
 437         printdebug "merge_series merge ok, series...\n";
 438         # We need to construct a new series file
 439         # Firstly, resolve prereq
 440         foreach my $f (sort keys %prereq) {
 441             printdebug "merge_series  patch\t$f\t";
 442             if (!stat_exists "debian/patches/$f") {
 443                 print DEBUG " drop\n" if $debuglevel;
 444                 # git merge deleted it; that's how we tell it's not wanted
 445                 delete $prereq{$f};
 446                 next;
 447             }
 448             print DEBUG " keep\n" if $debuglevel;
 449             foreach my $g (sort keys %{ $prereq{$f} }) {
 450                 my $gfp = $prereq{$f}{$g};
 451                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 452                 if (!!$gfp->{0} == !!$gfp->{1}
 453                     ? $gfp->{0}
 454                     : !$gfp->{base}) {
 455                     print DEBUG "\tkeep\n" if $debuglevel;
 456                 } else {
 457                     print DEBUG "\tdrop\n" if $debuglevel;
 458                     delete $prereq{$f}{$g};
 459                 }
 460             }
 461         }
 462
 463         my $unsat = sub {
 464             my ($f) = @_;
 465             return scalar keys %{ $prereq{$f} };
 466         };
 467
 468         my $nodate = time + 1;
 469         my %authordate;
 470         # $authordate{<patch filename>};
 471         my $authordate = sub {
 472             my ($f) = @_;
 473             $authordate{$f} //= do {
 474                 open PF, "<", "debian/patches/$f" or die "$f $!";
 475                 while (<PF>) {
 476                     return $nodate if m/^$/;
 477                     last if s{^Date: }{};
 478                 }
 479                 chomp;
 480                 return cmdoutput qw(date +%s -d), $_;
 481             };
 482         };
 483
 484         open NS, '>', $seriesfile or die $!;
 485
 486         while (keys %prereq) {
 487             my $best;
 488             foreach my $try (sort keys %prereq) {
 489                 if ($best) {
 490                     next if (
 491                              $unsat->($try) <=> $unsat->($best) or
 492                              $authordate->($try) <=> $authordate->($best) or
 493                              $try cmp $best
 494                             ) >= 0;
 495                 }
 496                 $best = $try;
 497             }
 498             printdebug "merge_series series next $best\n";
 499             print NS "$best\n" or die $!;
 500             delete $prereq{$best};
 501             foreach my $gp (values %prereq) {
 502                 delete $gp->{$best};
 503             }
 504         }
 505
 506         runcmd @git, qw(add), $seriesfile;
 507         runcmd @git, qw(commit --quiet -m), 'Merged series';
 508
 509         printdebug "merge_series series gbp pq import\n";
 510         runcmd qw(gbp pq import);
 511
 512         # OK now we are on patch-queue/merge, and we need to rebase
 513         # onto the intended parent and drop the patches from each one
 514
 515         printdebug "merge_series series ok, building...\n";
 516         my $build = $newbase;
 517         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 518         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 519             my $commit = git_cat_file $c, 'commit';
 520             printdebug "merge_series series ok, building $c\n";
 521             read_tree_upstream $c;
 522             my $tree = cmdoutput @git, qw(write-tree);
 523             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 524             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 525             open C, ">", "../mcommit" or die $!;
 526             print C $commit or die $!;
 527             close C or die $!;
 528             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 529         }
 530         $result = $build;
 531         runcmd @git, qw(update-ref refs/heads/result), $result;
 532     };
 533     printdebug "merge_series returns $result\n";
 534     return $result;
 535 }
 536
 537 # classify returns an info hash like this
 538 #   CommitId => $objid
 539 #   Hdr => # commit headers, including 1 final newline
 540 #   Msg => # commit message (so one newline is dropped)
 541 #   Tree => $treeobjid
 542 #   Type => (see below)
 543 #   Parents = [ {
 544 #       Ix => $index # ie 0, 1, 2, ...
 545 #       CommitId
 546 #       Differs => return value from get_differs
 547 #       IsOrigin
 548 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 549 #     } ...]
 550 #   NewMsg => # commit message, but with any [dgit import ...] edited
 551 #             # to say "[was: ...]"
 552 #
 553 # Types:
 554 #   Packaging
 555 #   Changelog
 556 #   Upstream
 557 #   AddPatches
 558 #   Mixed
 559 #
 560 #   Pseudomerge
 561 #     has additional entres in classification result
 562 #       Overwritten = [ subset of Parents ]
 563 #       Contributor = $the_remaining_Parent
 564 #
 565 #   DgitImportUnpatched
 566 #     has additional entry in classification result
 567 #       OrigParents = [ subset of Parents ]
 568 #
 569 #   Anchor
 570 #     has additional entry in classification result
 571 #       OrigParents = [ subset of Parents ]  # singleton list
 572 #
 573 #   TreatAsAnchor
 574 #
 575 #   BreakwaterStart
 576 #
 577 #   Unknown
 578 #     has additional entry in classification result
 579 #       Why => "prose"
 580
 581 sub parsecommit ($;$) {
 582     my ($objid, $p_ref) = @_;
 583     # => hash with                   CommitId Hdr Msg Tree Parents
 584     #    Parents entries have only   Ix CommitId
 585     #    $p_ref, if provided, must be [] and is used as a base for Parents
 586
 587     $p_ref //= [];
 588     die if @$p_ref;
 589
 590     my ($h,$m) = get_commit $objid;
 591
 592     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 593     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 594
 595     my $r = {
 596         CommitId => $objid,
 597         Hdr => $h,
 598         Msg => $m,
 599         Tree => $t,
 600         Parents => $p_ref,
 601     };
 602
 603     foreach my $ph (@ph) {
 604         push @$p_ref, {
 605             Ix => scalar @$p_ref,
 606             CommitId => $ph,
 607         };
 608     }
 609
 610     return $r;
 611 }
 612
 613 sub classify ($) {
 614     my ($objid) = @_;
 615
 616     my @p;
 617     my $r = parsecommit($objid, \@p);
 618     my $t = $r->{Tree};
 619
 620     foreach my $p (@p) {
 621         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 622     }
 623
 624     printdebug "classify $objid \$t=$t \@p",
 625         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 626         "\n";
 627
 628     my $classify = sub {
 629         my ($type, @rest) = @_;
 630         $r = { %$r, Type => $type, @rest };
 631         if ($debuglevel) {
 632             printdebug " = $type ".(dd $r)."\n";
 633         }
 634         return $r;
 635     };
 636     my $unknown = sub {
 637         my ($why) = @_;
 638         $r = { %$r, Type => qw(Unknown), Why => $why };
 639         printdebug " ** Unknown\n";
 640         return $r;
 641     };
 642
 643     if (grep { $_ eq $objid } @opt_anchors) {
 644         return $classify->('TreatAsAnchor');
 645     }
 646
 647     my @identical = grep { !$_->{Differs} } @p;
 648     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 649     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 650
 651     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 652         # multi-orig upstreams are represented with an anchor merge
 653         # from a single upstream commit which combines the orig tarballs
 654
 655         # Every anchor tagged this way must be a merge.
 656         # We are relying on the
 657         #     [git-debrebase anchor: ...]
 658         # commit message annotation in "declare" anchor merges (which
 659         # do not have any upstream changes), to distinguish those
 660         # anchor merges from ordinary pseudomerges (which we might
 661         # just try to strip).
 662         #
 663         # However, the user is going to be doing git-rebase a lot.  We
 664         # really don't want them to rewrite an anchor commit.
 665         # git-rebase trips up on merges, so that is a useful safety
 666         # catch.
 667         #
 668         # BreakwaterStart commits are also anchors in the terminology
 669         # of git-debrebase(5), but they are untagged (and always
 670         # manually generated).
 671         #
 672         # We cannot not tolerate any tagged linear commit (ie,
 673         # BreakwaterStart commits tagged `[anchor:') because such a
 674         # thing could result from an erroneous linearising raw git
 675         # rebase of a merge anchor.  That would represent a corruption
 676         # of the branch. and we want to detect and reject the results
 677         # of such corruption before it makes it out anywhere.  If we
 678         # reject it here then we avoid making the pseudomerge which
 679         # would be needed to push it.
 680
 681         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 682         @p == 2 or return $badanchor->("has other than two parents");
 683         $haspatches and return $badanchor->("contains debian/patches");
 684
 685         # How to decide about l/r ordering of anchors ?  git
 686         # --topo-order prefers to expand 2nd parent first.  There's
 687         # already an easy rune to look for debian/ history anyway (git log
 688         # debian/) so debian breakwater branch should be 1st parent; that
 689         # way also there's also an easy rune to look for the upstream
 690         # patches (--topo-order).
 691
 692         # Also this makes --first-parent be slightly more likely to
 693         # be useful - it makes it provide a linearised breakwater history.
 694
 695         # Of course one can say somthing like
 696         #  gitk -- ':/' ':!/debian'
 697         # to get _just_ the commits touching upstream files, and by
 698         # the TREESAME logic in git-rev-list this will leave the
 699         # breakwater into upstream at the first anchor.  But that
 700         # doesn't report debian/ changes at all.
 701
 702         # Other observations about gitk: by default, gitk seems to
 703         # produce output in a different order to git-rev-list.  I
 704         # can't seem to find this documented anywhere.  gitk
 705         # --date-order DTRT.  But, gitk always seems to put the
 706         # parents from left to right, in order, so it's easy to see
 707         # which way round a pseudomerge is.
 708
 709         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 710         $p[1]{Differs} & ~DS_DEB and
 711             $badanchor->("upstream files differ from left parent");
 712         $p[0]{Differs} & ~D_UPS and
 713             $badanchor->("debian/ differs from right parent");
 714
 715         return $classify->(qw(Anchor),
 716                            OrigParents => [ $p[1] ]);
 717     }
 718
 719     if (@p == 1) {
 720         my $d = $r->{Parents}[0]{Differs};
 721         if ($d == D_PAT_ADD) {
 722             return $classify->(qw(AddPatches));
 723         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 724             return $unknown->("edits debian/patches");
 725         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 726             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 727             if ($ty eq 'tree') {
 728                 if ($d == D_DEB_CLOG) {
 729                     return $classify->(qw(Changelog));
 730                 } else {
 731                     return $classify->(qw(Packaging));
 732                 }
 733             } elsif ($ty eq 'missing') {
 734                 return $classify->(qw(BreakwaterStart));
 735             } else {
 736                 return $unknown->("parent's debian is not a directory");
 737             }
 738         } elsif ($d == D_UPS) {
 739             return $classify->(qw(Upstream));
 740         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 741             return $classify->(qw(Mixed));
 742         } elsif ($d == 0) {
 743             return $unknown->("no changes");
 744         } else {
 745             confess "internal error $objid ?";
 746         }
 747     }
 748     if (!@p) {
 749         return $unknown->("origin commit");
 750     }
 751
 752     if (@p == 2 && @identical == 1) {
 753         my @overwritten = grep { $_->{Differs} } @p;
 754         confess "internal error $objid ?" unless @overwritten==1;
 755         return $classify->(qw(Pseudomerge),
 756                            Overwritten => [ $overwritten[0] ],
 757                            Contributor => $identical[0]);
 758     }
 759     if (@p == 2 && @identical == 2) {
 760         my $get_t = sub {
 761             my ($ph,$pm) = get_commit $_[0]{CommitId};
 762             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 763             $1;
 764         };
 765         my @bytime = @p;
 766         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 767         if ($order > 0) { # newer first
 768         } elsif ($order < 0) {
 769             @bytime = reverse @bytime;
 770         } else {
 771             # same age, default to order made by -s ours
 772             # that is, commit was made by someone who preferred L
 773         }
 774         return $classify->(qw(Pseudomerge),
 775                            SubType => qw(Ambiguous),
 776                            Contributor => $bytime[0],
 777                            Overwritten => [ $bytime[1] ]);
 778     }
 779     foreach my $p (@p) {
 780         my ($p_h, $p_m) = get_commit $p->{CommitId};
 781         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 782         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 783     }
 784     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 785     my $m2 = $r->{Msg};
 786     if (!(grep { !$_->{IsOrigin} } @p) and
 787         (@orig_ps >= @p - 1) and
 788         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 789         $r->{NewMsg} = $m2;
 790         return $classify->(qw(DgitImportUnpatched),
 791                            OrigParents => \@orig_ps);
 792     }
 793
 794     if (@p == 2 and
 795         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 796         # xxx ^ metadata tag needs adding to (5)
 797         return $classify->("MergedBreakwaters");
 798     }
 799     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 800         return $unknown->("unknown kind of merge from $1");
 801     }
 802     if (@p > 2) {
 803         return $unknown->("octopus merge");
 804     }
 805
 806     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 807         return $unknown->("general two-parent merge");
 808     }
 809
 810     return $classify->("VanillaMerge");
 811 }
 812
 813 sub keycommits ($;$$$$$) {
 814     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 815     # => ($anchor, $breakwater)
 816
 817     # $unclean->("unclean-$tagsfx", $msg, $cl)
 818     # $furniture->("unclean-$tagsfx", $msg, $cl)
 819     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 820     #   is callled for each situation or commit that
 821     #   wouldn't be found in a laundered branch
 822     # $furniture is for furniture commits such as might be found on an
 823     #   interchange branch (pseudomerge, d/patches, changelog)
 824     # $trouble is for things whnich prevent the return of
 825     #   anchor and breakwater information; if that is ignored,
 826     #   then keycommits returns (undef, undef) instead.
 827     # $fatal is for unprocessable commits, and should normally cause
 828     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 829     #
 830     # If $claimed_bw, this is supposed to be a breakwater commit.
 831     #
 832     # If a callback is undef, fail is called instead.
 833     # If a callback is defined but false, the situation is ignored.
 834     # Callbacks may say:
 835     #   no warnings qw(exiting); last;
 836     # if the answer is no longer wanted.
 837
 838     my ($anchor, $breakwater);
 839     $breakwater = $head if $claimed_bw;
 840     my $clogonly;
 841     my $cl;
 842     my $found_pm;
 843     $fatal //= sub { fail $_[1]; };
 844     my $x = sub {
 845         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 846         my $why = $mainwhy.$xwhy;
 847         my $m = "branch needs laundering (run git-debrebase): $why";
 848         fail $m unless defined $cb;
 849         return unless $cb;
 850         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 851     };
 852     my $found_anchor = sub {
 853         ($anchor) = @_;
 854         $breakwater //= $clogonly;
 855         $breakwater //= $head;
 856         no warnings qw(exiting);
 857         last;
 858     };
 859     for (;;) {
 860         $cl = classify $head;
 861         my $ty = $cl->{Type};
 862         if ($ty eq 'Packaging') {
 863             $breakwater //= $clogonly;
 864             $breakwater //= $head;
 865         } elsif ($ty eq 'Changelog') {
 866             # this is going to count as the tip of the breakwater
 867             # only if it has no upstream stuff before it
 868             $clogonly //= $head;
 869         } elsif ($ty eq 'Anchor' or
 870                  $ty eq 'TreatAsAnchor' or
 871                  $ty eq 'BreakwaterStart') {
 872             $found_anchor->($head);
 873         } elsif ($ty eq 'Upstream') {
 874             $x->($unclean, 'ordering',
 875  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 876                 if defined $breakwater;
 877             $clogonly = undef;
 878             $breakwater = undef;
 879         } elsif ($ty eq 'Mixed') {
 880             $x->($unclean, 'mixed',
 881                  "found mixed upstream/packaging commit"," ($head)");
 882             $clogonly = undef;
 883             $breakwater = undef;
 884         } elsif ($ty eq 'Pseudomerge' or
 885                  $ty eq 'AddPatches') {
 886             my $found_pm = 1;
 887             $x->($furniture, (lc $ty),
 888                  "found interchange bureaucracy commit ($ty)"," ($head)");
 889         } elsif ($ty eq 'DgitImportUnpatched') {
 890             if ($found_pm) {
 891                 $x->($trouble, 'dgitimport',
 892                      "found dgit dsc import"," ($head)");
 893                 return (undef,undef);
 894             } else {
 895                 $x->($fatal, 'unprocessable',
 896                      "found bare dgit dsc import with no prior history",
 897                      " ($head)");
 898                 return (undef,undef);
 899             }
 900         } elsif ($ty eq 'VanillaMerge') {
 901             $x->($trouble, 'vanillamerge',
 902                  "found vanilla merge"," ($head)");
 903             return (undef,undef);
 904         } else {
 905             $x->($fatal, 'unprocessable',
 906                  "found unprocessable commit, cannot cope: $cl->{Why}",
 907                  " ($head)");
 908             return (undef,undef);
 909         }
 910         $head = $cl->{Parents}[0]{CommitId};
 911     }
 912     return ($anchor, $breakwater);
 913 }
 914
 915 sub walk ($;$$$);
 916 sub walk ($;$$$) {
 917     my ($input,
 918         $nogenerate,$report, $report_lprefix) = @_;
 919     # => ($tip, $breakwater_tip, $last_anchor)
 920     # (or nothing, if $nogenerate)
 921
 922     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 923     $report_lprefix //= '';
 924
 925     # go through commits backwards
 926     # we generate two lists of commits to apply:
 927     # breakwater branch and upstream patches
 928     my (@brw_cl, @upp_cl, @processed);
 929     my %found;
 930     my $upp_limit;
 931     my @pseudomerges;
 932
 933     my $cl;
 934     my $xmsg = sub {
 935         my ($prose, $info) = @_;
 936         my $ms = $cl->{Msg};
 937         chomp $ms;
 938         $info //= '';
 939         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 940         return (Msg => $ms);
 941     };
 942     my $rewrite_from_here = sub {
 943         my ($cl) = @_;
 944         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 945         push @$cl, $sp_cl;
 946         push @processed, $sp_cl;
 947     };
 948     my $cur = $input;
 949
 950     my $prdelim = "";
 951     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 952
 953     my $prline = sub {
 954         return unless $report;
 955         print $report $prdelim, $report_lprefix, @_;
 956         $prdelim = "\n";
 957     };
 958
 959     my $bomb = sub { # usage: return $bomb->();
 960         print $report " Unprocessable" if $report;
 961         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
 962         $prprdelim->();
 963         if ($nogenerate) {
 964             return (undef,undef);
 965         }
 966         fail "found unprocessable commit, cannot cope".
 967             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
 968             " (commit $cur) (d.".
 969             (join ' ', map { sprintf "%#x", $_->{Differs} }
 970              @{ $cl->{Parents} }).
 971                  ")";
 972     };
 973
 974     my $build;
 975     my $breakwater;
 976
 977     my $build_start = sub {
 978         my ($msg, $parent) = @_;
 979         $prline->(" $msg");
 980         $build = $parent;
 981         no warnings qw(exiting); last;
 982     };
 983
 984     my $nomerge = sub {
 985         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
 986     };
 987
 988     my $last_anchor;
 989
 990     for (;;) {
 991         $cl = classify $cur;
 992         my $ty = $cl->{Type};
 993         my $st = $cl->{SubType};
 994         $prline->("$cl->{CommitId} $cl->{Type}");
 995         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
 996         push @processed, $cl;
 997         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
 998         if ($ty eq 'AddPatches') {
 999             $cur = $p0;
1000             $rewrite_from_here->(\@upp_cl);
1001             next;
1002         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1003             push @brw_cl, $cl;
1004             $cur = $p0;
1005             next;
1006         } elsif ($ty eq 'BreakwaterStart') {
1007             $last_anchor = $cur;
1008             $build_start->('FirstPackaging', $cur);
1009         } elsif ($ty eq 'Upstream') {
1010             push @upp_cl, $cl;
1011             $cur = $p0;
1012             next;
1013         } elsif ($ty eq 'Mixed') {
1014             my $queue = sub {
1015                 my ($q, $wh) = @_;
1016                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1017                 push @$q, $cls;
1018             };
1019             $queue->(\@brw_cl, "debian");
1020             $queue->(\@upp_cl, "upstream");
1021             $rewrite_from_here->(\@brw_cl);
1022             $cur = $p0;
1023             next;
1024         } elsif ($ty eq 'Pseudomerge') {
1025             my $contrib = $cl->{Contributor}{CommitId};
1026             print $report " Contributor=$contrib" if $report;
1027             push @pseudomerges, $cl;
1028             $rewrite_from_here->(\@upp_cl);
1029             $cur = $contrib;
1030             next;
1031         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1032             $last_anchor = $cur;
1033             $build_start->("Anchor", $cur);
1034         } elsif ($ty eq 'DgitImportUnpatched') {
1035             my $pm = $pseudomerges[-1];
1036             if (defined $pm) {
1037                 # To an extent, this is heuristic.  Imports don't have
1038                 # a useful history of the debian/ branch.  We assume
1039                 # that the first pseudomerge after an import has a
1040                 # useful history of debian/, and ignore the histories
1041                 # from later pseudomerges.  Often the first pseudomerge
1042                 # will be the dgit import of the upload to the actual
1043                 # suite intended by the non-dgit NMUer, and later
1044                 # pseudomerges may represent in-archive copies.
1045                 my $ovwrs = $pm->{Overwritten};
1046                 printf $report " PM=%s \@Overwr:%d",
1047                     $pm->{CommitId}, (scalar @$ovwrs)
1048                     if $report;
1049                 if (@$ovwrs != 1) {
1050                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1051                     return $bomb->();
1052                 }
1053                 my $ovwr = $ovwrs->[0]{CommitId};
1054                 printf $report " Overwr=%s", $ovwr if $report;
1055                 # This import has a tree which is just like a
1056                 # breakwater tree, but it has the wrong history.  It
1057                 # ought to have the previous breakwater (which the
1058                 # pseudomerge overwrote) as an ancestor.  That will
1059                 # make the history of the debian/ files correct.  As
1060                 # for the upstream version: either it's the same as
1061                 # was ovewritten (ie, same as the previous
1062                 # breakwater), in which case that history is precisely
1063                 # right; or, otherwise, it was a non-gitish upload of a
1064                 # new upstream version.  We can tell these apart by
1065                 # looking at the tree of the supposed upstream.
1066                 push @brw_cl, {
1067                     %$cl,
1068                     SpecialMethod => 'DgitImportDebianUpdate',
1069                     $xmsg->("convert dgit import: debian changes")
1070                 }, {
1071                     %$cl,
1072                     SpecialMethod => 'DgitImportUpstreamUpdate',
1073                     $xmsg->("convert dgit import: upstream update",
1074                             " anchor")
1075                 };
1076                 $prline->(" Import");
1077                 $rewrite_from_here->(\@brw_cl);
1078                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1079                 $cur = $ovwr;
1080                 next;
1081             } else {
1082                 # Everything is from this import.  This kind of import
1083                 # is already nearly in valid breakwater format, with the
1084                 # patches as commits.  Unfortunately it contains
1085                 # debian/patches/.
1086                 printdebug "*** WALK BOMB bare dgit import\n";
1087                 $cl->{Why} = "bare dgit dsc import";
1088                 return $bomb->();
1089             }
1090             die "$ty ?";
1091         } elsif ($ty eq 'VanillaMerge' or $ty eq 'MergedBreakwaters') {
1092             # User may have merged unstitched branch(es).  We will
1093             # have now lost what ffq-prev was then (since the later
1094             # pseudomerge may introduce further changes).  The effect
1095             # of resolving such a merge is that we may have to go back
1096             # further in history to find a merge base, since the one
1097             # which was reachable via ffq-prev is no longer findable.
1098             # This is suboptimal, but if it all works we'll have done
1099             # the right thing.
1100             # xxx we should warn the user in the docs about this
1101
1102             my $ok=1;
1103             my $best_anchor;
1104             # We expect to find a dominating anchor amongst the
1105             # inputs' anchors.  That will be the new anchor.
1106             #
1107             # More complicated is finding a merge base for the
1108             # breakwaters.  We need a merge base that is a breakwater
1109             # commit.  The ancestors of breakwater commits are more
1110             # breakwater commits and possibly upstream commits and the
1111             # ancestors of those upstream.  Upstreams might have
1112             # arbitrary ancestors.  But any upstream commit U is
1113             # either included in both anchors, in which case the
1114             # earlier anchor is a better merge base than any of U's
1115             # ancestors; or U is not included in the older anchor, in
1116             # which case U is not an ancestor of the vanilla merge at
1117             # all.  So no upstream commit, nor any ancestor thereof,
1118             # is a best merge base.  As for non-breakwater Debian
1119             # commits: these are never ancestors of any breakwater.
1120             #
1121             # So any best merge base as found by git-merge-base
1122             # is a suitable breakwater anchor.  Usually there will
1123             # be only one.
1124
1125             printdebug "*** MERGE\n";
1126
1127             # xxx avoid calling walk without nogenerate when
1128             # we have a MergedBreakwater; instead call keycommits ?
1129
1130             my @bwbcmd = (@git, qw(merge-base));
1131             my @ibcmd = (@git, qw(merge-base --all));
1132             my $might_be_in_bw = 1;
1133
1134             my $ps = $cl->{Parents};
1135
1136             foreach my $p (@$ps) {
1137                 $prline->(" VanillaMerge ".$p->{Ix});
1138                 $prprdelim->();
1139                 my ($ptip, $pbw, $panchor) =
1140                     walk $p->{CommitId}, 0, $report,
1141                          $report_lprefix.'  ';
1142                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1143                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1144                 $p->{Anchor} = $panchor;
1145
1146                 $best_anchor = $panchor if
1147                     !defined $best_anchor or
1148                     is_fast_fwd $best_anchor, $panchor;
1149
1150                 printdebug " MERGE BA best=".($best_anchor//'-').
1151                     " p=$panchor\n";
1152             }
1153
1154             foreach my $p (@$ps) {
1155                 $prline->(" VanillaMerge ".$p->{Ix});
1156                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1157                     $nomerge->('DivergentAnchor');
1158                 } elsif ($p->{Anchor} eq $best_anchor) {
1159                     print $report " SameAnchor" if $report;
1160                 } else {
1161                     print $report " SupersededAnchor" if $report;
1162                 }
1163                 if ($p->{Breakwater} eq $p->{CommitId}) {
1164                     # this parent commit was its own breakwater,
1165                     # ie it is part of the breakwater
1166                     print $report " Breakwater" if $report;
1167                 } else {
1168                     $might_be_in_bw = 0;
1169                 }
1170                 push @bwbcmd, $p->{Breakwater};
1171                 push @ibcmd, $p->{CommitId};
1172             }
1173
1174             if ($ok && $might_be_in_bw) {
1175                 $prline->(" VanillaMerge MergedBreakwaters");
1176                 $last_anchor = $best_anchor;
1177                 $build_start->('MergedBreakwaters', $cur);
1178             }
1179
1180             $nomerge->("alleged merged-breakwater is not a breakwater")
1181                 unless $ty eq 'VanillaMerge';
1182
1183             my $bwb = cmdoutput @bwbcmd;
1184
1185             # OK, now we have a breakwater base, but we need the merge
1186             # base for the interchange branch because we need the delta
1187             # queue.
1188             #
1189             # This a the best merge base of our inputs which has the
1190             # breakwater merge base as an ancestor.
1191
1192             my @ibs =
1193                 grep { is_fast_fwd $bwb, $_ }
1194                 grep /./,
1195                 split /\n/,
1196                 cmdoutput @ibcmd;
1197             my ($ib) = @ibs
1198                 or $nomerge->("no suitable interchange merge base");
1199
1200             $prline->("  VanillaMerge Base");
1201             $prprdelim->();
1202             my ($btip, $bbw, $banchor) =
1203                 walk $ib, 0, $report, $report_lprefix.'  ';
1204
1205             my $ibinfo = { SeriesTip => $btip,
1206                            SeriesBase => $bbw,
1207                            Anchor => $banchor };
1208             $bbw eq $bwb
1209                 or $nomerge->("interchange merge-base ($ib)'s".
1210                               " breakwater ($bbw)".
1211                               " != breakwaters' merge-base ($bwb)");
1212             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1213                  or $nomerge->("interchange merge-base ($ib)'s".
1214                                " anchor ($ibinfo->{SeriesBase})".
1215                                " != any merge input's anchor (".
1216                                (join ' ', map { $_->{Anchor} } @$ps).
1217                                ")");
1218
1219
1220             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1221             $cl->{MergeBestAnchor} = $best_anchor;
1222             push @brw_cl, {
1223                 %$cl,
1224                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1225                 $xmsg->('constructed from vanilla merge',
1226                         ' merged-breakwater'),
1227             };
1228             push @upp_cl, {
1229                 %$cl,
1230                 SpecialMethod => 'MergeMergeSeries',
1231             };
1232             $build_start->('MergeBreakwaters', $cur);
1233         } else {
1234             printdebug "*** WALK BOMB unrecognised\n";
1235             return $bomb->();
1236         }
1237     }
1238     $prprdelim->();
1239
1240     printdebug "*** WALK prep done cur=$cur".
1241         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1242
1243     return if $nogenerate;
1244
1245     # Now we build it back up again
1246
1247     fresh_workarea();
1248
1249     my $rewriting = 0;
1250
1251     $#upp_cl = $upp_limit if defined $upp_limit;
1252
1253     my $committer_authline = calculate_committer_authline();
1254
1255     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1256
1257     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1258
1259     in_workarea sub {
1260         mkdir $rd or $!==EEXIST or die $!;
1261         my $current_method;
1262         runcmd @git, qw(read-tree), $build;
1263         foreach my $cl (qw(Debian), (reverse @brw_cl),
1264                         { SpecialMethod => 'RecordBreakwaterTip' },
1265                         qw(Upstream), (reverse @upp_cl)) {
1266             if (!ref $cl) {
1267                 $current_method = $cl;
1268                 next;
1269             }
1270             my $method = $cl->{SpecialMethod} // $current_method;
1271             my @parents = ($build);
1272             my $cltree = $cl->{CommitId};
1273             printdebug "WALK BUILD ".($cltree//'undef').
1274                 " $method (rewriting=$rewriting)\n";
1275             if ($method eq 'Debian') {
1276                 read_tree_debian($cltree);
1277             } elsif ($method eq 'Upstream') {
1278                 read_tree_upstream($cltree);
1279             } elsif ($method eq 'StartRewrite') {
1280                 $rewriting = 1;
1281                 next;
1282             } elsif ($method eq 'RecordBreakwaterTip') {
1283                 $breakwater = $build;
1284                 next;
1285             } elsif ($method eq 'DgitImportDebianUpdate') {
1286                 read_tree_debian($cltree);
1287             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1288                 confess unless $rewriting;
1289                 my $differs = (get_differs $build, $cltree);
1290                 next unless $differs & D_UPS;
1291                 read_tree_upstream($cltree);
1292                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1293             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1294                 print "Found a general merge, will try to tidy it up.\n";
1295                 $rewriting = 1;
1296                 read_tree_upstream($cl->{MergeBestAnchor});
1297                 read_tree_upstream($cl->{MergeBestAnchor});
1298                 read_tree_debian($cltree);
1299                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1300             } elsif ($method eq 'MergeMergeSeries') {
1301                 print "Running merge resolution for $cl->{CommitId}...\n";
1302                 $build = merge_series
1303                     $build,
1304                     $cl->{MergeInterchangeBaseInfo},
1305                     @{ $cl->{Parents} };
1306                 $last_anchor = $cl->{MergeBestAnchor};
1307                 my $check_differs = get_differs $build, $cl->{CommitId};
1308                 # Breakwater changes which were in each side of the
1309                 # merge should be in MergeCreateMergedBreakwaters
1310                 # output.  Upstream changes are exactly the result
1311                 # of merge_series.  So the only difference should
1312                 # be potential laundry results.
1313                 $nomerge->(sprintf
1314                     "merge misresolved: tree is not the same (%s %s d.%#x)",
1315                            $cl->{CommitId}, $build, $check_differs)
1316                     if $check_differs & ~D_PAT_ADD;
1317                 print "Merge resolution successful.\n";
1318                 next;
1319             } else {
1320                 confess "$method ?";
1321             }
1322             if (!$rewriting) {
1323                 my $procd = (pop @processed) // 'UNDEF';
1324                 if ($cl ne $procd) {
1325                     $rewriting = 1;
1326                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1327                 }
1328             }
1329             my $newtree = cmdoutput @git, qw(write-tree);
1330             my $ch = $cl->{Hdr};
1331             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1332             $ch =~ s{^parent .*\n}{}mg;
1333             $ch =~ s{(?=^author)}{
1334                 join '', map { "parent $_\n" } @parents
1335             }me or confess "$ch ?";
1336             if ($rewriting) {
1337                 $ch =~ s{^committer .*$}{$committer_authline}m
1338                     or confess "$ch ?";
1339             }
1340             my $cf = "$rd/m$rewriting";
1341             open CD, ">", $cf or die $!;
1342             print CD $ch, "\n", $cl->{Msg} or die $!;
1343             close CD or die $!;
1344             my @cmd = (@git, qw(hash-object));
1345             push @cmd, qw(-w) if $rewriting;
1346             push @cmd, qw(-t commit), $cf;
1347             my $newcommit = cmdoutput @cmd;
1348             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1349             $build = $newcommit;
1350             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1351                 $last_anchor = $cur;
1352             }
1353         }
1354     };
1355
1356     my $final_check = get_differs $build, $input;
1357     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1358         if $final_check & ~D_PAT_ADD;
1359
1360     my @r = ($build, $breakwater, $last_anchor);
1361     printdebug "*** WALK RETURN @r\n";
1362     return @r
1363 }
1364
1365 sub get_head () {
1366     git_check_unmodified();
1367     return git_rev_parse qw(HEAD);
1368 }
1369
1370 sub update_head ($$$) {
1371     my ($old, $new, $mrest) = @_;
1372     push @deferred_updates, "update HEAD $new $old";
1373     run_deferred_updates $mrest;
1374 }
1375
1376 sub update_head_checkout ($$$) {
1377     my ($old, $new, $mrest) = @_;
1378     update_head $old, $new, $mrest;
1379     runcmd @git, qw(reset --hard);
1380 }
1381
1382 sub update_head_postlaunder ($$$) {
1383     my ($old, $tip, $reflogmsg) = @_;
1384     return if $tip eq $old;
1385     print "git-debrebase: laundered (head was $old)\n";
1386     update_head $old, $tip, $reflogmsg;
1387     # no tree changes except debian/patches
1388     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1389 }
1390
1391 sub currently_rebasing() {
1392     foreach (qw(rebase-merge rebase-apply)) {
1393         return 1 if stat_exists "$maindir_gitdir/$_";
1394     }
1395     return 0;
1396 }
1397
1398 sub bail_if_rebasing() {
1399     fail "you are in the middle of a git-rebase already"
1400         if currently_rebasing();
1401 }
1402
1403 sub do_launder_head ($) {
1404     my ($reflogmsg) = @_;
1405     my $old = get_head();
1406     record_ffq_auto();
1407     my ($tip,$breakwater) = walk $old;
1408     snags_maybe_bail();
1409     update_head_postlaunder $old, $tip, $reflogmsg;
1410     return ($tip,$breakwater);
1411 }
1412
1413 sub cmd_launder_v0 () {
1414     badusage "no arguments to launder-v0 allowed" if @ARGV;
1415     my $old = get_head();
1416     my ($tip,$breakwater,$last_anchor) = walk $old;
1417     update_head_postlaunder $old, $tip, 'launder';
1418     printf "# breakwater tip\n%s\n", $breakwater;
1419     printf "# working tip\n%s\n", $tip;
1420     printf "# last anchor\n%s\n", $last_anchor;
1421 }
1422
1423 sub defaultcmd_rebase () {
1424     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1425     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1426     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1427 }
1428
1429 sub cmd_analyse () {
1430     badusage "analyse does not support any options"
1431         if @ARGV and $ARGV[0] =~ m/^-/;
1432     badusage "too many arguments to analyse" if @ARGV>1;
1433     my ($old) = @ARGV;
1434     if (defined $old) {
1435         $old = git_rev_parse $old;
1436     } else {
1437         $old = git_rev_parse 'HEAD';
1438     }
1439     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1440     STDOUT->error and die $!;
1441 }
1442
1443 sub ffq_prev_branchinfo () {
1444     my $current = git_get_symref();
1445     return gdr_ffq_prev_branchinfo($current);
1446 }
1447
1448 sub ffq_check ($;$$) {
1449     # calls $ff and/or $notff zero or more times
1450     # then returns either (status,message) where status is
1451     #    exists
1452     #    detached
1453     #    weird-symref
1454     #    notbranch
1455     # or (undef,undef, $ffq_prev,$gdrlast)
1456     # $ff and $notff are called like this:
1457     #   $ff->("message for stdout\n");
1458     #   $notff->('snag-name', $message);
1459     # normally $currentval should be HEAD
1460     my ($currentval, $ff, $notff) =@_;
1461
1462     $ff //= sub { print $_[0] or die $!; };
1463     $notff //= \&snag;
1464
1465     my ($status, $message, $current, $ffq_prev, $gdrlast)
1466         = ffq_prev_branchinfo();
1467     return ($status, $message) unless $status eq 'branch';
1468
1469     my $exists = git_get_ref $ffq_prev;
1470     return ('exists',"$ffq_prev already exists") if $exists;
1471
1472     return ('not-branch', 'HEAD symref is not to refs/heads/')
1473         unless $current =~ m{^refs/heads/};
1474     my $branch = $';
1475
1476     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1477     my %checked;
1478
1479     printdebug "ffq check_specs @check_specs\n";
1480
1481     my $check = sub {
1482         my ($lrref, $desc) = @_;
1483         printdebug "ffq might check $lrref ($desc)\n";
1484         my $invert;
1485         for my $chk (@check_specs) {
1486             my $glob = $chk;
1487             $invert = $glob =~ s{^[!^]}{};
1488             last if fnmatch $glob, $lrref;
1489         }
1490         return if $invert;
1491         my $lrval = git_get_ref $lrref;
1492         return unless length $lrval;
1493
1494         if (is_fast_fwd $lrval, $currentval) {
1495             $ff->("OK, you are ahead of $lrref\n");
1496             $checked{$lrref} = 1;
1497         } elsif (is_fast_fwd $currentval, $lrval) {
1498             $checked{$lrref} = -1;
1499             $notff->('behind', "you are behind $lrref, divergence risk");
1500         } else {
1501             $checked{$lrref} = -1;
1502             $notff->('diverged', "you have diverged from $lrref");
1503         }
1504     };
1505
1506     my $merge = cfg "branch.$branch.merge",1;
1507     if (defined $merge and $merge =~ m{^refs/heads/}) {
1508         my $rhs = $';
1509         printdebug "ffq merge $rhs\n";
1510         my $check_remote = sub {
1511             my ($remote, $desc) = @_;
1512             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1513             return unless defined $remote;
1514             $check->("refs/remotes/$remote/$rhs", $desc);
1515         };
1516         $check_remote->((scalar cfg "branch.$branch.remote",1),
1517                         'remote fetch/merge branch');
1518         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1519                         (scalar cfg "branch.$branch.pushDefault",1),
1520                         'remote push branch');
1521     }
1522     if ($branch =~ m{^dgit/}) {
1523         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1524     } elsif ($branch =~ m{^master$}) {
1525         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1526     }
1527     return (undef, undef, $ffq_prev, $gdrlast);
1528 }
1529
1530 sub record_ffq_prev_deferred () {
1531     # => ('status', "message")
1532     # 'status' may be
1533     #    deferred          message is undef
1534     #    exists
1535     #    detached
1536     #    weird-symref
1537     #    notbranch
1538     # if not ff from some branch we should be ff from, is an snag
1539     # if "deferred", will have added something about that to
1540     #   @deferred_update_messages, and also maybe printed (already)
1541     #   some messages about ff checks
1542     bail_if_rebasing();
1543     my $currentval = get_head();
1544
1545     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1546     return ($status,$message) if defined $status;
1547
1548     snags_maybe_bail();
1549
1550     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1551     push @deferred_updates, "delete $gdrlast";
1552     push @deferred_update_messages, "Recorded previous head for preservation";
1553     return ('deferred', undef);
1554 }
1555
1556 sub record_ffq_auto () {
1557     my ($status, $message) = record_ffq_prev_deferred();
1558     if ($status eq 'deferred' || $status eq 'exists') {
1559     } else {
1560         snag $status, "could not record ffq-prev: $message";
1561         snags_maybe_bail();
1562     }
1563 }
1564
1565 sub ffq_prev_info () {
1566     bail_if_rebasing();
1567     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1568     my ($status, $message, $current, $ffq_prev, $gdrlast)
1569         = ffq_prev_branchinfo();
1570     if ($status ne 'branch') {
1571         snag $status, "could not check ffq-prev: $message";
1572         snags_maybe_bail();
1573     }
1574     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1575     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1576 }
1577
1578 sub stitch ($$$$$) {
1579     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1580
1581     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1582
1583     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1584         my $differs = get_differs $old_head, $ffq_prev_commitish;
1585         unless ($differs & ~D_PAT_ADD) {
1586             # ffq-prev is ahead of us, and the only tree changes it has
1587             # are possibly addition of things in debian/patches/.
1588             # Just wind forwards rather than making a pointless pseudomerge.
1589             push @deferred_updates,
1590                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1591             update_head_checkout $old_head, $ffq_prev_commitish,
1592                 "stitch (fast forward)";
1593             return;
1594         }
1595     }
1596     fresh_workarea();
1597     # We make pseudomerges with L as the contributing parent.
1598     # This makes git rev-list --first-parent work properly.
1599     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1600         'Declare fast forward / record previous work',
1601         "[git-debrebase pseudomerge: $prose]",
1602     ];
1603     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1604     update_head $old_head, $new_head, "stitch: $prose";
1605 }
1606
1607 sub do_stitch ($;$) {
1608     my ($prose, $unclean) = @_;
1609
1610     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1611     if (!$ffq_prev_commitish) {
1612         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1613         return;
1614     }
1615     my $dangling_head = get_head();
1616
1617     keycommits $dangling_head, $unclean,$unclean,$unclean;
1618     snags_maybe_bail();
1619
1620     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1621 }
1622
1623 sub upstream_commitish_search ($$) {
1624     my ($upstream_version, $tried) = @_;
1625     # todo: at some point maybe use git-deborig to do this
1626     foreach my $tagpfx ('', 'v', 'upstream/') {
1627         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1628         my $new_upstream = git_get_ref "refs/tags/$tag";
1629         push @$tried, $tag;
1630         return $new_upstream if length $new_upstream;
1631     }
1632 }
1633
1634 sub resolve_upstream_version ($$) {
1635     my ($new_upstream, $upstream_version) = @_;
1636
1637     if (!defined $new_upstream) {
1638         my @tried;
1639         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1640         if (!length $new_upstream) {
1641             fail "Could not determine appropriate upstream commitish.\n".
1642                 " (Tried these tags: @tried)\n".
1643                 " Check version, and specify upstream commitish explicitly.";
1644         }
1645     }
1646     $new_upstream = git_rev_parse $new_upstream;
1647
1648     return $new_upstream;
1649 }
1650
1651 sub cmd_new_upstream () {
1652     # automatically and unconditionally launders before rebasing
1653     # if rebase --abort is used, laundering has still been done
1654
1655     my %pieces;
1656
1657     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1658
1659     # parse args - low commitment
1660     my $spec_version = shift @ARGV;
1661     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1662     fail "bad version number \`$spec_version'" unless defined $new_version;
1663     if ($new_version->is_native()) {
1664         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1665     }
1666
1667     my $new_upstream = shift @ARGV;
1668     my $new_upstream_version = upstreamversion  $new_version;
1669     $new_upstream =
1670         resolve_upstream_version $new_upstream, $new_upstream_version;
1671
1672     record_ffq_auto();
1673
1674     my $piece = sub {
1675         my ($n, @x) = @_; # may be ''
1676         my $pc = $pieces{$n} //= {
1677             Name => $n,
1678             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1679         };
1680         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1681         $pc;
1682     };
1683
1684     my @newpieces;
1685     my $newpiece = sub {
1686         my ($n, @x) = @_; # may be ''
1687         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1688         push @newpieces, $pc;
1689     };
1690
1691     $newpiece->('',
1692         OldIx => 0,
1693         New => $new_upstream,
1694     );
1695     while (@ARGV && $ARGV[0] !~ m{^-}) {
1696         my $n = shift @ARGV;
1697
1698         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1699             unless @ARGV && $ARGV[0] !~ m{^-};
1700
1701         my $c = git_rev_parse shift @ARGV;
1702         die unless $n =~ m/^$extra_orig_namepart_re$/;
1703         $newpiece->($n, New => $c);
1704     }
1705
1706     # now we need to investigate the branch this generates the
1707     # laundered version but we don't switch to it yet
1708     my $old_head = get_head();
1709     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1710
1711     my $old_bw_cl = classify $old_bw;
1712     my $old_anchor_cl = classify $old_anchor;
1713     my $old_upstream;
1714     if (!$old_anchor_cl->{OrigParents}) {
1715         snag 'anchor-treated',
1716             'old anchor is recognised due to --anchor, cannot check upstream';
1717     } else {
1718         $old_upstream = parsecommit
1719             $old_anchor_cl->{OrigParents}[0]{CommitId};
1720         $piece->('', Old => $old_upstream->{CommitId});
1721     }
1722
1723     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1724         if ($old_upstream->{Msg} =~
1725  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1726            ) {
1727             my @oldpieces = (split / /, $1);
1728             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1729             if ($old_n_parents != @oldpieces &&
1730                 $old_n_parents != @oldpieces + 1) {
1731                 snag 'upstream-confusing', sprintf
1732                     "previous upstream combine %s".
1733                     " mentions %d pieces (each implying one parent)".
1734                     " but has %d parents".
1735                     " (one per piece plus maybe a previous combine)",
1736                     $old_upstream->{CommitId},
1737                     (scalar @oldpieces),
1738                     $old_n_parents;
1739             } elsif ($oldpieces[0] ne '.') {
1740                 snag 'upstream-confusing', sprintf
1741                     "previous upstream combine %s".
1742                     " first piece is not \`.'",
1743                     $oldpieces[0];
1744             } else {
1745                 $oldpieces[0] = '';
1746                 foreach my $i (0..$#oldpieces) {
1747                     my $n = $oldpieces[$i];
1748                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1749                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1750                 }
1751             }
1752         } else {
1753             snag 'upstream-confusing',
1754                 "previous upstream $old_upstream->{CommitId} is from".
1755                " git-debrebase but not an \`upstream-combine' commit";
1756         }
1757     }
1758
1759     foreach my $pc (values %pieces) {
1760         if (!$old_upstream) {
1761             # we have complained already
1762         } elsif (!$pc->{Old}) {
1763             snag 'upstream-new-piece',
1764                 "introducing upstream piece \`$pc->{Name}'";
1765         } elsif (!$pc->{New}) {
1766             snag 'upstream-rm-piece',
1767                 "dropping upstream piece \`$pc->{Name}'";
1768         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1769             snag 'upstream-not-ff',
1770                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1771         }
1772     }
1773
1774     printdebug "%pieces = ", (dd \%pieces), "\n";
1775     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1776
1777     snags_maybe_bail();
1778
1779     my $new_bw;
1780
1781     fresh_workarea();
1782     in_workarea sub {
1783         my @upstream_merge_parents;
1784
1785         if (!any_snags()) {
1786             push @upstream_merge_parents, $old_upstream->{CommitId};
1787         }
1788
1789         foreach my $pc (@newpieces) { # always has '' first
1790             if ($pc->{Name}) {
1791                 read_tree_subdir $pc->{Name}, $pc->{New};
1792             } else {
1793                 runcmd @git, qw(read-tree), $pc->{New};
1794             }
1795             push @upstream_merge_parents, $pc->{New};
1796         }
1797
1798         # index now contains the new upstream
1799
1800         if (@newpieces > 1) {
1801             # need to make the upstream subtree merge commit
1802             $new_upstream = make_commit \@upstream_merge_parents,
1803                 [ "Combine upstreams for $new_upstream_version",
1804  ("[git-debrebase upstream-combine . ".
1805  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1806  ": new upstream]"),
1807                 ];
1808         }
1809
1810         # $new_upstream is either the single upstream commit, or the
1811         # combined commit we just made.  Either way it will be the
1812         # "upstream" parent of the anchor merge.
1813
1814         read_tree_subdir 'debian', "$old_bw:debian";
1815
1816         # index now contains the anchor merge contents
1817         $new_bw = make_commit [ $old_bw, $new_upstream ],
1818             [ "Update to upstream $new_upstream_version",
1819  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1820             ];
1821
1822         my $clogsignoff = cmdoutput qw(git show),
1823             '--pretty=format:%an <%ae>  %aD',
1824             $new_bw;
1825
1826         # Now we have to add a changelog stanza so the Debian version
1827         # is right.
1828         die if unlink "debian";
1829         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1830         unlink "debian/changelog" or $!==ENOENT or die $!;
1831         mkdir "debian" or die $!;
1832         open CN, ">", "debian/changelog" or die $!;
1833         my $oldclog = git_cat_file ":debian/changelog";
1834         $oldclog =~ m/^($package_re) \(\S+\) / or
1835             fail "cannot parse old changelog to get package name";
1836         my $p = $1;
1837         print CN <<END, $oldclog or die $!;
1838 $p ($new_version) UNRELEASED; urgency=medium
1839
1840   * Update to new upstream version $new_upstream_version.
1841
1842  -- $clogsignoff
1843
1844 END
1845         close CN or die $!;
1846         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1847
1848         # Now we have the final new breakwater branch in the index
1849         $new_bw = make_commit [ $new_bw ],
1850             [ "Update changelog for new upstream $new_upstream_version",
1851               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1852             ];
1853     };
1854
1855     # we have constructed the new breakwater. we now need to commit to
1856     # the laundering output, because git-rebase can't easily be made
1857     # to make a replay list which is based on some other branch
1858
1859     update_head_postlaunder $old_head, $old_laundered_tip,
1860         'launder for new upstream';
1861
1862     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1863     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1864         "debrebase new-upstream $new_version: rebase";
1865     runcmd @cmd;
1866     # now it's for the user to sort out
1867 }
1868
1869 sub cmd_record_ffq_prev () {
1870     badusage "no arguments allowed" if @ARGV;
1871     my ($status, $msg) = record_ffq_prev_deferred();
1872     if ($status eq 'exists' && $opt_noop_ok) {
1873         print "Previous head already recorded\n" or die $!;
1874     } elsif ($status eq 'deferred') {
1875         run_deferred_updates 'record-ffq-prev';
1876     } else {
1877         fail "Could not preserve: $msg";
1878     }
1879 }
1880
1881 sub cmd_anchor () {
1882     badusage "no arguments allowed" if @ARGV;
1883     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1884     print "$bw\n" or die $!;
1885 }
1886
1887 sub cmd_breakwater () {
1888     badusage "no arguments allowed" if @ARGV;
1889     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1890     print "$bw\n" or die $!;
1891 }
1892
1893 sub cmd_status () {
1894     badusage "no arguments allowed" if @ARGV;
1895
1896     # todo: gdr status should print divergence info
1897     # todo: gdr status should print upstream component(s) info
1898     # todo: gdr should leave/maintain some refs with this kind of info ?
1899
1900     my $oldest = { Badness => 0 };
1901     my $newest;
1902     my $note = sub {
1903         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1904         if ($oldest->{Badness} < $badness) {
1905             $oldest = $newest = undef;
1906         }
1907         $oldest = {
1908                    Badness => $badness,
1909                    CommitId => $cl->{CommitId},
1910                    OurMsg => $ourmsg,
1911                    KcMsg => $kcmsg,
1912                   };
1913         $newest //= $oldest;
1914     };
1915     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1916         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1917         sub { $note->(2, 'branch is unlaundered', @_); },
1918         sub { $note->(3, 'branch needs laundering', @_); },
1919         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1920
1921     my $prcommitinfo = sub {
1922         my ($cid) = @_;
1923         flush STDOUT or die $!;
1924         runcmd @git, qw(--no-pager log -n1),
1925             '--pretty=format:    %h %s%n',
1926             $cid;
1927     };
1928
1929     print "current branch contents, in git-debrebase terms:\n";
1930     if (!$oldest->{Badness}) {
1931         print "  branch is laundered\n";
1932     } else {
1933         print "  $oldest->{OurMsg}\n";
1934         my $printed = '';
1935         foreach my $info ($oldest, $newest) {
1936             my $cid = $info->{CommitId};
1937             next if $cid eq $printed;
1938             $printed = $cid;
1939             print "  $info->{KcMsg}\n";
1940             $prcommitinfo->($cid);
1941         }
1942     }
1943
1944     my $prab = sub {
1945         my ($cid, $what) = @_;
1946         if (!defined $cid) {
1947             print "  $what is not well-defined\n";
1948         } else {
1949             print "  $what\n";
1950             $prcommitinfo->($cid);
1951         }
1952     };
1953     print "key git-debrebase commits:\n";
1954     $prab->($anchor, 'anchor');
1955     $prab->($bw, 'breakwater');
1956
1957     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
1958         ffq_prev_branchinfo();
1959
1960     print "branch and ref status, in git-debrebase terms:\n";
1961     if ($ffq_msg) {
1962         print "  $ffq_msg\n";
1963     } else {
1964         $ffq_prev = git_get_ref $ffq_prev;
1965         $gdrlast = git_get_ref $gdrlast;
1966         if ($ffq_prev) {
1967             print "  unstitched; previous tip was:\n";
1968             $prcommitinfo->($ffq_prev);
1969         } elsif (!$gdrlast) {
1970             print "  stitched? (no record of git-debrebase work)\n";
1971         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
1972             print "  stitched\n";
1973         } else {
1974             print "  not git-debrebase (diverged since last stitch)\n"
1975         }
1976     }
1977     print "you are currently rebasing\n" if currently_rebasing();
1978 }
1979
1980 sub cmd_stitch () {
1981     my $prose = 'stitch';
1982     getoptions("stitch",
1983                'prose=s', \$prose);
1984     badusage "no arguments allowed" if @ARGV;
1985     do_stitch $prose, 0;
1986 }
1987 sub cmd_prepush () { cmd_stitch(); }
1988
1989 sub cmd_quick () {
1990     badusage "no arguments allowed" if @ARGV;
1991     do_launder_head 'launder for git-debrebase quick';
1992     do_stitch 'quick';
1993 }
1994
1995 sub cmd_conclude () {
1996     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1997     if (!$ffq_prev_commitish) {
1998         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
1999         return;
2000     }
2001     my $dangling_head = get_head();
2002
2003     badusage "no arguments allowed" if @ARGV;
2004     do_launder_head 'launder for git-debrebase quick';
2005     do_stitch 'quick';
2006 }
2007
2008 sub cmd_scrap () {
2009     if (currently_rebasing()) {
2010         runcmd @git, qw(rebase --abort);
2011     }
2012     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2013     if (!$ffq_prev_commitish) {
2014         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2015         finish 0;
2016     }
2017     my $scrapping_head = get_head();
2018     badusage "no arguments allowed" if @ARGV;
2019     push @deferred_updates,
2020         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2021         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2022     snags_maybe_bail();
2023     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2024 }
2025
2026 sub make_patches_staged ($) {
2027     my ($head) = @_;
2028     # Produces the patches that would result from $head if it were
2029     # laundered.
2030     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2031     fresh_workarea();
2032     in_workarea sub {
2033         gbp_pq_export 'bw', $secret_bw, $secret_head;
2034     };
2035 }
2036
2037 sub make_patches ($) {
2038     my ($head) = @_;
2039     keycommits $head, 0, \&snag;
2040     make_patches_staged $head;
2041     my $out;
2042     in_workarea sub {
2043         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2044         runcmd @git, qw(read-tree), $head;
2045         read_tree_subdir 'debian/patches', $ptree;
2046         $out = make_commit [$head], [
2047             'Commit patch queue (exported by git-debrebase)',
2048             '[git-debrebase: export and commit patches]',
2049         ];
2050     };
2051     return $out;
2052 }
2053
2054 sub cmd_make_patches () {
2055     my $opt_quiet_would_amend;
2056     getoptions("make-patches",
2057                'quiet-would-amend!', \$opt_quiet_would_amend);
2058     badusage "no arguments allowed" if @ARGV;
2059     bail_if_rebasing();
2060     my $old_head = get_head();
2061     my $new = make_patches $old_head;
2062     my $d = get_differs $old_head, $new;
2063     if ($d == 0) {
2064         fail "No (more) patches to export." unless $opt_noop_ok;
2065         return;
2066     } elsif ($d == D_PAT_ADD) {
2067         snags_maybe_bail();
2068         update_head_checkout $old_head, $new, 'make-patches';
2069     } else {
2070         print STDERR failmsg
2071             "Patch export produced patch amendments".
2072             " (abandoned output commit $new).".
2073             "  Try laundering first."
2074             unless $opt_quiet_would_amend;
2075         finish 7;
2076     }
2077 }
2078
2079 sub cmd_convert_from_gbp () {
2080     badusage "want only 1 optional argument, the upstream git commitish"
2081         unless @ARGV<=1;
2082
2083     my $clogp = parsechangelog();
2084     my $version = $clogp->{'Version'}
2085         // die "missing Version from changelog";
2086
2087     my ($upstream_spec) = @ARGV;
2088
2089     my $upstream_version = upstreamversion $version;
2090     my $upstream =
2091         resolve_upstream_version($upstream_spec, $upstream_version);
2092
2093     my $old_head = get_head();
2094
2095     my $upsdiff = get_differs $upstream, $old_head;
2096     if ($upsdiff & D_UPS) {
2097         runcmd @git, qw(--no-pager diff --stat),
2098             $upstream, $old_head,
2099             qw( -- :!/debian :/);
2100         fail <<END;
2101 upstream ($upstream_spec) and HEAD are not
2102 identical in upstream files.  See diffstat above, or run
2103   git diff $upstream_spec HEAD -- :!/debian :/
2104 END
2105     }
2106
2107     if (!is_fast_fwd $upstream, $old_head) {
2108         snag 'upstream-not-ancestor',
2109             "upstream ($upstream) is not an ancestor of HEAD";
2110     } else {
2111         my $wrong = cmdoutput
2112             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2113              qw(-- :/ :!/debian));
2114         if (length $wrong) {
2115             snag 'unexpected-upstream-changes',
2116                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2117             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2118         }
2119     }
2120
2121     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2122         snag 'upstream-has-debian',
2123             "upstream ($upstream) contains debian/ directory";
2124     }
2125
2126     my $previous_dgit_view = eval {
2127         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2128         my ($lvsn, $suite);
2129         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2130             my ($stz, $desc) = @_;
2131             no warnings qw(exiting);
2132             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2133             next unless $stz->{Date};
2134             next unless $stz->{Distribution} ne 'UNRELEASED';
2135             $lvsn = $stz->{Version};
2136             $suite = $stz->{Distribution};
2137             last;
2138         };
2139         die "neither of the first two changelog entries are released\n"
2140             unless defined $lvsn;
2141         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2142         my $mtag_pat = debiantag_maintview $lvsn, '*';
2143         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2144             $mtag_pat;
2145         die "could not find suitable maintainer view tag $mtag_pat\n"
2146             unless $mtag_pat =~ m{/};
2147         is_fast_fwd $mtag, 'HEAD' or
2148             die "HEAD is not FF from maintainer tag $mtag!";
2149         my $dtag = "archive/$mtag";
2150         is_fast_fwd $mtag, $dtag or
2151             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2152         print "will stitch in dgit view, $dtag\n";
2153         git_rev_parse $dtag;
2154     };
2155     if (!$previous_dgit_view) {
2156         $@ =~ s/^\n+//;
2157         chomp $@;
2158         print STDERR "cannot stitch in dgit view: $@\n";
2159     }
2160
2161     snags_maybe_bail_early();
2162
2163     my $work;
2164
2165     fresh_workarea();
2166     in_workarea sub {
2167         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2168         # make a branch out of the patch queue - we'll want this in a mo
2169         runcmd qw(gbp pq import);
2170         # strip the patches out
2171         runcmd @git, qw(checkout -q gdr-internal~0);
2172         rm_subdir_cached 'debian/patches';
2173         $work = make_commit ['HEAD'], [
2174  'git-debrebase convert-from-gbp: drop patches from tree',
2175  'Delete debian/patches, as part of converting to git-debrebase format.',
2176  '[git-debrebase convert-from-gbp: drop patches from tree]'
2177                               ];
2178         # make the anchor merge
2179         # the tree is already exactly right
2180         $work = make_commit [$work, $upstream], [
2181  'git-debrebase import: declare upstream',
2182  'First breakwater merge.',
2183  '[git-debrebase anchor: declare upstream]'
2184                               ];
2185
2186         # rebase the patch queue onto the new breakwater
2187         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2188         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2189         $work = git_rev_parse 'HEAD';
2190
2191         if ($previous_dgit_view) {
2192             $work = make_commit [$work, $previous_dgit_view], [
2193  'git-debrebase import: declare ff from dgit archive view',
2194  '[git-debrebase pseudomerge: import-from-gbp]',
2195             ];
2196         }
2197     };
2198
2199     ffq_check $work;
2200     snags_maybe_bail();
2201     update_head_checkout $old_head, $work, 'convert-from-gbp';
2202 }
2203
2204 sub cmd_convert_to_gbp () {
2205     badusage "no arguments allowed" if @ARGV;
2206     my $head = get_head();
2207     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2208     keycommits $head, 0;
2209     my $out;
2210     make_patches_staged $head;
2211     in_workarea sub {
2212         $out = make_commit ['HEAD'], [
2213             'Commit patch queue (converted from git-debrebase format)',
2214             '[git-debrebase convert-to-gbp: commit patches]',
2215         ];
2216     };
2217     if (defined $ffq) {
2218         push @deferred_updates, "delete $ffq";
2219         push @deferred_updates, "delete $gdrlast";
2220     }
2221     snags_maybe_bail();
2222     update_head_checkout $head, $out, "convert to gbp (v0)";
2223     print <<END or die $!;
2224 git-debrebase: converted to git-buildpackage branch format
2225 git-debrebase: WARNING: do not now run "git-debrebase" any more
2226 git-debrebase: WARNING: doing so would drop all upstream patches!
2227 END
2228 }
2229
2230 sub cmd_convert_from_dgit_view () {
2231     my $clogp = parsechangelog();
2232
2233     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2234     my $do_origs = 1;
2235     my $do_tags = 1;
2236     my $always = 0;
2237     my $diagnose = 0;
2238
2239     getoptions("convert-from-dgit-view",
2240                'diagnose!', \$diagnose,
2241                'build-products-dir:s', \$bpd,
2242                'origs!', \$do_origs,
2243                'tags!', \$do_tags,
2244                'always-convert-anyway!', \$always);
2245     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2246
2247     my @upstreams;
2248
2249     if (@ARGV) {
2250         my $spec = shift @ARGV;
2251         my $commit = git_rev_parse "$spec^{commit}";
2252         push @upstreams, { Commit => $commit,
2253                            Source => "$ARGV[0], from command line",
2254                            Only => 1,
2255                          };
2256     }
2257
2258     my $head = get_head();
2259
2260     if (!$always) {
2261         my $troubles = 0;
2262         my $trouble = sub { $troubles++; };
2263         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2264         printdebug "troubles=$troubles\n";
2265         if (!$troubles) {
2266             print STDERR <<END;
2267 $us: Branch already seems to be in git-debrebase format!
2268 $us: --always-convert-anyway would do the conversion operation anyway
2269 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2270 END
2271             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2272             finish 0;
2273         }
2274     }
2275
2276     snags_maybe_bail_early();
2277
2278     my $version = upstreamversion $clogp->{Version};
2279     print STDERR "Considering possible commits corresponding to upstream:\n";
2280
2281     if (!@upstreams) {
2282         if ($do_tags) {
2283             my @tried;
2284             my $ups_tag = upstream_commitish_search $version, \@tried;
2285             if ($ups_tag) {
2286                 my $this = "git tag $tried[-1]";
2287                 push @upstreams, { Commit => $ups_tag,
2288                                    Source => $this,
2289                                  };
2290             } else {
2291                 printf STDERR
2292                     " git tag: no suitable tag found (tried %s)\n",
2293                     "@tried";
2294             }
2295         }
2296         if ($do_origs) {
2297             my $p = $clogp->{'Source'};
2298             # we do a quick check to see if there are plausible origs
2299             my $something=0;
2300             if (!opendir BPD, $bpd) {
2301                 die "$bpd: opendir: $!" unless $!==ENOENT;
2302             } else {
2303                 while ($!=0, my $f = readdir BPD) {
2304                     next unless is_orig_file_of_p_v $f, $p, $version;
2305                     printf STDERR
2306                         " orig: found what looks like a .orig, %s\n",
2307                         "$bpd/$f";
2308                     $something=1;
2309                     last;
2310                 }
2311                 die "read $bpd: $!" if $!;
2312                 closedir BPD;
2313             }
2314             if ($something) {
2315                 my $tree = cmdoutput
2316                     @dgit, qw(--build-products-dir), $bpd,
2317                     qw(print-unapplied-treeish);
2318                 fresh_workarea();
2319                 in_workarea sub {
2320                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2321                     rm_subdir_cached 'debian';
2322                     $tree = cmdoutput @git, qw(write-tree);
2323                     my $ups_synth = make_commit [], [ <<END, <<END,
2324 Import effective orig tree for upstream version $version
2325 END
2326 This includes the contents of the .orig(s), minus any debian/ directory.
2327
2328 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2329 END
2330                                                     ];
2331                     push @upstreams, { Commit => $ups_synth,
2332                                        Source => "orig(s) imported via dgit",
2333                                      };
2334                 }
2335             } else {
2336                 printf STDERR
2337                     " orig: no suitable origs found (looked for %s in %s)\n",
2338                     "${p}_".(stripeoch $version)."...", $bpd;
2339             }
2340         }
2341     }
2342
2343     my $some_patches = stat_exists 'debian/patches/series';
2344
2345     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2346
2347     my $result;
2348     foreach my $u (@upstreams) {
2349         my $work = $head;
2350         fresh_workarea();
2351         in_workarea sub {
2352             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2353             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2354             runcmd @git, qw(clean -xdff);
2355             runcmd @git, qw(checkout), $head, qw(-- debian);
2356             if ($some_patches) {
2357                 rm_subdir_cached 'debian/patches';
2358                 $work = make_commit [ $work ], [
2359  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2360  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2361  "to git-debrebase format.  Upstream changes will appear as commits.",
2362  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2363                                            ];
2364             }
2365             $work = make_commit [ $work, $u->{Commit} ], [
2366  'git-debrebase convert-from-dgit-view: declare upstream',
2367  '(Re)constructed breakwater merge.',
2368  '[git-debrebase anchor: declare upstream]'
2369                                                          ];
2370             runcmd @git, qw(checkout --quiet -b mk), $work;
2371             if ($some_patches) {
2372                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2373                 runcmd @git, qw(reset --quiet);
2374                 my @gbp_cmd = (qw(gbp pq import));
2375                 if (!$diagnose) {
2376                     my $gbp_err = "../gbp-pq-err";
2377                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2378                 }
2379                 my $r = system @gbp_cmd;
2380                 if ($r) {
2381                     printf STDERR
2382                         " %s: couldn't apply patches: gbp pq %s",
2383                         $u->{Source}, waitstatusmsg();
2384                     return;
2385                 }
2386             }
2387             my $work = git_rev_parse qw(HEAD);
2388             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2389             if (length $diffout) {
2390                 print STDERR
2391                     " $u->{Source}: applying patches gives different tree\n";
2392                 print STDERR $diffout if $diagnose;
2393                 return;
2394             }
2395             # OMG!
2396             $u->{Result} = $work;
2397             $result = $u;
2398         };
2399         last if $result;
2400     }
2401
2402     if (!$result) {
2403         fail <<END;
2404 Could not find or construct a suitable upstream commit.
2405 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2406 upstream commmit explicitly or provide suitable origs.
2407 END
2408     }
2409
2410     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2411
2412     ffq_check $result->{Result};
2413     snags_maybe_bail();
2414     update_head_checkout $head, $result->{Result},
2415         'convert-from-dgit-view';
2416 }
2417
2418 sub cmd_downstream_rebase_launder_v0 () {
2419     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2420     my ($base) = @ARGV;
2421     $base = git_rev_parse $base;
2422     my $old_head = get_head();
2423     my $current = $old_head;
2424     my $topmost_keep;
2425     for (;;) {
2426         if ($current eq $base) {
2427             $topmost_keep //= $current;
2428             print " $current BASE stop\n";
2429             last;
2430         }
2431         my $cl = classify $current;
2432         print " $current $cl->{Type}";
2433         my $keep = 0;
2434         my $p0 = $cl->{Parents}[0]{CommitId};
2435         my $next;
2436         if ($cl->{Type} eq 'Pseudomerge') {
2437             print " ^".($cl->{Contributor}{Ix}+1);
2438             $next = $cl->{Contributor}{CommitId};
2439         } elsif ($cl->{Type} eq 'AddPatches' or
2440                  $cl->{Type} eq 'Changelog') {
2441             print " strip";
2442             $next = $p0;
2443         } else {
2444             print " keep";
2445             $next = $p0;
2446             $keep = 1;
2447         }
2448         print "\n";
2449         if ($keep) {
2450             $topmost_keep //= $current;
2451         } else {
2452             die "to-be stripped changes not on top of the branch\n"
2453                 if $topmost_keep;
2454         }
2455         $current = $next;
2456     }
2457     if ($topmost_keep eq $old_head) {
2458         print "unchanged\n";
2459     } else {
2460         print "updating to $topmost_keep\n";
2461         update_head_checkout
2462             $old_head, $topmost_keep,
2463             'downstream-rebase-launder-v0';
2464     }
2465 }
2466
2467 getoptions_main
2468           ("bad options\n",
2469            "D+" => \$debuglevel,
2470            'noop-ok', => \$opt_noop_ok,
2471            'f=s' => \@snag_force_opts,
2472            'anchor=s' => \@opt_anchors,
2473            '--dgit=s' => \($dgit[0]),
2474            'force!',
2475            '-i:s' => sub {
2476                my ($opt,$val) = @_;
2477                badusage "git-debrebase: no cuddling to -i for git-rebase"
2478                    if length $val;
2479                die if $opt_defaultcmd_interactive; # should not happen
2480                $opt_defaultcmd_interactive = [ qw(-i) ];
2481                # This access to @ARGV is excessive familiarity with
2482                # Getopt::Long, but there isn't another sensible
2483                # approach.  '-i=s{0,}' does not work with bundling.
2484                push @$opt_defaultcmd_interactive, @ARGV;
2485                @ARGV=();
2486            },
2487            'help' => sub { print $usage_message or die $!; finish 0; },
2488            );
2489
2490 initdebug('git-debrebase ');
2491 enabledebug if $debuglevel;
2492
2493 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2494 chdir $toplevel or die "chdir $toplevel: $!";
2495
2496 $rd = fresh_playground "$playprefix/misc";
2497
2498 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2499
2500 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2501     defaultcmd_rebase();
2502 } else {
2503     my $cmd = shift @ARGV;
2504     my $cmdfn = $cmd;
2505     $cmdfn =~ y/-/_/;
2506     $cmdfn = ${*::}{"cmd_$cmdfn"};
2507
2508     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2509     $cmdfn->();
2510 }
2511
2512 finish 0;