dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use IO::Handle;
  23 use Data::Dumper;
  24 use LWP::UserAgent;
  25 use Dpkg::Control::Hash;
  26 use File::Path;
  27 use File::Temp qw(tempdir);
  28 use File::Basename;
  29 use Dpkg::Version;
  30 use POSIX;
  31 use IPC::Open2;
  32 use Digest::SHA;
  33 use Digest::MD5;
  34 use Config;
  35
  36 our $our_version = 'UNRELEASED'; ###substituted###
  37
  38 our $rpushprotovsn = 2;
  39
  40 our $isuite = 'unstable';
  41 our $idistro;
  42 our $package;
  43 our @ropts;
  44
  45 our $sign = 1;
  46 our $dryrun_level = 0;
  47 our $changesfile;
  48 our $buildproductsdir = '..';
  49 our $new_package = 0;
  50 our $ignoredirty = 0;
  51 our $noquilt = 0;
  52 our $rmonerror = 1;
  53 our $existing_package = 'dpkg';
  54 our $cleanmode = 'dpkg-source';
  55 our $changes_since_version;
  56 our $we_are_responder;
  57 our $initiator_tempdir;
  58
  59 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  60
  61 our $suite_re = '[-+.0-9a-z]+';
  62
  63 our (@git) = qw(git);
  64 our (@dget) = qw(dget);
  65 our (@curl) = qw(curl -f);
  66 our (@dput) = qw(dput);
  67 our (@debsign) = qw(debsign);
  68 our (@gpg) = qw(gpg);
  69 our (@sbuild) = qw(sbuild -A);
  70 our (@ssh) = 'ssh';
  71 our (@dgit) = qw(dgit);
  72 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  73 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  74 our (@dpkggenchanges) = qw(dpkg-genchanges);
  75 our (@mergechanges) = qw(mergechanges -f);
  76 our (@changesopts) = ('');
  77
  78 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  79                      'curl' => \@curl,
  80                      'dput' => \@dput,
  81                      'debsign' => \@debsign,
  82                      'gpg' => \@gpg,
  83                      'sbuild' => \@sbuild,
  84                      'ssh' => \@ssh,
  85                      'dgit' => \@dgit,
  86                      'dpkg-source' => \@dpkgsource,
  87                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  88                      'dpkg-genchanges' => \@dpkggenchanges,
  89                      'ch' => \@changesopts,
  90                      'mergechanges' => \@mergechanges);
  91
  92 our %opts_opt_cmdonly = ('gpg' => 1);
  93
  94 our $keyid;
  95
  96 our $debug = 0;
  97 open DEBUG, ">/dev/null" or die $!;
  98
  99 autoflush STDOUT 1;
 100
 101 our $remotename = 'dgit';
 102 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 103 our $branchprefix = 'dgit';
 104 our $csuite;
 105 our $instead_distro;
 106
 107 sub lbranch () { return "$branchprefix/$csuite"; }
 108 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 109 sub lref () { return "refs/heads/".lbranch(); }
 110 sub lrref () { return "refs/remotes/$remotename/$branchprefix/$csuite"; }
 111 sub rrref () { return "refs/$branchprefix/$csuite"; }
 112 sub debiantag ($) {
 113     my ($v) = @_;
 114     $v =~ y/~:/_%/;
 115     return "debian/$v";
 116 }
 117
 118 sub stripepoch ($) {
 119     my ($vsn) = @_;
 120     $vsn =~ s/^\d+\://;
 121     return $vsn;
 122 }
 123
 124 sub srcfn ($$) {
 125     my ($vsn,$sfx) = @_;
 126     return "${package}_".(stripepoch $vsn).$sfx
 127 }
 128
 129 sub dscfn ($) {
 130     my ($vsn) = @_;
 131     return srcfn($vsn,".dsc");
 132 }
 133
 134 our $us = 'dgit';
 135 our $debugprefix = '';
 136
 137 our @end;
 138 END {
 139     local ($?);
 140     foreach my $f (@end) {
 141         eval { $f->(); };
 142         warn "$us: cleanup: $@" if length $@;
 143     }
 144 };
 145
 146 our @signames = split / /, $Config{sig_name};
 147
 148 sub waitstatusmsg () {
 149     if (!$?) {
 150         return "terminated, reporting successful completion";
 151     } elsif (!($? & 255)) {
 152         return "failed with error exit status ".WEXITSTATUS($?);
 153     } elsif (WIFSIGNALED($?)) {
 154         my $signum=WTERMSIG($?);
 155         return "died due to fatal signal ".
 156             ($signames[$signum] // "number $signum").
 157             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 158     } else {
 159         return "failed with unknown wait status ".$?;
 160     }
 161 }
 162
 163 sub printdebug { print DEBUG $debugprefix, @_ or die $!; }
 164
 165 sub fail {
 166     die $us.($we_are_responder ? " (build host)" : "").": @_\n";
 167 }
 168
 169 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 170
 171 sub no_such_package () {
 172     print STDERR "$us: package $package does not exist in suite $isuite\n";
 173     exit 4;
 174 }
 175
 176 sub fetchspec () {
 177     local $csuite = '*';
 178     return  "+".rrref().":".lrref();
 179 }
 180
 181 sub changedir ($) {
 182     my ($newdir) = @_;
 183     printdebug "CD $newdir\n";
 184     chdir $newdir or die "chdir: $newdir: $!";
 185 }
 186
 187 sub stat_exists ($) {
 188     my ($f) = @_;
 189     return 1 if stat $f;
 190     return 0 if $!==&ENOENT;
 191     die "stat $f: $!";
 192 }
 193
 194 #---------- remote protocol support, common ----------
 195
 196 # remote push initiator/responder protocol:
 197 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 198 #
 199 #  > file parsed-changelog
 200 #  [indicates that output of dpkg-parsechangelog follows]
 201 #  > data-block NBYTES
 202 #  > [NBYTES bytes of data (no newline)]
 203 #  [maybe some more blocks]
 204 #  > data-end
 205 #
 206 #  > file dsc
 207 #  [etc]
 208 #
 209 #  > file changes
 210 #  [etc]
 211 #
 212 #  > param head HEAD
 213 #
 214 #  > want signed-tag
 215 #  [indicates that signed tag is wanted]
 216 #  < data-block NBYTES
 217 #  < [NBYTES bytes of data (no newline)]
 218 #  [maybe some more blocks]
 219 #  < data-end
 220 #  < files-end
 221 #
 222 #  > want signed-dsc-changes
 223 #  < data-block NBYTES    [transfer of signed dsc]
 224 #  [etc]
 225 #  < data-block NBYTES    [transfer of signed changes]
 226 #  [etc]
 227 #  < files-end
 228 #
 229 #  > complete
 230
 231 our $i_child_pid;
 232
 233 sub i_child_report () {
 234     # Sees if our child has died, and reap it if so.  Returns a string
 235     # describing how it died if it failed, or undef otherwise.
 236     return undef unless $i_child_pid;
 237     my $got = waitpid $i_child_pid, WNOHANG;
 238     return undef if $got <= 0;
 239     die unless $got == $i_child_pid;
 240     $i_child_pid = undef;
 241     return undef unless $?;
 242     return "build host child ".waitstatusmsg();
 243 }
 244
 245 sub badproto ($$) {
 246     my ($fh, $m) = @_;
 247     fail "connection lost: $!" if $fh->error;
 248     fail "protocol violation; $m not expected";
 249 }
 250
 251 sub badproto_badread ($$) {
 252     my ($fh, $wh) = @_;
 253     fail "connection lost: $!" if $!;
 254     my $report = i_child_report();
 255     fail $report if defined $report;
 256     badproto $fh, "eof (reading $wh)";
 257 }
 258
 259 sub protocol_expect (&$) {
 260     my ($match, $fh) = @_;
 261     local $_;
 262     $_ = <$fh>;
 263     defined && chomp or badproto_badread $fh, "protocol message";
 264     if (wantarray) {
 265         my @r = &$match;
 266         return @r if @r;
 267     } else {
 268         my $r = &$match;
 269         return $r if $r;
 270     }
 271     badproto $fh, "\`$_'";
 272 }
 273
 274 sub protocol_send_file ($$) {
 275     my ($fh, $ourfn) = @_;
 276     open PF, "<", $ourfn or die "$ourfn: $!";
 277     for (;;) {
 278         my $d;
 279         my $got = read PF, $d, 65536;
 280         die "$ourfn: $!" unless defined $got;
 281         last if !$got;
 282         print $fh "data-block ".length($d)."\n" or die $!;
 283         print $fh $d or die $!;
 284     }
 285     PF->error and die "$ourfn $!";
 286     print $fh "data-end\n" or die $!;
 287     close PF;
 288 }
 289
 290 sub protocol_read_bytes ($$) {
 291     my ($fh, $nbytes) = @_;
 292     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 293     my $d;
 294     my $got = read $fh, $d, $nbytes;
 295     $got==$nbytes or badproto_badread $fh, "data block";
 296     return $d;
 297 }
 298
 299 sub protocol_receive_file ($$) {
 300     my ($fh, $ourfn) = @_;
 301     printdebug "() $ourfn\n";
 302     open PF, ">", $ourfn or die "$ourfn: $!";
 303     for (;;) {
 304         my ($y,$l) = protocol_expect {
 305             m/^data-block (.*)$/ ? (1,$1) :
 306             m/^data-end$/ ? (0,) :
 307             ();
 308         } $fh;
 309         last unless $y;
 310         my $d = protocol_read_bytes $fh, $l;
 311         print PF $d or die $!;
 312     }
 313     close PF or die $!;
 314 }
 315
 316 #---------- remote protocol support, responder ----------
 317
 318 sub responder_send_command ($) {
 319     my ($command) = @_;
 320     return unless $we_are_responder;
 321     # called even without $we_are_responder
 322     printdebug ">> $command\n";
 323     print PO $command, "\n" or die $!;
 324 }
 325
 326 sub responder_send_file ($$) {
 327     my ($keyword, $ourfn) = @_;
 328     return unless $we_are_responder;
 329     printdebug "]] $keyword $ourfn\n";
 330     responder_send_command "file $keyword";
 331     protocol_send_file \*PO, $ourfn;
 332 }
 333
 334 sub responder_receive_files ($@) {
 335     my ($keyword, @ourfns) = @_;
 336     die unless $we_are_responder;
 337     printdebug "[[ $keyword @ourfns\n";
 338     responder_send_command "want $keyword";
 339     foreach my $fn (@ourfns) {
 340         protocol_receive_file \*PI, $fn;
 341     }
 342     printdebug "[[\$\n";
 343     protocol_expect { m/^files-end$/ } \*PI;
 344 }
 345
 346 #---------- remote protocol support, initiator ----------
 347
 348 sub initiator_expect (&) {
 349     my ($match) = @_;
 350     protocol_expect { &$match } \*RO;
 351 }
 352
 353 #---------- end remote code ----------
 354
 355 sub progress {
 356     if ($we_are_responder) {
 357         my $m = join '', @_;
 358         responder_send_command "progress ".length($m) or die $!;
 359         print PO $m or die $!;
 360     } else {
 361         print @_, "\n";
 362     }
 363 }
 364
 365 our $ua;
 366
 367 sub url_get {
 368     if (!$ua) {
 369         $ua = LWP::UserAgent->new();
 370         $ua->env_proxy;
 371     }
 372     my $what = $_[$#_];
 373     progress "downloading $what...";
 374     my $r = $ua->get(@_) or die $!;
 375     return undef if $r->code == 404;
 376     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 377     return $r->decoded_content(charset => 'none');
 378 }
 379
 380 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 381
 382 sub shellquote {
 383     my @out;
 384     local $_;
 385     foreach my $a (@_) {
 386         $_ = $a;
 387         if (m{[^-=_./0-9a-z]}i) {
 388             s{['\\]}{'\\$&'}g;
 389             push @out, "'$_'";
 390         } else {
 391             push @out, $_;
 392         }
 393     }
 394     return join ' ', @out;
 395 }
 396
 397 sub printcmd {
 398     my $fh = shift @_;
 399     my $intro = shift @_;
 400     print $fh $intro," " or die $!;
 401     print $fh shellquote @_ or die $!;
 402     print $fh "\n" or die $!;
 403 }
 404
 405 sub failedcmd {
 406     { local ($!); printcmd \*STDERR, "$us: failed command:", @_ or die $!; };
 407     if ($!) {
 408         fail "failed to fork/exec: $!";
 409     } elsif ($?) {
 410         fail "subprocess ".waitstatusmsg();
 411     } else {
 412         fail "subprocess produced invalid output";
 413     }
 414 }
 415
 416 sub runcmd {
 417     printcmd(\*DEBUG,$debugprefix."+",@_) if $debug>0;
 418     $!=0; $?=0;
 419     failedcmd @_ if system @_;
 420 }
 421
 422 sub act_local () { return $dryrun_level <= 1; }
 423 sub act_scary () { return !$dryrun_level; }
 424
 425 sub printdone {
 426     if (!$dryrun_level) {
 427         progress "dgit ok: @_";
 428     } else {
 429         progress "would be ok: @_ (but dry run only)";
 430     }
 431 }
 432
 433 sub cmdoutput_errok {
 434     die Dumper(\@_)." ?" if grep { !defined } @_;
 435     printcmd(\*DEBUG,$debugprefix."|",@_) if $debug>0;
 436     open P, "-|", @_ or die $!;
 437     my $d;
 438     $!=0; $?=0;
 439     { local $/ = undef; $d = <P>; }
 440     die $! if P->error;
 441     if (!close P) { printdebug "=>!$?\n" if $debug>0; return undef; }
 442     chomp $d;
 443     $d =~ m/^.*/;
 444     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debug>0; #';
 445     return $d;
 446 }
 447
 448 sub cmdoutput {
 449     my $d = cmdoutput_errok @_;
 450     defined $d or failedcmd @_;
 451     return $d;
 452 }
 453
 454 sub dryrun_report {
 455     printcmd(\*STDERR,$debugprefix."#",@_);
 456 }
 457
 458 sub runcmd_ordryrun {
 459     if (act_scary()) {
 460         runcmd @_;
 461     } else {
 462         dryrun_report @_;
 463     }
 464 }
 465
 466 sub runcmd_ordryrun_local {
 467     if (act_local()) {
 468         runcmd @_;
 469     } else {
 470         dryrun_report @_;
 471     }
 472 }
 473
 474 sub shell_cmd {
 475     my ($first_shell, @cmd) = @_;
 476     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 477 }
 478
 479 our $helpmsg = <<END;
 480 main usages:
 481   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 482   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 483   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 484   dgit [dgit-opts] push [dgit-opts] [suite]
 485   dgit [dgit-opts] rpush build-host:build-dir ...
 486 important dgit options:
 487   -k<keyid>           sign tag and package with <keyid> instead of default
 488   --dry-run -n        do not change anything, but go through the motions
 489   --damp-run -L       like --dry-run but make local changes, without signing
 490   --new -N            allow introducing a new package
 491   --debug -D          increase debug level
 492   -c<name>=<value>    set git config option (used directly by dgit too)
 493 END
 494
 495 our $later_warning_msg = <<END;
 496 Perhaps the upload is stuck in incoming.  Using the version from git.
 497 END
 498
 499 sub badusage {
 500     print STDERR "$us: @_\n", $helpmsg or die $!;
 501     exit 8;
 502 }
 503
 504 sub nextarg {
 505     @ARGV or badusage "too few arguments";
 506     return scalar shift @ARGV;
 507 }
 508
 509 sub cmd_help () {
 510     print $helpmsg or die $!;
 511     exit 0;
 512 }
 513
 514 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 515
 516 our %defcfg = ('dgit.default.distro' => 'debian',
 517                'dgit.default.username' => '',
 518                'dgit.default.archive-query-default-component' => 'main',
 519                'dgit.default.ssh' => 'ssh',
 520                'dgit.default.archive-query' => 'madison:',
 521                'dgit.default.sshpsql-dbname' => 'service=projectb',
 522                'dgit-distro.debian.archive-query' => 'sshpsql:',
 523                'dgit-distro.debian.git-host' => 'git.debian.org',
 524                'dgit-distro.debian.git-proto' => 'git+ssh://',
 525                'dgit-distro.debian.git-path' => '/git/dgit-repos/repos',
 526                'dgit-distro.debian.git-check' => 'ssh-cmd',
 527                'dgit-distro.debian.git-create' => 'ssh-cmd',
 528                'dgit-distro.debian.sshpsql-host' => 'mirror.ftp-master.debian.org',
 529                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 530                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 531  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 532  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 533                'dgit-distro.ubuntu.git-check' => 'false',
 534  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 535                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 536                'dgit-distro.test-dummy.username' => "alice",
 537                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 538                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 539                'dgit-distro.test-dummy.git-url' => "$td/git",
 540                'dgit-distro.test-dummy.git-host' => "git",
 541                'dgit-distro.test-dummy.git-path' => "$td/git",
 542                'dgit-distro.test-dummy.archive-query' => "dummycat:$td/aq",
 543                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 544                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 545                );
 546
 547 sub cfg {
 548     foreach my $c (@_) {
 549         return undef if $c =~ /RETURN-UNDEF/;
 550         my @cmd = (@git, qw(config --), $c);
 551         my $v;
 552         {
 553             local ($debug) = $debug-1;
 554             $v = cmdoutput_errok @cmd;
 555         };
 556         if ($?==0) {
 557             return $v;
 558         } elsif ($?!=256) {
 559             failedcmd @cmd;
 560         }
 561         my $dv = $defcfg{$c};
 562         return $dv if defined $dv;
 563     }
 564     badcfg "need value for one of: @_\n".
 565         "$us: distro or suite appears not to be (properly) supported";
 566 }
 567
 568 sub access_basedistro () {
 569     if (defined $idistro) {
 570         return $idistro;
 571     } else {
 572         return cfg("dgit-suite.$isuite.distro",
 573                    "dgit.default.distro");
 574     }
 575 }
 576
 577 sub access_quirk () {
 578     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 579     my $basedistro = access_basedistro();
 580     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 581                               'RETURN-UNDEF');
 582     if (defined $backports_quirk) {
 583         my $re = $backports_quirk;
 584         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 585         $re =~ s/\*/.*/g;
 586         $re =~ s/\%/([-0-9a-z_]+)/
 587             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 588         if ($isuite =~ m/^$re$/) {
 589             return ('backports',"$basedistro-backports",$1);
 590         }
 591     }
 592     return ('none',undef);
 593 }
 594
 595 sub access_distros () {
 596     # Returns list of distros to try, in order
 597     #
 598     # We want to try:
 599     #    0. `instead of' distro name(s) we have been pointed to
 600     #    1. the access_quirk distro, if any
 601     #    2a. the user's specified distro, or failing that  } basedistro
 602     #    2b. the distro calculated from the suite          }
 603     my @l = access_basedistro();
 604
 605     my (undef,$quirkdistro) = access_quirk();
 606     unshift @l, $quirkdistro;
 607     unshift @l, $instead_distro;
 608     return grep { defined } @l;
 609 }
 610
 611 sub access_cfg (@) {
 612     my (@keys) = @_;
 613     my @cfgs;
 614     # The nesting of these loops determines the search order.  We put
 615     # the key loop on the outside so that we search all the distros
 616     # for each key, before going on to the next key.  That means that
 617     # if access_cfg is called with a more specific, and then a less
 618     # specific, key, an earlier distro can override the less specific
 619     # without necessarily overriding any more specific keys.  (If the
 620     # distro wants to override the more specific keys it can simply do
 621     # so; whereas if we did the loop the other way around, it would be
 622     # impossible to for an earlier distro to override a less specific
 623     # key but not the more specific ones without restating the unknown
 624     # values of the more specific keys.
 625     my @realkeys;
 626     my @rundef;
 627     # We have to deal with RETURN-UNDEF specially, so that we don't
 628     # terminate the search prematurely.
 629     foreach (@keys) {
 630         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 631         push @realkeys, $_
 632     }
 633     foreach my $d (access_distros()) {
 634         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 635     }
 636     push @cfgs, map { "dgit.default.$_" } @realkeys;
 637     push @cfgs, @rundef;
 638     my $value = cfg(@cfgs);
 639     return $value;
 640 }
 641
 642 sub string_to_ssh ($) {
 643     my ($spec) = @_;
 644     if ($spec =~ m/\s/) {
 645         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 646     } else {
 647         return ($spec);
 648     }
 649 }
 650
 651 sub access_cfg_ssh () {
 652     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 653     if (!defined $gitssh) {
 654         return @ssh;
 655     } else {
 656         return string_to_ssh $gitssh;
 657     }
 658 }
 659
 660 sub access_runeinfo ($) {
 661     my ($info) = @_;
 662     return ": dgit ".access_basedistro()." $info ;";
 663 }
 664
 665 sub access_someuserhost ($) {
 666     my ($some) = @_;
 667     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 668     defined($user) && length($user) or
 669         $user = access_cfg("$some-user",'username');
 670     my $host = access_cfg("$some-host");
 671     return length($user) ? "$user\@$host" : $host;
 672 }
 673
 674 sub access_gituserhost () {
 675     return access_someuserhost('git');
 676 }
 677
 678 sub access_giturl (;$) {
 679     my ($optional) = @_;
 680     my $url = access_cfg('git-url','RETURN-UNDEF');
 681     if (!defined $url) {
 682         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 683         return undef unless defined $proto;
 684         $url =
 685             $proto.
 686             access_gituserhost().
 687             access_cfg('git-path');
 688     }
 689     return "$url/$package.git";
 690 }
 691
 692 sub parsecontrolfh ($$;$) {
 693     my ($fh, $desc, $allowsigned) = @_;
 694     our $dpkgcontrolhash_noissigned;
 695     my $c;
 696     for (;;) {
 697         my %opts = ('name' => $desc);
 698         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 699         $c = Dpkg::Control::Hash->new(%opts);
 700         $c->parse($fh,$desc) or die "parsing of $desc failed";
 701         last if $allowsigned;
 702         last if $dpkgcontrolhash_noissigned;
 703         my $issigned= $c->get_option('is_pgp_signed');
 704         if (!defined $issigned) {
 705             $dpkgcontrolhash_noissigned= 1;
 706             seek $fh, 0,0 or die "seek $desc: $!";
 707         } elsif ($issigned) {
 708             fail "control file $desc is (already) PGP-signed. ".
 709                 " Note that dgit push needs to modify the .dsc and then".
 710                 " do the signature itself";
 711         } else {
 712             last;
 713         }
 714     }
 715     return $c;
 716 }
 717
 718 sub parsecontrol {
 719     my ($file, $desc) = @_;
 720     my $fh = new IO::Handle;
 721     open $fh, '<', $file or die "$file: $!";
 722     my $c = parsecontrolfh($fh,$desc);
 723     $fh->error and die $!;
 724     close $fh;
 725     return $c;
 726 }
 727
 728 sub getfield ($$) {
 729     my ($dctrl,$field) = @_;
 730     my $v = $dctrl->{$field};
 731     return $v if defined $v;
 732     fail "missing field $field in ".$v->get_option('name');
 733 }
 734
 735 sub parsechangelog {
 736     my $c = Dpkg::Control::Hash->new();
 737     my $p = new IO::Handle;
 738     my @cmd = (qw(dpkg-parsechangelog), @_);
 739     open $p, '-|', @cmd or die $!;
 740     $c->parse($p);
 741     $?=0; $!=0; close $p or failedcmd @cmd;
 742     return $c;
 743 }
 744
 745 sub git_get_ref ($) {
 746     my ($refname) = @_;
 747     my $got = cmdoutput_errok @git, qw(show-ref --), $refname;
 748     if (!defined $got) {
 749         $?==256 or fail "git show-ref failed (status $?)";
 750         printdebug "ref $refname= [show-ref exited 1]\n";
 751         return '';
 752     }
 753     if ($got =~ m/^(\w+) \Q$refname\E$/m) {
 754         printdebug "ref $refname=$1\n";
 755         return $1;
 756     } else {
 757         printdebug "ref $refname= [no match]\n";
 758         return '';
 759     }
 760 }
 761
 762 sub must_getcwd () {
 763     my $d = getcwd();
 764     defined $d or fail "getcwd failed: $!";
 765     return $d;
 766 }
 767
 768 our %rmad;
 769
 770 sub archive_query ($) {
 771     my ($method) = @_;
 772     my $query = access_cfg('archive-query','RETURN-UNDEF');
 773     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 774     my $proto = $1;
 775     my $data = $'; #';
 776     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 777 }
 778
 779 sub pool_dsc_subpath ($$) {
 780     my ($vsn,$component) = @_; # $package is implict arg
 781     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 782     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 783 }
 784
 785 sub archive_query_madison {
 786     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 787 }
 788
 789 sub madison_get_parse {
 790     my ($proto,$data) = @_;
 791     die unless $proto eq 'madison';
 792     if (!length $data) {
 793         $data= access_cfg('madison-distro','RETURN-UNDEF');
 794         $data //= access_basedistro();
 795     }
 796     $rmad{$proto,$data,$package} ||= cmdoutput
 797         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 798     my $rmad = $rmad{$proto,$data,$package};
 799
 800     my @out;
 801     foreach my $l (split /\n/, $rmad) {
 802         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 803                   \s*( [^ \t|]+ )\s* \|
 804                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 805                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 806         $1 eq $package or die "$rmad $package ?";
 807         my $vsn = $2;
 808         my $newsuite = $3;
 809         my $component;
 810         if (defined $4) {
 811             $component = $4;
 812         } else {
 813             $component = access_cfg('archive-query-default-component');
 814         }
 815         $5 eq 'source' or die "$rmad ?";
 816         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 817     }
 818     return sort { -version_compare($a->[0],$b->[0]); } @out;
 819 }
 820
 821 sub canonicalise_suite_madison {
 822     # madison canonicalises for us
 823     my @r = madison_get_parse(@_);
 824     @r or fail
 825         "unable to canonicalise suite using package $package".
 826         " which does not appear to exist in suite $isuite;".
 827         " --existing-package may help";
 828     return $r[0][2];
 829 }
 830
 831 sub sshpsql ($$$) {
 832     my ($data,$runeinfo,$sql) = @_;
 833     if (!length $data) {
 834         $data= access_someuserhost('sshpsql').':'.
 835             access_cfg('sshpsql-dbname');
 836     }
 837     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 838     my ($userhost,$dbname) = ($`,$'); #';
 839     my @rows;
 840     my @cmd = (access_cfg_ssh, $userhost,
 841                access_runeinfo("ssh-psql $runeinfo").
 842                " export LANG=C;".
 843                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 844     printcmd(\*DEBUG,$debugprefix."|",@cmd) if $debug>0;
 845     open P, "-|", @cmd or die $!;
 846     while (<P>) {
 847         chomp or die;
 848         printdebug("$debugprefix>|$_|\n");
 849         push @rows, $_;
 850     }
 851     $!=0; $?=0; close P or failedcmd @cmd;
 852     @rows or die;
 853     my $nrows = pop @rows;
 854     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 855     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 856     @rows = map { [ split /\|/, $_ ] } @rows;
 857     my $ncols = scalar @{ shift @rows };
 858     die if grep { scalar @$_ != $ncols } @rows;
 859     return @rows;
 860 }
 861
 862 sub sql_injection_check {
 863     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 864 }
 865
 866 sub archive_query_sshpsql ($$) {
 867     my ($proto,$data) = @_;
 868     sql_injection_check $isuite, $package;
 869     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 870         SELECT source.version, component.name, files.filename, files.sha256sum
 871           FROM source
 872           JOIN src_associations ON source.id = src_associations.source
 873           JOIN suite ON suite.id = src_associations.suite
 874           JOIN dsc_files ON dsc_files.source = source.id
 875           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 876           JOIN component ON component.id = files_archive_map.component_id
 877           JOIN files ON files.id = dsc_files.file
 878          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 879            AND source.source='$package'
 880            AND files.filename LIKE '%.dsc';
 881 END
 882     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 883     my $digester = Digest::SHA->new(256);
 884     @rows = map {
 885         my ($vsn,$component,$filename,$sha256sum) = @$_;
 886         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 887     } @rows;
 888     return @rows;
 889 }
 890
 891 sub canonicalise_suite_sshpsql ($$) {
 892     my ($proto,$data) = @_;
 893     sql_injection_check $isuite;
 894     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 895         SELECT suite.codename
 896           FROM suite where suite_name='$isuite' or codename='$isuite';
 897 END
 898     @rows = map { $_->[0] } @rows;
 899     fail "unknown suite $isuite" unless @rows;
 900     die "ambiguous $isuite: @rows ?" if @rows>1;
 901     return $rows[0];
 902 }
 903
 904 sub canonicalise_suite_dummycat ($$) {
 905     my ($proto,$data) = @_;
 906     my $dpath = "$data/suite.$isuite";
 907     if (!open C, "<", $dpath) {
 908         $!==ENOENT or die "$dpath: $!";
 909         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 910         return $isuite;
 911     }
 912     $!=0; $_ = <C>;
 913     chomp or die "$dpath: $!";
 914     close C;
 915     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 916     return $_;
 917 }
 918
 919 sub archive_query_dummycat ($$) {
 920     my ($proto,$data) = @_;
 921     canonicalise_suite();
 922     my $dpath = "$data/package.$csuite.$package";
 923     if (!open C, "<", $dpath) {
 924         $!==ENOENT or die "$dpath: $!";
 925         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 926         return ();
 927     }
 928     my @rows;
 929     while (<C>) {
 930         next if m/^\#/;
 931         next unless m/\S/;
 932         die unless chomp;
 933         printdebug "dummycat query $csuite $package $dpath | $_\n";
 934         my @row = split /\s+/, $_;
 935         @row==2 or die "$dpath: $_ ?";
 936         push @rows, \@row;
 937     }
 938     C->error and die "$dpath: $!";
 939     close C;
 940     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 941 }
 942
 943 sub canonicalise_suite () {
 944     return if defined $csuite;
 945     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 946     $csuite = archive_query('canonicalise_suite');
 947     if ($isuite ne $csuite) {
 948         progress "canonical suite name for $isuite is $csuite";
 949     }
 950 }
 951
 952 sub get_archive_dsc () {
 953     canonicalise_suite();
 954     my @vsns = archive_query('archive_query');
 955     foreach my $vinfo (@vsns) {
 956         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 957         $dscurl = access_cfg('mirror').$subpath;
 958         $dscdata = url_get($dscurl);
 959         if (!$dscdata) {
 960             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 961             next;
 962         }
 963         if ($digester) {
 964             $digester->reset();
 965             $digester->add($dscdata);
 966             my $got = $digester->hexdigest();
 967             $got eq $digest or
 968                 fail "$dscurl has hash $got but".
 969                     " archive told us to expect $digest";
 970         }
 971         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 972         printdebug Dumper($dscdata) if $debug>1;
 973         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 974         printdebug Dumper($dsc) if $debug>1;
 975         my $fmt = getfield $dsc, 'Format';
 976         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
 977         $dsc_checked = !!$digester;
 978         return;
 979     }
 980     $dsc = undef;
 981 }
 982
 983 sub check_for_git ();
 984 sub check_for_git () {
 985     # returns 0 or 1
 986     my $how = access_cfg('git-check');
 987     if ($how eq 'ssh-cmd') {
 988         my @cmd =
 989             (access_cfg_ssh, access_gituserhost(),
 990              access_runeinfo("git-check $package").
 991              " set -e; cd ".access_cfg('git-path').";".
 992              " if test -d $package.git; then echo 1; else echo 0; fi");
 993         my $r= cmdoutput @cmd;
 994         if ($r =~ m/^divert (\w+)$/) {
 995             my $divert=$1;
 996             my ($usedistro,) = access_distros();
 997             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
 998             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
 999             printdebug "diverting $divert so using distro $instead_distro\n";
1000             return check_for_git();
1001         }
1002         failedcmd @cmd unless $r =~ m/^[01]$/;
1003         return $r+0;
1004     } elsif ($how eq 'true') {
1005         return 1;
1006     } elsif ($how eq 'false') {
1007         return 0;
1008     } else {
1009         badcfg "unknown git-check \`$how'";
1010     }
1011 }
1012
1013 sub create_remote_git_repo () {
1014     my $how = access_cfg('git-create');
1015     if ($how eq 'ssh-cmd') {
1016         runcmd_ordryrun
1017             (access_cfg_ssh, access_gituserhost(),
1018              access_runeinfo("git-create $package").
1019              "set -e; cd ".access_cfg('git-path').";".
1020              " cp -a _template $package.git");
1021     } elsif ($how eq 'true') {
1022         # nothing to do
1023     } else {
1024         badcfg "unknown git-create \`$how'";
1025     }
1026 }
1027
1028 our ($dsc_hash,$lastpush_hash);
1029
1030 our $ud = '.git/dgit/unpack';
1031
1032 sub prep_ud () {
1033     rmtree($ud);
1034     mkpath '.git/dgit';
1035     mkdir $ud or die $!;
1036 }
1037
1038 sub mktree_in_ud_here () {
1039     runcmd qw(git init -q);
1040     rmtree('.git/objects');
1041     symlink '../../../../objects','.git/objects' or die $!;
1042 }
1043
1044 sub mktree_in_ud_from_only_subdir () {
1045     # changes into the subdir
1046     my (@dirs) = <*/.>;
1047     die unless @dirs==1;
1048     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1049     my $dir = $1;
1050     changedir $dir;
1051     fail "source package contains .git directory" if stat_exists '.git';
1052     mktree_in_ud_here();
1053     my $format=get_source_format();
1054     if (madformat($format)) {
1055         rmtree '.pc';
1056     }
1057     runcmd @git, qw(add -Af);
1058     my $tree = cmdoutput @git, qw(write-tree);
1059     $tree =~ m/^\w+$/ or die "$tree ?";
1060     return ($tree,$dir);
1061 }
1062
1063 sub dsc_files_info () {
1064     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1065                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1066                        ['Files',           'Digest::MD5', 'new()']) {
1067         my ($fname, $module, $method) = @$csumi;
1068         my $field = $dsc->{$fname};
1069         next unless defined $field;
1070         eval "use $module; 1;" or die $@;
1071         my @out;
1072         foreach (split /\n/, $field) {
1073             next unless m/\S/;
1074             m/^(\w+) (\d+) (\S+)$/ or
1075                 fail "could not parse .dsc $fname line \`$_'";
1076             my $digester = eval "$module"."->$method;" or die $@;
1077             push @out, {
1078                 Hash => $1,
1079                 Bytes => $2,
1080                 Filename => $3,
1081                 Digester => $digester,
1082             };
1083         }
1084         return @out;
1085     }
1086     fail "missing any supported Checksums-* or Files field in ".
1087         $dsc->get_option('name');
1088 }
1089
1090 sub dsc_files () {
1091     map { $_->{Filename} } dsc_files_info();
1092 }
1093
1094 sub is_orig_file ($;$) {
1095     local ($_) = $_[0];
1096     my $base = $_[1];
1097     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1098     defined $base or return 1;
1099     return $` eq $base;
1100 }
1101
1102 sub make_commit ($) {
1103     my ($file) = @_;
1104     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1105 }
1106
1107 sub clogp_authline ($) {
1108     my ($clogp) = @_;
1109     my $author = getfield $clogp, 'Maintainer';
1110     $author =~ s#,.*##ms;
1111     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1112     my $authline = "$author $date";
1113     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1114         fail "unexpected commit author line format \`$authline'".
1115         " (was generated from changelog Maintainer field)";
1116     return $authline;
1117 }
1118
1119 sub generate_commit_from_dsc () {
1120     prep_ud();
1121     changedir $ud;
1122
1123     foreach my $fi (dsc_files_info()) {
1124         my $f = $fi->{Filename};
1125         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1126
1127         link "../../../$f", $f
1128             or $!==&ENOENT
1129             or die "$f $!";
1130
1131         complete_file_from_dsc('.', $fi);
1132
1133         if (is_orig_file($f)) {
1134             link $f, "../../../../$f"
1135                 or $!==&EEXIST
1136                 or die "$f $!";
1137         }
1138     }
1139
1140     my $dscfn = "$package.dsc";
1141
1142     open D, ">", $dscfn or die "$dscfn: $!";
1143     print D $dscdata or die "$dscfn: $!";
1144     close D or die "$dscfn: $!";
1145     my @cmd = qw(dpkg-source);
1146     push @cmd, '--no-check' if $dsc_checked;
1147     push @cmd, qw(-x --), $dscfn;
1148     runcmd @cmd;
1149
1150     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1151     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1152     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1153     my $authline = clogp_authline $clogp;
1154     my $changes = getfield $clogp, 'Changes';
1155     open C, ">../commit.tmp" or die $!;
1156     print C <<END or die $!;
1157 tree $tree
1158 author $authline
1159 committer $authline
1160
1161 $changes
1162
1163 # imported from the archive
1164 END
1165     close C or die $!;
1166     my $outputhash = make_commit qw(../commit.tmp);
1167     my $cversion = getfield $clogp, 'Version';
1168     progress "synthesised git commit from .dsc $cversion";
1169     if ($lastpush_hash) {
1170         runcmd @git, qw(reset --hard), $lastpush_hash;
1171         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1172         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1173         my $oversion = getfield $oldclogp, 'Version';
1174         my $vcmp =
1175             version_compare($oversion, $cversion);
1176         if ($vcmp < 0) {
1177             # git upload/ is earlier vsn than archive, use archive
1178             open C, ">../commit2.tmp" or die $!;
1179             print C <<END or die $!;
1180 tree $tree
1181 parent $lastpush_hash
1182 parent $outputhash
1183 author $authline
1184 committer $authline
1185
1186 Record $package ($cversion) in archive suite $csuite
1187 END
1188             $outputhash = make_commit qw(../commit2.tmp);
1189         } elsif ($vcmp > 0) {
1190             print STDERR <<END or die $!;
1191
1192 Version actually in archive:    $cversion (older)
1193 Last allegedly pushed/uploaded: $oversion (newer or same)
1194 $later_warning_msg
1195 END
1196             $outputhash = $lastpush_hash;
1197         } else {
1198             $outputhash = $lastpush_hash;
1199         }
1200     }
1201     changedir '../../../..';
1202     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1203             'DGIT_ARCHIVE', $outputhash;
1204     cmdoutput @git, qw(log -n2), $outputhash;
1205     # ... gives git a chance to complain if our commit is malformed
1206     rmtree($ud);
1207     return $outputhash;
1208 }
1209
1210 sub complete_file_from_dsc ($$) {
1211     our ($dstdir, $fi) = @_;
1212     # Ensures that we have, in $dir, the file $fi, with the correct
1213     # contents.  (Downloading it from alongside $dscurl if necessary.)
1214
1215     my $f = $fi->{Filename};
1216     my $tf = "$dstdir/$f";
1217     my $downloaded = 0;
1218
1219     if (stat_exists $tf) {
1220         progress "using existing $f";
1221     } else {
1222         my $furl = $dscurl;
1223         $furl =~ s{/[^/]+$}{};
1224         $furl .= "/$f";
1225         die "$f ?" unless $f =~ m/^${package}_/;
1226         die "$f ?" if $f =~ m#/#;
1227         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1228         next if !act_local();
1229         $downloaded = 1;
1230     }
1231
1232     open F, "<", "$tf" or die "$tf: $!";
1233     $fi->{Digester}->reset();
1234     $fi->{Digester}->addfile(*F);
1235     F->error and die $!;
1236     my $got = $fi->{Digester}->hexdigest();
1237     $got eq $fi->{Hash} or
1238         fail "file $f has hash $got but .dsc".
1239             " demands hash $fi->{Hash} ".
1240             ($downloaded ? "(got wrong file from archive!)"
1241              : "(perhaps you should delete this file?)");
1242 }
1243
1244 sub ensure_we_have_orig () {
1245     foreach my $fi (dsc_files_info()) {
1246         my $f = $fi->{Filename};
1247         next unless is_orig_file($f);
1248         complete_file_from_dsc('..', $fi);
1249     }
1250 }
1251
1252 sub rev_parse ($) {
1253     return cmdoutput @git, qw(rev-parse), "$_[0]~0";
1254 }
1255
1256 sub is_fast_fwd ($$) {
1257     my ($ancestor,$child) = @_;
1258     my @cmd = (@git, qw(merge-base), $ancestor, $child);
1259     my $mb = cmdoutput_errok @cmd;
1260     if (defined $mb) {
1261         return rev_parse($mb) eq rev_parse($ancestor);
1262     } else {
1263         $?==256 or failedcmd @cmd;
1264         return 0;
1265     }
1266 }
1267
1268 sub git_fetch_us () {
1269     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1270 }
1271
1272 sub fetch_from_archive () {
1273     # ensures that lrref() is what is actually in the archive,
1274     #  one way or another
1275     get_archive_dsc();
1276
1277     if ($dsc) {
1278         foreach my $field (@ourdscfield) {
1279             $dsc_hash = $dsc->{$field};
1280             last if defined $dsc_hash;
1281         }
1282         if (defined $dsc_hash) {
1283             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1284             $dsc_hash = $&;
1285             progress "last upload to archive specified git hash";
1286         } else {
1287             progress "last upload to archive has NO git hash";
1288         }
1289     } else {
1290         progress "no version available from the archive";
1291     }
1292
1293     $lastpush_hash = git_get_ref(lrref());
1294     printdebug "previous reference hash=$lastpush_hash\n";
1295     my $hash;
1296     if (defined $dsc_hash) {
1297         fail "missing remote git history even though dsc has hash -".
1298             " could not find ref ".lrref().
1299             " (should have been fetched from ".access_giturl()."#".rrref().")"
1300             unless $lastpush_hash;
1301         $hash = $dsc_hash;
1302         ensure_we_have_orig();
1303         if ($dsc_hash eq $lastpush_hash) {
1304         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1305             print STDERR <<END or die $!;
1306
1307 Git commit in archive is behind the last version allegedly pushed/uploaded.
1308 Commit referred to by archive:  $dsc_hash
1309 Last allegedly pushed/uploaded: $lastpush_hash
1310 $later_warning_msg
1311 END
1312             $hash = $lastpush_hash;
1313         } else {
1314             fail "archive's .dsc refers to ".$dsc_hash.
1315                 " but this is an ancestor of ".$lastpush_hash;
1316         }
1317     } elsif ($dsc) {
1318         $hash = generate_commit_from_dsc();
1319     } elsif ($lastpush_hash) {
1320         # only in git, not in the archive yet
1321         $hash = $lastpush_hash;
1322         print STDERR <<END or die $!;
1323
1324 Package not found in the archive, but has allegedly been pushed using dgit.
1325 $later_warning_msg
1326 END
1327     } else {
1328         printdebug "nothing found!\n";
1329         if (defined $skew_warning_vsn) {
1330             print STDERR <<END or die $!;
1331
1332 Warning: relevant archive skew detected.
1333 Archive allegedly contains $skew_warning_vsn
1334 But we were not able to obtain any version from the archive or git.
1335
1336 END
1337         }
1338         return 0;
1339     }
1340     printdebug "current hash=$hash\n";
1341     if ($lastpush_hash) {
1342         fail "not fast forward on last upload branch!".
1343             " (archive's version left in DGIT_ARCHIVE)"
1344             unless is_fast_fwd($lastpush_hash, $hash);
1345     }
1346     if (defined $skew_warning_vsn) {
1347         mkpath '.git/dgit';
1348         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1349         my $clogf = ".git/dgit/changelog.tmp";
1350         runcmd shell_cmd "exec >$clogf",
1351             @git, qw(cat-file blob), "$hash:debian/changelog";
1352         my $gotclogp = parsechangelog("-l$clogf");
1353         my $got_vsn = getfield $gotclogp, 'Version';
1354         printdebug "SKEW CHECK GOT $got_vsn\n";
1355         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1356             print STDERR <<END or die $!;
1357
1358 Warning: archive skew detected.  Using the available version:
1359 Archive allegedly contains    $skew_warning_vsn
1360 We were able to obtain only   $got_vsn
1361
1362 END
1363         }
1364     }
1365     if ($lastpush_hash ne $hash) {
1366         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1367         if (act_local()) {
1368             cmdoutput @upd_cmd;
1369         } else {
1370             dryrun_report @upd_cmd;
1371         }
1372     }
1373     return 1;
1374 }
1375
1376 sub clone ($) {
1377     my ($dstdir) = @_;
1378     canonicalise_suite();
1379     badusage "dry run makes no sense with clone" unless act_local();
1380     my $hasgit = check_for_git();
1381     mkdir $dstdir or die "$dstdir $!";
1382     changedir $dstdir;
1383     runcmd @git, qw(init -q);
1384     my $giturl = access_giturl(1);
1385     if (defined $giturl) {
1386         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1387         open H, "> .git/HEAD" or die $!;
1388         print H "ref: ".lref()."\n" or die $!;
1389         close H or die $!;
1390         runcmd @git, qw(remote add), 'origin', $giturl;
1391     }
1392     if ($hasgit) {
1393         progress "fetching existing git history";
1394         git_fetch_us();
1395         runcmd_ordryrun_local @git, qw(fetch origin);
1396     } else {
1397         progress "starting new git history";
1398     }
1399     fetch_from_archive() or no_such_package;
1400     my $vcsgiturl = $dsc->{'Vcs-Git'};
1401     if (length $vcsgiturl) {
1402         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1403     }
1404     runcmd @git, qw(reset --hard), lrref();
1405     printdone "ready for work in $dstdir";
1406 }
1407
1408 sub fetch () {
1409     if (check_for_git()) {
1410         git_fetch_us();
1411     }
1412     fetch_from_archive() or no_such_package();
1413     printdone "fetched into ".lrref();
1414 }
1415
1416 sub pull () {
1417     fetch();
1418     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1419         lrref();
1420     printdone "fetched to ".lrref()." and merged into HEAD";
1421 }
1422
1423 sub check_not_dirty () {
1424     return if $ignoredirty;
1425     my @cmd = (@git, qw(diff --quiet HEAD));
1426     printcmd(\*DEBUG,$debugprefix."+",@cmd) if $debug>0;
1427     $!=0; $?=0; system @cmd;
1428     return if !$! && !$?;
1429     if (!$! && $?==256) {
1430         fail "working tree is dirty (does not match HEAD)";
1431     } else {
1432         failedcmd @cmd;
1433     }
1434 }
1435
1436 sub commit_admin ($) {
1437     my ($m) = @_;
1438     progress "$m";
1439     runcmd_ordryrun_local @git, qw(commit -m), $m;
1440 }
1441
1442 sub commit_quilty_patch () {
1443     my $output = cmdoutput @git, qw(status --porcelain);
1444     my %adds;
1445     foreach my $l (split /\n/, $output) {
1446         next unless $l =~ m/\S/;
1447         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1448             $adds{$1}++;
1449         }
1450     }
1451     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1452     if (!%adds) {
1453         progress "nothing quilty to commit, ok.";
1454         return;
1455     }
1456     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1457     commit_admin "Commit Debian 3.0 (quilt) metadata";
1458 }
1459
1460 sub get_source_format () {
1461     if (!open F, "debian/source/format") {
1462         die $! unless $!==&ENOENT;
1463         return '';
1464     }
1465     $_ = <F>;
1466     F->error and die $!;
1467     chomp;
1468     return $_;
1469 }
1470
1471 sub madformat ($) {
1472     my ($format) = @_;
1473     return 0 unless $format eq '3.0 (quilt)';
1474     if ($noquilt) {
1475         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1476         return 0;
1477     }
1478     progress "Format \`$format', checking/updating patch stack";
1479     return 1;
1480 }
1481
1482 sub push_parse_changelog ($) {
1483     my ($clogpfn) = @_;
1484
1485     my $clogp = Dpkg::Control::Hash->new();
1486     $clogp->load($clogpfn) or die;
1487
1488     $package = getfield $clogp, 'Source';
1489     my $cversion = getfield $clogp, 'Version';
1490     my $tag = debiantag($cversion);
1491     runcmd @git, qw(check-ref-format), $tag;
1492
1493     my $dscfn = dscfn($cversion);
1494
1495     return ($clogp, $cversion, $tag, $dscfn);
1496 }
1497
1498 sub push_parse_dsc ($$$) {
1499     my ($dscfn,$dscfnwhat, $cversion) = @_;
1500     $dsc = parsecontrol($dscfn,$dscfnwhat);
1501     my $dversion = getfield $dsc, 'Version';
1502     my $dscpackage = getfield $dsc, 'Source';
1503     ($dscpackage eq $package && $dversion eq $cversion) or
1504         fail "$dscfn is for $dscpackage $dversion".
1505             " but debian/changelog is for $package $cversion";
1506 }
1507
1508 sub push_mktag ($$$$$$$) {
1509     my ($head,$clogp,$tag,
1510         $dscfn,
1511         $changesfile,$changesfilewhat,
1512         $tfn) = @_;
1513
1514     $dsc->{$ourdscfield[0]} = $head;
1515     $dsc->save("$dscfn.tmp") or die $!;
1516
1517     my $changes = parsecontrol($changesfile,$changesfilewhat);
1518     foreach my $field (qw(Source Distribution Version)) {
1519         $changes->{$field} eq $clogp->{$field} or
1520             fail "changes field $field \`$changes->{$field}'".
1521                 " does not match changelog \`$clogp->{$field}'";
1522     }
1523
1524     my $cversion = getfield $clogp, 'Version';
1525     my $clogsuite = getfield $clogp, 'Distribution';
1526
1527     # We make the git tag by hand because (a) that makes it easier
1528     # to control the "tagger" (b) we can do remote signing
1529     my $authline = clogp_authline $clogp;
1530     open TO, '>', $tfn->('.tmp') or die $!;
1531     print TO <<END or die $!;
1532 object $head
1533 type commit
1534 tag $tag
1535 tagger $authline
1536
1537 $package release $cversion for $clogsuite ($csuite) [dgit]
1538 END
1539     close TO or die $!;
1540
1541     my $tagobjfn = $tfn->('.tmp');
1542     if ($sign) {
1543         if (!defined $keyid) {
1544             $keyid = access_cfg('keyid','RETURN-UNDEF');
1545         }
1546         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1547         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1548         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1549         push @sign_cmd, $tfn->('.tmp');
1550         runcmd_ordryrun @sign_cmd;
1551         if (act_scary()) {
1552             $tagobjfn = $tfn->('.signed.tmp');
1553             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1554                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1555         }
1556     }
1557
1558     return ($tagobjfn);
1559 }
1560
1561 sub sign_changes ($) {
1562     my ($changesfile) = @_;
1563     if ($sign) {
1564         my @debsign_cmd = @debsign;
1565         push @debsign_cmd, "-k$keyid" if defined $keyid;
1566         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1567         push @debsign_cmd, $changesfile;
1568         runcmd_ordryrun @debsign_cmd;
1569     }
1570 }
1571
1572 sub dopush () {
1573     printdebug "actually entering push\n";
1574     prep_ud();
1575
1576     access_giturl(); # check that success is vaguely likely
1577
1578     my $clogpfn = ".git/dgit/changelog.822.tmp";
1579     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1580
1581     responder_send_file('parsed-changelog', $clogpfn);
1582
1583     my ($clogp, $cversion, $tag, $dscfn) =
1584         push_parse_changelog("$clogpfn");
1585
1586     my $dscpath = "$buildproductsdir/$dscfn";
1587     stat_exists $dscpath or
1588         fail "looked for .dsc $dscfn, but $!;".
1589             " maybe you forgot to build";
1590
1591     responder_send_file('dsc', $dscpath);
1592
1593     push_parse_dsc($dscpath, $dscfn, $cversion);
1594
1595     my $format = getfield $dsc, 'Format';
1596     printdebug "format $format\n";
1597     if (madformat($format)) {
1598         commit_quilty_patch();
1599     }
1600     check_not_dirty();
1601     changedir $ud;
1602     progress "checking that $dscfn corresponds to HEAD";
1603     runcmd qw(dpkg-source -x --),
1604         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1605     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1606     changedir '../../../..';
1607     my $diffopt = $debug>0 ? '--exit-code' : '--quiet';
1608     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1609     printcmd \*DEBUG,$debugprefix."+",@diffcmd;
1610     $!=0; $?=0;
1611     my $r = system @diffcmd;
1612     if ($r) {
1613         if ($r==256) {
1614             fail "$dscfn specifies a different tree to your HEAD commit;".
1615                 " perhaps you forgot to build".
1616                 ($diffopt eq '--exit-code' ? "" :
1617                  " (run with -D to see full diff output)");
1618         } else {
1619             failedcmd @diffcmd;
1620         }
1621     }
1622 #fetch from alioth
1623 #do fast forward check and maybe fake merge
1624 #    if (!is_fast_fwd(mainbranch
1625 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1626 #        map { lref($_).":".rref($_) }
1627 #        (uploadbranch());
1628     my $head = rev_parse('HEAD');
1629     if (!$changesfile) {
1630         my $multi = "$buildproductsdir/".
1631             "${package}_".(stripepoch $cversion)."_multi.changes";
1632         if (stat_exists "$multi") {
1633             $changesfile = $multi;
1634         } else {
1635             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1636             my @cs = glob "$buildproductsdir/$pat";
1637             fail "failed to find unique changes file".
1638                 " (looked for $pat in $buildproductsdir, or $multi);".
1639                 " perhaps you need to use dgit -C"
1640                 unless @cs==1;
1641             ($changesfile) = @cs;
1642         }
1643     } else {
1644         $changesfile = "$buildproductsdir/$changesfile";
1645     }
1646
1647     responder_send_file('changes',$changesfile);
1648     responder_send_command("param head $head");
1649     responder_send_command("param csuite $csuite");
1650
1651     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1652     my $tagobjfn;
1653
1654     if ($we_are_responder) {
1655         $tagobjfn = $tfn->('.signed.tmp');
1656         responder_receive_files('signed-tag', $tagobjfn);
1657     } else {
1658         $tagobjfn =
1659             push_mktag($head,$clogp,$tag,
1660                        $dscpath,
1661                        $changesfile,$changesfile,
1662                        $tfn);
1663     }
1664
1665     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1666     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1667     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1668     runcmd_ordryrun @git, qw(tag -v --), $tag;
1669
1670     if (!check_for_git()) {
1671         create_remote_git_repo();
1672     }
1673     runcmd_ordryrun @git, qw(push),access_giturl(),
1674         "HEAD:".rrref(), "refs/tags/$tag";
1675     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1676
1677     if ($we_are_responder) {
1678         my $dryrunsuffix = act_local() ? "" : ".tmp";
1679         responder_receive_files('signed-dsc-changes',
1680                                 "$dscpath$dryrunsuffix",
1681                                 "$changesfile$dryrunsuffix");
1682     } else {
1683         if (act_local()) {
1684             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1685         } else {
1686             progress "[new .dsc left in $dscpath.tmp]";
1687         }
1688         sign_changes $changesfile;
1689     }
1690
1691     my $host = access_cfg('upload-host','RETURN-UNDEF');
1692     my @hostarg = defined($host) ? ($host,) : ();
1693     runcmd_ordryrun @dput, @hostarg, $changesfile;
1694     printdone "pushed and uploaded $cversion";
1695
1696     responder_send_command("complete");
1697 }
1698
1699 sub cmd_clone {
1700     parseopts();
1701     my $dstdir;
1702     badusage "-p is not allowed with clone; specify as argument instead"
1703         if defined $package;
1704     if (@ARGV==1) {
1705         ($package) = @ARGV;
1706     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1707         ($package,$isuite) = @ARGV;
1708     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1709         ($package,$dstdir) = @ARGV;
1710     } elsif (@ARGV==3) {
1711         ($package,$isuite,$dstdir) = @ARGV;
1712     } else {
1713         badusage "incorrect arguments to dgit clone";
1714     }
1715     $dstdir ||= "$package";
1716
1717     if (stat_exists $dstdir) {
1718         fail "$dstdir already exists";
1719     }
1720
1721     my $cwd_remove;
1722     if ($rmonerror && !$dryrun_level) {
1723         $cwd_remove= getcwd();
1724         unshift @end, sub {
1725             return unless defined $cwd_remove;
1726             if (!chdir "$cwd_remove") {
1727                 return if $!==&ENOENT;
1728                 die "chdir $cwd_remove: $!";
1729             }
1730             rmtree($dstdir) or die "remove $dstdir: $!\n";
1731         };
1732     }
1733
1734     clone($dstdir);
1735     $cwd_remove = undef;
1736 }
1737
1738 sub branchsuite () {
1739     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1740     if ($branch =~ m#$lbranch_re#o) {
1741         return $1;
1742     } else {
1743         return undef;
1744     }
1745 }
1746
1747 sub fetchpullargs () {
1748     if (!defined $package) {
1749         my $sourcep = parsecontrol('debian/control','debian/control');
1750         $package = getfield $sourcep, 'Source';
1751     }
1752     if (@ARGV==0) {
1753 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1754         if (!$isuite) {
1755             my $clogp = parsechangelog();
1756             $isuite = getfield $clogp, 'Distribution';
1757         }
1758         canonicalise_suite();
1759         progress "fetching from suite $csuite";
1760     } elsif (@ARGV==1) {
1761         ($isuite) = @ARGV;
1762         canonicalise_suite();
1763     } else {
1764         badusage "incorrect arguments to dgit fetch or dgit pull";
1765     }
1766 }
1767
1768 sub cmd_fetch {
1769     parseopts();
1770     fetchpullargs();
1771     fetch();
1772 }
1773
1774 sub cmd_pull {
1775     parseopts();
1776     fetchpullargs();
1777     pull();
1778 }
1779
1780 sub cmd_push {
1781     parseopts();
1782     badusage "-p is not allowed with dgit push" if defined $package;
1783     check_not_dirty();
1784     my $clogp = parsechangelog();
1785     $package = getfield $clogp, 'Source';
1786     my $specsuite;
1787     if (@ARGV==0) {
1788     } elsif (@ARGV==1) {
1789         ($specsuite) = (@ARGV);
1790     } else {
1791         badusage "incorrect arguments to dgit push";
1792     }
1793     $isuite = getfield $clogp, 'Distribution';
1794     if ($new_package) {
1795         local ($package) = $existing_package; # this is a hack
1796         canonicalise_suite();
1797     }
1798     if (defined $specsuite && $specsuite ne $isuite) {
1799         canonicalise_suite();
1800         $csuite eq $specsuite or
1801             fail "dgit push: changelog specifies $isuite ($csuite)".
1802                 " but command line specifies $specsuite";
1803     }
1804     if (check_for_git()) {
1805         git_fetch_us();
1806     }
1807     if (fetch_from_archive()) {
1808         is_fast_fwd(lrref(), 'HEAD') or
1809             fail "dgit push: HEAD is not a descendant".
1810                 " of the archive's version.\n".
1811                 "$us: To overwrite it, use git merge -s ours ".lrref().".";
1812     } else {
1813         $new_package or
1814             fail "package appears to be new in this suite;".
1815                 " if this is intentional, use --new";
1816     }
1817     dopush();
1818 }
1819
1820 #---------- remote commands' implementation ----------
1821
1822 sub cmd_remote_push_build_host {
1823     my ($nrargs) = shift @ARGV;
1824     my (@rargs) = @ARGV[0..$nrargs-1];
1825     @ARGV = @ARGV[$nrargs..$#ARGV];
1826     die unless @rargs;
1827     my ($dir,$vsnwant) = @rargs;
1828     # vsnwant is a comma-separated list; we report which we have
1829     # chosen in our ready response (so other end can tell if they
1830     # offered several)
1831     $debugprefix = ' ';
1832     $we_are_responder = 1;
1833
1834     open PI, "<&STDIN" or die $!;
1835     open STDIN, "/dev/null" or die $!;
1836     open PO, ">&STDOUT" or die $!;
1837     autoflush PO 1;
1838     open STDOUT, ">&STDERR" or die $!;
1839     autoflush STDOUT 1;
1840
1841     $vsnwant //= 1;
1842     fail "build host has dgit rpush protocol version".
1843         " $rpushprotovsn but invocation host has $vsnwant"
1844         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1845
1846     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1847
1848     changedir $dir;
1849     &cmd_push;
1850 }
1851
1852 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1853 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1854 #     a good error message)
1855
1856 our $i_tmp;
1857
1858 sub i_cleanup {
1859     local ($@, $?);
1860     my $report = i_child_report();
1861     if (defined $report) {
1862         printdebug "($report)\n";
1863     } elsif ($i_child_pid) {
1864         printdebug "(killing build host child $i_child_pid)\n";
1865         kill 15, $i_child_pid;
1866     }
1867     if (defined $i_tmp && !defined $initiator_tempdir) {
1868         changedir "/";
1869         eval { rmtree $i_tmp; };
1870     }
1871 }
1872
1873 END { i_cleanup(); }
1874
1875 sub i_method {
1876     my ($base,$selector,@args) = @_;
1877     $selector =~ s/\-/_/g;
1878     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1879 }
1880
1881 sub cmd_rpush {
1882     my $host = nextarg;
1883     my $dir;
1884     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1885         $host = $1;
1886         $dir = $'; #';
1887     } else {
1888         $dir = nextarg;
1889     }
1890     $dir =~ s{^-}{./-};
1891     my @rargs = ($dir,$rpushprotovsn);
1892     my @rdgit;
1893     push @rdgit, @dgit;
1894     push @rdgit, @ropts;
1895     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1896     push @rdgit, @ARGV;
1897     my @cmd = (@ssh, $host, shellquote @rdgit);
1898     printcmd \*DEBUG,$debugprefix."+",@cmd;
1899
1900     if (defined $initiator_tempdir) {
1901         rmtree $initiator_tempdir;
1902         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1903         $i_tmp = $initiator_tempdir;
1904     } else {
1905         $i_tmp = tempdir();
1906     }
1907     $i_child_pid = open2(\*RO, \*RI, @cmd);
1908     changedir $i_tmp;
1909     initiator_expect { m/^dgit-remote-push-ready/ };
1910     for (;;) {
1911         my ($icmd,$iargs) = initiator_expect {
1912             m/^(\S+)(?: (.*))?$/;
1913             ($1,$2);
1914         };
1915         i_method "i_resp", $icmd, $iargs;
1916     }
1917 }
1918
1919 sub i_resp_progress ($) {
1920     my ($rhs) = @_;
1921     my $msg = protocol_read_bytes \*RO, $rhs;
1922     progress $msg;
1923 }
1924
1925 sub i_resp_complete {
1926     my $pid = $i_child_pid;
1927     $i_child_pid = undef; # prevents killing some other process with same pid
1928     printdebug "waiting for build host child $pid...\n";
1929     my $got = waitpid $pid, 0;
1930     die $! unless $got == $pid;
1931     die "build host child failed $?" if $?;
1932
1933     i_cleanup();
1934     printdebug "all done\n";
1935     exit 0;
1936 }
1937
1938 sub i_resp_file ($) {
1939     my ($keyword) = @_;
1940     my $localname = i_method "i_localname", $keyword;
1941     my $localpath = "$i_tmp/$localname";
1942     stat_exists $localpath and
1943         badproto \*RO, "file $keyword ($localpath) twice";
1944     protocol_receive_file \*RO, $localpath;
1945     i_method "i_file", $keyword;
1946 }
1947
1948 our %i_param;
1949
1950 sub i_resp_param ($) {
1951     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
1952     $i_param{$1} = $2;
1953 }
1954
1955 our %i_wanted;
1956
1957 sub i_resp_want ($) {
1958     my ($keyword) = @_;
1959     die "$keyword ?" if $i_wanted{$keyword}++;
1960     my @localpaths = i_method "i_want", $keyword;
1961     printdebug "[[  $keyword @localpaths\n";
1962     foreach my $localpath (@localpaths) {
1963         protocol_send_file \*RI, $localpath;
1964     }
1965     print RI "files-end\n" or die $!;
1966 }
1967
1968 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
1969
1970 sub i_localname_parsed_changelog {
1971     return "remote-changelog.822";
1972 }
1973 sub i_file_parsed_changelog {
1974     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
1975         push_parse_changelog "$i_tmp/remote-changelog.822";
1976     die if $i_dscfn =~ m#/|^\W#;
1977 }
1978
1979 sub i_localname_dsc {
1980     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1981     return $i_dscfn;
1982 }
1983 sub i_file_dsc { }
1984
1985 sub i_localname_changes {
1986     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
1987     $i_changesfn = $i_dscfn;
1988     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
1989     return $i_changesfn;
1990 }
1991 sub i_file_changes { }
1992
1993 sub i_want_signed_tag {
1994     printdebug Dumper(\%i_param, $i_dscfn);
1995     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
1996         && defined $i_param{'csuite'}
1997         or badproto \*RO, "premature desire for signed-tag";
1998     my $head = $i_param{'head'};
1999     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2000
2001     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2002     $csuite = $&;
2003     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2004
2005     my $tagobjfn =
2006         push_mktag $head, $i_clogp, $i_tag,
2007             $i_dscfn,
2008             $i_changesfn, 'remote changes',
2009             sub { "tag$_[0]"; };
2010
2011     return $tagobjfn;
2012 }
2013
2014 sub i_want_signed_dsc_changes {
2015     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2016     sign_changes $i_changesfn;
2017     return ($i_dscfn, $i_changesfn);
2018 }
2019
2020 #---------- building etc. ----------
2021
2022 our $version;
2023 our $sourcechanges;
2024 our $dscfn;
2025
2026 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2027
2028 sub build_maybe_quilt_fixup () {
2029     my $format=get_source_format;
2030     return unless madformat $format;
2031     # sigh
2032
2033     # Our objective is:
2034     #  - honour any existing .pc in case it has any strangeness
2035     #  - determine the git commit corresponding to the tip of
2036     #    the patch stack (if there is one)
2037     #  - if there is such a git commit, convert each subsequent
2038     #    git commit into a quilt patch with dpkg-source --commit
2039     #  - otherwise convert all the differences in the tree into
2040     #    a single git commit
2041     #
2042     # To do this we:
2043
2044     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2045     # dgit would include the .pc in the git tree.)  If there isn't
2046     # one, we need to generate one by unpacking the patches that we
2047     # have.
2048     #
2049     # We first look for a .pc in the git tree.  If there is one, we
2050     # will use it.  (This is not the normal case.)
2051     #
2052     # Otherwise need to regenerate .pc so that dpkg-source --commit
2053     # can work.  We do this as follows:
2054     #     1. Collect all relevant .orig from parent directory
2055     #     2. Generate a debian.tar.gz out of
2056     #         debian/{patches,rules,source/format}
2057     #     3. Generate a fake .dsc containing just these fields:
2058     #          Format Source Version Files
2059     #     4. Extract the fake .dsc
2060     #        Now the fake .dsc has a .pc directory.
2061     # (In fact we do this in every case, because in future we will
2062     # want to search for a good base commit for generating patches.)
2063     #
2064     # Then we can actually do the dpkg-source --commit
2065     #     1. Make a new working tree with the same object
2066     #        store as our main tree and check out the main
2067     #        tree's HEAD.
2068     #     2. Copy .pc from the fake's extraction, if necessary
2069     #     3. Run dpkg-source --commit
2070     #     4. If the result has changes to debian/, then
2071     #          - git-add them them
2072     #          - git-add .pc if we had a .pc in-tree
2073     #          - git-commit
2074     #     5. If we had a .pc in-tree, delete it, and git-commit
2075     #     6. Back in the main tree, fast forward to the new HEAD
2076
2077     my $clogp = parsechangelog();
2078     my $headref = rev_parse('HEAD');
2079
2080     prep_ud();
2081     changedir $ud;
2082
2083     my $upstreamversion=$version;
2084     $upstreamversion =~ s/-[^-]*$//;
2085
2086     my $fakeversion="$upstreamversion-~~DGITFAKE";
2087
2088     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2089     print $fakedsc <<END or die $!;
2090 Format: 3.0 (quilt)
2091 Source: $package
2092 Version: $fakeversion
2093 Files:
2094 END
2095
2096     my $dscaddfile=sub {
2097         my ($b) = @_;
2098
2099         my $md = new Digest::MD5;
2100
2101         my $fh = new IO::File $b, '<' or die "$b $!";
2102         stat $fh or die $!;
2103         my $size = -s _;
2104
2105         $md->addfile($fh);
2106         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2107     };
2108
2109     foreach my $f (<../../../../*>) { #/){
2110         my $b=$f; $b =~ s{.*/}{};
2111         next unless is_orig_file $b, srcfn $upstreamversion,'';
2112         link $f, $b or die "$b $!";
2113         $dscaddfile->($b);
2114     }
2115
2116     my @files=qw(debian/source/format debian/rules);
2117     if (stat_exists '../../../debian/patches') {
2118         push @files, 'debian/patches';
2119     }
2120
2121     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2122     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2123
2124     $dscaddfile->($debtar);
2125     close $fakedsc or die $!;
2126
2127     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2128
2129     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2130     rename $fakexdir, "fake" or die "$fakexdir $!";
2131
2132     mkdir "work" or die $!;
2133     changedir "work";
2134     mktree_in_ud_here();
2135     runcmd @git, qw(reset --hard), $headref;
2136
2137     my $mustdeletepc=0;
2138     if (stat_exists ".pc") {
2139         -d _ or die;
2140         progress "Tree already contains .pc - will use it then delete it.";
2141         $mustdeletepc=1;
2142     } else {
2143         rename '../fake/.pc','.pc' or die $!;
2144     }
2145
2146     my $author = getfield $clogp, 'Maintainer';
2147     my $time = time;
2148     my $ncommits = 3;
2149     my $patchname = "auto-$version-$headref-$time";
2150     my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2151     mkpath '.git/dgit';
2152     my $descfn = ".git/dgit/quilt-description.tmp";
2153     open O, '>', $descfn or die "$descfn: $!";
2154     $msg =~ s/\n/\n /g;
2155     $msg =~ s/^\s+$/ ./mg;
2156     print O <<END or die $!;
2157 Description: Automatically generated patch ($clogp->{Version})
2158  Last (up to) $ncommits git changes, FYI:
2159  .
2160  $msg
2161 Author: $author
2162
2163 ---
2164
2165 END
2166     close O or die $!;
2167     {
2168         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2169         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2170         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2171         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2172     }
2173
2174     if (!open P, '>>', ".pc/applied-patches") {
2175         $!==&ENOENT or die $!;
2176     } else {
2177         close P;
2178     }
2179
2180     commit_quilty_patch();
2181
2182     if ($mustdeletepc) {
2183         runcmd @git, qw(rm -rq .pc);
2184         commit_admin "Commit removal of .pc (quilt series tracking data)";
2185     }
2186
2187     changedir '../../../..';
2188     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2189 }
2190
2191 sub quilt_fixup_editor () {
2192     my $descfn = $ENV{$fakeeditorenv};
2193     my $editing = $ARGV[$#ARGV];
2194     open I1, '<', $descfn or die "$descfn: $!";
2195     open I2, '<', $editing or die "$editing: $!";
2196     unlink $editing or die "$editing: $!";
2197     open O, '>', $editing or die "$editing: $!";
2198     while (<I1>) { print O or die $!; } I1->error and die $!;
2199     my $copying = 0;
2200     while (<I2>) {
2201         $copying ||= m/^\-\-\- /;
2202         next unless $copying;
2203         print O or die $!;
2204     }
2205     I2->error and die $!;
2206     close O or die $1;
2207     exit 0;
2208 }
2209
2210 sub clean_tree () {
2211     if ($cleanmode eq 'dpkg-source') {
2212         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2213     } elsif ($cleanmode eq 'git') {
2214         runcmd_ordryrun_local @git, qw(clean -xdf);
2215     } elsif ($cleanmode eq 'none') {
2216     } else {
2217         die "$cleanmode ?";
2218     }
2219 }
2220
2221 sub cmd_clean () {
2222     badusage "clean takes no additional arguments" if @ARGV;
2223     clean_tree();
2224 }
2225
2226 sub build_prep () {
2227     badusage "-p is not allowed when building" if defined $package;
2228     check_not_dirty();
2229     clean_tree();
2230     my $clogp = parsechangelog();
2231     $isuite = getfield $clogp, 'Distribution';
2232     $package = getfield $clogp, 'Source';
2233     $version = getfield $clogp, 'Version';
2234     build_maybe_quilt_fixup();
2235 }
2236
2237 sub changesopts () {
2238     my @opts =@changesopts[1..$#changesopts];
2239     if (!defined $changes_since_version) {
2240         my @vsns = archive_query('archive_query');
2241         my @quirk = access_quirk();
2242         if ($quirk[0] eq 'backports') {
2243             local $isuite = $quirk[2];
2244             local $csuite;
2245             canonicalise_suite();
2246             push @vsns, archive_query('archive_query');
2247         }
2248         if (@vsns) {
2249             @vsns = map { $_->[0] } @vsns;
2250             @vsns = sort { -version_compare($a, $b) } @vsns;
2251             $changes_since_version = $vsns[0];
2252             progress "changelog will contain changes since $vsns[0]";
2253         } else {
2254             $changes_since_version = '_';
2255             progress "package seems new, not specifying -v<version>";
2256         }
2257     }
2258     if ($changes_since_version ne '_') {
2259         unshift @opts, "-v$changes_since_version";
2260     }
2261     return @opts;
2262 }
2263
2264 sub cmd_build {
2265     build_prep();
2266     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2267     printdone "build successful\n";
2268 }
2269
2270 sub cmd_git_build {
2271     build_prep();
2272     my @cmd =
2273         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2274          "--git-builder=@dpkgbuildpackage");
2275     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2276         canonicalise_suite();
2277         push @cmd, "--git-debian-branch=".lbranch();
2278     }
2279     push @cmd, changesopts();
2280     runcmd_ordryrun_local @cmd, @ARGV;
2281     printdone "build successful\n";
2282 }
2283
2284 sub build_source {
2285     build_prep();
2286     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2287     $dscfn = dscfn($version);
2288     if ($cleanmode eq 'dpkg-source') {
2289         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2290             changesopts();
2291     } else {
2292         my $pwd = must_getcwd();
2293         my $leafdir = basename $pwd;
2294         changedir "..";
2295         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2296         changedir $pwd;
2297         runcmd_ordryrun_local qw(sh -ec),
2298             'exec >$1; shift; exec "$@"','x',
2299             "../$sourcechanges",
2300             @dpkggenchanges, qw(-S), changesopts();
2301     }
2302 }
2303
2304 sub cmd_build_source {
2305     badusage "build-source takes no additional arguments" if @ARGV;
2306     build_source();
2307     printdone "source built, results in $dscfn and $sourcechanges";
2308 }
2309
2310 sub cmd_sbuild {
2311     build_source();
2312     changedir "..";
2313     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2314     if (act_local()) {
2315         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2316         stat_exists $sourcechanges
2317             or fail "$sourcechanges (in parent directory): $!";
2318         foreach my $cf (glob $pat) {
2319             next if $cf eq $sourcechanges;
2320             unlink $cf or fail "remove $cf: $!";
2321         }
2322     }
2323     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2324     my @changesfiles = glob $pat;
2325     @changesfiles = sort {
2326         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2327             or $a cmp $b
2328     } @changesfiles;
2329     fail "wrong number of different changes files (@changesfiles)"
2330         unless @changesfiles;
2331     runcmd_ordryrun_local @mergechanges, @changesfiles;
2332     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2333     if (act_local()) {
2334         stat_exists $multichanges or fail "$multichanges: $!";
2335     }
2336     printdone "build successful, results in $multichanges\n" or die $!;
2337 }
2338
2339 sub cmd_quilt_fixup {
2340     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2341     my $clogp = parsechangelog();
2342     $version = getfield $clogp, 'Version';
2343     $package = getfield $clogp, 'Source';
2344     build_maybe_quilt_fixup();
2345 }
2346
2347 #---------- argument parsing and main program ----------
2348
2349 sub cmd_version {
2350     print "dgit version $our_version\n" or die $!;
2351     exit 0;
2352 }
2353
2354 sub parseopts () {
2355     my $om;
2356
2357     if (defined $ENV{'DGIT_SSH'}) {
2358         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2359     } elsif (defined $ENV{'GIT_SSH'}) {
2360         @ssh = ($ENV{'GIT_SSH'});
2361     }
2362
2363     while (@ARGV) {
2364         last unless $ARGV[0] =~ m/^-/;
2365         $_ = shift @ARGV;
2366         last if m/^--?$/;
2367         if (m/^--/) {
2368             if (m/^--dry-run$/) {
2369                 push @ropts, $_;
2370                 $dryrun_level=2;
2371             } elsif (m/^--damp-run$/) {
2372                 push @ropts, $_;
2373                 $dryrun_level=1;
2374             } elsif (m/^--no-sign$/) {
2375                 push @ropts, $_;
2376                 $sign=0;
2377             } elsif (m/^--help$/) {
2378                 cmd_help();
2379             } elsif (m/^--version$/) {
2380                 cmd_version();
2381             } elsif (m/^--new$/) {
2382                 push @ropts, $_;
2383                 $new_package=1;
2384             } elsif (m/^--since-version=([^_]+|_)$/) {
2385                 push @ropts, $_;
2386                 $changes_since_version = $1;
2387             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2388                      ($om = $opts_opt_map{$1}) &&
2389                      length $om->[0]) {
2390                 push @ropts, $_;
2391                 $om->[0] = $2;
2392             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2393                      !$opts_opt_cmdonly{$1} &&
2394                      ($om = $opts_opt_map{$1})) {
2395                 push @ropts, $_;
2396                 push @$om, $2;
2397             } elsif (m/^--existing-package=(.*)/s) {
2398                 push @ropts, $_;
2399                 $existing_package = $1;
2400             } elsif (m/^--initiator-tempdir=(.*)/s) {
2401                 $initiator_tempdir = $1;
2402                 $initiator_tempdir =~ m#^/# or
2403                     badusage "--initiator-tempdir must be used specify an".
2404                         " absolute, not relative, directory."
2405             } elsif (m/^--distro=(.*)/s) {
2406                 push @ropts, $_;
2407                 $idistro = $1;
2408             } elsif (m/^--build-products-dir=(.*)/s) {
2409                 push @ropts, $_;
2410                 $buildproductsdir = $1;
2411             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2412                 push @ropts, $_;
2413                 $cleanmode = $1;
2414             } elsif (m/^--clean=(.*)$/s) {
2415                 badusage "unknown cleaning mode \`$1'";
2416             } elsif (m/^--ignore-dirty$/s) {
2417                 push @ropts, $_;
2418                 $ignoredirty = 1;
2419             } elsif (m/^--no-quilt-fixup$/s) {
2420                 push @ropts, $_;
2421                 $noquilt = 1;
2422             } elsif (m/^--no-rm-on-error$/s) {
2423                 push @ropts, $_;
2424                 $rmonerror = 0;
2425             } else {
2426                 badusage "unknown long option \`$_'";
2427             }
2428         } else {
2429             while (m/^-./s) {
2430                 if (s/^-n/-/) {
2431                     push @ropts, $&;
2432                     $dryrun_level=2;
2433                 } elsif (s/^-L/-/) {
2434                     push @ropts, $&;
2435                     $dryrun_level=1;
2436                 } elsif (s/^-h/-/) {
2437                     cmd_help();
2438                 } elsif (s/^-D/-/) {
2439                     push @ropts, $&;
2440                     open DEBUG, ">&STDERR" or die $!;
2441                     autoflush DEBUG 1;
2442                     $debug++;
2443                 } elsif (s/^-N/-/) {
2444                     push @ropts, $&;
2445                     $new_package=1;
2446                 } elsif (s/^-v([^_]+|_)$//s) {
2447                     push @ropts, $&;
2448                     $changes_since_version = $1;
2449                 } elsif (m/^-m/) {
2450                     push @ropts, $&;
2451                     push @changesopts, $_;
2452                     $_ = '';
2453                 } elsif (s/^-c(.*=.*)//s) {
2454                     push @ropts, $&;
2455                     push @git, '-c', $1;
2456                 } elsif (s/^-d(.*)//s) {
2457                     push @ropts, $&;
2458                     $idistro = $1;
2459                 } elsif (s/^-C(.*)//s) {
2460                     push @ropts, $&;
2461                     $changesfile = $1;
2462                     if ($changesfile =~ s#^(.*)/##) {
2463                         $buildproductsdir = $1;
2464                     }
2465                 } elsif (s/^-k(.*)//s) {
2466                     $keyid=$1;
2467                 } elsif (s/^-wn//s) {
2468                     push @ropts, $&;
2469                     $cleanmode = 'none';
2470                 } elsif (s/^-wg//s) {
2471                     push @ropts, $&;
2472                     $cleanmode = 'git';
2473                 } elsif (s/^-wd//s) {
2474                     push @ropts, $&;
2475                     $cleanmode = 'dpkg-source';
2476                 } else {
2477                     badusage "unknown short option \`$_'";
2478                 }
2479             }
2480         }
2481     }
2482 }
2483
2484 if ($ENV{$fakeeditorenv}) {
2485     quilt_fixup_editor();
2486 }
2487
2488 parseopts();
2489 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2490 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2491     if $dryrun_level == 1;
2492 if (!@ARGV) {
2493     print STDERR $helpmsg or die $!;
2494     exit 8;
2495 }
2496 my $cmd = shift @ARGV;
2497 $cmd =~ y/-/_/;
2498
2499 my $fn = ${*::}{"cmd_$cmd"};
2500 $fn or badusage "unknown operation $cmd";
2501 $fn->();