dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37
  38 use Debian::Dgit;
  39
  40 our $our_version = 'UNRELEASED'; ###substituted###
  41
  42 our @rpushprotovsn_support = qw(3 2);
  43 our $protovsn;
  44
  45 our $isuite = 'unstable';
  46 our $idistro;
  47 our $package;
  48 our @ropts;
  49
  50 our $sign = 1;
  51 our $dryrun_level = 0;
  52 our $changesfile;
  53 our $buildproductsdir = '..';
  54 our $new_package = 0;
  55 our $ignoredirty = 0;
  56 our $rmonerror = 1;
  57 our @deliberatelies;
  58 our %previously;
  59 our $existing_package = 'dpkg';
  60 our $cleanmode;
  61 our $changes_since_version;
  62 our $quilt_mode;
  63 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  64 our $we_are_responder;
  65 our $initiator_tempdir;
  66
  67 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  68
  69 our $suite_re = '[-+.0-9a-z]+';
  70 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  71
  72 our (@git) = qw(git);
  73 our (@dget) = qw(dget);
  74 our (@curl) = qw(curl -f);
  75 our (@dput) = qw(dput);
  76 our (@debsign) = qw(debsign);
  77 our (@gpg) = qw(gpg);
  78 our (@sbuild) = qw(sbuild -A);
  79 our (@ssh) = 'ssh';
  80 our (@dgit) = qw(dgit);
  81 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  82 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  83 our (@dpkggenchanges) = qw(dpkg-genchanges);
  84 our (@mergechanges) = qw(mergechanges -f);
  85 our (@changesopts) = ('');
  86
  87 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  88                      'curl' => \@curl,
  89                      'dput' => \@dput,
  90                      'debsign' => \@debsign,
  91                      'gpg' => \@gpg,
  92                      'sbuild' => \@sbuild,
  93                      'ssh' => \@ssh,
  94                      'dgit' => \@dgit,
  95                      'git' => \@git,
  96                      'dpkg-source' => \@dpkgsource,
  97                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  98                      'dpkg-genchanges' => \@dpkggenchanges,
  99                      'ch' => \@changesopts,
 100                      'mergechanges' => \@mergechanges);
 101
 102 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 103 our %opts_cfg_insertpos = map {
 104     $_,
 105     scalar @{ $opts_opt_map{$_} }
 106 } keys %opts_opt_map;
 107
 108 sub finalise_opts_opts();
 109
 110 our $keyid;
 111
 112 autoflush STDOUT 1;
 113
 114 our $supplementary_message = '';
 115
 116 END {
 117     local ($@, $?);
 118     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 119 }
 120
 121 our $remotename = 'dgit';
 122 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 123 our $csuite;
 124 our $instead_distro;
 125
 126 sub lbranch () { return "$branchprefix/$csuite"; }
 127 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 128 sub lref () { return "refs/heads/".lbranch(); }
 129 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 130 sub rrref () { return server_ref($csuite); }
 131
 132 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 133
 134 sub stripepoch ($) {
 135     my ($vsn) = @_;
 136     $vsn =~ s/^\d+\://;
 137     return $vsn;
 138 }
 139
 140 sub srcfn ($$) {
 141     my ($vsn,$sfx) = @_;
 142     return "${package}_".(stripepoch $vsn).$sfx
 143 }
 144
 145 sub dscfn ($) {
 146     my ($vsn) = @_;
 147     return srcfn($vsn,".dsc");
 148 }
 149
 150 our $us = 'dgit';
 151 initdebug('');
 152
 153 our @end;
 154 END {
 155     local ($?);
 156     foreach my $f (@end) {
 157         eval { $f->(); };
 158         warn "$us: cleanup: $@" if length $@;
 159     }
 160 };
 161
 162 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 163
 164 sub no_such_package () {
 165     print STDERR "$us: package $package does not exist in suite $isuite\n";
 166     exit 4;
 167 }
 168
 169 sub fetchspec () {
 170     local $csuite = '*';
 171     return  "+".rrref().":".lrref();
 172 }
 173
 174 sub changedir ($) {
 175     my ($newdir) = @_;
 176     printdebug "CD $newdir\n";
 177     chdir $newdir or die "chdir: $newdir: $!";
 178 }
 179
 180 sub deliberately ($) {
 181     my ($enquiry) = @_;
 182     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 183 }
 184
 185 sub deliberately_not_fast_forward () {
 186     foreach (qw(not-fast-forward fresh-repo)) {
 187         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 188     }
 189 }
 190
 191 #---------- remote protocol support, common ----------
 192
 193 # remote push initiator/responder protocol:
 194 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 195 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 196 #  < dgit-remote-push-ready <actual-proto-vsn>
 197 #
 198 #  > file parsed-changelog
 199 #  [indicates that output of dpkg-parsechangelog follows]
 200 #  > data-block NBYTES
 201 #  > [NBYTES bytes of data (no newline)]
 202 #  [maybe some more blocks]
 203 #  > data-end
 204 #
 205 #  > file dsc
 206 #  [etc]
 207 #
 208 #  > file changes
 209 #  [etc]
 210 #
 211 #  > param head HEAD
 212 #
 213 #  > want signed-tag
 214 #  [indicates that signed tag is wanted]
 215 #  < data-block NBYTES
 216 #  < [NBYTES bytes of data (no newline)]
 217 #  [maybe some more blocks]
 218 #  < data-end
 219 #  < files-end
 220 #
 221 #  > want signed-dsc-changes
 222 #  < data-block NBYTES    [transfer of signed dsc]
 223 #  [etc]
 224 #  < data-block NBYTES    [transfer of signed changes]
 225 #  [etc]
 226 #  < files-end
 227 #
 228 #  > complete
 229
 230 our $i_child_pid;
 231
 232 sub i_child_report () {
 233     # Sees if our child has died, and reap it if so.  Returns a string
 234     # describing how it died if it failed, or undef otherwise.
 235     return undef unless $i_child_pid;
 236     my $got = waitpid $i_child_pid, WNOHANG;
 237     return undef if $got <= 0;
 238     die unless $got == $i_child_pid;
 239     $i_child_pid = undef;
 240     return undef unless $?;
 241     return "build host child ".waitstatusmsg();
 242 }
 243
 244 sub badproto ($$) {
 245     my ($fh, $m) = @_;
 246     fail "connection lost: $!" if $fh->error;
 247     fail "protocol violation; $m not expected";
 248 }
 249
 250 sub badproto_badread ($$) {
 251     my ($fh, $wh) = @_;
 252     fail "connection lost: $!" if $!;
 253     my $report = i_child_report();
 254     fail $report if defined $report;
 255     badproto $fh, "eof (reading $wh)";
 256 }
 257
 258 sub protocol_expect (&$) {
 259     my ($match, $fh) = @_;
 260     local $_;
 261     $_ = <$fh>;
 262     defined && chomp or badproto_badread $fh, "protocol message";
 263     if (wantarray) {
 264         my @r = &$match;
 265         return @r if @r;
 266     } else {
 267         my $r = &$match;
 268         return $r if $r;
 269     }
 270     badproto $fh, "\`$_'";
 271 }
 272
 273 sub protocol_send_file ($$) {
 274     my ($fh, $ourfn) = @_;
 275     open PF, "<", $ourfn or die "$ourfn: $!";
 276     for (;;) {
 277         my $d;
 278         my $got = read PF, $d, 65536;
 279         die "$ourfn: $!" unless defined $got;
 280         last if !$got;
 281         print $fh "data-block ".length($d)."\n" or die $!;
 282         print $fh $d or die $!;
 283     }
 284     PF->error and die "$ourfn $!";
 285     print $fh "data-end\n" or die $!;
 286     close PF;
 287 }
 288
 289 sub protocol_read_bytes ($$) {
 290     my ($fh, $nbytes) = @_;
 291     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 292     my $d;
 293     my $got = read $fh, $d, $nbytes;
 294     $got==$nbytes or badproto_badread $fh, "data block";
 295     return $d;
 296 }
 297
 298 sub protocol_receive_file ($$) {
 299     my ($fh, $ourfn) = @_;
 300     printdebug "() $ourfn\n";
 301     open PF, ">", $ourfn or die "$ourfn: $!";
 302     for (;;) {
 303         my ($y,$l) = protocol_expect {
 304             m/^data-block (.*)$/ ? (1,$1) :
 305             m/^data-end$/ ? (0,) :
 306             ();
 307         } $fh;
 308         last unless $y;
 309         my $d = protocol_read_bytes $fh, $l;
 310         print PF $d or die $!;
 311     }
 312     close PF or die $!;
 313 }
 314
 315 #---------- remote protocol support, responder ----------
 316
 317 sub responder_send_command ($) {
 318     my ($command) = @_;
 319     return unless $we_are_responder;
 320     # called even without $we_are_responder
 321     printdebug ">> $command\n";
 322     print PO $command, "\n" or die $!;
 323 }
 324
 325 sub responder_send_file ($$) {
 326     my ($keyword, $ourfn) = @_;
 327     return unless $we_are_responder;
 328     printdebug "]] $keyword $ourfn\n";
 329     responder_send_command "file $keyword";
 330     protocol_send_file \*PO, $ourfn;
 331 }
 332
 333 sub responder_receive_files ($@) {
 334     my ($keyword, @ourfns) = @_;
 335     die unless $we_are_responder;
 336     printdebug "[[ $keyword @ourfns\n";
 337     responder_send_command "want $keyword";
 338     foreach my $fn (@ourfns) {
 339         protocol_receive_file \*PI, $fn;
 340     }
 341     printdebug "[[\$\n";
 342     protocol_expect { m/^files-end$/ } \*PI;
 343 }
 344
 345 #---------- remote protocol support, initiator ----------
 346
 347 sub initiator_expect (&) {
 348     my ($match) = @_;
 349     protocol_expect { &$match } \*RO;
 350 }
 351
 352 #---------- end remote code ----------
 353
 354 sub progress {
 355     if ($we_are_responder) {
 356         my $m = join '', @_;
 357         responder_send_command "progress ".length($m) or die $!;
 358         print PO $m or die $!;
 359     } else {
 360         print @_, "\n";
 361     }
 362 }
 363
 364 our $ua;
 365
 366 sub url_get {
 367     if (!$ua) {
 368         $ua = LWP::UserAgent->new();
 369         $ua->env_proxy;
 370     }
 371     my $what = $_[$#_];
 372     progress "downloading $what...";
 373     my $r = $ua->get(@_) or die $!;
 374     return undef if $r->code == 404;
 375     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 376     return $r->decoded_content(charset => 'none');
 377 }
 378
 379 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 380
 381 sub runcmd {
 382     debugcmd "+",@_;
 383     $!=0; $?=0;
 384     failedcmd @_ if system @_;
 385 }
 386
 387 sub act_local () { return $dryrun_level <= 1; }
 388 sub act_scary () { return !$dryrun_level; }
 389
 390 sub printdone {
 391     if (!$dryrun_level) {
 392         progress "dgit ok: @_";
 393     } else {
 394         progress "would be ok: @_ (but dry run only)";
 395     }
 396 }
 397
 398 sub dryrun_report {
 399     printcmd(\*STDERR,$debugprefix."#",@_);
 400 }
 401
 402 sub runcmd_ordryrun {
 403     if (act_scary()) {
 404         runcmd @_;
 405     } else {
 406         dryrun_report @_;
 407     }
 408 }
 409
 410 sub runcmd_ordryrun_local {
 411     if (act_local()) {
 412         runcmd @_;
 413     } else {
 414         dryrun_report @_;
 415     }
 416 }
 417
 418 sub shell_cmd {
 419     my ($first_shell, @cmd) = @_;
 420     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 421 }
 422
 423 our $helpmsg = <<END;
 424 main usages:
 425   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 426   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 427   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 428   dgit [dgit-opts] sbuild [sbuild-opts]
 429   dgit [dgit-opts] push [dgit-opts] [suite]
 430   dgit [dgit-opts] rpush build-host:build-dir ...
 431 important dgit options:
 432   -k<keyid>           sign tag and package with <keyid> instead of default
 433   --dry-run -n        do not change anything, but go through the motions
 434   --damp-run -L       like --dry-run but make local changes, without signing
 435   --new -N            allow introducing a new package
 436   --debug -D          increase debug level
 437   -c<name>=<value>    set git config option (used directly by dgit too)
 438 END
 439
 440 our $later_warning_msg = <<END;
 441 Perhaps the upload is stuck in incoming.  Using the version from git.
 442 END
 443
 444 sub badusage {
 445     print STDERR "$us: @_\n", $helpmsg or die $!;
 446     exit 8;
 447 }
 448
 449 sub nextarg {
 450     @ARGV or badusage "too few arguments";
 451     return scalar shift @ARGV;
 452 }
 453
 454 sub cmd_help () {
 455     print $helpmsg or die $!;
 456     exit 0;
 457 }
 458
 459 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 460
 461 our %defcfg = ('dgit.default.distro' => 'debian',
 462                'dgit.default.username' => '',
 463                'dgit.default.archive-query-default-component' => 'main',
 464                'dgit.default.ssh' => 'ssh',
 465                'dgit.default.archive-query' => 'madison:',
 466                'dgit.default.sshpsql-dbname' => 'service=projectb',
 467                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 468                'dgit-distro.debian.git-check' => 'url',
 469                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 470                'dgit-distro.debian.new-private-pushers' => 't',
 471                'dgit-distro.debian/push.git-url' => '',
 472                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 473                'dgit-distro.debian/push.git-user-force' => 'dgit',
 474                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 475                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 476                'dgit-distro.debian/push.git-create' => 'true',
 477                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 478  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 479 # 'dgit-distro.debian.archive-query-tls-key',
 480 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 481 # ^ this does not work because curl is broken nowadays
 482 # Fixing #790093 properly will involve providing providing the key
 483 # in some pacagke and maybe updating these paths.
 484 #
 485 # 'dgit-distro.debian.archive-query-tls-curl-args',
 486 #   '--ca-path=/etc/ssl/ca-debian',
 487 # ^ this is a workaround but works (only) on DSA-administered machines
 488                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 489                'dgit-distro.debian.git-url-suffix' => '',
 490                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 491                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 492  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 493  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 494                'dgit-distro.ubuntu.git-check' => 'false',
 495  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 496                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 497                'dgit-distro.test-dummy.username' => "alice",
 498                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 499                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 500                'dgit-distro.test-dummy.git-url' => "$td/git",
 501                'dgit-distro.test-dummy.git-host' => "git",
 502                'dgit-distro.test-dummy.git-path' => "$td/git",
 503                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 504                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 505                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 506                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 507                );
 508
 509 our %gitcfg;
 510
 511 sub git_slurp_config () {
 512     local ($debuglevel) = $debuglevel-2;
 513     local $/="\0";
 514
 515     my @cmd = (@git, qw(config -z --get-regexp .*));
 516     debugcmd "|",@cmd;
 517
 518     open GITS, "-|", @cmd or failedcmd @cmd;
 519     while (<GITS>) {
 520         chomp or die;
 521         printdebug "=> ", (messagequote $_), "\n";
 522         m/\n/ or die "$_ ?";
 523         push @{ $gitcfg{$`} }, $'; #';
 524     }
 525     $!=0; $?=0;
 526     close GITS
 527         or ($!==0 && $?==256)
 528         or failedcmd @cmd;
 529 }
 530
 531 sub git_get_config ($) {
 532     my ($c) = @_;
 533     my $l = $gitcfg{$c};
 534     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 535         if $debuglevel >= 4;
 536     $l or return undef;
 537     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
 538     return $l->[0];
 539 }
 540
 541 sub cfg {
 542     foreach my $c (@_) {
 543         return undef if $c =~ /RETURN-UNDEF/;
 544         my $v = git_get_config($c);
 545         return $v if defined $v;
 546         my $dv = $defcfg{$c};
 547         return $dv if defined $dv;
 548     }
 549     badcfg "need value for one of: @_\n".
 550         "$us: distro or suite appears not to be (properly) supported";
 551 }
 552
 553 sub access_basedistro () {
 554     if (defined $idistro) {
 555         return $idistro;
 556     } else {
 557         return cfg("dgit-suite.$isuite.distro",
 558                    "dgit.default.distro");
 559     }
 560 }
 561
 562 sub access_quirk () {
 563     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 564     my $basedistro = access_basedistro();
 565     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 566                               'RETURN-UNDEF');
 567     if (defined $backports_quirk) {
 568         my $re = $backports_quirk;
 569         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 570         $re =~ s/\*/.*/g;
 571         $re =~ s/\%/([-0-9a-z_]+)/
 572             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 573         if ($isuite =~ m/^$re$/) {
 574             return ('backports',"$basedistro-backports",$1);
 575         }
 576     }
 577     return ('none',undef);
 578 }
 579
 580 our $access_forpush;
 581
 582 sub parse_cfg_bool ($$$) {
 583     my ($what,$def,$v) = @_;
 584     $v //= $def;
 585     return
 586         $v =~ m/^[ty1]/ ? 1 :
 587         $v =~ m/^[fn0]/ ? 0 :
 588         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 589 }
 590
 591 sub access_forpush_config () {
 592     my $d = access_basedistro();
 593
 594     return 1 if
 595         $new_package &&
 596         parse_cfg_bool('new-private-pushers', 0,
 597                        cfg("dgit-distro.$d.new-private-pushers",
 598                            'RETURN-UNDEF'));
 599
 600     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 601     $v //= 'a';
 602     return
 603         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 604         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 605         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 606         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 607 }
 608
 609 sub access_forpush () {
 610     $access_forpush //= access_forpush_config();
 611     return $access_forpush;
 612 }
 613
 614 sub pushing () {
 615     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 616     badcfg "pushing but distro is configured readonly"
 617         if access_forpush_config() eq '0';
 618     $access_forpush = 1;
 619     $supplementary_message = <<'END' unless $we_are_responder;
 620 Push failed, before we got started.
 621 You can retry the push, after fixing the problem, if you like.
 622 END
 623     finalise_opts_opts();
 624 }
 625
 626 sub notpushing () {
 627     finalise_opts_opts();
 628 }
 629
 630 sub supplementary_message ($) {
 631     my ($msg) = @_;
 632     if (!$we_are_responder) {
 633         $supplementary_message = $msg;
 634         return;
 635     } elsif ($protovsn >= 3) {
 636         responder_send_command "supplementary-message ".length($msg)
 637             or die $!;
 638         print PO $msg or die $!;
 639     }
 640 }
 641
 642 sub access_distros () {
 643     # Returns list of distros to try, in order
 644     #
 645     # We want to try:
 646     #    0. `instead of' distro name(s) we have been pointed to
 647     #    1. the access_quirk distro, if any
 648     #    2a. the user's specified distro, or failing that  } basedistro
 649     #    2b. the distro calculated from the suite          }
 650     my @l = access_basedistro();
 651
 652     my (undef,$quirkdistro) = access_quirk();
 653     unshift @l, $quirkdistro;
 654     unshift @l, $instead_distro;
 655     @l = grep { defined } @l;
 656
 657     if (access_forpush()) {
 658         @l = map { ("$_/push", $_) } @l;
 659     }
 660     @l;
 661 }
 662
 663 sub access_cfg_cfgs (@) {
 664     my (@keys) = @_;
 665     my @cfgs;
 666     # The nesting of these loops determines the search order.  We put
 667     # the key loop on the outside so that we search all the distros
 668     # for each key, before going on to the next key.  That means that
 669     # if access_cfg is called with a more specific, and then a less
 670     # specific, key, an earlier distro can override the less specific
 671     # without necessarily overriding any more specific keys.  (If the
 672     # distro wants to override the more specific keys it can simply do
 673     # so; whereas if we did the loop the other way around, it would be
 674     # impossible to for an earlier distro to override a less specific
 675     # key but not the more specific ones without restating the unknown
 676     # values of the more specific keys.
 677     my @realkeys;
 678     my @rundef;
 679     # We have to deal with RETURN-UNDEF specially, so that we don't
 680     # terminate the search prematurely.
 681     foreach (@keys) {
 682         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 683         push @realkeys, $_
 684     }
 685     foreach my $d (access_distros()) {
 686         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 687     }
 688     push @cfgs, map { "dgit.default.$_" } @realkeys;
 689     push @cfgs, @rundef;
 690     return @cfgs;
 691 }
 692
 693 sub access_cfg (@) {
 694     my (@keys) = @_;
 695     my (@cfgs) = access_cfg_cfgs(@keys);
 696     my $value = cfg(@cfgs);
 697     return $value;
 698 }
 699
 700 sub access_cfg_bool ($$) {
 701     my ($def, @keys) = @_;
 702     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 703 }
 704
 705 sub string_to_ssh ($) {
 706     my ($spec) = @_;
 707     if ($spec =~ m/\s/) {
 708         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 709     } else {
 710         return ($spec);
 711     }
 712 }
 713
 714 sub access_cfg_ssh () {
 715     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 716     if (!defined $gitssh) {
 717         return @ssh;
 718     } else {
 719         return string_to_ssh $gitssh;
 720     }
 721 }
 722
 723 sub access_runeinfo ($) {
 724     my ($info) = @_;
 725     return ": dgit ".access_basedistro()." $info ;";
 726 }
 727
 728 sub access_someuserhost ($) {
 729     my ($some) = @_;
 730     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 731     defined($user) && length($user) or
 732         $user = access_cfg("$some-user",'username');
 733     my $host = access_cfg("$some-host");
 734     return length($user) ? "$user\@$host" : $host;
 735 }
 736
 737 sub access_gituserhost () {
 738     return access_someuserhost('git');
 739 }
 740
 741 sub access_giturl (;$) {
 742     my ($optional) = @_;
 743     my $url = access_cfg('git-url','RETURN-UNDEF');
 744     my $suffix;
 745     if (!length $url) {
 746         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 747         return undef unless defined $proto;
 748         $url =
 749             $proto.
 750             access_gituserhost().
 751             access_cfg('git-path');
 752     } else {
 753         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 754     }
 755     $suffix //= '.git';
 756     return "$url/$package$suffix";
 757 }
 758
 759 sub parsecontrolfh ($$;$) {
 760     my ($fh, $desc, $allowsigned) = @_;
 761     our $dpkgcontrolhash_noissigned;
 762     my $c;
 763     for (;;) {
 764         my %opts = ('name' => $desc);
 765         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 766         $c = Dpkg::Control::Hash->new(%opts);
 767         $c->parse($fh,$desc) or die "parsing of $desc failed";
 768         last if $allowsigned;
 769         last if $dpkgcontrolhash_noissigned;
 770         my $issigned= $c->get_option('is_pgp_signed');
 771         if (!defined $issigned) {
 772             $dpkgcontrolhash_noissigned= 1;
 773             seek $fh, 0,0 or die "seek $desc: $!";
 774         } elsif ($issigned) {
 775             fail "control file $desc is (already) PGP-signed. ".
 776                 " Note that dgit push needs to modify the .dsc and then".
 777                 " do the signature itself";
 778         } else {
 779             last;
 780         }
 781     }
 782     return $c;
 783 }
 784
 785 sub parsecontrol {
 786     my ($file, $desc) = @_;
 787     my $fh = new IO::Handle;
 788     open $fh, '<', $file or die "$file: $!";
 789     my $c = parsecontrolfh($fh,$desc);
 790     $fh->error and die $!;
 791     close $fh;
 792     return $c;
 793 }
 794
 795 sub getfield ($$) {
 796     my ($dctrl,$field) = @_;
 797     my $v = $dctrl->{$field};
 798     return $v if defined $v;
 799     fail "missing field $field in ".$v->get_option('name');
 800 }
 801
 802 sub parsechangelog {
 803     my $c = Dpkg::Control::Hash->new();
 804     my $p = new IO::Handle;
 805     my @cmd = (qw(dpkg-parsechangelog), @_);
 806     open $p, '-|', @cmd or die $!;
 807     $c->parse($p);
 808     $?=0; $!=0; close $p or failedcmd @cmd;
 809     return $c;
 810 }
 811
 812 sub must_getcwd () {
 813     my $d = getcwd();
 814     defined $d or fail "getcwd failed: $!";
 815     return $d;
 816 }
 817
 818 our %rmad;
 819
 820 sub archive_query ($) {
 821     my ($method) = @_;
 822     my $query = access_cfg('archive-query','RETURN-UNDEF');
 823     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 824     my $proto = $1;
 825     my $data = $'; #';
 826     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 827 }
 828
 829 sub pool_dsc_subpath ($$) {
 830     my ($vsn,$component) = @_; # $package is implict arg
 831     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 832     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 833 }
 834
 835 #---------- `ftpmasterapi' archive query method (nascent) ----------
 836
 837 sub archive_api_query_cmd ($) {
 838     my ($subpath) = @_;
 839     my @cmd = qw(curl -sS);
 840     my $url = access_cfg('archive-query-url');
 841     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 842         my $host = $1;
 843         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 844         foreach my $key (split /\:/, $keys) {
 845             $key =~ s/\%HOST\%/$host/g;
 846             if (!stat $key) {
 847                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 848                 next;
 849             }
 850             fail "config requested specific TLS key but do not know".
 851                 " how to get curl to use exactly that EE key ($key)";
 852 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 853 #           # Sadly the above line does not work because of changes
 854 #           # to gnutls.   The real fix for #790093 may involve
 855 #           # new curl options.
 856             last;
 857         }
 858         # Fixing #790093 properly will involve providing a value
 859         # for this on clients.
 860         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 861         push @cmd, split / /, $kargs if defined $kargs;
 862     }
 863     push @cmd, $url.$subpath;
 864     return @cmd;
 865 }
 866
 867 sub api_query ($$) {
 868     use JSON;
 869     my ($data, $subpath) = @_;
 870     badcfg "ftpmasterapi archive query method takes no data part"
 871         if length $data;
 872     my @cmd = archive_api_query_cmd($subpath);
 873     my $json = cmdoutput @cmd;
 874     return decode_json($json);
 875 }
 876
 877 sub canonicalise_suite_ftpmasterapi () {
 878     my ($proto,$data) = @_;
 879     my $suites = api_query($data, 'suites');
 880     my @matched;
 881     foreach my $entry (@$suites) {
 882         next unless grep {
 883             my $v = $entry->{$_};
 884             defined $v && $v eq $isuite;
 885         } qw(codename name);
 886         push @matched, $entry;
 887     }
 888     fail "unknown suite $isuite" unless @matched;
 889     my $cn;
 890     eval {
 891         @matched==1 or die "multiple matches for suite $isuite\n";
 892         $cn = "$matched[0]{codename}";
 893         defined $cn or die "suite $isuite info has no codename\n";
 894         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 895     };
 896     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 897         if length $@;
 898     return $cn;
 899 }
 900
 901 sub archive_query_ftpmasterapi () {
 902     my ($proto,$data) = @_;
 903     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 904     my @rows;
 905     my $digester = Digest::SHA->new(256);
 906     foreach my $entry (@$info) {
 907         eval {
 908             my $vsn = "$entry->{version}";
 909             my ($ok,$msg) = version_check $vsn;
 910             die "bad version: $msg\n" unless $ok;
 911             my $component = "$entry->{component}";
 912             $component =~ m/^$component_re$/ or die "bad component";
 913             my $filename = "$entry->{filename}";
 914             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 915                 or die "bad filename";
 916             my $sha256sum = "$entry->{sha256sum}";
 917             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 918             push @rows, [ $vsn, "/pool/$component/$filename",
 919                           $digester, $sha256sum ];
 920         };
 921         die "bad ftpmaster api response: $@\n".Dumper($entry)
 922             if length $@;
 923     }
 924     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 925     return @rows;
 926 }
 927
 928 #---------- `madison' archive query method ----------
 929
 930 sub archive_query_madison {
 931     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 932 }
 933
 934 sub madison_get_parse {
 935     my ($proto,$data) = @_;
 936     die unless $proto eq 'madison';
 937     if (!length $data) {
 938         $data= access_cfg('madison-distro','RETURN-UNDEF');
 939         $data //= access_basedistro();
 940     }
 941     $rmad{$proto,$data,$package} ||= cmdoutput
 942         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 943     my $rmad = $rmad{$proto,$data,$package};
 944
 945     my @out;
 946     foreach my $l (split /\n/, $rmad) {
 947         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 948                   \s*( [^ \t|]+ )\s* \|
 949                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 950                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 951         $1 eq $package or die "$rmad $package ?";
 952         my $vsn = $2;
 953         my $newsuite = $3;
 954         my $component;
 955         if (defined $4) {
 956             $component = $4;
 957         } else {
 958             $component = access_cfg('archive-query-default-component');
 959         }
 960         $5 eq 'source' or die "$rmad ?";
 961         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 962     }
 963     return sort { -version_compare($a->[0],$b->[0]); } @out;
 964 }
 965
 966 sub canonicalise_suite_madison {
 967     # madison canonicalises for us
 968     my @r = madison_get_parse(@_);
 969     @r or fail
 970         "unable to canonicalise suite using package $package".
 971         " which does not appear to exist in suite $isuite;".
 972         " --existing-package may help";
 973     return $r[0][2];
 974 }
 975
 976 #---------- `sshpsql' archive query method ----------
 977
 978 sub sshpsql ($$$) {
 979     my ($data,$runeinfo,$sql) = @_;
 980     if (!length $data) {
 981         $data= access_someuserhost('sshpsql').':'.
 982             access_cfg('sshpsql-dbname');
 983     }
 984     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 985     my ($userhost,$dbname) = ($`,$'); #';
 986     my @rows;
 987     my @cmd = (access_cfg_ssh, $userhost,
 988                access_runeinfo("ssh-psql $runeinfo").
 989                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 990                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 991     debugcmd "|",@cmd;
 992     open P, "-|", @cmd or die $!;
 993     while (<P>) {
 994         chomp or die;
 995         printdebug(">|$_|\n");
 996         push @rows, $_;
 997     }
 998     $!=0; $?=0; close P or failedcmd @cmd;
 999     @rows or die;
1000     my $nrows = pop @rows;
1001     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1002     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1003     @rows = map { [ split /\|/, $_ ] } @rows;
1004     my $ncols = scalar @{ shift @rows };
1005     die if grep { scalar @$_ != $ncols } @rows;
1006     return @rows;
1007 }
1008
1009 sub sql_injection_check {
1010     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1011 }
1012
1013 sub archive_query_sshpsql ($$) {
1014     my ($proto,$data) = @_;
1015     sql_injection_check $isuite, $package;
1016     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1017         SELECT source.version, component.name, files.filename, files.sha256sum
1018           FROM source
1019           JOIN src_associations ON source.id = src_associations.source
1020           JOIN suite ON suite.id = src_associations.suite
1021           JOIN dsc_files ON dsc_files.source = source.id
1022           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1023           JOIN component ON component.id = files_archive_map.component_id
1024           JOIN files ON files.id = dsc_files.file
1025          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1026            AND source.source='$package'
1027            AND files.filename LIKE '%.dsc';
1028 END
1029     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1030     my $digester = Digest::SHA->new(256);
1031     @rows = map {
1032         my ($vsn,$component,$filename,$sha256sum) = @$_;
1033         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1034     } @rows;
1035     return @rows;
1036 }
1037
1038 sub canonicalise_suite_sshpsql ($$) {
1039     my ($proto,$data) = @_;
1040     sql_injection_check $isuite;
1041     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1042         SELECT suite.codename
1043           FROM suite where suite_name='$isuite' or codename='$isuite';
1044 END
1045     @rows = map { $_->[0] } @rows;
1046     fail "unknown suite $isuite" unless @rows;
1047     die "ambiguous $isuite: @rows ?" if @rows>1;
1048     return $rows[0];
1049 }
1050
1051 #---------- `dummycat' archive query method ----------
1052
1053 sub canonicalise_suite_dummycat ($$) {
1054     my ($proto,$data) = @_;
1055     my $dpath = "$data/suite.$isuite";
1056     if (!open C, "<", $dpath) {
1057         $!==ENOENT or die "$dpath: $!";
1058         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1059         return $isuite;
1060     }
1061     $!=0; $_ = <C>;
1062     chomp or die "$dpath: $!";
1063     close C;
1064     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1065     return $_;
1066 }
1067
1068 sub archive_query_dummycat ($$) {
1069     my ($proto,$data) = @_;
1070     canonicalise_suite();
1071     my $dpath = "$data/package.$csuite.$package";
1072     if (!open C, "<", $dpath) {
1073         $!==ENOENT or die "$dpath: $!";
1074         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1075         return ();
1076     }
1077     my @rows;
1078     while (<C>) {
1079         next if m/^\#/;
1080         next unless m/\S/;
1081         die unless chomp;
1082         printdebug "dummycat query $csuite $package $dpath | $_\n";
1083         my @row = split /\s+/, $_;
1084         @row==2 or die "$dpath: $_ ?";
1085         push @rows, \@row;
1086     }
1087     C->error and die "$dpath: $!";
1088     close C;
1089     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1090 }
1091
1092 #---------- archive query entrypoints and rest of program ----------
1093
1094 sub canonicalise_suite () {
1095     return if defined $csuite;
1096     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1097     $csuite = archive_query('canonicalise_suite');
1098     if ($isuite ne $csuite) {
1099         progress "canonical suite name for $isuite is $csuite";
1100     }
1101 }
1102
1103 sub get_archive_dsc () {
1104     canonicalise_suite();
1105     my @vsns = archive_query('archive_query');
1106     foreach my $vinfo (@vsns) {
1107         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1108         $dscurl = access_cfg('mirror').$subpath;
1109         $dscdata = url_get($dscurl);
1110         if (!$dscdata) {
1111             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1112             next;
1113         }
1114         if ($digester) {
1115             $digester->reset();
1116             $digester->add($dscdata);
1117             my $got = $digester->hexdigest();
1118             $got eq $digest or
1119                 fail "$dscurl has hash $got but".
1120                     " archive told us to expect $digest";
1121         }
1122         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1123         printdebug Dumper($dscdata) if $debuglevel>1;
1124         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1125         printdebug Dumper($dsc) if $debuglevel>1;
1126         my $fmt = getfield $dsc, 'Format';
1127         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1128         $dsc_checked = !!$digester;
1129         return;
1130     }
1131     $dsc = undef;
1132 }
1133
1134 sub check_for_git ();
1135 sub check_for_git () {
1136     # returns 0 or 1
1137     my $how = access_cfg('git-check');
1138     if ($how eq 'ssh-cmd') {
1139         my @cmd =
1140             (access_cfg_ssh, access_gituserhost(),
1141              access_runeinfo("git-check $package").
1142              " set -e; cd ".access_cfg('git-path').";".
1143              " if test -d $package.git; then echo 1; else echo 0; fi");
1144         my $r= cmdoutput @cmd;
1145         if ($r =~ m/^divert (\w+)$/) {
1146             my $divert=$1;
1147             my ($usedistro,) = access_distros();
1148             # NB that if we are pushing, $usedistro will be $distro/push
1149             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1150             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1151             progress "diverting to $divert (using config for $instead_distro)";
1152             return check_for_git();
1153         }
1154         failedcmd @cmd unless $r =~ m/^[01]$/;
1155         return $r+0;
1156     } elsif ($how eq 'url') {
1157         my $prefix = access_cfg('git-check-url','git-url');
1158         my $suffix = access_cfg('git-check-suffix','git-suffix',
1159                                 'RETURN-UNDEF') // '.git';
1160         my $url = "$prefix/$package$suffix";
1161         my @cmd = (qw(curl -sS -I), $url);
1162         my $result = cmdoutput @cmd;
1163         $result =~ s/^\S+ 200 .*\n\r?\n//;
1164         # curl -sS -I with https_proxy prints
1165         # HTTP/1.0 200 Connection established
1166         $result =~ m/^\S+ (404|200) /s or
1167             fail "unexpected results from git check query - ".
1168                 Dumper($prefix, $result);
1169         my $code = $1;
1170         if ($code eq '404') {
1171             return 0;
1172         } elsif ($code eq '200') {
1173             return 1;
1174         } else {
1175             die;
1176         }
1177     } elsif ($how eq 'true') {
1178         return 1;
1179     } elsif ($how eq 'false') {
1180         return 0;
1181     } else {
1182         badcfg "unknown git-check \`$how'";
1183     }
1184 }
1185
1186 sub create_remote_git_repo () {
1187     my $how = access_cfg('git-create');
1188     if ($how eq 'ssh-cmd') {
1189         runcmd_ordryrun
1190             (access_cfg_ssh, access_gituserhost(),
1191              access_runeinfo("git-create $package").
1192              "set -e; cd ".access_cfg('git-path').";".
1193              " cp -a _template $package.git");
1194     } elsif ($how eq 'true') {
1195         # nothing to do
1196     } else {
1197         badcfg "unknown git-create \`$how'";
1198     }
1199 }
1200
1201 our ($dsc_hash,$lastpush_hash);
1202
1203 our $ud = '.git/dgit/unpack';
1204
1205 sub prep_ud () {
1206     rmtree($ud);
1207     mkpath '.git/dgit';
1208     mkdir $ud or die $!;
1209 }
1210
1211 sub mktree_in_ud_here () {
1212     runcmd qw(git init -q);
1213     rmtree('.git/objects');
1214     symlink '../../../../objects','.git/objects' or die $!;
1215 }
1216
1217 sub git_write_tree () {
1218     my $tree = cmdoutput @git, qw(write-tree);
1219     $tree =~ m/^\w+$/ or die "$tree ?";
1220     return $tree;
1221 }
1222
1223 sub remove_stray_gits () {
1224     my @gitscmd = qw(find -name .git -prune -print0);
1225     debugcmd "|",@gitscmd;
1226     open GITS, "-|", @gitscmd or failedcmd @gitscmd;
1227     {
1228         local $/="\0";
1229         while (<GITS>) {
1230             chomp or die;
1231             print STDERR "$us: warning: removing from source package: ",
1232                 (messagequote $_), "\n";
1233             rmtree $_;
1234         }
1235     }
1236     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1237 }
1238
1239 sub mktree_in_ud_from_only_subdir () {
1240     # changes into the subdir
1241     my (@dirs) = <*/.>;
1242     die unless @dirs==1;
1243     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1244     my $dir = $1;
1245     changedir $dir;
1246
1247     remove_stray_gits();
1248     mktree_in_ud_here();
1249     my ($format, $fopts) = get_source_format();
1250     if (madformat($format)) {
1251         rmtree '.pc';
1252     }
1253     runcmd @git, qw(add -Af);
1254     my $tree=git_write_tree();
1255     return ($tree,$dir);
1256 }
1257
1258 sub dsc_files_info () {
1259     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1260                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1261                        ['Files',           'Digest::MD5', 'new()']) {
1262         my ($fname, $module, $method) = @$csumi;
1263         my $field = $dsc->{$fname};
1264         next unless defined $field;
1265         eval "use $module; 1;" or die $@;
1266         my @out;
1267         foreach (split /\n/, $field) {
1268             next unless m/\S/;
1269             m/^(\w+) (\d+) (\S+)$/ or
1270                 fail "could not parse .dsc $fname line \`$_'";
1271             my $digester = eval "$module"."->$method;" or die $@;
1272             push @out, {
1273                 Hash => $1,
1274                 Bytes => $2,
1275                 Filename => $3,
1276                 Digester => $digester,
1277             };
1278         }
1279         return @out;
1280     }
1281     fail "missing any supported Checksums-* or Files field in ".
1282         $dsc->get_option('name');
1283 }
1284
1285 sub dsc_files () {
1286     map { $_->{Filename} } dsc_files_info();
1287 }
1288
1289 sub is_orig_file ($;$) {
1290     local ($_) = $_[0];
1291     my $base = $_[1];
1292     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1293     defined $base or return 1;
1294     return $` eq $base;
1295 }
1296
1297 sub make_commit ($) {
1298     my ($file) = @_;
1299     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1300 }
1301
1302 sub clogp_authline ($) {
1303     my ($clogp) = @_;
1304     my $author = getfield $clogp, 'Maintainer';
1305     $author =~ s#,.*##ms;
1306     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1307     my $authline = "$author $date";
1308     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1309         fail "unexpected commit author line format \`$authline'".
1310         " (was generated from changelog Maintainer field)";
1311     return $authline;
1312 }
1313
1314 sub vendor_patches_distro ($$) {
1315     my ($checkdistro, $what) = @_;
1316     return unless defined $checkdistro;
1317
1318     my $series = "debian/patches/\L$checkdistro\E.series";
1319     printdebug "checking for vendor-specific $series ($what)\n";
1320
1321     if (!open SERIES, "<", $series) {
1322         die "$series $!" unless $!==ENOENT;
1323         return;
1324     }
1325     while (<SERIES>) {
1326         next unless m/\S/;
1327         next if m/^\s+\#/;
1328
1329         print STDERR <<END;
1330
1331 Unfortunately, this source package uses a feature of dpkg-source where
1332 the same source package unpacks to different source code on different
1333 distros.  dgit cannot safely operate on such packages on affected
1334 distros, because the meaning of source packages is not stable.
1335
1336 Please ask the distro/maintainer to remove the distro-specific series
1337 files and use a different technique (if necessary, uploading actually
1338 different packages, if different distros are supposed to have
1339 different code).
1340
1341 END
1342         fail "Found active distro-specific series file for".
1343             " $checkdistro ($what): $series, cannot continue";
1344     }
1345     die "$series $!" if SERIES->error;
1346     close SERIES;
1347 }
1348
1349 sub check_for_vendor_patches () {
1350     # This dpkg-source feature doesn't seem to be documented anywhere!
1351     # But it can be found in the changelog (reformatted):
1352
1353     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1354     #   Author: Raphael Hertzog <hertzog@debian.org>
1355     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1356
1357     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1358     #   series files
1359     #
1360     #   If you have debian/patches/ubuntu.series and you were
1361     #   unpacking the source package on ubuntu, quilt was still
1362     #   directed to debian/patches/series instead of
1363     #   debian/patches/ubuntu.series.
1364     #
1365     #   debian/changelog                        |    3 +++
1366     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1367     #   2 files changed, 6 insertions(+), 1 deletion(-)
1368
1369     use Dpkg::Vendor;
1370     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1371     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1372                          "Dpkg::Vendor \`current vendor'");
1373     vendor_patches_distro(access_basedistro(),
1374                           "distro being accessed");
1375 }
1376
1377 sub generate_commit_from_dsc () {
1378     prep_ud();
1379     changedir $ud;
1380
1381     foreach my $fi (dsc_files_info()) {
1382         my $f = $fi->{Filename};
1383         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1384
1385         link_ltarget "../../../$f", $f
1386             or $!==&ENOENT
1387             or die "$f $!";
1388
1389         complete_file_from_dsc('.', $fi)
1390             or next;
1391
1392         if (is_orig_file($f)) {
1393             link $f, "../../../../$f"
1394                 or $!==&EEXIST
1395                 or die "$f $!";
1396         }
1397     }
1398
1399     my $dscfn = "$package.dsc";
1400
1401     open D, ">", $dscfn or die "$dscfn: $!";
1402     print D $dscdata or die "$dscfn: $!";
1403     close D or die "$dscfn: $!";
1404     my @cmd = qw(dpkg-source);
1405     push @cmd, '--no-check' if $dsc_checked;
1406     push @cmd, qw(-x --), $dscfn;
1407     runcmd @cmd;
1408
1409     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1410     check_for_vendor_patches() if madformat($dsc->{format});
1411     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1412     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1413     my $authline = clogp_authline $clogp;
1414     my $changes = getfield $clogp, 'Changes';
1415     open C, ">../commit.tmp" or die $!;
1416     print C <<END or die $!;
1417 tree $tree
1418 author $authline
1419 committer $authline
1420
1421 $changes
1422
1423 # imported from the archive
1424 END
1425     close C or die $!;
1426     my $outputhash = make_commit qw(../commit.tmp);
1427     my $cversion = getfield $clogp, 'Version';
1428     progress "synthesised git commit from .dsc $cversion";
1429     if ($lastpush_hash) {
1430         runcmd @git, qw(reset --hard), $lastpush_hash;
1431         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1432         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1433         my $oversion = getfield $oldclogp, 'Version';
1434         my $vcmp =
1435             version_compare($oversion, $cversion);
1436         if ($vcmp < 0) {
1437             # git upload/ is earlier vsn than archive, use archive
1438             open C, ">../commit2.tmp" or die $!;
1439             print C <<END or die $!;
1440 tree $tree
1441 parent $lastpush_hash
1442 parent $outputhash
1443 author $authline
1444 committer $authline
1445
1446 Record $package ($cversion) in archive suite $csuite
1447 END
1448             $outputhash = make_commit qw(../commit2.tmp);
1449         } elsif ($vcmp > 0) {
1450             print STDERR <<END or die $!;
1451
1452 Version actually in archive:    $cversion (older)
1453 Last allegedly pushed/uploaded: $oversion (newer or same)
1454 $later_warning_msg
1455 END
1456             $outputhash = $lastpush_hash;
1457         } else {
1458             $outputhash = $lastpush_hash;
1459         }
1460     }
1461     changedir '../../../..';
1462     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1463             'DGIT_ARCHIVE', $outputhash;
1464     cmdoutput @git, qw(log -n2), $outputhash;
1465     # ... gives git a chance to complain if our commit is malformed
1466     rmtree($ud);
1467     return $outputhash;
1468 }
1469
1470 sub complete_file_from_dsc ($$) {
1471     our ($dstdir, $fi) = @_;
1472     # Ensures that we have, in $dir, the file $fi, with the correct
1473     # contents.  (Downloading it from alongside $dscurl if necessary.)
1474
1475     my $f = $fi->{Filename};
1476     my $tf = "$dstdir/$f";
1477     my $downloaded = 0;
1478
1479     if (stat_exists $tf) {
1480         progress "using existing $f";
1481     } else {
1482         my $furl = $dscurl;
1483         $furl =~ s{/[^/]+$}{};
1484         $furl .= "/$f";
1485         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
1486         die "$f ?" if $f =~ m#/#;
1487         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1488         return 0 if !act_local();
1489         $downloaded = 1;
1490     }
1491
1492     open F, "<", "$tf" or die "$tf: $!";
1493     $fi->{Digester}->reset();
1494     $fi->{Digester}->addfile(*F);
1495     F->error and die $!;
1496     my $got = $fi->{Digester}->hexdigest();
1497     $got eq $fi->{Hash} or
1498         fail "file $f has hash $got but .dsc".
1499             " demands hash $fi->{Hash} ".
1500             ($downloaded ? "(got wrong file from archive!)"
1501              : "(perhaps you should delete this file?)");
1502
1503     return 1;
1504 }
1505
1506 sub ensure_we_have_orig () {
1507     foreach my $fi (dsc_files_info()) {
1508         my $f = $fi->{Filename};
1509         next unless is_orig_file($f);
1510         complete_file_from_dsc('..', $fi)
1511             or next;
1512     }
1513 }
1514
1515 sub git_fetch_us () {
1516     my @specs = (fetchspec());
1517     push @specs,
1518         map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1519         qw(tags heads);
1520     runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(), @specs;
1521
1522     my %here;
1523     my $tagpat = debiantag('*',access_basedistro);
1524
1525     git_for_each_ref("refs/tags/".$tagpat, sub {
1526         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1527         printdebug "currently $fullrefname=$objid\n";
1528         $here{$fullrefname} = $objid;
1529     });
1530     git_for_each_ref(lrfetchrefs."/tags/".$tagpat, sub {
1531         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1532         my $lref = "refs".substr($fullrefname, length lrfetchrefs);
1533         printdebug "offered $lref=$objid\n";
1534         if (!defined $here{$lref}) {
1535             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1536             runcmd_ordryrun_local @upd;
1537         } elsif ($here{$lref} eq $objid) {
1538         } else {
1539             print STDERR \
1540                 "Not updateting $lref from $here{$lref} to $objid.\n";
1541         }
1542     });
1543 }
1544
1545 sub fetch_from_archive () {
1546     # ensures that lrref() is what is actually in the archive,
1547     #  one way or another
1548     get_archive_dsc();
1549
1550     if ($dsc) {
1551         foreach my $field (@ourdscfield) {
1552             $dsc_hash = $dsc->{$field};
1553             last if defined $dsc_hash;
1554         }
1555         if (defined $dsc_hash) {
1556             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1557             $dsc_hash = $&;
1558             progress "last upload to archive specified git hash";
1559         } else {
1560             progress "last upload to archive has NO git hash";
1561         }
1562     } else {
1563         progress "no version available from the archive";
1564     }
1565
1566     $lastpush_hash = git_get_ref(lrref());
1567     printdebug "previous reference hash=$lastpush_hash\n";
1568     my $hash;
1569     if (defined $dsc_hash) {
1570         fail "missing remote git history even though dsc has hash -".
1571             " could not find ref ".lrref().
1572             " (should have been fetched from ".access_giturl()."#".rrref().")"
1573             unless $lastpush_hash;
1574         $hash = $dsc_hash;
1575         ensure_we_have_orig();
1576         if ($dsc_hash eq $lastpush_hash) {
1577         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1578             print STDERR <<END or die $!;
1579
1580 Git commit in archive is behind the last version allegedly pushed/uploaded.
1581 Commit referred to by archive:  $dsc_hash
1582 Last allegedly pushed/uploaded: $lastpush_hash
1583 $later_warning_msg
1584 END
1585             $hash = $lastpush_hash;
1586         } else {
1587             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1588                 "descendant of archive's .dsc hash ($dsc_hash)";
1589         }
1590     } elsif ($dsc) {
1591         $hash = generate_commit_from_dsc();
1592     } elsif ($lastpush_hash) {
1593         # only in git, not in the archive yet
1594         $hash = $lastpush_hash;
1595         print STDERR <<END or die $!;
1596
1597 Package not found in the archive, but has allegedly been pushed using dgit.
1598 $later_warning_msg
1599 END
1600     } else {
1601         printdebug "nothing found!\n";
1602         if (defined $skew_warning_vsn) {
1603             print STDERR <<END or die $!;
1604
1605 Warning: relevant archive skew detected.
1606 Archive allegedly contains $skew_warning_vsn
1607 But we were not able to obtain any version from the archive or git.
1608
1609 END
1610         }
1611         return 0;
1612     }
1613     printdebug "current hash=$hash\n";
1614     if ($lastpush_hash) {
1615         fail "not fast forward on last upload branch!".
1616             " (archive's version left in DGIT_ARCHIVE)"
1617             unless is_fast_fwd($lastpush_hash, $hash);
1618     }
1619     if (defined $skew_warning_vsn) {
1620         mkpath '.git/dgit';
1621         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1622         my $clogf = ".git/dgit/changelog.tmp";
1623         runcmd shell_cmd "exec >$clogf",
1624             @git, qw(cat-file blob), "$hash:debian/changelog";
1625         my $gotclogp = parsechangelog("-l$clogf");
1626         my $got_vsn = getfield $gotclogp, 'Version';
1627         printdebug "SKEW CHECK GOT $got_vsn\n";
1628         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1629             print STDERR <<END or die $!;
1630
1631 Warning: archive skew detected.  Using the available version:
1632 Archive allegedly contains    $skew_warning_vsn
1633 We were able to obtain only   $got_vsn
1634
1635 END
1636         }
1637     }
1638     if ($lastpush_hash ne $hash) {
1639         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1640         if (act_local()) {
1641             cmdoutput @upd_cmd;
1642         } else {
1643             dryrun_report @upd_cmd;
1644         }
1645     }
1646     return 1;
1647 }
1648
1649 sub set_local_git_config ($$) {
1650     my ($k, $v) = @_;
1651     runcmd @git, qw(config), $k, $v;
1652 }
1653
1654 sub setup_mergechangelogs (;$) {
1655     my ($always) = @_;
1656     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
1657
1658     my $driver = 'dpkg-mergechangelogs';
1659     my $cb = "merge.$driver";
1660     my $attrs = '.git/info/attributes';
1661     ensuredir '.git/info';
1662
1663     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
1664     if (!open ATTRS, "<", $attrs) {
1665         $!==ENOENT or die "$attrs: $!";
1666     } else {
1667         while (<ATTRS>) {
1668             chomp;
1669             next if m{^debian/changelog\s};
1670             print NATTRS $_, "\n" or die $!;
1671         }
1672         ATTRS->error and die $!;
1673         close ATTRS;
1674     }
1675     print NATTRS "debian/changelog merge=$driver\n" or die $!;
1676     close NATTRS;
1677
1678     set_local_git_config "$cb.name", 'debian/changelog merge driver';
1679     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
1680
1681     rename "$attrs.new", "$attrs" or die "$attrs: $!";
1682 }
1683
1684 sub setup_useremail (;$) {
1685     my ($always) = @_;
1686     return unless $always || access_cfg_bool(1, 'setup-useremail');
1687
1688     my $setup = sub {
1689         my ($k, $envvar) = @_;
1690         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
1691         return unless defined $v;
1692         set_local_git_config "user.$k", $v;
1693     };
1694
1695     $setup->('email', 'DEBEMAIL');
1696     $setup->('name', 'DEBFULLNAME');
1697 }
1698
1699 sub setup_new_tree () {
1700     setup_mergechangelogs();
1701     setup_useremail();
1702 }
1703
1704 sub clone ($) {
1705     my ($dstdir) = @_;
1706     canonicalise_suite();
1707     badusage "dry run makes no sense with clone" unless act_local();
1708     my $hasgit = check_for_git();
1709     mkdir $dstdir or die "$dstdir $!";
1710     changedir $dstdir;
1711     runcmd @git, qw(init -q);
1712     my $giturl = access_giturl(1);
1713     if (defined $giturl) {
1714         set_local_git_config "remote.$remotename.fetch", fetchspec();
1715         open H, "> .git/HEAD" or die $!;
1716         print H "ref: ".lref()."\n" or die $!;
1717         close H or die $!;
1718         runcmd @git, qw(remote add), 'origin', $giturl;
1719     }
1720     if ($hasgit) {
1721         progress "fetching existing git history";
1722         git_fetch_us();
1723         runcmd_ordryrun_local @git, qw(fetch origin);
1724     } else {
1725         progress "starting new git history";
1726     }
1727     fetch_from_archive() or no_such_package;
1728     my $vcsgiturl = $dsc->{'Vcs-Git'};
1729     if (length $vcsgiturl) {
1730         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1731         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1732     }
1733     setup_new_tree();
1734     runcmd @git, qw(reset --hard), lrref();
1735     printdone "ready for work in $dstdir";
1736 }
1737
1738 sub fetch () {
1739     if (check_for_git()) {
1740         git_fetch_us();
1741     }
1742     fetch_from_archive() or no_such_package();
1743     printdone "fetched into ".lrref();
1744 }
1745
1746 sub pull () {
1747     fetch();
1748     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1749         lrref();
1750     printdone "fetched to ".lrref()." and merged into HEAD";
1751 }
1752
1753 sub check_not_dirty () {
1754     return if $ignoredirty;
1755     my @cmd = (@git, qw(diff --quiet HEAD));
1756     debugcmd "+",@cmd;
1757     $!=0; $?=0; system @cmd;
1758     return if !$! && !$?;
1759     if (!$! && $?==256) {
1760         fail "working tree is dirty (does not match HEAD)";
1761     } else {
1762         failedcmd @cmd;
1763     }
1764
1765     foreach my $f (qw(local-options local-patch-header)) {
1766         if (stat_exists "debian/source/$f") {
1767             fail "git tree contains debian/source/$f";
1768         }
1769     }
1770 }
1771
1772 sub commit_admin ($) {
1773     my ($m) = @_;
1774     progress "$m";
1775     runcmd_ordryrun_local @git, qw(commit -m), $m;
1776 }
1777
1778 sub commit_quilty_patch () {
1779     my $output = cmdoutput @git, qw(status --porcelain);
1780     my %adds;
1781     foreach my $l (split /\n/, $output) {
1782         next unless $l =~ m/\S/;
1783         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1784             $adds{$1}++;
1785         }
1786     }
1787     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1788     if (!%adds) {
1789         progress "nothing quilty to commit, ok.";
1790         return;
1791     }
1792     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
1793     runcmd_ordryrun_local @git, qw(add -f), @adds;
1794     commit_admin "Commit Debian 3.0 (quilt) metadata";
1795 }
1796
1797 sub get_source_format () {
1798     my %options;
1799     if (open F, "debian/source/options") {
1800         while (<F>) {
1801             next if m/^\s*\#/;
1802             next unless m/\S/;
1803             s/\s+$//; # ignore missing final newline
1804             if (m/\s*\#\s*/) {
1805                 my ($k, $v) = ($`, $'); #');
1806                 $v =~ s/^"(.*)"$/$1/;
1807                 $options{$k} = $v;
1808             } else {
1809                 $options{$_} = 1;
1810             }
1811         }
1812         F->error and die $!;
1813         close F;
1814     } else {
1815         die $! unless $!==&ENOENT;
1816     }
1817
1818     if (!open F, "debian/source/format") {
1819         die $! unless $!==&ENOENT;
1820         return '';
1821     }
1822     $_ = <F>;
1823     F->error and die $!;
1824     chomp;
1825     return ($_, \%options);
1826 }
1827
1828 sub madformat ($) {
1829     my ($format) = @_;
1830     return 0 unless $format eq '3.0 (quilt)';
1831     if ($quilt_mode eq 'nocheck') {
1832         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1833         return 0;
1834     }
1835     progress "Format \`$format', checking/updating patch stack";
1836     return 1;
1837 }
1838
1839 sub push_parse_changelog ($) {
1840     my ($clogpfn) = @_;
1841
1842     my $clogp = Dpkg::Control::Hash->new();
1843     $clogp->load($clogpfn) or die;
1844
1845     $package = getfield $clogp, 'Source';
1846     my $cversion = getfield $clogp, 'Version';
1847     my $tag = debiantag($cversion, access_basedistro);
1848     runcmd @git, qw(check-ref-format), $tag;
1849
1850     my $dscfn = dscfn($cversion);
1851
1852     return ($clogp, $cversion, $tag, $dscfn);
1853 }
1854
1855 sub push_parse_dsc ($$$) {
1856     my ($dscfn,$dscfnwhat, $cversion) = @_;
1857     $dsc = parsecontrol($dscfn,$dscfnwhat);
1858     my $dversion = getfield $dsc, 'Version';
1859     my $dscpackage = getfield $dsc, 'Source';
1860     ($dscpackage eq $package && $dversion eq $cversion) or
1861         fail "$dscfn is for $dscpackage $dversion".
1862             " but debian/changelog is for $package $cversion";
1863 }
1864
1865 sub push_mktag ($$$$$$$) {
1866     my ($head,$clogp,$tag,
1867         $dscfn,
1868         $changesfile,$changesfilewhat,
1869         $tfn) = @_;
1870
1871     $dsc->{$ourdscfield[0]} = $head;
1872     $dsc->save("$dscfn.tmp") or die $!;
1873
1874     my $changes = parsecontrol($changesfile,$changesfilewhat);
1875     foreach my $field (qw(Source Distribution Version)) {
1876         $changes->{$field} eq $clogp->{$field} or
1877             fail "changes field $field \`$changes->{$field}'".
1878                 " does not match changelog \`$clogp->{$field}'";
1879     }
1880
1881     my $cversion = getfield $clogp, 'Version';
1882     my $clogsuite = getfield $clogp, 'Distribution';
1883
1884     # We make the git tag by hand because (a) that makes it easier
1885     # to control the "tagger" (b) we can do remote signing
1886     my $authline = clogp_authline $clogp;
1887     my $delibs = join(" ", "",@deliberatelies);
1888     my $declaredistro = access_basedistro();
1889     open TO, '>', $tfn->('.tmp') or die $!;
1890     print TO <<END or die $!;
1891 object $head
1892 type commit
1893 tag $tag
1894 tagger $authline
1895
1896 $package release $cversion for $clogsuite ($csuite) [dgit]
1897 [dgit distro=$declaredistro$delibs]
1898 END
1899     foreach my $ref (sort keys %previously) {
1900                     print TO <<END or die $!;
1901 [dgit previously:$ref=$previously{$ref}]
1902 END
1903     }
1904
1905     close TO or die $!;
1906
1907     my $tagobjfn = $tfn->('.tmp');
1908     if ($sign) {
1909         if (!defined $keyid) {
1910             $keyid = access_cfg('keyid','RETURN-UNDEF');
1911         }
1912         if (!defined $keyid) {
1913             $keyid = getfield $clogp, 'Maintainer';
1914         }
1915         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1916         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1917         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1918         push @sign_cmd, $tfn->('.tmp');
1919         runcmd_ordryrun @sign_cmd;
1920         if (act_scary()) {
1921             $tagobjfn = $tfn->('.signed.tmp');
1922             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1923                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1924         }
1925     }
1926
1927     return ($tagobjfn);
1928 }
1929
1930 sub sign_changes ($) {
1931     my ($changesfile) = @_;
1932     if ($sign) {
1933         my @debsign_cmd = @debsign;
1934         push @debsign_cmd, "-k$keyid" if defined $keyid;
1935         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1936         push @debsign_cmd, $changesfile;
1937         runcmd_ordryrun @debsign_cmd;
1938     }
1939 }
1940
1941 sub dopush ($) {
1942     my ($forceflag) = @_;
1943     printdebug "actually entering push\n";
1944     supplementary_message(<<'END');
1945 Push failed, while preparing your push.
1946 You can retry the push, after fixing the problem, if you like.
1947 END
1948     prep_ud();
1949
1950     access_giturl(); # check that success is vaguely likely
1951
1952     my $clogpfn = ".git/dgit/changelog.822.tmp";
1953     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1954
1955     responder_send_file('parsed-changelog', $clogpfn);
1956
1957     my ($clogp, $cversion, $tag, $dscfn) =
1958         push_parse_changelog("$clogpfn");
1959
1960     my $dscpath = "$buildproductsdir/$dscfn";
1961     stat_exists $dscpath or
1962         fail "looked for .dsc $dscfn, but $!;".
1963             " maybe you forgot to build";
1964
1965     responder_send_file('dsc', $dscpath);
1966
1967     push_parse_dsc($dscpath, $dscfn, $cversion);
1968
1969     my $format = getfield $dsc, 'Format';
1970     printdebug "format $format\n";
1971     if (madformat($format)) {
1972         commit_quilty_patch();
1973     }
1974     check_not_dirty();
1975     changedir $ud;
1976     progress "checking that $dscfn corresponds to HEAD";
1977     runcmd qw(dpkg-source -x --),
1978         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1979     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1980     check_for_vendor_patches() if madformat($dsc->{format});
1981     changedir '../../../..';
1982     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1983     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1984     debugcmd "+",@diffcmd;
1985     $!=0; $?=0;
1986     my $r = system @diffcmd;
1987     if ($r) {
1988         if ($r==256) {
1989             fail "$dscfn specifies a different tree to your HEAD commit;".
1990                 " perhaps you forgot to build".
1991                 ($diffopt eq '--exit-code' ? "" :
1992                  " (run with -D to see full diff output)");
1993         } else {
1994             failedcmd @diffcmd;
1995         }
1996     }
1997     my $head = git_rev_parse('HEAD');
1998     if (!$changesfile) {
1999         my $multi = "$buildproductsdir/".
2000             "${package}_".(stripepoch $cversion)."_multi.changes";
2001         if (stat_exists "$multi") {
2002             $changesfile = $multi;
2003         } else {
2004             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
2005             my @cs = glob "$buildproductsdir/$pat";
2006             fail "failed to find unique changes file".
2007                 " (looked for $pat in $buildproductsdir, or $multi);".
2008                 " perhaps you need to use dgit -C"
2009                 unless @cs==1;
2010             ($changesfile) = @cs;
2011         }
2012     } else {
2013         $changesfile = "$buildproductsdir/$changesfile";
2014     }
2015
2016     responder_send_file('changes',$changesfile);
2017     responder_send_command("param head $head");
2018     responder_send_command("param csuite $csuite");
2019
2020     if (deliberately_not_fast_forward) {
2021         git_for_each_ref(lrfetchrefs, sub {
2022             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
2023             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
2024             responder_send_command("previously $rrefname=$objid");
2025             $previously{$rrefname} = $objid;
2026         });
2027     }
2028
2029     my $tfn = sub { ".git/dgit/tag$_[0]"; };
2030     my $tagobjfn;
2031
2032     supplementary_message(<<'END');
2033 Push failed, while signing the tag.
2034 You can retry the push, after fixing the problem, if you like.
2035 END
2036     # If we manage to sign but fail to record it anywhere, it's fine.
2037     if ($we_are_responder) {
2038         $tagobjfn = $tfn->('.signed.tmp');
2039         responder_receive_files('signed-tag', $tagobjfn);
2040     } else {
2041         $tagobjfn =
2042             push_mktag($head,$clogp,$tag,
2043                        $dscpath,
2044                        $changesfile,$changesfile,
2045                        $tfn);
2046     }
2047     supplementary_message(<<'END');
2048 Push failed, *after* signing the tag.
2049 If you want to try again, you should use a new version number.
2050 END
2051
2052     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
2053     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
2054     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
2055
2056     supplementary_message(<<'END');
2057 Push failed, while updating the remote git repository - see messages above.
2058 If you want to try again, you should use a new version number.
2059 END
2060     if (!check_for_git()) {
2061         create_remote_git_repo();
2062     }
2063     runcmd_ordryrun @git, qw(push),access_giturl(),
2064         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
2065     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
2066
2067     supplementary_message(<<'END');
2068 Push failed, after updating the remote git repository.
2069 If you want to try again, you must use a new version number.
2070 END
2071     if ($we_are_responder) {
2072         my $dryrunsuffix = act_local() ? "" : ".tmp";
2073         responder_receive_files('signed-dsc-changes',
2074                                 "$dscpath$dryrunsuffix",
2075                                 "$changesfile$dryrunsuffix");
2076     } else {
2077         if (act_local()) {
2078             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2079         } else {
2080             progress "[new .dsc left in $dscpath.tmp]";
2081         }
2082         sign_changes $changesfile;
2083     }
2084
2085     supplementary_message(<<'END');
2086 Push failed, while uploading package(s) to the archive server.
2087 You can retry the upload of exactly these same files with dput of:
2088   $changesfile
2089 If that .changes file is broken, you will need to use a new version
2090 number for your next attempt at the upload.
2091 END
2092     my $host = access_cfg('upload-host','RETURN-UNDEF');
2093     my @hostarg = defined($host) ? ($host,) : ();
2094     runcmd_ordryrun @dput, @hostarg, $changesfile;
2095     printdone "pushed and uploaded $cversion";
2096
2097     supplementary_message('');
2098     responder_send_command("complete");
2099 }
2100
2101 sub cmd_clone {
2102     parseopts();
2103     notpushing();
2104     my $dstdir;
2105     badusage "-p is not allowed with clone; specify as argument instead"
2106         if defined $package;
2107     if (@ARGV==1) {
2108         ($package) = @ARGV;
2109     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2110         ($package,$isuite) = @ARGV;
2111     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2112         ($package,$dstdir) = @ARGV;
2113     } elsif (@ARGV==3) {
2114         ($package,$isuite,$dstdir) = @ARGV;
2115     } else {
2116         badusage "incorrect arguments to dgit clone";
2117     }
2118     $dstdir ||= "$package";
2119
2120     if (stat_exists $dstdir) {
2121         fail "$dstdir already exists";
2122     }
2123
2124     my $cwd_remove;
2125     if ($rmonerror && !$dryrun_level) {
2126         $cwd_remove= getcwd();
2127         unshift @end, sub {
2128             return unless defined $cwd_remove;
2129             if (!chdir "$cwd_remove") {
2130                 return if $!==&ENOENT;
2131                 die "chdir $cwd_remove: $!";
2132             }
2133             rmtree($dstdir) or die "remove $dstdir: $!\n";
2134         };
2135     }
2136
2137     clone($dstdir);
2138     $cwd_remove = undef;
2139 }
2140
2141 sub branchsuite () {
2142     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2143     if ($branch =~ m#$lbranch_re#o) {
2144         return $1;
2145     } else {
2146         return undef;
2147     }
2148 }
2149
2150 sub fetchpullargs () {
2151     notpushing();
2152     if (!defined $package) {
2153         my $sourcep = parsecontrol('debian/control','debian/control');
2154         $package = getfield $sourcep, 'Source';
2155     }
2156     if (@ARGV==0) {
2157 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2158         if (!$isuite) {
2159             my $clogp = parsechangelog();
2160             $isuite = getfield $clogp, 'Distribution';
2161         }
2162         canonicalise_suite();
2163         progress "fetching from suite $csuite";
2164     } elsif (@ARGV==1) {
2165         ($isuite) = @ARGV;
2166         canonicalise_suite();
2167     } else {
2168         badusage "incorrect arguments to dgit fetch or dgit pull";
2169     }
2170 }
2171
2172 sub cmd_fetch {
2173     parseopts();
2174     fetchpullargs();
2175     fetch();
2176 }
2177
2178 sub cmd_pull {
2179     parseopts();
2180     fetchpullargs();
2181     pull();
2182 }
2183
2184 sub cmd_push {
2185     parseopts();
2186     pushing();
2187     badusage "-p is not allowed with dgit push" if defined $package;
2188     check_not_dirty();
2189     my $clogp = parsechangelog();
2190     $package = getfield $clogp, 'Source';
2191     my $specsuite;
2192     if (@ARGV==0) {
2193     } elsif (@ARGV==1) {
2194         ($specsuite) = (@ARGV);
2195     } else {
2196         badusage "incorrect arguments to dgit push";
2197     }
2198     $isuite = getfield $clogp, 'Distribution';
2199     if ($new_package) {
2200         local ($package) = $existing_package; # this is a hack
2201         canonicalise_suite();
2202     } else {
2203         canonicalise_suite();
2204     }
2205     if (defined $specsuite &&
2206         $specsuite ne $isuite &&
2207         $specsuite ne $csuite) {
2208             fail "dgit push: changelog specifies $isuite ($csuite)".
2209                 " but command line specifies $specsuite";
2210     }
2211     supplementary_message(<<'END');
2212 Push failed, while checking state of the archive.
2213 You can retry the push, after fixing the problem, if you like.
2214 END
2215     if (check_for_git()) {
2216         git_fetch_us();
2217     }
2218     my $forceflag = '';
2219     if (fetch_from_archive()) {
2220         if (is_fast_fwd(lrref(), 'HEAD')) {
2221             # ok
2222         } elsif (deliberately_not_fast_forward) {
2223             $forceflag = '+';
2224         } else {
2225             fail "dgit push: HEAD is not a descendant".
2226                 " of the archive's version.\n".
2227                 "dgit: To overwrite its contents,".
2228                 " use git merge -s ours ".lrref().".\n".
2229                 "dgit: To rewind history, if permitted by the archive,".
2230                 " use --deliberately-not-fast-forward";
2231         }
2232     } else {
2233         $new_package or
2234             fail "package appears to be new in this suite;".
2235                 " if this is intentional, use --new";
2236     }
2237     dopush($forceflag);
2238 }
2239
2240 #---------- remote commands' implementation ----------
2241
2242 sub cmd_remote_push_build_host {
2243     my ($nrargs) = shift @ARGV;
2244     my (@rargs) = @ARGV[0..$nrargs-1];
2245     @ARGV = @ARGV[$nrargs..$#ARGV];
2246     die unless @rargs;
2247     my ($dir,$vsnwant) = @rargs;
2248     # vsnwant is a comma-separated list; we report which we have
2249     # chosen in our ready response (so other end can tell if they
2250     # offered several)
2251     $debugprefix = ' ';
2252     $we_are_responder = 1;
2253     $us .= " (build host)";
2254
2255     pushing();
2256
2257     open PI, "<&STDIN" or die $!;
2258     open STDIN, "/dev/null" or die $!;
2259     open PO, ">&STDOUT" or die $!;
2260     autoflush PO 1;
2261     open STDOUT, ">&STDERR" or die $!;
2262     autoflush STDOUT 1;
2263
2264     $vsnwant //= 1;
2265     ($protovsn) = grep {
2266         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2267     } @rpushprotovsn_support;
2268
2269     fail "build host has dgit rpush protocol versions ".
2270         (join ",", @rpushprotovsn_support).
2271         " but invocation host has $vsnwant"
2272         unless defined $protovsn;
2273
2274     responder_send_command("dgit-remote-push-ready $protovsn");
2275
2276     changedir $dir;
2277     &cmd_push;
2278 }
2279
2280 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
2281 # ... for compatibility with proto vsn.1 dgit (just so that user gets
2282 #     a good error message)
2283
2284 our $i_tmp;
2285
2286 sub i_cleanup {
2287     local ($@, $?);
2288     my $report = i_child_report();
2289     if (defined $report) {
2290         printdebug "($report)\n";
2291     } elsif ($i_child_pid) {
2292         printdebug "(killing build host child $i_child_pid)\n";
2293         kill 15, $i_child_pid;
2294     }
2295     if (defined $i_tmp && !defined $initiator_tempdir) {
2296         changedir "/";
2297         eval { rmtree $i_tmp; };
2298     }
2299 }
2300
2301 END { i_cleanup(); }
2302
2303 sub i_method {
2304     my ($base,$selector,@args) = @_;
2305     $selector =~ s/\-/_/g;
2306     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
2307 }
2308
2309 sub cmd_rpush {
2310     pushing();
2311     my $host = nextarg;
2312     my $dir;
2313     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
2314         $host = $1;
2315         $dir = $'; #';
2316     } else {
2317         $dir = nextarg;
2318     }
2319     $dir =~ s{^-}{./-};
2320     my @rargs = ($dir);
2321     push @rargs, join ",", @rpushprotovsn_support;
2322     my @rdgit;
2323     push @rdgit, @dgit;
2324     push @rdgit, @ropts;
2325     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
2326     push @rdgit, @ARGV;
2327     my @cmd = (@ssh, $host, shellquote @rdgit);
2328     debugcmd "+",@cmd;
2329
2330     if (defined $initiator_tempdir) {
2331         rmtree $initiator_tempdir;
2332         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
2333         $i_tmp = $initiator_tempdir;
2334     } else {
2335         $i_tmp = tempdir();
2336     }
2337     $i_child_pid = open2(\*RO, \*RI, @cmd);
2338     changedir $i_tmp;
2339     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
2340     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
2341     $supplementary_message = '' unless $protovsn >= 3;
2342     for (;;) {
2343         my ($icmd,$iargs) = initiator_expect {
2344             m/^(\S+)(?: (.*))?$/;
2345             ($1,$2);
2346         };
2347         i_method "i_resp", $icmd, $iargs;
2348     }
2349 }
2350
2351 sub i_resp_progress ($) {
2352     my ($rhs) = @_;
2353     my $msg = protocol_read_bytes \*RO, $rhs;
2354     progress $msg;
2355 }
2356
2357 sub i_resp_supplementary_message ($) {
2358     my ($rhs) = @_;
2359     $supplementary_message = protocol_read_bytes \*RO, $rhs;
2360 }
2361
2362 sub i_resp_complete {
2363     my $pid = $i_child_pid;
2364     $i_child_pid = undef; # prevents killing some other process with same pid
2365     printdebug "waiting for build host child $pid...\n";
2366     my $got = waitpid $pid, 0;
2367     die $! unless $got == $pid;
2368     die "build host child failed $?" if $?;
2369
2370     i_cleanup();
2371     printdebug "all done\n";
2372     exit 0;
2373 }
2374
2375 sub i_resp_file ($) {
2376     my ($keyword) = @_;
2377     my $localname = i_method "i_localname", $keyword;
2378     my $localpath = "$i_tmp/$localname";
2379     stat_exists $localpath and
2380         badproto \*RO, "file $keyword ($localpath) twice";
2381     protocol_receive_file \*RO, $localpath;
2382     i_method "i_file", $keyword;
2383 }
2384
2385 our %i_param;
2386
2387 sub i_resp_param ($) {
2388     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2389     $i_param{$1} = $2;
2390 }
2391
2392 sub i_resp_previously ($) {
2393     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2394         or badproto \*RO, "bad previously spec";
2395     my $r = system qw(git check-ref-format), $1;
2396     die "bad previously ref spec ($r)" if $r;
2397     $previously{$1} = $2;
2398 }
2399
2400 our %i_wanted;
2401
2402 sub i_resp_want ($) {
2403     my ($keyword) = @_;
2404     die "$keyword ?" if $i_wanted{$keyword}++;
2405     my @localpaths = i_method "i_want", $keyword;
2406     printdebug "[[  $keyword @localpaths\n";
2407     foreach my $localpath (@localpaths) {
2408         protocol_send_file \*RI, $localpath;
2409     }
2410     print RI "files-end\n" or die $!;
2411 }
2412
2413 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2414
2415 sub i_localname_parsed_changelog {
2416     return "remote-changelog.822";
2417 }
2418 sub i_file_parsed_changelog {
2419     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2420         push_parse_changelog "$i_tmp/remote-changelog.822";
2421     die if $i_dscfn =~ m#/|^\W#;
2422 }
2423
2424 sub i_localname_dsc {
2425     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2426     return $i_dscfn;
2427 }
2428 sub i_file_dsc { }
2429
2430 sub i_localname_changes {
2431     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2432     $i_changesfn = $i_dscfn;
2433     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2434     return $i_changesfn;
2435 }
2436 sub i_file_changes { }
2437
2438 sub i_want_signed_tag {
2439     printdebug Dumper(\%i_param, $i_dscfn);
2440     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2441         && defined $i_param{'csuite'}
2442         or badproto \*RO, "premature desire for signed-tag";
2443     my $head = $i_param{'head'};
2444     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2445
2446     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2447     $csuite = $&;
2448     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2449
2450     my $tagobjfn =
2451         push_mktag $head, $i_clogp, $i_tag,
2452             $i_dscfn,
2453             $i_changesfn, 'remote changes',
2454             sub { "tag$_[0]"; };
2455
2456     return $tagobjfn;
2457 }
2458
2459 sub i_want_signed_dsc_changes {
2460     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2461     sign_changes $i_changesfn;
2462     return ($i_dscfn, $i_changesfn);
2463 }
2464
2465 #---------- building etc. ----------
2466
2467 our $version;
2468 our $sourcechanges;
2469 our $dscfn;
2470
2471 #----- `3.0 (quilt)' handling -----
2472
2473 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2474
2475 sub quiltify_dpkg_commit ($$$;$) {
2476     my ($patchname,$author,$msg, $xinfo) = @_;
2477     $xinfo //= '';
2478
2479     mkpath '.git/dgit';
2480     my $descfn = ".git/dgit/quilt-description.tmp";
2481     open O, '>', $descfn or die "$descfn: $!";
2482     $msg =~ s/\s+$//g;
2483     $msg =~ s/\n/\n /g;
2484     $msg =~ s/^\s+$/ ./mg;
2485     print O <<END or die $!;
2486 Description: $msg
2487 Author: $author
2488 $xinfo
2489 ---
2490
2491 END
2492     close O or die $!;
2493
2494     {
2495         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2496         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2497         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2498         runcmd @dpkgsource, qw(--commit .), $patchname;
2499     }
2500 }
2501
2502 sub quiltify_trees_differ ($$) {
2503     my ($x,$y) = @_;
2504     # returns 1 iff the two tree objects differ other than in debian/
2505     local $/=undef;
2506     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2507     my $diffs= cmdoutput @cmd;
2508     foreach my $f (split /\0/, $diffs) {
2509         next if $f eq 'debian';
2510         return 1;
2511     }
2512     return 0;
2513 }
2514
2515 sub quiltify_tree_sentinelfiles ($) {
2516     # lists the `sentinel' files present in the tree
2517     my ($x) = @_;
2518     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2519         qw(-- debian/rules debian/control);
2520     $r =~ s/\n/,/g;
2521     return $r;
2522 }
2523
2524 sub quiltify ($$) {
2525     my ($clogp,$target) = @_;
2526
2527     # Quilt patchification algorithm
2528     #
2529     # We search backwards through the history of the main tree's HEAD
2530     # (T) looking for a start commit S whose tree object is identical
2531     # to to the patch tip tree (ie the tree corresponding to the
2532     # current dpkg-committed patch series).  For these purposes
2533     # `identical' disregards anything in debian/ - this wrinkle is
2534     # necessary because dpkg-source treates debian/ specially.
2535     #
2536     # We can only traverse edges where at most one of the ancestors'
2537     # trees differs (in changes outside in debian/).  And we cannot
2538     # handle edges which change .pc/ or debian/patches.  To avoid
2539     # going down a rathole we avoid traversing edges which introduce
2540     # debian/rules or debian/control.  And we set a limit on the
2541     # number of edges we are willing to look at.
2542     #
2543     # If we succeed, we walk forwards again.  For each traversed edge
2544     # PC (with P parent, C child) (starting with P=S and ending with
2545     # C=T) to we do this:
2546     #  - git checkout C
2547     #  - dpkg-source --commit with a patch name and message derived from C
2548     # After traversing PT, we git commit the changes which
2549     # should be contained within debian/patches.
2550
2551     changedir '../fake';
2552     remove_stray_gits();
2553     mktree_in_ud_here();
2554     rmtree '.pc';
2555     runcmd @git, qw(add -Af .);
2556     my $oldtiptree=git_write_tree();
2557     changedir '../work';
2558
2559     # The search for the path S..T is breadth-first.  We maintain a
2560     # todo list containing search nodes.  A search node identifies a
2561     # commit, and looks something like this:
2562     #  $p = {
2563     #      Commit => $git_commit_id,
2564     #      Child => $c,                          # or undef if P=T
2565     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2566     #      Nontrivial => true iff $p..$c has relevant changes
2567     #  };
2568
2569     my @todo;
2570     my @nots;
2571     my $sref_S;
2572     my $max_work=100;
2573     my %considered; # saves being exponential on some weird graphs
2574
2575     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2576
2577     my $not = sub {
2578         my ($search,$whynot) = @_;
2579         printdebug " search NOT $search->{Commit} $whynot\n";
2580         $search->{Whynot} = $whynot;
2581         push @nots, $search;
2582         no warnings qw(exiting);
2583         next;
2584     };
2585
2586     push @todo, {
2587         Commit => $target,
2588     };
2589
2590     while (@todo) {
2591         my $c = shift @todo;
2592         next if $considered{$c->{Commit}}++;
2593
2594         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2595
2596         printdebug "quiltify investigate $c->{Commit}\n";
2597
2598         # are we done?
2599         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2600             printdebug " search finished hooray!\n";
2601             $sref_S = $c;
2602             last;
2603         }
2604
2605         if ($quilt_mode eq 'nofix') {
2606             fail "quilt fixup required but quilt mode is \`nofix'\n".
2607                 "HEAD commit $c->{Commit} differs from tree implied by ".
2608                 " debian/patches (tree object $oldtiptree)";
2609         }
2610         if ($quilt_mode eq 'smash') {
2611             printdebug " search quitting smash\n";
2612             last;
2613         }
2614
2615         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2616         $not->($c, "has $c_sentinels not $t_sentinels")
2617             if $c_sentinels ne $t_sentinels;
2618
2619         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2620         $commitdata =~ m/\n\n/;
2621         $commitdata =~ $`;
2622         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2623         @parents = map { { Commit => $_, Child => $c } } @parents;
2624
2625         $not->($c, "root commit") if !@parents;
2626
2627         foreach my $p (@parents) {
2628             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2629         }
2630         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2631         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2632
2633         foreach my $p (@parents) {
2634             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2635
2636             my @cmd= (@git, qw(diff-tree -r --name-only),
2637                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2638             my $patchstackchange = cmdoutput @cmd;
2639             if (length $patchstackchange) {
2640                 $patchstackchange =~ s/\n/,/g;
2641                 $not->($p, "changed $patchstackchange");
2642             }
2643
2644             printdebug " search queue P=$p->{Commit} ",
2645                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2646             push @todo, $p;
2647         }
2648     }
2649
2650     if (!$sref_S) {
2651         printdebug "quiltify want to smash\n";
2652
2653         my $abbrev = sub {
2654             my $x = $_[0]{Commit};
2655             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2656             return $x;
2657         };
2658         my $reportnot = sub {
2659             my ($notp) = @_;
2660             my $s = $abbrev->($notp);
2661             my $c = $notp->{Child};
2662             $s .= "..".$abbrev->($c) if $c;
2663             $s .= ": ".$notp->{Whynot};
2664             return $s;
2665         };
2666         if ($quilt_mode eq 'linear') {
2667             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2668             foreach my $notp (@nots) {
2669                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2670             }
2671             fail "quilt fixup naive history linearisation failed.\n".
2672  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2673         } elsif ($quilt_mode eq 'smash') {
2674         } elsif ($quilt_mode eq 'auto') {
2675             progress "quilt fixup cannot be linear, smashing...";
2676         } else {
2677             die "$quilt_mode ?";
2678         }
2679
2680         my $time = time;
2681         my $ncommits = 3;
2682         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2683
2684         quiltify_dpkg_commit "auto-$version-$target-$time",
2685             (getfield $clogp, 'Maintainer'),
2686             "Automatically generated patch ($clogp->{Version})\n".
2687             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2688         return;
2689     }
2690
2691     progress "quiltify linearisation planning successful, executing...";
2692
2693     for (my $p = $sref_S;
2694          my $c = $p->{Child};
2695          $p = $p->{Child}) {
2696         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2697         next unless $p->{Nontrivial};
2698
2699         my $cc = $c->{Commit};
2700
2701         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2702         $commitdata =~ m/\n\n/ or die "$c ?";
2703         $commitdata = $`;
2704         my $msg = $'; #';
2705         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2706         my $author = $1;
2707
2708         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2709
2710         my $title = $1;
2711         my $patchname = $title;
2712         $patchname =~ s/[.:]$//;
2713         $patchname =~ y/ A-Z/-a-z/;
2714         $patchname =~ y/-a-z0-9_.+=~//cd;
2715         $patchname =~ s/^\W/x-$&/;
2716         $patchname = substr($patchname,0,40);
2717         my $index;
2718         for ($index='';
2719              stat "debian/patches/$patchname$index";
2720              $index++) { }
2721         $!==ENOENT or die "$patchname$index $!";
2722
2723         runcmd @git, qw(checkout -q), $cc;
2724
2725         # We use the tip's changelog so that dpkg-source doesn't
2726         # produce complaining messages from dpkg-parsechangelog.  None
2727         # of the information dpkg-source gets from the changelog is
2728         # actually relevant - it gets put into the original message
2729         # which dpkg-source provides our stunt editor, and then
2730         # overwritten.
2731         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2732
2733         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2734             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2735
2736         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2737     }
2738
2739     runcmd @git, qw(checkout -q master);
2740 }
2741
2742 sub build_maybe_quilt_fixup () {
2743     my ($format,$fopts) = get_source_format;
2744     return unless madformat $format;
2745     # sigh
2746
2747     check_for_vendor_patches();
2748
2749     my $clogp = parsechangelog();
2750     my $headref = git_rev_parse('HEAD');
2751
2752     prep_ud();
2753     changedir $ud;
2754
2755     my $upstreamversion=$version;
2756     $upstreamversion =~ s/-[^-]*$//;
2757
2758     if ($fopts->{'single-debian-patch'}) {
2759         quilt_fixup_singlepatch($clogp, $headref, $upstreamversion);
2760     } else {
2761         quilt_fixup_multipatch($clogp, $headref, $upstreamversion);
2762     }
2763
2764     changedir '../../../..';
2765     runcmd_ordryrun_local
2766         @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2767 }
2768
2769 sub quilt_fixup_mkwork ($) {
2770     my ($headref) = @_;
2771
2772     mkdir "work" or die $!;
2773     changedir "work";
2774     mktree_in_ud_here();
2775     runcmd @git, qw(reset --hard), $headref;
2776 }
2777
2778 sub quilt_fixup_linkorigs ($$) {
2779     my ($upstreamversion, $fn) = @_;
2780     # calls $fn->($leafname);
2781
2782     foreach my $f (<../../../../*>) { #/){
2783         my $b=$f; $b =~ s{.*/}{};
2784         {
2785             local ($debuglevel) = $debuglevel-1;
2786             printdebug "QF linkorigs $b, $f ?\n";
2787         }
2788         next unless is_orig_file $b, srcfn $upstreamversion,'';
2789         printdebug "QF linkorigs $b, $f Y\n";
2790         link_ltarget $f, $b or die "$b $!";
2791         $fn->($b);
2792     }
2793 }
2794
2795 sub quilt_fixup_delete_pc () {
2796     runcmd @git, qw(rm -rqf .pc);
2797     commit_admin "Commit removal of .pc (quilt series tracking data)";
2798 }
2799
2800 sub quilt_fixup_singlepatch ($$$) {
2801     my ($clogp, $headref, $upstreamversion) = @_;
2802
2803     # dpkg-source --commit generates new patches even if
2804     # single-debian-patch is in debian/source/options.  In order to
2805     # get it to generate debian/patches/debian-changes, it is
2806     # necessary to build the source package.
2807
2808     quilt_fixup_linkorigs($upstreamversion, sub { });
2809     quilt_fixup_mkwork($headref);
2810
2811     rmtree("debian/patches");
2812
2813     runcmd @dpkgsource, qw(-b .);
2814     chdir "..";
2815     runcmd @dpkgsource, qw(-x), (srcfn $version, ".dsc");
2816     rename srcfn("$upstreamversion", "/debian/patches"),
2817            "work/debian/patches";
2818
2819     chdir "work";
2820     commit_quilty_patch();
2821
2822
2823 }
2824
2825 sub quilt_fixup_multipatch ($$$) {
2826     my ($clogp, $headref, $upstreamversion) = @_;
2827
2828     # Our objective is:
2829     #  - honour any existing .pc in case it has any strangeness
2830     #  - determine the git commit corresponding to the tip of
2831     #    the patch stack (if there is one)
2832     #  - if there is such a git commit, convert each subsequent
2833     #    git commit into a quilt patch with dpkg-source --commit
2834     #  - otherwise convert all the differences in the tree into
2835     #    a single git commit
2836     #
2837     # To do this we:
2838
2839     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2840     # dgit would include the .pc in the git tree.)  If there isn't
2841     # one, we need to generate one by unpacking the patches that we
2842     # have.
2843     #
2844     # We first look for a .pc in the git tree.  If there is one, we
2845     # will use it.  (This is not the normal case.)
2846     #
2847     # Otherwise need to regenerate .pc so that dpkg-source --commit
2848     # can work.  We do this as follows:
2849     #     1. Collect all relevant .orig from parent directory
2850     #     2. Generate a debian.tar.gz out of
2851     #         debian/{patches,rules,source/format,source/options}
2852     #     3. Generate a fake .dsc containing just these fields:
2853     #          Format Source Version Files
2854     #     4. Extract the fake .dsc
2855     #        Now the fake .dsc has a .pc directory.
2856     # (In fact we do this in every case, because in future we will
2857     # want to search for a good base commit for generating patches.)
2858     #
2859     # Then we can actually do the dpkg-source --commit
2860     #     1. Make a new working tree with the same object
2861     #        store as our main tree and check out the main
2862     #        tree's HEAD.
2863     #     2. Copy .pc from the fake's extraction, if necessary
2864     #     3. Run dpkg-source --commit
2865     #     4. If the result has changes to debian/, then
2866     #          - git-add them them
2867     #          - git-add .pc if we had a .pc in-tree
2868     #          - git-commit
2869     #     5. If we had a .pc in-tree, delete it, and git-commit
2870     #     6. Back in the main tree, fast forward to the new HEAD
2871
2872     my $fakeversion="$upstreamversion-~~DGITFAKE";
2873
2874     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2875     print $fakedsc <<END or die $!;
2876 Format: 3.0 (quilt)
2877 Source: $package
2878 Version: $fakeversion
2879 Files:
2880 END
2881
2882     my $dscaddfile=sub {
2883         my ($b) = @_;
2884
2885         my $md = new Digest::MD5;
2886
2887         my $fh = new IO::File $b, '<' or die "$b $!";
2888         stat $fh or die $!;
2889         my $size = -s _;
2890
2891         $md->addfile($fh);
2892         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2893     };
2894
2895     quilt_fixup_linkorigs($upstreamversion, $dscaddfile);
2896
2897     my @files=qw(debian/source/format debian/rules);
2898     foreach my $maybe (qw(debian/patches debian/source/options)) {
2899         next unless stat_exists "../../../$maybe";
2900         push @files, $maybe;
2901     }
2902
2903     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2904     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2905
2906     $dscaddfile->($debtar);
2907     close $fakedsc or die $!;
2908
2909     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2910
2911     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2912     rename $fakexdir, "fake" or die "$fakexdir $!";
2913
2914     quilt_fixup_mkwork($headref);
2915
2916     my $mustdeletepc=0;
2917     if (stat_exists ".pc") {
2918         -d _ or die;
2919         progress "Tree already contains .pc - will use it then delete it.";
2920         $mustdeletepc=1;
2921     } else {
2922         rename '../fake/.pc','.pc' or die $!;
2923     }
2924
2925     quiltify($clogp,$headref);
2926
2927     if (!open P, '>>', ".pc/applied-patches") {
2928         $!==&ENOENT or die $!;
2929     } else {
2930         close P;
2931     }
2932
2933     commit_quilty_patch();
2934
2935     if ($mustdeletepc) {
2936         quilt_fixup_delete_pc();
2937     }
2938 }
2939
2940 sub quilt_fixup_editor () {
2941     my $descfn = $ENV{$fakeeditorenv};
2942     my $editing = $ARGV[$#ARGV];
2943     open I1, '<', $descfn or die "$descfn: $!";
2944     open I2, '<', $editing or die "$editing: $!";
2945     unlink $editing or die "$editing: $!";
2946     open O, '>', $editing or die "$editing: $!";
2947     while (<I1>) { print O or die $!; } I1->error and die $!;
2948     my $copying = 0;
2949     while (<I2>) {
2950         $copying ||= m/^\-\-\- /;
2951         next unless $copying;
2952         print O or die $!;
2953     }
2954     I2->error and die $!;
2955     close O or die $1;
2956     exit 0;
2957 }
2958
2959 #----- other building -----
2960
2961 our $suppress_clean;
2962
2963 sub clean_tree () {
2964     return if $suppress_clean;
2965     if ($cleanmode eq 'dpkg-source') {
2966         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2967     } elsif ($cleanmode eq 'dpkg-source-d') {
2968         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
2969     } elsif ($cleanmode eq 'git') {
2970         runcmd_ordryrun_local @git, qw(clean -xdf);
2971     } elsif ($cleanmode eq 'git-ff') {
2972         runcmd_ordryrun_local @git, qw(clean -xdff);
2973     } elsif ($cleanmode eq 'check') {
2974         my $leftovers = cmdoutput @git, qw(clean -xdn);
2975         if (length $leftovers) {
2976             print STDERR $leftovers, "\n" or die $!;
2977             fail "tree contains uncommitted files and --clean=check specified";
2978         }
2979     } elsif ($cleanmode eq 'none') {
2980     } else {
2981         die "$cleanmode ?";
2982     }
2983 }
2984
2985 sub cmd_clean () {
2986     badusage "clean takes no additional arguments" if @ARGV;
2987     notpushing();
2988     clean_tree();
2989 }
2990
2991 sub build_prep () {
2992     notpushing();
2993     badusage "-p is not allowed when building" if defined $package;
2994     check_not_dirty();
2995     clean_tree();
2996     my $clogp = parsechangelog();
2997     $isuite = getfield $clogp, 'Distribution';
2998     $package = getfield $clogp, 'Source';
2999     $version = getfield $clogp, 'Version';
3000     build_maybe_quilt_fixup();
3001 }
3002
3003 sub changesopts_initial () {
3004     my @opts =@changesopts[1..$#changesopts];
3005 }
3006
3007 sub changesopts_version () {
3008     if (!defined $changes_since_version) {
3009         my @vsns = archive_query('archive_query');
3010         my @quirk = access_quirk();
3011         if ($quirk[0] eq 'backports') {
3012             local $isuite = $quirk[2];
3013             local $csuite;
3014             canonicalise_suite();
3015             push @vsns, archive_query('archive_query');
3016         }
3017         if (@vsns) {
3018             @vsns = map { $_->[0] } @vsns;
3019             @vsns = sort { -version_compare($a, $b) } @vsns;
3020             $changes_since_version = $vsns[0];
3021             progress "changelog will contain changes since $vsns[0]";
3022         } else {
3023             $changes_since_version = '_';
3024             progress "package seems new, not specifying -v<version>";
3025         }
3026     }
3027     if ($changes_since_version ne '_') {
3028         return ("-v$changes_since_version");
3029     } else {
3030         return ();
3031     }
3032 }
3033
3034 sub changesopts () {
3035     return (changesopts_initial(), changesopts_version());
3036 }
3037
3038 sub massage_dbp_args ($;$) {
3039     my ($cmd,$xargs) = @_;
3040     if ($cleanmode eq 'dpkg-source') {
3041         $suppress_clean = 1;
3042         return;
3043     }
3044     debugcmd '#massaging#', @$cmd if $debuglevel>1;
3045     my @newcmd = shift @$cmd;
3046     # -nc has the side effect of specifying -b if nothing else specified
3047     push @newcmd, '-nc';
3048     # and some combinations of -S, -b, et al, are errors, rather than
3049     # later simply overriding earlier
3050     push @newcmd, '-F' unless grep { m/^-[bBASF]$/ } (@$cmd, @$xargs);
3051     push @newcmd, @$cmd;
3052     @$cmd = @newcmd;
3053 }
3054
3055 sub cmd_build {
3056     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
3057     massage_dbp_args \@dbp;
3058     build_prep();
3059     push @dbp, changesopts_version();
3060     runcmd_ordryrun_local @dbp;
3061     printdone "build successful\n";
3062 }
3063
3064 sub cmd_gbp_build {
3065     my @dbp = @dpkgbuildpackage;
3066     massage_dbp_args \@dbp, \@ARGV;
3067
3068     my @cmd;
3069     if (length executable_on_path('git-buildpackage')) {
3070         @cmd = qw(git-buildpackage);
3071     } else {
3072         @cmd = qw(gbp buildpackage);
3073     }
3074     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
3075
3076     if ($cleanmode eq 'dpkg-source') {
3077         $suppress_clean = 1;
3078     } else {
3079         push @cmd, '--git-cleaner=true';
3080     }
3081     build_prep();
3082     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
3083         canonicalise_suite();
3084         push @cmd, "--git-debian-branch=".lbranch();
3085     }
3086     push @cmd, changesopts();
3087     runcmd_ordryrun_local @cmd, @ARGV;
3088     printdone "build successful\n";
3089 }
3090 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
3091
3092 sub build_source {
3093     if ($cleanmode =~ m/^dpkg-source/) {
3094         # dpkg-source will clean, so we shouldn't
3095         $suppress_clean = 1;
3096     }
3097     build_prep();
3098     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
3099     $dscfn = dscfn($version);
3100     if ($cleanmode eq 'dpkg-source') {
3101         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
3102             changesopts();
3103     } elsif ($cleanmode eq 'dpkg-source-d') {
3104         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S -d)),
3105             changesopts();
3106     } else {
3107         my $pwd = must_getcwd();
3108         my $leafdir = basename $pwd;
3109         changedir "..";
3110         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
3111         changedir $pwd;
3112         runcmd_ordryrun_local qw(sh -ec),
3113             'exec >$1; shift; exec "$@"','x',
3114             "../$sourcechanges",
3115             @dpkggenchanges, qw(-S), changesopts();
3116     }
3117 }
3118
3119 sub cmd_build_source {
3120     badusage "build-source takes no additional arguments" if @ARGV;
3121     build_source();
3122     printdone "source built, results in $dscfn and $sourcechanges";
3123 }
3124
3125 sub cmd_sbuild {
3126     build_source();
3127     changedir "..";
3128     my $pat = "${package}_".(stripepoch $version)."_*.changes";
3129     if (act_local()) {
3130         stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
3131         stat_exists $sourcechanges
3132             or fail "$sourcechanges (in parent directory): $!";
3133         foreach my $cf (glob $pat) {
3134             next if $cf eq $sourcechanges;
3135             unlink $cf or fail "remove $cf: $!";
3136         }
3137     }
3138     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
3139     my @changesfiles = glob $pat;
3140     @changesfiles = sort {
3141         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
3142             or $a cmp $b
3143     } @changesfiles;
3144     fail "wrong number of different changes files (@changesfiles)"
3145         unless @changesfiles;
3146     runcmd_ordryrun_local @mergechanges, @changesfiles;
3147     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
3148     if (act_local()) {
3149         stat_exists $multichanges or fail "$multichanges: $!";
3150     }
3151     printdone "build successful, results in $multichanges\n" or die $!;
3152 }
3153
3154 sub cmd_quilt_fixup {
3155     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
3156     my $clogp = parsechangelog();
3157     $version = getfield $clogp, 'Version';
3158     $package = getfield $clogp, 'Source';
3159     build_maybe_quilt_fixup();
3160 }
3161
3162 sub cmd_archive_api_query {
3163     badusage "need only 1 subpath argument" unless @ARGV==1;
3164     my ($subpath) = @ARGV;
3165     my @cmd = archive_api_query_cmd($subpath);
3166     debugcmd ">",@cmd;
3167     exec @cmd or fail "exec curl: $!\n";
3168 }
3169
3170 sub cmd_clone_dgit_repos_server {
3171     badusage "need destination argument" unless @ARGV==1;
3172     my ($destdir) = @ARGV;
3173     $package = '_dgit-repos-server';
3174     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
3175     debugcmd ">",@cmd;
3176     exec @cmd or fail "exec git clone: $!\n";
3177 }
3178
3179 sub cmd_setup_mergechangelogs {
3180     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3181     setup_mergechangelogs(1);
3182 }
3183
3184 sub cmd_setup_useremail {
3185     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3186     setup_useremail(1);
3187 }
3188
3189 sub cmd_setup_new_tree {
3190     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
3191     setup_new_tree();
3192 }
3193
3194 #---------- argument parsing and main program ----------
3195
3196 sub cmd_version {
3197     print "dgit version $our_version\n" or die $!;
3198     exit 0;
3199 }
3200
3201 our (%valopts_long, %valopts_short);
3202 our @rvalopts;
3203
3204 sub defvalopt ($$$$) {
3205     my ($long,$short,$val_re,$how) = @_;
3206     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
3207     $valopts_long{$long} = $oi;
3208     $valopts_short{$short} = $oi;
3209     # $how subref should:
3210     #   do whatever assignemnt or thing it likes with $_[0]
3211     #   if the option should not be passed on to remote, @rvalopts=()
3212     # or $how can be a scalar ref, meaning simply assign the value
3213 }
3214
3215 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
3216 defvalopt '--distro',        '-d', '.+',      \$idistro;
3217 defvalopt '',                '-k', '.+',      \$keyid;
3218 defvalopt '--existing-package','', '.*',      \$existing_package;
3219 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
3220 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
3221 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
3222
3223 defvalopt '', '-c', '.*=.*', sub { push @git, '-c', @_; };
3224
3225 defvalopt '', '-C', '.+', sub {
3226     ($changesfile) = (@_);
3227     if ($changesfile =~ s#^(.*)/##) {
3228         $buildproductsdir = $1;
3229     }
3230 };
3231
3232 defvalopt '--initiator-tempdir','','.*', sub {
3233     ($initiator_tempdir) = (@_);
3234     $initiator_tempdir =~ m#^/# or
3235         badusage "--initiator-tempdir must be used specify an".
3236         " absolute, not relative, directory."
3237 };
3238
3239 sub parseopts () {
3240     my $om;
3241
3242     if (defined $ENV{'DGIT_SSH'}) {
3243         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
3244     } elsif (defined $ENV{'GIT_SSH'}) {
3245         @ssh = ($ENV{'GIT_SSH'});
3246     }
3247
3248     my $oi;
3249     my $val;
3250     my $valopt = sub {
3251         my ($what) = @_;
3252         @rvalopts = ($_);
3253         if (!defined $val) {
3254             badusage "$what needs a value" unless @ARGV;
3255             $val = shift @ARGV;
3256             push @rvalopts, $val;
3257         }
3258         badusage "bad value \`$val' for $what" unless
3259             $val =~ m/^$oi->{Re}$(?!\n)/s;
3260         my $how = $oi->{How};
3261         if (ref($how) eq 'SCALAR') {
3262             $$how = $val;
3263         } else {
3264             $how->($val);
3265         }
3266         push @ropts, @rvalopts;
3267     };
3268
3269     while (@ARGV) {
3270         last unless $ARGV[0] =~ m/^-/;
3271         $_ = shift @ARGV;
3272         last if m/^--?$/;
3273         if (m/^--/) {
3274             if (m/^--dry-run$/) {
3275                 push @ropts, $_;
3276                 $dryrun_level=2;
3277             } elsif (m/^--damp-run$/) {
3278                 push @ropts, $_;
3279                 $dryrun_level=1;
3280             } elsif (m/^--no-sign$/) {
3281                 push @ropts, $_;
3282                 $sign=0;
3283             } elsif (m/^--help$/) {
3284                 cmd_help();
3285             } elsif (m/^--version$/) {
3286                 cmd_version();
3287             } elsif (m/^--new$/) {
3288                 push @ropts, $_;
3289                 $new_package=1;
3290             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
3291                      ($om = $opts_opt_map{$1}) &&
3292                      length $om->[0]) {
3293                 push @ropts, $_;
3294                 $om->[0] = $2;
3295             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
3296                      !$opts_opt_cmdonly{$1} &&
3297                      ($om = $opts_opt_map{$1})) {
3298                 push @ropts, $_;
3299                 push @$om, $2;
3300             } elsif (m/^--ignore-dirty$/s) {
3301                 push @ropts, $_;
3302                 $ignoredirty = 1;
3303             } elsif (m/^--no-quilt-fixup$/s) {
3304                 push @ropts, $_;
3305                 $quilt_mode = 'nocheck';
3306             } elsif (m/^--no-rm-on-error$/s) {
3307                 push @ropts, $_;
3308                 $rmonerror = 0;
3309             } elsif (m/^--deliberately-($deliberately_re)$/s) {
3310                 push @ropts, $_;
3311                 push @deliberatelies, $&;
3312             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
3313                 $val = $2 ? $' : undef; #';
3314                 $valopt->($oi->{Long});
3315             } else {
3316                 badusage "unknown long option \`$_'";
3317             }
3318         } else {
3319             while (m/^-./s) {
3320                 if (s/^-n/-/) {
3321                     push @ropts, $&;
3322                     $dryrun_level=2;
3323                 } elsif (s/^-L/-/) {
3324                     push @ropts, $&;
3325                     $dryrun_level=1;
3326                 } elsif (s/^-h/-/) {
3327                     cmd_help();
3328                 } elsif (s/^-D/-/) {
3329                     push @ropts, $&;
3330                     $debuglevel++;
3331                     enabledebug();
3332                 } elsif (s/^-N/-/) {
3333                     push @ropts, $&;
3334                     $new_package=1;
3335                 } elsif (m/^-m/) {
3336                     push @ropts, $&;
3337                     push @changesopts, $_;
3338                     $_ = '';
3339                 } elsif (s/^-wn$//s) {
3340                     push @ropts, $&;
3341                     $cleanmode = 'none';
3342                 } elsif (s/^-wg$//s) {
3343                     push @ropts, $&;
3344                     $cleanmode = 'git';
3345                 } elsif (s/^-wgf$//s) {
3346                     push @ropts, $&;
3347                     $cleanmode = 'git-ff';
3348                 } elsif (s/^-wd$//s) {
3349                     push @ropts, $&;
3350                     $cleanmode = 'dpkg-source';
3351                 } elsif (s/^-wdd$//s) {
3352                     push @ropts, $&;
3353                     $cleanmode = 'dpkg-source-d';
3354                 } elsif (s/^-wc$//s) {
3355                     push @ropts, $&;
3356                     $cleanmode = 'check';
3357                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
3358                     $val = $'; #';
3359                     $val = undef unless length $val;
3360                     $valopt->($oi->{Short});
3361                     $_ = '';
3362                 } else {
3363                     badusage "unknown short option \`$_'";
3364                 }
3365             }
3366         }
3367     }
3368 }
3369
3370 sub finalise_opts_opts () {
3371     foreach my $k (keys %opts_opt_map) {
3372         my $om = $opts_opt_map{$k};
3373
3374         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
3375         if (defined $v) {
3376             badcfg "cannot set command for $k"
3377                 unless length $om->[0];
3378             $om->[0] = $v;
3379         }
3380
3381         foreach my $c (access_cfg_cfgs("opts-$k")) {
3382             my $vl = $gitcfg{$c};
3383             printdebug "CL $c ",
3384                 ($vl ? join " ", map { shellquote } @$vl : ""),
3385                 "\n" if $debuglevel >= 4;
3386             next unless $vl;
3387             badcfg "cannot configure options for $k"
3388                 if $opts_opt_cmdonly{$k};
3389             my $insertpos = $opts_cfg_insertpos{$k};
3390             @$om = ( @$om[0..$insertpos-1],
3391                      @$vl,
3392                      @$om[$insertpos..$#$om] );
3393         }
3394     }
3395 }
3396
3397 if ($ENV{$fakeeditorenv}) {
3398     git_slurp_config();
3399     quilt_fixup_editor();
3400 }
3401
3402 parseopts();
3403 git_slurp_config();
3404
3405 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
3406 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
3407     if $dryrun_level == 1;
3408 if (!@ARGV) {
3409     print STDERR $helpmsg or die $!;
3410     exit 8;
3411 }
3412 my $cmd = shift @ARGV;
3413 $cmd =~ y/-/_/;
3414
3415 if (!defined $quilt_mode) {
3416     local $access_forpush;
3417     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
3418         // access_cfg('quilt-mode', 'RETURN-UNDEF')
3419         // 'linear';
3420     $quilt_mode =~ m/^($quilt_modes_re)$/
3421         or badcfg "unknown quilt-mode \`$quilt_mode'";
3422     $quilt_mode = $1;
3423 }
3424
3425 if (!defined $cleanmode) {
3426     local $access_forpush;
3427     $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
3428     $cleanmode //= 'dpkg-source';
3429
3430     badcfg "unknown clean-mode \`$cleanmode'" unless
3431         $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
3432 }
3433
3434 my $fn = ${*::}{"cmd_$cmd"};
3435 $fn or badusage "unknown operation $cmd";
3436 $fn->();