git-debrebase

   1 #!/usr/bin/perl -w
   2 # git-debrebase
   3 # Script helping make fast-forwarding histories while still rebasing
   4 # upstream deltas when working on Debian packaging
   5 #
   6 # Copyright (C)2017,2018 Ian Jackson
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 END { $? = $Debian::Dgit::ExitStatus::desired // -1; };
  22 use Debian::Dgit::GDR;
  23 use Debian::Dgit::ExitStatus;
  24
  25 use strict;
  26
  27 use Debian::Dgit qw(:DEFAULT :playground);
  28 setup_sigwarn();
  29
  30 use Memoize;
  31 use Carp;
  32 use POSIX;
  33 use Data::Dumper;
  34 use Getopt::Long qw(:config posix_default gnu_compat bundling);
  35 use Dpkg::Version;
  36 use File::FnMatch qw(:fnmatch);
  37 use File::Copy;
  38
  39 $debugcmd_when_debuglevel = 2;
  40
  41 our ($usage_message) = <<'END';
  42 usages:
  43   git-debrebase [<options>] [--|-i <git rebase options...>]
  44   git-debrebase [<options>] status
  45   git-debrebase [<options>] prepush [--prose=...]
  46   git-debrebase [<options>] quick|conclude
  47   git-debrebase [<options>] new-upstream <new-version> [<details ...>]
  48   git-debrebase [<options>] convert-from-gbp [<upstream-commitish>]
  49   ...
  50 See git-debrebase(1), git-debrebase(5), dgit-maint-debrebase(7) (in dgit).
  51 END
  52
  53 our ($opt_force, $opt_noop_ok, @opt_anchors);
  54 our ($opt_defaultcmd_interactive, $opt_save_wreckage);
  55
  56 our $us = qw(git-debrebase);
  57
  58 our $wrecknoteprefix = 'refs/debrebase-wreckage';
  59
  60 $|=1;
  61
  62 sub badusage ($) {
  63     my ($m) = @_;
  64     print STDERR "$us: bad usage: $m\n";
  65     finish 8;
  66 }
  67
  68 sub getoptions_main {
  69     my $m = shift;
  70     local $SIG{__WARN__}; # GetOptions calls `warn' to print messages
  71     GetOptions @_ or badusage $m;
  72 }
  73 sub getoptions {
  74     my $sc = shift;
  75     getoptions_main "bad options follow \`git-debrebase $sc'", @_;
  76 }
  77
  78 sub cfg ($;$) {
  79     my ($k, $optional) = @_;
  80     local $/ = "\0";
  81     my @cmd = qw(git config -z);
  82     push @cmd, qw(--get-all) if wantarray;
  83     push @cmd, $k;
  84     my $out = cmdoutput_errok @cmd;
  85     if (!defined $out) {
  86         fail "missing required git config $k" unless $optional;
  87         return ();
  88     }
  89     my @l = split /\0/, $out;
  90     return wantarray ? @l : $l[0];
  91 }
  92
  93 memoize('cfg');
  94
  95 sub dd ($) {
  96     my ($v) = @_;
  97     my $dd = new Data::Dumper [ $v ];
  98     Terse $dd 1; Indent $dd 0; Useqq $dd 1;
  99     return Dump $dd;
 100 }
 101
 102 sub get_commit ($) {
 103     my ($objid) = @_;
 104     my $data = (git_cat_file $objid, 'commit');
 105     $data =~ m/(?<=\n)\n/ or die "$objid ($data) ?";
 106     return ($`,$');
 107 }
 108
 109 sub D_UPS ()      { 0x02; } # upstream files
 110 sub D_PAT_ADD ()  { 0x04; } # debian/patches/ extra patches at end
 111 sub D_PAT_OTH ()  { 0x08; } # debian/patches other changes
 112 sub D_DEB_CLOG () { 0x10; } # debian/ (not patches/ or changelog)
 113 sub D_DEB_OTH ()  { 0x20; } # debian/changelog
 114 sub DS_DEB ()     { D_DEB_CLOG | D_DEB_OTH; } # debian/ (not patches/)
 115
 116 our $playprefix = 'debrebase';
 117 our $rd;
 118 our $workarea;
 119
 120 our @git = qw(git);
 121 our @dgit = qw(dgit);
 122
 123 sub in_workarea ($) {
 124     my ($sub) = @_;
 125     changedir $workarea;
 126     my $r = eval { $sub->(); };
 127     { local $@; changedir $maindir; }
 128     die $@ if $@;
 129 }
 130
 131 sub fresh_workarea () {
 132     $workarea = fresh_playground "$playprefix/work";
 133     in_workarea sub { playtree_setup };
 134 }
 135
 136 sub run_ref_updates_now ($$) {
 137     my ($mrest, $updates) = @_;
 138     # @$updates is a list of lines for git-update-ref, without \ns
 139
 140     my @upd_cmd = (git_update_ref_cmd "debrebase: $mrest", qw(--stdin));
 141     debugcmd '>|', @upd_cmd;
 142     open U, "|-", @upd_cmd or die $!;
 143     foreach (@$updates) {
 144         printdebug ">= ", $_, "\n";
 145         print U $_, "\n" or die $!;
 146     }
 147     printdebug ">\$\n";
 148     close U or failedcmd @upd_cmd;
 149 }
 150
 151 our $snags_forced = 0;
 152 our $snags_tripped = 0;
 153 our $snags_summarised = 0;
 154 our @deferred_updates;
 155 our @deferred_update_messages;
 156
 157 sub merge_wreckage_cleaning ($) {
 158     my ($updates) = @_;
 159     git_for_each_ref("$wrecknoteprefix/*", sub {
 160         my ($objid,$objtype,$fullrefname,$reftail) = @_;
 161         push @$updates, "delete $fullrefname";
 162     });
 163 }
 164
 165 sub all_snags_summarised () {
 166     $snags_forced + $snags_tripped == $snags_summarised;
 167 }
 168 sub run_deferred_updates ($) {
 169     my ($mrest) = @_;
 170
 171     confess 'dangerous internal error' unless all_snags_summarised();
 172
 173     merge_wreckage_cleaning \@deferred_updates;
 174     run_ref_updates_now $mrest, \@deferred_updates;
 175     print $_, "\n" foreach @deferred_update_messages;
 176
 177     @deferred_updates = ();
 178     @deferred_update_messages = ();
 179 }
 180
 181 sub get_differs ($$) {
 182     my ($x,$y) = @_;
 183     # This resembles quiltify_trees_differ, in dgit, a bit.
 184     # But we don't care about modes, or dpkg-source-unrepresentable
 185     # changes, and we don't need the plethora of different modes.
 186     # Conversely we need to distinguish different kinds of changes to
 187     # debian/ and debian/patches/.
 188
 189     my $differs = 0;
 190
 191     my $rundiff = sub {
 192         my ($opts, $limits, $fn) = @_;
 193         my @cmd = (@git, qw(diff-tree -z --no-renames));
 194         push @cmd, @$opts;
 195         push @cmd, "$_:" foreach $x, $y;
 196         push @cmd, '--', @$limits;
 197         my $diffs = cmdoutput @cmd;
 198         foreach (split /\0/, $diffs) { $fn->(); }
 199     };
 200
 201     $rundiff->([qw(--name-only)], [], sub {
 202         $differs |= $_ eq 'debian' ? DS_DEB : D_UPS;
 203     });
 204
 205     if ($differs & DS_DEB) {
 206         $differs &= ~DS_DEB;
 207         $rundiff->([qw(--name-only -r)], [qw(debian)], sub {
 208             $differs |=
 209                 m{^debian/patches/}      ? D_PAT_OTH  :
 210                 $_ eq 'debian/changelog' ? D_DEB_CLOG :
 211                                            D_DEB_OTH;
 212         });
 213         die "mysterious debian changes $x..$y"
 214             unless $differs & (D_PAT_OTH|DS_DEB);
 215     }
 216
 217     if ($differs & D_PAT_OTH) {
 218         my $mode;
 219         $differs &= ~D_PAT_OTH;
 220         my $pat_oth = sub {
 221             $differs |= D_PAT_OTH;
 222             no warnings qw(exiting);  last;
 223         };
 224         $rundiff->([qw(--name-status -r)], [qw(debian/patches/)], sub {
 225             no warnings qw(exiting);
 226             if (!defined $mode) {
 227                 $mode = $_;  next;
 228             }
 229             die unless s{^debian/patches/}{};
 230             my $ok;
 231             if ($mode eq 'A' && !m/\.series$/s) {
 232                 $ok = 1;
 233             } elsif ($mode eq 'M' && $_ eq 'series') {
 234                 my $x_s = (git_cat_file "$x:debian/patches/series", 'blob');
 235                 my $y_s = (git_cat_file "$y:debian/patches/series", 'blob');
 236                 chomp $x_s;  $x_s .= "\n";
 237                 $ok = $x_s eq substr($y_s, 0, length $x_s);
 238             } else {
 239                 # nope
 240             }
 241             $mode = undef;
 242             $differs |= $ok ? D_PAT_ADD : D_PAT_OTH;
 243         });
 244         die "mysterious debian/patches changes $x..$y"
 245             unless $differs & (D_PAT_ADD|D_PAT_OTH);
 246     }
 247
 248     printdebug sprintf "get_differs %s %s = %#x\n", $x, $y, $differs;
 249
 250     return $differs;
 251 }
 252
 253 sub commit_pr_info ($) {
 254     my ($r) = @_;
 255     return Data::Dumper->dump([$r], [qw(commit)]);
 256 }
 257
 258 sub calculate_committer_authline () {
 259     my $c = cmdoutput @git, qw(commit-tree --no-gpg-sign -m),
 260         'DUMMY COMMIT (git-debrebase)', "HEAD:";
 261     my ($h,$m) = get_commit $c;
 262     $h =~ m/^committer .*$/m or confess "($h) ?";
 263     return $&;
 264 }
 265
 266 sub rm_subdir_cached ($) {
 267     my ($subdir) = @_;
 268     runcmd @git, qw(rm --quiet -rf --cached --ignore-unmatch), $subdir;
 269 }
 270
 271 sub read_tree_subdir ($$) {
 272     my ($subdir, $new_tree_object) = @_;
 273     rm_subdir_cached $subdir;
 274     runcmd @git, qw(read-tree), "--prefix=$subdir/", $new_tree_object;
 275 }
 276
 277 sub read_tree_debian ($) {
 278     my ($treeish) = @_;
 279     read_tree_subdir 'debian', "$treeish:debian";
 280     rm_subdir_cached 'debian/patches';
 281 }
 282
 283 sub read_tree_upstream ($;$$) {
 284     my ($treeish, $keep_patches, $tree_with_debian) = @_;
 285     # if $tree_with_debian is supplied, will use that for debian/
 286     # otherwise will save and restore it.
 287     my $debian =
 288         $tree_with_debian ? "$tree_with_debian:debian"
 289         : cmdoutput @git, qw(write-tree --prefix=debian/);
 290     runcmd @git, qw(read-tree), $treeish;
 291     read_tree_subdir 'debian', $debian;
 292     rm_subdir_cached 'debian/patches' unless $keep_patches;
 293 };
 294
 295 sub make_commit ($$) {
 296     my ($parents, $message_paras) = @_;
 297     my $tree = cmdoutput @git, qw(write-tree);
 298     my @cmd = (@git, qw(commit-tree), $tree);
 299     push @cmd, qw(-p), $_ foreach @$parents;
 300     push @cmd, qw(-m), $_ foreach @$message_paras;
 301     return cmdoutput @cmd;
 302 }
 303
 304 our @snag_force_opts;
 305 sub snag ($$;@) {
 306     my ($tag,$msg) = @_; # ignores extra args, for benefit of keycommits
 307     if (grep { $_ eq $tag } @snag_force_opts) {
 308         $snags_forced++;
 309         print STDERR "git-debrebase: snag ignored (-f$tag): $msg\n";
 310     } else {
 311         $snags_tripped++;
 312         print STDERR "git-debrebase: snag detected (-f$tag): $msg\n";
 313     }
 314 }
 315
 316 # Important: all mainline code must call snags_maybe_bail after
 317 # any point where snag might be called, but before making changes
 318 # (eg before any call to run_deferred_updates).  snags_maybe_bail
 319 # may be called more than once if necessary (but this is not ideal
 320 # because then the messages about number of snags may be confusing).
 321 sub snags_maybe_bail () {
 322     return if all_snags_summarised();
 323     if ($snags_forced) {
 324         printf STDERR
 325             "%s: snags: %d overriden by individual -f options\n",
 326             $us, $snags_forced;
 327     }
 328     if ($snags_tripped) {
 329         if ($opt_force) {
 330             printf STDERR
 331                 "%s: snags: %d overriden by global --force\n",
 332                 $us, $snags_tripped;
 333         } else {
 334             fail sprintf
 335   "%s: snags: %d blocker(s) (you could -f<tag>, or --force)",
 336                 $us, $snags_tripped;
 337         }
 338     }
 339     $snags_summarised = $snags_forced + $snags_tripped;
 340 }
 341 sub snags_maybe_bail_early () {
 342     # useful to bail out early without doing a lot of work;
 343     # not a substitute for snags_maybe_bail.
 344     snags_maybe_bail() if $snags_tripped && !$opt_force;
 345 }
 346 sub any_snags () {
 347     return $snags_forced || $snags_tripped;
 348 }
 349
 350 sub gbp_pq_export ($$$) {
 351     my ($bname, $base, $tip) = @_;
 352     # must be run in a workarea.  $bname and patch-queue/$bname
 353     # ought not to exist.  Leaves you on patch-queue/$bname with
 354     # the patches staged but not committed.
 355     printdebug "gbp_pq_export $bname $base $tip\n";
 356     runcmd @git, qw(checkout -q -b), $bname, $base;
 357     runcmd @git, qw(checkout -q -b), "patch-queue/$bname", $tip;
 358     my @gbp_cmd = (qw(gbp pq export));
 359     my $r = system shell_cmd 'exec >../gbp-pq-err 2>&1', @gbp_cmd;
 360     if ($r) {
 361         { local ($!,$?); copy('../gbp-pq-err', \*STDERR); }
 362         failedcmd @gbp_cmd;
 363     }
 364     runcmd @git, qw(add -f debian/patches) if stat_exists 'debian/patches';
 365 }
 366
 367
 368 # xxx allow merge resolution separately from laundering, before git merge
 369 #
 370 # xxx general gdr docs highlight forbidden things
 371 # xxx general gdr docs list allowable things ?
 372 # xxx general gdr docs explicitly forbid some rebase
 373 #
 374 # xxx provide a way for the user to help
 375 # xxx (eg, provide wreckage provide way to continue)
 376
 377 # later/rework?
 378 #  use git-format-patch?
 379 #  our own patch identification algorithm?
 380 #  this is an alternative strategy
 381
 382 sub merge_failed ($$) {
 383     my ($wrecknotes, $emsg) = @_;
 384     my @m;
 385     push @m, "Merge resolution failed: $emsg";
 386
 387     $opt_save_wreckage //= do {
 388         my $c = cfg 'git-debrebase.merge.save-wreckage', 1;
 389         # ^ xxx documentation
 390         $c && $c =~ m/^[1ty]/;
 391     };
 392
 393     if ($opt_save_wreckage) {
 394         my @updates;
 395         merge_wreckage_cleaning \@updates;
 396         keys %$wrecknotes;
 397         while (my ($k,$v) = each %$wrecknotes) {
 398             push @updates, "create $wrecknoteprefix/$k $v";
 399         }
 400         run_ref_updates_now "merge failed", \@updates;
 401         push @m, "Wreckage left in $wrecknoteprefix/* as requested.";
 402     }
 403     push @m, "See git-debrebase(1) section FAILED MERGES for suggestions.";
 404     # ^ xxx this section does not yet exist
 405     fail join '', map { "$_\n" } @m;
 406 }
 407
 408 sub mwrecknote ($$$) {
 409     my ($wrecknotes, $reftail, $commitish) = @_;
 410     confess unless defined $commitish;
 411     printdebug "mwrecknote $reftail $commitish\n";
 412     $wrecknotes->{$reftail} = $commitish;
 413 }
 414
 415 sub merge_series ($$$;@) {
 416     my ($newbase, $wrecknotes, $base_q, @input_qs) = @_;
 417     # $base_q{SeriesBase}  $input_qs[]{SeriesBase}
 418     # $base_q{SeriesTip}   $input_qs[]{SeriesTip}
 419     # ^ specifies several patch series (currently we only support exactly 2)
 420     # return value is a commit which is the result of
 421     # merging the two versions of the same topic branch
 422     #   $input_q[0] and $input_q[1]
 423     # with respect to the old version
 424     #   $base_q
 425     # all onto $newbase.
 426
 427     # Creates, in *_q, a key MR for its private use
 428
 429     printdebug "merge_series newbase=$newbase\n";
 430
 431     $input_qs[$_]{MR}{S} = $_ foreach (0..$#input_qs);
 432     $base_q->{MR}{S} = 'base';
 433
 434     my %prereq;
 435     # $prereq{<patch filename>}{<possible prereq}{<S>} = 1 or absent
 436     # $prereq{<patch filename>}{<possible prereq}  exists or not (later)
 437     # $prereq{<patch filename>}               exists or not (even later)
 438
 439     my $result;
 440
 441     my $mwrecknote = sub { &mwrecknote($wrecknotes, @_); };
 442
 443     local $workarea = fresh_playground "$playprefix/merge";
 444     my $seriesfile = "debian/patches/series";
 445     in_workarea sub {
 446         playtree_setup();
 447         foreach my $q ($base_q, reverse @input_qs) {
 448             my $s = $q->{MR}{S};
 449             gbp_pq_export "p-$s", $q->{SeriesBase}, $q->{SeriesTip};
 450             my @earlier;
 451             if (open S, $seriesfile) {
 452                 while (my $patch = <S>) {
 453                     chomp $patch or die $!;
 454                     $prereq{$patch} //= {};
 455                     foreach my $earlier (@earlier) {
 456                         $prereq{$patch}{$earlier}{$s}++ and die;
 457                     }
 458                     push @earlier, $patch;
 459                     stat "debian/patches/$patch" or die "$patch ?";
 460                 }
 461                 S->error and die "$seriesfile $!";
 462                 close S;
 463             } else {
 464                 die "$seriesfile $!" unless $!==ENOENT;
 465             }
 466             read_tree_upstream $newbase, 1;
 467             my $pec = make_commit [ grep { defined } $base_q->{MR}{PEC} ], [
 468                 "Convert $s to patch queue for merging",
 469                 "[git-debrebase merge-innards patch-queue import:".
 470                 " $q->{SeriesTip}]"
 471             ];
 472             printdebug "merge_series  pec $pec ";
 473             runcmd @git, qw(rm -q --ignore-unmatch --cached), $seriesfile;
 474             $pec = make_commit [ $pec ], [
 475                 "Drop series file from $s to avoid merge trouble",
 476                 "[git-debrebase merge-innards patch-queue prep:".
 477                 " $q->{SeriesTip}]"
 478             ];
 479
 480             read_tree_debian $newbase;
 481             if (@earlier) {
 482                 read_tree_subdir 'debian/patches', "$pec:debian/patches";
 483             } else {
 484                 rm_subdir_cached 'debian/patches';
 485             }
 486             $pec = make_commit [ $pec ], [
 487  "Update debian/ (excluding patches) to final to avoid re-merging",
 488  "debian/ was already merged and we need to just take that.",
 489                 "[git-debrebase merge-innards patch-queue packaging:".
 490                 " $q->{SeriesTip}]"
 491             ];
 492
 493             printdebug "pec' $pec\n";
 494             runcmd @git, qw(reset -q --hard), $pec;
 495             $q->{MR}{PEC} = $pec;
 496             $mwrecknote->("$q->{LeftRight}-patchqueue", $pec);
 497         }
 498         # now, because of reverse, we are on $input_q->{MR}{OQC}
 499         runcmd @git, qw(checkout -q -b merge);
 500         printdebug "merge_series merging...\n";
 501         my @mergecmd = (@git, qw(merge --quiet --no-edit), "p-1");
 502         debugcmd '+', @mergecmd;
 503         $!=0; $?=-1;
 504         if (system @mergecmd) {
 505             failedcmd @mergecmd;
 506         }
 507
 508         printdebug "merge_series merge ok, series...\n";
 509         # We need to construct a new series file
 510         # Firstly, resolve prereq
 511         foreach my $f (sort keys %prereq) {
 512             printdebug "merge_series  patch\t$f\t";
 513             if (!stat_exists "debian/patches/$f") {
 514                 print DEBUG " drop\n" if $debuglevel;
 515                 # git merge deleted it; that's how we tell it's not wanted
 516                 delete $prereq{$f};
 517                 next;
 518             }
 519             print DEBUG " keep\n" if $debuglevel;
 520             foreach my $g (sort keys %{ $prereq{$f} }) {
 521                 my $gfp = $prereq{$f}{$g};
 522                 printdebug "merge_series  prereq\t$f\t-> $g\t";
 523                 if (!!$gfp->{0} == !!$gfp->{1}
 524                     ? $gfp->{0}
 525                     : !$gfp->{base}) {
 526                     print DEBUG "\tkeep\n" if $debuglevel;
 527                 } else {
 528                     print DEBUG "\tdrop\n" if $debuglevel;
 529                     delete $prereq{$f}{$g};
 530                 }
 531             }
 532         }
 533
 534         my $unsat = sub {
 535             my ($f) = @_;
 536             return scalar keys %{ $prereq{$f} };
 537         };
 538
 539         my $nodate = time + 1;
 540         my %authordate;
 541         # $authordate{<patch filename>};
 542         my $authordate = sub {
 543             my ($f) = @_;
 544             $authordate{$f} //= do {
 545                 open PF, "<", "debian/patches/$f" or die "$f $!";
 546                 while (<PF>) {
 547                     return $nodate if m/^$/;
 548                     last if s{^Date: }{};
 549                 }
 550                 chomp;
 551                 return cmdoutput qw(date +%s -d), $_;
 552             };
 553         };
 554
 555         open NS, '>', $seriesfile or die $!;
 556
 557         while (keys %prereq) {
 558             my $best;
 559             foreach my $try (sort keys %prereq) {
 560                 if ($best) {
 561                     next if (
 562                              $unsat->($try) <=> $unsat->($best) or
 563                              $authordate->($try) <=> $authordate->($best) or
 564                              $try cmp $best
 565                             ) >= 0;
 566                 }
 567                 $best = $try;
 568             }
 569             printdebug "merge_series series next $best\n";
 570             print NS "$best\n" or die $!;
 571             delete $prereq{$best};
 572             foreach my $gp (values %prereq) {
 573                 delete $gp->{$best};
 574             }
 575         }
 576
 577         runcmd @git, qw(add), $seriesfile;
 578         runcmd @git, qw(commit --quiet -m), 'Merged patch queue form';
 579         $mwrecknote->('merged-patchqueue', git_rev_parse 'HEAD');
 580
 581         printdebug "merge_series series gbp pq import\n";
 582         runcmd qw(gbp pq import);
 583
 584         # OK now we are on patch-queue/merge, and we need to rebase
 585         # onto the intended parent and drop the patches from each one
 586
 587         printdebug "merge_series series ok, building...\n";
 588         my $build = $newbase;
 589         my @lcmd = (@git, qw(rev-list --reverse merge..patch-queue/merge));
 590         foreach my $c (grep /./, split /\n/, cmdoutput @lcmd) {
 591             my $commit = git_cat_file $c, 'commit';
 592             printdebug "merge_series series ok, building $c\n";
 593             read_tree_upstream $c, 0, $newbase;
 594             my $tree = cmdoutput @git, qw(write-tree);
 595             $commit =~ s{^parent (\S+)$}{parent $build}m or confess;
 596             $commit =~ s{^tree (\S+)$}{tree $tree}m      or confess;
 597             open C, ">", "../mcommit" or die $!;
 598             print C $commit or die $!;
 599             close C or die $!;
 600             $build = cmdoutput @git, qw(hash-object -w -t commit ../mcommit);
 601         }
 602         $result = $build;
 603         $mwrecknote->('merged-result', $result);
 604
 605         runcmd @git, qw(update-ref refs/heads/result), $result;
 606
 607         runcmd @git, qw(checkout -q -b debug);
 608         runcmd @git, qw(commit --allow-empty -q -m M-INDEX);
 609         runcmd @git, qw(add .);
 610         runcmd @git, qw(commit --allow-empty -q -m M-WORKTREE);
 611         my $mdebug = git_rev_parse 'HEAD';
 612         printdebug sprintf "merge_series done debug=%s\n", $mdebug;
 613         $mwrecknote->('merged-debug', $mdebug);
 614     };
 615     printdebug "merge_series returns $result\n";
 616     return $result;
 617 }
 618
 619 # classify returns an info hash like this
 620 #   CommitId => $objid
 621 #   Hdr => # commit headers, including 1 final newline
 622 #   Msg => # commit message (so one newline is dropped)
 623 #   Tree => $treeobjid
 624 #   Type => (see below)
 625 #   Parents = [ {
 626 #       Ix => $index # ie 0, 1, 2, ...
 627 #       CommitId
 628 #       Differs => return value from get_differs
 629 #       IsOrigin
 630 #       IsDggitImport => 'orig' 'tarball' 'unpatched' 'package' (as from dgit)
 631 #     } ...]
 632 #   NewMsg => # commit message, but with any [dgit import ...] edited
 633 #             # to say "[was: ...]"
 634 #
 635 # Types:
 636 #   Packaging
 637 #   Changelog
 638 #   Upstream
 639 #   AddPatches
 640 #   Mixed
 641 #
 642 #   Pseudomerge
 643 #     has additional entres in classification result
 644 #       Overwritten = [ subset of Parents ]
 645 #       Contributor = $the_remaining_Parent
 646 #
 647 #   DgitImportUnpatched
 648 #     has additional entry in classification result
 649 #       OrigParents = [ subset of Parents ]
 650 #
 651 #   Anchor
 652 #     has additional entry in classification result
 653 #       OrigParents = [ subset of Parents ]  # singleton list
 654 #
 655 #   TreatAsAnchor
 656 #
 657 #   BreakwaterStart
 658 #
 659 #   Unknown
 660 #     has additional entry in classification result
 661 #       Why => "prose"
 662
 663 sub parsecommit ($;$) {
 664     my ($objid, $p_ref) = @_;
 665     # => hash with                   CommitId Hdr Msg Tree Parents
 666     #    Parents entries have only   Ix CommitId
 667     #    $p_ref, if provided, must be [] and is used as a base for Parents
 668
 669     $p_ref //= [];
 670     die if @$p_ref;
 671
 672     my ($h,$m) = get_commit $objid;
 673
 674     my ($t) = $h =~ m/^tree (\w+)$/m or die $objid;
 675     my (@ph) = $h =~ m/^parent (\w+)$/mg;
 676
 677     my $r = {
 678         CommitId => $objid,
 679         Hdr => $h,
 680         Msg => $m,
 681         Tree => $t,
 682         Parents => $p_ref,
 683     };
 684
 685     foreach my $ph (@ph) {
 686         push @$p_ref, {
 687             Ix => scalar @$p_ref,
 688             CommitId => $ph,
 689         };
 690     }
 691
 692     return $r;
 693 }
 694
 695 sub classify ($) {
 696     my ($objid) = @_;
 697
 698     my @p;
 699     my $r = parsecommit($objid, \@p);
 700     my $t = $r->{Tree};
 701
 702     foreach my $p (@p) {
 703         $p->{Differs} = (get_differs $p->{CommitId}, $t),
 704     }
 705
 706     printdebug "classify $objid \$t=$t \@p",
 707         (map { sprintf " %s/%#x", $_->{CommitId}, $_->{Differs} } @p),
 708         "\n";
 709
 710     my $classify = sub {
 711         my ($type, @rest) = @_;
 712         $r = { %$r, Type => $type, @rest };
 713         if ($debuglevel) {
 714             printdebug " = $type ".(dd $r)."\n";
 715         }
 716         return $r;
 717     };
 718     my $unknown = sub {
 719         my ($why) = @_;
 720         $r = { %$r, Type => qw(Unknown), Why => $why };
 721         printdebug " ** Unknown\n";
 722         return $r;
 723     };
 724
 725     if (grep { $_ eq $objid } @opt_anchors) {
 726         return $classify->('TreatAsAnchor');
 727     }
 728
 729     my @identical = grep { !$_->{Differs} } @p;
 730     my ($stype, $series) = git_cat_file "$t:debian/patches/series";
 731     my $haspatches = $stype ne 'missing' && $series =~ m/^\s*[^#\n\t ]/m;
 732
 733     if ($r->{Msg} =~ m{^\[git-debrebase anchor.*\]$}m) {
 734         # multi-orig upstreams are represented with an anchor merge
 735         # from a single upstream commit which combines the orig tarballs
 736
 737         # Every anchor tagged this way must be a merge.
 738         # We are relying on the
 739         #     [git-debrebase anchor: ...]
 740         # commit message annotation in "declare" anchor merges (which
 741         # do not have any upstream changes), to distinguish those
 742         # anchor merges from ordinary pseudomerges (which we might
 743         # just try to strip).
 744         #
 745         # However, the user is going to be doing git-rebase a lot.  We
 746         # really don't want them to rewrite an anchor commit.
 747         # git-rebase trips up on merges, so that is a useful safety
 748         # catch.
 749         #
 750         # BreakwaterStart commits are also anchors in the terminology
 751         # of git-debrebase(5), but they are untagged (and always
 752         # manually generated).
 753         #
 754         # We cannot not tolerate any tagged linear commit (ie,
 755         # BreakwaterStart commits tagged `[anchor:') because such a
 756         # thing could result from an erroneous linearising raw git
 757         # rebase of a merge anchor.  That would represent a corruption
 758         # of the branch. and we want to detect and reject the results
 759         # of such corruption before it makes it out anywhere.  If we
 760         # reject it here then we avoid making the pseudomerge which
 761         # would be needed to push it.
 762
 763         my $badanchor = sub { $unknown->("git-debrebase \`anchor' but @_"); };
 764         @p == 2 or return $badanchor->("has other than two parents");
 765         $haspatches and return $badanchor->("contains debian/patches");
 766
 767         # How to decide about l/r ordering of anchors ?  git
 768         # --topo-order prefers to expand 2nd parent first.  There's
 769         # already an easy rune to look for debian/ history anyway (git log
 770         # debian/) so debian breakwater branch should be 1st parent; that
 771         # way also there's also an easy rune to look for the upstream
 772         # patches (--topo-order).
 773
 774         # Also this makes --first-parent be slightly more likely to
 775         # be useful - it makes it provide a linearised breakwater history.
 776
 777         # Of course one can say somthing like
 778         #  gitk -- ':/' ':!/debian'
 779         # to get _just_ the commits touching upstream files, and by
 780         # the TREESAME logic in git-rev-list this will leave the
 781         # breakwater into upstream at the first anchor.  But that
 782         # doesn't report debian/ changes at all.
 783
 784         # Other observations about gitk: by default, gitk seems to
 785         # produce output in a different order to git-rev-list.  I
 786         # can't seem to find this documented anywhere.  gitk
 787         # --date-order DTRT.  But, gitk always seems to put the
 788         # parents from left to right, in order, so it's easy to see
 789         # which way round a pseudomerge is.
 790
 791         $p[0]{IsOrigin} and $badanchor->("is an origin commit");
 792         $p[1]{Differs} & ~DS_DEB and
 793             $badanchor->("upstream files differ from left parent");
 794         $p[0]{Differs} & ~D_UPS and
 795             $badanchor->("debian/ differs from right parent");
 796
 797         return $classify->(qw(Anchor),
 798                            OrigParents => [ $p[1] ]);
 799     }
 800
 801     if (@p == 1) {
 802         my $d = $r->{Parents}[0]{Differs};
 803         if ($d == D_PAT_ADD) {
 804             return $classify->(qw(AddPatches));
 805         } elsif ($d & (D_PAT_ADD|D_PAT_OTH)) {
 806             return $unknown->("edits debian/patches");
 807         } elsif ($d & DS_DEB and !($d & ~DS_DEB)) {
 808             my ($ty,$dummy) = git_cat_file "$p[0]{CommitId}:debian";
 809             if ($ty eq 'tree') {
 810                 if ($d == D_DEB_CLOG) {
 811                     return $classify->(qw(Changelog));
 812                 } else {
 813                     return $classify->(qw(Packaging));
 814                 }
 815             } elsif ($ty eq 'missing') {
 816                 return $classify->(qw(BreakwaterStart));
 817             } else {
 818                 return $unknown->("parent's debian is not a directory");
 819             }
 820         } elsif ($d == D_UPS) {
 821             return $classify->(qw(Upstream));
 822         } elsif ($d & DS_DEB and $d & D_UPS and !($d & ~(DS_DEB|D_UPS))) {
 823             return $classify->(qw(Mixed));
 824         } elsif ($d == 0) {
 825             return $unknown->("no changes");
 826         } else {
 827             confess "internal error $objid ?";
 828         }
 829     }
 830     if (!@p) {
 831         return $unknown->("origin commit");
 832     }
 833
 834     if (@p == 2 && @identical == 1) {
 835         my @overwritten = grep { $_->{Differs} } @p;
 836         confess "internal error $objid ?" unless @overwritten==1;
 837         return $classify->(qw(Pseudomerge),
 838                            Overwritten => [ $overwritten[0] ],
 839                            Contributor => $identical[0]);
 840     }
 841     if (@p == 2 && @identical == 2) {
 842         my $get_t = sub {
 843             my ($ph,$pm) = get_commit $_[0]{CommitId};
 844             $ph =~ m/^committer .* (\d+) [-+]\d+$/m or die "$_->{CommitId} ?";
 845             $1;
 846         };
 847         my @bytime = @p;
 848         my $order = $get_t->($bytime[0]) <=> $get_t->($bytime[1]);
 849         if ($order > 0) { # newer first
 850         } elsif ($order < 0) {
 851             @bytime = reverse @bytime;
 852         } else {
 853             # same age, default to order made by -s ours
 854             # that is, commit was made by someone who preferred L
 855         }
 856         return $classify->(qw(Pseudomerge),
 857                            SubType => qw(Ambiguous),
 858                            Contributor => $bytime[0],
 859                            Overwritten => [ $bytime[1] ]);
 860     }
 861     foreach my $p (@p) {
 862         my ($p_h, $p_m) = get_commit $p->{CommitId};
 863         $p->{IsOrigin} = $p_h !~ m/^parent \w+$/m;
 864         ($p->{IsDgitImport},) = $p_m =~ m/^\[dgit import ([0-9a-z]+) .*\]$/m;
 865     }
 866     my @orig_ps = grep { ($_->{IsDgitImport}//'X') eq 'orig' } @p;
 867     my $m2 = $r->{Msg};
 868     if (!(grep { !$_->{IsOrigin} } @p) and
 869         (@orig_ps >= @p - 1) and
 870         $m2 =~ s{^\[(dgit import unpatched .*)\]$}{[was: $1]}m) {
 871         $r->{NewMsg} = $m2;
 872         return $classify->(qw(DgitImportUnpatched),
 873                            OrigParents => \@orig_ps);
 874     }
 875
 876     if (@p == 2 and
 877         $r->{Msg} =~ m{^\[git-debrebase merged-breakwater.*\]$}m) {
 878         # xxx ^ metadata tag needs adding to (5)
 879         return $classify->("MergedBreakwaters");
 880     }
 881     if ($r->{Msg} =~ m{^\[(git-debrebase|dgit)[: ].*\]$}m) {
 882         return $unknown->("unknown kind of merge from $1");
 883     }
 884     if (@p > 2) {
 885         return $unknown->("octopus merge");
 886     }
 887
 888     if (!$ENV{GIT_DEBREBASE_EXPERIMENTAL_MERGE}) {
 889         return $unknown->("general two-parent merge");
 890     }
 891
 892     return $classify->("VanillaMerge");
 893 }
 894
 895 sub keycommits ($;$$$$$);
 896
 897 sub mergedbreakwaters_anchor ($) {
 898     my ($cl) = @_;
 899     my $best_anchor;
 900     foreach my $p (@{ $cl->{Parents} }) {
 901         my ($panchor, $pbw) = keycommits $p->{CommitId},
 902             undef,undef,undef,undef, 1;
 903         $best_anchor = $panchor
 904             if !defined $best_anchor
 905             or is_fast_fwd $best_anchor, $panchor;
 906         fail "inconsistent anchors in merged-breakwaters $p->{CommitId}"
 907             unless is_fast_fwd $panchor, $best_anchor;
 908     }
 909     return $best_anchor;
 910 }
 911
 912 sub keycommits ($;$$$$$) {
 913     my ($head, $furniture, $unclean, $trouble, $fatal, $claimed_bw) = @_;
 914     # => ($anchor, $breakwater)
 915
 916     # $unclean->("unclean-$tagsfx", $msg, $cl)
 917     # $furniture->("unclean-$tagsfx", $msg, $cl)
 918     # $dgitimport->("unclean-$tagsfx", $msg, $cl))
 919     #   is callled for each situation or commit that
 920     #   wouldn't be found in a laundered branch
 921     # $furniture is for furniture commits such as might be found on an
 922     #   interchange branch (pseudomerge, d/patches, changelog)
 923     # $trouble is for things whnich prevent the return of
 924     #   anchor and breakwater information; if that is ignored,
 925     #   then keycommits returns (undef, undef) instead.
 926     # $fatal is for unprocessable commits, and should normally cause
 927     #    a failure.  If ignored, agaion, (undef, undef) is returned.
 928     #
 929     # If $claimed_bw, this is supposed to be a breakwater commit.
 930     #
 931     # If a callback is undef, fail is called instead.
 932     # If a callback is defined but false, the situation is ignored.
 933     # Callbacks may say:
 934     #   no warnings qw(exiting); last;
 935     # if the answer is no longer wanted.
 936
 937     my ($anchor, $breakwater);
 938     $breakwater = $head if $claimed_bw;
 939     my $clogonly;
 940     my $cl;
 941     my $found_pm;
 942     $fatal //= sub { fail $_[1]; };
 943     my $x = sub {
 944         my ($cb, $tagsfx, $mainwhy, $xwhy) = @_;
 945         my $why = $mainwhy.$xwhy;
 946         my $m = "branch needs laundering (run git-debrebase): $why";
 947         fail $m unless defined $cb;
 948         return unless $cb;
 949         $cb->("unclean-$tagsfx", $why, $cl, $mainwhy);
 950     };
 951     my $found_anchor = sub {
 952         ($anchor) = @_;
 953         $breakwater //= $clogonly;
 954         $breakwater //= $head;
 955         no warnings qw(exiting);
 956         last;
 957     };
 958     for (;;) {
 959         $cl = classify $head;
 960         my $ty = $cl->{Type};
 961         if ($ty eq 'Packaging') {
 962             $breakwater //= $clogonly;
 963             $breakwater //= $head;
 964         } elsif ($ty eq 'Changelog') {
 965             # this is going to count as the tip of the breakwater
 966             # only if it has no upstream stuff before it
 967             $clogonly //= $head;
 968         } elsif ($ty eq 'Anchor' or
 969                  $ty eq 'TreatAsAnchor' or
 970                  $ty eq 'BreakwaterStart') {
 971             $found_anchor->($head);
 972         } elsif ($ty eq 'Upstream') {
 973             $x->($unclean, 'ordering',
 974  "packaging change ($breakwater) follows upstream change"," (eg $head)")
 975                 if defined $breakwater;
 976             $clogonly = undef;
 977             $breakwater = undef;
 978         } elsif ($ty eq 'Mixed') {
 979             $x->($unclean, 'mixed',
 980                  "found mixed upstream/packaging commit"," ($head)");
 981             $clogonly = undef;
 982             $breakwater = undef;
 983         } elsif ($ty eq 'Pseudomerge' or
 984                  $ty eq 'AddPatches') {
 985             my $found_pm = 1;
 986             $x->($furniture, (lc $ty),
 987                  "found interchange bureaucracy commit ($ty)"," ($head)");
 988         } elsif ($ty eq 'DgitImportUnpatched') {
 989             if ($found_pm) {
 990                 $x->($trouble, 'dgitimport',
 991                      "found dgit dsc import"," ($head)");
 992                 return (undef,undef);
 993             } else {
 994                 $x->($fatal, 'unprocessable',
 995                      "found bare dgit dsc import with no prior history",
 996                      " ($head)");
 997                 return (undef,undef);
 998             }
 999         } elsif ($ty eq 'VanillaMerge') {
1000             $x->($trouble, 'vanillamerge',
1001                  "found vanilla merge"," ($head)");
1002             return (undef,undef);
1003         } elsif ($ty eq 'MergedBreakwaters') {
1004             $found_anchor->(mergedbreakwaters_anchor $cl);
1005         } else {
1006             $x->($fatal, 'unprocessable',
1007                  "found unprocessable commit, cannot cope: $cl->{Why}",
1008                  " ($head)");
1009             return (undef,undef);
1010         }
1011         $head = $cl->{Parents}[0]{CommitId};
1012     }
1013     return ($anchor, $breakwater);
1014 }
1015
1016 sub walk ($;$$$);
1017 sub walk ($;$$$) {
1018     my ($input,
1019         $nogenerate,$report, $report_lprefix) = @_;
1020     # => ($tip, $breakwater_tip, $last_anchor)
1021     # (or nothing, if $nogenerate)
1022
1023     printdebug "*** WALK $input ".($nogenerate//0)." ".($report//'-')."\n";
1024     $report_lprefix //= '';
1025
1026     # go through commits backwards
1027     # we generate two lists of commits to apply:
1028     # breakwater branch and upstream patches
1029     my (@brw_cl, @upp_cl, @processed);
1030     my %found;
1031     my $upp_limit;
1032     my @pseudomerges;
1033
1034     my $cl;
1035     my $xmsg = sub {
1036         my ($prose, $info) = @_;
1037         my $ms = $cl->{Msg};
1038         chomp $ms;
1039         $info //= '';
1040         $ms .= "\n\n[git-debrebase$info: $prose]\n";
1041         return (Msg => $ms);
1042     };
1043     my $rewrite_from_here = sub {
1044         my ($cl) = @_;
1045         my $sp_cl = { SpecialMethod => 'StartRewrite' };
1046         push @$cl, $sp_cl;
1047         push @processed, $sp_cl;
1048     };
1049     my $cur = $input;
1050
1051     my $prdelim = "";
1052     my $prprdelim = sub { print $report $prdelim if $report; $prdelim=""; };
1053
1054     my $prline = sub {
1055         return unless $report;
1056         print $report $prdelim, $report_lprefix, @_;
1057         $prdelim = "\n";
1058     };
1059
1060     my $bomb = sub { # usage: return $bomb->();
1061         print $report " Unprocessable" if $report;
1062         print $report " ($cl->{Why})" if $report && defined $cl->{Why};
1063         $prprdelim->();
1064         if ($nogenerate) {
1065             return (undef,undef);
1066         }
1067         fail "found unprocessable commit, cannot cope".
1068             (defined $cl->{Why} ? "; $cl->{Why}:": ':').
1069             " (commit $cur) (d.".
1070             (join ' ', map { sprintf "%#x", $_->{Differs} }
1071              @{ $cl->{Parents} }).
1072                  ")";
1073     };
1074
1075     my $build;
1076     my $breakwater;
1077
1078     my $build_start = sub {
1079         my ($msg, $parent) = @_;
1080         $prline->(" $msg");
1081         $build = $parent;
1082         no warnings qw(exiting); last;
1083     };
1084
1085     my $nomerge = sub {
1086         my ($emsg) = @_;
1087         merge_failed $cl->{MergeWreckNotes}, $emsg;
1088     };
1089
1090     my $mwrecknote = sub { &mwrecknote($cl->{MergeWreckNotes}, @_); };
1091
1092     my $last_anchor;
1093
1094     for (;;) {
1095         $cl = classify $cur;
1096         $cl->{MergeWreckNotes} //= {};
1097         my $ty = $cl->{Type};
1098         my $st = $cl->{SubType};
1099         $prline->("$cl->{CommitId} $cl->{Type}");
1100         $found{$ty. ( defined($st) ? "-$st" : '' )}++;
1101         push @processed, $cl;
1102         my $p0 = @{ $cl->{Parents} }==1 ? $cl->{Parents}[0]{CommitId} : undef;
1103         if ($ty eq 'AddPatches') {
1104             $cur = $p0;
1105             $rewrite_from_here->(\@upp_cl);
1106             next;
1107         } elsif ($ty eq 'Packaging' or $ty eq 'Changelog') {
1108             push @brw_cl, $cl;
1109             $cur = $p0;
1110             next;
1111         } elsif ($ty eq 'BreakwaterStart') {
1112             $last_anchor = $cur;
1113             $build_start->('FirstPackaging', $cur);
1114         } elsif ($ty eq 'Upstream') {
1115             push @upp_cl, $cl;
1116             $cur = $p0;
1117             next;
1118         } elsif ($ty eq 'Mixed') {
1119             my $queue = sub {
1120                 my ($q, $wh) = @_;
1121                 my $cls = { %$cl, $xmsg->("split mixed commit: $wh part") };
1122                 push @$q, $cls;
1123             };
1124             $queue->(\@brw_cl, "debian");
1125             $queue->(\@upp_cl, "upstream");
1126             $rewrite_from_here->(\@brw_cl);
1127             $cur = $p0;
1128             next;
1129         } elsif ($ty eq 'Pseudomerge') {
1130             my $contrib = $cl->{Contributor}{CommitId};
1131             print $report " Contributor=$contrib" if $report;
1132             push @pseudomerges, $cl;
1133             $rewrite_from_here->(\@upp_cl);
1134             $cur = $contrib;
1135             next;
1136         } elsif ($ty eq 'Anchor' or $ty eq 'TreatAsAnchor') {
1137             $last_anchor = $cur;
1138             $build_start->("Anchor", $cur);
1139         } elsif ($ty eq 'DgitImportUnpatched') {
1140             my $pm = $pseudomerges[-1];
1141             if (defined $pm) {
1142                 # To an extent, this is heuristic.  Imports don't have
1143                 # a useful history of the debian/ branch.  We assume
1144                 # that the first pseudomerge after an import has a
1145                 # useful history of debian/, and ignore the histories
1146                 # from later pseudomerges.  Often the first pseudomerge
1147                 # will be the dgit import of the upload to the actual
1148                 # suite intended by the non-dgit NMUer, and later
1149                 # pseudomerges may represent in-archive copies.
1150                 my $ovwrs = $pm->{Overwritten};
1151                 printf $report " PM=%s \@Overwr:%d",
1152                     $pm->{CommitId}, (scalar @$ovwrs)
1153                     if $report;
1154                 if (@$ovwrs != 1) {
1155                     printdebug "*** WALK BOMB DgitImportUnpatched\n";
1156                     return $bomb->();
1157                 }
1158                 my $ovwr = $ovwrs->[0]{CommitId};
1159                 printf $report " Overwr=%s", $ovwr if $report;
1160                 # This import has a tree which is just like a
1161                 # breakwater tree, but it has the wrong history.  It
1162                 # ought to have the previous breakwater (which the
1163                 # pseudomerge overwrote) as an ancestor.  That will
1164                 # make the history of the debian/ files correct.  As
1165                 # for the upstream version: either it's the same as
1166                 # was ovewritten (ie, same as the previous
1167                 # breakwater), in which case that history is precisely
1168                 # right; or, otherwise, it was a non-gitish upload of a
1169                 # new upstream version.  We can tell these apart by
1170                 # looking at the tree of the supposed upstream.
1171                 push @brw_cl, {
1172                     %$cl,
1173                     SpecialMethod => 'DgitImportDebianUpdate',
1174                     $xmsg->("convert dgit import: debian changes")
1175                 }, {
1176                     %$cl,
1177                     SpecialMethod => 'DgitImportUpstreamUpdate',
1178                     $xmsg->("convert dgit import: upstream update",
1179                             " anchor")
1180                 };
1181                 $prline->(" Import");
1182                 $rewrite_from_here->(\@brw_cl);
1183                 $upp_limit //= $#upp_cl; # further, deeper, patches discarded
1184                 $cur = $ovwr;
1185                 next;
1186             } else {
1187                 # Everything is from this import.  This kind of import
1188                 # is already nearly in valid breakwater format, with the
1189                 # patches as commits.  Unfortunately it contains
1190                 # debian/patches/.
1191                 printdebug "*** WALK BOMB bare dgit import\n";
1192                 $cl->{Why} = "bare dgit dsc import";
1193                 return $bomb->();
1194             }
1195             die "$ty ?";
1196         } elsif ($ty eq 'MergedBreakwaters') {
1197             $last_anchor = mergedbreakwaters_anchor $cl;
1198             $build_start->(' MergedBreakwaters', $cur);
1199             last;
1200         } elsif ($ty eq 'VanillaMerge') {
1201             # User may have merged unstitched branch(es).  We will
1202             # have now lost what ffq-prev was then (since the later
1203             # pseudomerge may introduce further changes).  The effect
1204             # of resolving such a merge is that we may have to go back
1205             # further in history to find a merge base, since the one
1206             # which was reachable via ffq-prev is no longer findable.
1207             # This is suboptimal, but if it all works we'll have done
1208             # the right thing.
1209             # xxx we should warn the user in the docs about this
1210
1211             my $ok=1;
1212             my $best_anchor;
1213             # We expect to find a dominating anchor amongst the
1214             # inputs' anchors.  That will be the new anchor.
1215             #
1216             # More complicated is finding a merge base for the
1217             # breakwaters.  We need a merge base that is a breakwater
1218             # commit.  The ancestors of breakwater commits are more
1219             # breakwater commits and possibly upstream commits and the
1220             # ancestors of those upstream.  Upstreams might have
1221             # arbitrary ancestors.  But any upstream commit U is
1222             # either included in both anchors, in which case the
1223             # earlier anchor is a better merge base than any of U's
1224             # ancestors; or U is not included in the older anchor, in
1225             # which case U is not an ancestor of the vanilla merge at
1226             # all.  So no upstream commit, nor any ancestor thereof,
1227             # is a best merge base.  As for non-breakwater Debian
1228             # commits: these are never ancestors of any breakwater.
1229             #
1230             # So any best merge base as found by git-merge-base
1231             # is a suitable breakwater anchor.  Usually there will
1232             # be only one.
1233
1234             printdebug "*** MERGE\n";
1235
1236             my @bwbcmd = (@git, qw(merge-base));
1237             my @ibcmd = (@git, qw(merge-base --all));
1238             my $might_be_in_bw = 1;
1239
1240             my $ps = $cl->{Parents};
1241
1242             $mwrecknote->('vanilla-merge', $cl->{CommitId});
1243
1244             foreach my $p (@$ps) {
1245                 $prline->(" VanillaMerge ".$p->{Ix});
1246                 $prprdelim->();
1247                 my ($ptip, $pbw, $panchor) =
1248                     walk $p->{CommitId}, 0, $report,
1249                          $report_lprefix.'  ';
1250                 $p->{Laundered} = $p->{SeriesTip} = $ptip;
1251                 $p->{Breakwater} = $p->{SeriesBase} = $pbw;
1252                 $p->{Anchor} = $panchor;
1253
1254                 my $lr = $p->{LeftRight} = (qw(left right))[$p->{Ix}];
1255                 $mwrecknote->("$lr-input", $p->{CommitId});
1256
1257                 my $mwrecknote_parent = sub {
1258                     my ($which) = @_;
1259                     $mwrecknote->("$lr-".(lc $which), $p->{$which});
1260                 };
1261                 $mwrecknote_parent->('Laundered');
1262                 $mwrecknote_parent->('Breakwater');
1263                 $mwrecknote_parent->('Anchor');
1264
1265                 $best_anchor = $panchor if
1266                     !defined $best_anchor or
1267                     is_fast_fwd $best_anchor, $panchor;
1268
1269                 printdebug " MERGE BA best=".($best_anchor//'-').
1270                     " p=$panchor\n";
1271             }
1272
1273             $mwrecknote->('result-anchor', $best_anchor);
1274
1275             foreach my $p (@$ps) {
1276                 $prline->(" VanillaMerge ".$p->{Ix});
1277                 if (!is_fast_fwd $p->{Anchor}, $best_anchor) {
1278                     $nomerge->('divergent anchors');
1279                 } elsif ($p->{Anchor} eq $best_anchor) {
1280                     print $report " SameAnchor" if $report;
1281                 } else {
1282                     print $report " SupersededAnchor" if $report;
1283                 }
1284                 if ($p->{Breakwater} eq $p->{CommitId}) {
1285                     # this parent commit was its own breakwater,
1286                     # ie it is part of the breakwater
1287                     print $report " Breakwater" if $report;
1288                 } else {
1289                     $might_be_in_bw = 0;
1290                 }
1291                 push @bwbcmd, $p->{Breakwater};
1292                 push @ibcmd, $p->{CommitId};
1293             }
1294
1295             if ($ok && $might_be_in_bw) {
1296                 # We could rewrite this to contaion the metadata
1297                 # declaring it to be MergedBreakwaters, but
1298                 # unnecessarily rewriting a merge seems unhelpful.
1299                 $prline->(" VanillaMerge MergedBreakwaters");
1300                 $last_anchor = $best_anchor;
1301                 $build_start->('MergedBreakwaters', $cur);
1302             }
1303
1304             my $bwb = cmdoutput @bwbcmd;
1305
1306             # OK, now we have a breakwater base, but we need the merge
1307             # base for the interchange branch because we need the delta
1308             # queue.
1309             #
1310             # This a the best merge base of our inputs which has the
1311             # breakwater merge base as an ancestor.
1312
1313             my @ibs =
1314                 grep /./,
1315                 split /\n/,
1316                 cmdoutput @ibcmd;
1317
1318             @ibs or confess 'internal error, expected anchor at least ?';
1319
1320             my $ib;
1321             my $ibleaf;
1322             foreach my $tibix (0..$#ibs) {
1323                 my $tib = $ibs[$tibix];
1324                 my $ff = is_fast_fwd $bwb, $tib;
1325                 my $ok = !$ff ? 'rej' : $ib ? 'extra' : 'ok';
1326                 my $tibleaf = "interchange-mbcand-$ok-$tibix";
1327                 $mwrecknote->($tibleaf, $tib);
1328                 next unless $ff;
1329                 next if $ib;
1330                 $ib = $tib;
1331                 $ibleaf = $tibleaf;
1332             }
1333
1334             $ib or $nomerge->("no suitable interchange merge base");
1335
1336             $prline->("  VanillaMerge Base");
1337             $prprdelim->();
1338             my ($btip, $bbw, $banchor) = eval {
1339                 walk $ib, 0, $report, $report_lprefix.'  ';
1340             };
1341             $nomerge->("walking interchange branch merge base ($ibleaf): ".
1342                        $@) if length $@;
1343
1344             $mwrecknote->("mergebase-laundered", $btip);
1345             $mwrecknote->("mergebase-breakwater", $bbw);
1346             $mwrecknote->("mergebase-anchor", $banchor);
1347
1348             my $ibinfo = { SeriesTip => $btip,
1349                            SeriesBase => $bbw,
1350                            Anchor => $banchor,
1351                            LeftRight => 'mergebase' };
1352
1353             $bbw eq $bwb
1354                 or $nomerge->("interchange merge-base ($ib)'s".
1355                               " breakwater ($bbw)".
1356                               " != breakwaters' merge-base ($bwb)");
1357
1358             grep { $_->{Anchor} eq $ibinfo->{Anchor} } @$ps
1359                  or $nomerge->("interchange merge-base ($ib)'s".
1360                                " anchor ($ibinfo->{SeriesBase})".
1361                                " != any merge input's anchor (".
1362                                (join ' ', map { $_->{Anchor} } @$ps).
1363                                ")");
1364
1365             $cl->{MergeInterchangeBaseInfo} = $ibinfo;
1366             $cl->{MergeBestAnchor} = $best_anchor;
1367             push @brw_cl, {
1368                 %$cl,
1369                 SpecialMethod => 'MergeCreateMergedBreakwaters',
1370                 $xmsg->('constructed from vanilla merge',
1371                         ' merged-breakwater'),
1372             };
1373             push @upp_cl, {
1374                 %$cl,
1375                 SpecialMethod => 'MergeMergeSeries',
1376             };
1377             $build_start->('MergeBreakwaters', $cur);
1378         } else {
1379             printdebug "*** WALK BOMB unrecognised\n";
1380             return $bomb->();
1381         }
1382     }
1383     $prprdelim->();
1384
1385     printdebug "*** WALK prep done cur=$cur".
1386         " brw $#brw_cl upp $#upp_cl proc $#processed pm $#pseudomerges\n";
1387
1388     return if $nogenerate;
1389
1390     # Now we build it back up again
1391
1392     fresh_workarea();
1393
1394     my $rewriting = 0;
1395
1396     my $read_tree_upstream = sub {
1397         my ($treeish) = @_;
1398         read_tree_upstream $treeish, 0, $build;
1399     };
1400
1401     $#upp_cl = $upp_limit if defined $upp_limit;
1402
1403     my $committer_authline = calculate_committer_authline();
1404
1405     printdebug "WALK REBUILD $build ".(scalar @processed)."\n";
1406
1407     confess "internal error" unless $build eq (pop @processed)->{CommitId};
1408
1409     in_workarea sub {
1410         mkdir $rd or $!==EEXIST or die $!;
1411         my $current_method;
1412         runcmd @git, qw(read-tree), $build;
1413         foreach my $cl (qw(Debian), (reverse @brw_cl),
1414                         { SpecialMethod => 'RecordBreakwaterTip' },
1415                         qw(Upstream), (reverse @upp_cl)) {
1416             if (!ref $cl) {
1417                 $current_method = $cl;
1418                 next;
1419             }
1420             my $method = $cl->{SpecialMethod} // $current_method;
1421             my @parents = ($build);
1422             my $cltree = $cl->{CommitId};
1423             printdebug "WALK BUILD ".($cltree//'undef').
1424                 " $method (rewriting=$rewriting)\n";
1425             if ($method eq 'Debian') {
1426                 read_tree_debian($cltree);
1427             } elsif ($method eq 'Upstream') {
1428                 $read_tree_upstream->($cltree);
1429             } elsif ($method eq 'StartRewrite') {
1430                 $rewriting = 1;
1431                 next;
1432             } elsif ($method eq 'RecordBreakwaterTip') {
1433                 $breakwater = $build;
1434                 next;
1435             } elsif ($method eq 'DgitImportDebianUpdate') {
1436                 read_tree_debian($cltree);
1437             } elsif ($method eq 'DgitImportUpstreamUpdate') {
1438                 confess unless $rewriting;
1439                 my $differs = (get_differs $build, $cltree);
1440                 next unless $differs & D_UPS;
1441                 $read_tree_upstream->($cltree);
1442                 push @parents, map { $_->{CommitId} } @{ $cl->{OrigParents} };
1443             } elsif ($method eq 'MergeCreateMergedBreakwaters') {
1444                 print "Found a general merge, will try to tidy it up.\n";
1445                 $rewriting = 1;
1446                 $read_tree_upstream->($cl->{MergeBestAnchor});
1447                 $read_tree_upstream->($cl->{MergeBestAnchor});
1448                 read_tree_debian($cltree);
1449                 @parents = map { $_->{Breakwater} } @{ $cl->{Parents} };
1450             } elsif ($method eq 'MergeMergeSeries') {
1451                 print "Running merge resolution for $cl->{CommitId}...\n";
1452                 $build = merge_series
1453                     $build, $cl->{MergeWreckNotes},
1454                     $cl->{MergeInterchangeBaseInfo},
1455                     @{ $cl->{Parents} };
1456                 $last_anchor = $cl->{MergeBestAnchor};
1457
1458                 # Check for mismerges:
1459                 my $check = sub {
1460                     my ($against, $allow, $what) = @_;
1461                     my $differs = get_differs $build, $against;
1462                     $nomerge->(sprintf
1463        "merge misresolved: %s are not the same (%s %s d.%#x)",
1464                                $what, $against, $build, $differs)
1465                         if $differs & ~($allow | D_PAT_ADD);
1466                 };
1467
1468                 # Breakwater changes which were in each side of the
1469                 # merge will have been incorporated into the
1470                 # MergeCreateMergedBreakwaters output.  Because the
1471                 # upstream series was rebased onto the new breakwater,
1472                 # so should all of the packaging changes which were in
1473                 # the input.
1474                 $check->($input, D_UPS, 'debian files');
1475
1476                 # Upstream files are merge_series, which ought to
1477                 # have been identical to the original merge.
1478                 $check->($cl->{CommitId}, DS_DEB, 'upstream files');
1479
1480                 print "Merge resolution successful.\n";
1481                 next;
1482             } else {
1483                 confess "$method ?";
1484             }
1485             if (!$rewriting) {
1486                 my $procd = (pop @processed) // 'UNDEF';
1487                 if ($cl ne $procd) {
1488                     $rewriting = 1;
1489                     printdebug "WALK REWRITING NOW cl=$cl procd=$procd\n";
1490                 }
1491             }
1492             my $newtree = cmdoutput @git, qw(write-tree);
1493             my $ch = $cl->{Hdr};
1494             $ch =~ s{^tree .*}{tree $newtree}m or confess "$ch ?";
1495             $ch =~ s{^parent .*\n}{}mg;
1496             $ch =~ s{(?=^author)}{
1497                 join '', map { "parent $_\n" } @parents
1498             }me or confess "$ch ?";
1499             if ($rewriting) {
1500                 $ch =~ s{^committer .*$}{$committer_authline}m
1501                     or confess "$ch ?";
1502             }
1503             my $cf = "$rd/m$rewriting";
1504             open CD, ">", $cf or die $!;
1505             print CD $ch, "\n", $cl->{Msg} or die $!;
1506             close CD or die $!;
1507             my @cmd = (@git, qw(hash-object));
1508             push @cmd, qw(-w) if $rewriting;
1509             push @cmd, qw(-t commit), $cf;
1510             my $newcommit = cmdoutput @cmd;
1511             confess "$ch ?" unless $rewriting or $newcommit eq $cl->{CommitId};
1512             $build = $newcommit;
1513             if (grep { $method eq $_ } qw(DgitImportUpstreamUpdate)) {
1514                 $last_anchor = $cur;
1515             }
1516         }
1517     };
1518
1519     my $final_check = get_differs $build, $input;
1520     die sprintf "internal error %#x %s %s", $final_check, $input, $build
1521         if $final_check & ~D_PAT_ADD;
1522
1523     my @r = ($build, $breakwater, $last_anchor);
1524     printdebug "*** WALK RETURN @r\n";
1525     return @r
1526 }
1527
1528 sub get_head () {
1529     git_check_unmodified();
1530     return git_rev_parse qw(HEAD);
1531 }
1532
1533 sub update_head ($$$) {
1534     my ($old, $new, $mrest) = @_;
1535     push @deferred_updates, "update HEAD $new $old";
1536     run_deferred_updates $mrest;
1537 }
1538
1539 sub update_head_checkout ($$$) {
1540     my ($old, $new, $mrest) = @_;
1541     update_head $old, $new, $mrest;
1542     runcmd @git, qw(reset --hard);
1543 }
1544
1545 sub update_head_postlaunder ($$$) {
1546     my ($old, $tip, $reflogmsg) = @_;
1547     return if $tip eq $old;
1548     print "git-debrebase: laundered (head was $old)\n";
1549     update_head $old, $tip, $reflogmsg;
1550     # no tree changes except debian/patches
1551     runcmd @git, qw(rm --quiet --ignore-unmatch -rf debian/patches);
1552 }
1553
1554 sub currently_rebasing() {
1555     foreach (qw(rebase-merge rebase-apply)) {
1556         return 1 if stat_exists "$maindir_gitdir/$_";
1557     }
1558     return 0;
1559 }
1560
1561 sub bail_if_rebasing() {
1562     fail "you are in the middle of a git-rebase already"
1563         if currently_rebasing();
1564 }
1565
1566 sub do_launder_head ($) {
1567     my ($reflogmsg) = @_;
1568     my $old = get_head();
1569     record_ffq_auto();
1570     my ($tip,$breakwater) = walk $old;
1571     snags_maybe_bail();
1572     update_head_postlaunder $old, $tip, $reflogmsg;
1573     return ($tip,$breakwater);
1574 }
1575
1576 sub cmd_launder_v0 () {
1577     badusage "no arguments to launder-v0 allowed" if @ARGV;
1578     my $old = get_head();
1579     my ($tip,$breakwater,$last_anchor) = walk $old;
1580     update_head_postlaunder $old, $tip, 'launder';
1581     printf "# breakwater tip\n%s\n", $breakwater;
1582     printf "# working tip\n%s\n", $tip;
1583     printf "# last anchor\n%s\n", $last_anchor;
1584 }
1585
1586 sub defaultcmd_rebase () {
1587     push @ARGV, @{ $opt_defaultcmd_interactive // [] };
1588     my ($tip,$breakwater) = do_launder_head 'launder for rebase';
1589     runcmd @git, qw(rebase), @ARGV, $breakwater if @ARGV;
1590 }
1591
1592 sub cmd_analyse () {
1593     badusage "analyse does not support any options"
1594         if @ARGV and $ARGV[0] =~ m/^-/;
1595     badusage "too many arguments to analyse" if @ARGV>1;
1596     my ($old) = @ARGV;
1597     if (defined $old) {
1598         $old = git_rev_parse $old;
1599     } else {
1600         $old = git_rev_parse 'HEAD';
1601     }
1602     my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
1603     STDOUT->error and die $!;
1604 }
1605
1606 sub ffq_prev_branchinfo () {
1607     my $current = git_get_symref();
1608     return gdr_ffq_prev_branchinfo($current);
1609 }
1610
1611 sub ffq_check ($;$$) {
1612     # calls $ff and/or $notff zero or more times
1613     # then returns either (status,message) where status is
1614     #    exists
1615     #    detached
1616     #    weird-symref
1617     #    notbranch
1618     # or (undef,undef, $ffq_prev,$gdrlast)
1619     # $ff and $notff are called like this:
1620     #   $ff->("message for stdout\n");
1621     #   $notff->('snag-name', $message);
1622     # normally $currentval should be HEAD
1623     my ($currentval, $ff, $notff) =@_;
1624
1625     $ff //= sub { print $_[0] or die $!; };
1626     $notff //= \&snag;
1627
1628     my ($status, $message, $current, $ffq_prev, $gdrlast)
1629         = ffq_prev_branchinfo();
1630     return ($status, $message) unless $status eq 'branch';
1631
1632     my $exists = git_get_ref $ffq_prev;
1633     return ('exists',"$ffq_prev already exists") if $exists;
1634
1635     return ('not-branch', 'HEAD symref is not to refs/heads/')
1636         unless $current =~ m{^refs/heads/};
1637     my $branch = $';
1638
1639     my @check_specs = split /\;/, (cfg "branch.$branch.ffq-ffrefs",1) // '*';
1640     my %checked;
1641
1642     printdebug "ffq check_specs @check_specs\n";
1643
1644     my $check = sub {
1645         my ($lrref, $desc) = @_;
1646         printdebug "ffq might check $lrref ($desc)\n";
1647         my $invert;
1648         for my $chk (@check_specs) {
1649             my $glob = $chk;
1650             $invert = $glob =~ s{^[!^]}{};
1651             last if fnmatch $glob, $lrref;
1652         }
1653         return if $invert;
1654         my $lrval = git_get_ref $lrref;
1655         return unless length $lrval;
1656
1657         if (is_fast_fwd $lrval, $currentval) {
1658             $ff->("OK, you are ahead of $lrref\n");
1659             $checked{$lrref} = 1;
1660         } elsif (is_fast_fwd $currentval, $lrval) {
1661             $checked{$lrref} = -1;
1662             $notff->('behind', "you are behind $lrref, divergence risk");
1663         } else {
1664             $checked{$lrref} = -1;
1665             $notff->('diverged', "you have diverged from $lrref");
1666         }
1667     };
1668
1669     my $merge = cfg "branch.$branch.merge",1;
1670     if (defined $merge and $merge =~ m{^refs/heads/}) {
1671         my $rhs = $';
1672         printdebug "ffq merge $rhs\n";
1673         my $check_remote = sub {
1674             my ($remote, $desc) = @_;
1675             printdebug "ffq check_remote ".($remote//'undef')." $desc\n";
1676             return unless defined $remote;
1677             $check->("refs/remotes/$remote/$rhs", $desc);
1678         };
1679         $check_remote->((scalar cfg "branch.$branch.remote",1),
1680                         'remote fetch/merge branch');
1681         $check_remote->((scalar cfg "branch.$branch.pushRemote",1) //
1682                         (scalar cfg "branch.$branch.pushDefault",1),
1683                         'remote push branch');
1684     }
1685     if ($branch =~ m{^dgit/}) {
1686         $check->("refs/remotes/dgit/$branch", 'remote dgit branch');
1687     } elsif ($branch =~ m{^master$}) {
1688         $check->("refs/remotes/dgit/dgit/sid", 'remote dgit branch for sid');
1689     }
1690     return (undef, undef, $ffq_prev, $gdrlast);
1691 }
1692
1693 sub record_ffq_prev_deferred () {
1694     # => ('status', "message")
1695     # 'status' may be
1696     #    deferred          message is undef
1697     #    exists
1698     #    detached
1699     #    weird-symref
1700     #    notbranch
1701     # if not ff from some branch we should be ff from, is an snag
1702     # if "deferred", will have added something about that to
1703     #   @deferred_update_messages, and also maybe printed (already)
1704     #   some messages about ff checks
1705     bail_if_rebasing();
1706     my $currentval = get_head();
1707
1708     my ($status,$message, $ffq_prev,$gdrlast) = ffq_check $currentval;
1709     return ($status,$message) if defined $status;
1710
1711     snags_maybe_bail();
1712
1713     push @deferred_updates, "update $ffq_prev $currentval $git_null_obj";
1714     push @deferred_updates, "delete $gdrlast";
1715     push @deferred_update_messages, "Recorded previous head for preservation";
1716     return ('deferred', undef);
1717 }
1718
1719 sub record_ffq_auto () {
1720     my ($status, $message) = record_ffq_prev_deferred();
1721     if ($status eq 'deferred' || $status eq 'exists') {
1722     } else {
1723         snag $status, "could not record ffq-prev: $message";
1724         snags_maybe_bail();
1725     }
1726 }
1727
1728 sub ffq_prev_info () {
1729     bail_if_rebasing();
1730     # => ($ffq_prev, $gdrlast, $ffq_prev_commitish)
1731     my ($status, $message, $current, $ffq_prev, $gdrlast)
1732         = ffq_prev_branchinfo();
1733     if ($status ne 'branch') {
1734         snag $status, "could not check ffq-prev: $message";
1735         snags_maybe_bail();
1736     }
1737     my $ffq_prev_commitish = $ffq_prev && git_get_ref $ffq_prev;
1738     return ($ffq_prev, $gdrlast, $ffq_prev_commitish);
1739 }
1740
1741 sub stitch ($$$$$) {
1742     my ($old_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose) = @_;
1743
1744     push @deferred_updates, "delete $ffq_prev $ffq_prev_commitish";
1745
1746     if (is_fast_fwd $old_head, $ffq_prev_commitish) {
1747         my $differs = get_differs $old_head, $ffq_prev_commitish;
1748         unless ($differs & ~D_PAT_ADD) {
1749             # ffq-prev is ahead of us, and the only tree changes it has
1750             # are possibly addition of things in debian/patches/.
1751             # Just wind forwards rather than making a pointless pseudomerge.
1752             push @deferred_updates,
1753                 "update $gdrlast $ffq_prev_commitish $git_null_obj";
1754             update_head_checkout $old_head, $ffq_prev_commitish,
1755                 "stitch (fast forward)";
1756             return;
1757         }
1758     }
1759     fresh_workarea();
1760     # We make pseudomerges with L as the contributing parent.
1761     # This makes git rev-list --first-parent work properly.
1762     my $new_head = make_commit [ $old_head, $ffq_prev ], [
1763         'Declare fast forward / record previous work',
1764         "[git-debrebase pseudomerge: $prose]",
1765     ];
1766     push @deferred_updates, "update $gdrlast $new_head $git_null_obj";
1767     update_head $old_head, $new_head, "stitch: $prose";
1768 }
1769
1770 sub do_stitch ($;$) {
1771     my ($prose, $unclean) = @_;
1772
1773     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
1774     if (!$ffq_prev_commitish) {
1775         fail "No ffq-prev to stitch." unless $opt_noop_ok;
1776         return;
1777     }
1778     my $dangling_head = get_head();
1779
1780     keycommits $dangling_head, $unclean,$unclean,$unclean;
1781     snags_maybe_bail();
1782
1783     stitch($dangling_head, $ffq_prev, $gdrlast, $ffq_prev_commitish, $prose);
1784 }
1785
1786 sub upstream_commitish_search ($$) {
1787     my ($upstream_version, $tried) = @_;
1788     # todo: at some point maybe use git-deborig to do this
1789     foreach my $tagpfx ('', 'v', 'upstream/') {
1790         my $tag = $tagpfx.(dep14_version_mangle $upstream_version);
1791         my $new_upstream = git_get_ref "refs/tags/$tag";
1792         push @$tried, $tag;
1793         return $new_upstream if length $new_upstream;
1794     }
1795 }
1796
1797 sub resolve_upstream_version ($$) {
1798     my ($new_upstream, $upstream_version) = @_;
1799
1800     if (!defined $new_upstream) {
1801         my @tried;
1802         $new_upstream = upstream_commitish_search $upstream_version, \@tried;
1803         if (!length $new_upstream) {
1804             fail "Could not determine appropriate upstream commitish.\n".
1805                 " (Tried these tags: @tried)\n".
1806                 " Check version, and specify upstream commitish explicitly.";
1807         }
1808     }
1809     $new_upstream = git_rev_parse $new_upstream;
1810
1811     return $new_upstream;
1812 }
1813
1814 sub cmd_new_upstream () {
1815     # automatically and unconditionally launders before rebasing
1816     # if rebase --abort is used, laundering has still been done
1817
1818     my %pieces;
1819
1820     badusage "need NEW-VERSION [UPS-COMMITTISH]" unless @ARGV >= 1;
1821
1822     # parse args - low commitment
1823     my $spec_version = shift @ARGV;
1824     my $new_version = (new Dpkg::Version $spec_version, check => 1);
1825     fail "bad version number \`$spec_version'" unless defined $new_version;
1826     if ($new_version->is_native()) {
1827         $new_version = (new Dpkg::Version "$spec_version-1", check => 1);
1828     }
1829
1830     my $new_upstream = shift @ARGV;
1831     my $new_upstream_version = upstreamversion  $new_version;
1832     $new_upstream =
1833         resolve_upstream_version $new_upstream, $new_upstream_version;
1834
1835     record_ffq_auto();
1836
1837     my $piece = sub {
1838         my ($n, @x) = @_; # may be ''
1839         my $pc = $pieces{$n} //= {
1840             Name => $n,
1841             Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
1842         };
1843         while (my $k = shift @x) { $pc->{$k} = shift @x; }
1844         $pc;
1845     };
1846
1847     my @newpieces;
1848     my $newpiece = sub {
1849         my ($n, @x) = @_; # may be ''
1850         my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
1851         push @newpieces, $pc;
1852     };
1853
1854     $newpiece->('',
1855         OldIx => 0,
1856         New => $new_upstream,
1857     );
1858     while (@ARGV && $ARGV[0] !~ m{^-}) {
1859         my $n = shift @ARGV;
1860
1861         badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
1862             unless @ARGV && $ARGV[0] !~ m{^-};
1863
1864         my $c = git_rev_parse shift @ARGV;
1865         die unless $n =~ m/^$extra_orig_namepart_re$/;
1866         $newpiece->($n, New => $c);
1867     }
1868
1869     # now we need to investigate the branch this generates the
1870     # laundered version but we don't switch to it yet
1871     my $old_head = get_head();
1872     my ($old_laundered_tip,$old_bw,$old_anchor) = walk $old_head;
1873
1874     my $old_bw_cl = classify $old_bw;
1875     my $old_anchor_cl = classify $old_anchor;
1876     my $old_upstream;
1877     if (!$old_anchor_cl->{OrigParents}) {
1878         snag 'anchor-treated',
1879             'old anchor is recognised due to --anchor, cannot check upstream';
1880     } else {
1881         $old_upstream = parsecommit
1882             $old_anchor_cl->{OrigParents}[0]{CommitId};
1883         $piece->('', Old => $old_upstream->{CommitId});
1884     }
1885
1886     if ($old_upstream && $old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
1887         if ($old_upstream->{Msg} =~
1888  m{^\[git-debrebase upstream-combine (\.(?: $extra_orig_namepart_re)+)\:.*\]$}m
1889            ) {
1890             my @oldpieces = (split / /, $1);
1891             my $old_n_parents = scalar @{ $old_upstream->{Parents} };
1892             if ($old_n_parents != @oldpieces &&
1893                 $old_n_parents != @oldpieces + 1) {
1894                 snag 'upstream-confusing', sprintf
1895                     "previous upstream combine %s".
1896                     " mentions %d pieces (each implying one parent)".
1897                     " but has %d parents".
1898                     " (one per piece plus maybe a previous combine)",
1899                     $old_upstream->{CommitId},
1900                     (scalar @oldpieces),
1901                     $old_n_parents;
1902             } elsif ($oldpieces[0] ne '.') {
1903                 snag 'upstream-confusing', sprintf
1904                     "previous upstream combine %s".
1905                     " first piece is not \`.'",
1906                     $oldpieces[0];
1907             } else {
1908                 $oldpieces[0] = '';
1909                 foreach my $i (0..$#oldpieces) {
1910                     my $n = $oldpieces[$i];
1911                     my $hat = 1 + $i + ($old_n_parents - @oldpieces);
1912                     $piece->($n, Old => $old_upstream->{CommitId}.'^'.$hat);
1913                 }
1914             }
1915         } else {
1916             snag 'upstream-confusing',
1917                 "previous upstream $old_upstream->{CommitId} is from".
1918                " git-debrebase but not an \`upstream-combine' commit";
1919         }
1920     }
1921
1922     foreach my $pc (values %pieces) {
1923         if (!$old_upstream) {
1924             # we have complained already
1925         } elsif (!$pc->{Old}) {
1926             snag 'upstream-new-piece',
1927                 "introducing upstream piece \`$pc->{Name}'";
1928         } elsif (!$pc->{New}) {
1929             snag 'upstream-rm-piece',
1930                 "dropping upstream piece \`$pc->{Name}'";
1931         } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
1932             snag 'upstream-not-ff',
1933                 "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
1934         }
1935     }
1936
1937     printdebug "%pieces = ", (dd \%pieces), "\n";
1938     printdebug "\@newpieces = ", (dd \@newpieces), "\n";
1939
1940     snags_maybe_bail();
1941
1942     my $new_bw;
1943
1944     fresh_workarea();
1945     in_workarea sub {
1946         my @upstream_merge_parents;
1947
1948         if (!any_snags()) {
1949             push @upstream_merge_parents, $old_upstream->{CommitId};
1950         }
1951
1952         foreach my $pc (@newpieces) { # always has '' first
1953             if ($pc->{Name}) {
1954                 read_tree_subdir $pc->{Name}, $pc->{New};
1955             } else {
1956                 runcmd @git, qw(read-tree), $pc->{New};
1957             }
1958             push @upstream_merge_parents, $pc->{New};
1959         }
1960
1961         # index now contains the new upstream
1962
1963         if (@newpieces > 1) {
1964             # need to make the upstream subtree merge commit
1965             $new_upstream = make_commit \@upstream_merge_parents,
1966                 [ "Combine upstreams for $new_upstream_version",
1967  ("[git-debrebase upstream-combine . ".
1968  (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
1969  ": new upstream]"),
1970                 ];
1971         }
1972
1973         # $new_upstream is either the single upstream commit, or the
1974         # combined commit we just made.  Either way it will be the
1975         # "upstream" parent of the anchor merge.
1976
1977         read_tree_subdir 'debian', "$old_bw:debian";
1978
1979         # index now contains the anchor merge contents
1980         $new_bw = make_commit [ $old_bw, $new_upstream ],
1981             [ "Update to upstream $new_upstream_version",
1982  "[git-debrebase anchor: new upstream $new_upstream_version, merge]",
1983             ];
1984
1985         my $clogsignoff = cmdoutput qw(git show),
1986             '--pretty=format:%an <%ae>  %aD',
1987             $new_bw;
1988
1989         # Now we have to add a changelog stanza so the Debian version
1990         # is right.
1991         die if unlink "debian";
1992         die $! unless $!==ENOENT or $!==ENOTEMPTY;
1993         unlink "debian/changelog" or $!==ENOENT or die $!;
1994         mkdir "debian" or die $!;
1995         open CN, ">", "debian/changelog" or die $!;
1996         my $oldclog = git_cat_file ":debian/changelog";
1997         $oldclog =~ m/^($package_re) \(\S+\) / or
1998             fail "cannot parse old changelog to get package name";
1999         my $p = $1;
2000         print CN <<END, $oldclog or die $!;
2001 $p ($new_version) UNRELEASED; urgency=medium
2002
2003   * Update to new upstream version $new_upstream_version.
2004
2005  -- $clogsignoff
2006
2007 END
2008         close CN or die $!;
2009         runcmd @git, qw(update-index --add --replace), 'debian/changelog';
2010
2011         # Now we have the final new breakwater branch in the index
2012         $new_bw = make_commit [ $new_bw ],
2013             [ "Update changelog for new upstream $new_upstream_version",
2014               "[git-debrebase: new upstream $new_upstream_version, changelog]",
2015             ];
2016     };
2017
2018     # we have constructed the new breakwater. we now need to commit to
2019     # the laundering output, because git-rebase can't easily be made
2020     # to make a replay list which is based on some other branch
2021
2022     update_head_postlaunder $old_head, $old_laundered_tip,
2023         'launder for new upstream';
2024
2025     my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
2026     local $ENV{GIT_REFLOG_ACTION} = git_reflog_action_msg
2027         "debrebase new-upstream $new_version: rebase";
2028     runcmd @cmd;
2029     # now it's for the user to sort out
2030 }
2031
2032 sub cmd_record_ffq_prev () {
2033     badusage "no arguments allowed" if @ARGV;
2034     my ($status, $msg) = record_ffq_prev_deferred();
2035     if ($status eq 'exists' && $opt_noop_ok) {
2036         print "Previous head already recorded\n" or die $!;
2037     } elsif ($status eq 'deferred') {
2038         run_deferred_updates 'record-ffq-prev';
2039     } else {
2040         fail "Could not preserve: $msg";
2041     }
2042 }
2043
2044 sub cmd_anchor () {
2045     badusage "no arguments allowed" if @ARGV;
2046     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2047     print "$bw\n" or die $!;
2048 }
2049
2050 sub cmd_breakwater () {
2051     badusage "no arguments allowed" if @ARGV;
2052     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'), 0,0;
2053     print "$bw\n" or die $!;
2054 }
2055
2056 sub cmd_status () {
2057     badusage "no arguments allowed" if @ARGV;
2058
2059     # todo: gdr status should print divergence info
2060     # todo: gdr status should print upstream component(s) info
2061     # todo: gdr should leave/maintain some refs with this kind of info ?
2062
2063     my $oldest = { Badness => 0 };
2064     my $newest;
2065     my $note = sub {
2066         my ($badness, $ourmsg, $snagname, $dummy, $cl, $kcmsg) = @_;
2067         if ($oldest->{Badness} < $badness) {
2068             $oldest = $newest = undef;
2069         }
2070         $oldest = {
2071                    Badness => $badness,
2072                    CommitId => $cl->{CommitId},
2073                    OurMsg => $ourmsg,
2074                    KcMsg => $kcmsg,
2075                   };
2076         $newest //= $oldest;
2077     };
2078     my ($anchor, $bw) = keycommits +(git_rev_parse 'HEAD'),
2079         sub { $note->(1, 'branch contains furniture (not laundered)', @_); },
2080         sub { $note->(2, 'branch is unlaundered', @_); },
2081         sub { $note->(3, 'branch needs laundering', @_); },
2082         sub { $note->(4, 'branch not in git-debrebase form', @_); };
2083
2084     my $prcommitinfo = sub {
2085         my ($cid) = @_;
2086         flush STDOUT or die $!;
2087         runcmd @git, qw(--no-pager log -n1),
2088             '--pretty=format:    %h %s%n',
2089             $cid;
2090     };
2091
2092     print "current branch contents, in git-debrebase terms:\n";
2093     if (!$oldest->{Badness}) {
2094         print "  branch is laundered\n";
2095     } else {
2096         print "  $oldest->{OurMsg}\n";
2097         my $printed = '';
2098         foreach my $info ($oldest, $newest) {
2099             my $cid = $info->{CommitId};
2100             next if $cid eq $printed;
2101             $printed = $cid;
2102             print "  $info->{KcMsg}\n";
2103             $prcommitinfo->($cid);
2104         }
2105     }
2106
2107     my $prab = sub {
2108         my ($cid, $what) = @_;
2109         if (!defined $cid) {
2110             print "  $what is not well-defined\n";
2111         } else {
2112             print "  $what\n";
2113             $prcommitinfo->($cid);
2114         }
2115     };
2116     print "key git-debrebase commits:\n";
2117     $prab->($anchor, 'anchor');
2118     $prab->($bw, 'breakwater');
2119
2120     my ($ffqstatus, $ffq_msg, $current, $ffq_prev, $gdrlast) =
2121         ffq_prev_branchinfo();
2122
2123     print "branch and ref status, in git-debrebase terms:\n";
2124     if ($ffq_msg) {
2125         print "  $ffq_msg\n";
2126     } else {
2127         $ffq_prev = git_get_ref $ffq_prev;
2128         $gdrlast = git_get_ref $gdrlast;
2129         if ($ffq_prev) {
2130             print "  unstitched; previous tip was:\n";
2131             $prcommitinfo->($ffq_prev);
2132         } elsif (!$gdrlast) {
2133             print "  stitched? (no record of git-debrebase work)\n";
2134         } elsif (is_fast_fwd $gdrlast, 'HEAD') {
2135             print "  stitched\n";
2136         } else {
2137             print "  not git-debrebase (diverged since last stitch)\n"
2138         }
2139     }
2140     print "you are currently rebasing\n" if currently_rebasing();
2141 }
2142
2143 sub cmd_stitch () {
2144     my $prose = 'stitch';
2145     getoptions("stitch",
2146                'prose=s', \$prose);
2147     badusage "no arguments allowed" if @ARGV;
2148     do_stitch $prose, 0;
2149 }
2150 sub cmd_prepush () { cmd_stitch(); }
2151
2152 sub cmd_quick () {
2153     badusage "no arguments allowed" if @ARGV;
2154     do_launder_head 'launder for git-debrebase quick';
2155     do_stitch 'quick';
2156 }
2157
2158 sub cmd_conclude () {
2159     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2160     if (!$ffq_prev_commitish) {
2161         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2162         return;
2163     }
2164     my $dangling_head = get_head();
2165
2166     badusage "no arguments allowed" if @ARGV;
2167     do_launder_head 'launder for git-debrebase quick';
2168     do_stitch 'quick';
2169 }
2170
2171 sub cmd_scrap () {
2172     if (currently_rebasing()) {
2173         runcmd @git, qw(rebase --abort);
2174     }
2175     my ($ffq_prev, $gdrlast, $ffq_prev_commitish) = ffq_prev_info();
2176     if (!$ffq_prev_commitish) {
2177         fail "No ongoing git-debrebase session." unless $opt_noop_ok;
2178         finish 0;
2179     }
2180     my $scrapping_head = get_head();
2181     badusage "no arguments allowed" if @ARGV;
2182     push @deferred_updates,
2183         "update $gdrlast $ffq_prev_commitish $git_null_obj",
2184         "update $ffq_prev $git_null_obj $ffq_prev_commitish";
2185     snags_maybe_bail();
2186     update_head_checkout $scrapping_head, $ffq_prev_commitish, "scrap";
2187 }
2188
2189 sub make_patches_staged ($) {
2190     my ($head) = @_;
2191     # Produces the patches that would result from $head if it were
2192     # laundered.
2193     my ($secret_head, $secret_bw, $last_anchor) = walk $head;
2194     fresh_workarea();
2195     in_workarea sub {
2196         gbp_pq_export 'bw', $secret_bw, $secret_head;
2197     };
2198 }
2199
2200 sub make_patches ($) {
2201     my ($head) = @_;
2202     keycommits $head, 0, \&snag;
2203     make_patches_staged $head;
2204     my $out;
2205     in_workarea sub {
2206         my $ptree = cmdoutput @git, qw(write-tree --prefix=debian/patches/);
2207         runcmd @git, qw(read-tree), $head;
2208         read_tree_subdir 'debian/patches', $ptree;
2209         $out = make_commit [$head], [
2210             'Commit patch queue (exported by git-debrebase)',
2211             '[git-debrebase: export and commit patches]',
2212         ];
2213     };
2214     return $out;
2215 }
2216
2217 sub cmd_make_patches () {
2218     my $opt_quiet_would_amend;
2219     getoptions("make-patches",
2220                'quiet-would-amend!', \$opt_quiet_would_amend);
2221     badusage "no arguments allowed" if @ARGV;
2222     bail_if_rebasing();
2223     my $old_head = get_head();
2224     my $new = make_patches $old_head;
2225     my $d = get_differs $old_head, $new;
2226     if ($d == 0) {
2227         fail "No (more) patches to export." unless $opt_noop_ok;
2228         return;
2229     } elsif ($d == D_PAT_ADD) {
2230         snags_maybe_bail();
2231         update_head_checkout $old_head, $new, 'make-patches';
2232     } else {
2233         print STDERR failmsg
2234             "Patch export produced patch amendments".
2235             " (abandoned output commit $new).".
2236             "  Try laundering first."
2237             unless $opt_quiet_would_amend;
2238         finish 7;
2239     }
2240 }
2241
2242 sub cmd_convert_from_gbp () {
2243     badusage "want only 1 optional argument, the upstream git commitish"
2244         unless @ARGV<=1;
2245
2246     my $clogp = parsechangelog();
2247     my $version = $clogp->{'Version'}
2248         // die "missing Version from changelog";
2249
2250     my ($upstream_spec) = @ARGV;
2251
2252     my $upstream_version = upstreamversion $version;
2253     my $upstream =
2254         resolve_upstream_version($upstream_spec, $upstream_version);
2255
2256     my $old_head = get_head();
2257
2258     my $upsdiff = get_differs $upstream, $old_head;
2259     if ($upsdiff & D_UPS) {
2260         runcmd @git, qw(--no-pager diff --stat),
2261             $upstream, $old_head,
2262             qw( -- :!/debian :/);
2263         fail <<END;
2264 upstream ($upstream_spec) and HEAD are not
2265 identical in upstream files.  See diffstat above, or run
2266   git diff $upstream_spec HEAD -- :!/debian :/
2267 END
2268     }
2269
2270     if (!is_fast_fwd $upstream, $old_head) {
2271         snag 'upstream-not-ancestor',
2272             "upstream ($upstream) is not an ancestor of HEAD";
2273     } else {
2274         my $wrong = cmdoutput
2275             (@git, qw(rev-list --ancestry-path), "$upstream..HEAD",
2276              qw(-- :/ :!/debian));
2277         if (length $wrong) {
2278             snag 'unexpected-upstream-changes',
2279                 "history between upstream ($upstream) and HEAD contains direct changes to upstream files - are you sure this is a gbp (patches-unapplied) branch?";
2280             print STDERR "list expected changes with:  git log --stat --ancestry-path $upstream_spec..HEAD -- :/ ':!/debian'\n";
2281         }
2282     }
2283
2284     if ((git_cat_file "$upstream:debian")[0] ne 'missing') {
2285         snag 'upstream-has-debian',
2286             "upstream ($upstream) contains debian/ directory";
2287     }
2288
2289     my $previous_dgit_view = eval {
2290         my @clogcmd = qw(dpkg-parsechangelog --format rfc822 -n2);
2291         my ($lvsn, $suite);
2292         parsechangelog_loop \@clogcmd, 'debian/changelog', sub {
2293             my ($stz, $desc) = @_;
2294             no warnings qw(exiting);
2295             printdebug 'CHANGELOG ', Dumper($desc, $stz);
2296             next unless $stz->{Date};
2297             next unless $stz->{Distribution} ne 'UNRELEASED';
2298             $lvsn = $stz->{Version};
2299             $suite = $stz->{Distribution};
2300             last;
2301         };
2302         die "neither of the first two changelog entries are released\n"
2303             unless defined $lvsn;
2304         print "last finished-looking changelog entry: ($lvsn) $suite\n";
2305         my $mtag_pat = debiantag_maintview $lvsn, '*';
2306         my $mtag = cmdoutput @git, qw(describe --always --abbrev=0 --match),
2307             $mtag_pat;
2308         die "could not find suitable maintainer view tag $mtag_pat\n"
2309             unless $mtag_pat =~ m{/};
2310         is_fast_fwd $mtag, 'HEAD' or
2311             die "HEAD is not FF from maintainer tag $mtag!";
2312         my $dtag = "archive/$mtag";
2313         is_fast_fwd $mtag, $dtag or
2314             die "dgit view tag $dtag is not FF from maintainer tag $mtag";
2315         print "will stitch in dgit view, $dtag\n";
2316         git_rev_parse $dtag;
2317     };
2318     if (!$previous_dgit_view) {
2319         $@ =~ s/^\n+//;
2320         chomp $@;
2321         print STDERR "cannot stitch in dgit view: $@\n";
2322     }
2323
2324     snags_maybe_bail_early();
2325
2326     my $work;
2327
2328     fresh_workarea();
2329     in_workarea sub {
2330         runcmd @git, qw(checkout -q -b gdr-internal), $old_head;
2331         # make a branch out of the patch queue - we'll want this in a mo
2332         runcmd qw(gbp pq import);
2333         # strip the patches out
2334         runcmd @git, qw(checkout -q gdr-internal~0);
2335         rm_subdir_cached 'debian/patches';
2336         $work = make_commit ['HEAD'], [
2337  'git-debrebase convert-from-gbp: drop patches from tree',
2338  'Delete debian/patches, as part of converting to git-debrebase format.',
2339  '[git-debrebase convert-from-gbp: drop patches from tree]'
2340                               ];
2341         # make the anchor merge
2342         # the tree is already exactly right
2343         $work = make_commit [$work, $upstream], [
2344  'git-debrebase import: declare upstream',
2345  'First breakwater merge.',
2346  '[git-debrebase anchor: declare upstream]'
2347                               ];
2348
2349         # rebase the patch queue onto the new breakwater
2350         runcmd @git, qw(reset --quiet --hard patch-queue/gdr-internal);
2351         runcmd @git, qw(rebase --quiet --onto), $work, qw(gdr-internal);
2352         $work = git_rev_parse 'HEAD';
2353
2354         if ($previous_dgit_view) {
2355             $work = make_commit [$work, $previous_dgit_view], [
2356  'git-debrebase import: declare ff from dgit archive view',
2357  '[git-debrebase pseudomerge: import-from-gbp]',
2358             ];
2359         }
2360     };
2361
2362     ffq_check $work;
2363     snags_maybe_bail();
2364     update_head_checkout $old_head, $work, 'convert-from-gbp';
2365 }
2366
2367 sub cmd_convert_to_gbp () {
2368     badusage "no arguments allowed" if @ARGV;
2369     my $head = get_head();
2370     my (undef, undef, undef, $ffq, $gdrlast) = ffq_prev_branchinfo();
2371     keycommits $head, 0;
2372     my $out;
2373     make_patches_staged $head;
2374     in_workarea sub {
2375         $out = make_commit ['HEAD'], [
2376             'Commit patch queue (converted from git-debrebase format)',
2377             '[git-debrebase convert-to-gbp: commit patches]',
2378         ];
2379     };
2380     if (defined $ffq) {
2381         push @deferred_updates, "delete $ffq";
2382         push @deferred_updates, "delete $gdrlast";
2383     }
2384     snags_maybe_bail();
2385     update_head_checkout $head, $out, "convert to gbp (v0)";
2386     print <<END or die $!;
2387 git-debrebase: converted to git-buildpackage branch format
2388 git-debrebase: WARNING: do not now run "git-debrebase" any more
2389 git-debrebase: WARNING: doing so would drop all upstream patches!
2390 END
2391 }
2392
2393 sub cmd_convert_from_dgit_view () {
2394     my $clogp = parsechangelog();
2395
2396     my $bpd = (cfg 'dgit.default.build-products-dir',1) // '..';
2397     my $do_origs = 1;
2398     my $do_tags = 1;
2399     my $always = 0;
2400     my $diagnose = 0;
2401
2402     getoptions("convert-from-dgit-view",
2403                'diagnose!', \$diagnose,
2404                'build-products-dir:s', \$bpd,
2405                'origs!', \$do_origs,
2406                'tags!', \$do_tags,
2407                'always-convert-anyway!', \$always);
2408     fail "takes 1 optional argument, the upstream commitish" if @ARGV>1;
2409
2410     my @upstreams;
2411
2412     if (@ARGV) {
2413         my $spec = shift @ARGV;
2414         my $commit = git_rev_parse "$spec^{commit}";
2415         push @upstreams, { Commit => $commit,
2416                            Source => "$ARGV[0], from command line",
2417                            Only => 1,
2418                          };
2419     }
2420
2421     my $head = get_head();
2422
2423     if (!$always) {
2424         my $troubles = 0;
2425         my $trouble = sub { $troubles++; };
2426         keycommits $head, sub{}, sub{}, $trouble, $trouble;
2427         printdebug "troubles=$troubles\n";
2428         if (!$troubles) {
2429             print STDERR <<END;
2430 $us: Branch already seems to be in git-debrebase format!
2431 $us: --always-convert-anyway would do the conversion operation anyway
2432 $us: but is probably a bad idea.  Probably, you wanted to do nothing.
2433 END
2434             fail "Branch already in git-debrebase format." unless $opt_noop_ok;
2435             finish 0;
2436         }
2437     }
2438
2439     snags_maybe_bail_early();
2440
2441     my $version = upstreamversion $clogp->{Version};
2442     print STDERR "Considering possible commits corresponding to upstream:\n";
2443
2444     if (!@upstreams) {
2445         if ($do_tags) {
2446             my @tried;
2447             my $ups_tag = upstream_commitish_search $version, \@tried;
2448             if ($ups_tag) {
2449                 my $this = "git tag $tried[-1]";
2450                 push @upstreams, { Commit => $ups_tag,
2451                                    Source => $this,
2452                                  };
2453             } else {
2454                 printf STDERR
2455                     " git tag: no suitable tag found (tried %s)\n",
2456                     "@tried";
2457             }
2458         }
2459         if ($do_origs) {
2460             my $p = $clogp->{'Source'};
2461             # we do a quick check to see if there are plausible origs
2462             my $something=0;
2463             if (!opendir BPD, $bpd) {
2464                 die "$bpd: opendir: $!" unless $!==ENOENT;
2465             } else {
2466                 while ($!=0, my $f = readdir BPD) {
2467                     next unless is_orig_file_of_p_v $f, $p, $version;
2468                     printf STDERR
2469                         " orig: found what looks like a .orig, %s\n",
2470                         "$bpd/$f";
2471                     $something=1;
2472                     last;
2473                 }
2474                 die "read $bpd: $!" if $!;
2475                 closedir BPD;
2476             }
2477             if ($something) {
2478                 my $tree = cmdoutput
2479                     @dgit, qw(--build-products-dir), $bpd,
2480                     qw(print-unapplied-treeish);
2481                 fresh_workarea();
2482                 in_workarea sub {
2483                     runcmd @git, qw(reset --quiet), $tree, qw(-- .);
2484                     rm_subdir_cached 'debian';
2485                     $tree = cmdoutput @git, qw(write-tree);
2486                     my $ups_synth = make_commit [], [ <<END, <<END,
2487 Import effective orig tree for upstream version $version
2488 END
2489 This includes the contents of the .orig(s), minus any debian/ directory.
2490
2491 [git-debrebase import-from-dgit-view upstream-import-convert: $version]
2492 END
2493                                                     ];
2494                     push @upstreams, { Commit => $ups_synth,
2495                                        Source => "orig(s) imported via dgit",
2496                                      };
2497                 }
2498             } else {
2499                 printf STDERR
2500                     " orig: no suitable origs found (looked for %s in %s)\n",
2501                     "${p}_".(stripeoch $version)."...", $bpd;
2502             }
2503         }
2504     }
2505
2506     my $some_patches = stat_exists 'debian/patches/series';
2507
2508     print STDERR "Evaluating possible commits corresponding to upstream:\n";
2509
2510     my $result;
2511     foreach my $u (@upstreams) {
2512         my $work = $head;
2513         fresh_workarea();
2514         in_workarea sub {
2515             runcmd @git, qw(reset --quiet), $u->{Commit}, qw(-- .);
2516             runcmd @git, qw(checkout), $u->{Commit}, qw(-- .);
2517             runcmd @git, qw(clean -xdff);
2518             runcmd @git, qw(checkout), $head, qw(-- debian);
2519             if ($some_patches) {
2520                 rm_subdir_cached 'debian/patches';
2521                 $work = make_commit [ $work ], [
2522  'git-debrebase convert-from-dgit-view: drop upstream changes from breakwater',
2523  "Drop upstream changes, and delete debian/patches, as part of converting\n".
2524  "to git-debrebase format.  Upstream changes will appear as commits.",
2525  '[git-debrebase convert-from-dgit-view: drop patches from tree]'
2526                                            ];
2527             }
2528             $work = make_commit [ $work, $u->{Commit} ], [
2529  'git-debrebase convert-from-dgit-view: declare upstream',
2530  '(Re)constructed breakwater merge.',
2531  '[git-debrebase anchor: declare upstream]'
2532                                                          ];
2533             runcmd @git, qw(checkout --quiet -b mk), $work;
2534             if ($some_patches) {
2535                 runcmd @git, qw(checkout), $head, qw(-- debian/patches);
2536                 runcmd @git, qw(reset --quiet);
2537                 my @gbp_cmd = (qw(gbp pq import));
2538                 if (!$diagnose) {
2539                     my $gbp_err = "../gbp-pq-err";
2540                     @gbp_cmd = shell_cmd "exec >$gbp_err 2>&1", @gbp_cmd;
2541                 }
2542                 my $r = system @gbp_cmd;
2543                 if ($r) {
2544                     printf STDERR
2545                         " %s: couldn't apply patches: gbp pq %s",
2546                         $u->{Source}, waitstatusmsg();
2547                     return;
2548                 }
2549             }
2550             my $work = git_rev_parse qw(HEAD);
2551             my $diffout = cmdoutput @git, qw(diff-tree --stat HEAD), $work;
2552             if (length $diffout) {
2553                 print STDERR
2554                     " $u->{Source}: applying patches gives different tree\n";
2555                 print STDERR $diffout if $diagnose;
2556                 return;
2557             }
2558             # OMG!
2559             $u->{Result} = $work;
2560             $result = $u;
2561         };
2562         last if $result;
2563     }
2564
2565     if (!$result) {
2566         fail <<END;
2567 Could not find or construct a suitable upstream commit.
2568 Rerun adding --diagnose after convert-from-dgit-view, or pass a
2569 upstream commmit explicitly or provide suitable origs.
2570 END
2571     }
2572
2573     printf STDERR "Yes, will base new branch on %s\n", $result->{Source};
2574
2575     ffq_check $result->{Result};
2576     snags_maybe_bail();
2577     update_head_checkout $head, $result->{Result},
2578         'convert-from-dgit-view';
2579 }
2580
2581 sub cmd_downstream_rebase_launder_v0 () {
2582     badusage "needs 1 argument, the baseline" unless @ARGV==1;
2583     my ($base) = @ARGV;
2584     $base = git_rev_parse $base;
2585     my $old_head = get_head();
2586     my $current = $old_head;
2587     my $topmost_keep;
2588     for (;;) {
2589         if ($current eq $base) {
2590             $topmost_keep //= $current;
2591             print " $current BASE stop\n";
2592             last;
2593         }
2594         my $cl = classify $current;
2595         print " $current $cl->{Type}";
2596         my $keep = 0;
2597         my $p0 = $cl->{Parents}[0]{CommitId};
2598         my $next;
2599         if ($cl->{Type} eq 'Pseudomerge') {
2600             print " ^".($cl->{Contributor}{Ix}+1);
2601             $next = $cl->{Contributor}{CommitId};
2602         } elsif ($cl->{Type} eq 'AddPatches' or
2603                  $cl->{Type} eq 'Changelog') {
2604             print " strip";
2605             $next = $p0;
2606         } else {
2607             print " keep";
2608             $next = $p0;
2609             $keep = 1;
2610         }
2611         print "\n";
2612         if ($keep) {
2613             $topmost_keep //= $current;
2614         } else {
2615             die "to-be stripped changes not on top of the branch\n"
2616                 if $topmost_keep;
2617         }
2618         $current = $next;
2619     }
2620     if ($topmost_keep eq $old_head) {
2621         print "unchanged\n";
2622     } else {
2623         print "updating to $topmost_keep\n";
2624         update_head_checkout
2625             $old_head, $topmost_keep,
2626             'downstream-rebase-launder-v0';
2627     }
2628 }
2629
2630 getoptions_main
2631           ("bad options\n",
2632            "D+" => \$debuglevel,
2633            'noop-ok', => \$opt_noop_ok,
2634            'f=s' => \@snag_force_opts,
2635            'anchor=s' => \@opt_anchors,
2636            '--dgit=s' => \($dgit[0]),
2637            'force!',
2638            '--save-wreckage', \$opt_save_wreckage,
2639            '-i:s' => sub {
2640                my ($opt,$val) = @_;
2641                badusage "git-debrebase: no cuddling to -i for git-rebase"
2642                    if length $val;
2643                die if $opt_defaultcmd_interactive; # should not happen
2644                $opt_defaultcmd_interactive = [ qw(-i) ];
2645                # This access to @ARGV is excessive familiarity with
2646                # Getopt::Long, but there isn't another sensible
2647                # approach.  '-i=s{0,}' does not work with bundling.
2648                push @$opt_defaultcmd_interactive, @ARGV;
2649                @ARGV=();
2650            },
2651            'help' => sub { print $usage_message or die $!; finish 0; },
2652            );
2653
2654 initdebug('git-debrebase ');
2655 enabledebug if $debuglevel;
2656
2657 my $toplevel = cmdoutput @git, qw(rev-parse --show-toplevel);
2658 chdir $toplevel or die "chdir $toplevel: $!";
2659
2660 $rd = fresh_playground "$playprefix/misc";
2661
2662 @opt_anchors = map { git_rev_parse $_ } @opt_anchors;
2663
2664 if (!@ARGV || $opt_defaultcmd_interactive || $ARGV[0] =~ m{^-}) {
2665     defaultcmd_rebase();
2666 } else {
2667     my $cmd = shift @ARGV;
2668     my $cmdfn = $cmd;
2669     $cmdfn =~ y/-/_/;
2670     $cmdfn = ${*::}{"cmd_$cmdfn"};
2671
2672     $cmdfn or badusage "unknown git-debrebase sub-operation $cmd";
2673     $cmdfn->();
2674 }
2675
2676 finish 0;