dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 $SIG{__WARN__} = sub { die $_[0]; };
  22
  23 use IO::Handle;
  24 use Data::Dumper;
  25 use LWP::UserAgent;
  26 use Dpkg::Control::Hash;
  27 use File::Path;
  28 use File::Temp qw(tempdir);
  29 use File::Basename;
  30 use Dpkg::Version;
  31 use POSIX;
  32 use IPC::Open2;
  33 use Digest::SHA;
  34 use Digest::MD5;
  35
  36 use Debian::Dgit;
  37
  38 our $our_version = 'UNRELEASED'; ###substituted###
  39
  40 our $rpushprotovsn = 2;
  41
  42 our $isuite = 'unstable';
  43 our $idistro;
  44 our $package;
  45 our @ropts;
  46
  47 our $sign = 1;
  48 our $dryrun_level = 0;
  49 our $changesfile;
  50 our $buildproductsdir = '..';
  51 our $new_package = 0;
  52 our $ignoredirty = 0;
  53 our $rmonerror = 1;
  54 our @deliberatelies;
  55 our %supersedes;
  56 our $existing_package = 'dpkg';
  57 our $cleanmode = 'dpkg-source';
  58 our $changes_since_version;
  59 our $quilt_mode;
  60 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  61 our $we_are_responder;
  62 our $initiator_tempdir;
  63
  64 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  65
  66 our $suite_re = '[-+.0-9a-z]+';
  67
  68 our (@git) = qw(git);
  69 our (@dget) = qw(dget);
  70 our (@curl) = qw(curl -f);
  71 our (@dput) = qw(dput);
  72 our (@debsign) = qw(debsign);
  73 our (@gpg) = qw(gpg);
  74 our (@sbuild) = qw(sbuild -A);
  75 our (@ssh) = 'ssh';
  76 our (@dgit) = qw(dgit);
  77 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  78 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  79 our (@dpkggenchanges) = qw(dpkg-genchanges);
  80 our (@mergechanges) = qw(mergechanges -f);
  81 our (@changesopts) = ('');
  82
  83 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  84                      'curl' => \@curl,
  85                      'dput' => \@dput,
  86                      'debsign' => \@debsign,
  87                      'gpg' => \@gpg,
  88                      'sbuild' => \@sbuild,
  89                      'ssh' => \@ssh,
  90                      'dgit' => \@dgit,
  91                      'dpkg-source' => \@dpkgsource,
  92                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  93                      'dpkg-genchanges' => \@dpkggenchanges,
  94                      'ch' => \@changesopts,
  95                      'mergechanges' => \@mergechanges);
  96
  97 our %opts_opt_cmdonly = ('gpg' => 1);
  98
  99 our $keyid;
 100
 101 autoflush STDOUT 1;
 102
 103 our $remotename = 'dgit';
 104 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 105 our $csuite;
 106 our $instead_distro;
 107
 108 sub lbranch () { return "$branchprefix/$csuite"; }
 109 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 110 sub lref () { return "refs/heads/".lbranch(); }
 111 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 112 sub rrref () { return server_ref($csuite); }
 113
 114 sub stripepoch ($) {
 115     my ($vsn) = @_;
 116     $vsn =~ s/^\d+\://;
 117     return $vsn;
 118 }
 119
 120 sub srcfn ($$) {
 121     my ($vsn,$sfx) = @_;
 122     return "${package}_".(stripepoch $vsn).$sfx
 123 }
 124
 125 sub dscfn ($) {
 126     my ($vsn) = @_;
 127     return srcfn($vsn,".dsc");
 128 }
 129
 130 our $us = 'dgit';
 131 initdebug('');
 132
 133 our @end;
 134 END {
 135     local ($?);
 136     foreach my $f (@end) {
 137         eval { $f->(); };
 138         warn "$us: cleanup: $@" if length $@;
 139     }
 140 };
 141
 142 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 143
 144 sub no_such_package () {
 145     print STDERR "$us: package $package does not exist in suite $isuite\n";
 146     exit 4;
 147 }
 148
 149 sub fetchspec () {
 150     local $csuite = '*';
 151     return  "+".rrref().":".lrref();
 152 }
 153
 154 sub changedir ($) {
 155     my ($newdir) = @_;
 156     printdebug "CD $newdir\n";
 157     chdir $newdir or die "chdir: $newdir: $!";
 158 }
 159
 160 sub deliberately ($) {
 161     my ($enquiry) = @_;
 162     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 163 }
 164
 165 #---------- remote protocol support, common ----------
 166
 167 # remote push initiator/responder protocol:
 168 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 169 #
 170 #  > file parsed-changelog
 171 #  [indicates that output of dpkg-parsechangelog follows]
 172 #  > data-block NBYTES
 173 #  > [NBYTES bytes of data (no newline)]
 174 #  [maybe some more blocks]
 175 #  > data-end
 176 #
 177 #  > file dsc
 178 #  [etc]
 179 #
 180 #  > file changes
 181 #  [etc]
 182 #
 183 #  > param head HEAD
 184 #
 185 #  > want signed-tag
 186 #  [indicates that signed tag is wanted]
 187 #  < data-block NBYTES
 188 #  < [NBYTES bytes of data (no newline)]
 189 #  [maybe some more blocks]
 190 #  < data-end
 191 #  < files-end
 192 #
 193 #  > want signed-dsc-changes
 194 #  < data-block NBYTES    [transfer of signed dsc]
 195 #  [etc]
 196 #  < data-block NBYTES    [transfer of signed changes]
 197 #  [etc]
 198 #  < files-end
 199 #
 200 #  > complete
 201
 202 our $i_child_pid;
 203
 204 sub i_child_report () {
 205     # Sees if our child has died, and reap it if so.  Returns a string
 206     # describing how it died if it failed, or undef otherwise.
 207     return undef unless $i_child_pid;
 208     my $got = waitpid $i_child_pid, WNOHANG;
 209     return undef if $got <= 0;
 210     die unless $got == $i_child_pid;
 211     $i_child_pid = undef;
 212     return undef unless $?;
 213     return "build host child ".waitstatusmsg();
 214 }
 215
 216 sub badproto ($$) {
 217     my ($fh, $m) = @_;
 218     fail "connection lost: $!" if $fh->error;
 219     fail "protocol violation; $m not expected";
 220 }
 221
 222 sub badproto_badread ($$) {
 223     my ($fh, $wh) = @_;
 224     fail "connection lost: $!" if $!;
 225     my $report = i_child_report();
 226     fail $report if defined $report;
 227     badproto $fh, "eof (reading $wh)";
 228 }
 229
 230 sub protocol_expect (&$) {
 231     my ($match, $fh) = @_;
 232     local $_;
 233     $_ = <$fh>;
 234     defined && chomp or badproto_badread $fh, "protocol message";
 235     if (wantarray) {
 236         my @r = &$match;
 237         return @r if @r;
 238     } else {
 239         my $r = &$match;
 240         return $r if $r;
 241     }
 242     badproto $fh, "\`$_'";
 243 }
 244
 245 sub protocol_send_file ($$) {
 246     my ($fh, $ourfn) = @_;
 247     open PF, "<", $ourfn or die "$ourfn: $!";
 248     for (;;) {
 249         my $d;
 250         my $got = read PF, $d, 65536;
 251         die "$ourfn: $!" unless defined $got;
 252         last if !$got;
 253         print $fh "data-block ".length($d)."\n" or die $!;
 254         print $fh $d or die $!;
 255     }
 256     PF->error and die "$ourfn $!";
 257     print $fh "data-end\n" or die $!;
 258     close PF;
 259 }
 260
 261 sub protocol_read_bytes ($$) {
 262     my ($fh, $nbytes) = @_;
 263     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 264     my $d;
 265     my $got = read $fh, $d, $nbytes;
 266     $got==$nbytes or badproto_badread $fh, "data block";
 267     return $d;
 268 }
 269
 270 sub protocol_receive_file ($$) {
 271     my ($fh, $ourfn) = @_;
 272     printdebug "() $ourfn\n";
 273     open PF, ">", $ourfn or die "$ourfn: $!";
 274     for (;;) {
 275         my ($y,$l) = protocol_expect {
 276             m/^data-block (.*)$/ ? (1,$1) :
 277             m/^data-end$/ ? (0,) :
 278             ();
 279         } $fh;
 280         last unless $y;
 281         my $d = protocol_read_bytes $fh, $l;
 282         print PF $d or die $!;
 283     }
 284     close PF or die $!;
 285 }
 286
 287 #---------- remote protocol support, responder ----------
 288
 289 sub responder_send_command ($) {
 290     my ($command) = @_;
 291     return unless $we_are_responder;
 292     # called even without $we_are_responder
 293     printdebug ">> $command\n";
 294     print PO $command, "\n" or die $!;
 295 }
 296
 297 sub responder_send_file ($$) {
 298     my ($keyword, $ourfn) = @_;
 299     return unless $we_are_responder;
 300     printdebug "]] $keyword $ourfn\n";
 301     responder_send_command "file $keyword";
 302     protocol_send_file \*PO, $ourfn;
 303 }
 304
 305 sub responder_receive_files ($@) {
 306     my ($keyword, @ourfns) = @_;
 307     die unless $we_are_responder;
 308     printdebug "[[ $keyword @ourfns\n";
 309     responder_send_command "want $keyword";
 310     foreach my $fn (@ourfns) {
 311         protocol_receive_file \*PI, $fn;
 312     }
 313     printdebug "[[\$\n";
 314     protocol_expect { m/^files-end$/ } \*PI;
 315 }
 316
 317 #---------- remote protocol support, initiator ----------
 318
 319 sub initiator_expect (&) {
 320     my ($match) = @_;
 321     protocol_expect { &$match } \*RO;
 322 }
 323
 324 #---------- end remote code ----------
 325
 326 sub progress {
 327     if ($we_are_responder) {
 328         my $m = join '', @_;
 329         responder_send_command "progress ".length($m) or die $!;
 330         print PO $m or die $!;
 331     } else {
 332         print @_, "\n";
 333     }
 334 }
 335
 336 our $ua;
 337
 338 sub url_get {
 339     if (!$ua) {
 340         $ua = LWP::UserAgent->new();
 341         $ua->env_proxy;
 342     }
 343     my $what = $_[$#_];
 344     progress "downloading $what...";
 345     my $r = $ua->get(@_) or die $!;
 346     return undef if $r->code == 404;
 347     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 348     return $r->decoded_content(charset => 'none');
 349 }
 350
 351 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 352
 353 sub runcmd {
 354     debugcmd "+",@_;
 355     $!=0; $?=0;
 356     failedcmd @_ if system @_;
 357 }
 358
 359 sub act_local () { return $dryrun_level <= 1; }
 360 sub act_scary () { return !$dryrun_level; }
 361
 362 sub printdone {
 363     if (!$dryrun_level) {
 364         progress "dgit ok: @_";
 365     } else {
 366         progress "would be ok: @_ (but dry run only)";
 367     }
 368 }
 369
 370 sub dryrun_report {
 371     printcmd(\*STDERR,$debugprefix."#",@_);
 372 }
 373
 374 sub runcmd_ordryrun {
 375     if (act_scary()) {
 376         runcmd @_;
 377     } else {
 378         dryrun_report @_;
 379     }
 380 }
 381
 382 sub runcmd_ordryrun_local {
 383     if (act_local()) {
 384         runcmd @_;
 385     } else {
 386         dryrun_report @_;
 387     }
 388 }
 389
 390 sub shell_cmd {
 391     my ($first_shell, @cmd) = @_;
 392     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 393 }
 394
 395 our $helpmsg = <<END;
 396 main usages:
 397   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 398   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 399   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 400   dgit [dgit-opts] push [dgit-opts] [suite]
 401   dgit [dgit-opts] rpush build-host:build-dir ...
 402 important dgit options:
 403   -k<keyid>           sign tag and package with <keyid> instead of default
 404   --dry-run -n        do not change anything, but go through the motions
 405   --damp-run -L       like --dry-run but make local changes, without signing
 406   --new -N            allow introducing a new package
 407   --debug -D          increase debug level
 408   -c<name>=<value>    set git config option (used directly by dgit too)
 409 END
 410
 411 our $later_warning_msg = <<END;
 412 Perhaps the upload is stuck in incoming.  Using the version from git.
 413 END
 414
 415 sub badusage {
 416     print STDERR "$us: @_\n", $helpmsg or die $!;
 417     exit 8;
 418 }
 419
 420 sub nextarg {
 421     @ARGV or badusage "too few arguments";
 422     return scalar shift @ARGV;
 423 }
 424
 425 sub cmd_help () {
 426     print $helpmsg or die $!;
 427     exit 0;
 428 }
 429
 430 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 431
 432 our %defcfg = ('dgit.default.distro' => 'debian',
 433                'dgit.default.username' => '',
 434                'dgit.default.archive-query-default-component' => 'main',
 435                'dgit.default.ssh' => 'ssh',
 436                'dgit.default.archive-query' => 'madison:',
 437                'dgit.default.sshpsql-dbname' => 'service=projectb',
 438                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 439                'dgit-distro.debian.git-host' => 'dgit-git.debian.net',
 440                'dgit-distro.debian.git-user-force' => 'dgit',
 441                'dgit-distro.debian.git-proto' => 'git+ssh://',
 442                'dgit-distro.debian.git-path' => '/dgit/debian/repos',
 443                'dgit-distro.debian.git-check' => 'ssh-cmd',
 444  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 445  'dgit-distro.debian.archive-query-tls-key',
 446     '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 447                'dgit-distro.debian.diverts.alioth' => '/alioth',
 448                'dgit-distro.debian/alioth.git-host' => 'git.debian.org',
 449                'dgit-distro.debian/alioth.git-user-force' => '',
 450                'dgit-distro.debian/alioth.git-proto' => 'git+ssh://',
 451                'dgit-distro.debian/alioth.git-path' => '/git/dgit-repos/repos',
 452                'dgit-distro.debian/alioth.git-create' => 'ssh-cmd',
 453                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 454                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 455  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 456  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 457                'dgit-distro.ubuntu.git-check' => 'false',
 458  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 459                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 460                'dgit-distro.test-dummy.username' => "alice",
 461                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 462                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 463                'dgit-distro.test-dummy.git-url' => "$td/git",
 464                'dgit-distro.test-dummy.git-host' => "git",
 465                'dgit-distro.test-dummy.git-path' => "$td/git",
 466                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 467                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 468                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 469                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 470                );
 471
 472 sub cfg {
 473     foreach my $c (@_) {
 474         return undef if $c =~ /RETURN-UNDEF/;
 475         my @cmd = (@git, qw(config --), $c);
 476         my $v;
 477         {
 478             local ($debuglevel) = $debuglevel-2;
 479             $v = cmdoutput_errok @cmd;
 480         };
 481         if ($?==0) {
 482             return $v;
 483         } elsif ($?!=256) {
 484             failedcmd @cmd;
 485         }
 486         my $dv = $defcfg{$c};
 487         return $dv if defined $dv;
 488     }
 489     badcfg "need value for one of: @_\n".
 490         "$us: distro or suite appears not to be (properly) supported";
 491 }
 492
 493 sub access_basedistro () {
 494     if (defined $idistro) {
 495         return $idistro;
 496     } else {
 497         return cfg("dgit-suite.$isuite.distro",
 498                    "dgit.default.distro");
 499     }
 500 }
 501
 502 sub access_quirk () {
 503     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 504     my $basedistro = access_basedistro();
 505     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 506                               'RETURN-UNDEF');
 507     if (defined $backports_quirk) {
 508         my $re = $backports_quirk;
 509         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 510         $re =~ s/\*/.*/g;
 511         $re =~ s/\%/([-0-9a-z_]+)/
 512             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 513         if ($isuite =~ m/^$re$/) {
 514             return ('backports',"$basedistro-backports",$1);
 515         }
 516     }
 517     return ('none',undef);
 518 }
 519
 520 sub access_distros () {
 521     # Returns list of distros to try, in order
 522     #
 523     # We want to try:
 524     #    0. `instead of' distro name(s) we have been pointed to
 525     #    1. the access_quirk distro, if any
 526     #    2a. the user's specified distro, or failing that  } basedistro
 527     #    2b. the distro calculated from the suite          }
 528     my @l = access_basedistro();
 529
 530     my (undef,$quirkdistro) = access_quirk();
 531     unshift @l, $quirkdistro;
 532     unshift @l, $instead_distro;
 533     return grep { defined } @l;
 534 }
 535
 536 sub access_cfg (@) {
 537     my (@keys) = @_;
 538     my @cfgs;
 539     # The nesting of these loops determines the search order.  We put
 540     # the key loop on the outside so that we search all the distros
 541     # for each key, before going on to the next key.  That means that
 542     # if access_cfg is called with a more specific, and then a less
 543     # specific, key, an earlier distro can override the less specific
 544     # without necessarily overriding any more specific keys.  (If the
 545     # distro wants to override the more specific keys it can simply do
 546     # so; whereas if we did the loop the other way around, it would be
 547     # impossible to for an earlier distro to override a less specific
 548     # key but not the more specific ones without restating the unknown
 549     # values of the more specific keys.
 550     my @realkeys;
 551     my @rundef;
 552     # We have to deal with RETURN-UNDEF specially, so that we don't
 553     # terminate the search prematurely.
 554     foreach (@keys) {
 555         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 556         push @realkeys, $_
 557     }
 558     foreach my $d (access_distros()) {
 559         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 560     }
 561     push @cfgs, map { "dgit.default.$_" } @realkeys;
 562     push @cfgs, @rundef;
 563     my $value = cfg(@cfgs);
 564     return $value;
 565 }
 566
 567 sub string_to_ssh ($) {
 568     my ($spec) = @_;
 569     if ($spec =~ m/\s/) {
 570         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 571     } else {
 572         return ($spec);
 573     }
 574 }
 575
 576 sub access_cfg_ssh () {
 577     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 578     if (!defined $gitssh) {
 579         return @ssh;
 580     } else {
 581         return string_to_ssh $gitssh;
 582     }
 583 }
 584
 585 sub access_runeinfo ($) {
 586     my ($info) = @_;
 587     return ": dgit ".access_basedistro()." $info ;";
 588 }
 589
 590 sub access_someuserhost ($) {
 591     my ($some) = @_;
 592     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 593     defined($user) && length($user) or
 594         $user = access_cfg("$some-user",'username');
 595     my $host = access_cfg("$some-host");
 596     return length($user) ? "$user\@$host" : $host;
 597 }
 598
 599 sub access_gituserhost () {
 600     return access_someuserhost('git');
 601 }
 602
 603 sub access_giturl (;$) {
 604     my ($optional) = @_;
 605     my $url = access_cfg('git-url','RETURN-UNDEF');
 606     if (!defined $url) {
 607         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 608         return undef unless defined $proto;
 609         $url =
 610             $proto.
 611             access_gituserhost().
 612             access_cfg('git-path');
 613     }
 614     return "$url/$package.git";
 615 }
 616
 617 sub parsecontrolfh ($$;$) {
 618     my ($fh, $desc, $allowsigned) = @_;
 619     our $dpkgcontrolhash_noissigned;
 620     my $c;
 621     for (;;) {
 622         my %opts = ('name' => $desc);
 623         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 624         $c = Dpkg::Control::Hash->new(%opts);
 625         $c->parse($fh,$desc) or die "parsing of $desc failed";
 626         last if $allowsigned;
 627         last if $dpkgcontrolhash_noissigned;
 628         my $issigned= $c->get_option('is_pgp_signed');
 629         if (!defined $issigned) {
 630             $dpkgcontrolhash_noissigned= 1;
 631             seek $fh, 0,0 or die "seek $desc: $!";
 632         } elsif ($issigned) {
 633             fail "control file $desc is (already) PGP-signed. ".
 634                 " Note that dgit push needs to modify the .dsc and then".
 635                 " do the signature itself";
 636         } else {
 637             last;
 638         }
 639     }
 640     return $c;
 641 }
 642
 643 sub parsecontrol {
 644     my ($file, $desc) = @_;
 645     my $fh = new IO::Handle;
 646     open $fh, '<', $file or die "$file: $!";
 647     my $c = parsecontrolfh($fh,$desc);
 648     $fh->error and die $!;
 649     close $fh;
 650     return $c;
 651 }
 652
 653 sub getfield ($$) {
 654     my ($dctrl,$field) = @_;
 655     my $v = $dctrl->{$field};
 656     return $v if defined $v;
 657     fail "missing field $field in ".$v->get_option('name');
 658 }
 659
 660 sub parsechangelog {
 661     my $c = Dpkg::Control::Hash->new();
 662     my $p = new IO::Handle;
 663     my @cmd = (qw(dpkg-parsechangelog), @_);
 664     open $p, '-|', @cmd or die $!;
 665     $c->parse($p);
 666     $?=0; $!=0; close $p or failedcmd @cmd;
 667     return $c;
 668 }
 669
 670 sub git_get_ref ($) {
 671     my ($refname) = @_;
 672     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 673     if (!defined $got) {
 674         $?==256 or fail "git show-ref failed (status $?)";
 675         printdebug "ref $refname= [show-ref exited 1]\n";
 676         return '';
 677     }
 678     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 679         printdebug "ref $refname=$1\n";
 680         return $1;
 681     } else {
 682         printdebug "ref $refname= [no match]\n";
 683         return '';
 684     }
 685 }
 686
 687 sub must_getcwd () {
 688     my $d = getcwd();
 689     defined $d or fail "getcwd failed: $!";
 690     return $d;
 691 }
 692
 693 our %rmad;
 694
 695 sub archive_query ($) {
 696     my ($method) = @_;
 697     my $query = access_cfg('archive-query','RETURN-UNDEF');
 698     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 699     my $proto = $1;
 700     my $data = $'; #';
 701     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 702 }
 703
 704 sub pool_dsc_subpath ($$) {
 705     my ($vsn,$component) = @_; # $package is implict arg
 706     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 707     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 708 }
 709
 710 #---------- `ftpmasterapi' archive query method (nascent) ----------
 711
 712 sub archive_api_query_cmd ($) {
 713     my ($subpath) = @_;
 714     my @cmd = qw(curl -sS);
 715     my $url = access_cfg('archive-query-url');
 716     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 717         my $host = $1;
 718         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF');
 719         foreach my $key (split /\:/, $keys) {
 720             $key =~ s/\%HOST\%/$host/g;
 721             if (!stat $key) {
 722                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 723                 next;
 724             }
 725             push @cmd, "--ca-certificate=$key", "--ca-directory=/dev/enoent";
 726             last;
 727         }
 728     }
 729     push @cmd, $url.$subpath;
 730     return @cmd;
 731 }
 732
 733 sub api_query ($$) {
 734     use JSON;
 735     my ($data, $subpath) = @_;
 736     badcfg "ftpmasterapi archive query method takes no data part"
 737         if length $data;
 738     my @cmd = archive_api_query_cmd($subpath);
 739     my $json = cmdoutput @cmd;
 740     return decode_json($json);
 741 }
 742
 743 sub canonicalise_suite_ftpmasterapi () {
 744     my ($proto,$data) = @_;
 745     my $suites = api_query($data, 'suites');
 746     my @matched;
 747     foreach my $entry (@$suites) {
 748         next unless grep {
 749             my $v = $entry->{$_};
 750             defined $v && $v eq $isuite;
 751         } qw(codename name);
 752         push @matched, $entry;
 753     }
 754     fail "unknown suite $isuite" unless @matched;
 755     my $cn;
 756     eval {
 757         @matched==1 or die "multiple matches for suite $isuite\n";
 758         $cn = "$matched[0]{codename}";
 759         defined $cn or die "suite $isuite info has no codename\n";
 760         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 761     };
 762     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 763         if length $@;
 764     return $cn;
 765 }
 766
 767 sub archive_query_ftpmasterapi () {
 768     my ($proto,$data) = @_;
 769     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 770     my @rows;
 771     my $digester = Digest::SHA->new(256);
 772     foreach my $entry (@$info) {
 773         eval {
 774             my $vsn = "$entry->{version}";
 775             my ($ok,$msg) = version_check $vsn;
 776             die "bad version: $msg\n" unless $ok;
 777             my $component = "$entry->{component}";
 778             $component =~ m/^$component_re$/ or die "bad component";
 779             my $filename = "$entry->{filename}";
 780             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 781                 or die "bad filename";
 782             my $sha256sum = "$entry->{sha256sum}";
 783             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 784             push @rows, [ $vsn, "/pool/$component/$filename",
 785                           $digester, $sha256sum ];
 786         };
 787         die "bad ftpmaster api response: $@\n".Dumper($entry)
 788             if length $@;
 789     }
 790     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 791     return @rows;
 792 }
 793
 794 #---------- `madison' archive query method ----------
 795
 796 sub archive_query_madison {
 797     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 798 }
 799
 800 sub madison_get_parse {
 801     my ($proto,$data) = @_;
 802     die unless $proto eq 'madison';
 803     if (!length $data) {
 804         $data= access_cfg('madison-distro','RETURN-UNDEF');
 805         $data //= access_basedistro();
 806     }
 807     $rmad{$proto,$data,$package} ||= cmdoutput
 808         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 809     my $rmad = $rmad{$proto,$data,$package};
 810
 811     my @out;
 812     foreach my $l (split /\n/, $rmad) {
 813         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 814                   \s*( [^ \t|]+ )\s* \|
 815                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 816                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 817         $1 eq $package or die "$rmad $package ?";
 818         my $vsn = $2;
 819         my $newsuite = $3;
 820         my $component;
 821         if (defined $4) {
 822             $component = $4;
 823         } else {
 824             $component = access_cfg('archive-query-default-component');
 825         }
 826         $5 eq 'source' or die "$rmad ?";
 827         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 828     }
 829     return sort { -version_compare($a->[0],$b->[0]); } @out;
 830 }
 831
 832 sub canonicalise_suite_madison {
 833     # madison canonicalises for us
 834     my @r = madison_get_parse(@_);
 835     @r or fail
 836         "unable to canonicalise suite using package $package".
 837         " which does not appear to exist in suite $isuite;".
 838         " --existing-package may help";
 839     return $r[0][2];
 840 }
 841
 842 #---------- `sshpsql' archive query method ----------
 843
 844 sub sshpsql ($$$) {
 845     my ($data,$runeinfo,$sql) = @_;
 846     if (!length $data) {
 847         $data= access_someuserhost('sshpsql').':'.
 848             access_cfg('sshpsql-dbname');
 849     }
 850     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 851     my ($userhost,$dbname) = ($`,$'); #';
 852     my @rows;
 853     my @cmd = (access_cfg_ssh, $userhost,
 854                access_runeinfo("ssh-psql $runeinfo").
 855                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 856                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 857     debugcmd "|",@cmd;
 858     open P, "-|", @cmd or die $!;
 859     while (<P>) {
 860         chomp or die;
 861         printdebug("$debugprefix>|$_|\n");
 862         push @rows, $_;
 863     }
 864     $!=0; $?=0; close P or failedcmd @cmd;
 865     @rows or die;
 866     my $nrows = pop @rows;
 867     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 868     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 869     @rows = map { [ split /\|/, $_ ] } @rows;
 870     my $ncols = scalar @{ shift @rows };
 871     die if grep { scalar @$_ != $ncols } @rows;
 872     return @rows;
 873 }
 874
 875 sub sql_injection_check {
 876     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 877 }
 878
 879 sub archive_query_sshpsql ($$) {
 880     my ($proto,$data) = @_;
 881     sql_injection_check $isuite, $package;
 882     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 883         SELECT source.version, component.name, files.filename, files.sha256sum
 884           FROM source
 885           JOIN src_associations ON source.id = src_associations.source
 886           JOIN suite ON suite.id = src_associations.suite
 887           JOIN dsc_files ON dsc_files.source = source.id
 888           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 889           JOIN component ON component.id = files_archive_map.component_id
 890           JOIN files ON files.id = dsc_files.file
 891          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 892            AND source.source='$package'
 893            AND files.filename LIKE '%.dsc';
 894 END
 895     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 896     my $digester = Digest::SHA->new(256);
 897     @rows = map {
 898         my ($vsn,$component,$filename,$sha256sum) = @$_;
 899         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 900     } @rows;
 901     return @rows;
 902 }
 903
 904 sub canonicalise_suite_sshpsql ($$) {
 905     my ($proto,$data) = @_;
 906     sql_injection_check $isuite;
 907     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 908         SELECT suite.codename
 909           FROM suite where suite_name='$isuite' or codename='$isuite';
 910 END
 911     @rows = map { $_->[0] } @rows;
 912     fail "unknown suite $isuite" unless @rows;
 913     die "ambiguous $isuite: @rows ?" if @rows>1;
 914     return $rows[0];
 915 }
 916
 917 #---------- `dummycat' archive query method ----------
 918
 919 sub canonicalise_suite_dummycat ($$) {
 920     my ($proto,$data) = @_;
 921     my $dpath = "$data/suite.$isuite";
 922     if (!open C, "<", $dpath) {
 923         $!==ENOENT or die "$dpath: $!";
 924         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 925         return $isuite;
 926     }
 927     $!=0; $_ = <C>;
 928     chomp or die "$dpath: $!";
 929     close C;
 930     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 931     return $_;
 932 }
 933
 934 sub archive_query_dummycat ($$) {
 935     my ($proto,$data) = @_;
 936     canonicalise_suite();
 937     my $dpath = "$data/package.$csuite.$package";
 938     if (!open C, "<", $dpath) {
 939         $!==ENOENT or die "$dpath: $!";
 940         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 941         return ();
 942     }
 943     my @rows;
 944     while (<C>) {
 945         next if m/^\#/;
 946         next unless m/\S/;
 947         die unless chomp;
 948         printdebug "dummycat query $csuite $package $dpath | $_\n";
 949         my @row = split /\s+/, $_;
 950         @row==2 or die "$dpath: $_ ?";
 951         push @rows, \@row;
 952     }
 953     C->error and die "$dpath: $!";
 954     close C;
 955     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 956 }
 957
 958 #---------- archive query entrypoints and rest of program ----------
 959
 960 sub canonicalise_suite () {
 961     return if defined $csuite;
 962     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 963     $csuite = archive_query('canonicalise_suite');
 964     if ($isuite ne $csuite) {
 965         progress "canonical suite name for $isuite is $csuite";
 966     }
 967 }
 968
 969 sub get_archive_dsc () {
 970     canonicalise_suite();
 971     my @vsns = archive_query('archive_query');
 972     foreach my $vinfo (@vsns) {
 973         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 974         $dscurl = access_cfg('mirror').$subpath;
 975         $dscdata = url_get($dscurl);
 976         if (!$dscdata) {
 977             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 978             next;
 979         }
 980         if ($digester) {
 981             $digester->reset();
 982             $digester->add($dscdata);
 983             my $got = $digester->hexdigest();
 984             $got eq $digest or
 985                 fail "$dscurl has hash $got but".
 986                     " archive told us to expect $digest";
 987         }
 988         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 989         printdebug Dumper($dscdata) if $debuglevel>1;
 990         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 991         printdebug Dumper($dsc) if $debuglevel>1;
 992         my $fmt = getfield $dsc, 'Format';
 993         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 994         $dsc_checked = !!$digester;
 995         return;
 996     }
 997     $dsc = undef;
 998 }
 999
1000 sub check_for_git ();
1001 sub check_for_git () {
1002     # returns 0 or 1
1003     my $how = access_cfg('git-check');
1004     if ($how eq 'ssh-cmd') {
1005         my @cmd =
1006             (access_cfg_ssh, access_gituserhost(),
1007              access_runeinfo("git-check $package").
1008              " set -e; cd ".access_cfg('git-path').";".
1009              " if test -d $package.git; then echo 1; else echo 0; fi");
1010         my $r= cmdoutput @cmd;
1011         if ($r =~ m/^divert (\w+)$/) {
1012             my $divert=$1;
1013             my ($usedistro,) = access_distros();
1014             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1015             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1016             printdebug "diverting $divert so using distro $instead_distro\n";
1017             return check_for_git();
1018         }
1019         failedcmd @cmd unless $r =~ m/^[01]$/;
1020         return $r+0;
1021     } elsif ($how eq 'true') {
1022         return 1;
1023     } elsif ($how eq 'false') {
1024         return 0;
1025     } else {
1026         badcfg "unknown git-check \`$how'";
1027     }
1028 }
1029
1030 sub create_remote_git_repo () {
1031     my $how = access_cfg('git-create');
1032     if ($how eq 'ssh-cmd') {
1033         runcmd_ordryrun
1034             (access_cfg_ssh, access_gituserhost(),
1035              access_runeinfo("git-create $package").
1036              "set -e; cd ".access_cfg('git-path').";".
1037              " cp -a _template $package.git");
1038     } elsif ($how eq 'true') {
1039         # nothing to do
1040     } else {
1041         badcfg "unknown git-create \`$how'";
1042     }
1043 }
1044
1045 our ($dsc_hash,$lastpush_hash);
1046
1047 our $ud = '.git/dgit/unpack';
1048
1049 sub prep_ud () {
1050     rmtree($ud);
1051     mkpath '.git/dgit';
1052     mkdir $ud or die $!;
1053 }
1054
1055 sub mktree_in_ud_here () {
1056     runcmd qw(git init -q);
1057     rmtree('.git/objects');
1058     symlink '../../../../objects','.git/objects' or die $!;
1059 }
1060
1061 sub git_write_tree () {
1062     my $tree = cmdoutput @git, qw(write-tree);
1063     $tree =~ m/^\w+$/ or die "$tree ?";
1064     return $tree;
1065 }
1066
1067 sub mktree_in_ud_from_only_subdir () {
1068     # changes into the subdir
1069     my (@dirs) = <*/.>;
1070     die unless @dirs==1;
1071     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1072     my $dir = $1;
1073     changedir $dir;
1074     fail "source package contains .git directory" if stat_exists '.git';
1075     mktree_in_ud_here();
1076     my $format=get_source_format();
1077     if (madformat($format)) {
1078         rmtree '.pc';
1079     }
1080     runcmd @git, qw(add -Af);
1081     my $tree=git_write_tree();
1082     return ($tree,$dir);
1083 }
1084
1085 sub dsc_files_info () {
1086     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1087                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1088                        ['Files',           'Digest::MD5', 'new()']) {
1089         my ($fname, $module, $method) = @$csumi;
1090         my $field = $dsc->{$fname};
1091         next unless defined $field;
1092         eval "use $module; 1;" or die $@;
1093         my @out;
1094         foreach (split /\n/, $field) {
1095             next unless m/\S/;
1096             m/^(\w+) (\d+) (\S+)$/ or
1097                 fail "could not parse .dsc $fname line \`$_'";
1098             my $digester = eval "$module"."->$method;" or die $@;
1099             push @out, {
1100                 Hash => $1,
1101                 Bytes => $2,
1102                 Filename => $3,
1103                 Digester => $digester,
1104             };
1105         }
1106         return @out;
1107     }
1108     fail "missing any supported Checksums-* or Files field in ".
1109         $dsc->get_option('name');
1110 }
1111
1112 sub dsc_files () {
1113     map { $_->{Filename} } dsc_files_info();
1114 }
1115
1116 sub is_orig_file ($;$) {
1117     local ($_) = $_[0];
1118     my $base = $_[1];
1119     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1120     defined $base or return 1;
1121     return $` eq $base;
1122 }
1123
1124 sub make_commit ($) {
1125     my ($file) = @_;
1126     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1127 }
1128
1129 sub clogp_authline ($) {
1130     my ($clogp) = @_;
1131     my $author = getfield $clogp, 'Maintainer';
1132     $author =~ s#,.*##ms;
1133     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1134     my $authline = "$author $date";
1135     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1136         fail "unexpected commit author line format \`$authline'".
1137         " (was generated from changelog Maintainer field)";
1138     return $authline;
1139 }
1140
1141 sub generate_commit_from_dsc () {
1142     prep_ud();
1143     changedir $ud;
1144
1145     foreach my $fi (dsc_files_info()) {
1146         my $f = $fi->{Filename};
1147         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1148
1149         link "../../../$f", $f
1150             or $!==&ENOENT
1151             or die "$f $!";
1152
1153         complete_file_from_dsc('.', $fi);
1154
1155         if (is_orig_file($f)) {
1156             link $f, "../../../../$f"
1157                 or $!==&EEXIST
1158                 or die "$f $!";
1159         }
1160     }
1161
1162     my $dscfn = "$package.dsc";
1163
1164     open D, ">", $dscfn or die "$dscfn: $!";
1165     print D $dscdata or die "$dscfn: $!";
1166     close D or die "$dscfn: $!";
1167     my @cmd = qw(dpkg-source);
1168     push @cmd, '--no-check' if $dsc_checked;
1169     push @cmd, qw(-x --), $dscfn;
1170     runcmd @cmd;
1171
1172     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1173     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1174     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1175     my $authline = clogp_authline $clogp;
1176     my $changes = getfield $clogp, 'Changes';
1177     open C, ">../commit.tmp" or die $!;
1178     print C <<END or die $!;
1179 tree $tree
1180 author $authline
1181 committer $authline
1182
1183 $changes
1184
1185 # imported from the archive
1186 END
1187     close C or die $!;
1188     my $outputhash = make_commit qw(../commit.tmp);
1189     my $cversion = getfield $clogp, 'Version';
1190     progress "synthesised git commit from .dsc $cversion";
1191     if ($lastpush_hash) {
1192         runcmd @git, qw(reset --hard), $lastpush_hash;
1193         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1194         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1195         my $oversion = getfield $oldclogp, 'Version';
1196         my $vcmp =
1197             version_compare($oversion, $cversion);
1198         if ($vcmp < 0) {
1199             # git upload/ is earlier vsn than archive, use archive
1200             open C, ">../commit2.tmp" or die $!;
1201             print C <<END or die $!;
1202 tree $tree
1203 parent $lastpush_hash
1204 parent $outputhash
1205 author $authline
1206 committer $authline
1207
1208 Record $package ($cversion) in archive suite $csuite
1209 END
1210             $outputhash = make_commit qw(../commit2.tmp);
1211         } elsif ($vcmp > 0) {
1212             print STDERR <<END or die $!;
1213
1214 Version actually in archive:    $cversion (older)
1215 Last allegedly pushed/uploaded: $oversion (newer or same)
1216 $later_warning_msg
1217 END
1218             $outputhash = $lastpush_hash;
1219         } else {
1220             $outputhash = $lastpush_hash;
1221         }
1222     }
1223     changedir '../../../..';
1224     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1225             'DGIT_ARCHIVE', $outputhash;
1226     cmdoutput @git, qw(log -n2), $outputhash;
1227     # ... gives git a chance to complain if our commit is malformed
1228     rmtree($ud);
1229     return $outputhash;
1230 }
1231
1232 sub complete_file_from_dsc ($$) {
1233     our ($dstdir, $fi) = @_;
1234     # Ensures that we have, in $dir, the file $fi, with the correct
1235     # contents.  (Downloading it from alongside $dscurl if necessary.)
1236
1237     my $f = $fi->{Filename};
1238     my $tf = "$dstdir/$f";
1239     my $downloaded = 0;
1240
1241     if (stat_exists $tf) {
1242         progress "using existing $f";
1243     } else {
1244         my $furl = $dscurl;
1245         $furl =~ s{/[^/]+$}{};
1246         $furl .= "/$f";
1247         die "$f ?" unless $f =~ m/^${package}_/;
1248         die "$f ?" if $f =~ m#/#;
1249         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1250         next if !act_local();
1251         $downloaded = 1;
1252     }
1253
1254     open F, "<", "$tf" or die "$tf: $!";
1255     $fi->{Digester}->reset();
1256     $fi->{Digester}->addfile(*F);
1257     F->error and die $!;
1258     my $got = $fi->{Digester}->hexdigest();
1259     $got eq $fi->{Hash} or
1260         fail "file $f has hash $got but .dsc".
1261             " demands hash $fi->{Hash} ".
1262             ($downloaded ? "(got wrong file from archive!)"
1263              : "(perhaps you should delete this file?)");
1264 }
1265
1266 sub ensure_we_have_orig () {
1267     foreach my $fi (dsc_files_info()) {
1268         my $f = $fi->{Filename};
1269         next unless is_orig_file($f);
1270         complete_file_from_dsc('..', $fi);
1271     }
1272 }
1273
1274 sub rev_parse ($) {
1275     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1276 }
1277
1278 sub is_fast_fwd ($$) {
1279     my ($ancestor,$child) = @_;
1280     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1281     my $mb = cmdoutput_errok @cmd;
1282     if (defined $mb) {
1283         return rev_parse($mb) eq rev_parse($ancestor);
1284     } else {
1285         $?==256 or failedcmd @cmd;
1286         return 0;
1287     }
1288 }
1289
1290 sub git_fetch_us () {
1291     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1292 }
1293
1294 sub fetch_from_archive () {
1295     # ensures that lrref() is what is actually in the archive,
1296     #  one way or another
1297     get_archive_dsc();
1298
1299     if ($dsc) {
1300         foreach my $field (@ourdscfield) {
1301             $dsc_hash = $dsc->{$field};
1302             last if defined $dsc_hash;
1303         }
1304         if (defined $dsc_hash) {
1305             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1306             $dsc_hash = $&;
1307             progress "last upload to archive specified git hash";
1308         } else {
1309             progress "last upload to archive has NO git hash";
1310         }
1311     } else {
1312         progress "no version available from the archive";
1313     }
1314
1315     $lastpush_hash = git_get_ref(lrref());
1316     printdebug "previous reference hash=$lastpush_hash\n";
1317     my $hash;
1318     if (defined $dsc_hash) {
1319         fail "missing remote git history even though dsc has hash -".
1320             " could not find ref ".lrref().
1321             " (should have been fetched from ".access_giturl()."#".rrref().")"
1322             unless $lastpush_hash;
1323         $hash = $dsc_hash;
1324         ensure_we_have_orig();
1325         if ($dsc_hash eq $lastpush_hash) {
1326         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1327             print STDERR <<END or die $!;
1328
1329 Git commit in archive is behind the last version allegedly pushed/uploaded.
1330 Commit referred to by archive:  $dsc_hash
1331 Last allegedly pushed/uploaded: $lastpush_hash
1332 $later_warning_msg
1333 END
1334             $hash = $lastpush_hash;
1335         } else {
1336             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1337                 "descendant of archive's .dsc hash ($dsc_hash)";
1338         }
1339     } elsif ($dsc) {
1340         $hash = generate_commit_from_dsc();
1341     } elsif ($lastpush_hash) {
1342         # only in git, not in the archive yet
1343         $hash = $lastpush_hash;
1344         print STDERR <<END or die $!;
1345
1346 Package not found in the archive, but has allegedly been pushed using dgit.
1347 $later_warning_msg
1348 END
1349     } else {
1350         printdebug "nothing found!\n";
1351         if (defined $skew_warning_vsn) {
1352             print STDERR <<END or die $!;
1353
1354 Warning: relevant archive skew detected.
1355 Archive allegedly contains $skew_warning_vsn
1356 But we were not able to obtain any version from the archive or git.
1357
1358 END
1359         }
1360         return 0;
1361     }
1362     printdebug "current hash=$hash\n";
1363     if ($lastpush_hash) {
1364         fail "not fast forward on last upload branch!".
1365             " (archive's version left in DGIT_ARCHIVE)"
1366             unless is_fast_fwd($lastpush_hash, $hash);
1367     }
1368     if (defined $skew_warning_vsn) {
1369         mkpath '.git/dgit';
1370         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1371         my $clogf = ".git/dgit/changelog.tmp";
1372         runcmd shell_cmd "exec >$clogf",
1373             @git, qw(cat-file blob), "$hash:debian/changelog";
1374         my $gotclogp = parsechangelog("-l$clogf");
1375         my $got_vsn = getfield $gotclogp, 'Version';
1376         printdebug "SKEW CHECK GOT $got_vsn\n";
1377         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1378             print STDERR <<END or die $!;
1379
1380 Warning: archive skew detected.  Using the available version:
1381 Archive allegedly contains    $skew_warning_vsn
1382 We were able to obtain only   $got_vsn
1383
1384 END
1385         }
1386     }
1387     if ($lastpush_hash ne $hash) {
1388         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1389         if (act_local()) {
1390             cmdoutput @upd_cmd;
1391         } else {
1392             dryrun_report @upd_cmd;
1393         }
1394     }
1395     return 1;
1396 }
1397
1398 sub clone ($) {
1399     my ($dstdir) = @_;
1400     canonicalise_suite();
1401     badusage "dry run makes no sense with clone" unless act_local();
1402     my $hasgit = check_for_git();
1403     mkdir $dstdir or die "$dstdir $!";
1404     changedir $dstdir;
1405     runcmd @git, qw(init -q);
1406     my $giturl = access_giturl(1);
1407     if (defined $giturl) {
1408         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1409         open H, "> .git/HEAD" or die $!;
1410         print H "ref: ".lref()."\n" or die $!;
1411         close H or die $!;
1412         runcmd @git, qw(remote add), 'origin', $giturl;
1413     }
1414     if ($hasgit) {
1415         progress "fetching existing git history";
1416         git_fetch_us();
1417         runcmd_ordryrun_local @git, qw(fetch origin);
1418     } else {
1419         progress "starting new git history";
1420     }
1421     fetch_from_archive() or no_such_package;
1422     my $vcsgiturl = $dsc->{'Vcs-Git'};
1423     if (length $vcsgiturl) {
1424         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1425         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1426     }
1427     runcmd @git, qw(reset --hard), lrref();
1428     printdone "ready for work in $dstdir";
1429 }
1430
1431 sub fetch () {
1432     if (check_for_git()) {
1433         git_fetch_us();
1434     }
1435     fetch_from_archive() or no_such_package();
1436     printdone "fetched into ".lrref();
1437 }
1438
1439 sub pull () {
1440     fetch();
1441     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1442         lrref();
1443     printdone "fetched to ".lrref()." and merged into HEAD";
1444 }
1445
1446 sub check_not_dirty () {
1447     return if $ignoredirty;
1448     my @cmd = (@git, qw(diff --quiet HEAD));
1449     debugcmd "+",@cmd;
1450     $!=0; $?=0; system @cmd;
1451     return if !$! && !$?;
1452     if (!$! && $?==256) {
1453         fail "working tree is dirty (does not match HEAD)";
1454     } else {
1455         failedcmd @cmd;
1456     }
1457 }
1458
1459 sub commit_admin ($) {
1460     my ($m) = @_;
1461     progress "$m";
1462     runcmd_ordryrun_local @git, qw(commit -m), $m;
1463 }
1464
1465 sub commit_quilty_patch () {
1466     my $output = cmdoutput @git, qw(status --porcelain);
1467     my %adds;
1468     foreach my $l (split /\n/, $output) {
1469         next unless $l =~ m/\S/;
1470         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1471             $adds{$1}++;
1472         }
1473     }
1474     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1475     if (!%adds) {
1476         progress "nothing quilty to commit, ok.";
1477         return;
1478     }
1479     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1480     commit_admin "Commit Debian 3.0 (quilt) metadata";
1481 }
1482
1483 sub get_source_format () {
1484     if (!open F, "debian/source/format") {
1485         die $! unless $!==&ENOENT;
1486         return '';
1487     }
1488     $_ = <F>;
1489     F->error and die $!;
1490     chomp;
1491     return $_;
1492 }
1493
1494 sub madformat ($) {
1495     my ($format) = @_;
1496     return 0 unless $format eq '3.0 (quilt)';
1497     if ($quilt_mode eq 'nocheck') {
1498         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1499         return 0;
1500     }
1501     progress "Format \`$format', checking/updating patch stack";
1502     return 1;
1503 }
1504
1505 sub push_parse_changelog ($) {
1506     my ($clogpfn) = @_;
1507
1508     my $clogp = Dpkg::Control::Hash->new();
1509     $clogp->load($clogpfn) or die;
1510
1511     $package = getfield $clogp, 'Source';
1512     my $cversion = getfield $clogp, 'Version';
1513     my $tag = debiantag($cversion);
1514     runcmd @git, qw(check-ref-format), $tag;
1515
1516     my $dscfn = dscfn($cversion);
1517
1518     return ($clogp, $cversion, $tag, $dscfn);
1519 }
1520
1521 sub push_parse_dsc ($$$) {
1522     my ($dscfn,$dscfnwhat, $cversion) = @_;
1523     $dsc = parsecontrol($dscfn,$dscfnwhat);
1524     my $dversion = getfield $dsc, 'Version';
1525     my $dscpackage = getfield $dsc, 'Source';
1526     ($dscpackage eq $package && $dversion eq $cversion) or
1527         fail "$dscfn is for $dscpackage $dversion".
1528             " but debian/changelog is for $package $cversion";
1529 }
1530
1531 sub push_mktag ($$$$$$$) {
1532     my ($head,$clogp,$tag,
1533         $dscfn,
1534         $changesfile,$changesfilewhat,
1535         $tfn) = @_;
1536
1537     $dsc->{$ourdscfield[0]} = $head;
1538     $dsc->save("$dscfn.tmp") or die $!;
1539
1540     my $changes = parsecontrol($changesfile,$changesfilewhat);
1541     foreach my $field (qw(Source Distribution Version)) {
1542         $changes->{$field} eq $clogp->{$field} or
1543             fail "changes field $field \`$changes->{$field}'".
1544                 " does not match changelog \`$clogp->{$field}'";
1545     }
1546
1547     my $cversion = getfield $clogp, 'Version';
1548     my $clogsuite = getfield $clogp, 'Distribution';
1549
1550     # We make the git tag by hand because (a) that makes it easier
1551     # to control the "tagger" (b) we can do remote signing
1552     my $authline = clogp_authline $clogp;
1553     my $delibs = join(" ", "",@deliberatelies);
1554     my $declaredistro = access_basedistro();
1555     open TO, '>', $tfn->('.tmp') or die $!;
1556     print TO <<END or die $!;
1557 object $head
1558 type commit
1559 tag $tag
1560 tagger $authline
1561
1562 $package release $cversion for $clogsuite ($csuite) [dgit]
1563 [dgit distro=$declaredistro$delibs]
1564 END
1565     foreach my $ref (sort keys %supersedes) {
1566                     print TO <<END or die $!;
1567 [dgit supersede:$ref=$supersedes{$ref}]
1568 END
1569     }
1570
1571     close TO or die $!;
1572
1573     my $tagobjfn = $tfn->('.tmp');
1574     if ($sign) {
1575         if (!defined $keyid) {
1576             $keyid = access_cfg('keyid','RETURN-UNDEF');
1577         }
1578         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1579         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1580         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1581         push @sign_cmd, $tfn->('.tmp');
1582         runcmd_ordryrun @sign_cmd;
1583         if (act_scary()) {
1584             $tagobjfn = $tfn->('.signed.tmp');
1585             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1586                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1587         }
1588     }
1589
1590     return ($tagobjfn);
1591 }
1592
1593 sub sign_changes ($) {
1594     my ($changesfile) = @_;
1595     if ($sign) {
1596         my @debsign_cmd = @debsign;
1597         push @debsign_cmd, "-k$keyid" if defined $keyid;
1598         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1599         push @debsign_cmd, $changesfile;
1600         runcmd_ordryrun @debsign_cmd;
1601     }
1602 }
1603
1604 sub dopush ($) {
1605     my ($forceflag) = @_;
1606     printdebug "actually entering push\n";
1607     prep_ud();
1608
1609     access_giturl(); # check that success is vaguely likely
1610
1611     my $clogpfn = ".git/dgit/changelog.822.tmp";
1612     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1613
1614     responder_send_file('parsed-changelog', $clogpfn);
1615
1616     my ($clogp, $cversion, $tag, $dscfn) =
1617         push_parse_changelog("$clogpfn");
1618
1619     my $dscpath = "$buildproductsdir/$dscfn";
1620     stat_exists $dscpath or
1621         fail "looked for .dsc $dscfn, but $!;".
1622             " maybe you forgot to build";
1623
1624     responder_send_file('dsc', $dscpath);
1625
1626     push_parse_dsc($dscpath, $dscfn, $cversion);
1627
1628     my $format = getfield $dsc, 'Format';
1629     printdebug "format $format\n";
1630     if (madformat($format)) {
1631         commit_quilty_patch();
1632     }
1633     check_not_dirty();
1634     changedir $ud;
1635     progress "checking that $dscfn corresponds to HEAD";
1636     runcmd qw(dpkg-source -x --),
1637         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1638     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1639     changedir '../../../..';
1640     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1641     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1642     debugcmd "+",@diffcmd;
1643     $!=0; $?=0;
1644     my $r = system @diffcmd;
1645     if ($r) {
1646         if ($r==256) {
1647             fail "$dscfn specifies a different tree to your HEAD commit;".
1648                 " perhaps you forgot to build".
1649                 ($diffopt eq '--exit-code' ? "" :
1650                  " (run with -D to see full diff output)");
1651         } else {
1652             failedcmd @diffcmd;
1653         }
1654     }
1655 #fetch from alioth
1656 #do fast forward check and maybe fake merge
1657 #    if (!is_fast_fwd(mainbranch
1658 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1659 #        map { lref($_).":".rref($_) }
1660 #        (uploadbranch());
1661     my $head = rev_parse('HEAD');
1662     if (!$changesfile) {
1663         my $multi = "$buildproductsdir/".
1664             "${package}_".(stripepoch $cversion)."_multi.changes";
1665         if (stat_exists "$multi") {
1666             $changesfile = $multi;
1667         } else {
1668             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1669             my @cs = glob "$buildproductsdir/$pat";
1670             fail "failed to find unique changes file".
1671                 " (looked for $pat in $buildproductsdir, or $multi);".
1672                 " perhaps you need to use dgit -C"
1673                 unless @cs==1;
1674             ($changesfile) = @cs;
1675         }
1676     } else {
1677         $changesfile = "$buildproductsdir/$changesfile";
1678     }
1679
1680     responder_send_file('changes',$changesfile);
1681     responder_send_command("param head $head");
1682     responder_send_command("param csuite $csuite");
1683
1684     if ($forceflag && defined $lastpush_hash) {
1685         git_for_each_tag_referring($lastpush_hash, sub {
1686             my ($objid,$fullrefname,$tagname) = @_;
1687             responder_send_command("supersedes $fullrefname=$objid");
1688             $supersedes{$fullrefname} = $objid;
1689         });
1690     }
1691
1692     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1693     my $tagobjfn;
1694
1695     if ($we_are_responder) {
1696         $tagobjfn = $tfn->('.signed.tmp');
1697         responder_receive_files('signed-tag', $tagobjfn);
1698     } else {
1699         $tagobjfn =
1700             push_mktag($head,$clogp,$tag,
1701                        $dscpath,
1702                        $changesfile,$changesfile,
1703                        $tfn);
1704     }
1705
1706     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1707     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1708     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1709     runcmd_ordryrun @git, qw(tag -v --), $tag;
1710
1711     if (!check_for_git()) {
1712         create_remote_git_repo();
1713     }
1714     runcmd_ordryrun @git, qw(push),access_giturl(),
1715         $forceflag."HEAD:".rrref(), "refs/tags/$tag";
1716     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1717
1718     if ($we_are_responder) {
1719         my $dryrunsuffix = act_local() ? "" : ".tmp";
1720         responder_receive_files('signed-dsc-changes',
1721                                 "$dscpath$dryrunsuffix",
1722                                 "$changesfile$dryrunsuffix");
1723     } else {
1724         if (act_local()) {
1725             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1726         } else {
1727             progress "[new .dsc left in $dscpath.tmp]";
1728         }
1729         sign_changes $changesfile;
1730     }
1731
1732     my $host = access_cfg('upload-host','RETURN-UNDEF');
1733     my @hostarg = defined($host) ? ($host,) : ();
1734     runcmd_ordryrun @dput, @hostarg, $changesfile;
1735     printdone "pushed and uploaded $cversion";
1736
1737     responder_send_command("complete");
1738 }
1739
1740 sub cmd_clone {
1741     parseopts();
1742     my $dstdir;
1743     badusage "-p is not allowed with clone; specify as argument instead"
1744         if defined $package;
1745     if (@ARGV==1) {
1746         ($package) = @ARGV;
1747     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1748         ($package,$isuite) = @ARGV;
1749     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1750         ($package,$dstdir) = @ARGV;
1751     } elsif (@ARGV==3) {
1752         ($package,$isuite,$dstdir) = @ARGV;
1753     } else {
1754         badusage "incorrect arguments to dgit clone";
1755     }
1756     $dstdir ||= "$package";
1757
1758     if (stat_exists $dstdir) {
1759         fail "$dstdir already exists";
1760     }
1761
1762     my $cwd_remove;
1763     if ($rmonerror && !$dryrun_level) {
1764         $cwd_remove= getcwd();
1765         unshift @end, sub {
1766             return unless defined $cwd_remove;
1767             if (!chdir "$cwd_remove") {
1768                 return if $!==&ENOENT;
1769                 die "chdir $cwd_remove: $!";
1770             }
1771             rmtree($dstdir) or die "remove $dstdir: $!\n";
1772         };
1773     }
1774
1775     clone($dstdir);
1776     $cwd_remove = undef;
1777 }
1778
1779 sub branchsuite () {
1780     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1781     if ($branch =~ m#$lbranch_re#o) {
1782         return $1;
1783     } else {
1784         return undef;
1785     }
1786 }
1787
1788 sub fetchpullargs () {
1789     if (!defined $package) {
1790         my $sourcep = parsecontrol('debian/control','debian/control');
1791         $package = getfield $sourcep, 'Source';
1792     }
1793     if (@ARGV==0) {
1794 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1795         if (!$isuite) {
1796             my $clogp = parsechangelog();
1797             $isuite = getfield $clogp, 'Distribution';
1798         }
1799         canonicalise_suite();
1800         progress "fetching from suite $csuite";
1801     } elsif (@ARGV==1) {
1802         ($isuite) = @ARGV;
1803         canonicalise_suite();
1804     } else {
1805         badusage "incorrect arguments to dgit fetch or dgit pull";
1806     }
1807 }
1808
1809 sub cmd_fetch {
1810     parseopts();
1811     fetchpullargs();
1812     fetch();
1813 }
1814
1815 sub cmd_pull {
1816     parseopts();
1817     fetchpullargs();
1818     pull();
1819 }
1820
1821 sub cmd_push {
1822     parseopts();
1823     badusage "-p is not allowed with dgit push" if defined $package;
1824     check_not_dirty();
1825     my $clogp = parsechangelog();
1826     $package = getfield $clogp, 'Source';
1827     my $specsuite;
1828     if (@ARGV==0) {
1829     } elsif (@ARGV==1) {
1830         ($specsuite) = (@ARGV);
1831     } else {
1832         badusage "incorrect arguments to dgit push";
1833     }
1834     $isuite = getfield $clogp, 'Distribution';
1835     if ($new_package) {
1836         local ($package) = $existing_package; # this is a hack
1837         canonicalise_suite();
1838     }
1839     if (defined $specsuite && $specsuite ne $isuite) {
1840         canonicalise_suite();
1841         $csuite eq $specsuite or
1842             fail "dgit push: changelog specifies $isuite ($csuite)".
1843                 " but command line specifies $specsuite";
1844     }
1845     if (check_for_git()) {
1846         git_fetch_us();
1847     }
1848     my $forceflag = '';
1849     if (fetch_from_archive()) {
1850         if (is_fast_fwd(lrref(), 'HEAD')) {
1851             # ok
1852         } elsif (deliberately('not-fast-forward') ||
1853                  deliberately('TEST-not-fast-forward-dgit-only')) {
1854             $forceflag = '+';
1855         } else {
1856             fail "dgit push: HEAD is not a descendant".
1857                 " of the archive's version.\n".
1858                 "dgit: To overwrite its contents,".
1859                 " use git merge -s ours ".lrref().".\n".
1860                 "dgit: To rewind history, if permitted by the archive,".
1861                 " use --deliberately-not-fast-forward";
1862         }
1863     } else {
1864         $new_package or
1865             fail "package appears to be new in this suite;".
1866                 " if this is intentional, use --new";
1867     }
1868     dopush($forceflag);
1869 }
1870
1871 #---------- remote commands' implementation ----------
1872
1873 sub cmd_remote_push_build_host {
1874     my ($nrargs) = shift @ARGV;
1875     my (@rargs) = @ARGV[0..$nrargs-1];
1876     @ARGV = @ARGV[$nrargs..$#ARGV];
1877     die unless @rargs;
1878     my ($dir,$vsnwant) = @rargs;
1879     # vsnwant is a comma-separated list; we report which we have
1880     # chosen in our ready response (so other end can tell if they
1881     # offered several)
1882     $debugprefix = ' ';
1883     $we_are_responder = 1;
1884     $us .= " (build host)";
1885
1886     open PI, "<&STDIN" or die $!;
1887     open STDIN, "/dev/null" or die $!;
1888     open PO, ">&STDOUT" or die $!;
1889     autoflush PO 1;
1890     open STDOUT, ">&STDERR" or die $!;
1891     autoflush STDOUT 1;
1892
1893     $vsnwant //= 1;
1894     fail "build host has dgit rpush protocol version".
1895         " $rpushprotovsn but invocation host has $vsnwant"
1896         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1897
1898     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1899
1900     changedir $dir;
1901     &cmd_push;
1902 }
1903
1904 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1905 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1906 #     a good error message)
1907
1908 our $i_tmp;
1909
1910 sub i_cleanup {
1911     local ($@, $?);
1912     my $report = i_child_report();
1913     if (defined $report) {
1914         printdebug "($report)\n";
1915     } elsif ($i_child_pid) {
1916         printdebug "(killing build host child $i_child_pid)\n";
1917         kill 15, $i_child_pid;
1918     }
1919     if (defined $i_tmp && !defined $initiator_tempdir) {
1920         changedir "/";
1921         eval { rmtree $i_tmp; };
1922     }
1923 }
1924
1925 END { i_cleanup(); }
1926
1927 sub i_method {
1928     my ($base,$selector,@args) = @_;
1929     $selector =~ s/\-/_/g;
1930     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1931 }
1932
1933 sub cmd_rpush {
1934     my $host = nextarg;
1935     my $dir;
1936     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1937         $host = $1;
1938         $dir = $'; #';
1939     } else {
1940         $dir = nextarg;
1941     }
1942     $dir =~ s{^-}{./-};
1943     my @rargs = ($dir,$rpushprotovsn);
1944     my @rdgit;
1945     push @rdgit, @dgit;
1946     push @rdgit, @ropts;
1947     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1948     push @rdgit, @ARGV;
1949     my @cmd = (@ssh, $host, shellquote @rdgit);
1950     debugcmd "+",@cmd;
1951
1952     if (defined $initiator_tempdir) {
1953         rmtree $initiator_tempdir;
1954         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1955         $i_tmp = $initiator_tempdir;
1956     } else {
1957         $i_tmp = tempdir();
1958     }
1959     $i_child_pid = open2(\*RO, \*RI, @cmd);
1960     changedir $i_tmp;
1961     initiator_expect { m/^dgit-remote-push-ready/ };
1962     for (;;) {
1963         my ($icmd,$iargs) = initiator_expect {
1964             m/^(\S+)(?: (.*))?$/;
1965             ($1,$2);
1966         };
1967         i_method "i_resp", $icmd, $iargs;
1968     }
1969 }
1970
1971 sub i_resp_progress ($) {
1972     my ($rhs) = @_;
1973     my $msg = protocol_read_bytes \*RO, $rhs;
1974     progress $msg;
1975 }
1976
1977 sub i_resp_complete {
1978     my $pid = $i_child_pid;
1979     $i_child_pid = undef; # prevents killing some other process with same pid
1980     printdebug "waiting for build host child $pid...\n";
1981     my $got = waitpid $pid, 0;
1982     die $! unless $got == $pid;
1983     die "build host child failed $?" if $?;
1984
1985     i_cleanup();
1986     printdebug "all done\n";
1987     exit 0;
1988 }
1989
1990 sub i_resp_file ($) {
1991     my ($keyword) = @_;
1992     my $localname = i_method "i_localname", $keyword;
1993     my $localpath = "$i_tmp/$localname";
1994     stat_exists $localpath and
1995         badproto \*RO, "file $keyword ($localpath) twice";
1996     protocol_receive_file \*RO, $localpath;
1997     i_method "i_file", $keyword;
1998 }
1999
2000 our %i_param;
2001
2002 sub i_resp_param ($) {
2003     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2004     $i_param{$1} = $2;
2005 }
2006
2007 sub i_resp_supersedes ($) {
2008     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2009         or badproto \*RO, "bad supersedes spec";
2010     my $r = system qw(git check-ref-format), $1;
2011     die "bad supersedes ref spec ($r)" if $r;
2012     $supersedes{$1} = $2;
2013 }
2014
2015 our %i_wanted;
2016
2017 sub i_resp_want ($) {
2018     my ($keyword) = @_;
2019     die "$keyword ?" if $i_wanted{$keyword}++;
2020     my @localpaths = i_method "i_want", $keyword;
2021     printdebug "[[  $keyword @localpaths\n";
2022     foreach my $localpath (@localpaths) {
2023         protocol_send_file \*RI, $localpath;
2024     }
2025     print RI "files-end\n" or die $!;
2026 }
2027
2028 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2029
2030 sub i_localname_parsed_changelog {
2031     return "remote-changelog.822";
2032 }
2033 sub i_file_parsed_changelog {
2034     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2035         push_parse_changelog "$i_tmp/remote-changelog.822";
2036     die if $i_dscfn =~ m#/|^\W#;
2037 }
2038
2039 sub i_localname_dsc {
2040     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2041     return $i_dscfn;
2042 }
2043 sub i_file_dsc { }
2044
2045 sub i_localname_changes {
2046     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2047     $i_changesfn = $i_dscfn;
2048     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2049     return $i_changesfn;
2050 }
2051 sub i_file_changes { }
2052
2053 sub i_want_signed_tag {
2054     printdebug Dumper(\%i_param, $i_dscfn);
2055     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2056         && defined $i_param{'csuite'}
2057         or badproto \*RO, "premature desire for signed-tag";
2058     my $head = $i_param{'head'};
2059     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2060
2061     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2062     $csuite = $&;
2063     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2064
2065     my $tagobjfn =
2066         push_mktag $head, $i_clogp, $i_tag,
2067             $i_dscfn,
2068             $i_changesfn, 'remote changes',
2069             sub { "tag$_[0]"; };
2070
2071     return $tagobjfn;
2072 }
2073
2074 sub i_want_signed_dsc_changes {
2075     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2076     sign_changes $i_changesfn;
2077     return ($i_dscfn, $i_changesfn);
2078 }
2079
2080 #---------- building etc. ----------
2081
2082 our $version;
2083 our $sourcechanges;
2084 our $dscfn;
2085
2086 #----- `3.0 (quilt)' handling -----
2087
2088 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2089
2090 sub quiltify_dpkg_commit ($$$;$) {
2091     my ($patchname,$author,$msg, $xinfo) = @_;
2092     $xinfo //= '';
2093
2094     mkpath '.git/dgit';
2095     my $descfn = ".git/dgit/quilt-description.tmp";
2096     open O, '>', $descfn or die "$descfn: $!";
2097     $msg =~ s/\s+$//g;
2098     $msg =~ s/\n/\n /g;
2099     $msg =~ s/^\s+$/ ./mg;
2100     print O <<END or die $!;
2101 Description: $msg
2102 Author: $author
2103 $xinfo
2104 ---
2105
2106 END
2107     close O or die $!;
2108
2109     {
2110         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2111         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2112         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2113         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2114     }
2115 }
2116
2117 sub quiltify_trees_differ ($$) {
2118     my ($x,$y) = @_;
2119     # returns 1 iff the two tree objects differ other than in debian/
2120     local $/=undef;
2121     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2122     my $diffs= cmdoutput @cmd;
2123     foreach my $f (split /\0/, $diffs) {
2124         next if $f eq 'debian';
2125         return 1;
2126     }
2127     return 0;
2128 }
2129
2130 sub quiltify_tree_sentinelfiles ($) {
2131     # lists the `sentinel' files present in the tree
2132     my ($x) = @_;
2133     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2134         qw(-- debian/rules debian/control);
2135     $r =~ s/\n/,/g;
2136     return $r;
2137 }
2138
2139 sub quiltify ($$) {
2140     my ($clogp,$target) = @_;
2141
2142     # Quilt patchification algorithm
2143     #
2144     # We search backwards through the history of the main tree's HEAD
2145     # (T) looking for a start commit S whose tree object is identical
2146     # to to the patch tip tree (ie the tree corresponding to the
2147     # current dpkg-committed patch series).  For these purposes
2148     # `identical' disregards anything in debian/ - this wrinkle is
2149     # necessary because dpkg-source treates debian/ specially.
2150     #
2151     # We can only traverse edges where at most one of the ancestors'
2152     # trees differs (in changes outside in debian/).  And we cannot
2153     # handle edges which change .pc/ or debian/patches.  To avoid
2154     # going down a rathole we avoid traversing edges which introduce
2155     # debian/rules or debian/control.  And we set a limit on the
2156     # number of edges we are willing to look at.
2157     #
2158     # If we succeed, we walk forwards again.  For each traversed edge
2159     # PC (with P parent, C child) (starting with P=S and ending with
2160     # C=T) to we do this:
2161     #  - git checkout C
2162     #  - dpkg-source --commit with a patch name and message derived from C
2163     # After traversing PT, we git commit the changes which
2164     # should be contained within debian/patches.
2165
2166     changedir '../fake';
2167     mktree_in_ud_here();
2168     rmtree '.pc';
2169     runcmd @git, 'add', '.';
2170     my $oldtiptree=git_write_tree();
2171     changedir '../work';
2172
2173     # The search for the path S..T is breadth-first.  We maintain a
2174     # todo list containing search nodes.  A search node identifies a
2175     # commit, and looks something like this:
2176     #  $p = {
2177     #      Commit => $git_commit_id,
2178     #      Child => $c,                          # or undef if P=T
2179     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2180     #      Nontrivial => true iff $p..$c has relevant changes
2181     #  };
2182
2183     my @todo;
2184     my @nots;
2185     my $sref_S;
2186     my $max_work=100;
2187     my %considered; # saves being exponential on some weird graphs
2188
2189     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2190
2191     my $not = sub {
2192         my ($search,$whynot) = @_;
2193         printdebug " search NOT $search->{Commit} $whynot\n";
2194         $search->{Whynot} = $whynot;
2195         push @nots, $search;
2196         no warnings qw(exiting);
2197         next;
2198     };
2199
2200     push @todo, {
2201         Commit => $target,
2202     };
2203
2204     while (@todo) {
2205         my $c = shift @todo;
2206         next if $considered{$c->{Commit}}++;
2207
2208         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2209
2210         printdebug "quiltify investigate $c->{Commit}\n";
2211
2212         # are we done?
2213         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2214             printdebug " search finished hooray!\n";
2215             $sref_S = $c;
2216             last;
2217         }
2218
2219         if ($quilt_mode eq 'nofix') {
2220             fail "quilt fixup required but quilt mode is \`nofix'\n".
2221                 "HEAD commit $c->{Commit} differs from tree implied by ".
2222                 " debian/patches (tree object $oldtiptree)";
2223         }
2224         if ($quilt_mode eq 'smash') {
2225             printdebug " search quitting smash\n";
2226             last;
2227         }
2228
2229         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2230         $not->($c, "has $c_sentinels not $t_sentinels")
2231             if $c_sentinels ne $t_sentinels;
2232
2233         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2234         $commitdata =~ m/\n\n/;
2235         $commitdata =~ $`;
2236         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2237         @parents = map { { Commit => $_, Child => $c } } @parents;
2238
2239         $not->($c, "root commit") if !@parents;
2240
2241         foreach my $p (@parents) {
2242             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2243         }
2244         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2245         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2246
2247         foreach my $p (@parents) {
2248             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2249
2250             my @cmd= (@git, qw(diff-tree -r --name-only),
2251                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2252             my $patchstackchange = cmdoutput @cmd;
2253             if (length $patchstackchange) {
2254                 $patchstackchange =~ s/\n/,/g;
2255                 $not->($p, "changed $patchstackchange");
2256             }
2257
2258             printdebug " search queue P=$p->{Commit} ",
2259                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2260             push @todo, $p;
2261         }
2262     }
2263
2264     if (!$sref_S) {
2265         printdebug "quiltify want to smash\n";
2266
2267         my $abbrev = sub {
2268             my $x = $_[0]{Commit};
2269             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2270             return $;
2271         };
2272         my $reportnot = sub {
2273             my ($notp) = @_;
2274             my $s = $abbrev->($notp);
2275             my $c = $notp->{Child};
2276             $s .= "..".$abbrev->($c) if $c;
2277             $s .= ": ".$c->{Whynot};
2278             return $s;
2279         };
2280         if ($quilt_mode eq 'linear') {
2281             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2282             foreach my $notp (@nots) {
2283                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2284             }
2285             fail "quilt fixup naive history linearisation failed.\n".
2286  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2287         } elsif ($quilt_mode eq 'smash') {
2288         } elsif ($quilt_mode eq 'auto') {
2289             progress "quilt fixup cannot be linear, smashing...";
2290         } else {
2291             die "$quilt_mode ?";
2292         }
2293
2294         my $time = time;
2295         my $ncommits = 3;
2296         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2297
2298         quiltify_dpkg_commit "auto-$version-$target-$time",
2299             (getfield $clogp, 'Maintainer'),
2300             "Automatically generated patch ($clogp->{Version})\n".
2301             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2302         return;
2303     }
2304
2305     progress "quiltify linearisation planning successful, executing...";
2306
2307     for (my $p = $sref_S;
2308          my $c = $p->{Child};
2309          $p = $p->{Child}) {
2310         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2311         next unless $p->{Nontrivial};
2312
2313         my $cc = $c->{Commit};
2314
2315         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2316         $commitdata =~ m/\n\n/ or die "$c ?";
2317         $commitdata = $`;
2318         my $msg = $'; #';
2319         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2320         my $author = $1;
2321
2322         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2323
2324         my $title = $1;
2325         my $patchname = $title;
2326         $patchname =~ s/[.:]$//;
2327         $patchname =~ y/ A-Z/-a-z/;
2328         $patchname =~ y/-a-z0-9_.+=~//cd;
2329         $patchname =~ s/^\W/x-$&/;
2330         $patchname = substr($patchname,0,40);
2331         my $index;
2332         for ($index='';
2333              stat "debian/patches/$patchname$index";
2334              $index++) { }
2335         $!==ENOENT or die "$patchname$index $!";
2336
2337         runcmd @git, qw(checkout -q), $cc;
2338
2339         # We use the tip's changelog so that dpkg-source doesn't
2340         # produce complaining messages from dpkg-parsechangelog.  None
2341         # of the information dpkg-source gets from the changelog is
2342         # actually relevant - it gets put into the original message
2343         # which dpkg-source provides our stunt editor, and then
2344         # overwritten.
2345         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2346
2347         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2348             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2349
2350         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2351     }
2352
2353     runcmd @git, qw(checkout -q master);
2354 }
2355
2356 sub build_maybe_quilt_fixup () {
2357     my $format=get_source_format;
2358     return unless madformat $format;
2359     # sigh
2360
2361     # Our objective is:
2362     #  - honour any existing .pc in case it has any strangeness
2363     #  - determine the git commit corresponding to the tip of
2364     #    the patch stack (if there is one)
2365     #  - if there is such a git commit, convert each subsequent
2366     #    git commit into a quilt patch with dpkg-source --commit
2367     #  - otherwise convert all the differences in the tree into
2368     #    a single git commit
2369     #
2370     # To do this we:
2371
2372     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2373     # dgit would include the .pc in the git tree.)  If there isn't
2374     # one, we need to generate one by unpacking the patches that we
2375     # have.
2376     #
2377     # We first look for a .pc in the git tree.  If there is one, we
2378     # will use it.  (This is not the normal case.)
2379     #
2380     # Otherwise need to regenerate .pc so that dpkg-source --commit
2381     # can work.  We do this as follows:
2382     #     1. Collect all relevant .orig from parent directory
2383     #     2. Generate a debian.tar.gz out of
2384     #         debian/{patches,rules,source/format}
2385     #     3. Generate a fake .dsc containing just these fields:
2386     #          Format Source Version Files
2387     #     4. Extract the fake .dsc
2388     #        Now the fake .dsc has a .pc directory.
2389     # (In fact we do this in every case, because in future we will
2390     # want to search for a good base commit for generating patches.)
2391     #
2392     # Then we can actually do the dpkg-source --commit
2393     #     1. Make a new working tree with the same object
2394     #        store as our main tree and check out the main
2395     #        tree's HEAD.
2396     #     2. Copy .pc from the fake's extraction, if necessary
2397     #     3. Run dpkg-source --commit
2398     #     4. If the result has changes to debian/, then
2399     #          - git-add them them
2400     #          - git-add .pc if we had a .pc in-tree
2401     #          - git-commit
2402     #     5. If we had a .pc in-tree, delete it, and git-commit
2403     #     6. Back in the main tree, fast forward to the new HEAD
2404
2405     my $clogp = parsechangelog();
2406     my $headref = rev_parse('HEAD');
2407
2408     prep_ud();
2409     changedir $ud;
2410
2411     my $upstreamversion=$version;
2412     $upstreamversion =~ s/-[^-]*$//;
2413
2414     my $fakeversion="$upstreamversion-~~DGITFAKE";
2415
2416     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2417     print $fakedsc <<END or die $!;
2418 Format: 3.0 (quilt)
2419 Source: $package
2420 Version: $fakeversion
2421 Files:
2422 END
2423
2424     my $dscaddfile=sub {
2425         my ($b) = @_;
2426
2427         my $md = new Digest::MD5;
2428
2429         my $fh = new IO::File $b, '<' or die "$b $!";
2430         stat $fh or die $!;
2431         my $size = -s _;
2432
2433         $md->addfile($fh);
2434         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2435     };
2436
2437     foreach my $f (<../../../../*>) { #/){
2438         my $b=$f; $b =~ s{.*/}{};
2439         next unless is_orig_file $b, srcfn $upstreamversion,'';
2440         link $f, $b or die "$b $!";
2441         $dscaddfile->($b);
2442     }
2443
2444     my @files=qw(debian/source/format debian/rules);
2445     if (stat_exists '../../../debian/patches') {
2446         push @files, 'debian/patches';
2447     }
2448
2449     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2450     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2451
2452     $dscaddfile->($debtar);
2453     close $fakedsc or die $!;
2454
2455     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2456
2457     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2458     rename $fakexdir, "fake" or die "$fakexdir $!";
2459
2460     mkdir "work" or die $!;
2461     changedir "work";
2462     mktree_in_ud_here();
2463     runcmd @git, qw(reset --hard), $headref;
2464
2465     my $mustdeletepc=0;
2466     if (stat_exists ".pc") {
2467         -d _ or die;
2468         progress "Tree already contains .pc - will use it then delete it.";
2469         $mustdeletepc=1;
2470     } else {
2471         rename '../fake/.pc','.pc' or die $!;
2472     }
2473
2474     quiltify($clogp,$headref);
2475
2476     if (!open P, '>>', ".pc/applied-patches") {
2477         $!==&ENOENT or die $!;
2478     } else {
2479         close P;
2480     }
2481
2482     commit_quilty_patch();
2483
2484     if ($mustdeletepc) {
2485         runcmd @git, qw(rm -rq .pc);
2486         commit_admin "Commit removal of .pc (quilt series tracking data)";
2487     }
2488
2489     changedir '../../../..';
2490     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2491 }
2492
2493 sub quilt_fixup_editor () {
2494     my $descfn = $ENV{$fakeeditorenv};
2495     my $editing = $ARGV[$#ARGV];
2496     open I1, '<', $descfn or die "$descfn: $!";
2497     open I2, '<', $editing or die "$editing: $!";
2498     unlink $editing or die "$editing: $!";
2499     open O, '>', $editing or die "$editing: $!";
2500     while (<I1>) { print O or die $!; } I1->error and die $!;
2501     my $copying = 0;
2502     while (<I2>) {
2503         $copying ||= m/^\-\-\- /;
2504         next unless $copying;
2505         print O or die $!;
2506     }
2507     I2->error and die $!;
2508     close O or die $1;
2509     exit 0;
2510 }
2511
2512 #----- other building -----
2513
2514 sub clean_tree () {
2515     if ($cleanmode eq 'dpkg-source') {
2516         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2517     } elsif ($cleanmode eq 'git') {
2518         runcmd_ordryrun_local @git, qw(clean -xdf);
2519     } elsif ($cleanmode eq 'none') {
2520     } else {
2521         die "$cleanmode ?";
2522     }
2523 }
2524
2525 sub cmd_clean () {
2526     badusage "clean takes no additional arguments" if @ARGV;
2527     clean_tree();
2528 }
2529
2530 sub build_prep () {
2531     badusage "-p is not allowed when building" if defined $package;
2532     check_not_dirty();
2533     clean_tree();
2534     my $clogp = parsechangelog();
2535     $isuite = getfield $clogp, 'Distribution';
2536     $package = getfield $clogp, 'Source';
2537     $version = getfield $clogp, 'Version';
2538     build_maybe_quilt_fixup();
2539 }
2540
2541 sub changesopts () {
2542     my @opts =@changesopts[1..$#changesopts];
2543     if (!defined $changes_since_version) {
2544         my @vsns = archive_query('archive_query');
2545         my @quirk = access_quirk();
2546         if ($quirk[0] eq 'backports') {
2547             local $isuite = $quirk[2];
2548             local $csuite;
2549             canonicalise_suite();
2550             push @vsns, archive_query('archive_query');
2551         }
2552         if (@vsns) {
2553             @vsns = map { $_->[0] } @vsns;
2554             @vsns = sort { -version_compare($a, $b) } @vsns;
2555             $changes_since_version = $vsns[0];
2556             progress "changelog will contain changes since $vsns[0]";
2557         } else {
2558             $changes_since_version = '_';
2559             progress "package seems new, not specifying -v<version>";
2560         }
2561     }
2562     if ($changes_since_version ne '_') {
2563         unshift @opts, "-v$changes_since_version";
2564     }
2565     return @opts;
2566 }
2567
2568 sub cmd_build {
2569     build_prep();
2570     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2571     printdone "build successful\n";
2572 }
2573
2574 sub cmd_git_build {
2575     build_prep();
2576     my @cmd =
2577         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2578          "--git-builder=@dpkgbuildpackage");
2579     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2580         canonicalise_suite();
2581         push @cmd, "--git-debian-branch=".lbranch();
2582     }
2583     push @cmd, changesopts();
2584     runcmd_ordryrun_local @cmd, @ARGV;
2585     printdone "build successful\n";
2586 }
2587
2588 sub build_source {
2589     build_prep();
2590     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2591     $dscfn = dscfn($version);
2592     if ($cleanmode eq 'dpkg-source') {
2593         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2594             changesopts();
2595     } else {
2596         my $pwd = must_getcwd();
2597         my $leafdir = basename $pwd;
2598         changedir "..";
2599         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2600         changedir $pwd;
2601         runcmd_ordryrun_local qw(sh -ec),
2602             'exec >$1; shift; exec "$@"','x',
2603             "../$sourcechanges",
2604             @dpkggenchanges, qw(-S), changesopts();
2605     }
2606 }
2607
2608 sub cmd_build_source {
2609     badusage "build-source takes no additional arguments" if @ARGV;
2610     build_source();
2611     printdone "source built, results in $dscfn and $sourcechanges";
2612 }
2613
2614 sub cmd_sbuild {
2615     build_source();
2616     changedir "..";
2617     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2618     if (act_local()) {
2619         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2620         stat_exists $sourcechanges
2621             or fail "$sourcechanges (in parent directory): $!";
2622         foreach my $cf (glob $pat) {
2623             next if $cf eq $sourcechanges;
2624             unlink $cf or fail "remove $cf: $!";
2625         }
2626     }
2627     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2628     my @changesfiles = glob $pat;
2629     @changesfiles = sort {
2630         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2631             or $a cmp $b
2632     } @changesfiles;
2633     fail "wrong number of different changes files (@changesfiles)"
2634         unless @changesfiles;
2635     runcmd_ordryrun_local @mergechanges, @changesfiles;
2636     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2637     if (act_local()) {
2638         stat_exists $multichanges or fail "$multichanges: $!";
2639     }
2640     printdone "build successful, results in $multichanges\n" or die $!;
2641 }
2642
2643 sub cmd_quilt_fixup {
2644     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2645     my $clogp = parsechangelog();
2646     $version = getfield $clogp, 'Version';
2647     $package = getfield $clogp, 'Source';
2648     build_maybe_quilt_fixup();
2649 }
2650
2651 sub cmd_archive_api_query {
2652     badusage "need only 1 subpath argument" unless @ARGV==1;
2653     my ($subpath) = @ARGV;
2654     my @cmd = archive_api_query_cmd($subpath);
2655     debugcmd ">",@cmd;
2656     exec @cmd or fail "exec curl: $!\n";
2657 }
2658
2659 #---------- argument parsing and main program ----------
2660
2661 sub cmd_version {
2662     print "dgit version $our_version\n" or die $!;
2663     exit 0;
2664 }
2665
2666 sub parseopts () {
2667     my $om;
2668
2669     if (defined $ENV{'DGIT_SSH'}) {
2670         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2671     } elsif (defined $ENV{'GIT_SSH'}) {
2672         @ssh = ($ENV{'GIT_SSH'});
2673     }
2674
2675     while (@ARGV) {
2676         last unless $ARGV[0] =~ m/^-/;
2677         $_ = shift @ARGV;
2678         last if m/^--?$/;
2679         if (m/^--/) {
2680             if (m/^--dry-run$/) {
2681                 push @ropts, $_;
2682                 $dryrun_level=2;
2683             } elsif (m/^--damp-run$/) {
2684                 push @ropts, $_;
2685                 $dryrun_level=1;
2686             } elsif (m/^--no-sign$/) {
2687                 push @ropts, $_;
2688                 $sign=0;
2689             } elsif (m/^--help$/) {
2690                 cmd_help();
2691             } elsif (m/^--version$/) {
2692                 cmd_version();
2693             } elsif (m/^--new$/) {
2694                 push @ropts, $_;
2695                 $new_package=1;
2696             } elsif (m/^--since-version=([^_]+|_)$/) {
2697                 push @ropts, $_;
2698                 $changes_since_version = $1;
2699             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2700                      ($om = $opts_opt_map{$1}) &&
2701                      length $om->[0]) {
2702                 push @ropts, $_;
2703                 $om->[0] = $2;
2704             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2705                      !$opts_opt_cmdonly{$1} &&
2706                      ($om = $opts_opt_map{$1})) {
2707                 push @ropts, $_;
2708                 push @$om, $2;
2709             } elsif (m/^--existing-package=(.*)/s) {
2710                 push @ropts, $_;
2711                 $existing_package = $1;
2712             } elsif (m/^--initiator-tempdir=(.*)/s) {
2713                 $initiator_tempdir = $1;
2714                 $initiator_tempdir =~ m#^/# or
2715                     badusage "--initiator-tempdir must be used specify an".
2716                         " absolute, not relative, directory."
2717             } elsif (m/^--distro=(.*)/s) {
2718                 push @ropts, $_;
2719                 $idistro = $1;
2720             } elsif (m/^--build-products-dir=(.*)/s) {
2721                 push @ropts, $_;
2722                 $buildproductsdir = $1;
2723             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2724                 push @ropts, $_;
2725                 $cleanmode = $1;
2726             } elsif (m/^--clean=(.*)$/s) {
2727                 badusage "unknown cleaning mode \`$1'";
2728             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
2729                 push @ropts, $_;
2730                 $quilt_mode = $1;
2731             } elsif (m/^--quilt=(.*)$/s) {
2732                 badusage "unknown quilt fixup mode \`$1'";
2733             } elsif (m/^--ignore-dirty$/s) {
2734                 push @ropts, $_;
2735                 $ignoredirty = 1;
2736             } elsif (m/^--no-quilt-fixup$/s) {
2737                 push @ropts, $_;
2738                 $quilt_mode = 'nocheck';
2739             } elsif (m/^--no-rm-on-error$/s) {
2740                 push @ropts, $_;
2741                 $rmonerror = 0;
2742             } elsif (m/^--deliberately-($deliberately_re)$/s) {
2743                 push @ropts, $_;
2744                 push @deliberatelies, $&;
2745             } else {
2746                 badusage "unknown long option \`$_'";
2747             }
2748         } else {
2749             while (m/^-./s) {
2750                 if (s/^-n/-/) {
2751                     push @ropts, $&;
2752                     $dryrun_level=2;
2753                 } elsif (s/^-L/-/) {
2754                     push @ropts, $&;
2755                     $dryrun_level=1;
2756                 } elsif (s/^-h/-/) {
2757                     cmd_help();
2758                 } elsif (s/^-D/-/) {
2759                     push @ropts, $&;
2760                     $debuglevel++;
2761                     enabledebug();
2762                 } elsif (s/^-N/-/) {
2763                     push @ropts, $&;
2764                     $new_package=1;
2765                 } elsif (s/^-v([^_]+|_)$//s) {
2766                     push @ropts, $&;
2767                     $changes_since_version = $1;
2768                 } elsif (m/^-m/) {
2769                     push @ropts, $&;
2770                     push @changesopts, $_;
2771                     $_ = '';
2772                 } elsif (s/^-c(.*=.*)//s) {
2773                     push @ropts, $&;
2774                     push @git, '-c', $1;
2775                 } elsif (s/^-d(.+)//s) {
2776                     push @ropts, $&;
2777                     $idistro = $1;
2778                 } elsif (s/^-C(.+)//s) {
2779                     push @ropts, $&;
2780                     $changesfile = $1;
2781                     if ($changesfile =~ s#^(.*)/##) {
2782                         $buildproductsdir = $1;
2783                     }
2784                 } elsif (s/^-k(.+)//s) {
2785                     $keyid=$1;
2786                 } elsif (m/^-[vdCk]$/) {
2787                     badusage
2788  "option \`$_' requires an argument (and no space before the argument)";
2789                 } elsif (s/^-wn$//s) {
2790                     push @ropts, $&;
2791                     $cleanmode = 'none';
2792                 } elsif (s/^-wg$//s) {
2793                     push @ropts, $&;
2794                     $cleanmode = 'git';
2795                 } elsif (s/^-wd$//s) {
2796                     push @ropts, $&;
2797                     $cleanmode = 'dpkg-source';
2798                 } else {
2799                     badusage "unknown short option \`$_'";
2800                 }
2801             }
2802         }
2803     }
2804 }
2805
2806 if ($ENV{$fakeeditorenv}) {
2807     quilt_fixup_editor();
2808 }
2809
2810 parseopts();
2811 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2812 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2813     if $dryrun_level == 1;
2814 if (!@ARGV) {
2815     print STDERR $helpmsg or die $!;
2816     exit 8;
2817 }
2818 my $cmd = shift @ARGV;
2819 $cmd =~ y/-/_/;
2820
2821 if (!defined $quilt_mode) {
2822     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
2823         // access_cfg('quilt-mode', 'RETURN-UNDEF')
2824         // 'linear';
2825     $quilt_mode =~ m/^($quilt_modes_re)$/
2826         or badcfg "unknown quilt-mode \`$quilt_mode'";
2827     $quilt_mode = $1;
2828 }
2829
2830 my $fn = ${*::}{"cmd_$cmd"};
2831 $fn or badusage "unknown operation $cmd";
2832 $fn->();