dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21 $SIG{__WARN__} = sub { die $_[0]; };
  22
  23 use IO::Handle;
  24 use Data::Dumper;
  25 use LWP::UserAgent;
  26 use Dpkg::Control::Hash;
  27 use File::Path;
  28 use File::Temp qw(tempdir);
  29 use File::Basename;
  30 use Dpkg::Version;
  31 use POSIX;
  32 use IPC::Open2;
  33 use Digest::SHA;
  34 use Digest::MD5;
  35
  36 use Debian::Dgit;
  37
  38 our $our_version = 'UNRELEASED'; ###substituted###
  39
  40 our $rpushprotovsn = 2;
  41
  42 our $isuite = 'unstable';
  43 our $idistro;
  44 our $package;
  45 our @ropts;
  46
  47 our $sign = 1;
  48 our $dryrun_level = 0;
  49 our $changesfile;
  50 our $buildproductsdir = '..';
  51 our $new_package = 0;
  52 our $ignoredirty = 0;
  53 our $rmonerror = 1;
  54 our @deliberatelies;
  55 our %previously;
  56 our $existing_package = 'dpkg';
  57 our $cleanmode = 'dpkg-source';
  58 our $changes_since_version;
  59 our $quilt_mode;
  60 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  61 our $we_are_responder;
  62 our $initiator_tempdir;
  63
  64 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  65
  66 our $suite_re = '[-+.0-9a-z]+';
  67
  68 our (@git) = qw(git);
  69 our (@dget) = qw(dget);
  70 our (@curl) = qw(curl -f);
  71 our (@dput) = qw(dput);
  72 our (@debsign) = qw(debsign);
  73 our (@gpg) = qw(gpg);
  74 our (@sbuild) = qw(sbuild -A);
  75 our (@ssh) = 'ssh';
  76 our (@dgit) = qw(dgit);
  77 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  78 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  79 our (@dpkggenchanges) = qw(dpkg-genchanges);
  80 our (@mergechanges) = qw(mergechanges -f);
  81 our (@changesopts) = ('');
  82
  83 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  84                      'curl' => \@curl,
  85                      'dput' => \@dput,
  86                      'debsign' => \@debsign,
  87                      'gpg' => \@gpg,
  88                      'sbuild' => \@sbuild,
  89                      'ssh' => \@ssh,
  90                      'dgit' => \@dgit,
  91                      'dpkg-source' => \@dpkgsource,
  92                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  93                      'dpkg-genchanges' => \@dpkggenchanges,
  94                      'ch' => \@changesopts,
  95                      'mergechanges' => \@mergechanges);
  96
  97 our %opts_opt_cmdonly = ('gpg' => 1);
  98
  99 our $keyid;
 100
 101 autoflush STDOUT 1;
 102
 103 our $remotename = 'dgit';
 104 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 105 our $csuite;
 106 our $instead_distro;
 107
 108 sub lbranch () { return "$branchprefix/$csuite"; }
 109 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 110 sub lref () { return "refs/heads/".lbranch(); }
 111 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 112 sub rrref () { return server_ref($csuite); }
 113
 114 sub lrfetchrefs () { return "refs/dgit-fetch/$isuite"; }
 115
 116 sub stripepoch ($) {
 117     my ($vsn) = @_;
 118     $vsn =~ s/^\d+\://;
 119     return $vsn;
 120 }
 121
 122 sub srcfn ($$) {
 123     my ($vsn,$sfx) = @_;
 124     return "${package}_".(stripepoch $vsn).$sfx
 125 }
 126
 127 sub dscfn ($) {
 128     my ($vsn) = @_;
 129     return srcfn($vsn,".dsc");
 130 }
 131
 132 our $us = 'dgit';
 133 initdebug('');
 134
 135 our @end;
 136 END {
 137     local ($?);
 138     foreach my $f (@end) {
 139         eval { $f->(); };
 140         warn "$us: cleanup: $@" if length $@;
 141     }
 142 };
 143
 144 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 145
 146 sub no_such_package () {
 147     print STDERR "$us: package $package does not exist in suite $isuite\n";
 148     exit 4;
 149 }
 150
 151 sub fetchspec () {
 152     local $csuite = '*';
 153     return  "+".rrref().":".lrref();
 154 }
 155
 156 sub changedir ($) {
 157     my ($newdir) = @_;
 158     printdebug "CD $newdir\n";
 159     chdir $newdir or die "chdir: $newdir: $!";
 160 }
 161
 162 sub deliberately ($) {
 163     my ($enquiry) = @_;
 164     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 165 }
 166
 167 sub deliberately_not_fast_forward () {
 168     foreach (qw(not-fast-forward fresh-repo)) {
 169         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 170     }
 171 }
 172
 173 #---------- remote protocol support, common ----------
 174
 175 # remote push initiator/responder protocol:
 176 #  < dgit-remote-push-ready [optional extra info ignored by old initiators]
 177 #
 178 #  > file parsed-changelog
 179 #  [indicates that output of dpkg-parsechangelog follows]
 180 #  > data-block NBYTES
 181 #  > [NBYTES bytes of data (no newline)]
 182 #  [maybe some more blocks]
 183 #  > data-end
 184 #
 185 #  > file dsc
 186 #  [etc]
 187 #
 188 #  > file changes
 189 #  [etc]
 190 #
 191 #  > param head HEAD
 192 #
 193 #  > want signed-tag
 194 #  [indicates that signed tag is wanted]
 195 #  < data-block NBYTES
 196 #  < [NBYTES bytes of data (no newline)]
 197 #  [maybe some more blocks]
 198 #  < data-end
 199 #  < files-end
 200 #
 201 #  > want signed-dsc-changes
 202 #  < data-block NBYTES    [transfer of signed dsc]
 203 #  [etc]
 204 #  < data-block NBYTES    [transfer of signed changes]
 205 #  [etc]
 206 #  < files-end
 207 #
 208 #  > complete
 209
 210 our $i_child_pid;
 211
 212 sub i_child_report () {
 213     # Sees if our child has died, and reap it if so.  Returns a string
 214     # describing how it died if it failed, or undef otherwise.
 215     return undef unless $i_child_pid;
 216     my $got = waitpid $i_child_pid, WNOHANG;
 217     return undef if $got <= 0;
 218     die unless $got == $i_child_pid;
 219     $i_child_pid = undef;
 220     return undef unless $?;
 221     return "build host child ".waitstatusmsg();
 222 }
 223
 224 sub badproto ($$) {
 225     my ($fh, $m) = @_;
 226     fail "connection lost: $!" if $fh->error;
 227     fail "protocol violation; $m not expected";
 228 }
 229
 230 sub badproto_badread ($$) {
 231     my ($fh, $wh) = @_;
 232     fail "connection lost: $!" if $!;
 233     my $report = i_child_report();
 234     fail $report if defined $report;
 235     badproto $fh, "eof (reading $wh)";
 236 }
 237
 238 sub protocol_expect (&$) {
 239     my ($match, $fh) = @_;
 240     local $_;
 241     $_ = <$fh>;
 242     defined && chomp or badproto_badread $fh, "protocol message";
 243     if (wantarray) {
 244         my @r = &$match;
 245         return @r if @r;
 246     } else {
 247         my $r = &$match;
 248         return $r if $r;
 249     }
 250     badproto $fh, "\`$_'";
 251 }
 252
 253 sub protocol_send_file ($$) {
 254     my ($fh, $ourfn) = @_;
 255     open PF, "<", $ourfn or die "$ourfn: $!";
 256     for (;;) {
 257         my $d;
 258         my $got = read PF, $d, 65536;
 259         die "$ourfn: $!" unless defined $got;
 260         last if !$got;
 261         print $fh "data-block ".length($d)."\n" or die $!;
 262         print $fh $d or die $!;
 263     }
 264     PF->error and die "$ourfn $!";
 265     print $fh "data-end\n" or die $!;
 266     close PF;
 267 }
 268
 269 sub protocol_read_bytes ($$) {
 270     my ($fh, $nbytes) = @_;
 271     $nbytes =~ m/^[1-9]\d{0,5}$/ or badproto \*RO, "bad byte count";
 272     my $d;
 273     my $got = read $fh, $d, $nbytes;
 274     $got==$nbytes or badproto_badread $fh, "data block";
 275     return $d;
 276 }
 277
 278 sub protocol_receive_file ($$) {
 279     my ($fh, $ourfn) = @_;
 280     printdebug "() $ourfn\n";
 281     open PF, ">", $ourfn or die "$ourfn: $!";
 282     for (;;) {
 283         my ($y,$l) = protocol_expect {
 284             m/^data-block (.*)$/ ? (1,$1) :
 285             m/^data-end$/ ? (0,) :
 286             ();
 287         } $fh;
 288         last unless $y;
 289         my $d = protocol_read_bytes $fh, $l;
 290         print PF $d or die $!;
 291     }
 292     close PF or die $!;
 293 }
 294
 295 #---------- remote protocol support, responder ----------
 296
 297 sub responder_send_command ($) {
 298     my ($command) = @_;
 299     return unless $we_are_responder;
 300     # called even without $we_are_responder
 301     printdebug ">> $command\n";
 302     print PO $command, "\n" or die $!;
 303 }
 304
 305 sub responder_send_file ($$) {
 306     my ($keyword, $ourfn) = @_;
 307     return unless $we_are_responder;
 308     printdebug "]] $keyword $ourfn\n";
 309     responder_send_command "file $keyword";
 310     protocol_send_file \*PO, $ourfn;
 311 }
 312
 313 sub responder_receive_files ($@) {
 314     my ($keyword, @ourfns) = @_;
 315     die unless $we_are_responder;
 316     printdebug "[[ $keyword @ourfns\n";
 317     responder_send_command "want $keyword";
 318     foreach my $fn (@ourfns) {
 319         protocol_receive_file \*PI, $fn;
 320     }
 321     printdebug "[[\$\n";
 322     protocol_expect { m/^files-end$/ } \*PI;
 323 }
 324
 325 #---------- remote protocol support, initiator ----------
 326
 327 sub initiator_expect (&) {
 328     my ($match) = @_;
 329     protocol_expect { &$match } \*RO;
 330 }
 331
 332 #---------- end remote code ----------
 333
 334 sub progress {
 335     if ($we_are_responder) {
 336         my $m = join '', @_;
 337         responder_send_command "progress ".length($m) or die $!;
 338         print PO $m or die $!;
 339     } else {
 340         print @_, "\n";
 341     }
 342 }
 343
 344 our $ua;
 345
 346 sub url_get {
 347     if (!$ua) {
 348         $ua = LWP::UserAgent->new();
 349         $ua->env_proxy;
 350     }
 351     my $what = $_[$#_];
 352     progress "downloading $what...";
 353     my $r = $ua->get(@_) or die $!;
 354     return undef if $r->code == 404;
 355     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 356     return $r->decoded_content(charset => 'none');
 357 }
 358
 359 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 360
 361 sub runcmd {
 362     debugcmd "+",@_;
 363     $!=0; $?=0;
 364     failedcmd @_ if system @_;
 365 }
 366
 367 sub act_local () { return $dryrun_level <= 1; }
 368 sub act_scary () { return !$dryrun_level; }
 369
 370 sub printdone {
 371     if (!$dryrun_level) {
 372         progress "dgit ok: @_";
 373     } else {
 374         progress "would be ok: @_ (but dry run only)";
 375     }
 376 }
 377
 378 sub dryrun_report {
 379     printcmd(\*STDERR,$debugprefix."#",@_);
 380 }
 381
 382 sub runcmd_ordryrun {
 383     if (act_scary()) {
 384         runcmd @_;
 385     } else {
 386         dryrun_report @_;
 387     }
 388 }
 389
 390 sub runcmd_ordryrun_local {
 391     if (act_local()) {
 392         runcmd @_;
 393     } else {
 394         dryrun_report @_;
 395     }
 396 }
 397
 398 sub shell_cmd {
 399     my ($first_shell, @cmd) = @_;
 400     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 401 }
 402
 403 our $helpmsg = <<END;
 404 main usages:
 405   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 406   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 407   dgit [dgit-opts] build [git-buildpackage-opts|dpkg-buildpackage-opts]
 408   dgit [dgit-opts] push [dgit-opts] [suite]
 409   dgit [dgit-opts] rpush build-host:build-dir ...
 410 important dgit options:
 411   -k<keyid>           sign tag and package with <keyid> instead of default
 412   --dry-run -n        do not change anything, but go through the motions
 413   --damp-run -L       like --dry-run but make local changes, without signing
 414   --new -N            allow introducing a new package
 415   --debug -D          increase debug level
 416   -c<name>=<value>    set git config option (used directly by dgit too)
 417 END
 418
 419 our $later_warning_msg = <<END;
 420 Perhaps the upload is stuck in incoming.  Using the version from git.
 421 END
 422
 423 sub badusage {
 424     print STDERR "$us: @_\n", $helpmsg or die $!;
 425     exit 8;
 426 }
 427
 428 sub nextarg {
 429     @ARGV or badusage "too few arguments";
 430     return scalar shift @ARGV;
 431 }
 432
 433 sub cmd_help () {
 434     print $helpmsg or die $!;
 435     exit 0;
 436 }
 437
 438 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 439
 440 our %defcfg = ('dgit.default.distro' => 'debian',
 441                'dgit.default.username' => '',
 442                'dgit.default.archive-query-default-component' => 'main',
 443                'dgit.default.ssh' => 'ssh',
 444                'dgit.default.archive-query' => 'madison:',
 445                'dgit.default.sshpsql-dbname' => 'service=projectb',
 446                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 447                'dgit-distro.debian.git-host' => 'dgit-git.debian.net',
 448                'dgit-distro.debian.git-user-force' => 'dgit',
 449                'dgit-distro.debian.git-proto' => 'git+ssh://',
 450                'dgit-distro.debian.git-path' => '/dgit/debian/repos',
 451                'dgit-distro.debian.git-check' => 'ssh-cmd',
 452  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 453 # 'dgit-distro.debian.archive-query-tls-key',
 454 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 455 # ^ this does not work because curl is broken nowadays
 456 # Fixing #790093 properly will involve providing providing the key
 457 # in some pacagke and maybe updating these paths.
 458 #
 459 # 'dgit-distro.debian.archive-query-tls-curl-args',
 460 #   '--ca-path=/etc/ssl/ca-debian',
 461 # ^ this is a workaround but works (only) on DSA-administered machines
 462                'dgit-distro.debian.diverts.alioth' => '/alioth',
 463                'dgit-distro.debian/alioth.git-host' => 'git.debian.org',
 464                'dgit-distro.debian/alioth.git-user-force' => '',
 465                'dgit-distro.debian/alioth.git-proto' => 'git+ssh://',
 466                'dgit-distro.debian/alioth.git-path' => '/git/dgit-repos/repos',
 467                'dgit-distro.debian/alioth.git-create' => 'ssh-cmd',
 468                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 469                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 470  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 471  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 472                'dgit-distro.ubuntu.git-check' => 'false',
 473  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 474                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 475                'dgit-distro.test-dummy.username' => "alice",
 476                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 477                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 478                'dgit-distro.test-dummy.git-url' => "$td/git",
 479                'dgit-distro.test-dummy.git-host' => "git",
 480                'dgit-distro.test-dummy.git-path' => "$td/git",
 481                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 482                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 483                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 484                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 485                );
 486
 487 sub cfg {
 488     foreach my $c (@_) {
 489         return undef if $c =~ /RETURN-UNDEF/;
 490         my @cmd = (@git, qw(config --), $c);
 491         my $v;
 492         {
 493             local ($debuglevel) = $debuglevel-2;
 494             $v = cmdoutput_errok @cmd;
 495         };
 496         if ($?==0) {
 497             return $v;
 498         } elsif ($?!=256) {
 499             failedcmd @cmd;
 500         }
 501         my $dv = $defcfg{$c};
 502         return $dv if defined $dv;
 503     }
 504     badcfg "need value for one of: @_\n".
 505         "$us: distro or suite appears not to be (properly) supported";
 506 }
 507
 508 sub access_basedistro () {
 509     if (defined $idistro) {
 510         return $idistro;
 511     } else {
 512         return cfg("dgit-suite.$isuite.distro",
 513                    "dgit.default.distro");
 514     }
 515 }
 516
 517 sub access_quirk () {
 518     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 519     my $basedistro = access_basedistro();
 520     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 521                               'RETURN-UNDEF');
 522     if (defined $backports_quirk) {
 523         my $re = $backports_quirk;
 524         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 525         $re =~ s/\*/.*/g;
 526         $re =~ s/\%/([-0-9a-z_]+)/
 527             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 528         if ($isuite =~ m/^$re$/) {
 529             return ('backports',"$basedistro-backports",$1);
 530         }
 531     }
 532     return ('none',undef);
 533 }
 534
 535 sub access_distros () {
 536     # Returns list of distros to try, in order
 537     #
 538     # We want to try:
 539     #    0. `instead of' distro name(s) we have been pointed to
 540     #    1. the access_quirk distro, if any
 541     #    2a. the user's specified distro, or failing that  } basedistro
 542     #    2b. the distro calculated from the suite          }
 543     my @l = access_basedistro();
 544
 545     my (undef,$quirkdistro) = access_quirk();
 546     unshift @l, $quirkdistro;
 547     unshift @l, $instead_distro;
 548     return grep { defined } @l;
 549 }
 550
 551 sub access_cfg (@) {
 552     my (@keys) = @_;
 553     my @cfgs;
 554     # The nesting of these loops determines the search order.  We put
 555     # the key loop on the outside so that we search all the distros
 556     # for each key, before going on to the next key.  That means that
 557     # if access_cfg is called with a more specific, and then a less
 558     # specific, key, an earlier distro can override the less specific
 559     # without necessarily overriding any more specific keys.  (If the
 560     # distro wants to override the more specific keys it can simply do
 561     # so; whereas if we did the loop the other way around, it would be
 562     # impossible to for an earlier distro to override a less specific
 563     # key but not the more specific ones without restating the unknown
 564     # values of the more specific keys.
 565     my @realkeys;
 566     my @rundef;
 567     # We have to deal with RETURN-UNDEF specially, so that we don't
 568     # terminate the search prematurely.
 569     foreach (@keys) {
 570         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 571         push @realkeys, $_
 572     }
 573     foreach my $d (access_distros()) {
 574         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 575     }
 576     push @cfgs, map { "dgit.default.$_" } @realkeys;
 577     push @cfgs, @rundef;
 578     my $value = cfg(@cfgs);
 579     return $value;
 580 }
 581
 582 sub string_to_ssh ($) {
 583     my ($spec) = @_;
 584     if ($spec =~ m/\s/) {
 585         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 586     } else {
 587         return ($spec);
 588     }
 589 }
 590
 591 sub access_cfg_ssh () {
 592     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 593     if (!defined $gitssh) {
 594         return @ssh;
 595     } else {
 596         return string_to_ssh $gitssh;
 597     }
 598 }
 599
 600 sub access_runeinfo ($) {
 601     my ($info) = @_;
 602     return ": dgit ".access_basedistro()." $info ;";
 603 }
 604
 605 sub access_someuserhost ($) {
 606     my ($some) = @_;
 607     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 608     defined($user) && length($user) or
 609         $user = access_cfg("$some-user",'username');
 610     my $host = access_cfg("$some-host");
 611     return length($user) ? "$user\@$host" : $host;
 612 }
 613
 614 sub access_gituserhost () {
 615     return access_someuserhost('git');
 616 }
 617
 618 sub access_giturl (;$) {
 619     my ($optional) = @_;
 620     my $url = access_cfg('git-url','RETURN-UNDEF');
 621     if (!defined $url) {
 622         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 623         return undef unless defined $proto;
 624         $url =
 625             $proto.
 626             access_gituserhost().
 627             access_cfg('git-path');
 628     }
 629     return "$url/$package.git";
 630 }
 631
 632 sub parsecontrolfh ($$;$) {
 633     my ($fh, $desc, $allowsigned) = @_;
 634     our $dpkgcontrolhash_noissigned;
 635     my $c;
 636     for (;;) {
 637         my %opts = ('name' => $desc);
 638         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 639         $c = Dpkg::Control::Hash->new(%opts);
 640         $c->parse($fh,$desc) or die "parsing of $desc failed";
 641         last if $allowsigned;
 642         last if $dpkgcontrolhash_noissigned;
 643         my $issigned= $c->get_option('is_pgp_signed');
 644         if (!defined $issigned) {
 645             $dpkgcontrolhash_noissigned= 1;
 646             seek $fh, 0,0 or die "seek $desc: $!";
 647         } elsif ($issigned) {
 648             fail "control file $desc is (already) PGP-signed. ".
 649                 " Note that dgit push needs to modify the .dsc and then".
 650                 " do the signature itself";
 651         } else {
 652             last;
 653         }
 654     }
 655     return $c;
 656 }
 657
 658 sub parsecontrol {
 659     my ($file, $desc) = @_;
 660     my $fh = new IO::Handle;
 661     open $fh, '<', $file or die "$file: $!";
 662     my $c = parsecontrolfh($fh,$desc);
 663     $fh->error and die $!;
 664     close $fh;
 665     return $c;
 666 }
 667
 668 sub getfield ($$) {
 669     my ($dctrl,$field) = @_;
 670     my $v = $dctrl->{$field};
 671     return $v if defined $v;
 672     fail "missing field $field in ".$v->get_option('name');
 673 }
 674
 675 sub parsechangelog {
 676     my $c = Dpkg::Control::Hash->new();
 677     my $p = new IO::Handle;
 678     my @cmd = (qw(dpkg-parsechangelog), @_);
 679     open $p, '-|', @cmd or die $!;
 680     $c->parse($p);
 681     $?=0; $!=0; close $p or failedcmd @cmd;
 682     return $c;
 683 }
 684
 685 sub must_getcwd () {
 686     my $d = getcwd();
 687     defined $d or fail "getcwd failed: $!";
 688     return $d;
 689 }
 690
 691 our %rmad;
 692
 693 sub archive_query ($) {
 694     my ($method) = @_;
 695     my $query = access_cfg('archive-query','RETURN-UNDEF');
 696     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 697     my $proto = $1;
 698     my $data = $'; #';
 699     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 700 }
 701
 702 sub pool_dsc_subpath ($$) {
 703     my ($vsn,$component) = @_; # $package is implict arg
 704     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 705     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 706 }
 707
 708 #---------- `ftpmasterapi' archive query method (nascent) ----------
 709
 710 sub archive_api_query_cmd ($) {
 711     my ($subpath) = @_;
 712     my @cmd = qw(curl -sS);
 713     my $url = access_cfg('archive-query-url');
 714     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 715         my $host = $1;
 716         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 717         foreach my $key (split /\:/, $keys) {
 718             $key =~ s/\%HOST\%/$host/g;
 719             if (!stat $key) {
 720                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 721                 next;
 722             }
 723             fail "config requested specific TLS key but do not know".
 724                 " how to get curl to use exactly that EE key ($key)";
 725 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 726 #           # Sadly the above line does not work because of changes
 727 #           # to gnutls.   The real fix for #790093 may involve
 728 #           # new curl options.
 729             last;
 730         }
 731         # Fixing #790093 properly will involve providing a value
 732         # for this on clients.
 733         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 734         push @cmd, split / /, $kargs if defined $kargs;
 735     }
 736     push @cmd, $url.$subpath;
 737     return @cmd;
 738 }
 739
 740 sub api_query ($$) {
 741     use JSON;
 742     my ($data, $subpath) = @_;
 743     badcfg "ftpmasterapi archive query method takes no data part"
 744         if length $data;
 745     my @cmd = archive_api_query_cmd($subpath);
 746     my $json = cmdoutput @cmd;
 747     return decode_json($json);
 748 }
 749
 750 sub canonicalise_suite_ftpmasterapi () {
 751     my ($proto,$data) = @_;
 752     my $suites = api_query($data, 'suites');
 753     my @matched;
 754     foreach my $entry (@$suites) {
 755         next unless grep {
 756             my $v = $entry->{$_};
 757             defined $v && $v eq $isuite;
 758         } qw(codename name);
 759         push @matched, $entry;
 760     }
 761     fail "unknown suite $isuite" unless @matched;
 762     my $cn;
 763     eval {
 764         @matched==1 or die "multiple matches for suite $isuite\n";
 765         $cn = "$matched[0]{codename}";
 766         defined $cn or die "suite $isuite info has no codename\n";
 767         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 768     };
 769     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 770         if length $@;
 771     return $cn;
 772 }
 773
 774 sub archive_query_ftpmasterapi () {
 775     my ($proto,$data) = @_;
 776     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 777     my @rows;
 778     my $digester = Digest::SHA->new(256);
 779     foreach my $entry (@$info) {
 780         eval {
 781             my $vsn = "$entry->{version}";
 782             my ($ok,$msg) = version_check $vsn;
 783             die "bad version: $msg\n" unless $ok;
 784             my $component = "$entry->{component}";
 785             $component =~ m/^$component_re$/ or die "bad component";
 786             my $filename = "$entry->{filename}";
 787             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 788                 or die "bad filename";
 789             my $sha256sum = "$entry->{sha256sum}";
 790             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 791             push @rows, [ $vsn, "/pool/$component/$filename",
 792                           $digester, $sha256sum ];
 793         };
 794         die "bad ftpmaster api response: $@\n".Dumper($entry)
 795             if length $@;
 796     }
 797     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 798     return @rows;
 799 }
 800
 801 #---------- `madison' archive query method ----------
 802
 803 sub archive_query_madison {
 804     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 805 }
 806
 807 sub madison_get_parse {
 808     my ($proto,$data) = @_;
 809     die unless $proto eq 'madison';
 810     if (!length $data) {
 811         $data= access_cfg('madison-distro','RETURN-UNDEF');
 812         $data //= access_basedistro();
 813     }
 814     $rmad{$proto,$data,$package} ||= cmdoutput
 815         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 816     my $rmad = $rmad{$proto,$data,$package};
 817
 818     my @out;
 819     foreach my $l (split /\n/, $rmad) {
 820         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 821                   \s*( [^ \t|]+ )\s* \|
 822                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 823                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 824         $1 eq $package or die "$rmad $package ?";
 825         my $vsn = $2;
 826         my $newsuite = $3;
 827         my $component;
 828         if (defined $4) {
 829             $component = $4;
 830         } else {
 831             $component = access_cfg('archive-query-default-component');
 832         }
 833         $5 eq 'source' or die "$rmad ?";
 834         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 835     }
 836     return sort { -version_compare($a->[0],$b->[0]); } @out;
 837 }
 838
 839 sub canonicalise_suite_madison {
 840     # madison canonicalises for us
 841     my @r = madison_get_parse(@_);
 842     @r or fail
 843         "unable to canonicalise suite using package $package".
 844         " which does not appear to exist in suite $isuite;".
 845         " --existing-package may help";
 846     return $r[0][2];
 847 }
 848
 849 #---------- `sshpsql' archive query method ----------
 850
 851 sub sshpsql ($$$) {
 852     my ($data,$runeinfo,$sql) = @_;
 853     if (!length $data) {
 854         $data= access_someuserhost('sshpsql').':'.
 855             access_cfg('sshpsql-dbname');
 856     }
 857     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 858     my ($userhost,$dbname) = ($`,$'); #';
 859     my @rows;
 860     my @cmd = (access_cfg_ssh, $userhost,
 861                access_runeinfo("ssh-psql $runeinfo").
 862                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 863                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 864     debugcmd "|",@cmd;
 865     open P, "-|", @cmd or die $!;
 866     while (<P>) {
 867         chomp or die;
 868         printdebug("$debugprefix>|$_|\n");
 869         push @rows, $_;
 870     }
 871     $!=0; $?=0; close P or failedcmd @cmd;
 872     @rows or die;
 873     my $nrows = pop @rows;
 874     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
 875     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
 876     @rows = map { [ split /\|/, $_ ] } @rows;
 877     my $ncols = scalar @{ shift @rows };
 878     die if grep { scalar @$_ != $ncols } @rows;
 879     return @rows;
 880 }
 881
 882 sub sql_injection_check {
 883     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
 884 }
 885
 886 sub archive_query_sshpsql ($$) {
 887     my ($proto,$data) = @_;
 888     sql_injection_check $isuite, $package;
 889     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
 890         SELECT source.version, component.name, files.filename, files.sha256sum
 891           FROM source
 892           JOIN src_associations ON source.id = src_associations.source
 893           JOIN suite ON suite.id = src_associations.suite
 894           JOIN dsc_files ON dsc_files.source = source.id
 895           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
 896           JOIN component ON component.id = files_archive_map.component_id
 897           JOIN files ON files.id = dsc_files.file
 898          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
 899            AND source.source='$package'
 900            AND files.filename LIKE '%.dsc';
 901 END
 902     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 903     my $digester = Digest::SHA->new(256);
 904     @rows = map {
 905         my ($vsn,$component,$filename,$sha256sum) = @$_;
 906         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
 907     } @rows;
 908     return @rows;
 909 }
 910
 911 sub canonicalise_suite_sshpsql ($$) {
 912     my ($proto,$data) = @_;
 913     sql_injection_check $isuite;
 914     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
 915         SELECT suite.codename
 916           FROM suite where suite_name='$isuite' or codename='$isuite';
 917 END
 918     @rows = map { $_->[0] } @rows;
 919     fail "unknown suite $isuite" unless @rows;
 920     die "ambiguous $isuite: @rows ?" if @rows>1;
 921     return $rows[0];
 922 }
 923
 924 #---------- `dummycat' archive query method ----------
 925
 926 sub canonicalise_suite_dummycat ($$) {
 927     my ($proto,$data) = @_;
 928     my $dpath = "$data/suite.$isuite";
 929     if (!open C, "<", $dpath) {
 930         $!==ENOENT or die "$dpath: $!";
 931         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
 932         return $isuite;
 933     }
 934     $!=0; $_ = <C>;
 935     chomp or die "$dpath: $!";
 936     close C;
 937     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
 938     return $_;
 939 }
 940
 941 sub archive_query_dummycat ($$) {
 942     my ($proto,$data) = @_;
 943     canonicalise_suite();
 944     my $dpath = "$data/package.$csuite.$package";
 945     if (!open C, "<", $dpath) {
 946         $!==ENOENT or die "$dpath: $!";
 947         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
 948         return ();
 949     }
 950     my @rows;
 951     while (<C>) {
 952         next if m/^\#/;
 953         next unless m/\S/;
 954         die unless chomp;
 955         printdebug "dummycat query $csuite $package $dpath | $_\n";
 956         my @row = split /\s+/, $_;
 957         @row==2 or die "$dpath: $_ ?";
 958         push @rows, \@row;
 959     }
 960     C->error and die "$dpath: $!";
 961     close C;
 962     return sort { -version_compare($a->[0],$b->[0]); } @rows;
 963 }
 964
 965 #---------- archive query entrypoints and rest of program ----------
 966
 967 sub canonicalise_suite () {
 968     return if defined $csuite;
 969     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
 970     $csuite = archive_query('canonicalise_suite');
 971     if ($isuite ne $csuite) {
 972         progress "canonical suite name for $isuite is $csuite";
 973     }
 974 }
 975
 976 sub get_archive_dsc () {
 977     canonicalise_suite();
 978     my @vsns = archive_query('archive_query');
 979     foreach my $vinfo (@vsns) {
 980         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
 981         $dscurl = access_cfg('mirror').$subpath;
 982         $dscdata = url_get($dscurl);
 983         if (!$dscdata) {
 984             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
 985             next;
 986         }
 987         if ($digester) {
 988             $digester->reset();
 989             $digester->add($dscdata);
 990             my $got = $digester->hexdigest();
 991             $got eq $digest or
 992                 fail "$dscurl has hash $got but".
 993                     " archive told us to expect $digest";
 994         }
 995         my $dscfh = new IO::File \$dscdata, '<' or die $!;
 996         printdebug Dumper($dscdata) if $debuglevel>1;
 997         $dsc = parsecontrolfh($dscfh,$dscurl,1);
 998         printdebug Dumper($dsc) if $debuglevel>1;
 999         my $fmt = getfield $dsc, 'Format';
1000         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1001         $dsc_checked = !!$digester;
1002         return;
1003     }
1004     $dsc = undef;
1005 }
1006
1007 sub check_for_git ();
1008 sub check_for_git () {
1009     # returns 0 or 1
1010     my $how = access_cfg('git-check');
1011     if ($how eq 'ssh-cmd') {
1012         my @cmd =
1013             (access_cfg_ssh, access_gituserhost(),
1014              access_runeinfo("git-check $package").
1015              " set -e; cd ".access_cfg('git-path').";".
1016              " if test -d $package.git; then echo 1; else echo 0; fi");
1017         my $r= cmdoutput @cmd;
1018         if ($r =~ m/^divert (\w+)$/) {
1019             my $divert=$1;
1020             my ($usedistro,) = access_distros();
1021             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1022             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1023             printdebug "diverting $divert so using distro $instead_distro\n";
1024             return check_for_git();
1025         }
1026         failedcmd @cmd unless $r =~ m/^[01]$/;
1027         return $r+0;
1028     } elsif ($how eq 'true') {
1029         return 1;
1030     } elsif ($how eq 'false') {
1031         return 0;
1032     } else {
1033         badcfg "unknown git-check \`$how'";
1034     }
1035 }
1036
1037 sub create_remote_git_repo () {
1038     my $how = access_cfg('git-create');
1039     if ($how eq 'ssh-cmd') {
1040         runcmd_ordryrun
1041             (access_cfg_ssh, access_gituserhost(),
1042              access_runeinfo("git-create $package").
1043              "set -e; cd ".access_cfg('git-path').";".
1044              " cp -a _template $package.git");
1045     } elsif ($how eq 'true') {
1046         # nothing to do
1047     } else {
1048         badcfg "unknown git-create \`$how'";
1049     }
1050 }
1051
1052 our ($dsc_hash,$lastpush_hash);
1053
1054 our $ud = '.git/dgit/unpack';
1055
1056 sub prep_ud () {
1057     rmtree($ud);
1058     mkpath '.git/dgit';
1059     mkdir $ud or die $!;
1060 }
1061
1062 sub mktree_in_ud_here () {
1063     runcmd qw(git init -q);
1064     rmtree('.git/objects');
1065     symlink '../../../../objects','.git/objects' or die $!;
1066 }
1067
1068 sub git_write_tree () {
1069     my $tree = cmdoutput @git, qw(write-tree);
1070     $tree =~ m/^\w+$/ or die "$tree ?";
1071     return $tree;
1072 }
1073
1074 sub mktree_in_ud_from_only_subdir () {
1075     # changes into the subdir
1076     my (@dirs) = <*/.>;
1077     die unless @dirs==1;
1078     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1079     my $dir = $1;
1080     changedir $dir;
1081     fail "source package contains .git directory" if stat_exists '.git';
1082     mktree_in_ud_here();
1083     my $format=get_source_format();
1084     if (madformat($format)) {
1085         rmtree '.pc';
1086     }
1087     runcmd @git, qw(add -Af);
1088     my $tree=git_write_tree();
1089     return ($tree,$dir);
1090 }
1091
1092 sub dsc_files_info () {
1093     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1094                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1095                        ['Files',           'Digest::MD5', 'new()']) {
1096         my ($fname, $module, $method) = @$csumi;
1097         my $field = $dsc->{$fname};
1098         next unless defined $field;
1099         eval "use $module; 1;" or die $@;
1100         my @out;
1101         foreach (split /\n/, $field) {
1102             next unless m/\S/;
1103             m/^(\w+) (\d+) (\S+)$/ or
1104                 fail "could not parse .dsc $fname line \`$_'";
1105             my $digester = eval "$module"."->$method;" or die $@;
1106             push @out, {
1107                 Hash => $1,
1108                 Bytes => $2,
1109                 Filename => $3,
1110                 Digester => $digester,
1111             };
1112         }
1113         return @out;
1114     }
1115     fail "missing any supported Checksums-* or Files field in ".
1116         $dsc->get_option('name');
1117 }
1118
1119 sub dsc_files () {
1120     map { $_->{Filename} } dsc_files_info();
1121 }
1122
1123 sub is_orig_file ($;$) {
1124     local ($_) = $_[0];
1125     my $base = $_[1];
1126     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1127     defined $base or return 1;
1128     return $` eq $base;
1129 }
1130
1131 sub make_commit ($) {
1132     my ($file) = @_;
1133     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1134 }
1135
1136 sub clogp_authline ($) {
1137     my ($clogp) = @_;
1138     my $author = getfield $clogp, 'Maintainer';
1139     $author =~ s#,.*##ms;
1140     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1141     my $authline = "$author $date";
1142     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1143         fail "unexpected commit author line format \`$authline'".
1144         " (was generated from changelog Maintainer field)";
1145     return $authline;
1146 }
1147
1148 sub generate_commit_from_dsc () {
1149     prep_ud();
1150     changedir $ud;
1151
1152     foreach my $fi (dsc_files_info()) {
1153         my $f = $fi->{Filename};
1154         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1155
1156         link "../../../$f", $f
1157             or $!==&ENOENT
1158             or die "$f $!";
1159
1160         complete_file_from_dsc('.', $fi);
1161
1162         if (is_orig_file($f)) {
1163             link $f, "../../../../$f"
1164                 or $!==&EEXIST
1165                 or die "$f $!";
1166         }
1167     }
1168
1169     my $dscfn = "$package.dsc";
1170
1171     open D, ">", $dscfn or die "$dscfn: $!";
1172     print D $dscdata or die "$dscfn: $!";
1173     close D or die "$dscfn: $!";
1174     my @cmd = qw(dpkg-source);
1175     push @cmd, '--no-check' if $dsc_checked;
1176     push @cmd, qw(-x --), $dscfn;
1177     runcmd @cmd;
1178
1179     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1180     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1181     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1182     my $authline = clogp_authline $clogp;
1183     my $changes = getfield $clogp, 'Changes';
1184     open C, ">../commit.tmp" or die $!;
1185     print C <<END or die $!;
1186 tree $tree
1187 author $authline
1188 committer $authline
1189
1190 $changes
1191
1192 # imported from the archive
1193 END
1194     close C or die $!;
1195     my $outputhash = make_commit qw(../commit.tmp);
1196     my $cversion = getfield $clogp, 'Version';
1197     progress "synthesised git commit from .dsc $cversion";
1198     if ($lastpush_hash) {
1199         runcmd @git, qw(reset --hard), $lastpush_hash;
1200         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1201         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1202         my $oversion = getfield $oldclogp, 'Version';
1203         my $vcmp =
1204             version_compare($oversion, $cversion);
1205         if ($vcmp < 0) {
1206             # git upload/ is earlier vsn than archive, use archive
1207             open C, ">../commit2.tmp" or die $!;
1208             print C <<END or die $!;
1209 tree $tree
1210 parent $lastpush_hash
1211 parent $outputhash
1212 author $authline
1213 committer $authline
1214
1215 Record $package ($cversion) in archive suite $csuite
1216 END
1217             $outputhash = make_commit qw(../commit2.tmp);
1218         } elsif ($vcmp > 0) {
1219             print STDERR <<END or die $!;
1220
1221 Version actually in archive:    $cversion (older)
1222 Last allegedly pushed/uploaded: $oversion (newer or same)
1223 $later_warning_msg
1224 END
1225             $outputhash = $lastpush_hash;
1226         } else {
1227             $outputhash = $lastpush_hash;
1228         }
1229     }
1230     changedir '../../../..';
1231     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1232             'DGIT_ARCHIVE', $outputhash;
1233     cmdoutput @git, qw(log -n2), $outputhash;
1234     # ... gives git a chance to complain if our commit is malformed
1235     rmtree($ud);
1236     return $outputhash;
1237 }
1238
1239 sub complete_file_from_dsc ($$) {
1240     our ($dstdir, $fi) = @_;
1241     # Ensures that we have, in $dir, the file $fi, with the correct
1242     # contents.  (Downloading it from alongside $dscurl if necessary.)
1243
1244     my $f = $fi->{Filename};
1245     my $tf = "$dstdir/$f";
1246     my $downloaded = 0;
1247
1248     if (stat_exists $tf) {
1249         progress "using existing $f";
1250     } else {
1251         my $furl = $dscurl;
1252         $furl =~ s{/[^/]+$}{};
1253         $furl .= "/$f";
1254         die "$f ?" unless $f =~ m/^${package}_/;
1255         die "$f ?" if $f =~ m#/#;
1256         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1257         next if !act_local();
1258         $downloaded = 1;
1259     }
1260
1261     open F, "<", "$tf" or die "$tf: $!";
1262     $fi->{Digester}->reset();
1263     $fi->{Digester}->addfile(*F);
1264     F->error and die $!;
1265     my $got = $fi->{Digester}->hexdigest();
1266     $got eq $fi->{Hash} or
1267         fail "file $f has hash $got but .dsc".
1268             " demands hash $fi->{Hash} ".
1269             ($downloaded ? "(got wrong file from archive!)"
1270              : "(perhaps you should delete this file?)");
1271 }
1272
1273 sub ensure_we_have_orig () {
1274     foreach my $fi (dsc_files_info()) {
1275         my $f = $fi->{Filename};
1276         next unless is_orig_file($f);
1277         complete_file_from_dsc('..', $fi);
1278     }
1279 }
1280
1281 sub git_fetch_us () {
1282     runcmd_ordryrun_local @git, qw(fetch),access_giturl(),fetchspec();
1283     if (deliberately_not_fast_forward) {
1284         runcmd_ordryrun_local @git, qw(fetch -p), access_giturl(),
1285             map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1286             qw(tags heads);
1287     }
1288 }
1289
1290 sub fetch_from_archive () {
1291     # ensures that lrref() is what is actually in the archive,
1292     #  one way or another
1293     get_archive_dsc();
1294
1295     if ($dsc) {
1296         foreach my $field (@ourdscfield) {
1297             $dsc_hash = $dsc->{$field};
1298             last if defined $dsc_hash;
1299         }
1300         if (defined $dsc_hash) {
1301             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1302             $dsc_hash = $&;
1303             progress "last upload to archive specified git hash";
1304         } else {
1305             progress "last upload to archive has NO git hash";
1306         }
1307     } else {
1308         progress "no version available from the archive";
1309     }
1310
1311     $lastpush_hash = git_get_ref(lrref());
1312     printdebug "previous reference hash=$lastpush_hash\n";
1313     my $hash;
1314     if (defined $dsc_hash) {
1315         fail "missing remote git history even though dsc has hash -".
1316             " could not find ref ".lrref().
1317             " (should have been fetched from ".access_giturl()."#".rrref().")"
1318             unless $lastpush_hash;
1319         $hash = $dsc_hash;
1320         ensure_we_have_orig();
1321         if ($dsc_hash eq $lastpush_hash) {
1322         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1323             print STDERR <<END or die $!;
1324
1325 Git commit in archive is behind the last version allegedly pushed/uploaded.
1326 Commit referred to by archive:  $dsc_hash
1327 Last allegedly pushed/uploaded: $lastpush_hash
1328 $later_warning_msg
1329 END
1330             $hash = $lastpush_hash;
1331         } else {
1332             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1333                 "descendant of archive's .dsc hash ($dsc_hash)";
1334         }
1335     } elsif ($dsc) {
1336         $hash = generate_commit_from_dsc();
1337     } elsif ($lastpush_hash) {
1338         # only in git, not in the archive yet
1339         $hash = $lastpush_hash;
1340         print STDERR <<END or die $!;
1341
1342 Package not found in the archive, but has allegedly been pushed using dgit.
1343 $later_warning_msg
1344 END
1345     } else {
1346         printdebug "nothing found!\n";
1347         if (defined $skew_warning_vsn) {
1348             print STDERR <<END or die $!;
1349
1350 Warning: relevant archive skew detected.
1351 Archive allegedly contains $skew_warning_vsn
1352 But we were not able to obtain any version from the archive or git.
1353
1354 END
1355         }
1356         return 0;
1357     }
1358     printdebug "current hash=$hash\n";
1359     if ($lastpush_hash) {
1360         fail "not fast forward on last upload branch!".
1361             " (archive's version left in DGIT_ARCHIVE)"
1362             unless is_fast_fwd($lastpush_hash, $hash);
1363     }
1364     if (defined $skew_warning_vsn) {
1365         mkpath '.git/dgit';
1366         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1367         my $clogf = ".git/dgit/changelog.tmp";
1368         runcmd shell_cmd "exec >$clogf",
1369             @git, qw(cat-file blob), "$hash:debian/changelog";
1370         my $gotclogp = parsechangelog("-l$clogf");
1371         my $got_vsn = getfield $gotclogp, 'Version';
1372         printdebug "SKEW CHECK GOT $got_vsn\n";
1373         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1374             print STDERR <<END or die $!;
1375
1376 Warning: archive skew detected.  Using the available version:
1377 Archive allegedly contains    $skew_warning_vsn
1378 We were able to obtain only   $got_vsn
1379
1380 END
1381         }
1382     }
1383     if ($lastpush_hash ne $hash) {
1384         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1385         if (act_local()) {
1386             cmdoutput @upd_cmd;
1387         } else {
1388             dryrun_report @upd_cmd;
1389         }
1390     }
1391     return 1;
1392 }
1393
1394 sub clone ($) {
1395     my ($dstdir) = @_;
1396     canonicalise_suite();
1397     badusage "dry run makes no sense with clone" unless act_local();
1398     my $hasgit = check_for_git();
1399     mkdir $dstdir or die "$dstdir $!";
1400     changedir $dstdir;
1401     runcmd @git, qw(init -q);
1402     my $giturl = access_giturl(1);
1403     if (defined $giturl) {
1404         runcmd @git, qw(config), "remote.$remotename.fetch", fetchspec();
1405         open H, "> .git/HEAD" or die $!;
1406         print H "ref: ".lref()."\n" or die $!;
1407         close H or die $!;
1408         runcmd @git, qw(remote add), 'origin', $giturl;
1409     }
1410     if ($hasgit) {
1411         progress "fetching existing git history";
1412         git_fetch_us();
1413         runcmd_ordryrun_local @git, qw(fetch origin);
1414     } else {
1415         progress "starting new git history";
1416     }
1417     fetch_from_archive() or no_such_package;
1418     my $vcsgiturl = $dsc->{'Vcs-Git'};
1419     if (length $vcsgiturl) {
1420         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1421         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1422     }
1423     runcmd @git, qw(reset --hard), lrref();
1424     printdone "ready for work in $dstdir";
1425 }
1426
1427 sub fetch () {
1428     if (check_for_git()) {
1429         git_fetch_us();
1430     }
1431     fetch_from_archive() or no_such_package();
1432     printdone "fetched into ".lrref();
1433 }
1434
1435 sub pull () {
1436     fetch();
1437     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1438         lrref();
1439     printdone "fetched to ".lrref()." and merged into HEAD";
1440 }
1441
1442 sub check_not_dirty () {
1443     return if $ignoredirty;
1444     my @cmd = (@git, qw(diff --quiet HEAD));
1445     debugcmd "+",@cmd;
1446     $!=0; $?=0; system @cmd;
1447     return if !$! && !$?;
1448     if (!$! && $?==256) {
1449         fail "working tree is dirty (does not match HEAD)";
1450     } else {
1451         failedcmd @cmd;
1452     }
1453 }
1454
1455 sub commit_admin ($) {
1456     my ($m) = @_;
1457     progress "$m";
1458     runcmd_ordryrun_local @git, qw(commit -m), $m;
1459 }
1460
1461 sub commit_quilty_patch () {
1462     my $output = cmdoutput @git, qw(status --porcelain);
1463     my %adds;
1464     foreach my $l (split /\n/, $output) {
1465         next unless $l =~ m/\S/;
1466         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1467             $adds{$1}++;
1468         }
1469     }
1470     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1471     if (!%adds) {
1472         progress "nothing quilty to commit, ok.";
1473         return;
1474     }
1475     runcmd_ordryrun_local @git, qw(add), sort keys %adds;
1476     commit_admin "Commit Debian 3.0 (quilt) metadata";
1477 }
1478
1479 sub get_source_format () {
1480     if (!open F, "debian/source/format") {
1481         die $! unless $!==&ENOENT;
1482         return '';
1483     }
1484     $_ = <F>;
1485     F->error and die $!;
1486     chomp;
1487     return $_;
1488 }
1489
1490 sub madformat ($) {
1491     my ($format) = @_;
1492     return 0 unless $format eq '3.0 (quilt)';
1493     if ($quilt_mode eq 'nocheck') {
1494         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1495         return 0;
1496     }
1497     progress "Format \`$format', checking/updating patch stack";
1498     return 1;
1499 }
1500
1501 sub push_parse_changelog ($) {
1502     my ($clogpfn) = @_;
1503
1504     my $clogp = Dpkg::Control::Hash->new();
1505     $clogp->load($clogpfn) or die;
1506
1507     $package = getfield $clogp, 'Source';
1508     my $cversion = getfield $clogp, 'Version';
1509     my $tag = debiantag($cversion);
1510     runcmd @git, qw(check-ref-format), $tag;
1511
1512     my $dscfn = dscfn($cversion);
1513
1514     return ($clogp, $cversion, $tag, $dscfn);
1515 }
1516
1517 sub push_parse_dsc ($$$) {
1518     my ($dscfn,$dscfnwhat, $cversion) = @_;
1519     $dsc = parsecontrol($dscfn,$dscfnwhat);
1520     my $dversion = getfield $dsc, 'Version';
1521     my $dscpackage = getfield $dsc, 'Source';
1522     ($dscpackage eq $package && $dversion eq $cversion) or
1523         fail "$dscfn is for $dscpackage $dversion".
1524             " but debian/changelog is for $package $cversion";
1525 }
1526
1527 sub push_mktag ($$$$$$$) {
1528     my ($head,$clogp,$tag,
1529         $dscfn,
1530         $changesfile,$changesfilewhat,
1531         $tfn) = @_;
1532
1533     $dsc->{$ourdscfield[0]} = $head;
1534     $dsc->save("$dscfn.tmp") or die $!;
1535
1536     my $changes = parsecontrol($changesfile,$changesfilewhat);
1537     foreach my $field (qw(Source Distribution Version)) {
1538         $changes->{$field} eq $clogp->{$field} or
1539             fail "changes field $field \`$changes->{$field}'".
1540                 " does not match changelog \`$clogp->{$field}'";
1541     }
1542
1543     my $cversion = getfield $clogp, 'Version';
1544     my $clogsuite = getfield $clogp, 'Distribution';
1545
1546     # We make the git tag by hand because (a) that makes it easier
1547     # to control the "tagger" (b) we can do remote signing
1548     my $authline = clogp_authline $clogp;
1549     my $delibs = join(" ", "",@deliberatelies);
1550     my $declaredistro = access_basedistro();
1551     open TO, '>', $tfn->('.tmp') or die $!;
1552     print TO <<END or die $!;
1553 object $head
1554 type commit
1555 tag $tag
1556 tagger $authline
1557
1558 $package release $cversion for $clogsuite ($csuite) [dgit]
1559 [dgit distro=$declaredistro$delibs]
1560 END
1561     foreach my $ref (sort keys %previously) {
1562                     print TO <<END or die $!;
1563 [dgit previously:$ref=$previously{$ref}]
1564 END
1565     }
1566
1567     close TO or die $!;
1568
1569     my $tagobjfn = $tfn->('.tmp');
1570     if ($sign) {
1571         if (!defined $keyid) {
1572             $keyid = access_cfg('keyid','RETURN-UNDEF');
1573         }
1574         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1575         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1576         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1577         push @sign_cmd, $tfn->('.tmp');
1578         runcmd_ordryrun @sign_cmd;
1579         if (act_scary()) {
1580             $tagobjfn = $tfn->('.signed.tmp');
1581             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1582                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1583         }
1584     }
1585
1586     return ($tagobjfn);
1587 }
1588
1589 sub sign_changes ($) {
1590     my ($changesfile) = @_;
1591     if ($sign) {
1592         my @debsign_cmd = @debsign;
1593         push @debsign_cmd, "-k$keyid" if defined $keyid;
1594         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1595         push @debsign_cmd, $changesfile;
1596         runcmd_ordryrun @debsign_cmd;
1597     }
1598 }
1599
1600 sub dopush ($) {
1601     my ($forceflag) = @_;
1602     printdebug "actually entering push\n";
1603     prep_ud();
1604
1605     access_giturl(); # check that success is vaguely likely
1606
1607     my $clogpfn = ".git/dgit/changelog.822.tmp";
1608     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1609
1610     responder_send_file('parsed-changelog', $clogpfn);
1611
1612     my ($clogp, $cversion, $tag, $dscfn) =
1613         push_parse_changelog("$clogpfn");
1614
1615     my $dscpath = "$buildproductsdir/$dscfn";
1616     stat_exists $dscpath or
1617         fail "looked for .dsc $dscfn, but $!;".
1618             " maybe you forgot to build";
1619
1620     responder_send_file('dsc', $dscpath);
1621
1622     push_parse_dsc($dscpath, $dscfn, $cversion);
1623
1624     my $format = getfield $dsc, 'Format';
1625     printdebug "format $format\n";
1626     if (madformat($format)) {
1627         commit_quilty_patch();
1628     }
1629     check_not_dirty();
1630     changedir $ud;
1631     progress "checking that $dscfn corresponds to HEAD";
1632     runcmd qw(dpkg-source -x --),
1633         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1634     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1635     changedir '../../../..';
1636     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1637     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1638     debugcmd "+",@diffcmd;
1639     $!=0; $?=0;
1640     my $r = system @diffcmd;
1641     if ($r) {
1642         if ($r==256) {
1643             fail "$dscfn specifies a different tree to your HEAD commit;".
1644                 " perhaps you forgot to build".
1645                 ($diffopt eq '--exit-code' ? "" :
1646                  " (run with -D to see full diff output)");
1647         } else {
1648             failedcmd @diffcmd;
1649         }
1650     }
1651 #fetch from alioth
1652 #do fast forward check and maybe fake merge
1653 #    if (!is_fast_fwd(mainbranch
1654 #    runcmd @git, qw(fetch -p ), "$alioth_git/$package.git",
1655 #        map { lref($_).":".rref($_) }
1656 #        (uploadbranch());
1657     my $head = git_rev_parse('HEAD');
1658     if (!$changesfile) {
1659         my $multi = "$buildproductsdir/".
1660             "${package}_".(stripepoch $cversion)."_multi.changes";
1661         if (stat_exists "$multi") {
1662             $changesfile = $multi;
1663         } else {
1664             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1665             my @cs = glob "$buildproductsdir/$pat";
1666             fail "failed to find unique changes file".
1667                 " (looked for $pat in $buildproductsdir, or $multi);".
1668                 " perhaps you need to use dgit -C"
1669                 unless @cs==1;
1670             ($changesfile) = @cs;
1671         }
1672     } else {
1673         $changesfile = "$buildproductsdir/$changesfile";
1674     }
1675
1676     responder_send_file('changes',$changesfile);
1677     responder_send_command("param head $head");
1678     responder_send_command("param csuite $csuite");
1679
1680     if (deliberately_not_fast_forward) {
1681         git_for_each_ref(lrfetchrefs, sub {
1682             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
1683             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
1684             responder_send_command("previously $rrefname=$objid");
1685             $previously{$rrefname} = $objid;
1686         });
1687     }
1688
1689     my $tfn = sub { ".git/dgit/tag$_[0]"; };
1690     my $tagobjfn;
1691
1692     if ($we_are_responder) {
1693         $tagobjfn = $tfn->('.signed.tmp');
1694         responder_receive_files('signed-tag', $tagobjfn);
1695     } else {
1696         $tagobjfn =
1697             push_mktag($head,$clogp,$tag,
1698                        $dscpath,
1699                        $changesfile,$changesfile,
1700                        $tfn);
1701     }
1702
1703     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
1704     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
1705     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
1706     runcmd_ordryrun @git, qw(tag -v --), $tag;
1707
1708     if (!check_for_git()) {
1709         create_remote_git_repo();
1710     }
1711     runcmd_ordryrun @git, qw(push),access_giturl(),
1712         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
1713     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
1714
1715     if ($we_are_responder) {
1716         my $dryrunsuffix = act_local() ? "" : ".tmp";
1717         responder_receive_files('signed-dsc-changes',
1718                                 "$dscpath$dryrunsuffix",
1719                                 "$changesfile$dryrunsuffix");
1720     } else {
1721         if (act_local()) {
1722             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
1723         } else {
1724             progress "[new .dsc left in $dscpath.tmp]";
1725         }
1726         sign_changes $changesfile;
1727     }
1728
1729     my $host = access_cfg('upload-host','RETURN-UNDEF');
1730     my @hostarg = defined($host) ? ($host,) : ();
1731     runcmd_ordryrun @dput, @hostarg, $changesfile;
1732     printdone "pushed and uploaded $cversion";
1733
1734     responder_send_command("complete");
1735 }
1736
1737 sub cmd_clone {
1738     parseopts();
1739     my $dstdir;
1740     badusage "-p is not allowed with clone; specify as argument instead"
1741         if defined $package;
1742     if (@ARGV==1) {
1743         ($package) = @ARGV;
1744     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
1745         ($package,$isuite) = @ARGV;
1746     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
1747         ($package,$dstdir) = @ARGV;
1748     } elsif (@ARGV==3) {
1749         ($package,$isuite,$dstdir) = @ARGV;
1750     } else {
1751         badusage "incorrect arguments to dgit clone";
1752     }
1753     $dstdir ||= "$package";
1754
1755     if (stat_exists $dstdir) {
1756         fail "$dstdir already exists";
1757     }
1758
1759     my $cwd_remove;
1760     if ($rmonerror && !$dryrun_level) {
1761         $cwd_remove= getcwd();
1762         unshift @end, sub {
1763             return unless defined $cwd_remove;
1764             if (!chdir "$cwd_remove") {
1765                 return if $!==&ENOENT;
1766                 die "chdir $cwd_remove: $!";
1767             }
1768             rmtree($dstdir) or die "remove $dstdir: $!\n";
1769         };
1770     }
1771
1772     clone($dstdir);
1773     $cwd_remove = undef;
1774 }
1775
1776 sub branchsuite () {
1777     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
1778     if ($branch =~ m#$lbranch_re#o) {
1779         return $1;
1780     } else {
1781         return undef;
1782     }
1783 }
1784
1785 sub fetchpullargs () {
1786     if (!defined $package) {
1787         my $sourcep = parsecontrol('debian/control','debian/control');
1788         $package = getfield $sourcep, 'Source';
1789     }
1790     if (@ARGV==0) {
1791 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
1792         if (!$isuite) {
1793             my $clogp = parsechangelog();
1794             $isuite = getfield $clogp, 'Distribution';
1795         }
1796         canonicalise_suite();
1797         progress "fetching from suite $csuite";
1798     } elsif (@ARGV==1) {
1799         ($isuite) = @ARGV;
1800         canonicalise_suite();
1801     } else {
1802         badusage "incorrect arguments to dgit fetch or dgit pull";
1803     }
1804 }
1805
1806 sub cmd_fetch {
1807     parseopts();
1808     fetchpullargs();
1809     fetch();
1810 }
1811
1812 sub cmd_pull {
1813     parseopts();
1814     fetchpullargs();
1815     pull();
1816 }
1817
1818 sub cmd_push {
1819     parseopts();
1820     badusage "-p is not allowed with dgit push" if defined $package;
1821     check_not_dirty();
1822     my $clogp = parsechangelog();
1823     $package = getfield $clogp, 'Source';
1824     my $specsuite;
1825     if (@ARGV==0) {
1826     } elsif (@ARGV==1) {
1827         ($specsuite) = (@ARGV);
1828     } else {
1829         badusage "incorrect arguments to dgit push";
1830     }
1831     $isuite = getfield $clogp, 'Distribution';
1832     if ($new_package) {
1833         local ($package) = $existing_package; # this is a hack
1834         canonicalise_suite();
1835     }
1836     if (defined $specsuite && $specsuite ne $isuite) {
1837         canonicalise_suite();
1838         $csuite eq $specsuite or
1839             fail "dgit push: changelog specifies $isuite ($csuite)".
1840                 " but command line specifies $specsuite";
1841     }
1842     if (check_for_git()) {
1843         git_fetch_us();
1844     }
1845     my $forceflag = '';
1846     if (fetch_from_archive()) {
1847         if (is_fast_fwd(lrref(), 'HEAD')) {
1848             # ok
1849         } elsif (deliberately_not_fast_forward) {
1850             $forceflag = '+';
1851         } else {
1852             fail "dgit push: HEAD is not a descendant".
1853                 " of the archive's version.\n".
1854                 "dgit: To overwrite its contents,".
1855                 " use git merge -s ours ".lrref().".\n".
1856                 "dgit: To rewind history, if permitted by the archive,".
1857                 " use --deliberately-not-fast-forward";
1858         }
1859     } else {
1860         $new_package or
1861             fail "package appears to be new in this suite;".
1862                 " if this is intentional, use --new";
1863     }
1864     dopush($forceflag);
1865 }
1866
1867 #---------- remote commands' implementation ----------
1868
1869 sub cmd_remote_push_build_host {
1870     my ($nrargs) = shift @ARGV;
1871     my (@rargs) = @ARGV[0..$nrargs-1];
1872     @ARGV = @ARGV[$nrargs..$#ARGV];
1873     die unless @rargs;
1874     my ($dir,$vsnwant) = @rargs;
1875     # vsnwant is a comma-separated list; we report which we have
1876     # chosen in our ready response (so other end can tell if they
1877     # offered several)
1878     $debugprefix = ' ';
1879     $we_are_responder = 1;
1880     $us .= " (build host)";
1881
1882     open PI, "<&STDIN" or die $!;
1883     open STDIN, "/dev/null" or die $!;
1884     open PO, ">&STDOUT" or die $!;
1885     autoflush PO 1;
1886     open STDOUT, ">&STDERR" or die $!;
1887     autoflush STDOUT 1;
1888
1889     $vsnwant //= 1;
1890     fail "build host has dgit rpush protocol version".
1891         " $rpushprotovsn but invocation host has $vsnwant"
1892         unless grep { $rpushprotovsn eq $_ } split /,/, $vsnwant;
1893
1894     responder_send_command("dgit-remote-push-ready $rpushprotovsn");
1895
1896     changedir $dir;
1897     &cmd_push;
1898 }
1899
1900 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
1901 # ... for compatibility with proto vsn.1 dgit (just so that user gets
1902 #     a good error message)
1903
1904 our $i_tmp;
1905
1906 sub i_cleanup {
1907     local ($@, $?);
1908     my $report = i_child_report();
1909     if (defined $report) {
1910         printdebug "($report)\n";
1911     } elsif ($i_child_pid) {
1912         printdebug "(killing build host child $i_child_pid)\n";
1913         kill 15, $i_child_pid;
1914     }
1915     if (defined $i_tmp && !defined $initiator_tempdir) {
1916         changedir "/";
1917         eval { rmtree $i_tmp; };
1918     }
1919 }
1920
1921 END { i_cleanup(); }
1922
1923 sub i_method {
1924     my ($base,$selector,@args) = @_;
1925     $selector =~ s/\-/_/g;
1926     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
1927 }
1928
1929 sub cmd_rpush {
1930     my $host = nextarg;
1931     my $dir;
1932     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
1933         $host = $1;
1934         $dir = $'; #';
1935     } else {
1936         $dir = nextarg;
1937     }
1938     $dir =~ s{^-}{./-};
1939     my @rargs = ($dir,$rpushprotovsn);
1940     my @rdgit;
1941     push @rdgit, @dgit;
1942     push @rdgit, @ropts;
1943     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
1944     push @rdgit, @ARGV;
1945     my @cmd = (@ssh, $host, shellquote @rdgit);
1946     debugcmd "+",@cmd;
1947
1948     if (defined $initiator_tempdir) {
1949         rmtree $initiator_tempdir;
1950         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
1951         $i_tmp = $initiator_tempdir;
1952     } else {
1953         $i_tmp = tempdir();
1954     }
1955     $i_child_pid = open2(\*RO, \*RI, @cmd);
1956     changedir $i_tmp;
1957     initiator_expect { m/^dgit-remote-push-ready/ };
1958     for (;;) {
1959         my ($icmd,$iargs) = initiator_expect {
1960             m/^(\S+)(?: (.*))?$/;
1961             ($1,$2);
1962         };
1963         i_method "i_resp", $icmd, $iargs;
1964     }
1965 }
1966
1967 sub i_resp_progress ($) {
1968     my ($rhs) = @_;
1969     my $msg = protocol_read_bytes \*RO, $rhs;
1970     progress $msg;
1971 }
1972
1973 sub i_resp_complete {
1974     my $pid = $i_child_pid;
1975     $i_child_pid = undef; # prevents killing some other process with same pid
1976     printdebug "waiting for build host child $pid...\n";
1977     my $got = waitpid $pid, 0;
1978     die $! unless $got == $pid;
1979     die "build host child failed $?" if $?;
1980
1981     i_cleanup();
1982     printdebug "all done\n";
1983     exit 0;
1984 }
1985
1986 sub i_resp_file ($) {
1987     my ($keyword) = @_;
1988     my $localname = i_method "i_localname", $keyword;
1989     my $localpath = "$i_tmp/$localname";
1990     stat_exists $localpath and
1991         badproto \*RO, "file $keyword ($localpath) twice";
1992     protocol_receive_file \*RO, $localpath;
1993     i_method "i_file", $keyword;
1994 }
1995
1996 our %i_param;
1997
1998 sub i_resp_param ($) {
1999     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2000     $i_param{$1} = $2;
2001 }
2002
2003 sub i_resp_previously ($) {
2004     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2005         or badproto \*RO, "bad previously spec";
2006     my $r = system qw(git check-ref-format), $1;
2007     die "bad previously ref spec ($r)" if $r;
2008     $previously{$1} = $2;
2009 }
2010
2011 our %i_wanted;
2012
2013 sub i_resp_want ($) {
2014     my ($keyword) = @_;
2015     die "$keyword ?" if $i_wanted{$keyword}++;
2016     my @localpaths = i_method "i_want", $keyword;
2017     printdebug "[[  $keyword @localpaths\n";
2018     foreach my $localpath (@localpaths) {
2019         protocol_send_file \*RI, $localpath;
2020     }
2021     print RI "files-end\n" or die $!;
2022 }
2023
2024 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2025
2026 sub i_localname_parsed_changelog {
2027     return "remote-changelog.822";
2028 }
2029 sub i_file_parsed_changelog {
2030     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2031         push_parse_changelog "$i_tmp/remote-changelog.822";
2032     die if $i_dscfn =~ m#/|^\W#;
2033 }
2034
2035 sub i_localname_dsc {
2036     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2037     return $i_dscfn;
2038 }
2039 sub i_file_dsc { }
2040
2041 sub i_localname_changes {
2042     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2043     $i_changesfn = $i_dscfn;
2044     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2045     return $i_changesfn;
2046 }
2047 sub i_file_changes { }
2048
2049 sub i_want_signed_tag {
2050     printdebug Dumper(\%i_param, $i_dscfn);
2051     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2052         && defined $i_param{'csuite'}
2053         or badproto \*RO, "premature desire for signed-tag";
2054     my $head = $i_param{'head'};
2055     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2056
2057     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2058     $csuite = $&;
2059     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2060
2061     my $tagobjfn =
2062         push_mktag $head, $i_clogp, $i_tag,
2063             $i_dscfn,
2064             $i_changesfn, 'remote changes',
2065             sub { "tag$_[0]"; };
2066
2067     return $tagobjfn;
2068 }
2069
2070 sub i_want_signed_dsc_changes {
2071     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2072     sign_changes $i_changesfn;
2073     return ($i_dscfn, $i_changesfn);
2074 }
2075
2076 #---------- building etc. ----------
2077
2078 our $version;
2079 our $sourcechanges;
2080 our $dscfn;
2081
2082 #----- `3.0 (quilt)' handling -----
2083
2084 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2085
2086 sub quiltify_dpkg_commit ($$$;$) {
2087     my ($patchname,$author,$msg, $xinfo) = @_;
2088     $xinfo //= '';
2089
2090     mkpath '.git/dgit';
2091     my $descfn = ".git/dgit/quilt-description.tmp";
2092     open O, '>', $descfn or die "$descfn: $!";
2093     $msg =~ s/\s+$//g;
2094     $msg =~ s/\n/\n /g;
2095     $msg =~ s/^\s+$/ ./mg;
2096     print O <<END or die $!;
2097 Description: $msg
2098 Author: $author
2099 $xinfo
2100 ---
2101
2102 END
2103     close O or die $!;
2104
2105     {
2106         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2107         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2108         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2109         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2110     }
2111 }
2112
2113 sub quiltify_trees_differ ($$) {
2114     my ($x,$y) = @_;
2115     # returns 1 iff the two tree objects differ other than in debian/
2116     local $/=undef;
2117     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2118     my $diffs= cmdoutput @cmd;
2119     foreach my $f (split /\0/, $diffs) {
2120         next if $f eq 'debian';
2121         return 1;
2122     }
2123     return 0;
2124 }
2125
2126 sub quiltify_tree_sentinelfiles ($) {
2127     # lists the `sentinel' files present in the tree
2128     my ($x) = @_;
2129     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2130         qw(-- debian/rules debian/control);
2131     $r =~ s/\n/,/g;
2132     return $r;
2133 }
2134
2135 sub quiltify ($$) {
2136     my ($clogp,$target) = @_;
2137
2138     # Quilt patchification algorithm
2139     #
2140     # We search backwards through the history of the main tree's HEAD
2141     # (T) looking for a start commit S whose tree object is identical
2142     # to to the patch tip tree (ie the tree corresponding to the
2143     # current dpkg-committed patch series).  For these purposes
2144     # `identical' disregards anything in debian/ - this wrinkle is
2145     # necessary because dpkg-source treates debian/ specially.
2146     #
2147     # We can only traverse edges where at most one of the ancestors'
2148     # trees differs (in changes outside in debian/).  And we cannot
2149     # handle edges which change .pc/ or debian/patches.  To avoid
2150     # going down a rathole we avoid traversing edges which introduce
2151     # debian/rules or debian/control.  And we set a limit on the
2152     # number of edges we are willing to look at.
2153     #
2154     # If we succeed, we walk forwards again.  For each traversed edge
2155     # PC (with P parent, C child) (starting with P=S and ending with
2156     # C=T) to we do this:
2157     #  - git checkout C
2158     #  - dpkg-source --commit with a patch name and message derived from C
2159     # After traversing PT, we git commit the changes which
2160     # should be contained within debian/patches.
2161
2162     changedir '../fake';
2163     mktree_in_ud_here();
2164     rmtree '.pc';
2165     runcmd @git, 'add', '.';
2166     my $oldtiptree=git_write_tree();
2167     changedir '../work';
2168
2169     # The search for the path S..T is breadth-first.  We maintain a
2170     # todo list containing search nodes.  A search node identifies a
2171     # commit, and looks something like this:
2172     #  $p = {
2173     #      Commit => $git_commit_id,
2174     #      Child => $c,                          # or undef if P=T
2175     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2176     #      Nontrivial => true iff $p..$c has relevant changes
2177     #  };
2178
2179     my @todo;
2180     my @nots;
2181     my $sref_S;
2182     my $max_work=100;
2183     my %considered; # saves being exponential on some weird graphs
2184
2185     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2186
2187     my $not = sub {
2188         my ($search,$whynot) = @_;
2189         printdebug " search NOT $search->{Commit} $whynot\n";
2190         $search->{Whynot} = $whynot;
2191         push @nots, $search;
2192         no warnings qw(exiting);
2193         next;
2194     };
2195
2196     push @todo, {
2197         Commit => $target,
2198     };
2199
2200     while (@todo) {
2201         my $c = shift @todo;
2202         next if $considered{$c->{Commit}}++;
2203
2204         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2205
2206         printdebug "quiltify investigate $c->{Commit}\n";
2207
2208         # are we done?
2209         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2210             printdebug " search finished hooray!\n";
2211             $sref_S = $c;
2212             last;
2213         }
2214
2215         if ($quilt_mode eq 'nofix') {
2216             fail "quilt fixup required but quilt mode is \`nofix'\n".
2217                 "HEAD commit $c->{Commit} differs from tree implied by ".
2218                 " debian/patches (tree object $oldtiptree)";
2219         }
2220         if ($quilt_mode eq 'smash') {
2221             printdebug " search quitting smash\n";
2222             last;
2223         }
2224
2225         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2226         $not->($c, "has $c_sentinels not $t_sentinels")
2227             if $c_sentinels ne $t_sentinels;
2228
2229         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2230         $commitdata =~ m/\n\n/;
2231         $commitdata =~ $`;
2232         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2233         @parents = map { { Commit => $_, Child => $c } } @parents;
2234
2235         $not->($c, "root commit") if !@parents;
2236
2237         foreach my $p (@parents) {
2238             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2239         }
2240         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2241         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2242
2243         foreach my $p (@parents) {
2244             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2245
2246             my @cmd= (@git, qw(diff-tree -r --name-only),
2247                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2248             my $patchstackchange = cmdoutput @cmd;
2249             if (length $patchstackchange) {
2250                 $patchstackchange =~ s/\n/,/g;
2251                 $not->($p, "changed $patchstackchange");
2252             }
2253
2254             printdebug " search queue P=$p->{Commit} ",
2255                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2256             push @todo, $p;
2257         }
2258     }
2259
2260     if (!$sref_S) {
2261         printdebug "quiltify want to smash\n";
2262
2263         my $abbrev = sub {
2264             my $x = $_[0]{Commit};
2265             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2266             return $;
2267         };
2268         my $reportnot = sub {
2269             my ($notp) = @_;
2270             my $s = $abbrev->($notp);
2271             my $c = $notp->{Child};
2272             $s .= "..".$abbrev->($c) if $c;
2273             $s .= ": ".$c->{Whynot};
2274             return $s;
2275         };
2276         if ($quilt_mode eq 'linear') {
2277             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2278             foreach my $notp (@nots) {
2279                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2280             }
2281             fail "quilt fixup naive history linearisation failed.\n".
2282  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2283         } elsif ($quilt_mode eq 'smash') {
2284         } elsif ($quilt_mode eq 'auto') {
2285             progress "quilt fixup cannot be linear, smashing...";
2286         } else {
2287             die "$quilt_mode ?";
2288         }
2289
2290         my $time = time;
2291         my $ncommits = 3;
2292         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2293
2294         quiltify_dpkg_commit "auto-$version-$target-$time",
2295             (getfield $clogp, 'Maintainer'),
2296             "Automatically generated patch ($clogp->{Version})\n".
2297             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2298         return;
2299     }
2300
2301     progress "quiltify linearisation planning successful, executing...";
2302
2303     for (my $p = $sref_S;
2304          my $c = $p->{Child};
2305          $p = $p->{Child}) {
2306         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2307         next unless $p->{Nontrivial};
2308
2309         my $cc = $c->{Commit};
2310
2311         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2312         $commitdata =~ m/\n\n/ or die "$c ?";
2313         $commitdata = $`;
2314         my $msg = $'; #';
2315         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2316         my $author = $1;
2317
2318         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2319
2320         my $title = $1;
2321         my $patchname = $title;
2322         $patchname =~ s/[.:]$//;
2323         $patchname =~ y/ A-Z/-a-z/;
2324         $patchname =~ y/-a-z0-9_.+=~//cd;
2325         $patchname =~ s/^\W/x-$&/;
2326         $patchname = substr($patchname,0,40);
2327         my $index;
2328         for ($index='';
2329              stat "debian/patches/$patchname$index";
2330              $index++) { }
2331         $!==ENOENT or die "$patchname$index $!";
2332
2333         runcmd @git, qw(checkout -q), $cc;
2334
2335         # We use the tip's changelog so that dpkg-source doesn't
2336         # produce complaining messages from dpkg-parsechangelog.  None
2337         # of the information dpkg-source gets from the changelog is
2338         # actually relevant - it gets put into the original message
2339         # which dpkg-source provides our stunt editor, and then
2340         # overwritten.
2341         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2342
2343         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2344             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2345
2346         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2347     }
2348
2349     runcmd @git, qw(checkout -q master);
2350 }
2351
2352 sub build_maybe_quilt_fixup () {
2353     my $format=get_source_format;
2354     return unless madformat $format;
2355     # sigh
2356
2357     # Our objective is:
2358     #  - honour any existing .pc in case it has any strangeness
2359     #  - determine the git commit corresponding to the tip of
2360     #    the patch stack (if there is one)
2361     #  - if there is such a git commit, convert each subsequent
2362     #    git commit into a quilt patch with dpkg-source --commit
2363     #  - otherwise convert all the differences in the tree into
2364     #    a single git commit
2365     #
2366     # To do this we:
2367
2368     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2369     # dgit would include the .pc in the git tree.)  If there isn't
2370     # one, we need to generate one by unpacking the patches that we
2371     # have.
2372     #
2373     # We first look for a .pc in the git tree.  If there is one, we
2374     # will use it.  (This is not the normal case.)
2375     #
2376     # Otherwise need to regenerate .pc so that dpkg-source --commit
2377     # can work.  We do this as follows:
2378     #     1. Collect all relevant .orig from parent directory
2379     #     2. Generate a debian.tar.gz out of
2380     #         debian/{patches,rules,source/format}
2381     #     3. Generate a fake .dsc containing just these fields:
2382     #          Format Source Version Files
2383     #     4. Extract the fake .dsc
2384     #        Now the fake .dsc has a .pc directory.
2385     # (In fact we do this in every case, because in future we will
2386     # want to search for a good base commit for generating patches.)
2387     #
2388     # Then we can actually do the dpkg-source --commit
2389     #     1. Make a new working tree with the same object
2390     #        store as our main tree and check out the main
2391     #        tree's HEAD.
2392     #     2. Copy .pc from the fake's extraction, if necessary
2393     #     3. Run dpkg-source --commit
2394     #     4. If the result has changes to debian/, then
2395     #          - git-add them them
2396     #          - git-add .pc if we had a .pc in-tree
2397     #          - git-commit
2398     #     5. If we had a .pc in-tree, delete it, and git-commit
2399     #     6. Back in the main tree, fast forward to the new HEAD
2400
2401     my $clogp = parsechangelog();
2402     my $headref = git_rev_parse('HEAD');
2403
2404     prep_ud();
2405     changedir $ud;
2406
2407     my $upstreamversion=$version;
2408     $upstreamversion =~ s/-[^-]*$//;
2409
2410     my $fakeversion="$upstreamversion-~~DGITFAKE";
2411
2412     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2413     print $fakedsc <<END or die $!;
2414 Format: 3.0 (quilt)
2415 Source: $package
2416 Version: $fakeversion
2417 Files:
2418 END
2419
2420     my $dscaddfile=sub {
2421         my ($b) = @_;
2422
2423         my $md = new Digest::MD5;
2424
2425         my $fh = new IO::File $b, '<' or die "$b $!";
2426         stat $fh or die $!;
2427         my $size = -s _;
2428
2429         $md->addfile($fh);
2430         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2431     };
2432
2433     foreach my $f (<../../../../*>) { #/){
2434         my $b=$f; $b =~ s{.*/}{};
2435         next unless is_orig_file $b, srcfn $upstreamversion,'';
2436         link $f, $b or die "$b $!";
2437         $dscaddfile->($b);
2438     }
2439
2440     my @files=qw(debian/source/format debian/rules);
2441     if (stat_exists '../../../debian/patches') {
2442         push @files, 'debian/patches';
2443     }
2444
2445     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2446     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2447
2448     $dscaddfile->($debtar);
2449     close $fakedsc or die $!;
2450
2451     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2452
2453     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2454     rename $fakexdir, "fake" or die "$fakexdir $!";
2455
2456     mkdir "work" or die $!;
2457     changedir "work";
2458     mktree_in_ud_here();
2459     runcmd @git, qw(reset --hard), $headref;
2460
2461     my $mustdeletepc=0;
2462     if (stat_exists ".pc") {
2463         -d _ or die;
2464         progress "Tree already contains .pc - will use it then delete it.";
2465         $mustdeletepc=1;
2466     } else {
2467         rename '../fake/.pc','.pc' or die $!;
2468     }
2469
2470     quiltify($clogp,$headref);
2471
2472     if (!open P, '>>', ".pc/applied-patches") {
2473         $!==&ENOENT or die $!;
2474     } else {
2475         close P;
2476     }
2477
2478     commit_quilty_patch();
2479
2480     if ($mustdeletepc) {
2481         runcmd @git, qw(rm -rq .pc);
2482         commit_admin "Commit removal of .pc (quilt series tracking data)";
2483     }
2484
2485     changedir '../../../..';
2486     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2487 }
2488
2489 sub quilt_fixup_editor () {
2490     my $descfn = $ENV{$fakeeditorenv};
2491     my $editing = $ARGV[$#ARGV];
2492     open I1, '<', $descfn or die "$descfn: $!";
2493     open I2, '<', $editing or die "$editing: $!";
2494     unlink $editing or die "$editing: $!";
2495     open O, '>', $editing or die "$editing: $!";
2496     while (<I1>) { print O or die $!; } I1->error and die $!;
2497     my $copying = 0;
2498     while (<I2>) {
2499         $copying ||= m/^\-\-\- /;
2500         next unless $copying;
2501         print O or die $!;
2502     }
2503     I2->error and die $!;
2504     close O or die $1;
2505     exit 0;
2506 }
2507
2508 #----- other building -----
2509
2510 sub clean_tree () {
2511     if ($cleanmode eq 'dpkg-source') {
2512         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2513     } elsif ($cleanmode eq 'git') {
2514         runcmd_ordryrun_local @git, qw(clean -xdf);
2515     } elsif ($cleanmode eq 'none') {
2516     } else {
2517         die "$cleanmode ?";
2518     }
2519 }
2520
2521 sub cmd_clean () {
2522     badusage "clean takes no additional arguments" if @ARGV;
2523     clean_tree();
2524 }
2525
2526 sub build_prep () {
2527     badusage "-p is not allowed when building" if defined $package;
2528     check_not_dirty();
2529     clean_tree();
2530     my $clogp = parsechangelog();
2531     $isuite = getfield $clogp, 'Distribution';
2532     $package = getfield $clogp, 'Source';
2533     $version = getfield $clogp, 'Version';
2534     build_maybe_quilt_fixup();
2535 }
2536
2537 sub changesopts () {
2538     my @opts =@changesopts[1..$#changesopts];
2539     if (!defined $changes_since_version) {
2540         my @vsns = archive_query('archive_query');
2541         my @quirk = access_quirk();
2542         if ($quirk[0] eq 'backports') {
2543             local $isuite = $quirk[2];
2544             local $csuite;
2545             canonicalise_suite();
2546             push @vsns, archive_query('archive_query');
2547         }
2548         if (@vsns) {
2549             @vsns = map { $_->[0] } @vsns;
2550             @vsns = sort { -version_compare($a, $b) } @vsns;
2551             $changes_since_version = $vsns[0];
2552             progress "changelog will contain changes since $vsns[0]";
2553         } else {
2554             $changes_since_version = '_';
2555             progress "package seems new, not specifying -v<version>";
2556         }
2557     }
2558     if ($changes_since_version ne '_') {
2559         unshift @opts, "-v$changes_since_version";
2560     }
2561     return @opts;
2562 }
2563
2564 sub cmd_build {
2565     build_prep();
2566     runcmd_ordryrun_local @dpkgbuildpackage, qw(-us -uc), changesopts(), @ARGV;
2567     printdone "build successful\n";
2568 }
2569
2570 sub cmd_git_build {
2571     build_prep();
2572     my @cmd =
2573         (qw(git-buildpackage -us -uc --git-no-sign-tags),
2574          "--git-builder=@dpkgbuildpackage");
2575     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
2576         canonicalise_suite();
2577         push @cmd, "--git-debian-branch=".lbranch();
2578     }
2579     push @cmd, changesopts();
2580     runcmd_ordryrun_local @cmd, @ARGV;
2581     printdone "build successful\n";
2582 }
2583
2584 sub build_source {
2585     build_prep();
2586     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
2587     $dscfn = dscfn($version);
2588     if ($cleanmode eq 'dpkg-source') {
2589         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
2590             changesopts();
2591     } else {
2592         my $pwd = must_getcwd();
2593         my $leafdir = basename $pwd;
2594         changedir "..";
2595         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
2596         changedir $pwd;
2597         runcmd_ordryrun_local qw(sh -ec),
2598             'exec >$1; shift; exec "$@"','x',
2599             "../$sourcechanges",
2600             @dpkggenchanges, qw(-S), changesopts();
2601     }
2602 }
2603
2604 sub cmd_build_source {
2605     badusage "build-source takes no additional arguments" if @ARGV;
2606     build_source();
2607     printdone "source built, results in $dscfn and $sourcechanges";
2608 }
2609
2610 sub cmd_sbuild {
2611     build_source();
2612     changedir "..";
2613     my $pat = "${package}_".(stripepoch $version)."_*.changes";
2614     if (act_local()) {
2615         stat_exist $dscfn or fail "$dscfn (in parent directory): $!";
2616         stat_exists $sourcechanges
2617             or fail "$sourcechanges (in parent directory): $!";
2618         foreach my $cf (glob $pat) {
2619             next if $cf eq $sourcechanges;
2620             unlink $cf or fail "remove $cf: $!";
2621         }
2622     }
2623     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
2624     my @changesfiles = glob $pat;
2625     @changesfiles = sort {
2626         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
2627             or $a cmp $b
2628     } @changesfiles;
2629     fail "wrong number of different changes files (@changesfiles)"
2630         unless @changesfiles;
2631     runcmd_ordryrun_local @mergechanges, @changesfiles;
2632     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
2633     if (act_local()) {
2634         stat_exists $multichanges or fail "$multichanges: $!";
2635     }
2636     printdone "build successful, results in $multichanges\n" or die $!;
2637 }
2638
2639 sub cmd_quilt_fixup {
2640     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
2641     my $clogp = parsechangelog();
2642     $version = getfield $clogp, 'Version';
2643     $package = getfield $clogp, 'Source';
2644     build_maybe_quilt_fixup();
2645 }
2646
2647 sub cmd_archive_api_query {
2648     badusage "need only 1 subpath argument" unless @ARGV==1;
2649     my ($subpath) = @ARGV;
2650     my @cmd = archive_api_query_cmd($subpath);
2651     debugcmd ">",@cmd;
2652     exec @cmd or fail "exec curl: $!\n";
2653 }
2654
2655 sub cmd_clone_dgit_repos_server {
2656     badusage "need destination argument" unless @ARGV==1;
2657     my ($destdir) = @ARGV;
2658     $package = '_dgit-repos-server';
2659     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
2660     debugcmd ">",@cmd;
2661     exec @cmd or fail "exec git clone: $!\n";
2662 }
2663
2664 #---------- argument parsing and main program ----------
2665
2666 sub cmd_version {
2667     print "dgit version $our_version\n" or die $!;
2668     exit 0;
2669 }
2670
2671 sub parseopts () {
2672     my $om;
2673
2674     if (defined $ENV{'DGIT_SSH'}) {
2675         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
2676     } elsif (defined $ENV{'GIT_SSH'}) {
2677         @ssh = ($ENV{'GIT_SSH'});
2678     }
2679
2680     while (@ARGV) {
2681         last unless $ARGV[0] =~ m/^-/;
2682         $_ = shift @ARGV;
2683         last if m/^--?$/;
2684         if (m/^--/) {
2685             if (m/^--dry-run$/) {
2686                 push @ropts, $_;
2687                 $dryrun_level=2;
2688             } elsif (m/^--damp-run$/) {
2689                 push @ropts, $_;
2690                 $dryrun_level=1;
2691             } elsif (m/^--no-sign$/) {
2692                 push @ropts, $_;
2693                 $sign=0;
2694             } elsif (m/^--help$/) {
2695                 cmd_help();
2696             } elsif (m/^--version$/) {
2697                 cmd_version();
2698             } elsif (m/^--new$/) {
2699                 push @ropts, $_;
2700                 $new_package=1;
2701             } elsif (m/^--since-version=([^_]+|_)$/) {
2702                 push @ropts, $_;
2703                 $changes_since_version = $1;
2704             } elsif (m/^--([-0-9a-z]+)=(.*)/s &&
2705                      ($om = $opts_opt_map{$1}) &&
2706                      length $om->[0]) {
2707                 push @ropts, $_;
2708                 $om->[0] = $2;
2709             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
2710                      !$opts_opt_cmdonly{$1} &&
2711                      ($om = $opts_opt_map{$1})) {
2712                 push @ropts, $_;
2713                 push @$om, $2;
2714             } elsif (m/^--existing-package=(.*)/s) {
2715                 push @ropts, $_;
2716                 $existing_package = $1;
2717             } elsif (m/^--initiator-tempdir=(.*)/s) {
2718                 $initiator_tempdir = $1;
2719                 $initiator_tempdir =~ m#^/# or
2720                     badusage "--initiator-tempdir must be used specify an".
2721                         " absolute, not relative, directory."
2722             } elsif (m/^--distro=(.*)/s) {
2723                 push @ropts, $_;
2724                 $idistro = $1;
2725             } elsif (m/^--build-products-dir=(.*)/s) {
2726                 push @ropts, $_;
2727                 $buildproductsdir = $1;
2728             } elsif (m/^--clean=(dpkg-source|git|none)$/s) {
2729                 push @ropts, $_;
2730                 $cleanmode = $1;
2731             } elsif (m/^--clean=(.*)$/s) {
2732                 badusage "unknown cleaning mode \`$1'";
2733             } elsif (m/^--quilt=($quilt_modes_re)$/s) {
2734                 push @ropts, $_;
2735                 $quilt_mode = $1;
2736             } elsif (m/^--quilt=(.*)$/s) {
2737                 badusage "unknown quilt fixup mode \`$1'";
2738             } elsif (m/^--ignore-dirty$/s) {
2739                 push @ropts, $_;
2740                 $ignoredirty = 1;
2741             } elsif (m/^--no-quilt-fixup$/s) {
2742                 push @ropts, $_;
2743                 $quilt_mode = 'nocheck';
2744             } elsif (m/^--no-rm-on-error$/s) {
2745                 push @ropts, $_;
2746                 $rmonerror = 0;
2747             } elsif (m/^--deliberately-($deliberately_re)$/s) {
2748                 push @ropts, $_;
2749                 push @deliberatelies, $&;
2750             } else {
2751                 badusage "unknown long option \`$_'";
2752             }
2753         } else {
2754             while (m/^-./s) {
2755                 if (s/^-n/-/) {
2756                     push @ropts, $&;
2757                     $dryrun_level=2;
2758                 } elsif (s/^-L/-/) {
2759                     push @ropts, $&;
2760                     $dryrun_level=1;
2761                 } elsif (s/^-h/-/) {
2762                     cmd_help();
2763                 } elsif (s/^-D/-/) {
2764                     push @ropts, $&;
2765                     $debuglevel++;
2766                     enabledebug();
2767                 } elsif (s/^-N/-/) {
2768                     push @ropts, $&;
2769                     $new_package=1;
2770                 } elsif (s/^-v([^_]+|_)$//s) {
2771                     push @ropts, $&;
2772                     $changes_since_version = $1;
2773                 } elsif (m/^-m/) {
2774                     push @ropts, $&;
2775                     push @changesopts, $_;
2776                     $_ = '';
2777                 } elsif (s/^-c(.*=.*)//s) {
2778                     push @ropts, $&;
2779                     push @git, '-c', $1;
2780                 } elsif (s/^-d(.+)//s) {
2781                     push @ropts, $&;
2782                     $idistro = $1;
2783                 } elsif (s/^-C(.+)//s) {
2784                     push @ropts, $&;
2785                     $changesfile = $1;
2786                     if ($changesfile =~ s#^(.*)/##) {
2787                         $buildproductsdir = $1;
2788                     }
2789                 } elsif (s/^-k(.+)//s) {
2790                     $keyid=$1;
2791                 } elsif (m/^-[vdCk]$/) {
2792                     badusage
2793  "option \`$_' requires an argument (and no space before the argument)";
2794                 } elsif (s/^-wn$//s) {
2795                     push @ropts, $&;
2796                     $cleanmode = 'none';
2797                 } elsif (s/^-wg$//s) {
2798                     push @ropts, $&;
2799                     $cleanmode = 'git';
2800                 } elsif (s/^-wd$//s) {
2801                     push @ropts, $&;
2802                     $cleanmode = 'dpkg-source';
2803                 } else {
2804                     badusage "unknown short option \`$_'";
2805                 }
2806             }
2807         }
2808     }
2809 }
2810
2811 if ($ENV{$fakeeditorenv}) {
2812     quilt_fixup_editor();
2813 }
2814
2815 parseopts();
2816 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
2817 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
2818     if $dryrun_level == 1;
2819 if (!@ARGV) {
2820     print STDERR $helpmsg or die $!;
2821     exit 8;
2822 }
2823 my $cmd = shift @ARGV;
2824 $cmd =~ y/-/_/;
2825
2826 if (!defined $quilt_mode) {
2827     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
2828         // access_cfg('quilt-mode', 'RETURN-UNDEF')
2829         // 'linear';
2830     $quilt_mode =~ m/^($quilt_modes_re)$/
2831         or badcfg "unknown quilt-mode \`$quilt_mode'";
2832     $quilt_mode = $1;
2833 }
2834
2835 my $fn = ${*::}{"cmd_$cmd"};
2836 $fn or badusage "unknown operation $cmd";
2837 $fn->();