dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Basename;
  28 use Dpkg::Version;
  29 use POSIX;
  30
  31 our $isuite = 'unstable';
  32 our $idistro;
  33 our $package;
  34
  35 our $sign = 1;
  36 our $dryrun = 0;
  37 our $changesfile;
  38 our $new_package = 0;
  39 our $existing_package = 'dpkg';
  40 our $cleanmode = 'dpkg-source';
  41
  42 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  43
  44 our (@git) = qw(git);
  45 our (@dget) = qw(dget);
  46 our (@dput) = qw(dput);
  47 our (@debsign) = qw(debsign);
  48 our (@sbuild) = qw(sbuild -A);
  49 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  50 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  51 our (@dpkggenchanges) = qw(dpkg-genchanges);
  52 our (@mergechanges) = qw(mergechanges -f);
  53 our (@changesopts) = ('');
  54
  55 our %opts_opt_map = ('dget' => \@dget,
  56                      'dput' => \@dput,
  57                      'debsign' => \@debsign,
  58                      'sbuild' => \@sbuild,
  59                      'dpkg-source' => \@dpkgsource,
  60                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  61                      'dpkg-genchanges' => \@dpkggenchanges,
  62                      'ch' => \@changesopts,
  63                      'mergechanges' => \@mergechanges);
  64
  65 our $keyid;
  66
  67 our $debug = 0;
  68 open DEBUG, ">/dev/null" or die $!;
  69
  70 our $remotename = 'dgit';
  71 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
  72 our $branchprefix = 'dgit';
  73 our $csuite;
  74
  75 sub lbranch () { return "$branchprefix/$csuite"; }
  76 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
  77 sub lref () { return "refs/heads/".lbranch(); }
  78 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
  79 sub rrref () { return "refs/$branchprefix/$csuite"; }
  80 sub debiantag ($) {
  81     my ($v) = @_;
  82     $v =~ y/~:/_%/;
  83     return "debian/$v";
  84 }
  85
  86 sub dscfn ($) { return "${package}_$_[0].dsc"; }
  87
  88 sub changesopts () { return @changesopts[1..$#changesopts]; }
  89
  90 our $us = 'dgit';
  91
  92 sub fail { die "$us: @_\n"; }
  93
  94 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
  95
  96 sub no_such_package () {
  97     print STDERR "$us: package $package does not exist in suite $isuite\n";
  98     exit 4;
  99 }
 100
 101 sub fetchspec () {
 102     local $csuite = '*';
 103     return  "+".rrref().":".lrref();
 104 }
 105
 106 our $ua;
 107
 108 sub url_get {
 109     if (!$ua) {
 110         $ua = LWP::UserAgent->new();
 111         $ua->env_proxy;
 112     }
 113     my $what = $_[$#_];
 114     print "downloading $what...\n";
 115     my $r = $ua->get(@_) or die $!;
 116     return undef if $r->code == 404;
 117     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 118     return $r->decoded_content();
 119 }
 120
 121 our ($dscdata,$dscurl,$dsc);
 122
 123 sub printcmd {
 124     my $fh = shift @_;
 125     my $intro = shift @_;
 126     print $fh $intro or die $!;
 127     local $_;
 128     foreach my $a (@_) {
 129         $_ = $a;
 130         if (s{['\\]}{\\$&}g || m{\s} || m{[^-_./0-9a-z]}i) {
 131             print $fh " '$_'" or die $!;
 132         } else {
 133             print $fh " $_" or die $!;
 134         }
 135     }
 136     print $fh "\n" or die $!;
 137 }
 138
 139 sub failedcmd {
 140     { local ($!); printcmd \*STDERR, "$_[0]: failed command:", @_ or die $!; };
 141     if ($!) {
 142         fail "failed to fork/exec: $!";
 143     } elsif (!($? & 0xff)) {
 144         fail "subprocess failed with error exit status ".($?>>8);
 145     } elsif ($?) {
 146         fail "subprocess crashed (wait status $?)";
 147     } else {
 148         fail "subprocess produced invalid output";
 149     }
 150 }
 151
 152 sub runcmd {
 153     printcmd(\*DEBUG,"+",@_) if $debug>0;
 154     $!=0; $?=0;
 155     failedcmd @_ if system @_;
 156 }
 157
 158 sub printdone {
 159     if (!$dryrun) {
 160         print "dgit ok: @_\n";
 161     } else {
 162         print "would be ok: @_ (but dry run only)\n";
 163     }
 164 }
 165
 166 sub cmdoutput_errok {
 167     die Dumper(\@_)." ?" if grep { !defined } @_;
 168     printcmd(\*DEBUG,"|",@_) if $debug>0;
 169     open P, "-|", @_ or die $!;
 170     my $d;
 171     $!=0; $?=0;
 172     { local $/ = undef; $d = <P>; }
 173     die $! if P->error;
 174     if (!close P) { print DEBUG "=>!$?\n" if $debug>0; return undef; }
 175     chomp $d;
 176     $d =~ m/^.*/;
 177     print DEBUG "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 178     return $d;
 179 }
 180
 181 sub cmdoutput {
 182     my $d = cmdoutput_errok @_;
 183     defined $d or failedcmd @_;
 184     return $d;
 185 }
 186
 187 sub dryrun_report {
 188     printcmd(\*STDOUT,"#",@_);
 189 }
 190
 191 sub runcmd_ordryrun {
 192     if (!$dryrun) {
 193         runcmd @_;
 194     } else {
 195         dryrun_report @_;
 196     }
 197 }
 198
 199 our $helpmsg = <<END;
 200 main usages:
 201   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 202   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 203   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 204   dgit [dgit-opts] push [dgit-opts] [suite]
 205 important dgit options:
 206   -k<keyid>           sign tag and package with <keyid> instead of default
 207   --dry-run -n        do not change anything, but go through the motions
 208   --new -N            allow introducing a new package
 209   --debug -D          increase debug level
 210   -c<name>=<value>    set git config option (used directly by dgit too)
 211 END
 212
 213 our $later_warning_msg = <<END;
 214 Perhaps the upload is stuck in incoming.  Using the version from git.
 215 END
 216
 217 sub badusage {
 218     print STDERR "$us: @_\n", $helpmsg or die $!;
 219     exit 8;
 220 }
 221
 222 sub helponly () {
 223     print $helpmsg or die $!;
 224     exit 0;
 225 }
 226
 227 our %defcfg = ('dgit.default.distro' => 'debian',
 228                'dgit.default.username' => '',
 229                'dgit.default.archive-query-default-component' => 'main',
 230                'dgit.default.ssh' => 'ssh',
 231                'dgit-distro.debian.git-host' => 'git.debian.org',
 232                'dgit-distro.debian.git-proto' => 'git+ssh://',
 233                'dgit-distro.debian.git-path' => '/git/dgit-repos',
 234                'dgit-distro.debian.git-check' => 'ssh-cmd',
 235                'dgit-distro.debian.git-create' => 'ssh-cmd',
 236                'dgit-distro.debian.sshdakls-host' => 'coccia.debian.org',
 237                'dgit-distro.debian.sshdakls-dir' =>
 238                    '/srv/ftp-master.debian.org/ftp/dists',
 239                'dgit-distro.debian.mirror' => 'http://http.debian.net/debian/');
 240
 241 sub cfg {
 242     foreach my $c (@_) {
 243         return undef if $c =~ /RETURN-UNDEF/;
 244         my @cmd = (@git, qw(config --), $c);
 245         my $v;
 246         {
 247             local ($debug) = $debug-1;
 248             $v = cmdoutput_errok @cmd;
 249         };
 250         if ($?==0) {
 251             return $v;
 252         } elsif ($?!=256) {
 253             failedcmd @cmd;
 254         }
 255         my $dv = $defcfg{$c};
 256         return $dv if defined $dv;
 257     }
 258     badcfg "need value for one of: @_";
 259 }
 260
 261 sub access_distro () {
 262     return cfg("dgit-suite.$isuite.distro",
 263                "dgit.default.distro");
 264 }
 265
 266 sub access_cfg (@) {
 267     my (@keys) = @_;
 268     my $distro = $idistro || access_distro();
 269     my $value = cfg(map { ("dgit-distro.$distro.$_",
 270                            "dgit.default.$_") } @keys);
 271     return $value;
 272 }
 273
 274 sub access_someuserhost ($) {
 275     my ($some) = @_;
 276     my $user = access_cfg("$some-user",'username');
 277     my $host = access_cfg("$some-host");
 278     return length($user) ? "$user\@$host" : $host;
 279 }
 280
 281 sub access_gituserhost () {
 282     return access_someuserhost('git');
 283 }
 284
 285 sub access_giturl () {
 286     my $url = access_cfg('git-url','RETURN-UNDEF');
 287     if (!defined $url) {
 288         $url =
 289             access_cfg('git-proto').
 290             access_gituserhost().
 291             access_cfg('git-path');
 292     }
 293     return "$url/$package.git";
 294 }
 295
 296 sub parsecontrolfh ($$@) {
 297     my ($fh, $desc, @opts) = @_;
 298     my %opts = ('name' => $desc, @opts);
 299     my $c = Dpkg::Control::Hash->new(%opts);
 300     $c->parse($fh) or die "parsing of $desc failed";
 301     return $c;
 302 }
 303
 304 sub parsecontrol {
 305     my ($file, $desc) = @_;
 306     my $fh = new IO::Handle;
 307     open $fh, '<', $file or die "$file: $!";
 308     my $c = parsecontrolfh($fh,$desc);
 309     $fh->error and die $!;
 310     close $fh;
 311     return $c;
 312 }
 313
 314 sub getfield ($$) {
 315     my ($dctrl,$field) = @_;
 316     my $v = $dctrl->{$field};
 317     return $v if defined $v;
 318     fail "missing field $field in ".$v->get_option('name');
 319 }
 320
 321 sub parsechangelog {
 322     my $c = Dpkg::Control::Hash->new();
 323     my $p = new IO::Handle;
 324     my @cmd = (qw(dpkg-parsechangelog));
 325     open $p, '-|', @cmd or die $!;
 326     $c->parse($p);
 327     $?=0; $!=0; close $p or failedcmd @cmd;
 328     return $c;
 329 }
 330
 331 our %rmad;
 332
 333 sub archive_query ($) {
 334     my ($method) = @_;
 335     my $query = access_cfg('archive-query','RETURN-UNDEF');
 336     if (!defined $query) {
 337         my $distro = access_distro();
 338         if ($distro eq 'debian') {
 339             $query = "sshdakls:".
 340                 access_someuserhost('sshdakls').':'.
 341                 access_cfg('sshdakls-dir');
 342         } else {
 343             $query = "madison:$distro";
 344         }
 345     }
 346     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 347     my $proto = $1;
 348     my $data = $'; #';
 349     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 350 }
 351
 352 sub archive_query_madison ($$) {
 353     my ($proto,$data) = @_;
 354     die unless $proto eq 'madison';
 355     $rmad{$package} ||= cmdoutput
 356         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 357     my $rmad = $rmad{$package};
 358     return madison_parse($rmad);
 359 }
 360
 361 sub archive_query_sshdakls ($$) {
 362     my ($proto,$data) = @_;
 363     $data =~ s/:.*// or badcfg "invalid sshdakls method string \`$data'";
 364     my $dakls = cmdoutput
 365         access_cfg('ssh'), $data, qw(dak ls -asource),"-s$isuite",$package;
 366     return madison_parse($dakls);
 367 }
 368
 369 sub canonicalise_suite_sshdakls ($$) {
 370     my ($proto,$data) = @_;
 371     $data =~ m/:/ or badcfg "invalid sshdakls method string \`$data'";
 372     my @cmd =
 373         (access_cfg('ssh'), $`,
 374          "set -e; cd $';".
 375          " if test -h $isuite; then readlink $isuite; exit 0; fi;".
 376          " if test -d $isuite; then echo $isuite; exit 0; fi;".
 377          " exit 1");
 378     my $dakls = cmdoutput @cmd;
 379     failedcmd @cmd unless $dakls =~ m/^\w/;
 380     return $dakls;
 381 }
 382
 383 sub madison_parse ($) {
 384     my ($rmad) = @_;
 385     my @out;
 386     foreach my $l (split /\n/, $rmad) {
 387         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 388                   \s*( [^ \t|]+ )\s* \|
 389                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 390                   \s*( [^ \t|]+ )\s* }x or die "$rmad $?";
 391         $1 eq $package or die "$rmad $package ?";
 392         my $vsn = $2;
 393         my $newsuite = $3;
 394         my $component;
 395         if (defined $4) {
 396             $component = $4;
 397         } else {
 398             $component = access_cfg('archive-query-default-component');
 399         }
 400         $5 eq 'source' or die "$rmad ?";
 401         my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 402         my $subpath = "/pool/$component/$prefix/$package/${package}_$vsn.dsc";
 403         push @out, [$vsn,$subpath,$newsuite];
 404     }
 405     return sort { -version_compare_string($a->[0],$b->[0]); } @out;
 406 }
 407
 408 sub canonicalise_suite_madison ($$) {
 409     my @r = archive_query_madison($_[0],$_[1]);
 410     @r or fail
 411         "unable to canonicalise suite using package $package".
 412         " which does not appear to exist in suite $isuite;".
 413         " --existing-package may help";
 414     return $r[0][2];
 415 }
 416
 417 sub canonicalise_suite () {
 418     $csuite = archive_query('canonicalise_suite');
 419     if ($isuite ne $csuite) {
 420         # madison canonicalises for us
 421         print "canonical suite name for $isuite is $csuite\n";
 422     }
 423 }
 424
 425 sub get_archive_dsc () {
 426     canonicalise_suite();
 427     my @vsns = archive_query('archive_query');
 428     foreach my $vinfo (@vsns) {
 429         my ($vsn,$subpath) = @$vinfo;
 430         $dscurl = access_cfg('mirror').$subpath;
 431         $dscdata = url_get($dscurl);
 432         next unless defined $dscdata;
 433         $dscurl = access_cfg('mirror').$subpath;
 434         $dscdata = url_get($dscurl);
 435         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 436         print DEBUG Dumper($dscdata) if $debug>1;
 437         $dsc = parsecontrolfh($dscfh,$dscurl, allow_pgp=>1);
 438         print DEBUG Dumper($dsc) if $debug>1;
 439         my $fmt = getfield $dsc, 'Format';
 440         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 441         return $dsc;
 442     }
 443     return undef;
 444 }
 445
 446 sub check_for_git () {
 447     # returns 0 or 1
 448     my $how = access_cfg('git-check');
 449     if ($how eq 'ssh-cmd') {
 450         my @cmd =
 451             (access_cfg('ssh'),access_gituserhost(),
 452              " set -e; cd ".access_cfg('git-path').";".
 453              " if test -d $package.git; then echo 1; else echo 0; fi");
 454         my $r= cmdoutput @cmd;
 455         failedcmd @cmd unless $r =~ m/^[01]$/;
 456         return $r+0;
 457     } else {
 458         badcfg "unknown git-check \`$how'";
 459     }
 460 }
 461
 462 sub create_remote_git_repo () {
 463     my $how = access_cfg('git-create');
 464     if ($how eq 'ssh-cmd') {
 465         runcmd_ordryrun
 466             (access_cfg('ssh'),access_gituserhost(),
 467              "set -e; cd ".access_cfg('git-path').";".
 468              " cp -a _template $package.git");
 469     } else {
 470         badcfg "unknown git-create \`$how'";
 471     }
 472 }
 473
 474 our ($dsc_hash,$upload_hash);
 475
 476 our $ud = '.git/dgit/unpack';
 477
 478 sub prep_ud () {
 479     rmtree($ud);
 480     mkpath '.git/dgit';
 481     mkdir $ud or die $!;
 482 }
 483
 484 sub mktree_in_ud_from_only_subdir () {
 485     # changes into the subdir
 486     my (@dirs) = <*/.>;
 487     die unless @dirs==1;
 488     $dirs[0] =~ m#^([^/]+)/\.$# or die;
 489     my $dir = $1;
 490     chdir $dir or die "$dir $!";
 491     fail "source package contains .git directory" if stat '.git';
 492     die $! unless $!==&ENOENT;
 493     runcmd qw(git init -q);
 494     rmtree('.git/objects');
 495     symlink '../../../../objects','.git/objects' or die $!;
 496     runcmd @git, qw(add -Af);
 497     my $tree = cmdoutput @git, qw(write-tree);
 498     $tree =~ m/^\w+$/ or die "$tree ?";
 499     return ($tree,$dir);
 500 }
 501
 502 sub dsc_files () {
 503     my $field = $dsc->{'Checksums-Sha256'} || $dsc->{Files};
 504     defined $field or
 505         fail "missing both Checksums-Sha256 and Files in ".
 506         $dsc->get_option('name');
 507     map {
 508         m/^\w+ \d+ (\S+)$/ or
 509             fail "could not parse .dsc Files/Checksums line \`$_'";
 510         $1;
 511     } grep m/\S/, split /\n/, $field;
 512 }
 513
 514 sub is_orig_file ($) {
 515     local ($_) = @_;
 516     m/\.orig(?:-\w+)?\.tar\.\w+$/;
 517 }
 518
 519 sub make_commit ($) {
 520     my ($file) = @_;
 521     return cmdoutput @git, qw(hash-object -w -t commit), $file;
 522 }
 523
 524 sub generate_commit_from_dsc () {
 525     prep_ud();
 526     chdir $ud or die $!;
 527     my @files;
 528     foreach my $f (dsc_files()) {
 529         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
 530         push @files, $f;
 531         link "../../../$f", $f
 532             or $!==&ENOENT
 533             or die "$f $!";
 534     }
 535     runcmd @dget, qw(--), $dscurl;
 536     foreach my $f (grep { is_orig_file($_) } @files) {
 537         link $f, "../../../../$f"
 538             or $!==&EEXIST
 539             or die "$f $!";
 540     }
 541     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 542     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
 543     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
 544     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
 545     my $author = getfield $clogp, 'Maintainer';
 546     $author =~ s#,.*##ms;
 547     my $authline = "$author $date";
 548     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
 549         fail "unexpected commit author line format \`$authline'".
 550             " (was generated from changelog Maintainer field)";
 551     my $changes = getfield $clogp, 'Changes';
 552     open C, ">../commit.tmp" or die $!;
 553     print C <<END or die $!;
 554 tree $tree
 555 author $authline
 556 committer $authline
 557
 558 $changes
 559
 560 # imported from the archive
 561 END
 562     close C or die $!;
 563     my $outputhash = make_commit qw(../commit.tmp);
 564     my $cversion = getfield $clogp, 'Version';
 565     print "synthesised git commit from .dsc $cversion\n";
 566     if ($upload_hash) {
 567         runcmd @git, qw(reset --hard), $upload_hash;
 568         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
 569         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
 570         my $oversion = getfield $oldclogp, 'Version';
 571         my $vcmp =
 572             version_compare_string($oversion, $cversion);
 573         if ($vcmp < 0) {
 574             # git upload/ is earlier vsn than archive, use archive
 575             open C, ">../commit2.tmp" or die $!;
 576             print C <<END or die $!;
 577 tree $tree
 578 parent $upload_hash
 579 parent $outputhash
 580 author $authline
 581 committer $authline
 582
 583 Record $package ($cversion) in archive suite $csuite
 584 END
 585             $outputhash = make_commit qw(../commit2.tmp);
 586         } elsif ($vcmp > 0) {
 587             print STDERR <<END or die $!;
 588
 589 Version actually in archive:    $cversion (older)
 590 Last allegedly pushed/uploaded: $oversion (newer or same)
 591 $later_warning_msg
 592 END
 593             $outputhash = $upload_hash;
 594         } elsif ($outputhash ne $upload_hash) {
 595             fail "version in archive ($cversion)".
 596                 " is same as version in git".
 597                 " to-be-uploaded (upload/) branch ($oversion)".
 598                 " but archive version hash no commit hash?!";
 599         }
 600     }
 601     chdir '../../../..' or die $!;
 602     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
 603             'DGIT_ARCHIVE', $outputhash;
 604     cmdoutput @git, qw(log -n2), $outputhash;
 605     # ... gives git a chance to complain if our commit is malformed
 606     rmtree($ud);
 607     return $outputhash;
 608 }
 609
 610 sub ensure_we_have_orig () {
 611     foreach my $f (dsc_files()) {
 612         next unless is_orig_file($f);
 613         if (stat "../$f") {
 614             die "$f ?" unless -f _;
 615         } else {
 616             die "$f $!" unless $!==&ENOENT;
 617         }
 618         my $origurl = $dscurl;
 619         $origurl =~ s{/[^/]+$}{};
 620         $origurl .= "/$f";
 621         die "$f ?" unless $f =~ m/^${package}_/;
 622         die "$f ?" if $f =~ m#/#;
 623         runcmd_ordryrun qw(sh -ec),'cd ..; exec "$@"','x',
 624             @dget,'--',$origurl;
 625     }
 626 }
 627
 628 sub rev_parse ($) {
 629     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
 630 }
 631
 632 sub is_fast_fwd ($$) {
 633     my ($ancestor,$child) = @_;
 634     my $mb = cmdoutput @git, qw(merge-base), $ancestor, $child;
 635     return rev_parse($mb) eq rev_parse($ancestor);
 636 }
 637
 638 sub git_fetch_us () {
 639     badusage "cannot dry run with fetch" if $dryrun;
 640     runcmd @git, qw(fetch),access_giturl(),fetchspec();
 641 }
 642
 643 sub fetch_from_archive () {
 644     # ensures that lrref() is what is actually in the archive,
 645     #  one way or another
 646     get_archive_dsc() or return 0;
 647     foreach my $field (@ourdscfield) {
 648         $dsc_hash = $dsc->{$field};
 649         last if defined $dsc_hash;
 650     }
 651     if (defined $dsc_hash) {
 652         $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
 653         $dsc_hash = $&;
 654         print "last upload to archive specified git hash\n";
 655     } else {
 656         print "last upload to archive has NO git hash\n";
 657     }
 658
 659     my $lrref_fn = ".git/".lrref();
 660     if (open H, $lrref_fn) {
 661         $upload_hash = <H>;
 662         chomp $upload_hash;
 663         die "$lrref_fn $upload_hash ?" unless $upload_hash =~ m/^\w+$/;
 664     } elsif ($! == &ENOENT) {
 665         $upload_hash = '';
 666     } else {
 667         die "$lrref_fn $!";
 668     }
 669     print DEBUG "previous reference hash=$upload_hash\n";
 670     my $hash;
 671     if (defined $dsc_hash) {
 672         fail "missing git history even though dsc has hash -".
 673             " could not find commit $dsc_hash".
 674             " (should be in ".access_giturl()."#".rrref().")"
 675             unless $upload_hash;
 676         $hash = $dsc_hash;
 677         ensure_we_have_orig();
 678         if ($dsc_hash eq $upload_hash) {
 679         } elsif (is_fast_fwd($dsc_hash,$upload_hash)) {
 680             print STDERR <<END or die $!;
 681
 682 Git commit in archive is behind the last version allegedly pushed/uploaded.
 683 Commit referred to by archive:  $dsc_hash
 684 Last allegedly pushed/uploaded: $upload_hash
 685 $later_warning_msg
 686 END
 687             $hash = $upload_hash;
 688         } else {
 689             fail "archive's .dsc refers to ".$dsc_hash.
 690                 " but this is an ancestor of ".$upload_hash;
 691         }
 692     } else {
 693         $hash = generate_commit_from_dsc();
 694     }
 695     print DEBUG "current hash=$hash\n";
 696     if ($upload_hash) {
 697         fail "not fast forward on last upload branch!".
 698             " (archive's version left in DGIT_ARCHIVE)"
 699             unless is_fast_fwd($upload_hash, $hash);
 700     }
 701     if ($upload_hash ne $hash) {
 702         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
 703         if (!$dryrun) {
 704             cmdoutput @upd_cmd;
 705         } else {
 706             dryrun_report @upd_cmd;
 707         }
 708     }
 709     return 1;
 710 }
 711
 712 sub clone ($) {
 713     my ($dstdir) = @_;
 714     canonicalise_suite();
 715     badusage "dry run makes no sense with clone" if $dryrun;
 716     mkdir $dstdir or die "$dstdir $!";
 717     chdir "$dstdir" or die "$dstdir $!";
 718     runcmd @git, qw(init -q);
 719     runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
 720     open H, "> .git/HEAD" or die $!;
 721     print H "ref: ".lref()."\n" or die $!;
 722     close H or die $!;
 723     runcmd @git, qw(remote add), 'origin', access_giturl();
 724     if (check_for_git()) {
 725         print "fetching existing git history\n";
 726         git_fetch_us();
 727         runcmd @git, qw(fetch origin);
 728     } else {
 729         print "starting new git history\n";
 730     }
 731     fetch_from_archive() or no_such_package;
 732     runcmd @git, qw(reset --hard), lrref();
 733     printdone "ready for work in $dstdir";
 734 }
 735
 736 sub fetch () {
 737     if (check_for_git()) {
 738         git_fetch_us();
 739     }
 740     fetch_from_archive() or no_such_package();
 741     printdone "fetched into ".lrref();
 742 }
 743
 744 sub pull () {
 745     fetch();
 746     runcmd_ordryrun @git, qw(merge -m),"Merge from $csuite [dgit]",
 747         lrref();
 748     printdone "fetched to ".lrref()." and merged into HEAD";
 749 }
 750
 751 sub check_not_dirty () {
 752     my @cmd = (@git, qw(diff --quiet HEAD));
 753     printcmd(\*DEBUG,"+",@cmd) if $debug>0;
 754     $!=0; $?=0; system @cmd;
 755     return if !$! && !$?;
 756     if (!$! && $?==256) {
 757         fail "working tree is dirty (does not match HEAD)";
 758     } else {
 759         failedcmd @cmd;
 760     }
 761 }
 762
 763 sub commit_quilty_patch () {
 764     my $output = cmdoutput @git, qw(status --porcelain);
 765     my %adds;
 766     my $bad=0;
 767     foreach my $l (split /\n/, $output) {
 768         next unless $l =~ m/\S/;
 769         if ($l =~ m{^\?\? (.pc|debian/patches)}) {
 770             $adds{$1}++;
 771         } else {
 772             print STDERR "git status: $l\n";
 773             $bad++;
 774         }
 775     }
 776     fail "unexpected output from git status (is tree clean?)" if $bad;
 777     if (!%adds) {
 778         print "nothing quilty to commit, ok.\n";
 779         return;
 780     }
 781     runcmd_ordryrun @git, qw(add), sort keys %adds;
 782     my $m = "Commit Debian 3.0 (quilt) metadata";
 783     print "$m\n";
 784     runcmd_ordryrun @git, qw(commit -m), $m;
 785 }
 786
 787 sub madformat ($) {
 788     my ($format) = @_;
 789     return 0 unless $format eq '3.0 (quilt)';
 790     print "Format \`$format', urgh\n";
 791     return 1;
 792 }
 793
 794 sub dopush () {
 795     print DEBUG "actually entering push\n";
 796     my $clogp = parsechangelog();
 797     $package = getfield $clogp, 'Source';
 798     my $cversion = getfield $clogp, 'Version';
 799     my $dscfn = dscfn($cversion);
 800     stat "../$dscfn" or
 801         fail "looked for .dsc $dscfn, but $!;".
 802             " maybe you forgot to build";
 803     $dsc = parsecontrol("../$dscfn","$dscfn");
 804     my $dscpackage = getfield $dsc, 'Source';
 805     my $format = getfield $dsc, 'Format';
 806     my $dversion = getfield $dsc, 'Version';
 807     ($dscpackage eq $package && $dversion eq $cversion) or
 808         fail "$dsc is for $dscpackage $dversion".
 809             " but debian/changelog is for $package $cversion";
 810     print DEBUG "format $format\n";
 811     if (madformat($format)) {
 812         commit_quilty_patch();
 813     }
 814     check_not_dirty();
 815     prep_ud();
 816     chdir $ud or die $!;
 817     print "checking that $dscfn corresponds to HEAD\n";
 818     runcmd qw(dpkg-source -x --), "../../../../$dscfn";
 819     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
 820     chdir '../../../..' or die $!;
 821     printcmd \*DEBUG,"+",@_;
 822     my @diffcmd = (@git, qw(diff --exit-code), $tree);
 823     $!=0; $?=0;
 824     if (system @diffcmd) {
 825         if ($! && $?==256) {
 826             fail "$dscfn specifies a different tree to your HEAD commit;".
 827                 " perhaps you forgot to build";
 828         } else {
 829             failedcmd @diffcmd;
 830         }
 831     }
 832 #fetch from alioth
 833 #do fast forward check and maybe fake merge
 834 #    if (!is_fast_fwd(mainbranch
 835 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
 836 #        map { lref($_).":".rref($_) }
 837 #        (uploadbranch());
 838     $dsc->{$ourdscfield[0]} = rev_parse('HEAD');
 839     $dsc->save("../$dscfn.tmp") or die $!;
 840     if (!$changesfile) {
 841         my $multi = "../${package}_${cversion}_multi.changes";
 842         if (stat "$multi") {
 843             $changesfile = $multi;
 844         } else {
 845             $!==&ENOENT or die "$multi: $!";
 846             my $pat = "${package}_${cversion}_*.changes";
 847             my @cs = glob "../$pat";
 848             fail "failed to find unique changes file".
 849                 " (looked for $pat in .., or $multi);".
 850                 " perhaps you need to use dgit -C"
 851                 unless @cs==1;
 852             ($changesfile) = @cs;
 853         }
 854     }
 855     my $changes = parsecontrol($changesfile,$changesfile);
 856     foreach my $field (qw(Source Distribution Version)) {
 857         $changes->{$field} eq $clogp->{$field} or
 858             fail "changes field $field \`$changes->{$field}'".
 859                 " does not match changelog \`$clogp->{$field}'";
 860     }
 861     my $tag = debiantag($dversion);
 862     if (!check_for_git()) {
 863         create_remote_git_repo();
 864     }
 865     runcmd_ordryrun @git, qw(push),access_giturl(),"HEAD:".rrref();
 866     if (!$dryrun) {
 867         rename "../$dscfn.tmp","../$dscfn" or die "$dscfn $!";
 868     } else {
 869         print "[new .dsc left in $dscfn.tmp]\n";
 870     }
 871     if ($sign) {
 872         if (!defined $keyid) {
 873             $keyid = access_cfg('keyid','RETURN-UNDEF');
 874         }
 875         my @tag_cmd = (@git, qw(tag -s -m),
 876                        "Release $dversion for $csuite [dgit]");
 877         push @tag_cmd, qw(-u),$keyid if defined $keyid;
 878         push @tag_cmd, $tag;
 879         runcmd_ordryrun @tag_cmd;
 880         my @debsign_cmd = @debsign;
 881         push @debsign_cmd, "-k$keyid" if defined $keyid;
 882         push @debsign_cmd, $changesfile;
 883         runcmd_ordryrun @debsign_cmd;
 884     }
 885     runcmd_ordryrun @git, qw(push),access_giturl(),"refs/tags/$tag";
 886     my $host = access_cfg('upload-host','RETURN-UNDEF');
 887     my @hostarg = defined($host) ? ($host,) : ();
 888     runcmd_ordryrun @dput, @hostarg, $changesfile;
 889     printdone "pushed and uploaded $dversion";
 890 }
 891
 892 sub cmd_clone {
 893     parseopts();
 894     my $dstdir;
 895     badusage "-p is not allowed with clone; specify as argument instead"
 896         if defined $package;
 897     if (@ARGV==1) {
 898         ($package) = @ARGV;
 899     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
 900         ($package,$isuite) = @ARGV;
 901     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
 902         ($package,$dstdir) = @ARGV;
 903     } elsif (@ARGV==3) {
 904         ($package,$isuite,$dstdir) = @ARGV;
 905     } else {
 906         badusage "incorrect arguments to dgit clone";
 907     }
 908     $dstdir ||= "$package";
 909     clone($dstdir);
 910 }
 911
 912 sub branchsuite () {
 913     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
 914     if ($branch =~ m#$lbranch_re#o) {
 915         return $1;
 916     } else {
 917         return undef;
 918     }
 919 }
 920
 921 sub fetchpullargs () {
 922     if (!defined $package) {
 923         my $sourcep = parsecontrol('debian/control','debian/control');
 924         $package = getfield $sourcep, 'Source';
 925     }
 926     if (@ARGV==0) {
 927 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
 928         if (!$isuite) {
 929             my $clogp = parsechangelog();
 930             $isuite = getfield $clogp, 'Distribution';
 931         }
 932         canonicalise_suite();
 933         print "fetching from suite $csuite\n";
 934     } elsif (@ARGV==1) {
 935         ($isuite) = @ARGV;
 936         canonicalise_suite();
 937     } else {
 938         badusage "incorrect arguments to dgit fetch or dgit pull";
 939     }
 940 }
 941
 942 sub cmd_fetch {
 943     parseopts();
 944     fetchpullargs();
 945     fetch();
 946 }
 947
 948 sub cmd_pull {
 949     parseopts();
 950     fetchpullargs();
 951     pull();
 952 }
 953
 954 sub cmd_push {
 955     parseopts();
 956     badusage "-p is not allowed with dgit push" if defined $package;
 957     runcmd @git, qw(diff --quiet HEAD);
 958     my $clogp = parsechangelog();
 959     $package = getfield $clogp, 'Source';
 960     if (@ARGV==0) {
 961         $isuite = getfield $clogp, 'Distribution';
 962         if ($new_package) {
 963             local ($package) = $existing_package; # this is a hack
 964             canonicalise_suite();
 965         }
 966     } else {
 967         badusage "incorrect arguments to dgit push";
 968     }
 969     if (check_for_git()) {
 970         git_fetch_us();
 971     }
 972     if (fetch_from_archive()) {
 973         is_fast_fwd(lrref(), 'HEAD') or die;
 974     } else {
 975         $new_package or
 976             fail "package appears to be new in this suite;".
 977                 " if this is intentional, use --new";
 978     }
 979     dopush();
 980 }
 981
 982 our $version;
 983 our $sourcechanges;
 984 our $dscfn;
 985
 986 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
 987
 988 sub build_maybe_quilt_fixup () {
 989     if (!open F, "debian/source/format") {
 990         die $! unless $!==&ENOENT;
 991         return;
 992     }
 993     $_ = <F>;
 994     F->error and die $!;
 995     chomp;
 996     return unless madformat($_);
 997     # sigh
 998     my $headref = rev_parse('HEAD');
 999     my $time = time;
1000     my $patchname = "auto-$version-$headref-$time";
1001     my $author = cmdoutput @git, qw(log -n1), '--pretty=format:%an <%ae>';
1002     my $msg = cmdoutput @git, qw(log -n1), "--pretty=format:%s\n%b";
1003     my $descfn = ".git/dgit/quilt-description.tmp";
1004     open O, '>', $descfn or die "$descfn: $!";
1005     $msg =~ s/\n/\n /g;
1006     $msg =~ s/^\s+$/ ./mg;
1007     print O <<END or die $!;
1008 Description: $msg
1009  [generated from git commit $headref]
1010 Author: $author
1011
1012 ---
1013
1014 END
1015     close O or die $!;
1016     {
1017         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
1018         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
1019         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
1020         runcmd_ordryrun @dpkgsource, qw(--commit .), $patchname;
1021     }
1022     commit_quilty_patch();
1023 }
1024
1025 sub quilt_fixup_editor () {
1026     my $descfn = $ENV{$fakeeditorenv};
1027     my $editing = $ARGV[$#ARGV];
1028     open I1, '<', $descfn or die "$descfn: $!";
1029     open I2, '<', $editing or die "$editing: $!";
1030     unlink $editing or die "$editing: $!";
1031     open O, '>', $editing or die "$editing: $!";
1032     while (<I1>) { print O or die $!; } I1->error and die $!;
1033     my $copying = 0;
1034     while (<I2>) {
1035         $copying ||= m/^\-\-\- /;
1036         next unless $copying;
1037         print O or die $!;
1038     }
1039     I2->error and die $!;
1040     close O or die $1;
1041     exit 0;
1042 }
1043
1044 sub cmd_build {
1045     # we pass further options and args to git-buildpackage
1046     badusage "-p is not allowed with dgit build" if defined $package;
1047     badusage "dgit build implies --clean=dpkg-source" if defined $package;
1048     my $clogp = parsechangelog();
1049     $isuite = getfield $clogp, 'Distribution';
1050     $package = getfield $clogp, 'Source';
1051     $version = getfield $clogp, 'Version';
1052     build_maybe_quilt_fixup();
1053     my @cmd =
1054         (qw(git-buildpackage -us -uc --git-no-sign-tags),
1055          "--git-builder=@dpkgbuildpackage");
1056     unless (grep { m/^--git-debian-branch/ } @ARGV) {
1057         canonicalise_suite();
1058         push @cmd, "--git-debian-branch=".lbranch();
1059     }
1060     push @cmd, changesopts();
1061     runcmd_ordryrun @cmd, @ARGV;
1062     printdone "build successful\n";
1063 }
1064
1065 sub build_source {
1066     badusage "-p is not allowed with this action" if defined $package;
1067     check_not_dirty();
1068     my $clogp = parsechangelog();
1069     $package = getfield $clogp, 'Source';
1070     $isuite = getfield $clogp, 'Distribution';
1071     $version = getfield $clogp, 'Version';
1072     $sourcechanges = "${package}_${version}_source.changes";
1073     $dscfn = dscfn($version);
1074     build_maybe_quilt_fixup();
1075     if ($cleanmode eq 'dpkg-source') {
1076         runcmd_ordryrun (@dpkgbuildpackage, qw(-us -uc -S)), changesopts();
1077     } else {
1078         if ($cleanmode eq 'git') {
1079             runcmd_ordryrun @git, qw(clean -xdf);
1080         } elsif ($cleanmode eq 'none') {
1081         } else {
1082             die "$cleanmode ?";
1083         }
1084         my $pwd = cmdoutput qw(env - pwd);
1085         my $leafdir = basename $pwd;
1086         chdir ".." or die $!;
1087         runcmd_ordryrun @dpkgsource, qw(-b --), $leafdir;
1088         chdir $pwd or die $!;
1089         runcmd_ordryrun qw(sh -ec),
1090             'exec >$1; shift; exec "$@"','x',
1091             "../$sourcechanges",
1092             @dpkggenchanges, qw(-S), changesopts();
1093     }
1094 }
1095
1096 sub cmd_build_source {
1097     badusage "build-source takes no additional arguments" if @ARGV;
1098     build_source();
1099     printdone "source built, results in $dscfn and $sourcechanges";
1100 }
1101
1102 sub cmd_sbuild {
1103     build_source();
1104     chdir ".." or die $!;
1105     my $pat = "${package}_${version}_*.changes";
1106     if (!$dryrun) {
1107         stat $dscfn or fail "$dscfn (in parent directory): $!";
1108         stat $sourcechanges or fail "$sourcechanges (in parent directory): $!";
1109         foreach my $cf (glob $pat) {
1110             next if $cf eq $sourcechanges;
1111             unlink $cf or fail "remove $cf: $!";
1112         }
1113     }
1114     runcmd_ordryrun @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
1115     runcmd_ordryrun @mergechanges, glob $pat;
1116     my $multichanges = "${package}_${version}_multi.changes";
1117     if (!$dryrun) {
1118         stat $multichanges or fail "$multichanges: $!";
1119     }
1120     printdone "build successful, results in $multichanges\n" or die $!;
1121 }
1122
1123 sub cmd_quilt_fixup {
1124     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
1125     my $clogp = parsechangelog();
1126     $version = getfield $clogp, 'Version';
1127     build_maybe_quilt_fixup();
1128 }
1129
1130 sub parseopts () {
1131     my $om;
1132     while (@ARGV) {
1133         last unless $ARGV[0] =~ m/^-/;
1134         $_ = shift @ARGV;
1135         last if m/^--?$/;
1136         if (m/^--/) {
1137             if (m/^--dry-run$/) {
1138                 $dryrun=1;
1139             } elsif (m/^--no-sign$/) {
1140                 $sign=0;
1141             } elsif (m/^--help$/) {
1142                 helponly();
1143             } elsif (m/^--new$/) {
1144                 $new_package=1;
1145             } elsif (m/^--(\w+)=(.*)/s &&
1146                      ($om = $opts_opt_map{$1}) &&
1147                      length $om->[0]) {
1148                 $om->[0] = $2;
1149             } elsif (m/^--(\w+):(.*)/s &&
1150                      ($om = $opts_opt_map{$1})) {
1151                 push @$om, $2;
1152             } elsif (m/^--existing-package=(.*)/s) {
1153                 $existing_package = $1;
1154             } elsif (m/^--distro=(.*)/s) {
1155                 $idistro = $1;
1156             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
1157                 $cleanmode = $1;
1158             } elsif (m/^--clean=(.*)$/s) {
1159                 badusage "unknown cleaning mode \`$1'";
1160             } else {
1161                 badusage "unknown long option \`$_'";
1162             }
1163         } else {
1164             while (m/^-./s) {
1165                 if (s/^-n/-/) {
1166                     $dryrun=1;
1167                 } elsif (s/^-h/-/) {
1168                     helponly();
1169                 } elsif (s/^-D/-/) {
1170                     open DEBUG, ">&STDERR" or die $!;
1171                     $debug++;
1172                 } elsif (s/^-N/-/) {
1173                     $new_package=1;
1174                 } elsif (m/^-[vm]/) {
1175                     push @changesopts, $_;
1176                     $_ = '';
1177                 } elsif (s/^-c(.*=.*)//s) {
1178                     push @git, '-c', $1;
1179                 } elsif (s/^-d(.*)//s) {
1180                     $idistro = $1;
1181                 } elsif (s/^-C(.*)//s) {
1182                     $changesfile = $1;
1183                 } elsif (s/^-k(.*)//s) {
1184                     $keyid=$1;
1185                 } elsif (s/^-wn//s) {
1186                     $cleanmode = 'none';
1187                 } elsif (s/^-wg//s) {
1188                     $cleanmode = 'git';
1189                 } elsif (s/^-wd//s) {
1190                     $cleanmode = 'dpkg-source';
1191                 } else {
1192                     badusage "unknown short option \`$_'";
1193                 }
1194             }
1195         }
1196     }
1197 }
1198
1199 if ($ENV{$fakeeditorenv}) {
1200     quilt_fixup_editor();
1201 }
1202
1203 parseopts();
1204 print STDERR "DRY RUN ONLY\n" if $dryrun;
1205 if (!@ARGV) {
1206     print STDERR $helpmsg or die $!;
1207     exit 8;
1208 }
1209 my $cmd = shift @ARGV;
1210 $cmd =~ y/-/_/;
1211 { no strict qw(refs); &{"cmd_$cmd"}(); }