dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Basename;
  28 use Dpkg::Version;
  29 use POSIX;
  30
  31 our $isuite = 'unstable';
  32 our $idistro;
  33 our $package;
  34
  35 our $sign = 1;
  36 our $dryrun = 0;
  37 our $changesfile;
  38 our $new_package = 0;
  39 our $ignoredirty = 0;
  40 our $noquilt = 0;
  41 our $existing_package = 'dpkg';
  42 our $cleanmode = 'dpkg-source';
  43
  44 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  45
  46 our (@git) = qw(git);
  47 our (@dget) = qw(dget);
  48 our (@dput) = qw(dput);
  49 our (@debsign) = qw(debsign);
  50 our (@sbuild) = qw(sbuild -A);
  51 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  52 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  53 our (@dpkggenchanges) = qw(dpkg-genchanges);
  54 our (@mergechanges) = qw(mergechanges -f);
  55 our (@changesopts) = ('');
  56
  57 our %opts_opt_map = ('dget' => \@dget,
  58                      'dput' => \@dput,
  59                      'debsign' => \@debsign,
  60                      'sbuild' => \@sbuild,
  61                      'dpkg-source' => \@dpkgsource,
  62                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  63                      'dpkg-genchanges' => \@dpkggenchanges,
  64                      'ch' => \@changesopts,
  65                      'mergechanges' => \@mergechanges);
  66
  67 our $keyid;
  68
  69 our $debug = 0;
  70 open DEBUG, ">/dev/null" or die $!;
  71
  72 our $remotename = 'dgit';
  73 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
  74 our $branchprefix = 'dgit';
  75 our $csuite;
  76
  77 sub lbranch () { return "$branchprefix/$csuite"; }
  78 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
  79 sub lref () { return "refs/heads/".lbranch(); }
  80 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
  81 sub rrref () { return "refs/$branchprefix/$csuite"; }
  82 sub debiantag ($) {
  83     my ($v) = @_;
  84     $v =~ y/~:/_%/;
  85     return "debian/$v";
  86 }
  87
  88 sub stripepoch ($) {
  89     my ($vsn) = @_;
  90     $vsn =~ s/^\d+\://;
  91     return $vsn;
  92 }
  93
  94 sub dscfn ($) {
  95     my ($vsn) = @_;
  96     return "${package}_".(stripepoch $vsn).".dsc";
  97 }
  98
  99 sub changesopts () { return @changesopts[1..$#changesopts]; }
 100
 101 our $us = 'dgit';
 102
 103 sub fail { die "$us: @_\n"; }
 104
 105 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 106
 107 sub no_such_package () {
 108     print STDERR "$us: package $package does not exist in suite $isuite\n";
 109     exit 4;
 110 }
 111
 112 sub fetchspec () {
 113     local $csuite = '*';
 114     return  "+".rrref().":".lrref();
 115 }
 116
 117 our $ua;
 118
 119 sub url_get {
 120     if (!$ua) {
 121         $ua = LWP::UserAgent->new();
 122         $ua->env_proxy;
 123     }
 124     my $what = $_[$#_];
 125     print "downloading $what...\n";
 126     my $r = $ua->get(@_) or die $!;
 127     return undef if $r->code == 404;
 128     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 129     return $r->decoded_content();
 130 }
 131
 132 our ($dscdata,$dscurl,$dsc);
 133
 134 sub printcmd {
 135     my $fh = shift @_;
 136     my $intro = shift @_;
 137     print $fh $intro or die $!;
 138     local $_;
 139     foreach my $a (@_) {
 140         $_ = $a;
 141         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
 142             print $fh " '$_'" or die $!;
 143         } else {
 144             print $fh " $_" or die $!;
 145         }
 146     }
 147     print $fh "\n" or die $!;
 148 }
 149
 150 sub failedcmd {
 151     { local ($!); printcmd \*STDERR, "$_[0]: failed command:", @_ or die $!; };
 152     if ($!) {
 153         fail "failed to fork/exec: $!";
 154     } elsif (!($? & 0xff)) {
 155         fail "subprocess failed with error exit status ".($?>>8);
 156     } elsif ($?) {
 157         fail "subprocess crashed (wait status $?)";
 158     } else {
 159         fail "subprocess produced invalid output";
 160     }
 161 }
 162
 163 sub runcmd {
 164     printcmd(\*DEBUG,"+",@_) if $debug>0;
 165     $!=0; $?=0;
 166     failedcmd @_ if system @_;
 167 }
 168
 169 sub printdone {
 170     if (!$dryrun) {
 171         print "dgit ok: @_\n";
 172     } else {
 173         print "would be ok: @_ (but dry run only)\n";
 174     }
 175 }
 176
 177 sub cmdoutput_errok {
 178     die Dumper(\@_)." ?" if grep { !defined } @_;
 179     printcmd(\*DEBUG,"|",@_) if $debug>0;
 180     open P, "-|", @_ or die $!;
 181     my $d;
 182     $!=0; $?=0;
 183     { local $/ = undef; $d = <P>; }
 184     die $! if P->error;
 185     if (!close P) { print DEBUG "=>!$?\n" if $debug>0; return undef; }
 186     chomp $d;
 187     $d =~ m/^.*/;
 188     print DEBUG "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 189     return $d;
 190 }
 191
 192 sub cmdoutput {
 193     my $d = cmdoutput_errok @_;
 194     defined $d or failedcmd @_;
 195     return $d;
 196 }
 197
 198 sub dryrun_report {
 199     printcmd(\*STDOUT,"#",@_);
 200 }
 201
 202 sub runcmd_ordryrun {
 203     if (!$dryrun) {
 204         runcmd @_;
 205     } else {
 206         dryrun_report @_;
 207     }
 208 }
 209
 210 our $helpmsg = <<END;
 211 main usages:
 212   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 213   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 214   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 215   dgit [dgit-opts] push [dgit-opts] [suite]
 216 important dgit options:
 217   -k<keyid>           sign tag and package with <keyid> instead of default
 218   --dry-run -n        do not change anything, but go through the motions
 219   --new -N            allow introducing a new package
 220   --debug -D          increase debug level
 221   -c<name>=<value>    set git config option (used directly by dgit too)
 222 END
 223
 224 our $later_warning_msg = <<END;
 225 Perhaps the upload is stuck in incoming.  Using the version from git.
 226 END
 227
 228 sub badusage {
 229     print STDERR "$us: @_\n", $helpmsg or die $!;
 230     exit 8;
 231 }
 232
 233 sub helponly () {
 234     print $helpmsg or die $!;
 235     exit 0;
 236 }
 237
 238 our %defcfg = ('dgit.default.distro' => 'debian',
 239                'dgit.default.username' => '',
 240                'dgit.default.archive-query-default-component' => 'main',
 241                'dgit.default.ssh' => 'ssh',
 242                'dgit-distro.debian.git-host' => 'git.debian.org',
 243                'dgit-distro.debian.git-proto' => 'git+ssh://',
 244                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 245                'dgit-distro.debian.git-check' => 'ssh-cmd',
 246                'dgit-distro.debian.git-create' => 'ssh-cmd',
 247                'dgit-distro.debian.sshdakls-host' => 'coccia.debian.org',
 248                'dgit-distro.debian.sshdakls-dir' =>
 249                    '/srv/ftp-master.debian.org/ftp/dists',
 250                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/');
 251
 252 sub cfg {
 253     foreach my $c (@_) {
 254         return undef if $c =~ /RETURN-UNDEF/;
 255         my @cmd = (@git, qw(config --), $c);
 256         my $v;
 257         {
 258             local ($debug) = $debug-1;
 259             $v = cmdoutput_errok @cmd;
 260         };
 261         if ($?==0) {
 262             return $v;
 263         } elsif ($?!=256) {
 264             failedcmd @cmd;
 265         }
 266         my $dv = $defcfg{$c};
 267         return $dv if defined $dv;
 268     }
 269     badcfg "need value for one of: @_";
 270 }
 271
 272 sub access_distro () {
 273     return cfg("dgit-suite.$isuite.distro",
 274                "dgit.default.distro");
 275 }
 276
 277 sub access_cfg (@) {
 278     my (@keys) = @_;
 279     my $distro = $idistro || access_distro();
 280     my $value = cfg(map { ("dgit-distro.$distro.$_",
 281                            "dgit.default.$_") } @keys);
 282     return $value;
 283 }
 284
 285 sub access_someuserhost ($) {
 286     my ($some) = @_;
 287     my $user = access_cfg("$some-user",'username');
 288     my $host = access_cfg("$some-host");
 289     return length($user) ? "$user\@$host" : $host;
 290 }
 291
 292 sub access_gituserhost () {
 293     return access_someuserhost('git');
 294 }
 295
 296 sub access_giturl () {
 297     my $url = access_cfg('git-url','RETURN-UNDEF');
 298     if (!defined $url) {
 299         $url =
 300             access_cfg('git-proto').
 301             access_gituserhost().
 302             access_cfg('git-path');
 303     }
 304     return "$url/$package.git";
 305 }
 306
 307 sub parsecontrolfh ($$@) {
 308     my ($fh, $desc, @opts) = @_;
 309     my %opts = ('name' => $desc, @opts);
 310     my $c = Dpkg::Control::Hash->new(%opts);
 311     $c->parse($fh) or die "parsing of $desc failed";
 312     return $c;
 313 }
 314
 315 sub parsecontrol {
 316     my ($file, $desc) = @_;
 317     my $fh = new IO::Handle;
 318     open $fh, '<', $file or die "$file: $!";
 319     my $c = parsecontrolfh($fh,$desc);
 320     $fh->error and die $!;
 321     close $fh;
 322     return $c;
 323 }
 324
 325 sub getfield ($$) {
 326     my ($dctrl,$field) = @_;
 327     my $v = $dctrl->{$field};
 328     return $v if defined $v;
 329     fail "missing field $field in ".$v->get_option('name');
 330 }
 331
 332 sub parsechangelog {
 333     my $c = Dpkg::Control::Hash->new();
 334     my $p = new IO::Handle;
 335     my @cmd = (qw(dpkg-parsechangelog));
 336     open $p, '-|', @cmd or die $!;
 337     $c->parse($p);
 338     $?=0; $!=0; close $p or failedcmd @cmd;
 339     return $c;
 340 }
 341
 342 our %rmad;
 343
 344 sub archive_query ($) {
 345     my ($method) = @_;
 346     my $query = access_cfg('archive-query','RETURN-UNDEF');
 347     if (!defined $query) {
 348         my $distro = access_distro();
 349         if ($distro eq 'debian') {
 350             $query = "sshdakls:".
 351                 access_someuserhost('sshdakls').':'.
 352                 access_cfg('sshdakls-dir');
 353         } else {
 354             $query = "madison:$distro";
 355         }
 356     }
 357     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 358     my $proto = $1;
 359     my $data = $'; #';
 360     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 361 }
 362
 363 sub archive_query_madison ($$) {
 364     my ($proto,$data) = @_;
 365     die unless $proto eq 'madison';
 366     $rmad{$package} ||= cmdoutput
 367         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 368     my $rmad = $rmad{$package};
 369     return madison_parse($rmad);
 370 }
 371
 372 sub archive_query_sshdakls ($$) {
 373     my ($proto,$data) = @_;
 374     $data =~ s/:.*// or badcfg "invalid sshdakls method string \`$data'";
 375     my $dakls = cmdoutput
 376         access_cfg('ssh'), $data, qw(dak ls -asource),"-s$isuite",$package;
 377     return madison_parse($dakls);
 378 }
 379
 380 sub canonicalise_suite_sshdakls ($$) {
 381     my ($proto,$data) = @_;
 382     $data =~ m/:/ or badcfg "invalid sshdakls method string \`$data'";
 383     my @cmd =
 384         (access_cfg('ssh'), $`,
 385          "set -e; cd $';".
 386          " if test -h $isuite; then readlink $isuite; exit 0; fi;".
 387          " if test -d $isuite; then echo $isuite; exit 0; fi;".
 388          " exit 1");
 389     my $dakls = cmdoutput @cmd;
 390     failedcmd @cmd unless $dakls =~ m/^\w/;
 391     return $dakls;
 392 }
 393
 394 sub madison_parse ($) {
 395     my ($rmad) = @_;
 396     my @out;
 397     foreach my $l (split /\n/, $rmad) {
 398         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 399                   \s*( [^ \t|]+ )\s* \|
 400                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 401                   \s*( [^ \t|]+ )\s* }x or die "$rmad $?";
 402         $1 eq $package or die "$rmad $package ?";
 403         my $vsn = $2;
 404         my $newsuite = $3;
 405         my $component;
 406         if (defined $4) {
 407             $component = $4;
 408         } else {
 409             $component = access_cfg('archive-query-default-component');
 410         }
 411         $5 eq 'source' or die "$rmad ?";
 412         my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 413         my $subpath = "/pool/$component/$prefix/$package/".dscfn($vsn);
 414         push @out, [$vsn,$subpath,$newsuite];
 415     }
 416     return sort { -version_compare_string($a->[0],$b->[0]); } @out;
 417 }
 418
 419 sub canonicalise_suite_madison ($$) {
 420     my @r = archive_query_madison($_[0],$_[1]);
 421     @r or fail
 422         "unable to canonicalise suite using package $package".
 423         " which does not appear to exist in suite $isuite;".
 424         " --existing-package may help";
 425     return $r[0][2];
 426 }
 427
 428 sub canonicalise_suite () {
 429     return if defined $csuite;
 430     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 431     $csuite = archive_query('canonicalise_suite');
 432     if ($isuite ne $csuite) {
 433         # madison canonicalises for us
 434         print "canonical suite name for $isuite is $csuite\n";
 435     }
 436 }
 437
 438 sub get_archive_dsc () {
 439     canonicalise_suite();
 440     my @vsns = archive_query('archive_query');
 441     foreach my $vinfo (@vsns) {
 442         my ($vsn,$subpath) = @$vinfo;
 443         $dscurl = access_cfg('mirror').$subpath;
 444         $dscdata = url_get($dscurl);
 445         next unless defined $dscdata;
 446         $dscurl = access_cfg('mirror').$subpath;
 447         $dscdata = url_get($dscurl);
 448         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 449         print DEBUG Dumper($dscdata) if $debug>1;
 450         $dsc = parsecontrolfh($dscfh,$dscurl, allow_pgp=>1);
 451         print DEBUG Dumper($dsc) if $debug>1;
 452         my $fmt = getfield $dsc, 'Format';
 453         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 454         return $dsc;
 455     }
 456     return undef;
 457 }
 458
 459 sub check_for_git () {
 460     # returns 0 or 1
 461     my $how = access_cfg('git-check');
 462     if ($how eq 'ssh-cmd') {
 463         my @cmd =
 464             (access_cfg('ssh'),access_gituserhost(),
 465              " set -e; cd ".access_cfg('git-path').";".
 466              " if test -d $package.git; then echo 1; else echo 0; fi");
 467         my $r= cmdoutput @cmd;
 468         failedcmd @cmd unless $r =~ m/^[01]$/;
 469         return $r+0;
 470     } else {
 471         badcfg "unknown git-check \`$how'";
 472     }
 473 }
 474
 475 sub create_remote_git_repo () {
 476     my $how = access_cfg('git-create');
 477     if ($how eq 'ssh-cmd') {
 478         runcmd_ordryrun
 479             (access_cfg('ssh'),access_gituserhost(),
 480              "set -e; cd ".access_cfg('git-path').";".
 481              " cp -a _template $package.git");
 482     } else {
 483         badcfg "unknown git-create \`$how'";
 484     }
 485 }
 486
 487 our ($dsc_hash,$upload_hash);
 488
 489 our $ud = '.git/dgit/unpack';
 490
 491 sub prep_ud () {
 492     rmtree($ud);
 493     mkpath '.git/dgit';
 494     mkdir $ud or die $!;
 495 }
 496
 497 sub mktree_in_ud_from_only_subdir () {
 498     # changes into the subdir
 499     my (@dirs) = <*/.>;
 500     die unless @dirs==1;
 501     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 502     my $dir = $1;
 503     chdir $dir or die "$dir $!";
 504     fail "source package contains .git directory" if stat '.git';
 505     die $! unless $!==&ENOENT;
 506     runcmd qw(git init -q);
 507     rmtree('.git/objects');
 508     symlink '../../../../objects','.git/objects' or die $!;
 509     runcmd @git, qw(add -Af);
 510     my $tree = cmdoutput @git, qw(write-tree);
 511     $tree =~ m/^\w+$/ or die "$tree ?";
 512     return ($tree,$dir);
 513 }
 514
 515 sub dsc_files_info () {
 516     foreach my $csum (qw(Sha256 Sha1 MD5)) {
 517         my $fname = $csum eq 'MD5' ? 'Files' : "Checksums-$csum";
 518         my $field = $dsc->{$fname};
 519         next unless defined $field;
 520         my $digest = uc $csum;
 521         if (!eval "use Digest::$digest; 1;") {
 522             print DEBUG "ignoring $fname because $@\n";
 523             next;
 524         }
 525         my @out;
 526         foreach (split /\n/, $field) {
 527             next unless m/\S/;
 528             m/^(\w+) (\d+) (\S+)$/ or
 529                 fail "could not parse .dsc $fname line \`$_'";
 530             my $digester = eval "Digest::$digest->new;" or die $@;
 531             push @out, {
 532                 Hash => $1,
 533                 Bytes => $2,
 534                 Filename => $3,
 535                 Digester => $digester,
 536             };
 537         }
 538         return @out;
 539     }
 540     fail "missing any supported Checksums-* or Files field in ".
 541         $dsc->get_option('name');
 542 }
 543
 544 sub dsc_files () {
 545     map { $_->{Filename} } dsc_files_info();
 546 }
 547
 548 sub is_orig_file ($) {
 549     local ($_) = @_;
 550     m/\.orig(?:-\w+)?\.tar\.\w+$/;
 551 }
 552
 553 sub make_commit ($) {
 554     my ($file) = @_;
 555     return cmdoutput @git, qw(hash-object -w -t commit), $file;
 556 }
 557
 558 sub generate_commit_from_dsc () {
 559     prep_ud();
 560     chdir $ud or die $!;
 561     my @files;
 562     foreach my $f (dsc_files()) {
 563         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 564         push @files, $f;
 565         link "../../../$f", $f
 566             or $!==&ENOENT
 567             or die "$f $!";
 568     }
 569     runcmd @dget, qw(--), $dscurl;
 570     foreach my $f (grep { is_orig_file($_) } @files) {
 571         link $f, "../../../../$f"
 572             or $!==&EEXIST
 573             or die "$f $!";
 574     }
 575     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 576     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 577     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
 578     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
 579     my $author = getfield $clogp, 'Maintainer';
 580     $author =~ s#,.*##ms;
 581     my $authline = "$author $date";
 582     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
 583         fail "unexpected commit author line format \`$authline'".
 584             " (was generated from changelog Maintainer field)";
 585     my $changes = getfield $clogp, 'Changes';
 586     open C, ">../commit.tmp" or die $!;
 587     print C <<END or die $!;
 588 tree $tree
 589 author $authline
 590 committer $authline
 591
 592 $changes
 593
 594 # imported from the archive
 595 END
 596     close C or die $!;
 597     my $outputhash = make_commit qw(../commit.tmp);
 598     my $cversion = getfield $clogp, 'Version';
 599     print "synthesised git commit from .dsc $cversion\n";
 600     if ($upload_hash) {
 601         runcmd @git, qw(reset --hard), $upload_hash;
 602         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 603         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
 604         my $oversion = getfield $oldclogp, 'Version';
 605         my $vcmp =
 606             version_compare_string($oversion, $cversion);
 607         if ($vcmp < 0) {
 608             # git upload/ is earlier vsn than archive, use archive
 609             open C, ">../commit2.tmp" or die $!;
 610             print C <<END or die $!;
 611 tree $tree
 612 parent $upload_hash
 613 parent $outputhash
 614 author $authline
 615 committer $authline
 616
 617 Record $package ($cversion) in archive suite $csuite
 618 END
 619             $outputhash = make_commit qw(../commit2.tmp);
 620         } elsif ($vcmp > 0) {
 621             print STDERR <<END or die $!;
 622
 623 Version actually in archive:    $cversion (older)
 624 Last allegedly pushed/uploaded: $oversion (newer or same)
 625 $later_warning_msg
 626 END
 627             $outputhash = $upload_hash;
 628         } else {
 629             $outputhash = $upload_hash;
 630         }
 631     }
 632     chdir '../../../..' or die $!;
 633     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
 634             'DGIT_ARCHIVE', $outputhash;
 635     cmdoutput @git, qw(log -n2), $outputhash;
 636     # ... gives git a chance to complain if our commit is malformed
 637     rmtree($ud);
 638     return $outputhash;
 639 }
 640
 641 sub ensure_we_have_orig () {
 642     foreach my $f (dsc_files()) {
 643         next unless is_orig_file($f);
 644         if (stat "../$f") {
 645             die "$f ?" unless -f _;
 646         } else {
 647             die "$f $!" unless $!==&ENOENT;
 648         }
 649         my $origurl = $dscurl;
 650         $origurl =~ s{/[^/]+$}{};
 651         $origurl .= "/$f";
 652         die "$f ?" unless $f =~ m/^${package}_/;
 653         die "$f ?" if $f =~ m#/#;
 654         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 655             @dget,'--',$origurl;
 656     }
 657 }
 658
 659 sub rev_parse ($) {
 660     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 661 }
 662
 663 sub is_fast_fwd ($$) {
 664     my ($ancestor,$child) = @_;
 665     my @cmd = (@git, qw(merge-base), $ancestor, $child);
 666     my $mb = cmdoutput_errok @cmd;
 667     if (defined $mb) {
 668         return rev_parse($mb) eq rev_parse($ancestor);
 669     } else {
 670         $?==256 or failedcmd @cmd;
 671         return 0;
 672     }
 673 }
 674
 675 sub git_fetch_us () {
 676     badusage "cannot dry run with fetch" if $dryrun;
 677     runcmd @git, qw(fetch),access_giturl(),fetchspec();
 678 }
 679
 680 sub fetch_from_archive () {
 681     # ensures that lrref() is what is actually in the archive,
 682     #  one way or another
 683     get_archive_dsc() or return 0;
 684     foreach my $field (@ourdscfield) {
 685         $dsc_hash = $dsc->{$field};
 686         last if defined $dsc_hash;
 687     }
 688     if (defined $dsc_hash) {
 689         $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
 690         $dsc_hash = $&;
 691         print "last upload to archive specified git hash\n";
 692     } else {
 693         print "last upload to archive has NO git hash\n";
 694     }
 695
 696     my $lrref_fn = ".git/".lrref();
 697     if (open H, $lrref_fn) {
 698         $upload_hash = <H>;
 699         chomp $upload_hash;
 700         die "$lrref_fn $upload_hash ?" unless $upload_hash =~ m/^\w+$/;
 701     } elsif ($! == &ENOENT) {
 702         $upload_hash = '';
 703     } else {
 704         die "$lrref_fn $!";
 705     }
 706     print DEBUG "previous reference hash=$upload_hash\n";
 707     my $hash;
 708     if (defined $dsc_hash) {
 709         fail "missing git history even though dsc has hash -".
 710             " could not find commit $dsc_hash".
 711             " (should be in ".access_giturl()."#".rrref().")"
 712             unless $upload_hash;
 713         $hash = $dsc_hash;
 714         ensure_we_have_orig();
 715         if ($dsc_hash eq $upload_hash) {
 716         } elsif (is_fast_fwd($dsc_hash,$upload_hash)) {
 717             print STDERR <<END or die $!;
 718
 719 Git commit in archive is behind the last version allegedly pushed/uploaded.
 720 Commit referred to by archive:  $dsc_hash
 721 Last allegedly pushed/uploaded: $upload_hash
 722 $later_warning_msg
 723 END
 724             $hash = $upload_hash;
 725         } else {
 726             fail "archive's .dsc refers to ".$dsc_hash.
 727                 " but this is an ancestor of ".$upload_hash;
 728         }
 729     } else {
 730         $hash = generate_commit_from_dsc();
 731     }
 732     print DEBUG "current hash=$hash\n";
 733     if ($upload_hash) {
 734         fail "not fast forward on last upload branch!".
 735             " (archive's version left in DGIT_ARCHIVE)"
 736             unless is_fast_fwd($upload_hash, $hash);
 737     }
 738     if ($upload_hash ne $hash) {
 739         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
 740         if (!$dryrun) {
 741             cmdoutput @upd_cmd;
 742         } else {
 743             dryrun_report @upd_cmd;
 744         }
 745     }
 746     return 1;
 747 }
 748
 749 sub clone ($) {
 750     my ($dstdir) = @_;
 751     canonicalise_suite();
 752     badusage "dry run makes no sense with clone" if $dryrun;
 753     mkdir $dstdir or die "$dstdir $!";
 754     chdir "$dstdir" or die "$dstdir $!";
 755     runcmd @git, qw(init -q);
 756     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
 757     open H, "> .git/HEAD" or die $!;
 758     print H "ref: ".lref()."\n" or die $!;
 759     close H or die $!;
 760     runcmd @git, qw(remote add), 'origin', access_giturl();
 761     if (check_for_git()) {
 762         print "fetching existing git history\n";
 763         git_fetch_us();
 764         runcmd @git, qw(fetch origin);
 765     } else {
 766         print "starting new git history\n";
 767     }
 768     fetch_from_archive() or no_such_package;
 769     runcmd @git, qw(reset --hard), lrref();
 770     printdone "ready for work in $dstdir";
 771 }
 772
 773 sub fetch () {
 774     if (check_for_git()) {
 775         git_fetch_us();
 776     }
 777     fetch_from_archive() or no_such_package();
 778     printdone "fetched into ".lrref();
 779 }
 780
 781 sub pull () {
 782     fetch();
 783     runcmd_ordryrun @git, qw(merge -m),"Merge from $csuite [dgit]",
 784         lrref();
 785     printdone "fetched to ".lrref()." and merged into HEAD";
 786 }
 787
 788 sub check_not_dirty () {
 789     return if $ignoredirty;
 790     my @cmd = (@git, qw(diff --quiet HEAD));
 791     printcmd(\*DEBUG,"+",@cmd) if $debug>0;
 792     $!=0; $?=0; system @cmd;
 793     return if !$! && !$?;
 794     if (!$! && $?==256) {
 795         fail "working tree is dirty (does not match HEAD)";
 796     } else {
 797         failedcmd @cmd;
 798     }
 799 }
 800
 801 sub commit_quilty_patch () {
 802     my $output = cmdoutput @git, qw(status --porcelain);
 803     my %adds;
 804     my $bad=0;
 805     foreach my $l (split /\n/, $output) {
 806         next unless $l =~ m/\S/;
 807         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
 808             $adds{$1}++;
 809         } else {
 810             print STDERR "git status: $l\n";
 811             $bad++;
 812         }
 813     }
 814     fail "unexpected output from git status (is tree clean?)" if $bad;
 815     if (!%adds) {
 816         print "nothing quilty to commit, ok.\n";
 817         return;
 818     }
 819     runcmd_ordryrun @git, qw(add), sort keys %adds;
 820     my $m = "Commit Debian 3.0 (quilt) metadata";
 821     print "$m\n";
 822     runcmd_ordryrun @git, qw(commit -m), $m;
 823 }
 824
 825 sub madformat ($) {
 826     my ($format) = @_;
 827     return 0 unless $format eq '3.0 (quilt)';
 828     print "Format \`$format', urgh\n";
 829     if ($noquilt) {
 830         print "Not doing any fixup of \`$format' due to --no-quilt-fixup";
 831         return 0;
 832     }
 833     return 1;
 834 }
 835
 836 sub dopush () {
 837     print DEBUG "actually entering push\n";
 838     my $clogp = parsechangelog();
 839     $package = getfield $clogp, 'Source';
 840     my $cversion = getfield $clogp, 'Version';
 841     my $dscfn = dscfn($cversion);
 842     stat "../$dscfn" or
 843         fail "looked for .dsc $dscfn, but $!;".
 844             " maybe you forgot to build";
 845     $dsc = parsecontrol("../$dscfn","$dscfn");
 846     my $dscpackage = getfield $dsc, 'Source';
 847     my $format = getfield $dsc, 'Format';
 848     my $dversion = getfield $dsc, 'Version';
 849     ($dscpackage eq $package && $dversion eq $cversion) or
 850         fail "$dsc is for $dscpackage $dversion".
 851             " but debian/changelog is for $package $cversion";
 852     print DEBUG "format $format\n";
 853     if (madformat($format)) {
 854         commit_quilty_patch();
 855     }
 856     check_not_dirty();
 857     prep_ud();
 858     chdir $ud or die $!;
 859     print "checking that $dscfn corresponds to HEAD\n";
 860     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 861     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 862     chdir '../../../..' or die $!;
 863     printcmd \*DEBUG,"+",@_;
 864     my @diffcmd = (@git, qw(diff --exit-code), $tree);
 865     $!=0; $?=0;
 866     if (system @diffcmd) {
 867         if ($! && $?==256) {
 868             fail "$dscfn specifies a different tree to your HEAD commit;".
 869                 " perhaps you forgot to build";
 870         } else {
 871             failedcmd @diffcmd;
 872         }
 873     }
 874 #fetch from alioth
 875 #do fast forward check and maybe fake merge
 876 #    if (!is_fast_fwd(mainbranch
 877 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 878 #        map { lref($_).":".rref($_) }
 879 #        (uploadbranch());
 880     $dsc->{$ourdscfield[0]} = rev_parse('HEAD');
 881     $dsc->save("../$dscfn.tmp") or die $!;
 882     if (!$changesfile) {
 883         my $multi = "../${package}_".(stripepoch $cversion)."_multi.changes";
 884         if (stat "$multi") {
 885             $changesfile = $multi;
 886         } else {
 887             $!==&ENOENT or die "$multi: $!";
 888             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
 889             my @cs = glob "../$pat";
 890             fail "failed to find unique changes file".
 891                 " (looked for $pat in .., or $multi);".
 892                 " perhaps you need to use dgit -C"
 893                 unless @cs==1;
 894             ($changesfile) = @cs;
 895         }
 896     }
 897     my $changes = parsecontrol($changesfile,$changesfile);
 898     foreach my $field (qw(Source Distribution Version)) {
 899         $changes->{$field} eq $clogp->{$field} or
 900             fail "changes field $field \`$changes->{$field}'".
 901                 " does not match changelog \`$clogp->{$field}'";
 902     }
 903     my $tag = debiantag($dversion);
 904     if (!check_for_git()) {
 905         create_remote_git_repo();
 906     }
 907     runcmd_ordryrun @git, qw(push),access_giturl(),"HEAD:".rrref();
 908     if (!$dryrun) {
 909         rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 910     } else {
 911         print "[new .dsc left in $dscfn.tmp]\n";
 912     }
 913     if ($sign) {
 914         if (!defined $keyid) {
 915             $keyid = access_cfg('keyid','RETURN-UNDEF');
 916         }
 917         my @tag_cmd = (@git, qw(tag -s -m),
 918                        "Release $dversion for $csuite [dgit]");
 919         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 920         push @tag_cmd, $tag;
 921         runcmd_ordryrun @tag_cmd;
 922         my @debsign_cmd = @debsign;
 923         push @debsign_cmd, "-k$keyid" if defined $keyid;
 924         push @debsign_cmd, $changesfile;
 925         runcmd_ordryrun @debsign_cmd;
 926     }
 927     runcmd_ordryrun @git, qw(push),access_giturl(),"refs/tags/$tag";
 928     my $host = access_cfg('upload-host','RETURN-UNDEF');
 929     my @hostarg = defined($host) ? ($host,) : ();
 930     runcmd_ordryrun @dput, @hostarg, $changesfile;
 931     printdone "pushed and uploaded $dversion";
 932 }
 933
 934 sub cmd_clone {
 935     parseopts();
 936     my $dstdir;
 937     badusage "-p is not allowed with clone; specify as argument instead"
 938         if defined $package;
 939     if (@ARGV==1) {
 940         ($package) = @ARGV;
 941     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
 942         ($package,$isuite) = @ARGV;
 943     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
 944         ($package,$dstdir) = @ARGV;
 945     } elsif (@ARGV==3) {
 946         ($package,$isuite,$dstdir) = @ARGV;
 947     } else {
 948         badusage "incorrect arguments to dgit clone";
 949     }
 950     $dstdir ||= "$package";
 951     clone($dstdir);
 952 }
 953
 954 sub branchsuite () {
 955     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 956     if ($branch =~ m#$lbranch_re#o) {
 957         return $1;
 958     } else {
 959         return undef;
 960     }
 961 }
 962
 963 sub fetchpullargs () {
 964     if (!defined $package) {
 965         my $sourcep = parsecontrol('debian/control','debian/control');
 966         $package = getfield $sourcep, 'Source';
 967     }
 968     if (@ARGV==0) {
 969 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
 970         if (!$isuite) {
 971             my $clogp = parsechangelog();
 972             $isuite = getfield $clogp, 'Distribution';
 973         }
 974         canonicalise_suite();
 975         print "fetching from suite $csuite\n";
 976     } elsif (@ARGV==1) {
 977         ($isuite) = @ARGV;
 978         canonicalise_suite();
 979     } else {
 980         badusage "incorrect arguments to dgit fetch or dgit pull";
 981     }
 982 }
 983
 984 sub cmd_fetch {
 985     parseopts();
 986     fetchpullargs();
 987     fetch();
 988 }
 989
 990 sub cmd_pull {
 991     parseopts();
 992     fetchpullargs();
 993     pull();
 994 }
 995
 996 sub cmd_push {
 997     parseopts();
 998     badusage "-p is not allowed with dgit push" if defined $package;
 999     check_not_dirty();
1000     my $clogp = parsechangelog();
1001     $package = getfield $clogp, 'Source';
1002     if (@ARGV==0) {
1003         $isuite = getfield $clogp, 'Distribution';
1004         if ($new_package) {
1005             local ($package) = $existing_package; # this is a hack
1006             canonicalise_suite();
1007         }
1008     } else {
1009         badusage "incorrect arguments to dgit push";
1010     }
1011     if (check_for_git()) {
1012         git_fetch_us();
1013     }
1014     if (fetch_from_archive()) {
1015         is_fast_fwd(lrref(), 'HEAD') or
1016             fail "dgit push: HEAD is not a descendant".
1017                 " of the archive's version.\n".
1018                 "$us: To overwrite it, use git-merge -s ours ".lrref().".";
1019     } else {
1020         $new_package or
1021             fail "package appears to be new in this suite;".
1022                 " if this is intentional, use --new";
1023     }
1024     dopush();
1025 }
1026
1027 our $version;
1028 our $sourcechanges;
1029 our $dscfn;
1030
1031 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
1032
1033 sub build_maybe_quilt_fixup () {
1034     if (!open F, "debian/source/format") {
1035         die $! unless $!==&ENOENT;
1036         return;
1037     }
1038     $_ = <F>;
1039     F->error and die $!;
1040     chomp;
1041     return unless madformat($_);
1042     # sigh
1043     my $clogp = parsechangelog();
1044     my $version = getfield $clogp, 'Version';
1045     my $author = getfield $clogp, 'Maintainer';
1046     my $headref = rev_parse('HEAD');
1047     my $time = time;
1048     my $ncommits = 3;
1049     my $patchname = "auto-$version-$headref-$time";
1050     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
1051     my $descfn = ".git/dgit/quilt-description.tmp";
1052     open O, '>', $descfn or die "$descfn: $!";
1053     $msg =~ s/\n/\n /g;
1054     $msg =~ s/^\s+$/ ./mg;
1055     print O <<END or die $!;
1056 Description: Automatically generated patch ($clogp->{Version})
1057  Last (up to) $ncommits git changes, FYI:
1058  .
1059  $msg
1060 Author: $author
1061
1062 ---
1063
1064 END
1065     close O or die $!;
1066     {
1067         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
1068         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
1069         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
1070         runcmd_ordryrun @dpkgsource, qw(--commit .), $patchname;
1071     }
1072
1073     if (!open P, '>>', ".pc/applied-patches") {
1074         $!==&ENOENT or die $!;
1075     } else {
1076         close P;
1077     }
1078
1079     commit_quilty_patch();
1080 }
1081
1082 sub quilt_fixup_editor () {
1083     my $descfn = $ENV{$fakeeditorenv};
1084     my $editing = $ARGV[$#ARGV];
1085     open I1, '<', $descfn or die "$descfn: $!";
1086     open I2, '<', $editing or die "$editing: $!";
1087     unlink $editing or die "$editing: $!";
1088     open O, '>', $editing or die "$editing: $!";
1089     while (<I1>) { print O or die $!; } I1->error and die $!;
1090     my $copying = 0;
1091     while (<I2>) {
1092         $copying ||= m/^\-\-\- /;
1093         next unless $copying;
1094         print O or die $!;
1095     }
1096     I2->error and die $!;
1097     close O or die $1;
1098     exit 0;
1099 }
1100
1101 sub build_prep () {
1102     badusage "-p is not allowed when building" if defined $package;
1103     check_not_dirty();
1104     my $clogp = parsechangelog();
1105     $isuite = getfield $clogp, 'Distribution';
1106     $package = getfield $clogp, 'Source';
1107     $version = getfield $clogp, 'Version';
1108     build_maybe_quilt_fixup();
1109 }
1110
1111 sub cmd_build {
1112     badusage "dgit build implies --clean=dpkg-source"
1113         if $cleanmode ne 'dpkg-source';
1114     build_prep();
1115     runcmd_ordryrun @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
1116     printdone "build successful\n";
1117 }
1118
1119 sub cmd_git_build {
1120     badusage "dgit git-build implies --clean=dpkg-source"
1121         if $cleanmode ne 'dpkg-source';
1122     build_prep();
1123     my @cmd =
1124         (qw(git-buildpackage -us -uc --git-no-sign-tags),
1125          "--git-builder=@dpkgbuildpackage");
1126     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
1127         canonicalise_suite();
1128         push @cmd, "--git-debian-branch=".lbranch();
1129     }
1130     push @cmd, changesopts();
1131     runcmd_ordryrun @cmd, @ARGV;
1132     printdone "build successful\n";
1133 }
1134
1135 sub build_source {
1136     build_prep();
1137     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
1138     $dscfn = dscfn($version);
1139     if ($cleanmode eq 'dpkg-source') {
1140         runcmd_ordryrun (@dpkgbuildpackage, qw(-us -uc -S)), changesopts();
1141     } else {
1142         if ($cleanmode eq 'git') {
1143             runcmd_ordryrun @git, qw(clean -xdf);
1144         } elsif ($cleanmode eq 'none') {
1145         } else {
1146             die "$cleanmode ?";
1147         }
1148         my $pwd = cmdoutput qw(env - pwd);
1149         my $leafdir = basename $pwd;
1150         chdir ".." or die $!;
1151         runcmd_ordryrun @dpkgsource, qw(-b --), $leafdir;
1152         chdir $pwd or die $!;
1153         runcmd_ordryrun qw(sh -ec),
1154             'exec >$1; shift; exec "$@"','x',
1155             "../$sourcechanges",
1156             @dpkggenchanges, qw(-S), changesopts();
1157     }
1158 }
1159
1160 sub cmd_build_source {
1161     badusage "build-source takes no additional arguments" if @ARGV;
1162     build_source();
1163     printdone "source built, results in $dscfn and $sourcechanges";
1164 }
1165
1166 sub cmd_sbuild {
1167     build_source();
1168     chdir ".." or die $!;
1169     my $pat = "${package}_".(stripepoch $version)."_*.changes";
1170     if (!$dryrun) {
1171         stat $dscfn or fail "$dscfn (in parent directory): $!";
1172         stat $sourcechanges or fail "$sourcechanges (in parent directory): $!";
1173         foreach my $cf (glob $pat) {
1174             next if $cf eq $sourcechanges;
1175             unlink $cf or fail "remove $cf: $!";
1176         }
1177     }
1178     runcmd_ordryrun @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
1179     runcmd_ordryrun @mergechanges, glob $pat;
1180     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
1181     if (!$dryrun) {
1182         stat $multichanges or fail "$multichanges: $!";
1183     }
1184     printdone "build successful, results in $multichanges\n" or die $!;
1185 }
1186
1187 sub cmd_quilt_fixup {
1188     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
1189     my $clogp = parsechangelog();
1190     $version = getfield $clogp, 'Version';
1191     build_maybe_quilt_fixup();
1192 }
1193
1194 sub parseopts () {
1195     my $om;
1196     while (@ARGV) {
1197         last unless $ARGV[0] =~ m/^-/;
1198         $_ = shift @ARGV;
1199         last if m/^--?$/;
1200         if (m/^--/) {
1201             if (m/^--dry-run$/) {
1202                 $dryrun=1;
1203             } elsif (m/^--no-sign$/) {
1204                 $sign=0;
1205             } elsif (m/^--help$/) {
1206                 helponly();
1207             } elsif (m/^--new$/) {
1208                 $new_package=1;
1209             } elsif (m/^--(\w+)=(.*)/s &&
1210                      ($om = $opts_opt_map{$1}) &&
1211                      length $om->[0]) {
1212                 $om->[0] = $2;
1213             } elsif (m/^--(\w+):(.*)/s &&
1214                      ($om = $opts_opt_map{$1})) {
1215                 push @$om, $2;
1216             } elsif (m/^--existing-package=(.*)/s) {
1217                 $existing_package = $1;
1218             } elsif (m/^--distro=(.*)/s) {
1219                 $idistro = $1;
1220             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
1221                 $cleanmode = $1;
1222             } elsif (m/^--clean=(.*)$/s) {
1223                 badusage "unknown cleaning mode \`$1'";
1224             } elsif (m/^--ignore-dirty$/s) {
1225                 $ignoredirty = 1;
1226             } elsif (m/^--no-quilt-fixup$/s) {
1227                 $noquilt = 1;
1228             } else {
1229                 badusage "unknown long option \`$_'";
1230             }
1231         } else {
1232             while (m/^-./s) {
1233                 if (s/^-n/-/) {
1234                     $dryrun=1;
1235                 } elsif (s/^-h/-/) {
1236                     helponly();
1237                 } elsif (s/^-D/-/) {
1238                     open DEBUG, ">&STDERR" or die $!;
1239                     $debug++;
1240                 } elsif (s/^-N/-/) {
1241                     $new_package=1;
1242                 } elsif (m/^-[vm]/) {
1243                     push @changesopts, $_;
1244                     $_ = '';
1245                 } elsif (s/^-c(.*=.*)//s) {
1246                     push @git, '-c', $1;
1247                 } elsif (s/^-d(.*)//s) {
1248                     $idistro = $1;
1249                 } elsif (s/^-C(.*)//s) {
1250                     $changesfile = $1;
1251                 } elsif (s/^-k(.*)//s) {
1252                     $keyid=$1;
1253                 } elsif (s/^-wn//s) {
1254                     $cleanmode = 'none';
1255                 } elsif (s/^-wg//s) {
1256                     $cleanmode = 'git';
1257                 } elsif (s/^-wd//s) {
1258                     $cleanmode = 'dpkg-source';
1259                 } else {
1260                     badusage "unknown short option \`$_'";
1261                 }
1262             }
1263         }
1264     }
1265 }
1266
1267 if ($ENV{$fakeeditorenv}) {
1268     quilt_fixup_editor();
1269 }
1270
1271 delete $ENV{'DGET_UNPACK'};
1272
1273 parseopts();
1274 print STDERR "DRY RUN ONLY\n" if $dryrun;
1275 if (!@ARGV) {
1276     print STDERR $helpmsg or die $!;
1277     exit 8;
1278 }
1279 my $cmd = shift @ARGV;
1280 $cmd =~ y/-/_/;
1281 { no strict qw(refs); &{"cmd_$cmd"}(); }