git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive);
  55
  56 our $us = qw(git-debrebase);
  57
  58 $|=1;
  59
  60 sub badusage ($) {
  61     my ($m) = @_;
  62     print STDERR "$us: bad usage: $m\n";
  63     finish 8;
  64 }
  65
  66 sub getoptions_main {
  67     my $m = shift;
  68     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  69     GetOptions @_ or badusage $m;
  70 }
  71 sub getoptions {
  72     my $sc = shift;
  73     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  74 }
  75
  76 sub cfg ($;$) {
  77     my ($k, $optional) = @_;
  78     local $/ = "\0";
  79     my @cmd = qw(git config -z);
  80     push @cmd, qw(--get-all) if wantarray;
  81     push @cmd, $k;
  82     my $out = cmdoutput_errok @cmd;
  83     if (!defined $out) {
  84         fail "missing required git config $k" unless $optional;
  85         return ();
  86     }
  87     my @l = split /\0/, $out;
  88     return wantarray ? @l : $l[0];
  89 }
  90
  91 memoize('cfg');
  92
  93 sub dd ($) {
  94     my ($v) = @_;
  95     my $dd = new Data::Dumper [ $v ];
  96     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  97     return Dump $dd;
  98 }
  99
 100 sub get_commit ($) {
 101     my ($objid) = @_;
 102     my $data = (git_cat_file $objid, 'commit');
 103     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 104     return ($`,$');
 105 }
 106
 107 sub D_UPS ()      { 0x02; } # upstream files
 108 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 109 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 110 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 111 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 112 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 113
 114 our $playprefix = 'debrebase';
 115 our $rd;
 116 our $workarea;
 117
 118 our @git = qw(git);
 119 our @dgit = qw(dgit);
 120
 121 sub in_workarea ($) {
 122     my ($sub) = @_;
 123     changedir $workarea;
 124     my $r = eval { $sub->(); };
 125     { local $@; changedir $maindir; }
 126     die $@ if $@;
 127 }
 128
 129 sub fresh_workarea () {
 130     $workarea = fresh_playground "$playprefix/work";
 131     in_workarea sub { playtree_setup };
 132 }
 133
 134 our $snags_forced = 0;
 135 our $snags_tripped = 0;
 136 our $snags_summarised = 0;
 137 our @deferred_updates;
 138 our @deferred_update_messages;
 139
 140 sub all_snags_summarised () {
 141     $snags_forced + $snags_tripped == $snags_summarised;
 142 }
 143 sub run_deferred_updates ($) {
 144     my ($mrest) = @_;
 145
 146     confess 'dangerous internal error' unless all_snags_summarised();
 147
 148     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 149     debugcmd '>|', @upd_cmd;
 150     open U, "|-", @upd_cmd or die $!;
 151     foreach (@deferred_updates) {
 152         printdebug ">= ", $_, "\n";
 153         print U $_, "\n" or die $!;
 154     }
 155     printdebug ">\$\n";
 156     close U or failedcmd @upd_cmd;
 157
 158     print $_, "\n" foreach @deferred_update_messages;
 159
 160     @deferred_updates = ();
 161     @deferred_update_messages = ();
 162 }
 163
 164 sub get_differs ($$) {
 165     my ($x,$y) = @_;
 166     # This resembles quiltify_trees_differ, in dgit, a bit.
 167     # But we don't care about modes, or dpkg-source-unrepresentable
 168     # changes, and we don't need the plethora of different modes.
 169     # Conversely we need to distinguish different kinds of changes to
 170     # debian/ and debian/patches/.
 171
 172     my $differs = 0;
 173
 174     my $rundiff = sub {
 175         my ($opts, $limits, $fn) = @_;
 176         my @cmd = (@git, qw(diff-tree -z --no-renames));
 177         push @cmd, @$opts;
 178         push @cmd, "$_:" foreach $x, $y;
 179         push @cmd, '--', @$limits;
 180         my $diffs = cmdoutput @cmd;
 181         foreach (split /\0/, $diffs) { $fn->(); }
 182     };
 183
 184     $rundiff->([qw(--name-only)], [], sub {
 185         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 186     });
 187
 188     if ($differs & DS_DEB) {
 189         $differs &= ~DS_DEB;
 190         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 191             $differs |=
 192                 m{^debian/patches/}      ? D_PAT_OTH  :
 193                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 194                                            D_DEB_OTH;
 195         });
 196         die "mysterious debian changes $x..$y"
 197             unless $differs & (D_PAT_OTH|DS_DEB);
 198     }
 199
 200     if ($differs & D_PAT_OTH) {
 201         my $mode;
 202         $differs &= ~D_PAT_OTH;
 203         my $pat_oth = sub {
 204             $differs |= D_PAT_OTH;
 205             no warnings qw(exiting);  last;
 206         };
 207         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 208             no warnings qw(exiting);
 209             if (!defined $mode) {
 210                 $mode = $_;  next;
 211             }
 212             die unless s{^debian/patches/}{};
 213             my $ok;
 214             if ($mode eq 'A' && !m/\.series$/s) {
 215                 $ok = 1;
 216             } elsif ($mode eq 'M' && $_ eq 'series') {
 217                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 218                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 219                 chomp $x_s;  $x_s .= "\n";
 220                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 221             } else {
 222                 # nope
 223             }
 224             $mode = undef;
 225             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 226         });
 227         die "mysterious debian/patches changes $x..$y"
 228             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 229     }
 230
 231     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 232
 233     return $differs;
 234 }
 235
 236 sub commit_pr_info ($) {
 237     my ($r) = @_;
 238     return Data::Dumper->dump([$r], [qw(commit)]);
 239 }
 240
 241 sub calculate_committer_authline () {
 242     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 243         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 244     my ($h,$m) = get_commit $c;
 245     $h =~ m/^committer .*$/m or confess "($h) ?";
 246     return $&;
 247 }
 248
 249 sub rm_subdir_cached ($) {
 250     my ($subdir) = @_;
 251     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 252 }
 253
 254 sub read_tree_subdir ($$) {
 255     my ($subdir, $new_tree_object) = @_;
 256     rm_subdir_cached $subdir;
 257     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 258 }
 259
 260 sub read_tree_debian ($) {
 261     my ($treeish) = @_;
 262     read_tree_subdir 'debian', "$treeish:debian";
 263     rm_subdir_cached 'debian/patches';
 264 }
 265
 266 sub read_tree_upstream ($;$$) {
 267     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 268     # if $tree_with_debian is supplied, will use that for debian/
 269     # otherwise will save and restore it.
 270     my $debian =
 271         $tree_with_debian ? "$tree_with_debian:debian"
 272         : cmdoutput @git, qw(write-tree --prefix=debian/);
 273     runcmd @git, qw(read-tree), $treeish;
 274     read_tree_subdir 'debian', $debian;
 275     rm_subdir_cached 'debian/patches' unless $keep_patches;
 276 };
 277
 278 sub make_commit ($$) {
 279     my ($parents, $message_paras) = @_;
 280     my $tree = cmdoutput @git, qw(write-tree);
 281     my @cmd = (@git, qw(commit-tree), $tree);
 282     push @cmd, qw(-p), $_ foreach @$parents;
 283     push @cmd, qw(-m), $_ foreach @$message_paras;
 284     return cmdoutput @cmd;
 285 }
 286
 287 our @snag_force_opts;
 288 sub snag ($$;@) {
 289     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 290     if (grep { $_ eq $tag } @snag_force_opts) {
 291         $snags_forced++;
 292         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 293     } else {
 294         $snags_tripped++;
 295         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 296     }
 297 }
 298
 299 # Important: all mainline code must call snags_maybe_bail after
 300 # any point where snag might be called, but before making changes
 301 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 302 # may be called more than once if necessary (but this is not ideal
 303 # because then the messages about number of snags may be confusing).
 304 sub snags_maybe_bail () {
 305     return if all_snags_summarised();
 306     if ($snags_forced) {
 307         printf STDERR
 308             "%s: snags: %d overriden by individual -f options\n",
 309             $us, $snags_forced;
 310     }
 311     if ($snags_tripped) {
 312         if ($opt_force) {
 313             printf STDERR
 314                 "%s: snags: %d overriden by global --force\n",
 315                 $us, $snags_tripped;
 316         } else {
 317             fail sprintf
 318   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 319                 $us, $snags_tripped;
 320         }
 321     }
 322     $snags_summarised = $snags_forced + $snags_tripped;
 323 }
 324 sub snags_maybe_bail_early () {
 325     # useful to bail out early without doing a lot of work;
 326     # not a substitute for snags_maybe_bail.
 327     snags_maybe_bail() if $snags_tripped && !$opt_force;
 328 }
 329 sub any_snags () {
 330     return $snags_forced || $snags_tripped;
 331 }
 332
 333 sub gbp_pq_export ($$$) {
 334     my ($bname, $base, $tip) = @_;
 335     # must be run in a workarea.  $bname and patch-queue/$bname
 336     # ought not to exist.  Leaves you on patch-queue/$bname with
 337     # the patches staged but not committed.
 338     printdebug "gbp_pq_export $bname $base $tip\n";
 339     runcmd @git, qw(checkout -q -b), $bname, $base;
 340     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 341     my @gbp_cmd = (qw(gbp pq export));
 342     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 343     if ($r) {
 344         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 345         failedcmd @gbp_cmd;
 346     }
 347     runcmd @git, qw(add -f debian/patches);
 348 }
 349
 350
 351 # xxx allow merge resolution separately from laundering, before git merge
 352 #
 353 # xxx general gdr docs highlight forbidden things
 354 # xxx general gdr docs list allowable things ?
 355 # xxx general gdr docs explicitly forbid some rebase
 356 #
 357 # xxx provide a way for the user to help
 358 # xxx (eg, provide wreckage provide way to continue)
 359
 360 # later/rework?
 361 #  use git-format-patch?
 362 #  our own patch identification algorithm?
 363 #  this is an alternative strategy
 364
 365 sub merge_series ($$;@) {
 366     my ($newbase, $base_q, @input_qs) = @_;
 367     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 368     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 369     # ^ specifies several patch series (currently we only support exactly 2)
 370     # return value is a commit which is the result of
 371     # merging the two versions of the same topic branch
 372     #   $input_q[0] and $input_q[1]
 373     # with respect to the old version
 374     #   $base_q
 375     # all onto $newbase.
 376
 377     # Creates, in *_q, a key MR for its private use
 378
 379     printdebug "merge_series newbase=$newbase\n";
 380
 381     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 382     $base_q->{MR}{S} = 'base';
 383
 384     my %prereq;
 385     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 386     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 387     # $prereq{<patch filename>}               exists or not (even later)
 388
 389     my $result;
 390
 391     local $workarea = fresh_playground "$playprefix/merge";
 392     my $seriesfile = "debian/patches/series";
 393     in_workarea sub {
 394         playtree_setup();
 395         foreach my $q ($base_q, reverse @input_qs) {
 396             my $s = $q->{MR}{S};
 397             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 398             my @earlier;
 399             if (open S, $seriesfile) {
 400                 while (my $patch = <S>) {
 401                     chomp $patch or die $!;
 402                     $prereq{$patch} //= {};
 403                     foreach my $earlier (@earlier) {
 404                         $prereq{$patch}{$earlier}{$s}++ and die;
 405                     }
 406                     push @earlier, $patch;
 407                     stat "debian/patches/$patch" or die "$patch ?";
 408                 }
 409                 S->error and die "$seriesfile $!";
 410                 close S;
 411             } else {
 412                 die "$seriesfile $!" unless $!==ENOENT;
 413             }
 414             read_tree_upstream $newbase, 1;
 415             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 416                 "Convert $s to patch queue for merging",
 417                 "[git-debrebase merge-innards patch-queue import:".
 418                 " $q->{SeriesTip}]"
 419             ];
 420             printdebug "merge_series  pec $pec ";
 421             runcmd @git, qw(rm -q --cached), $seriesfile;
 422             $pec = make_commit [ $pec ], [
 423                 "Drop series file from $s to avoid merge trouble",
 424                 "[git-debrebase merge-innards patch-queue prep:".
 425                 " $q->{SeriesTip}]"
 426             ];
 427
 428             read_tree_debian $newbase;
 429             if (@earlier) {
 430                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 431             } else {
 432                 rm_subdir_cached 'debian/patches';
 433             }
 434             $pec = make_commit [ $pec ], [
 435  "Update debian/ (excluding patches) to final to avoid re-merging",
 436  "debian/ was already merged and we need to just take that.",
 437                 "[git-debrebase merge-innards patch-queue packaging:".
 438                 " $q->{SeriesTip}]"
 439             ];
 440
 441             printdebug "pec' $pec\n";
 442             runcmd @git, qw(reset -q --hard), $pec;
 443             $q->{MR}{PEC} = $pec;
 444         }
 445         # now, because of reverse, we are on $input_q->{MR}{OQC}
 446         runcmd @git, qw(checkout -q -b merge);
 447         printdebug "merge_series merging...\n";
 448         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 449         debugcmd '+', @mergecmd;
 450         $!=0; $?=-1;
 451         if (system @mergecmd) {
 452             failedcmd @mergecmd;
 453         }
 454
 455         printdebug "merge_series merge ok, series...\n";
 456         # We need to construct a new series file
 457         # Firstly, resolve prereq
 458         foreach my $f (sort keys %prereq) {
 459             printdebug "merge_series  patch\t$f\t";
 460             if (!stat_exists "debian/patches/$f") {
 461                 print DEBUG " drop\n" if $debuglevel;
 462                 # git merge deleted it; that's how we tell it's not wanted
 463                 delete $prereq{$f};
 464                 next;
 465             }
 466             print DEBUG " keep\n" if $debuglevel;
 467             foreach my $g (sort keys %{ $prereq{$f} }) {
 468                 my $gfp = $prereq{$f}{$g};
 469                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 470                 if (!!$gfp->{0} == !!$gfp->{1}
 471                     ? $gfp->{0}
 472                     : !$gfp->{base}) {
 473                     print DEBUG "\tkeep\n" if $debuglevel;
 474                 } else {
 475                     print DEBUG "\tdrop\n" if $debuglevel;
 476                     delete $prereq{$f}{$g};
 477                 }
 478             }
 479         }
 480
 481         my $unsat = sub {
 482             my ($f) = @_;
 483             return scalar keys %{ $prereq{$f} };
 484         };
 485
 486         my $nodate = time + 1;
 487         my %authordate;
 488         # $authordate{<patch filename>};
 489         my $authordate = sub {
 490             my ($f) = @_;
 491             $authordate{$f} //= do {
 492                 open PF, "<", "debian/patches/$f" or die "$f $!";
 493                 while (<PF>) {
 494                     return $nodate if m/^$/;
 495                     last if s{^Date: }{};
 496                 }
 497                 chomp;
 498                 return cmdoutput qw(date +%s -d), $_;
 499             };
 500         };
 501
 502         open NS, '>', $seriesfile or die $!;
 503
 504         while (keys %prereq) {
 505             my $best;
 506             foreach my $try (sort keys %prereq) {
 507                 if ($best) {
 508                     next if (
 509                              $unsat->($try) <=> $unsat->($best) or
 510                              $authordate->($try) <=> $authordate->($best) or
 511                              $try cmp $best
 512                             ) >= 0;
 513                 }
 514                 $best = $try;
 515             }
 516             printdebug "merge_series series next $best\n";
 517             print NS "$best\n" or die $!;
 518             delete $prereq{$best};
 519             foreach my $gp (values %prereq) {
 520                 delete $gp->{$best};
 521             }
 522         }
 523
 524         runcmd @git, qw(add), $seriesfile;
 525         runcmd @git, qw(commit --quiet -m), 'Merged series';
 526
 527         printdebug "merge_series series gbp pq import\n";
 528         runcmd qw(gbp pq import);
 529
 530         # OK now we are on patch-queue/merge, and we need to rebase
 531         # onto the intended parent and drop the patches from each one
 532
 533         printdebug "merge_series series ok, building...\n";
 534         my $build = $newbase;
 535         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 536         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 537             my $commit = git_cat_file $c, 'commit';
 538             printdebug "merge_series series ok, building $c\n";
 539             read_tree_upstream $c, 0, $newbase;
 540             my $tree = cmdoutput @git, qw(write-tree);
 541             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 542             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 543             open C, ">", "../mcommit" or die $!;
 544             print C $commit or die $!;
 545             close C or die $!;
 546             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 547         }
 548         $result = $build;
 549         runcmd @git, qw(update-ref refs/heads/result), $result;
 550
 551         runcmd @git, qw(checkout -q -b debug);
 552         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 553         runcmd @git, qw(add .);
 554         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 555         printdebug sprintf "merge_series done debug=%s\n",
 556             git_rev_parse 'HEAD';
 557     };
 558     printdebug "merge_series returns $result\n";
 559     return $result;
 560 }
 561
 562 # classify returns an info hash like this
 563 #   CommitId => $objid
 564 #   Hdr => # commit headers, including 1 final newline
 565 #   Msg => # commit message (so one newline is dropped)
 566 #   Tree => $treeobjid
 567 #   Type => (see below)
 568 #   Parents = [ {
 569 #       Ix => $index # ie 0, 1, 2, ...
 570 #       CommitId
 571 #       Differs => return value from get_differs
 572 #       IsOrigin
 573 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 574 #     } ...]
 575 #   NewMsg => # commit message, but with any [dgit import ...] edited
 576 #             # to say "[was: ...]"
 577 #
 578 # Types:
 579 #   Packaging
 580 #   Changelog
 581 #   Upstream
 582 #   AddPatches
 583 #   Mixed
 584 #
 585 #   Pseudomerge
 586 #     has additional entres in classification result
 587 #       Overwritten = [ subset of Parents ]
 588 #       Contributor = $the_remaining_Parent
 589 #
 590 #   DgitImportUnpatched
 591 #     has additional entry in classification result
 592 #       OrigParents = [ subset of Parents ]
 593 #
 594 #   Anchor
 595 #     has additional entry in classification result
 596 #       OrigParents = [ subset of Parents ]  # singleton list
 597 #
 598 #   TreatAsAnchor
 599 #
 600 #   BreakwaterStart
 601 #
 602 #   Unknown
 603 #     has additional entry in classification result
 604 #       Why => "prose"
 605
 606 sub parsecommit ($;$) {
 607     my ($objid, $p_ref) = @_;
 608     # => hash with                   CommitId Hdr Msg Tree Parents
 609     #    Parents entries have only   Ix CommitId
 610     #    $p_ref, if provided, must be [] and is used as a base for Parents
 611
 612     $p_ref //= [];
 613     die if @$p_ref;
 614
 615     my ($h,$m) = get_commit $objid;
 616
 617     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 618     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 619
 620     my $r = {
 621         CommitId => $objid,
 622         Hdr => $h,
 623         Msg => $m,
 624         Tree => $t,
 625         Parents => $p_ref,
 626     };
 627
 628     foreach my $ph (@ph) {
 629         push @$p_ref, {
 630             Ix => scalar @$p_ref,
 631             CommitId => $ph,
 632         };
 633     }
 634
 635     return $r;
 636 }
 637
 638 sub classify ($) {
 639     my ($objid) = @_;
 640
 641     my @p;
 642     my $r = parsecommit($objid, \@p);
 643     my $t = $r->{Tree};
 644
 645     foreach my $p (@p) {
 646         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 647     }
 648
 649     printdebug "classify $objid \$t=$t \@p",
 650         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 651         "\n";
 652
 653     my $classify = sub {
 654         my ($type, @rest) = @_;
 655         $r = { %$r, Type => $type, @rest };
 656         if ($debuglevel) {
 657             printdebug " = $type ".(dd $r)."\n";
 658         }
 659         return $r;
 660     };
 661     my $unknown = sub {
 662         my ($why) = @_;
 663         $r = { %$r, Type => qw(Unknown), Why => $why };
 664         printdebug " ** Unknown\n";
 665         return $r;
 666     };
 667
 668     if (grep { $_ eq $objid } @opt_anchors) {
 669         return $classify->('TreatAsAnchor');
 670     }
 671
 672     my @identical = grep { !$_->{Differs} } @p;
 673     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 674     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 675
 676     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 677         # multi-orig upstreams are represented with an anchor merge
 678         # from a single upstream commit which combines the orig tarballs
 679
 680         # Every anchor tagged this way must be a merge.
 681         # We are relying on the
 682         #     [git-debrebase anchor: ...]
 683         # commit message annotation in "declare" anchor merges (which
 684         # do not have any upstream changes), to distinguish those
 685         # anchor merges from ordinary pseudomerges (which we might
 686         # just try to strip).
 687         #
 688         # However, the user is going to be doing git-rebase a lot.  We
 689         # really don't want them to rewrite an anchor commit.
 690         # git-rebase trips up on merges, so that is a useful safety
 691         # catch.
 692         #
 693         # BreakwaterStart commits are also anchors in the terminology
 694         # of git-debrebase(5), but they are untagged (and always
 695         # manually generated).
 696         #
 697         # We cannot not tolerate any tagged linear commit (ie,
 698         # BreakwaterStart commits tagged `[anchor:') because such a
 699         # thing could result from an erroneous linearising raw git
 700         # rebase of a merge anchor.  That would represent a corruption
 701         # of the branch. and we want to detect and reject the results
 702         # of such corruption before it makes it out anywhere.  If we
 703         # reject it here then we avoid making the pseudomerge which
 704         # would be needed to push it.
 705
 706         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 707         @p == 2 or return $badanchor->("has other than two parents");
 708         $haspatches and return $badanchor->("contains debian/patches");
 709
 710         # How to decide about l/r ordering of anchors ?  git
 711         # --topo-order prefers to expand 2nd parent first.  There's
 712         # already an easy rune to look for debian/ history anyway (git log
 713         # debian/) so debian breakwater branch should be 1st parent; that
 714         # way also there's also an easy rune to look for the upstream
 715         # patches (--topo-order).
 716
 717         # Also this makes --first-parent be slightly more likely to
 718         # be useful - it makes it provide a linearised breakwater history.
 719
 720         # Of course one can say somthing like
 721         #  gitk -- ':/' ':!/debian'
 722         # to get _just_ the commits touching upstream files, and by
 723         # the TREESAME logic in git-rev-list this will leave the
 724         # breakwater into upstream at the first anchor.  But that
 725         # doesn't report debian/ changes at all.
 726
 727         # Other observations about gitk: by default, gitk seems to
 728         # produce output in a different order to git-rev-list.  I
 729         # can't seem to find this documented anywhere.  gitk
 730         # --date-order DTRT.  But, gitk always seems to put the
 731         # parents from left to right, in order, so it's easy to see
 732         # which way round a pseudomerge is.
 733
 734         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 735         $p[1]{Differs} & ~DS_DEB and
 736             $badanchor->("upstream files differ from left parent");
 737         $p[0]{Differs} & ~D_UPS and
 738             $badanchor->("debian/ differs from right parent");
 739
 740         return $classify->(qw(Anchor),
 741                            OrigParents => [ $p[1] ]);
 742     }
 743
 744     if (@p == 1) {
 745         my $d = $r->{Parents}[0]{Differs};
 746         if ($d == D_PAT_ADD) {
 747             return $classify->(qw(AddPatches));
 748         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 749             return $unknown->("edits debian/patches");
 750         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 751             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 752             if ($ty eq 'tree') {
 753                 if ($d == D_DEB_CLOG) {
 754                     return $classify->(qw(Changelog));
 755                 } else {
 756                     return $classify->(qw(Packaging));
 757                 }
 758             } elsif ($ty eq 'missing') {
 759                 return $classify->(qw(BreakwaterStart));
 760             } else {
 761                 return $unknown->("parent's debian is not a directory");
 762             }
 763         } elsif ($d == D_UPS) {
 764             return $classify->(qw(Upstream));
 765         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 766             return $classify->(qw(Mixed));
 767         } elsif ($d == 0) {
 768             return $unknown->("no changes");
 769         } else {
 770             confess "internal error $objid ?";
 771         }
 772     }
 773     if (!@p) {
 774         return $unknown->("origin commit");
 775     }
 776
 777     if (@p == 2 && @identical == 1) {
 778         my @overwritten = grep { $_->{Differs} } @p;
 779         confess "internal error $objid ?" unless @overwritten==1;
 780         return $classify->(qw(Pseudomerge),
 781                            Overwritten => [ $overwritten[0] ],
 782                            Contributor => $identical[0]);
 783     }
 784     if (@p == 2 && @identical == 2) {
 785         my $get_t = sub {
 786             my ($ph,$pm) = get_commit $_[0]{CommitId};
 787             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 788             $1;
 789         };
 790         my @bytime = @p;
 791         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 792         if ($order > 0) { # newer first
 793         } elsif ($order < 0) {
 794             @bytime = reverse @bytime;
 795         } else {
 796             # same age, default to order made by -s ours
 797             # that is, commit was made by someone who preferred L
 798         }
 799         return $classify->(qw(Pseudomerge),
 800                            SubType => qw(Ambiguous),
 801                            Contributor => $bytime[0],
 802                            Overwritten => [ $bytime[1] ]);
 803     }
 804     foreach my $p (@p) {
 805         my ($p_h, $p_m) = get_commit $p->{CommitId};
 806         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 807         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 808     }
 809     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 810     my $m2 = $r->{Msg};
 811     if (!(grep { !$_->{IsOrigin} } @p) and
 812         (@orig_ps >= @p - 1) and
 813         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 814         $r->{NewMsg} = $m2;
 815         return $classify->(qw(DgitImportUnpatched),
 816                            OrigParents => \@orig_ps);
 817     }
 818
 819     if (@p == 2 and
 820         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 821         # xxx ^ metadata tag needs adding to (5)
 822         return $classify->("MergedBreakwaters");
 823     }
 824     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 825         return $unknown->("unknown kind of merge from $1");
 826     }
 827     if (@p > 2) {
 828         return $unknown->("octopus merge");
 829     }
 830
 831     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 832         return $unknown->("general two-parent merge");
 833     }
 834
 835     return $classify->("VanillaMerge");
 836 }
 837
 838 sub keycommits ($;$$$$$);
 839
 840 sub mergedbreakwaters_anchor ($) {
 841     my ($cl) = @_;
 842     my $best_anchor;
 843     foreach my $p (@{ $cl->{Parents} }) {
 844         my ($panchor, $pbw) = keycommits $p->{CommitId},
 845             undef,undef,undef,undef, 1;
 846         $best_anchor = $panchor
 847             if !defined $best_anchor
 848             or is_fast_fwd $best_anchor, $panchor;
 849     }
 850     return $best_anchor;
 851 }
 852
 853 sub keycommits ($;$$$$$) {
 854     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 855     # => ($anchor, $breakwater)
 856
 857     # $unclean->("unclean-$tagsfx", $msg, $cl)
 858     # $furniture->("unclean-$tagsfx", $msg, $cl)
 859     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 860     #   is callled for each situation or commit that
 861     #   wouldn't be found in a laundered branch
 862     # $furniture is for furniture commits such as might be found on an
 863     #   interchange branch (pseudomerge, d/patches, changelog)
 864     # $trouble is for things whnich prevent the return of
 865     #   anchor and breakwater information; if that is ignored,
 866     #   then keycommits returns (undef, undef) instead.
 867     # $fatal is for unprocessable commits, and should normally cause
 868     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 869     #
 870     # If $claimed_bw, this is supposed to be a breakwater commit.
 871     #
 872     # If a callback is undef, fail is called instead.
 873     # If a callback is defined but false, the situation is ignored.
 874     # Callbacks may say:
 875     #   no warnings qw(exiting); last;
 876     # if the answer is no longer wanted.
 877
 878     my ($anchor, $breakwater);
 879     $breakwater = $head if $claimed_bw;
 880     my $clogonly;
 881     my $cl;
 882     my $found_pm;
 883     $fatal //= sub { fail $_[1]; };
 884     my $x = sub {
 885         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 886         my $why = $mainwhy.$xwhy;
 887         my $m = "branch needs laundering (run git-debrebase): $why";
 888         fail $m unless defined $cb;
 889         return unless $cb;
 890         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 891     };
 892     my $found_anchor = sub {
 893         ($anchor) = @_;
 894         $breakwater //= $clogonly;
 895         $breakwater //= $head;
 896         no warnings qw(exiting);
 897         last;
 898     };
 899     for (;;) {
 900         $cl = classify $head;
 901         my $ty = $cl->{Type};
 902         if ($ty eq 'Packaging') {
 903             $breakwater //= $clogonly;
 904             $breakwater //= $head;
 905         } elsif ($ty eq 'Changelog') {
 906             # this is going to count as the tip of the breakwater
 907             # only if it has no upstream stuff before it
 908             $clogonly //= $head;
 909         } elsif ($ty eq 'Anchor' or
 910                  $ty eq 'TreatAsAnchor' or
 911                  $ty eq 'BreakwaterStart') {
 912             $found_anchor->($head);
 913         } elsif ($ty eq 'Upstream') {
 914             $x->($unclean, 'ordering',
 915  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 916                 if defined $breakwater;
 917             $clogonly = undef;
 918             $breakwater = undef;
 919         } elsif ($ty eq 'Mixed') {
 920             $x->($unclean, 'mixed',
 921                  "found mixed upstream/packaging commit"," ($head)");
 922             $clogonly = undef;
 923             $breakwater = undef;
 924         } elsif ($ty eq 'Pseudomerge' or
 925                  $ty eq 'AddPatches') {
 926             my $found_pm = 1;
 927             $x->($furniture, (lc $ty),
 928                  "found interchange bureaucracy commit ($ty)"," ($head)");
 929         } elsif ($ty eq 'DgitImportUnpatched') {
 930             if ($found_pm) {
 931                 $x->($trouble, 'dgitimport',
 932                      "found dgit dsc import"," ($head)");
 933                 return (undef,undef);
 934             } else {
 935                 $x->($fatal, 'unprocessable',
 936                      "found bare dgit dsc import with no prior history",
 937                      " ($head)");
 938                 return (undef,undef);
 939             }
 940         } elsif ($ty eq 'VanillaMerge') {
 941             $x->($trouble, 'vanillamerge',
 942                  "found vanilla merge"," ($head)");
 943             return (undef,undef);
 944         } elsif ($ty eq 'MergedBreakwaters') {
 945             $found_anchor->(mergedbreakwaters_anchor $cl);
 946         } else {
 947             $x->($fatal, 'unprocessable',
 948                  "found unprocessable commit, cannot cope: $cl->{Why}",
 949                  " ($head)");
 950             return (undef,undef);
 951         }
 952         $head = $cl->{Parents}[0]{CommitId};
 953     }
 954     return ($anchor, $breakwater);
 955 }
 956
 957 sub walk ($;$$$);
 958 sub walk ($;$$$) {
 959     my ($input,
 960         $nogenerate,$report, $report_lprefix) = @_;
 961     # => ($tip, $breakwater_tip, $last_anchor)
 962     # (or nothing, if $nogenerate)
 963
 964     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
 965     $report_lprefix //= '';
 966
 967     # go through commits backwards
 968     # we generate two lists of commits to apply:
 969     # breakwater branch and upstream patches
 970     my (@brw_cl, @upp_cl, @processed);
 971     my %found;
 972     my $upp_limit;
 973     my @pseudomerges;
 974
 975     my $cl;
 976     my $xmsg = sub {
 977         my ($prose, $info) = @_;
 978         my $ms = $cl->{Msg};
 979         chomp $ms;
 980         $info //= '';
 981         $ms .= "\n\n[git-debrebase$info: $prose]\n";
 982         return (Msg => $ms);
 983     };
 984     my $rewrite_from_here = sub {
 985         my ($cl) = @_;
 986         my $sp_cl = { SpecialMethod => 'StartRewrite' };
 987         push @$cl, $sp_cl;
 988         push @processed, $sp_cl;
 989     };
 990     my $cur = $input;
 991
 992     my $prdelim = "";
 993     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
 994
 995     my $prline = sub {
 996         return unless $report;
 997         print $report $prdelim, $report_lprefix, @_;
 998         $prdelim = "\n";
 999     };
1000
1001     my $bomb = sub { # usage: return $bomb->();
1002         print $report " Unprocessable" if $report;
1003         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1004         $prprdelim->();
1005         if ($nogenerate) {
1006             return (undef,undef);
1007         }
1008         fail "found unprocessable commit, cannot cope".
1009             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1010             " (commit $cur) (d.".
1011             (join ' ', map { sprintf "%#x", $_->{Differs} }
1012              @{ $cl->{Parents} }).
1013                  ")";
1014     };
1015
1016     my $build;
1017     my $breakwater;
1018
1019     my $build_start = sub {
1020         my ($msg, $parent) = @_;
1021         $prline->(" $msg");
1022         $build = $parent;
1023         no warnings qw(exiting); last;
1024     };
1025
1026     my $nomerge = sub {
1027         fail "something useful about failed merge attempt @_ xxx".Dumper($cl);
1028     };
1029
1030     my $last_anchor;
1031
1032     for (;;) {
1033         $cl = classify $cur;
1034         my $ty = $cl->{Type};
1035         my $st = $cl->{SubType};
1036         $prline->("$cl->{CommitId} $cl->{Type}");
1037         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1038         push @processed, $cl;
1039         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1040         if ($ty eq 'AddPatches') {
1041             $cur = $p0;
1042             $rewrite_from_here->(\@upp_cl);
1043             next;
1044         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1045             push @brw_cl, $cl;
1046             $cur = $p0;
1047             next;
1048         } elsif ($ty eq 'BreakwaterStart') {
1049             $last_anchor = $cur;
1050             $build_start->('FirstPackaging', $cur);
1051         } elsif ($ty eq 'Upstream') {
1052             push @upp_cl, $cl;
1053             $cur = $p0;
1054             next;
1055         } elsif ($ty eq 'Mixed') {
1056             my $queue = sub {
1057                 my ($q, $wh) = @_;
1058                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1059                 push @$q, $cls;
1060             };
1061             $queue->(\@brw_cl, "debian");
1062             $queue->(\@upp_cl, "upstream");
1063             $rewrite_from_here->(\@brw_cl);
1064             $cur = $p0;
1065             next;
1066         } elsif ($ty eq 'Pseudomerge') {
1067             my $contrib = $cl->{Contributor}{CommitId};
1068             print $report " Contributor=$contrib" if $report;
1069             push @pseudomerges, $cl;
1070             $rewrite_from_here->(\@upp_cl);
1071             $cur = $contrib;
1072             next;
1073         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1074             $last_anchor = $cur;
1075             $build_start->("Anchor", $cur);
1076         } elsif ($ty eq 'DgitImportUnpatched') {
1077             my $pm = $pseudomerges[-1];
1078             if (defined $pm) {
1079                 # To an extent, this is heuristic.  Imports don't have
1080                 # a useful history of the debian/ branch.  We assume
1081                 # that the first pseudomerge after an import has a
1082                 # useful history of debian/, and ignore the histories
1083                 # from later pseudomerges.  Often the first pseudomerge
1084                 # will be the dgit import of the upload to the actual
1085                 # suite intended by the non-dgit NMUer, and later
1086                 # pseudomerges may represent in-archive copies.
1087                 my $ovwrs = $pm->{Overwritten};
1088                 printf $report " PM=%s \@Overwr:%d",
1089                     $pm->{CommitId}, (scalar @$ovwrs)
1090                     if $report;
1091                 if (@$ovwrs != 1) {
1092                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1093                     return $bomb->();
1094                 }
1095                 my $ovwr = $ovwrs->[0]{CommitId};
1096                 printf $report " Overwr=%s", $ovwr if $report;
1097                 # This import has a tree which is just like a
1098                 # breakwater tree, but it has the wrong history.  It
1099                 # ought to have the previous breakwater (which the
1100                 # pseudomerge overwrote) as an ancestor.  That will
1101                 # make the history of the debian/ files correct.  As
1102                 # for the upstream version: either it's the same as
1103                 # was ovewritten (ie, same as the previous
1104                 # breakwater), in which case that history is precisely
1105                 # right; or, otherwise, it was a non-gitish upload of a
1106                 # new upstream version.  We can tell these apart by
1107                 # looking at the tree of the supposed upstream.
1108                 push @brw_cl, {
1109                     %$cl,
1110                     SpecialMethod => 'DgitImportDebianUpdate',
1111                     $xmsg->("convert dgit import: debian changes")
1112                 }, {
1113                     %$cl,
1114                     SpecialMethod => 'DgitImportUpstreamUpdate',
1115                     $xmsg->("convert dgit import: upstream update",
1116                             " anchor")
1117                 };
1118                 $prline->(" Import");
1119                 $rewrite_from_here->(\@brw_cl);
1120                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1121                 $cur = $ovwr;
1122                 next;
1123             } else {
1124                 # Everything is from this import.  This kind of import
1125                 # is already nearly in valid breakwater format, with the
1126                 # patches as commits.  Unfortunately it contains
1127                 # debian/patches/.
1128                 printdebug "*** WALK BOMB bare dgit import\n";
1129                 $cl->{Why} = "bare dgit dsc import";
1130                 return $bomb->();
1131             }
1132             die "$ty ?";
1133         } elsif ($ty eq 'MergedBreakwaters') {
1134             $last_anchor = mergedbreakwaters_anchor $cl;
1135             $build_start->(' MergedBreakwaters', $cur);
1136             last;
1137         } elsif ($ty eq 'VanillaMerge') {
1138             # User may have merged unstitched branch(es).  We will
1139             # have now lost what ffq-prev was then (since the later
1140             # pseudomerge may introduce further changes).  The effect
1141             # of resolving such a merge is that we may have to go back
1142             # further in history to find a merge base, since the one
1143             # which was reachable via ffq-prev is no longer findable.
1144             # This is suboptimal, but if it all works we'll have done
1145             # the right thing.
1146             # xxx we should warn the user in the docs about this
1147
1148             my $ok=1;
1149             my $best_anchor;
1150             # We expect to find a dominating anchor amongst the
1151             # inputs' anchors.  That will be the new anchor.
1152             #
1153             # More complicated is finding a merge base for the
1154             # breakwaters.  We need a merge base that is a breakwater
1155             # commit.  The ancestors of breakwater commits are more
1156             # breakwater commits and possibly upstream commits and the
1157             # ancestors of those upstream.  Upstreams might have
1158             # arbitrary ancestors.  But any upstream commit U is
1159             # either included in both anchors, in which case the
1160             # earlier anchor is a better merge base than any of U's
1161             # ancestors; or U is not included in the older anchor, in
1162             # which case U is not an ancestor of the vanilla merge at
1163             # all.  So no upstream commit, nor any ancestor thereof,
1164             # is a best merge base.  As for non-breakwater Debian
1165             # commits: these are never ancestors of any breakwater.
1166             #
1167             # So any best merge base as found by git-merge-base
1168             # is a suitable breakwater anchor.  Usually there will
1169             # be only one.
1170
1171             printdebug "*** MERGE\n";
1172
1173             my @bwbcmd = (@git, qw(merge-base));
1174             my @ibcmd = (@git, qw(merge-base --all));
1175             my $might_be_in_bw = 1;
1176
1177             my $ps = $cl->{Parents};
1178
1179             foreach my $p (@$ps) {
1180                 $prline->(" VanillaMerge ".$p->{Ix});
1181                 $prprdelim->();
1182                 my ($ptip, $pbw, $panchor) =
1183                     walk $p->{CommitId}, 0, $report,
1184                          $report_lprefix.'  ';
1185                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1186                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1187                 $p->{Anchor} = $panchor;
1188
1189                 $best_anchor = $panchor if
1190                     !defined $best_anchor or
1191                     is_fast_fwd $best_anchor, $panchor;
1192
1193                 printdebug " MERGE BA best=".($best_anchor//'-').
1194                     " p=$panchor\n";
1195             }
1196
1197             foreach my $p (@$ps) {
1198                 $prline->(" VanillaMerge ".$p->{Ix});
1199                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1200                     $nomerge->('DivergentAnchor');
1201                 } elsif ($p->{Anchor} eq $best_anchor) {
1202                     print $report " SameAnchor" if $report;
1203                 } else {
1204                     print $report " SupersededAnchor" if $report;
1205                 }
1206                 if ($p->{Breakwater} eq $p->{CommitId}) {
1207                     # this parent commit was its own breakwater,
1208                     # ie it is part of the breakwater
1209                     print $report " Breakwater" if $report;
1210                 } else {
1211                     $might_be_in_bw = 0;
1212                 }
1213                 push @bwbcmd, $p->{Breakwater};
1214                 push @ibcmd, $p->{CommitId};
1215             }
1216
1217             if ($ok && $might_be_in_bw) {
1218                 $prline->(" VanillaMerge MergedBreakwaters");
1219                 $last_anchor = $best_anchor;
1220                 $build_start->('MergedBreakwaters', $cur);
1221             }
1222
1223             $nomerge->("alleged merged-breakwater is not a breakwater")
1224                 unless $ty eq 'VanillaMerge';
1225
1226             my $bwb = cmdoutput @bwbcmd;
1227
1228             # OK, now we have a breakwater base, but we need the merge
1229             # base for the interchange branch because we need the delta
1230             # queue.
1231             #
1232             # This a the best merge base of our inputs which has the
1233             # breakwater merge base as an ancestor.
1234
1235             my @ibs =
1236                 grep { is_fast_fwd $bwb, $_ }
1237                 grep /./,
1238                 split /\n/,
1239                 cmdoutput @ibcmd;
1240             my ($ib) = @ibs
1241                 or $nomerge->("no suitable interchange merge base");
1242
1243             $prline->("  VanillaMerge Base");
1244             $prprdelim->();
1245             my ($btip, $bbw, $banchor) =
1246                 walk $ib, 0, $report, $report_lprefix.'  ';
1247
1248             my $ibinfo = { SeriesTip => $btip,
1249                            SeriesBase => $bbw,
1250                            Anchor => $banchor };
1251             $bbw eq $bwb
1252                 or $nomerge->("interchange merge-base ($ib)'s".
1253                               " breakwater ($bbw)".
1254                               " != breakwaters' merge-base ($bwb)");
1255             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1256                  or $nomerge->("interchange merge-base ($ib)'s".
1257                                " anchor ($ibinfo->{SeriesBase})".
1258                                " != any merge input's anchor (".
1259                                (join ' ', map { $_->{Anchor} } @$ps).
1260                                ")");
1261
1262
1263             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1264             $cl->{MergeBestAnchor} = $best_anchor;
1265             push @brw_cl, {
1266                 %$cl,
1267                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1268                 $xmsg->('constructed from vanilla merge',
1269                         ' merged-breakwater'),
1270             };
1271             push @upp_cl, {
1272                 %$cl,
1273                 SpecialMethod => 'MergeMergeSeries',
1274             };
1275             $build_start->('MergeBreakwaters', $cur);
1276         } else {
1277             printdebug "*** WALK BOMB unrecognised\n";
1278             return $bomb->();
1279         }
1280     }
1281     $prprdelim->();
1282
1283     printdebug "*** WALK prep done cur=$cur".
1284         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1285
1286     return if $nogenerate;
1287
1288     # Now we build it back up again
1289
1290     fresh_workarea();
1291
1292     my $rewriting = 0;
1293
1294     my $read_tree_upstream = sub {
1295         my ($treeish) = @_;
1296         read_tree_upstream $treeish, 0, $build;
1297     };
1298
1299     $#upp_cl = $upp_limit if defined $upp_limit;
1300
1301     my $committer_authline = calculate_committer_authline();
1302
1303     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1304
1305     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1306
1307     in_workarea sub {
1308         mkdir $rd or $!==EEXIST or die $!;
1309         my $current_method;
1310         runcmd @git, qw(read-tree), $build;
1311         foreach my $cl (qw(Debian), (reverse @brw_cl),
1312                         { SpecialMethod => 'RecordBreakwaterTip' },
1313                         qw(Upstream), (reverse @upp_cl)) {
1314             if (!ref $cl) {
1315                 $current_method = $cl;
1316                 next;
1317             }
1318             my $method = $cl->{SpecialMethod} // $current_method;
1319             my @parents = ($build);
1320             my $cltree = $cl->{CommitId};
1321             printdebug "WALK BUILD ".($cltree//'undef').
1322                 " $method (rewriting=$rewriting)\n";
1323             if ($method eq 'Debian') {
1324                 read_tree_debian($cltree);
1325             } elsif ($method eq 'Upstream') {
1326                 $read_tree_upstream->($cltree);
1327             } elsif ($method eq 'StartRewrite') {
1328                 $rewriting = 1;
1329                 next;
1330             } elsif ($method eq 'RecordBreakwaterTip') {
1331                 $breakwater = $build;
1332                 next;
1333             } elsif ($method eq 'DgitImportDebianUpdate') {
1334                 read_tree_debian($cltree);
1335             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1336                 confess unless $rewriting;
1337                 my $differs = (get_differs $build, $cltree);
1338                 next unless $differs & D_UPS;
1339                 $read_tree_upstream->($cltree);
1340                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1341             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1342                 print "Found a general merge, will try to tidy it up.\n";
1343                 $rewriting = 1;
1344                 $read_tree_upstream->($cl->{MergeBestAnchor});
1345                 $read_tree_upstream->($cl->{MergeBestAnchor});
1346                 read_tree_debian($cltree);
1347                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1348             } elsif ($method eq 'MergeMergeSeries') {
1349                 print "Running merge resolution for $cl->{CommitId}...\n";
1350                 $build = merge_series
1351                     $build,
1352                     $cl->{MergeInterchangeBaseInfo},
1353                     @{ $cl->{Parents} };
1354                 $last_anchor = $cl->{MergeBestAnchor};
1355
1356                 # Check for mismerges:
1357                 my $check = sub {
1358                     my ($against, $allow, $what) = @_;
1359                     my $differs = get_differs $build, $against;
1360                     $nomerge->(sprintf
1361        "merge misresolved: %s are not the same (%s %s d.%#x)",
1362                                $what, $against, $build, $differs)
1363                         if $differs & ~($allow | D_PAT_ADD);
1364                 };
1365
1366                 # Breakwater changes which were in each side of the
1367                 # merge will have been incorporated into the
1368                 # MergeCreateMergedBreakwaters output.  Because the
1369                 # upstream series was rebased onto the new breakwater,
1370                 # so should all of the packaging changes which were in
1371                 # the input.
1372                 $check->($input, D_UPS, 'debian files');
1373
1374                 # Upstream files are merge_series, which ought to
1375                 # have been identical to the original merge.
1376                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1377
1378                 print "Merge resolution successful.\n";
1379                 next;
1380             } else {
1381                 confess "$method ?";
1382             }
1383             if (!$rewriting) {
1384                 my $procd = (pop @processed) // 'UNDEF';
1385                 if ($cl ne $procd) {
1386                     $rewriting = 1;
1387                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1388                 }
1389             }
1390             my $newtree = cmdoutput @git, qw(write-tree);
1391             my $ch = $cl->{Hdr};
1392             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1393             $ch =~ s{^parent .*\n}{}mg;
1394             $ch =~ s{(?=^author)}{
1395                 join '', map { "parent $_\n" } @parents
1396             }me or confess "$ch ?";
1397             if ($rewriting) {
1398                 $ch =~ s{^committer .*$}{$committer_authline}m
1399                     or confess "$ch ?";
1400             }
1401             my $cf = "$rd/m$rewriting";
1402             open CD, ">", $cf or die $!;
1403             print CD $ch, "\n", $cl->{Msg} or die $!;
1404             close CD or die $!;
1405             my @cmd = (@git, qw(hash-object));
1406             push @cmd, qw(-w) if $rewriting;
1407             push @cmd, qw(-t commit), $cf;
1408             my $newcommit = cmdoutput @cmd;
1409             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1410             $build = $newcommit;
1411             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1412                 $last_anchor = $cur;
1413             }
1414         }
1415     };
1416
1417     my $final_check = get_differs $build, $input;
1418     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1419         if $final_check & ~D_PAT_ADD;
1420
1421     my @r = ($build, $breakwater, $last_anchor);
1422     printdebug "*** WALK RETURN @r\n";
1423     return @r
1424 }
1425
1426 sub get_head () {
1427     git_check_unmodified();
1428     return git_rev_parse qw(HEAD);
1429 }
1430
1431 sub update_head ($$$) {
1432     my ($old, $new, $mrest) = @_;
1433     push @deferred_updates, "update HEAD $new $old";
1434     run_deferred_updates $mrest;
1435 }
1436
1437 sub update_head_checkout ($$$) {
1438     my ($old, $new, $mrest) = @_;
1439     update_head $old, $new, $mrest;
1440     runcmd @git, qw(reset --hard);
1441 }
1442
1443 sub update_head_postlaunder ($$$) {
1444     my ($old, $tip, $reflogmsg) = @_;
1445     return if $tip eq $old;
1446     print "git-debrebase: laundered (head was $old)\n";
1447     update_head $old, $tip, $reflogmsg;
1448     # no tree changes except debian/patches
1449     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1450 }
1451
1452 sub currently_rebasing() {
1453     foreach (qw(rebase-merge rebase-apply)) {
1454         return 1 if stat_exists "$maindir_gitdir/$_";
1455     }
1456     return 0;
1457 }
1458
1459 sub bail_if_rebasing() {
1460     fail "you are in the middle of a git-rebase already"
1461         if currently_rebasing();
1462 }
1463
1464 sub do_launder_head ($) {
1465     my ($reflogmsg) = @_;
1466     my $old = get_head();
1467     record_ffq_auto();
1468     my ($tip,$breakwater) = walk $old;
1469     snags_maybe_bail();
1470     update_head_postlaunder $old, $tip, $reflogmsg;
1471     return ($tip,$breakwater);
1472 }
1473
1474 sub cmd_launder_v0 () {
1475     badusage "no arguments to launder-v0 allowed" if @ARGV;
1476     my $old = get_head();
1477     my ($tip,$breakwater,$last_anchor) = walk $old;
1478     update_head_postlaunder $old, $tip, 'launder';
1479     printf "# breakwater tip\n%s\n", $breakwater;
1480     printf "# working tip\n%s\n", $tip;
1481     printf "# last anchor\n%s\n", $last_anchor;
1482 }
1483
1484 sub defaultcmd_rebase () {
1485     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1486     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1487     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1488 }
1489
1490 sub cmd_analyse () {
1491     badusage "analyse does not support any options"
1492         if @ARGV and $ARGV[0] =~ m/^-/;
1493     badusage "too many arguments to analyse" if @ARGV>1;
1494     my ($old) = @ARGV;
1495     if (defined $old) {
1496         $old = git_rev_parse $old;
1497     } else {
1498         $old = git_rev_parse 'HEAD';
1499     }
1500     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1501     STDOUT->error and die $!;
1502 }
1503
1504 sub ffq_prev_branchinfo () {
1505     my $current = git_get_symref();
1506     return gdr_ffq_prev_branchinfo($current);
1507 }
1508
1509 sub ffq_check ($;$$) {
1510     # calls $ff and/or $notff zero or more times
1511     # then returns either (status,message) where status is
1512     #    exists
1513     #    detached
1514     #    weird-symref
1515     #    notbranch
1516     # or (undef,undef, $ffq_prev,$gdrlast)
1517     # $ff and $notff are called like this:
1518     #   $ff->("message for stdout\n");
1519     #   $notff->('snag-name', $message);
1520     # normally $currentval should be HEAD
1521     my ($currentval, $ff, $notff) =@_;
1522
1523     $ff //= sub { print $_[0] or die $!; };
1524     $notff //= \&snag;
1525
1526     my ($status, $message, $current, $ffq_prev, $gdrlast)
1527         = ffq_prev_branchinfo();
1528     return ($status, $message) unless $status eq 'branch';
1529
1530     my $exists = git_get_ref $ffq_prev;
1531     return ('exists',"$ffq_prev already exists") if $exists;
1532
1533     return ('not-branch', 'HEAD symref is not to refs/heads/')
1534         unless $current =~ m{^refs/heads/};
1535     my $branch = $';
1536
1537     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1538     my %checked;
1539
1540     printdebug "ffq check_specs @check_specs\n";
1541
1542     my $check = sub {
1543         my ($lrref, $desc) = @_;
1544         printdebug "ffq might check $lrref ($desc)\n";
1545         my $invert;
1546         for my $chk (@check_specs) {
1547             my $glob = $chk;
1548             $invert = $glob =~ s{^[!^]}{};
1549             last if fnmatch $glob, $lrref;
1550         }
1551         return if $invert;
1552         my $lrval = git_get_ref $lrref;
1553         return unless length $lrval;
1554
1555         if (is_fast_fwd $lrval, $currentval) {
1556             $ff->("OK, you are ahead of $lrref\n");
1557             $checked{$lrref} = 1;
1558         } elsif (is_fast_fwd $currentval, $lrval) {
1559             $checked{$lrref} = -1;
1560             $notff->('behind', "you are behind $lrref, divergence risk");
1561         } else {
1562             $checked{$lrref} = -1;
1563             $notff->('diverged', "you have diverged from $lrref");
1564         }
1565     };
1566
1567     my $merge = cfg "branch.$branch.merge",1;
1568     if (defined $merge and $merge =~ m{^refs/heads/}) {
1569         my $rhs = $';
1570         printdebug "ffq merge $rhs\n";
1571         my $check_remote = sub {
1572             my ($remote, $desc) = @_;
1573             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1574             return unless defined $remote;
1575             $check->("refs/remotes/$remote/$rhs", $desc);
1576         };
1577         $check_remote->((scalar cfg "branch.$branch.remote",1),
1578                         'remote fetch/merge branch');
1579         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1580                         (scalar cfg "branch.$branch.pushDefault",1),
1581                         'remote push branch');
1582     }
1583     if ($branch =~ m{^dgit/}) {
1584         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1585     } elsif ($branch =~ m{^master$}) {
1586         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1587     }
1588     return (undef, undef, $ffq_prev, $gdrlast);
1589 }
1590
1591 sub record_ffq_prev_deferred () {
1592     # => ('status', "message")
1593     # 'status' may be
1594     #    deferred          message is undef
1595     #    exists
1596     #    detached
1597     #    weird-symref
1598     #    notbranch
1599     # if not ff from some branch we should be ff from, is an snag
1600     # if "deferred", will have added something about that to
1601     #   @deferred_update_messages, and also maybe printed (already)
1602     #   some messages about ff checks
1603     bail_if_rebasing();
1604     my $currentval = get_head();
1605
1606     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1607     return ($status,$message) if defined $status;
1608
1609     snags_maybe_bail();
1610
1611     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1612     push @deferred_updates, "delete $gdrlast";
1613     push @deferred_update_messages, "Recorded previous head for preservation";
1614     return ('deferred', undef);
1615 }
1616
1617 sub record_ffq_auto () {
1618     my ($status, $message) = record_ffq_prev_deferred();
1619     if ($status eq 'deferred' || $status eq 'exists') {
1620     } else {
1621         snag $status, "could not record ffq-prev: $message";
1622         snags_maybe_bail();
1623     }
1624 }
1625
1626 sub ffq_prev_info () {
1627     bail_if_rebasing();
1628     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1629     my ($status, $message, $current, $ffq_prev, $gdrlast)
1630         = ffq_prev_branchinfo();
1631     if ($status ne 'branch') {
1632         snag $status, "could not check ffq-prev: $message";
1633         snags_maybe_bail();
1634     }
1635     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1636     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1637 }
1638
1639 sub stitch ($$$$$) {
1640     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1641
1642     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1643
1644     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1645         my $differs = get_differs $old_head, $ffq_prev_commitish;
1646         unless ($differs & ~D_PAT_ADD) {
1647             # ffq-prev is ahead of us, and the only tree changes it has
1648             # are possibly addition of things in debian/patches/.
1649             # Just wind forwards rather than making a pointless pseudomerge.
1650             push @deferred_updates,
1651                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1652             update_head_checkout $old_head, $ffq_prev_commitish,
1653                 "stitch (fast forward)";
1654             return;
1655         }
1656     }
1657     fresh_workarea();
1658     # We make pseudomerges with L as the contributing parent.
1659     # This makes git rev-list --first-parent work properly.
1660     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1661         'Declare fast forward / record previous work',
1662         "[git-debrebase pseudomerge: $prose]",
1663     ];
1664     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1665     update_head $old_head, $new_head, "stitch: $prose";
1666 }
1667
1668 sub do_stitch ($;$) {
1669     my ($prose, $unclean) = @_;
1670
1671     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1672     if (!$ffq_prev_commitish) {
1673         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1674         return;
1675     }
1676     my $dangling_head = get_head();
1677
1678     keycommits $dangling_head, $unclean,$unclean,$unclean;
1679     snags_maybe_bail();
1680
1681     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1682 }
1683
1684 sub upstream_commitish_search ($$) {
1685     my ($upstream_version, $tried) = @_;
1686     # todo: at some point maybe use git-deborig to do this
1687     foreach my $tagpfx ('', 'v', 'upstream/') {
1688         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1689         my $new_upstream = git_get_ref "refs/tags/$tag";
1690         push @$tried, $tag;
1691         return $new_upstream if length $new_upstream;
1692     }
1693 }
1694
1695 sub resolve_upstream_version ($$) {
1696     my ($new_upstream, $upstream_version) = @_;
1697
1698     if (!defined $new_upstream) {
1699         my @tried;
1700         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1701         if (!length $new_upstream) {
1702             fail "Could not determine appropriate upstream commitish.\n".
1703                 " (Tried these tags: @tried)\n".
1704                 " Check version, and specify upstream commitish explicitly.";
1705         }
1706     }
1707     $new_upstream = git_rev_parse $new_upstream;
1708
1709     return $new_upstream;
1710 }
1711
1712 sub cmd_new_upstream () {
1713     # automatically and unconditionally launders before rebasing
1714     # if rebase --abort is used, laundering has still been done
1715
1716     my %pieces;
1717
1718     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1719
1720     # parse args - low commitment
1721     my $spec_version = shift @ARGV;
1722     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1723     fail "bad version number \`$spec_version'" unless defined $new_version;
1724     if ($new_version->is_native()) {
1725         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1726     }
1727
1728     my $new_upstream = shift @ARGV;
1729     my $new_upstream_version = upstreamversion  $new_version;
1730     $new_upstream =
1731         resolve_upstream_version $new_upstream, $new_upstream_version;
1732
1733     record_ffq_auto();
1734
1735     my $piece = sub {
1736         my ($n, @x) = @_; # may be ''
1737         my $pc = $pieces{$n} //= {
1738             Name => $n,
1739             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1740         };
1741         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1742         $pc;
1743     };
1744
1745     my @newpieces;
1746     my $newpiece = sub {
1747         my ($n, @x) = @_; # may be ''
1748         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1749         push @newpieces, $pc;
1750     };
1751
1752     $newpiece->('',
1753         OldIx => 0,
1754         New => $new_upstream,
1755     );
1756     while (@ARGV && $ARGV[0] !~ m{^-}) {
1757         my $n = shift @ARGV;
1758
1759         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1760             unless @ARGV && $ARGV[0] !~ m{^-};
1761
1762         my $c = git_rev_parse shift @ARGV;
1763         die unless $n =~ m/^$extra_orig_namepart_re$/;
1764         $newpiece->($n, New => $c);
1765     }
1766
1767     # now we need to investigate the branch this generates the
1768     # laundered version but we don't switch to it yet
1769     my $old_head = get_head();
1770     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1771
1772     my $old_bw_cl = classify $old_bw;
1773     my $old_anchor_cl = classify $old_anchor;
1774     my $old_upstream;
1775     if (!$old_anchor_cl->{OrigParents}) {
1776         snag 'anchor-treated',
1777             'old anchor is recognised due to --anchor, cannot check upstream';
1778     } else {
1779         $old_upstream = parsecommit
1780             $old_anchor_cl->{OrigParents}[0]{CommitId};
1781         $piece->('', Old => $old_upstream->{CommitId});
1782     }
1783
1784     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1785         if ($old_upstream->{Msg} =~
1786  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1787            ) {
1788             my @oldpieces = (split / /, $1);
1789             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1790             if ($old_n_parents != @oldpieces &&
1791                 $old_n_parents != @oldpieces + 1) {
1792                 snag 'upstream-confusing', sprintf
1793                     "previous upstream combine %s".
1794                     " mentions %d pieces (each implying one parent)".
1795                     " but has %d parents".
1796                     " (one per piece plus maybe a previous combine)",
1797                     $old_upstream->{CommitId},
1798                     (scalar @oldpieces),
1799                     $old_n_parents;
1800             } elsif ($oldpieces[0] ne '.') {
1801                 snag 'upstream-confusing', sprintf
1802                     "previous upstream combine %s".
1803                     " first piece is not \`.'",
1804                     $oldpieces[0];
1805             } else {
1806                 $oldpieces[0] = '';
1807                 foreach my $i (0..$#oldpieces) {
1808                     my $n = $oldpieces[$i];
1809                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1810                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1811                 }
1812             }
1813         } else {
1814             snag 'upstream-confusing',
1815                 "previous upstream $old_upstream->{CommitId} is from".
1816                " git-debrebase but not an \`upstream-combine' commit";
1817         }
1818     }
1819
1820     foreach my $pc (values %pieces) {
1821         if (!$old_upstream) {
1822             # we have complained already
1823         } elsif (!$pc->{Old}) {
1824             snag 'upstream-new-piece',
1825                 "introducing upstream piece \`$pc->{Name}'";
1826         } elsif (!$pc->{New}) {
1827             snag 'upstream-rm-piece',
1828                 "dropping upstream piece \`$pc->{Name}'";
1829         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1830             snag 'upstream-not-ff',
1831                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1832         }
1833     }
1834
1835     printdebug "%pieces = ", (dd \%pieces), "\n";
1836     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1837
1838     snags_maybe_bail();
1839
1840     my $new_bw;
1841
1842     fresh_workarea();
1843     in_workarea sub {
1844         my @upstream_merge_parents;
1845
1846         if (!any_snags()) {
1847             push @upstream_merge_parents, $old_upstream->{CommitId};
1848         }
1849
1850         foreach my $pc (@newpieces) { # always has '' first
1851             if ($pc->{Name}) {
1852                 read_tree_subdir $pc->{Name}, $pc->{New};
1853             } else {
1854                 runcmd @git, qw(read-tree), $pc->{New};
1855             }
1856             push @upstream_merge_parents, $pc->{New};
1857         }
1858
1859         # index now contains the new upstream
1860
1861         if (@newpieces > 1) {
1862             # need to make the upstream subtree merge commit
1863             $new_upstream = make_commit \@upstream_merge_parents,
1864                 [ "Combine upstreams for $new_upstream_version",
1865  ("[git-debrebase upstream-combine . ".
1866  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1867  ": new upstream]"),
1868                 ];
1869         }
1870
1871         # $new_upstream is either the single upstream commit, or the
1872         # combined commit we just made.  Either way it will be the
1873         # "upstream" parent of the anchor merge.
1874
1875         read_tree_subdir 'debian', "$old_bw:debian";
1876
1877         # index now contains the anchor merge contents
1878         $new_bw = make_commit [ $old_bw, $new_upstream ],
1879             [ "Update to upstream $new_upstream_version",
1880  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1881             ];
1882
1883         my $clogsignoff = cmdoutput qw(git show),
1884             '--pretty=format:%an <%ae>  %aD',
1885             $new_bw;
1886
1887         # Now we have to add a changelog stanza so the Debian version
1888         # is right.
1889         die if unlink "debian";
1890         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1891         unlink "debian/changelog" or $!==ENOENT or die $!;
1892         mkdir "debian" or die $!;
1893         open CN, ">", "debian/changelog" or die $!;
1894         my $oldclog = git_cat_file ":debian/changelog";
1895         $oldclog =~ m/^($package_re) \(\S+\) / or
1896             fail "cannot parse old changelog to get package name";
1897         my $p = $1;
1898         print CN <<END, $oldclog or die $!;
1899 $p ($new_version) UNRELEASED; urgency=medium
1900
1901   * Update to new upstream version $new_upstream_version.
1902
1903  -- $clogsignoff
1904
1905 END
1906         close CN or die $!;
1907         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
1908
1909         # Now we have the final new breakwater branch in the index
1910         $new_bw = make_commit [ $new_bw ],
1911             [ "Update changelog for new upstream $new_upstream_version",
1912               "[git-debrebase: new upstream $new_upstream_version, changelog]",
1913             ];
1914     };
1915
1916     # we have constructed the new breakwater. we now need to commit to
1917     # the laundering output, because git-rebase can't easily be made
1918     # to make a replay list which is based on some other branch
1919
1920     update_head_postlaunder $old_head, $old_laundered_tip,
1921         'launder for new upstream';
1922
1923     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
1924     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
1925         "debrebase new-upstream $new_version: rebase";
1926     runcmd @cmd;
1927     # now it's for the user to sort out
1928 }
1929
1930 sub cmd_record_ffq_prev () {
1931     badusage "no arguments allowed" if @ARGV;
1932     my ($status, $msg) = record_ffq_prev_deferred();
1933     if ($status eq 'exists' && $opt_noop_ok) {
1934         print "Previous head already recorded\n" or die $!;
1935     } elsif ($status eq 'deferred') {
1936         run_deferred_updates 'record-ffq-prev';
1937     } else {
1938         fail "Could not preserve: $msg";
1939     }
1940 }
1941
1942 sub cmd_anchor () {
1943     badusage "no arguments allowed" if @ARGV;
1944     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1945     print "$bw\n" or die $!;
1946 }
1947
1948 sub cmd_breakwater () {
1949     badusage "no arguments allowed" if @ARGV;
1950     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
1951     print "$bw\n" or die $!;
1952 }
1953
1954 sub cmd_status () {
1955     badusage "no arguments allowed" if @ARGV;
1956
1957     # todo: gdr status should print divergence info
1958     # todo: gdr status should print upstream component(s) info
1959     # todo: gdr should leave/maintain some refs with this kind of info ?
1960
1961     my $oldest = { Badness => 0 };
1962     my $newest;
1963     my $note = sub {
1964         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
1965         if ($oldest->{Badness} < $badness) {
1966             $oldest = $newest = undef;
1967         }
1968         $oldest = {
1969                    Badness => $badness,
1970                    CommitId => $cl->{CommitId},
1971                    OurMsg => $ourmsg,
1972                    KcMsg => $kcmsg,
1973                   };
1974         $newest //= $oldest;
1975     };
1976     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
1977         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
1978         sub { $note->(2, 'branch is unlaundered', @_); },
1979         sub { $note->(3, 'branch needs laundering', @_); },
1980         sub { $note->(4, 'branch not in git-debrebase form', @_); };
1981
1982     my $prcommitinfo = sub {
1983         my ($cid) = @_;
1984         flush STDOUT or die $!;
1985         runcmd @git, qw(--no-pager log -n1),
1986             '--pretty=format:    %h %s%n',
1987             $cid;
1988     };
1989
1990     print "current branch contents, in git-debrebase terms:\n";
1991     if (!$oldest->{Badness}) {
1992         print "  branch is laundered\n";
1993     } else {
1994         print "  $oldest->{OurMsg}\n";
1995         my $printed = '';
1996         foreach my $info ($oldest, $newest) {
1997             my $cid = $info->{CommitId};
1998             next if $cid eq $printed;
1999             $printed = $cid;
2000             print "  $info->{KcMsg}\n";
2001             $prcommitinfo->($cid);
2002         }
2003     }
2004
2005     my $prab = sub {
2006         my ($cid, $what) = @_;
2007         if (!defined $cid) {
2008             print "  $what is not well-defined\n";
2009         } else {
2010             print "  $what\n";
2011             $prcommitinfo->($cid);
2012         }
2013     };
2014     print "key git-debrebase commits:\n";
2015     $prab->($anchor, 'anchor');
2016     $prab->($bw, 'breakwater');
2017
2018     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2019         ffq_prev_branchinfo();
2020
2021     print "branch and ref status, in git-debrebase terms:\n";
2022     if ($ffq_msg) {
2023         print "  $ffq_msg\n";
2024     } else {
2025         $ffq_prev = git_get_ref $ffq_prev;
2026         $gdrlast = git_get_ref $gdrlast;
2027         if ($ffq_prev) {
2028             print "  unstitched; previous tip was:\n";
2029             $prcommitinfo->($ffq_prev);
2030         } elsif (!$gdrlast) {
2031             print "  stitched? (no record of git-debrebase work)\n";
2032         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2033             print "  stitched\n";
2034         } else {
2035             print "  not git-debrebase (diverged since last stitch)\n"
2036         }
2037     }
2038     print "you are currently rebasing\n" if currently_rebasing();
2039 }
2040
2041 sub cmd_stitch () {
2042     my $prose = 'stitch';
2043     getoptions("stitch",
2044                'prose=s', \$prose);
2045     badusage "no arguments allowed" if @ARGV;
2046     do_stitch $prose, 0;
2047 }
2048 sub cmd_prepush () { cmd_stitch(); }
2049
2050 sub cmd_quick () {
2051     badusage "no arguments allowed" if @ARGV;
2052     do_launder_head 'launder for git-debrebase quick';
2053     do_stitch 'quick';
2054 }
2055
2056 sub cmd_conclude () {
2057     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2058     if (!$ffq_prev_commitish) {
2059         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2060         return;
2061     }
2062     my $dangling_head = get_head();
2063
2064     badusage "no arguments allowed" if @ARGV;
2065     do_launder_head 'launder for git-debrebase quick';
2066     do_stitch 'quick';
2067 }
2068
2069 sub cmd_scrap () {
2070     if (currently_rebasing()) {
2071         runcmd @git, qw(rebase --abort);
2072     }
2073     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2074     if (!$ffq_prev_commitish) {
2075         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2076         finish 0;
2077     }
2078     my $scrapping_head = get_head();
2079     badusage "no arguments allowed" if @ARGV;
2080     push @deferred_updates,
2081         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2082         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2083     snags_maybe_bail();
2084     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2085 }
2086
2087 sub make_patches_staged ($) {
2088     my ($head) = @_;
2089     # Produces the patches that would result from $head if it were
2090     # laundered.
2091     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2092     fresh_workarea();
2093     in_workarea sub {
2094         gbp_pq_export 'bw', $secret_bw, $secret_head;
2095     };
2096 }
2097
2098 sub make_patches ($) {
2099     my ($head) = @_;
2100     keycommits $head, 0, \&snag;
2101     make_patches_staged $head;
2102     my $out;
2103     in_workarea sub {
2104         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2105         runcmd @git, qw(read-tree), $head;
2106         read_tree_subdir 'debian/patches', $ptree;
2107         $out = make_commit [$head], [
2108             'Commit patch queue (exported by git-debrebase)',
2109             '[git-debrebase: export and commit patches]',
2110         ];
2111     };
2112     return $out;
2113 }
2114
2115 sub cmd_make_patches () {
2116     my $opt_quiet_would_amend;
2117     getoptions("make-patches",
2118                'quiet-would-amend!', \$opt_quiet_would_amend);
2119     badusage "no arguments allowed" if @ARGV;
2120     bail_if_rebasing();
2121     my $old_head = get_head();
2122     my $new = make_patches $old_head;
2123     my $d = get_differs $old_head, $new;
2124     if ($d == 0) {
2125         fail "No (more) patches to export." unless $opt_noop_ok;
2126         return;
2127     } elsif ($d == D_PAT_ADD) {
2128         snags_maybe_bail();
2129         update_head_checkout $old_head, $new, 'make-patches';
2130     } else {
2131         print STDERR failmsg
2132             "Patch export produced patch amendments".
2133             " (abandoned output commit $new).".
2134             "  Try laundering first."
2135             unless $opt_quiet_would_amend;
2136         finish 7;
2137     }
2138 }
2139
2140 sub cmd_convert_from_gbp () {
2141     badusage "want only 1 optional argument, the upstream git commitish"
2142         unless @ARGV<=1;
2143
2144     my $clogp = parsechangelog();
2145     my $version = $clogp->{'Version'}
2146         // die "missing Version from changelog";
2147
2148     my ($upstream_spec) = @ARGV;
2149
2150     my $upstream_version = upstreamversion $version;
2151     my $upstream =
2152         resolve_upstream_version($upstream_spec, $upstream_version);
2153
2154     my $old_head = get_head();
2155
2156     my $upsdiff = get_differs $upstream, $old_head;
2157     if ($upsdiff & D_UPS) {
2158         runcmd @git, qw(--no-pager diff --stat),
2159             $upstream, $old_head,
2160             qw( -- :!/debian :/);
2161         fail <<END;
2162 upstream ($upstream_spec) and HEAD are not
2163 identical in upstream files.  See diffstat above, or run
2164   git diff $upstream_spec HEAD -- :!/debian :/
2165 END
2166     }
2167
2168     if (!is_fast_fwd $upstream, $old_head) {
2169         snag 'upstream-not-ancestor',
2170             "upstream ($upstream) is not an ancestor of HEAD";
2171     } else {
2172         my $wrong = cmdoutput
2173             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2174              qw(-- :/ :!/debian));
2175         if (length $wrong) {
2176             snag 'unexpected-upstream-changes',
2177                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2178             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2179         }
2180     }
2181
2182     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2183         snag 'upstream-has-debian',
2184             "upstream ($upstream) contains debian/ directory";
2185     }
2186
2187     my $previous_dgit_view = eval {
2188         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2189         my ($lvsn, $suite);
2190         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2191             my ($stz, $desc) = @_;
2192             no warnings qw(exiting);
2193             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2194             next unless $stz->{Date};
2195             next unless $stz->{Distribution} ne 'UNRELEASED';
2196             $lvsn = $stz->{Version};
2197             $suite = $stz->{Distribution};
2198             last;
2199         };
2200         die "neither of the first two changelog entries are released\n"
2201             unless defined $lvsn;
2202         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2203         my $mtag_pat = debiantag_maintview $lvsn, '*';
2204         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2205             $mtag_pat;
2206         die "could not find suitable maintainer view tag $mtag_pat\n"
2207             unless $mtag_pat =~ m{/};
2208         is_fast_fwd $mtag, 'HEAD' or
2209             die "HEAD is not FF from maintainer tag $mtag!";
2210         my $dtag = "archive/$mtag";
2211         is_fast_fwd $mtag, $dtag or
2212             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2213         print "will stitch in dgit view, $dtag\n";
2214         git_rev_parse $dtag;
2215     };
2216     if (!$previous_dgit_view) {
2217         $@ =~ s/^\n+//;
2218         chomp $@;
2219         print STDERR "cannot stitch in dgit view: $@\n";
2220     }
2221
2222     snags_maybe_bail_early();
2223
2224     my $work;
2225
2226     fresh_workarea();
2227     in_workarea sub {
2228         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2229         # make a branch out of the patch queue - we'll want this in a mo
2230         runcmd qw(gbp pq import);
2231         # strip the patches out
2232         runcmd @git, qw(checkout -q gdr-internal~0);
2233         rm_subdir_cached 'debian/patches';
2234         $work = make_commit ['HEAD'], [
2235  'git-debrebase convert-from-gbp: drop patches from tree',
2236  'Delete debian/patches, as part of converting to git-debrebase format.',
2237  '[git-debrebase convert-from-gbp: drop patches from tree]'
2238                               ];
2239         # make the anchor merge
2240         # the tree is already exactly right
2241         $work = make_commit [$work, $upstream], [
2242  'git-debrebase import: declare upstream',
2243  'First breakwater merge.',
2244  '[git-debrebase anchor: declare upstream]'
2245                               ];
2246
2247         # rebase the patch queue onto the new breakwater
2248         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2249         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2250         $work = git_rev_parse 'HEAD';
2251
2252         if ($previous_dgit_view) {
2253             $work = make_commit [$work, $previous_dgit_view], [
2254  'git-debrebase import: declare ff from dgit archive view',
2255  '[git-debrebase pseudomerge: import-from-gbp]',
2256             ];
2257         }
2258     };
2259
2260     ffq_check $work;
2261     snags_maybe_bail();
2262     update_head_checkout $old_head, $work, 'convert-from-gbp';
2263 }
2264
2265 sub cmd_convert_to_gbp () {
2266     badusage "no arguments allowed" if @ARGV;
2267     my $head = get_head();
2268     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2269     keycommits $head, 0;
2270     my $out;
2271     make_patches_staged $head;
2272     in_workarea sub {
2273         $out = make_commit ['HEAD'], [
2274             'Commit patch queue (converted from git-debrebase format)',
2275             '[git-debrebase convert-to-gbp: commit patches]',
2276         ];
2277     };
2278     if (defined $ffq) {
2279         push @deferred_updates, "delete $ffq";
2280         push @deferred_updates, "delete $gdrlast";
2281     }
2282     snags_maybe_bail();
2283     update_head_checkout $head, $out, "convert to gbp (v0)";
2284     print <<END or die $!;
2285 git-debrebase: converted to git-buildpackage branch format
2286 git-debrebase: WARNING: do not now run "git-debrebase" any more
2287 git-debrebase: WARNING: doing so would drop all upstream patches!
2288 END
2289 }
2290
2291 sub cmd_convert_from_dgit_view () {
2292     my $clogp = parsechangelog();
2293
2294     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2295     my $do_origs = 1;
2296     my $do_tags = 1;
2297     my $always = 0;
2298     my $diagnose = 0;
2299
2300     getoptions("convert-from-dgit-view",
2301                'diagnose!', \$diagnose,
2302                'build-products-dir:s', \$bpd,
2303                'origs!', \$do_origs,
2304                'tags!', \$do_tags,
2305                'always-convert-anyway!', \$always);
2306     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2307
2308     my @upstreams;
2309
2310     if (@ARGV) {
2311         my $spec = shift @ARGV;
2312         my $commit = git_rev_parse "$spec^{commit}";
2313         push @upstreams, { Commit => $commit,
2314                            Source => "$ARGV[0], from command line",
2315                            Only => 1,
2316                          };
2317     }
2318
2319     my $head = get_head();
2320
2321     if (!$always) {
2322         my $troubles = 0;
2323         my $trouble = sub { $troubles++; };
2324         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2325         printdebug "troubles=$troubles\n";
2326         if (!$troubles) {
2327             print STDERR <<END;
2328 $us: Branch already seems to be in git-debrebase format!
2329 $us: --always-convert-anyway would do the conversion operation anyway
2330 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2331 END
2332             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2333             finish 0;
2334         }
2335     }
2336
2337     snags_maybe_bail_early();
2338
2339     my $version = upstreamversion $clogp->{Version};
2340     print STDERR "Considering possible commits corresponding to upstream:\n";
2341
2342     if (!@upstreams) {
2343         if ($do_tags) {
2344             my @tried;
2345             my $ups_tag = upstream_commitish_search $version, \@tried;
2346             if ($ups_tag) {
2347                 my $this = "git tag $tried[-1]";
2348                 push @upstreams, { Commit => $ups_tag,
2349                                    Source => $this,
2350                                  };
2351             } else {
2352                 printf STDERR
2353                     " git tag: no suitable tag found (tried %s)\n",
2354                     "@tried";
2355             }
2356         }
2357         if ($do_origs) {
2358             my $p = $clogp->{'Source'};
2359             # we do a quick check to see if there are plausible origs
2360             my $something=0;
2361             if (!opendir BPD, $bpd) {
2362                 die "$bpd: opendir: $!" unless $!==ENOENT;
2363             } else {
2364                 while ($!=0, my $f = readdir BPD) {
2365                     next unless is_orig_file_of_p_v $f, $p, $version;
2366                     printf STDERR
2367                         " orig: found what looks like a .orig, %s\n",
2368                         "$bpd/$f";
2369                     $something=1;
2370                     last;
2371                 }
2372                 die "read $bpd: $!" if $!;
2373                 closedir BPD;
2374             }
2375             if ($something) {
2376                 my $tree = cmdoutput
2377                     @dgit, qw(--build-products-dir), $bpd,
2378                     qw(print-unapplied-treeish);
2379                 fresh_workarea();
2380                 in_workarea sub {
2381                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2382                     rm_subdir_cached 'debian';
2383                     $tree = cmdoutput @git, qw(write-tree);
2384                     my $ups_synth = make_commit [], [ <<END, <<END,
2385 Import effective orig tree for upstream version $version
2386 END
2387 This includes the contents of the .orig(s), minus any debian/ directory.
2388
2389 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2390 END
2391                                                     ];
2392                     push @upstreams, { Commit => $ups_synth,
2393                                        Source => "orig(s) imported via dgit",
2394                                      };
2395                 }
2396             } else {
2397                 printf STDERR
2398                     " orig: no suitable origs found (looked for %s in %s)\n",
2399                     "${p}_".(stripeoch $version)."...", $bpd;
2400             }
2401         }
2402     }
2403
2404     my $some_patches = stat_exists 'debian/patches/series';
2405
2406     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2407
2408     my $result;
2409     foreach my $u (@upstreams) {
2410         my $work = $head;
2411         fresh_workarea();
2412         in_workarea sub {
2413             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2414             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2415             runcmd @git, qw(clean -xdff);
2416             runcmd @git, qw(checkout), $head, qw(-- debian);
2417             if ($some_patches) {
2418                 rm_subdir_cached 'debian/patches';
2419                 $work = make_commit [ $work ], [
2420  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2421  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2422  "to git-debrebase format.  Upstream changes will appear as commits.",
2423  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2424                                            ];
2425             }
2426             $work = make_commit [ $work, $u->{Commit} ], [
2427  'git-debrebase convert-from-dgit-view: declare upstream',
2428  '(Re)constructed breakwater merge.',
2429  '[git-debrebase anchor: declare upstream]'
2430                                                          ];
2431             runcmd @git, qw(checkout --quiet -b mk), $work;
2432             if ($some_patches) {
2433                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2434                 runcmd @git, qw(reset --quiet);
2435                 my @gbp_cmd = (qw(gbp pq import));
2436                 if (!$diagnose) {
2437                     my $gbp_err = "../gbp-pq-err";
2438                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2439                 }
2440                 my $r = system @gbp_cmd;
2441                 if ($r) {
2442                     printf STDERR
2443                         " %s: couldn't apply patches: gbp pq %s",
2444                         $u->{Source}, waitstatusmsg();
2445                     return;
2446                 }
2447             }
2448             my $work = git_rev_parse qw(HEAD);
2449             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2450             if (length $diffout) {
2451                 print STDERR
2452                     " $u->{Source}: applying patches gives different tree\n";
2453                 print STDERR $diffout if $diagnose;
2454                 return;
2455             }
2456             # OMG!
2457             $u->{Result} = $work;
2458             $result = $u;
2459         };
2460         last if $result;
2461     }
2462
2463     if (!$result) {
2464         fail <<END;
2465 Could not find or construct a suitable upstream commit.
2466 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2467 upstream commmit explicitly or provide suitable origs.
2468 END
2469     }
2470
2471     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2472
2473     ffq_check $result->{Result};
2474     snags_maybe_bail();
2475     update_head_checkout $head, $result->{Result},
2476         'convert-from-dgit-view';
2477 }
2478
2479 sub cmd_downstream_rebase_launder_v0 () {
2480     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2481     my ($base) = @ARGV;
2482     $base = git_rev_parse $base;
2483     my $old_head = get_head();
2484     my $current = $old_head;
2485     my $topmost_keep;
2486     for (;;) {
2487         if ($current eq $base) {
2488             $topmost_keep //= $current;
2489             print " $current BASE stop\n";
2490             last;
2491         }
2492         my $cl = classify $current;
2493         print " $current $cl->{Type}";
2494         my $keep = 0;
2495         my $p0 = $cl->{Parents}[0]{CommitId};
2496         my $next;
2497         if ($cl->{Type} eq 'Pseudomerge') {
2498             print " ^".($cl->{Contributor}{Ix}+1);
2499             $next = $cl->{Contributor}{CommitId};
2500         } elsif ($cl->{Type} eq 'AddPatches' or
2501                  $cl->{Type} eq 'Changelog') {
2502             print " strip";
2503             $next = $p0;
2504         } else {
2505             print " keep";
2506             $next = $p0;
2507             $keep = 1;
2508         }
2509         print "\n";
2510         if ($keep) {
2511             $topmost_keep //= $current;
2512         } else {
2513             die "to-be stripped changes not on top of the branch\n"
2514                 if $topmost_keep;
2515         }
2516         $current = $next;
2517     }
2518     if ($topmost_keep eq $old_head) {
2519         print "unchanged\n";
2520     } else {
2521         print "updating to $topmost_keep\n";
2522         update_head_checkout
2523             $old_head, $topmost_keep,
2524             'downstream-rebase-launder-v0';
2525     }
2526 }
2527
2528 getoptions_main
2529           ("bad options\n",
2530            "D+" => \$debuglevel,
2531            'noop-ok', => \$opt_noop_ok,
2532            'f=s' => \@snag_force_opts,
2533            'anchor=s' => \@opt_anchors,
2534            '--dgit=s' => \($dgit[0]),
2535            'force!',
2536            '-i:s' => sub {
2537                my ($opt,$val) = @_;
2538                badusage "git-debrebase: no cuddling to -i for git-rebase"
2539                    if length $val;
2540                die if $opt_defaultcmd_interactive; # should not happen
2541                $opt_defaultcmd_interactive = [ qw(-i) ];
2542                # This access to @ARGV is excessive familiarity with
2543                # Getopt::Long, but there isn't another sensible
2544                # approach.  '-i=s{0,}' does not work with bundling.
2545                push @$opt_defaultcmd_interactive, @ARGV;
2546                @ARGV=();
2547            },
2548            'help' => sub { print $usage_message or die $!; finish 0; },
2549            );
2550
2551 initdebug('git-debrebase ');
2552 enabledebug if $debuglevel;
2553
2554 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2555 chdir $toplevel or die "chdir $toplevel: $!";
2556
2557 $rd = fresh_playground "$playprefix/misc";
2558
2559 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2560
2561 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2562     defaultcmd_rebase();
2563 } else {
2564     my $cmd = shift @ARGV;
2565     my $cmdfn = $cmd;
2566     $cmdfn =~ y/-/_/;
2567     $cmdfn = ${*::}{"cmd_$cmdfn"};
2568
2569     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2570     $cmdfn->();
2571 }
2572
2573 finish 0;