dgit

   1 #!/usr/bin/perl -w
   2 # dgit
   3 # Integration between git and Debian-style archives
   4 #
   5 # Copyright (C)2013-2015 Ian Jackson
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use strict;
  21
  22 use Debian::Dgit;
  23 setup_sigwarn();
  24
  25 use IO::Handle;
  26 use Data::Dumper;
  27 use LWP::UserAgent;
  28 use Dpkg::Control::Hash;
  29 use File::Path;
  30 use File::Temp qw(tempdir);
  31 use File::Basename;
  32 use Dpkg::Version;
  33 use POSIX;
  34 use IPC::Open2;
  35 use Digest::SHA;
  36 use Digest::MD5;
  37
  38 use Debian::Dgit;
  39
  40 our $our_version = 'UNRELEASED'; ###substituted###
  41
  42 our @rpushprotovsn_support = qw(3 2);
  43 our $protovsn;
  44
  45 our $isuite = 'unstable';
  46 our $idistro;
  47 our $package;
  48 our @ropts;
  49
  50 our $sign = 1;
  51 our $dryrun_level = 0;
  52 our $changesfile;
  53 our $buildproductsdir = '..';
  54 our $new_package = 0;
  55 our $ignoredirty = 0;
  56 our $rmonerror = 1;
  57 our @deliberatelies;
  58 our %previously;
  59 our $existing_package = 'dpkg';
  60 our $cleanmode;
  61 our $changes_since_version;
  62 our $quilt_mode;
  63 our $quilt_modes_re = 'linear|smash|auto|nofix|nocheck';
  64 our $we_are_responder;
  65 our $initiator_tempdir;
  66
  67 our %format_ok = map { $_=>1 } ("1.0","3.0 (native)","3.0 (quilt)");
  68
  69 our $suite_re = '[-+.0-9a-z]+';
  70 our $cleanmode_re = 'dpkg-source(?:-d)?|git|git-ff|check|none';
  71
  72 our (@git) = qw(git);
  73 our (@dget) = qw(dget);
  74 our (@curl) = qw(curl -f);
  75 our (@dput) = qw(dput);
  76 our (@debsign) = qw(debsign);
  77 our (@gpg) = qw(gpg);
  78 our (@sbuild) = qw(sbuild -A);
  79 our (@ssh) = 'ssh';
  80 our (@dgit) = qw(dgit);
  81 our (@dpkgbuildpackage) = qw(dpkg-buildpackage -i\.git/ -I.git);
  82 our (@dpkgsource) = qw(dpkg-source -i\.git/ -I.git);
  83 our (@dpkggenchanges) = qw(dpkg-genchanges);
  84 our (@mergechanges) = qw(mergechanges -f);
  85 our (@changesopts) = ('');
  86
  87 our %opts_opt_map = ('dget' => \@dget, # accept for compatibility
  88                      'curl' => \@curl,
  89                      'dput' => \@dput,
  90                      'debsign' => \@debsign,
  91                      'gpg' => \@gpg,
  92                      'sbuild' => \@sbuild,
  93                      'ssh' => \@ssh,
  94                      'dgit' => \@dgit,
  95                      'git' => \@git,
  96                      'dpkg-source' => \@dpkgsource,
  97                      'dpkg-buildpackage' => \@dpkgbuildpackage,
  98                      'dpkg-genchanges' => \@dpkggenchanges,
  99                      'ch' => \@changesopts,
 100                      'mergechanges' => \@mergechanges);
 101
 102 our %opts_opt_cmdonly = ('gpg' => 1, 'git' => 1);
 103 our %opts_cfg_insertpos = map {
 104     $_,
 105     scalar @{ $opts_opt_map{$_} }
 106 } keys %opts_opt_map;
 107
 108 sub finalise_opts_opts();
 109
 110 our $keyid;
 111
 112 autoflush STDOUT 1;
 113
 114 our $supplementary_message = '';
 115
 116 END {
 117     local ($@, $?);
 118     print STDERR "! $_\n" foreach $supplementary_message =~ m/^.+$/mg;
 119 }
 120
 121 our $remotename = 'dgit';
 122 our @ourdscfield = qw(Dgit Vcs-Dgit-Master);
 123 our $csuite;
 124 our $instead_distro;
 125
 126 sub lbranch () { return "$branchprefix/$csuite"; }
 127 my $lbranch_re = '^refs/heads/'.$branchprefix.'/([^/.]+)$';
 128 sub lref () { return "refs/heads/".lbranch(); }
 129 sub lrref () { return "refs/remotes/$remotename/".server_branch($csuite); }
 130 sub rrref () { return server_ref($csuite); }
 131
 132 sub lrfetchrefs () { return "refs/dgit-fetch/$csuite"; }
 133
 134 sub stripepoch ($) {
 135     my ($vsn) = @_;
 136     $vsn =~ s/^\d+\://;
 137     return $vsn;
 138 }
 139
 140 sub srcfn ($$) {
 141     my ($vsn,$sfx) = @_;
 142     return "${package}_".(stripepoch $vsn).$sfx
 143 }
 144
 145 sub dscfn ($) {
 146     my ($vsn) = @_;
 147     return srcfn($vsn,".dsc");
 148 }
 149
 150 our $us = 'dgit';
 151 initdebug('');
 152
 153 our @end;
 154 END {
 155     local ($?);
 156     foreach my $f (@end) {
 157         eval { $f->(); };
 158         warn "$us: cleanup: $@" if length $@;
 159     }
 160 };
 161
 162 sub badcfg { print STDERR "$us: invalid configuration: @_\n"; exit 12; }
 163
 164 sub no_such_package () {
 165     print STDERR "$us: package $package does not exist in suite $isuite\n";
 166     exit 4;
 167 }
 168
 169 sub fetchspec () {
 170     local $csuite = '*';
 171     return  "+".rrref().":".lrref();
 172 }
 173
 174 sub changedir ($) {
 175     my ($newdir) = @_;
 176     printdebug "CD $newdir\n";
 177     chdir $newdir or die "chdir: $newdir: $!";
 178 }
 179
 180 sub deliberately ($) {
 181     my ($enquiry) = @_;
 182     return !!grep { $_ eq "--deliberately-$enquiry" } @deliberatelies;
 183 }
 184
 185 sub deliberately_not_fast_forward () {
 186     foreach (qw(not-fast-forward fresh-repo)) {
 187         return 1 if deliberately($_) || deliberately("TEST-dgit-only-$_");
 188     }
 189 }
 190
 191 #---------- remote protocol support, common ----------
 192
 193 # remote push initiator/responder protocol:
 194 #  $ dgit remote-push-build-host <n-rargs> <rargs>... <push-args>...
 195 #  where <rargs> is <push-host-dir> <supported-proto-vsn>,... ...
 196 #  < dgit-remote-push-ready <actual-proto-vsn>
 197 #
 198 #  > file parsed-changelog
 199 #  [indicates that output of dpkg-parsechangelog follows]
 200 #  > data-block NBYTES
 201 #  > [NBYTES bytes of data (no newline)]
 202 #  [maybe some more blocks]
 203 #  > data-end
 204 #
 205 #  > file dsc
 206 #  [etc]
 207 #
 208 #  > file changes
 209 #  [etc]
 210 #
 211 #  > param head HEAD
 212 #
 213 #  > want signed-tag
 214 #  [indicates that signed tag is wanted]
 215 #  < data-block NBYTES
 216 #  < [NBYTES bytes of data (no newline)]
 217 #  [maybe some more blocks]
 218 #  < data-end
 219 #  < files-end
 220 #
 221 #  > want signed-dsc-changes
 222 #  < data-block NBYTES    [transfer of signed dsc]
 223 #  [etc]
 224 #  < data-block NBYTES    [transfer of signed changes]
 225 #  [etc]
 226 #  < files-end
 227 #
 228 #  > complete
 229
 230 our $i_child_pid;
 231
 232 sub i_child_report () {
 233     # Sees if our child has died, and reap it if so.  Returns a string
 234     # describing how it died if it failed, or undef otherwise.
 235     return undef unless $i_child_pid;
 236     my $got = waitpid $i_child_pid, WNOHANG;
 237     return undef if $got <= 0;
 238     die unless $got == $i_child_pid;
 239     $i_child_pid = undef;
 240     return undef unless $?;
 241     return "build host child ".waitstatusmsg();
 242 }
 243
 244 sub badproto ($$) {
 245     my ($fh, $m) = @_;
 246     fail "connection lost: $!" if $fh->error;
 247     fail "protocol violation; $m not expected";
 248 }
 249
 250 sub badproto_badread ($$) {
 251     my ($fh, $wh) = @_;
 252     fail "connection lost: $!" if $!;
 253     my $report = i_child_report();
 254     fail $report if defined $report;
 255     badproto $fh, "eof (reading $wh)";
 256 }
 257
 258 sub protocol_expect (&$) {
 259     my ($match, $fh) = @_;
 260     local $_;
 261     $_ = <$fh>;
 262     defined && chomp or badproto_badread $fh, "protocol message";
 263     if (wantarray) {
 264         my @r = &$match;
 265         return @r if @r;
 266     } else {
 267         my $r = &$match;
 268         return $r if $r;
 269     }
 270     badproto $fh, "\`$_'";
 271 }
 272
 273 sub protocol_send_file ($$) {
 274     my ($fh, $ourfn) = @_;
 275     open PF, "<", $ourfn or die "$ourfn: $!";
 276     for (;;) {
 277         my $d;
 278         my $got = read PF, $d, 65536;
 279         die "$ourfn: $!" unless defined $got;
 280         last if !$got;
 281         print $fh "data-block ".length($d)."\n" or die $!;
 282         print $fh $d or die $!;
 283     }
 284     PF->error and die "$ourfn $!";
 285     print $fh "data-end\n" or die $!;
 286     close PF;
 287 }
 288
 289 sub protocol_read_bytes ($$) {
 290     my ($fh, $nbytes) = @_;
 291     $nbytes =~ m/^[1-9]\d{0,5}$|^0$/ or badproto \*RO, "bad byte count";
 292     my $d;
 293     my $got = read $fh, $d, $nbytes;
 294     $got==$nbytes or badproto_badread $fh, "data block";
 295     return $d;
 296 }
 297
 298 sub protocol_receive_file ($$) {
 299     my ($fh, $ourfn) = @_;
 300     printdebug "() $ourfn\n";
 301     open PF, ">", $ourfn or die "$ourfn: $!";
 302     for (;;) {
 303         my ($y,$l) = protocol_expect {
 304             m/^data-block (.*)$/ ? (1,$1) :
 305             m/^data-end$/ ? (0,) :
 306             ();
 307         } $fh;
 308         last unless $y;
 309         my $d = protocol_read_bytes $fh, $l;
 310         print PF $d or die $!;
 311     }
 312     close PF or die $!;
 313 }
 314
 315 #---------- remote protocol support, responder ----------
 316
 317 sub responder_send_command ($) {
 318     my ($command) = @_;
 319     return unless $we_are_responder;
 320     # called even without $we_are_responder
 321     printdebug ">> $command\n";
 322     print PO $command, "\n" or die $!;
 323 }
 324
 325 sub responder_send_file ($$) {
 326     my ($keyword, $ourfn) = @_;
 327     return unless $we_are_responder;
 328     printdebug "]] $keyword $ourfn\n";
 329     responder_send_command "file $keyword";
 330     protocol_send_file \*PO, $ourfn;
 331 }
 332
 333 sub responder_receive_files ($@) {
 334     my ($keyword, @ourfns) = @_;
 335     die unless $we_are_responder;
 336     printdebug "[[ $keyword @ourfns\n";
 337     responder_send_command "want $keyword";
 338     foreach my $fn (@ourfns) {
 339         protocol_receive_file \*PI, $fn;
 340     }
 341     printdebug "[[\$\n";
 342     protocol_expect { m/^files-end$/ } \*PI;
 343 }
 344
 345 #---------- remote protocol support, initiator ----------
 346
 347 sub initiator_expect (&) {
 348     my ($match) = @_;
 349     protocol_expect { &$match } \*RO;
 350 }
 351
 352 #---------- end remote code ----------
 353
 354 sub progress {
 355     if ($we_are_responder) {
 356         my $m = join '', @_;
 357         responder_send_command "progress ".length($m) or die $!;
 358         print PO $m or die $!;
 359     } else {
 360         print @_, "\n";
 361     }
 362 }
 363
 364 our $ua;
 365
 366 sub url_get {
 367     if (!$ua) {
 368         $ua = LWP::UserAgent->new();
 369         $ua->env_proxy;
 370     }
 371     my $what = $_[$#_];
 372     progress "downloading $what...";
 373     my $r = $ua->get(@_) or die $!;
 374     return undef if $r->code == 404;
 375     $r->is_success or fail "failed to fetch $what: ".$r->status_line;
 376     return $r->decoded_content(charset => 'none');
 377 }
 378
 379 our ($dscdata,$dscurl,$dsc,$dsc_checked,$skew_warning_vsn);
 380
 381 sub runcmd {
 382     debugcmd "+",@_;
 383     $!=0; $?=0;
 384     failedcmd @_ if system @_;
 385 }
 386
 387 sub act_local () { return $dryrun_level <= 1; }
 388 sub act_scary () { return !$dryrun_level; }
 389
 390 sub printdone {
 391     if (!$dryrun_level) {
 392         progress "dgit ok: @_";
 393     } else {
 394         progress "would be ok: @_ (but dry run only)";
 395     }
 396 }
 397
 398 sub dryrun_report {
 399     printcmd(\*STDERR,$debugprefix."#",@_);
 400 }
 401
 402 sub runcmd_ordryrun {
 403     if (act_scary()) {
 404         runcmd @_;
 405     } else {
 406         dryrun_report @_;
 407     }
 408 }
 409
 410 sub runcmd_ordryrun_local {
 411     if (act_local()) {
 412         runcmd @_;
 413     } else {
 414         dryrun_report @_;
 415     }
 416 }
 417
 418 sub shell_cmd {
 419     my ($first_shell, @cmd) = @_;
 420     return qw(sh -ec), $first_shell.'; exec "$@"', 'x', @cmd;
 421 }
 422
 423 our $helpmsg = <<END;
 424 main usages:
 425   dgit [dgit-opts] clone [dgit-opts] package [suite] [./dir|/dir]
 426   dgit [dgit-opts] fetch|pull [dgit-opts] [suite]
 427   dgit [dgit-opts] build [dpkg-buildpackage-opts]
 428   dgit [dgit-opts] sbuild [sbuild-opts]
 429   dgit [dgit-opts] push [dgit-opts] [suite]
 430   dgit [dgit-opts] rpush build-host:build-dir ...
 431 important dgit options:
 432   -k<keyid>           sign tag and package with <keyid> instead of default
 433   --dry-run -n        do not change anything, but go through the motions
 434   --damp-run -L       like --dry-run but make local changes, without signing
 435   --new -N            allow introducing a new package
 436   --debug -D          increase debug level
 437   -c<name>=<value>    set git config option (used directly by dgit too)
 438 END
 439
 440 our $later_warning_msg = <<END;
 441 Perhaps the upload is stuck in incoming.  Using the version from git.
 442 END
 443
 444 sub badusage {
 445     print STDERR "$us: @_\n", $helpmsg or die $!;
 446     exit 8;
 447 }
 448
 449 sub nextarg {
 450     @ARGV or badusage "too few arguments";
 451     return scalar shift @ARGV;
 452 }
 453
 454 sub cmd_help () {
 455     print $helpmsg or die $!;
 456     exit 0;
 457 }
 458
 459 our $td = $ENV{DGIT_TEST_DUMMY_DIR} || "DGIT_TEST_DUMMY_DIR-unset";
 460
 461 our %defcfg = ('dgit.default.distro' => 'debian',
 462                'dgit.default.username' => '',
 463                'dgit.default.archive-query-default-component' => 'main',
 464                'dgit.default.ssh' => 'ssh',
 465                'dgit.default.archive-query' => 'madison:',
 466                'dgit.default.sshpsql-dbname' => 'service=projectb',
 467                'dgit-distro.debian.archive-query' => 'ftpmasterapi:',
 468                'dgit-distro.debian.git-check' => 'url',
 469                'dgit-distro.debian.git-check-suffix' => '/info/refs',
 470                'dgit-distro.debian.new-private-pushers' => 't',
 471                'dgit-distro.debian/push.git-url' => '',
 472                'dgit-distro.debian/push.git-host' => 'push.dgit.debian.org',
 473                'dgit-distro.debian/push.git-user-force' => 'dgit',
 474                'dgit-distro.debian/push.git-proto' => 'git+ssh://',
 475                'dgit-distro.debian/push.git-path' => '/dgit/debian/repos',
 476                'dgit-distro.debian/push.git-create' => 'true',
 477                'dgit-distro.debian/push.git-check' => 'ssh-cmd',
 478  'dgit-distro.debian.archive-query-url', 'https://api.ftp-master.debian.org/',
 479 # 'dgit-distro.debian.archive-query-tls-key',
 480 #    '/etc/ssl/certs/%HOST%.pem:/etc/dgit/%HOST%.pem',
 481 # ^ this does not work because curl is broken nowadays
 482 # Fixing #790093 properly will involve providing providing the key
 483 # in some pacagke and maybe updating these paths.
 484 #
 485 # 'dgit-distro.debian.archive-query-tls-curl-args',
 486 #   '--ca-path=/etc/ssl/ca-debian',
 487 # ^ this is a workaround but works (only) on DSA-administered machines
 488                'dgit-distro.debian.git-url' => 'https://git.dgit.debian.org',
 489                'dgit-distro.debian.git-url-suffix' => '',
 490                'dgit-distro.debian.upload-host' => 'ftp-master', # for dput
 491                'dgit-distro.debian.mirror' => 'http://ftp.debian.org/debian/',
 492  'dgit-distro.debian.backports-quirk' => '(squeeze)-backports*',
 493  'dgit-distro.debian-backports.mirror' => 'http://backports.debian.org/debian-backports/',
 494                'dgit-distro.ubuntu.git-check' => 'false',
 495  'dgit-distro.ubuntu.mirror' => 'http://archive.ubuntu.com/ubuntu',
 496                'dgit-distro.test-dummy.ssh' => "$td/ssh",
 497                'dgit-distro.test-dummy.username' => "alice",
 498                'dgit-distro.test-dummy.git-check' => "ssh-cmd",
 499                'dgit-distro.test-dummy.git-create' => "ssh-cmd",
 500                'dgit-distro.test-dummy.git-url' => "$td/git",
 501                'dgit-distro.test-dummy.git-host' => "git",
 502                'dgit-distro.test-dummy.git-path' => "$td/git",
 503                'dgit-distro.test-dummy.archive-query' => "ftpmasterapi:",
 504                'dgit-distro.test-dummy.archive-query-url' => "file://$td/aq/",
 505                'dgit-distro.test-dummy.mirror' => "file://$td/mirror/",
 506                'dgit-distro.test-dummy.upload-host' => 'test-dummy',
 507                );
 508
 509 our %gitcfg;
 510
 511 sub git_slurp_config () {
 512     local ($debuglevel) = $debuglevel-2;
 513     local $/="\0";
 514
 515     my @cmd = (@git, qw(config -z --get-regexp .*));
 516     debugcmd "|",@cmd;
 517
 518     open GITS, "-|", @cmd or failedcmd @cmd;
 519     while (<GITS>) {
 520         chomp or die;
 521         printdebug "=> ", (messagequote $_), "\n";
 522         m/\n/ or die "$_ ?";
 523         push @{ $gitcfg{$`} }, $'; #';
 524     }
 525     $!=0; $?=0;
 526     close GITS
 527         or ($!==0 && $?==256)
 528         or failedcmd @cmd;
 529 }
 530
 531 sub git_get_config ($) {
 532     my ($c) = @_;
 533     my $l = $gitcfg{$c};
 534     printdebug"C $c ".(defined $l ? messagequote "'$l'" : "undef")."\n"
 535         if $debuglevel >= 4;
 536     $l or return undef;
 537     @$l==1 or badcfg "multiple values for $c" if @$l > 1;
 538     return $l->[0];
 539 }
 540
 541 sub cfg {
 542     foreach my $c (@_) {
 543         return undef if $c =~ /RETURN-UNDEF/;
 544         my $v = git_get_config($c);
 545         return $v if defined $v;
 546         my $dv = $defcfg{$c};
 547         return $dv if defined $dv;
 548     }
 549     badcfg "need value for one of: @_\n".
 550         "$us: distro or suite appears not to be (properly) supported";
 551 }
 552
 553 sub access_basedistro () {
 554     if (defined $idistro) {
 555         return $idistro;
 556     } else {
 557         return cfg("dgit-suite.$isuite.distro",
 558                    "dgit.default.distro");
 559     }
 560 }
 561
 562 sub access_quirk () {
 563     # returns (quirk name, distro to use instead or undef, quirk-specific info)
 564     my $basedistro = access_basedistro();
 565     my $backports_quirk = cfg("dgit-distro.$basedistro.backports-quirk",
 566                               'RETURN-UNDEF');
 567     if (defined $backports_quirk) {
 568         my $re = $backports_quirk;
 569         $re =~ s/[^-0-9a-z_\%*()]/\\$&/ig;
 570         $re =~ s/\*/.*/g;
 571         $re =~ s/\%/([-0-9a-z_]+)/
 572             or $re =~ m/[()]/ or badcfg "backports-quirk needs \% or ( )";
 573         if ($isuite =~ m/^$re$/) {
 574             return ('backports',"$basedistro-backports",$1);
 575         }
 576     }
 577     return ('none',undef);
 578 }
 579
 580 our $access_forpush;
 581
 582 sub parse_cfg_bool ($$$) {
 583     my ($what,$def,$v) = @_;
 584     $v //= $def;
 585     return
 586         $v =~ m/^[ty1]/ ? 1 :
 587         $v =~ m/^[fn0]/ ? 0 :
 588         badcfg "$what needs t (true, y, 1) or f (false, n, 0) not \`$v'";
 589 }
 590
 591 sub access_forpush_config () {
 592     my $d = access_basedistro();
 593
 594     return 1 if
 595         $new_package &&
 596         parse_cfg_bool('new-private-pushers', 0,
 597                        cfg("dgit-distro.$d.new-private-pushers",
 598                            'RETURN-UNDEF'));
 599
 600     my $v = cfg("dgit-distro.$d.readonly", 'RETURN-UNDEF');
 601     $v //= 'a';
 602     return
 603         $v =~ m/^[ty1]/ ? 0 : # force readonly,    forpush = 0
 604         $v =~ m/^[fn0]/ ? 1 : # force nonreadonly, forpush = 1
 605         $v =~ m/^[a]/  ? '' : # auto,              forpush = ''
 606         badcfg "readonly needs t (true, y, 1) or f (false, n, 0) or a (auto)";
 607 }
 608
 609 sub access_forpush () {
 610     $access_forpush //= access_forpush_config();
 611     return $access_forpush;
 612 }
 613
 614 sub pushing () {
 615     die "$access_forpush ?" if ($access_forpush // 1) ne 1;
 616     badcfg "pushing but distro is configured readonly"
 617         if access_forpush_config() eq '0';
 618     $access_forpush = 1;
 619     $supplementary_message = <<'END' unless $we_are_responder;
 620 Push failed, before we got started.
 621 You can retry the push, after fixing the problem, if you like.
 622 END
 623     finalise_opts_opts();
 624 }
 625
 626 sub notpushing () {
 627     finalise_opts_opts();
 628 }
 629
 630 sub supplementary_message ($) {
 631     my ($msg) = @_;
 632     if (!$we_are_responder) {
 633         $supplementary_message = $msg;
 634         return;
 635     } elsif ($protovsn >= 3) {
 636         responder_send_command "supplementary-message ".length($msg)
 637             or die $!;
 638         print PO $msg or die $!;
 639     }
 640 }
 641
 642 sub access_distros () {
 643     # Returns list of distros to try, in order
 644     #
 645     # We want to try:
 646     #    0. `instead of' distro name(s) we have been pointed to
 647     #    1. the access_quirk distro, if any
 648     #    2a. the user's specified distro, or failing that  } basedistro
 649     #    2b. the distro calculated from the suite          }
 650     my @l = access_basedistro();
 651
 652     my (undef,$quirkdistro) = access_quirk();
 653     unshift @l, $quirkdistro;
 654     unshift @l, $instead_distro;
 655     @l = grep { defined } @l;
 656
 657     if (access_forpush()) {
 658         @l = map { ("$_/push", $_) } @l;
 659     }
 660     @l;
 661 }
 662
 663 sub access_cfg_cfgs (@) {
 664     my (@keys) = @_;
 665     my @cfgs;
 666     # The nesting of these loops determines the search order.  We put
 667     # the key loop on the outside so that we search all the distros
 668     # for each key, before going on to the next key.  That means that
 669     # if access_cfg is called with a more specific, and then a less
 670     # specific, key, an earlier distro can override the less specific
 671     # without necessarily overriding any more specific keys.  (If the
 672     # distro wants to override the more specific keys it can simply do
 673     # so; whereas if we did the loop the other way around, it would be
 674     # impossible to for an earlier distro to override a less specific
 675     # key but not the more specific ones without restating the unknown
 676     # values of the more specific keys.
 677     my @realkeys;
 678     my @rundef;
 679     # We have to deal with RETURN-UNDEF specially, so that we don't
 680     # terminate the search prematurely.
 681     foreach (@keys) {
 682         if (m/RETURN-UNDEF/) { push @rundef, $_; last; }
 683         push @realkeys, $_
 684     }
 685     foreach my $d (access_distros()) {
 686         push @cfgs, map { "dgit-distro.$d.$_" } @realkeys;
 687     }
 688     push @cfgs, map { "dgit.default.$_" } @realkeys;
 689     push @cfgs, @rundef;
 690     return @cfgs;
 691 }
 692
 693 sub access_cfg (@) {
 694     my (@keys) = @_;
 695     my (@cfgs) = access_cfg_cfgs(@keys);
 696     my $value = cfg(@cfgs);
 697     return $value;
 698 }
 699
 700 sub access_cfg_bool ($$) {
 701     my ($def, @keys) = @_;
 702     parse_cfg_bool($keys[0], $def, access_cfg(@keys, 'RETURN-UNDEF'));
 703 }
 704
 705 sub string_to_ssh ($) {
 706     my ($spec) = @_;
 707     if ($spec =~ m/\s/) {
 708         return qw(sh -ec), 'exec '.$spec.' "$@"', 'x';
 709     } else {
 710         return ($spec);
 711     }
 712 }
 713
 714 sub access_cfg_ssh () {
 715     my $gitssh = access_cfg('ssh', 'RETURN-UNDEF');
 716     if (!defined $gitssh) {
 717         return @ssh;
 718     } else {
 719         return string_to_ssh $gitssh;
 720     }
 721 }
 722
 723 sub access_runeinfo ($) {
 724     my ($info) = @_;
 725     return ": dgit ".access_basedistro()." $info ;";
 726 }
 727
 728 sub access_someuserhost ($) {
 729     my ($some) = @_;
 730     my $user = access_cfg("$some-user-force", 'RETURN-UNDEF');
 731     defined($user) && length($user) or
 732         $user = access_cfg("$some-user",'username');
 733     my $host = access_cfg("$some-host");
 734     return length($user) ? "$user\@$host" : $host;
 735 }
 736
 737 sub access_gituserhost () {
 738     return access_someuserhost('git');
 739 }
 740
 741 sub access_giturl (;$) {
 742     my ($optional) = @_;
 743     my $url = access_cfg('git-url','RETURN-UNDEF');
 744     my $suffix;
 745     if (!length $url) {
 746         my $proto = access_cfg('git-proto', 'RETURN-UNDEF');
 747         return undef unless defined $proto;
 748         $url =
 749             $proto.
 750             access_gituserhost().
 751             access_cfg('git-path');
 752     } else {
 753         $suffix = access_cfg('git-url-suffix','RETURN-UNDEF');
 754     }
 755     $suffix //= '.git';
 756     return "$url/$package$suffix";
 757 }
 758
 759 sub parsecontrolfh ($$;$) {
 760     my ($fh, $desc, $allowsigned) = @_;
 761     our $dpkgcontrolhash_noissigned;
 762     my $c;
 763     for (;;) {
 764         my %opts = ('name' => $desc);
 765         $opts{allow_pgp}= $allowsigned || !$dpkgcontrolhash_noissigned;
 766         $c = Dpkg::Control::Hash->new(%opts);
 767         $c->parse($fh,$desc) or die "parsing of $desc failed";
 768         last if $allowsigned;
 769         last if $dpkgcontrolhash_noissigned;
 770         my $issigned= $c->get_option('is_pgp_signed');
 771         if (!defined $issigned) {
 772             $dpkgcontrolhash_noissigned= 1;
 773             seek $fh, 0,0 or die "seek $desc: $!";
 774         } elsif ($issigned) {
 775             fail "control file $desc is (already) PGP-signed. ".
 776                 " Note that dgit push needs to modify the .dsc and then".
 777                 " do the signature itself";
 778         } else {
 779             last;
 780         }
 781     }
 782     return $c;
 783 }
 784
 785 sub parsecontrol {
 786     my ($file, $desc) = @_;
 787     my $fh = new IO::Handle;
 788     open $fh, '<', $file or die "$file: $!";
 789     my $c = parsecontrolfh($fh,$desc);
 790     $fh->error and die $!;
 791     close $fh;
 792     return $c;
 793 }
 794
 795 sub getfield ($$) {
 796     my ($dctrl,$field) = @_;
 797     my $v = $dctrl->{$field};
 798     return $v if defined $v;
 799     fail "missing field $field in ".$v->get_option('name');
 800 }
 801
 802 sub parsechangelog {
 803     my $c = Dpkg::Control::Hash->new();
 804     my $p = new IO::Handle;
 805     my @cmd = (qw(dpkg-parsechangelog), @_);
 806     open $p, '-|', @cmd or die $!;
 807     $c->parse($p);
 808     $?=0; $!=0; close $p or failedcmd @cmd;
 809     return $c;
 810 }
 811
 812 sub must_getcwd () {
 813     my $d = getcwd();
 814     defined $d or fail "getcwd failed: $!";
 815     return $d;
 816 }
 817
 818 our %rmad;
 819
 820 sub archive_query ($) {
 821     my ($method) = @_;
 822     my $query = access_cfg('archive-query','RETURN-UNDEF');
 823     $query =~ s/^(\w+):// or badcfg "invalid archive-query method \`$query'";
 824     my $proto = $1;
 825     my $data = $'; #';
 826     { no strict qw(refs); &{"${method}_${proto}"}($proto,$data); }
 827 }
 828
 829 sub pool_dsc_subpath ($$) {
 830     my ($vsn,$component) = @_; # $package is implict arg
 831     my $prefix = substr($package, 0, $package =~ m/^l/ ? 4 : 1);
 832     return "/pool/$component/$prefix/$package/".dscfn($vsn);
 833 }
 834
 835 #---------- `ftpmasterapi' archive query method (nascent) ----------
 836
 837 sub archive_api_query_cmd ($) {
 838     my ($subpath) = @_;
 839     my @cmd = qw(curl -sS);
 840     my $url = access_cfg('archive-query-url');
 841     if ($url =~ m#^https://([-.0-9a-z]+)/#) {
 842         my $host = $1;
 843         my $keys = access_cfg('archive-query-tls-key','RETURN-UNDEF') //'';
 844         foreach my $key (split /\:/, $keys) {
 845             $key =~ s/\%HOST\%/$host/g;
 846             if (!stat $key) {
 847                 fail "for $url: stat $key: $!" unless $!==ENOENT;
 848                 next;
 849             }
 850             fail "config requested specific TLS key but do not know".
 851                 " how to get curl to use exactly that EE key ($key)";
 852 #           push @cmd, "--cacert", $key, "--capath", "/dev/enoent";
 853 #           # Sadly the above line does not work because of changes
 854 #           # to gnutls.   The real fix for #790093 may involve
 855 #           # new curl options.
 856             last;
 857         }
 858         # Fixing #790093 properly will involve providing a value
 859         # for this on clients.
 860         my $kargs = access_cfg('archive-query-tls-curl-ca-args','RETURN-UNDEF');
 861         push @cmd, split / /, $kargs if defined $kargs;
 862     }
 863     push @cmd, $url.$subpath;
 864     return @cmd;
 865 }
 866
 867 sub api_query ($$) {
 868     use JSON;
 869     my ($data, $subpath) = @_;
 870     badcfg "ftpmasterapi archive query method takes no data part"
 871         if length $data;
 872     my @cmd = archive_api_query_cmd($subpath);
 873     my $json = cmdoutput @cmd;
 874     return decode_json($json);
 875 }
 876
 877 sub canonicalise_suite_ftpmasterapi () {
 878     my ($proto,$data) = @_;
 879     my $suites = api_query($data, 'suites');
 880     my @matched;
 881     foreach my $entry (@$suites) {
 882         next unless grep {
 883             my $v = $entry->{$_};
 884             defined $v && $v eq $isuite;
 885         } qw(codename name);
 886         push @matched, $entry;
 887     }
 888     fail "unknown suite $isuite" unless @matched;
 889     my $cn;
 890     eval {
 891         @matched==1 or die "multiple matches for suite $isuite\n";
 892         $cn = "$matched[0]{codename}";
 893         defined $cn or die "suite $isuite info has no codename\n";
 894         $cn =~ m/^$suite_re$/ or die "suite $isuite maps to bad codename\n";
 895     };
 896     die "bad ftpmaster api response: $@\n".Dumper(\@matched)
 897         if length $@;
 898     return $cn;
 899 }
 900
 901 sub archive_query_ftpmasterapi () {
 902     my ($proto,$data) = @_;
 903     my $info = api_query($data, "dsc_in_suite/$isuite/$package");
 904     my @rows;
 905     my $digester = Digest::SHA->new(256);
 906     foreach my $entry (@$info) {
 907         eval {
 908             my $vsn = "$entry->{version}";
 909             my ($ok,$msg) = version_check $vsn;
 910             die "bad version: $msg\n" unless $ok;
 911             my $component = "$entry->{component}";
 912             $component =~ m/^$component_re$/ or die "bad component";
 913             my $filename = "$entry->{filename}";
 914             $filename && $filename !~ m#[^-+:._~0-9a-zA-Z/]|^[/.]|/[/.]#
 915                 or die "bad filename";
 916             my $sha256sum = "$entry->{sha256sum}";
 917             $sha256sum =~ m/^[0-9a-f]+$/ or die "bad sha256sum";
 918             push @rows, [ $vsn, "/pool/$component/$filename",
 919                           $digester, $sha256sum ];
 920         };
 921         die "bad ftpmaster api response: $@\n".Dumper($entry)
 922             if length $@;
 923     }
 924     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
 925     return @rows;
 926 }
 927
 928 #---------- `madison' archive query method ----------
 929
 930 sub archive_query_madison {
 931     return map { [ @$_[0..1] ] } madison_get_parse(@_);
 932 }
 933
 934 sub madison_get_parse {
 935     my ($proto,$data) = @_;
 936     die unless $proto eq 'madison';
 937     if (!length $data) {
 938         $data= access_cfg('madison-distro','RETURN-UNDEF');
 939         $data //= access_basedistro();
 940     }
 941     $rmad{$proto,$data,$package} ||= cmdoutput
 942         qw(rmadison -asource),"-s$isuite","-u$data",$package;
 943     my $rmad = $rmad{$proto,$data,$package};
 944
 945     my @out;
 946     foreach my $l (split /\n/, $rmad) {
 947         $l =~ m{^ \s*( [^ \t|]+ )\s* \|
 948                   \s*( [^ \t|]+ )\s* \|
 949                   \s*( [^ \t|/]+ )(?:/([^ \t|/]+))? \s* \|
 950                   \s*( [^ \t|]+ )\s* }x or die "$rmad ?";
 951         $1 eq $package or die "$rmad $package ?";
 952         my $vsn = $2;
 953         my $newsuite = $3;
 954         my $component;
 955         if (defined $4) {
 956             $component = $4;
 957         } else {
 958             $component = access_cfg('archive-query-default-component');
 959         }
 960         $5 eq 'source' or die "$rmad ?";
 961         push @out, [$vsn,pool_dsc_subpath($vsn,$component),$newsuite];
 962     }
 963     return sort { -version_compare($a->[0],$b->[0]); } @out;
 964 }
 965
 966 sub canonicalise_suite_madison {
 967     # madison canonicalises for us
 968     my @r = madison_get_parse(@_);
 969     @r or fail
 970         "unable to canonicalise suite using package $package".
 971         " which does not appear to exist in suite $isuite;".
 972         " --existing-package may help";
 973     return $r[0][2];
 974 }
 975
 976 #---------- `sshpsql' archive query method ----------
 977
 978 sub sshpsql ($$$) {
 979     my ($data,$runeinfo,$sql) = @_;
 980     if (!length $data) {
 981         $data= access_someuserhost('sshpsql').':'.
 982             access_cfg('sshpsql-dbname');
 983     }
 984     $data =~ m/:/ or badcfg "invalid sshpsql method string \`$data'";
 985     my ($userhost,$dbname) = ($`,$'); #';
 986     my @rows;
 987     my @cmd = (access_cfg_ssh, $userhost,
 988                access_runeinfo("ssh-psql $runeinfo").
 989                " export LC_MESSAGES=C; export LC_CTYPE=C;".
 990                " ".shellquote qw(psql -A), $dbname, qw(-c), $sql);
 991     debugcmd "|",@cmd;
 992     open P, "-|", @cmd or die $!;
 993     while (<P>) {
 994         chomp or die;
 995         printdebug(">|$_|\n");
 996         push @rows, $_;
 997     }
 998     $!=0; $?=0; close P or failedcmd @cmd;
 999     @rows or die;
1000     my $nrows = pop @rows;
1001     $nrows =~ s/^\((\d+) rows?\)$/$1/ or die "$nrows ?";
1002     @rows == $nrows+1 or die "$nrows ".(scalar @rows)." ?";
1003     @rows = map { [ split /\|/, $_ ] } @rows;
1004     my $ncols = scalar @{ shift @rows };
1005     die if grep { scalar @$_ != $ncols } @rows;
1006     return @rows;
1007 }
1008
1009 sub sql_injection_check {
1010     foreach (@_) { die "$_ $& ?" if m{[^-+=:_.,/0-9a-zA-Z]}; }
1011 }
1012
1013 sub archive_query_sshpsql ($$) {
1014     my ($proto,$data) = @_;
1015     sql_injection_check $isuite, $package;
1016     my @rows = sshpsql($data, "archive-query $isuite $package", <<END);
1017         SELECT source.version, component.name, files.filename, files.sha256sum
1018           FROM source
1019           JOIN src_associations ON source.id = src_associations.source
1020           JOIN suite ON suite.id = src_associations.suite
1021           JOIN dsc_files ON dsc_files.source = source.id
1022           JOIN files_archive_map ON files_archive_map.file_id = dsc_files.file
1023           JOIN component ON component.id = files_archive_map.component_id
1024           JOIN files ON files.id = dsc_files.file
1025          WHERE ( suite.suite_name='$isuite' OR suite.codename='$isuite' )
1026            AND source.source='$package'
1027            AND files.filename LIKE '%.dsc';
1028 END
1029     @rows = sort { -version_compare($a->[0],$b->[0]) } @rows;
1030     my $digester = Digest::SHA->new(256);
1031     @rows = map {
1032         my ($vsn,$component,$filename,$sha256sum) = @$_;
1033         [ $vsn, "/pool/$component/$filename",$digester,$sha256sum ];
1034     } @rows;
1035     return @rows;
1036 }
1037
1038 sub canonicalise_suite_sshpsql ($$) {
1039     my ($proto,$data) = @_;
1040     sql_injection_check $isuite;
1041     my @rows = sshpsql($data, "canonicalise-suite $isuite", <<END);
1042         SELECT suite.codename
1043           FROM suite where suite_name='$isuite' or codename='$isuite';
1044 END
1045     @rows = map { $_->[0] } @rows;
1046     fail "unknown suite $isuite" unless @rows;
1047     die "ambiguous $isuite: @rows ?" if @rows>1;
1048     return $rows[0];
1049 }
1050
1051 #---------- `dummycat' archive query method ----------
1052
1053 sub canonicalise_suite_dummycat ($$) {
1054     my ($proto,$data) = @_;
1055     my $dpath = "$data/suite.$isuite";
1056     if (!open C, "<", $dpath) {
1057         $!==ENOENT or die "$dpath: $!";
1058         printdebug "dummycat canonicalise_suite $isuite $dpath ENOENT\n";
1059         return $isuite;
1060     }
1061     $!=0; $_ = <C>;
1062     chomp or die "$dpath: $!";
1063     close C;
1064     printdebug "dummycat canonicalise_suite $isuite $dpath = $_\n";
1065     return $_;
1066 }
1067
1068 sub archive_query_dummycat ($$) {
1069     my ($proto,$data) = @_;
1070     canonicalise_suite();
1071     my $dpath = "$data/package.$csuite.$package";
1072     if (!open C, "<", $dpath) {
1073         $!==ENOENT or die "$dpath: $!";
1074         printdebug "dummycat query $csuite $package $dpath ENOENT\n";
1075         return ();
1076     }
1077     my @rows;
1078     while (<C>) {
1079         next if m/^\#/;
1080         next unless m/\S/;
1081         die unless chomp;
1082         printdebug "dummycat query $csuite $package $dpath | $_\n";
1083         my @row = split /\s+/, $_;
1084         @row==2 or die "$dpath: $_ ?";
1085         push @rows, \@row;
1086     }
1087     C->error and die "$dpath: $!";
1088     close C;
1089     return sort { -version_compare($a->[0],$b->[0]); } @rows;
1090 }
1091
1092 #---------- archive query entrypoints and rest of program ----------
1093
1094 sub canonicalise_suite () {
1095     return if defined $csuite;
1096     fail "cannot operate on $isuite suite" if $isuite eq 'UNRELEASED';
1097     $csuite = archive_query('canonicalise_suite');
1098     if ($isuite ne $csuite) {
1099         progress "canonical suite name for $isuite is $csuite";
1100     }
1101 }
1102
1103 sub get_archive_dsc () {
1104     canonicalise_suite();
1105     my @vsns = archive_query('archive_query');
1106     foreach my $vinfo (@vsns) {
1107         my ($vsn,$subpath,$digester,$digest) = @$vinfo;
1108         $dscurl = access_cfg('mirror').$subpath;
1109         $dscdata = url_get($dscurl);
1110         if (!$dscdata) {
1111             $skew_warning_vsn = $vsn if !defined $skew_warning_vsn;
1112             next;
1113         }
1114         if ($digester) {
1115             $digester->reset();
1116             $digester->add($dscdata);
1117             my $got = $digester->hexdigest();
1118             $got eq $digest or
1119                 fail "$dscurl has hash $got but".
1120                     " archive told us to expect $digest";
1121         }
1122         my $dscfh = new IO::File \$dscdata, '<' or die $!;
1123         printdebug Dumper($dscdata) if $debuglevel>1;
1124         $dsc = parsecontrolfh($dscfh,$dscurl,1);
1125         printdebug Dumper($dsc) if $debuglevel>1;
1126         my $fmt = getfield $dsc, 'Format';
1127         fail "unsupported source format $fmt, sorry" unless $format_ok{$fmt};
1128         $dsc_checked = !!$digester;
1129         return;
1130     }
1131     $dsc = undef;
1132 }
1133
1134 sub check_for_git ();
1135 sub check_for_git () {
1136     # returns 0 or 1
1137     my $how = access_cfg('git-check');
1138     if ($how eq 'ssh-cmd') {
1139         my @cmd =
1140             (access_cfg_ssh, access_gituserhost(),
1141              access_runeinfo("git-check $package").
1142              " set -e; cd ".access_cfg('git-path').";".
1143              " if test -d $package.git; then echo 1; else echo 0; fi");
1144         my $r= cmdoutput @cmd;
1145         if ($r =~ m/^divert (\w+)$/) {
1146             my $divert=$1;
1147             my ($usedistro,) = access_distros();
1148             # NB that if we are pushing, $usedistro will be $distro/push
1149             $instead_distro= cfg("dgit-distro.$usedistro.diverts.$divert");
1150             $instead_distro =~ s{^/}{ access_basedistro()."/" }e;
1151             progress "diverting to $divert (using config for $instead_distro)";
1152             return check_for_git();
1153         }
1154         failedcmd @cmd unless $r =~ m/^[01]$/;
1155         return $r+0;
1156     } elsif ($how eq 'url') {
1157         my $prefix = access_cfg('git-check-url','git-url');
1158         my $suffix = access_cfg('git-check-suffix','git-suffix',
1159                                 'RETURN-UNDEF') // '.git';
1160         my $url = "$prefix/$package$suffix";
1161         my @cmd = (qw(curl -sS -I), $url);
1162         my $result = cmdoutput @cmd;
1163         $result =~ s/^\S+ 200 .*\n\r?\n//;
1164         # curl -sS -I with https_proxy prints
1165         # HTTP/1.0 200 Connection established
1166         $result =~ m/^\S+ (404|200) /s or
1167             fail "unexpected results from git check query - ".
1168                 Dumper($prefix, $result);
1169         my $code = $1;
1170         if ($code eq '404') {
1171             return 0;
1172         } elsif ($code eq '200') {
1173             return 1;
1174         } else {
1175             die;
1176         }
1177     } elsif ($how eq 'true') {
1178         return 1;
1179     } elsif ($how eq 'false') {
1180         return 0;
1181     } else {
1182         badcfg "unknown git-check \`$how'";
1183     }
1184 }
1185
1186 sub create_remote_git_repo () {
1187     my $how = access_cfg('git-create');
1188     if ($how eq 'ssh-cmd') {
1189         runcmd_ordryrun
1190             (access_cfg_ssh, access_gituserhost(),
1191              access_runeinfo("git-create $package").
1192              "set -e; cd ".access_cfg('git-path').";".
1193              " cp -a _template $package.git");
1194     } elsif ($how eq 'true') {
1195         # nothing to do
1196     } else {
1197         badcfg "unknown git-create \`$how'";
1198     }
1199 }
1200
1201 our ($dsc_hash,$lastpush_hash);
1202
1203 our $ud = '.git/dgit/unpack';
1204
1205 sub prep_ud () {
1206     rmtree($ud);
1207     mkpath '.git/dgit';
1208     mkdir $ud or die $!;
1209 }
1210
1211 sub mktree_in_ud_here () {
1212     runcmd qw(git init -q);
1213     rmtree('.git/objects');
1214     symlink '../../../../objects','.git/objects' or die $!;
1215 }
1216
1217 sub git_write_tree () {
1218     my $tree = cmdoutput @git, qw(write-tree);
1219     $tree =~ m/^\w+$/ or die "$tree ?";
1220     return $tree;
1221 }
1222
1223 sub remove_stray_gits () {
1224     my @gitscmd = qw(find -name .git -prune -print0);
1225     debugcmd "|",@gitscmd;
1226     open GITS, "-|", @gitscmd or failedcmd @gitscmd;
1227     {
1228         local $/="\0";
1229         while (<GITS>) {
1230             chomp or die;
1231             print STDERR "$us: warning: removing from source package: ",
1232                 (messagequote $_), "\n";
1233             rmtree $_;
1234         }
1235     }
1236     $!=0; $?=0; close GITS or failedcmd @gitscmd;
1237 }
1238
1239 sub mktree_in_ud_from_only_subdir () {
1240     # changes into the subdir
1241     my (@dirs) = <*/.>;
1242     die unless @dirs==1;
1243     $dirs[0] =~ m#^([^/]+)/\.$# or die;
1244     my $dir = $1;
1245     changedir $dir;
1246
1247     remove_stray_gits();
1248     mktree_in_ud_here();
1249     my $format=get_source_format();
1250     if (madformat($format)) {
1251         rmtree '.pc';
1252     }
1253     runcmd @git, qw(add -Af);
1254     my $tree=git_write_tree();
1255     return ($tree,$dir);
1256 }
1257
1258 sub dsc_files_info () {
1259     foreach my $csumi (['Checksums-Sha256','Digest::SHA', 'new(256)'],
1260                        ['Checksums-Sha1',  'Digest::SHA', 'new(1)'],
1261                        ['Files',           'Digest::MD5', 'new()']) {
1262         my ($fname, $module, $method) = @$csumi;
1263         my $field = $dsc->{$fname};
1264         next unless defined $field;
1265         eval "use $module; 1;" or die $@;
1266         my @out;
1267         foreach (split /\n/, $field) {
1268             next unless m/\S/;
1269             m/^(\w+) (\d+) (\S+)$/ or
1270                 fail "could not parse .dsc $fname line \`$_'";
1271             my $digester = eval "$module"."->$method;" or die $@;
1272             push @out, {
1273                 Hash => $1,
1274                 Bytes => $2,
1275                 Filename => $3,
1276                 Digester => $digester,
1277             };
1278         }
1279         return @out;
1280     }
1281     fail "missing any supported Checksums-* or Files field in ".
1282         $dsc->get_option('name');
1283 }
1284
1285 sub dsc_files () {
1286     map { $_->{Filename} } dsc_files_info();
1287 }
1288
1289 sub is_orig_file ($;$) {
1290     local ($_) = $_[0];
1291     my $base = $_[1];
1292     m/\.orig(?:-\w+)?\.tar\.\w+$/ or return 0;
1293     defined $base or return 1;
1294     return $` eq $base;
1295 }
1296
1297 sub make_commit ($) {
1298     my ($file) = @_;
1299     return cmdoutput @git, qw(hash-object -w -t commit), $file;
1300 }
1301
1302 sub clogp_authline ($) {
1303     my ($clogp) = @_;
1304     my $author = getfield $clogp, 'Maintainer';
1305     $author =~ s#,.*##ms;
1306     my $date = cmdoutput qw(date), '+%s %z', qw(-d), getfield($clogp,'Date');
1307     my $authline = "$author $date";
1308     $authline =~ m/^[^<>]+ \<\S+\> \d+ [-+]\d+$/ or
1309         fail "unexpected commit author line format \`$authline'".
1310         " (was generated from changelog Maintainer field)";
1311     return $authline;
1312 }
1313
1314 sub vendor_patches_distro ($$) {
1315     my ($checkdistro, $what) = @_;
1316     return unless defined $checkdistro;
1317
1318     my $series = "debian/patches/\L$checkdistro\E.series";
1319     printdebug "checking for vendor-specific $series ($what)\n";
1320
1321     if (!open SERIES, "<", $series) {
1322         die "$series $!" unless $!==ENOENT;
1323         return;
1324     }
1325     while (<SERIES>) {
1326         next unless m/\S/;
1327         next if m/^\s+\#/;
1328
1329         print STDERR <<END;
1330
1331 Unfortunately, this source package uses a feature of dpkg-source where
1332 the same source package unpacks to different source code on different
1333 distros.  dgit cannot safely operate on such packages on affected
1334 distros, because the meaning of source packages is not stable.
1335
1336 Please ask the distro/maintainer to remove the distro-specific series
1337 files and use a different technique (if necessary, uploading actually
1338 different packages, if different distros are supposed to have
1339 different code).
1340
1341 END
1342         fail "Found active distro-specific series file for".
1343             " $checkdistro ($what): $series, cannot continue";
1344     }
1345     die "$series $!" if SERIES->error;
1346     close SERIES;
1347 }
1348
1349 sub check_for_vendor_patches () {
1350     # This dpkg-source feature doesn't seem to be documented anywhere!
1351     # But it can be found in the changelog (reformatted):
1352
1353     #   commit  4fa01b70df1dc4458daee306cfa1f987b69da58c
1354     #   Author: Raphael Hertzog <hertzog@debian.org>
1355     #   Date: Sun  Oct  3  09:36:48  2010 +0200
1356
1357     #   dpkg-source: correctly create .pc/.quilt_series with alternate
1358     #   series files
1359     #
1360     #   If you have debian/patches/ubuntu.series and you were
1361     #   unpacking the source package on ubuntu, quilt was still
1362     #   directed to debian/patches/series instead of
1363     #   debian/patches/ubuntu.series.
1364     #
1365     #   debian/changelog                        |    3 +++
1366     #   scripts/Dpkg/Source/Package/V3/quilt.pm |    4 +++-
1367     #   2 files changed, 6 insertions(+), 1 deletion(-)
1368
1369     use Dpkg::Vendor;
1370     vendor_patches_distro($ENV{DEB_VENDOR}, "DEB_VENDOR");
1371     vendor_patches_distro(Dpkg::Vendor::get_current_vendor(),
1372                          "Dpkg::Vendor \`current vendor'");
1373     vendor_patches_distro(access_basedistro(),
1374                           "distro being accessed");
1375 }
1376
1377 sub generate_commit_from_dsc () {
1378     prep_ud();
1379     changedir $ud;
1380
1381     foreach my $fi (dsc_files_info()) {
1382         my $f = $fi->{Filename};
1383         die "$f ?" if $f =~ m#/|^\.|\.dsc$|\.tmp$#;
1384
1385         link_ltarget "../../../$f", $f
1386             or $!==&ENOENT
1387             or die "$f $!";
1388
1389         complete_file_from_dsc('.', $fi)
1390             or next;
1391
1392         if (is_orig_file($f)) {
1393             link $f, "../../../../$f"
1394                 or $!==&EEXIST
1395                 or die "$f $!";
1396         }
1397     }
1398
1399     my $dscfn = "$package.dsc";
1400
1401     open D, ">", $dscfn or die "$dscfn: $!";
1402     print D $dscdata or die "$dscfn: $!";
1403     close D or die "$dscfn: $!";
1404     my @cmd = qw(dpkg-source);
1405     push @cmd, '--no-check' if $dsc_checked;
1406     push @cmd, qw(-x --), $dscfn;
1407     runcmd @cmd;
1408
1409     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1410     check_for_vendor_patches() if madformat($dsc->{format});
1411     runcmd qw(sh -ec), 'dpkg-parsechangelog >../changelog.tmp';
1412     my $clogp = parsecontrol('../changelog.tmp',"commit's changelog");
1413     my $authline = clogp_authline $clogp;
1414     my $changes = getfield $clogp, 'Changes';
1415     open C, ">../commit.tmp" or die $!;
1416     print C <<END or die $!;
1417 tree $tree
1418 author $authline
1419 committer $authline
1420
1421 $changes
1422
1423 # imported from the archive
1424 END
1425     close C or die $!;
1426     my $outputhash = make_commit qw(../commit.tmp);
1427     my $cversion = getfield $clogp, 'Version';
1428     progress "synthesised git commit from .dsc $cversion";
1429     if ($lastpush_hash) {
1430         runcmd @git, qw(reset --hard), $lastpush_hash;
1431         runcmd qw(sh -ec), 'dpkg-parsechangelog >>../changelogold.tmp';
1432         my $oldclogp = parsecontrol('../changelogold.tmp','previous changelog');
1433         my $oversion = getfield $oldclogp, 'Version';
1434         my $vcmp =
1435             version_compare($oversion, $cversion);
1436         if ($vcmp < 0) {
1437             # git upload/ is earlier vsn than archive, use archive
1438             open C, ">../commit2.tmp" or die $!;
1439             print C <<END or die $!;
1440 tree $tree
1441 parent $lastpush_hash
1442 parent $outputhash
1443 author $authline
1444 committer $authline
1445
1446 Record $package ($cversion) in archive suite $csuite
1447 END
1448             $outputhash = make_commit qw(../commit2.tmp);
1449         } elsif ($vcmp > 0) {
1450             print STDERR <<END or die $!;
1451
1452 Version actually in archive:    $cversion (older)
1453 Last allegedly pushed/uploaded: $oversion (newer or same)
1454 $later_warning_msg
1455 END
1456             $outputhash = $lastpush_hash;
1457         } else {
1458             $outputhash = $lastpush_hash;
1459         }
1460     }
1461     changedir '../../../..';
1462     runcmd @git, qw(update-ref -m),"dgit fetch import $cversion",
1463             'DGIT_ARCHIVE', $outputhash;
1464     cmdoutput @git, qw(log -n2), $outputhash;
1465     # ... gives git a chance to complain if our commit is malformed
1466     rmtree($ud);
1467     return $outputhash;
1468 }
1469
1470 sub complete_file_from_dsc ($$) {
1471     our ($dstdir, $fi) = @_;
1472     # Ensures that we have, in $dir, the file $fi, with the correct
1473     # contents.  (Downloading it from alongside $dscurl if necessary.)
1474
1475     my $f = $fi->{Filename};
1476     my $tf = "$dstdir/$f";
1477     my $downloaded = 0;
1478
1479     if (stat_exists $tf) {
1480         progress "using existing $f";
1481     } else {
1482         my $furl = $dscurl;
1483         $furl =~ s{/[^/]+$}{};
1484         $furl .= "/$f";
1485         die "$f ?" unless $f =~ m/^\Q${package}\E_/;
1486         die "$f ?" if $f =~ m#/#;
1487         runcmd_ordryrun_local @curl,qw(-o),$tf,'--',"$furl";
1488         return 0 if !act_local();
1489         $downloaded = 1;
1490     }
1491
1492     open F, "<", "$tf" or die "$tf: $!";
1493     $fi->{Digester}->reset();
1494     $fi->{Digester}->addfile(*F);
1495     F->error and die $!;
1496     my $got = $fi->{Digester}->hexdigest();
1497     $got eq $fi->{Hash} or
1498         fail "file $f has hash $got but .dsc".
1499             " demands hash $fi->{Hash} ".
1500             ($downloaded ? "(got wrong file from archive!)"
1501              : "(perhaps you should delete this file?)");
1502
1503     return 1;
1504 }
1505
1506 sub ensure_we_have_orig () {
1507     foreach my $fi (dsc_files_info()) {
1508         my $f = $fi->{Filename};
1509         next unless is_orig_file($f);
1510         complete_file_from_dsc('..', $fi)
1511             or next;
1512     }
1513 }
1514
1515 sub git_fetch_us () {
1516     my @specs = (fetchspec());
1517     push @specs,
1518         map { "+refs/$_/*:".lrfetchrefs."/$_/*" }
1519         qw(tags heads);
1520     runcmd_ordryrun_local @git, qw(fetch -p -n -q), access_giturl(), @specs;
1521
1522     my %here;
1523     my $tagpat = debiantag('*',access_basedistro);
1524
1525     git_for_each_ref("refs/tags/".$tagpat, sub {
1526         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1527         printdebug "currently $fullrefname=$objid\n";
1528         $here{$fullrefname} = $objid;
1529     });
1530     git_for_each_ref(lrfetchrefs."/tags/".$tagpat, sub {
1531         my ($objid,$objtype,$fullrefname,$reftail) = @_;
1532         my $lref = "refs".substr($fullrefname, length lrfetchrefs);
1533         printdebug "offered $lref=$objid\n";
1534         if (!defined $here{$lref}) {
1535             my @upd = (@git, qw(update-ref), $lref, $objid, '');
1536             runcmd_ordryrun_local @upd;
1537         } elsif ($here{$lref} eq $objid) {
1538         } else {
1539             print STDERR \
1540                 "Not updateting $lref from $here{$lref} to $objid.\n";
1541         }
1542     });
1543 }
1544
1545 sub fetch_from_archive () {
1546     # ensures that lrref() is what is actually in the archive,
1547     #  one way or another
1548     get_archive_dsc();
1549
1550     if ($dsc) {
1551         foreach my $field (@ourdscfield) {
1552             $dsc_hash = $dsc->{$field};
1553             last if defined $dsc_hash;
1554         }
1555         if (defined $dsc_hash) {
1556             $dsc_hash =~ m/\w+/ or fail "invalid hash in .dsc \`$dsc_hash'";
1557             $dsc_hash = $&;
1558             progress "last upload to archive specified git hash";
1559         } else {
1560             progress "last upload to archive has NO git hash";
1561         }
1562     } else {
1563         progress "no version available from the archive";
1564     }
1565
1566     $lastpush_hash = git_get_ref(lrref());
1567     printdebug "previous reference hash=$lastpush_hash\n";
1568     my $hash;
1569     if (defined $dsc_hash) {
1570         fail "missing remote git history even though dsc has hash -".
1571             " could not find ref ".lrref().
1572             " (should have been fetched from ".access_giturl()."#".rrref().")"
1573             unless $lastpush_hash;
1574         $hash = $dsc_hash;
1575         ensure_we_have_orig();
1576         if ($dsc_hash eq $lastpush_hash) {
1577         } elsif (is_fast_fwd($dsc_hash,$lastpush_hash)) {
1578             print STDERR <<END or die $!;
1579
1580 Git commit in archive is behind the last version allegedly pushed/uploaded.
1581 Commit referred to by archive:  $dsc_hash
1582 Last allegedly pushed/uploaded: $lastpush_hash
1583 $later_warning_msg
1584 END
1585             $hash = $lastpush_hash;
1586         } else {
1587             fail "git head (".lrref()."=$lastpush_hash) is not a ".
1588                 "descendant of archive's .dsc hash ($dsc_hash)";
1589         }
1590     } elsif ($dsc) {
1591         $hash = generate_commit_from_dsc();
1592     } elsif ($lastpush_hash) {
1593         # only in git, not in the archive yet
1594         $hash = $lastpush_hash;
1595         print STDERR <<END or die $!;
1596
1597 Package not found in the archive, but has allegedly been pushed using dgit.
1598 $later_warning_msg
1599 END
1600     } else {
1601         printdebug "nothing found!\n";
1602         if (defined $skew_warning_vsn) {
1603             print STDERR <<END or die $!;
1604
1605 Warning: relevant archive skew detected.
1606 Archive allegedly contains $skew_warning_vsn
1607 But we were not able to obtain any version from the archive or git.
1608
1609 END
1610         }
1611         return 0;
1612     }
1613     printdebug "current hash=$hash\n";
1614     if ($lastpush_hash) {
1615         fail "not fast forward on last upload branch!".
1616             " (archive's version left in DGIT_ARCHIVE)"
1617             unless is_fast_fwd($lastpush_hash, $hash);
1618     }
1619     if (defined $skew_warning_vsn) {
1620         mkpath '.git/dgit';
1621         printdebug "SKEW CHECK WANT $skew_warning_vsn\n";
1622         my $clogf = ".git/dgit/changelog.tmp";
1623         runcmd shell_cmd "exec >$clogf",
1624             @git, qw(cat-file blob), "$hash:debian/changelog";
1625         my $gotclogp = parsechangelog("-l$clogf");
1626         my $got_vsn = getfield $gotclogp, 'Version';
1627         printdebug "SKEW CHECK GOT $got_vsn\n";
1628         if (version_compare($got_vsn, $skew_warning_vsn) < 0) {
1629             print STDERR <<END or die $!;
1630
1631 Warning: archive skew detected.  Using the available version:
1632 Archive allegedly contains    $skew_warning_vsn
1633 We were able to obtain only   $got_vsn
1634
1635 END
1636         }
1637     }
1638     if ($lastpush_hash ne $hash) {
1639         my @upd_cmd = (@git, qw(update-ref -m), 'dgit fetch', lrref(), $hash);
1640         if (act_local()) {
1641             cmdoutput @upd_cmd;
1642         } else {
1643             dryrun_report @upd_cmd;
1644         }
1645     }
1646     return 1;
1647 }
1648
1649 sub set_local_git_config ($$) {
1650     my ($k, $v) = @_;
1651     runcmd @git, qw(config), $k, $v;
1652 }
1653
1654 sub setup_mergechangelogs (;$) {
1655     my ($always) = @_;
1656     return unless $always || access_cfg_bool(1, 'setup-mergechangelogs');
1657
1658     my $driver = 'dpkg-mergechangelogs';
1659     my $cb = "merge.$driver";
1660     my $attrs = '.git/info/attributes';
1661     ensuredir '.git/info';
1662
1663     open NATTRS, ">", "$attrs.new" or die "$attrs.new $!";
1664     if (!open ATTRS, "<", $attrs) {
1665         $!==ENOENT or die "$attrs: $!";
1666     } else {
1667         while (<ATTRS>) {
1668             chomp;
1669             next if m{^debian/changelog\s};
1670             print NATTRS $_, "\n" or die $!;
1671         }
1672         ATTRS->error and die $!;
1673         close ATTRS;
1674     }
1675     print NATTRS "debian/changelog merge=$driver\n" or die $!;
1676     close NATTRS;
1677
1678     set_local_git_config "$cb.name", 'debian/changelog merge driver';
1679     set_local_git_config "$cb.driver", 'dpkg-mergechangelogs -m %O %A %B %A';
1680
1681     rename "$attrs.new", "$attrs" or die "$attrs: $!";
1682 }
1683
1684 sub setup_useremail (;$) {
1685     my ($always) = @_;
1686     return unless $always || access_cfg_bool(1, 'setup-useremail');
1687
1688     my $setup = sub {
1689         my ($k, $envvar) = @_;
1690         my $v = access_cfg("user-$k", 'RETURN-UNDEF') // $ENV{$envvar};
1691         return unless defined $v;
1692         set_local_git_config "user.$k", $v;
1693     };
1694
1695     $setup->('email', 'DEBEMAIL');
1696     $setup->('name', 'DEBFULLNAME');
1697 }
1698
1699 sub setup_new_tree () {
1700     setup_mergechangelogs();
1701     setup_useremail();
1702 }
1703
1704 sub clone ($) {
1705     my ($dstdir) = @_;
1706     canonicalise_suite();
1707     badusage "dry run makes no sense with clone" unless act_local();
1708     my $hasgit = check_for_git();
1709     mkdir $dstdir or die "$dstdir $!";
1710     changedir $dstdir;
1711     runcmd @git, qw(init -q);
1712     my $giturl = access_giturl(1);
1713     if (defined $giturl) {
1714         set_local_git_config "remote.$remotename.fetch", fetchspec();
1715         open H, "> .git/HEAD" or die $!;
1716         print H "ref: ".lref()."\n" or die $!;
1717         close H or die $!;
1718         runcmd @git, qw(remote add), 'origin', $giturl;
1719     }
1720     if ($hasgit) {
1721         progress "fetching existing git history";
1722         git_fetch_us();
1723         runcmd_ordryrun_local @git, qw(fetch origin);
1724     } else {
1725         progress "starting new git history";
1726     }
1727     fetch_from_archive() or no_such_package;
1728     my $vcsgiturl = $dsc->{'Vcs-Git'};
1729     if (length $vcsgiturl) {
1730         $vcsgiturl =~ s/\s+-b\s+\S+//g;
1731         runcmd @git, qw(remote add vcs-git), $vcsgiturl;
1732     }
1733     setup_new_tree();
1734     runcmd @git, qw(reset --hard), lrref();
1735     printdone "ready for work in $dstdir";
1736 }
1737
1738 sub fetch () {
1739     if (check_for_git()) {
1740         git_fetch_us();
1741     }
1742     fetch_from_archive() or no_such_package();
1743     printdone "fetched into ".lrref();
1744 }
1745
1746 sub pull () {
1747     fetch();
1748     runcmd_ordryrun_local @git, qw(merge -m),"Merge from $csuite [dgit]",
1749         lrref();
1750     printdone "fetched to ".lrref()." and merged into HEAD";
1751 }
1752
1753 sub check_not_dirty () {
1754     return if $ignoredirty;
1755     my @cmd = (@git, qw(diff --quiet HEAD));
1756     debugcmd "+",@cmd;
1757     $!=0; $?=0; system @cmd;
1758     return if !$! && !$?;
1759     if (!$! && $?==256) {
1760         fail "working tree is dirty (does not match HEAD)";
1761     } else {
1762         failedcmd @cmd;
1763     }
1764
1765     if (stat_exists "debian/source/local-options") {
1766         fail "git tree contains debian/source/local-options";
1767     }
1768 }
1769
1770 sub commit_admin ($) {
1771     my ($m) = @_;
1772     progress "$m";
1773     runcmd_ordryrun_local @git, qw(commit -m), $m;
1774 }
1775
1776 sub commit_quilty_patch () {
1777     my $output = cmdoutput @git, qw(status --porcelain);
1778     my %adds;
1779     foreach my $l (split /\n/, $output) {
1780         next unless $l =~ m/\S/;
1781         if ($l =~ m{^(?:\?\?| M) (.pc|debian/patches)}) {
1782             $adds{$1}++;
1783         }
1784     }
1785     delete $adds{'.pc'}; # if there wasn't one before, don't add it
1786     if (!%adds) {
1787         progress "nothing quilty to commit, ok.";
1788         return;
1789     }
1790     my @adds = map { s/[][*?\\]/\\$&/g; $_; } sort keys %adds;
1791     runcmd_ordryrun_local @git, qw(add -f), @adds;
1792     commit_admin "Commit Debian 3.0 (quilt) metadata";
1793 }
1794
1795 sub get_source_format () {
1796     if (!open F, "debian/source/format") {
1797         die $! unless $!==&ENOENT;
1798         return '';
1799     }
1800     $_ = <F>;
1801     F->error and die $!;
1802     chomp;
1803     return $_;
1804 }
1805
1806 sub madformat ($) {
1807     my ($format) = @_;
1808     return 0 unless $format eq '3.0 (quilt)';
1809     if ($quilt_mode eq 'nocheck') {
1810         progress "Not doing any fixup of \`$format' due to --no-quilt-fixup";
1811         return 0;
1812     }
1813     progress "Format \`$format', checking/updating patch stack";
1814     return 1;
1815 }
1816
1817 sub push_parse_changelog ($) {
1818     my ($clogpfn) = @_;
1819
1820     my $clogp = Dpkg::Control::Hash->new();
1821     $clogp->load($clogpfn) or die;
1822
1823     $package = getfield $clogp, 'Source';
1824     my $cversion = getfield $clogp, 'Version';
1825     my $tag = debiantag($cversion, access_basedistro);
1826     runcmd @git, qw(check-ref-format), $tag;
1827
1828     my $dscfn = dscfn($cversion);
1829
1830     return ($clogp, $cversion, $tag, $dscfn);
1831 }
1832
1833 sub push_parse_dsc ($$$) {
1834     my ($dscfn,$dscfnwhat, $cversion) = @_;
1835     $dsc = parsecontrol($dscfn,$dscfnwhat);
1836     my $dversion = getfield $dsc, 'Version';
1837     my $dscpackage = getfield $dsc, 'Source';
1838     ($dscpackage eq $package && $dversion eq $cversion) or
1839         fail "$dscfn is for $dscpackage $dversion".
1840             " but debian/changelog is for $package $cversion";
1841 }
1842
1843 sub push_mktag ($$$$$$$) {
1844     my ($head,$clogp,$tag,
1845         $dscfn,
1846         $changesfile,$changesfilewhat,
1847         $tfn) = @_;
1848
1849     $dsc->{$ourdscfield[0]} = $head;
1850     $dsc->save("$dscfn.tmp") or die $!;
1851
1852     my $changes = parsecontrol($changesfile,$changesfilewhat);
1853     foreach my $field (qw(Source Distribution Version)) {
1854         $changes->{$field} eq $clogp->{$field} or
1855             fail "changes field $field \`$changes->{$field}'".
1856                 " does not match changelog \`$clogp->{$field}'";
1857     }
1858
1859     my $cversion = getfield $clogp, 'Version';
1860     my $clogsuite = getfield $clogp, 'Distribution';
1861
1862     # We make the git tag by hand because (a) that makes it easier
1863     # to control the "tagger" (b) we can do remote signing
1864     my $authline = clogp_authline $clogp;
1865     my $delibs = join(" ", "",@deliberatelies);
1866     my $declaredistro = access_basedistro();
1867     open TO, '>', $tfn->('.tmp') or die $!;
1868     print TO <<END or die $!;
1869 object $head
1870 type commit
1871 tag $tag
1872 tagger $authline
1873
1874 $package release $cversion for $clogsuite ($csuite) [dgit]
1875 [dgit distro=$declaredistro$delibs]
1876 END
1877     foreach my $ref (sort keys %previously) {
1878                     print TO <<END or die $!;
1879 [dgit previously:$ref=$previously{$ref}]
1880 END
1881     }
1882
1883     close TO or die $!;
1884
1885     my $tagobjfn = $tfn->('.tmp');
1886     if ($sign) {
1887         if (!defined $keyid) {
1888             $keyid = access_cfg('keyid','RETURN-UNDEF');
1889         }
1890         if (!defined $keyid) {
1891             $keyid = getfield $clogp, 'Maintainer';
1892         }
1893         unlink $tfn->('.tmp.asc') or $!==&ENOENT or die $!;
1894         my @sign_cmd = (@gpg, qw(--detach-sign --armor));
1895         push @sign_cmd, qw(-u),$keyid if defined $keyid;
1896         push @sign_cmd, $tfn->('.tmp');
1897         runcmd_ordryrun @sign_cmd;
1898         if (act_scary()) {
1899             $tagobjfn = $tfn->('.signed.tmp');
1900             runcmd shell_cmd "exec >$tagobjfn", qw(cat --),
1901                 $tfn->('.tmp'), $tfn->('.tmp.asc');
1902         }
1903     }
1904
1905     return ($tagobjfn);
1906 }
1907
1908 sub sign_changes ($) {
1909     my ($changesfile) = @_;
1910     if ($sign) {
1911         my @debsign_cmd = @debsign;
1912         push @debsign_cmd, "-k$keyid" if defined $keyid;
1913         push @debsign_cmd, "-p$gpg[0]" if $gpg[0] ne 'gpg';
1914         push @debsign_cmd, $changesfile;
1915         runcmd_ordryrun @debsign_cmd;
1916     }
1917 }
1918
1919 sub dopush ($) {
1920     my ($forceflag) = @_;
1921     printdebug "actually entering push\n";
1922     supplementary_message(<<'END');
1923 Push failed, while preparing your push.
1924 You can retry the push, after fixing the problem, if you like.
1925 END
1926     prep_ud();
1927
1928     access_giturl(); # check that success is vaguely likely
1929
1930     my $clogpfn = ".git/dgit/changelog.822.tmp";
1931     runcmd shell_cmd "exec >$clogpfn", qw(dpkg-parsechangelog);
1932
1933     responder_send_file('parsed-changelog', $clogpfn);
1934
1935     my ($clogp, $cversion, $tag, $dscfn) =
1936         push_parse_changelog("$clogpfn");
1937
1938     my $dscpath = "$buildproductsdir/$dscfn";
1939     stat_exists $dscpath or
1940         fail "looked for .dsc $dscfn, but $!;".
1941             " maybe you forgot to build";
1942
1943     responder_send_file('dsc', $dscpath);
1944
1945     push_parse_dsc($dscpath, $dscfn, $cversion);
1946
1947     my $format = getfield $dsc, 'Format';
1948     printdebug "format $format\n";
1949     if (madformat($format)) {
1950         commit_quilty_patch();
1951     }
1952     check_not_dirty();
1953     changedir $ud;
1954     progress "checking that $dscfn corresponds to HEAD";
1955     runcmd qw(dpkg-source -x --),
1956         $dscpath =~ m#^/# ? $dscpath : "../../../$dscpath";
1957     my ($tree,$dir) = mktree_in_ud_from_only_subdir();
1958     check_for_vendor_patches() if madformat($dsc->{format});
1959     changedir '../../../..';
1960     my $diffopt = $debuglevel>0 ? '--exit-code' : '--quiet';
1961     my @diffcmd = (@git, qw(diff), $diffopt, $tree);
1962     debugcmd "+",@diffcmd;
1963     $!=0; $?=0;
1964     my $r = system @diffcmd;
1965     if ($r) {
1966         if ($r==256) {
1967             fail "$dscfn specifies a different tree to your HEAD commit;".
1968                 " perhaps you forgot to build".
1969                 ($diffopt eq '--exit-code' ? "" :
1970                  " (run with -D to see full diff output)");
1971         } else {
1972             failedcmd @diffcmd;
1973         }
1974     }
1975     my $head = git_rev_parse('HEAD');
1976     if (!$changesfile) {
1977         my $multi = "$buildproductsdir/".
1978             "${package}_".(stripepoch $cversion)."_multi.changes";
1979         if (stat_exists "$multi") {
1980             $changesfile = $multi;
1981         } else {
1982             my $pat = "${package}_".(stripepoch $cversion)."_*.changes";
1983             my @cs = glob "$buildproductsdir/$pat";
1984             fail "failed to find unique changes file".
1985                 " (looked for $pat in $buildproductsdir, or $multi);".
1986                 " perhaps you need to use dgit -C"
1987                 unless @cs==1;
1988             ($changesfile) = @cs;
1989         }
1990     } else {
1991         $changesfile = "$buildproductsdir/$changesfile";
1992     }
1993
1994     responder_send_file('changes',$changesfile);
1995     responder_send_command("param head $head");
1996     responder_send_command("param csuite $csuite");
1997
1998     if (deliberately_not_fast_forward) {
1999         git_for_each_ref(lrfetchrefs, sub {
2000             my ($objid,$objtype,$lrfetchrefname,$reftail) = @_;
2001             my $rrefname= substr($lrfetchrefname, length(lrfetchrefs) + 1);
2002             responder_send_command("previously $rrefname=$objid");
2003             $previously{$rrefname} = $objid;
2004         });
2005     }
2006
2007     my $tfn = sub { ".git/dgit/tag$_[0]"; };
2008     my $tagobjfn;
2009
2010     supplementary_message(<<'END');
2011 Push failed, while signing the tag.
2012 You can retry the push, after fixing the problem, if you like.
2013 END
2014     # If we manage to sign but fail to record it anywhere, it's fine.
2015     if ($we_are_responder) {
2016         $tagobjfn = $tfn->('.signed.tmp');
2017         responder_receive_files('signed-tag', $tagobjfn);
2018     } else {
2019         $tagobjfn =
2020             push_mktag($head,$clogp,$tag,
2021                        $dscpath,
2022                        $changesfile,$changesfile,
2023                        $tfn);
2024     }
2025     supplementary_message(<<'END');
2026 Push failed, *after* signing the tag.
2027 If you want to try again, you should use a new version number.
2028 END
2029
2030     my $tag_obj_hash = cmdoutput @git, qw(hash-object -w -t tag), $tagobjfn;
2031     runcmd_ordryrun @git, qw(verify-tag), $tag_obj_hash;
2032     runcmd_ordryrun_local @git, qw(update-ref), "refs/tags/$tag", $tag_obj_hash;
2033
2034     supplementary_message(<<'END');
2035 Push failed, while updating the remote git repository - see messages above.
2036 If you want to try again, you should use a new version number.
2037 END
2038     if (!check_for_git()) {
2039         create_remote_git_repo();
2040     }
2041     runcmd_ordryrun @git, qw(push),access_giturl(),
2042         $forceflag."HEAD:".rrref(), $forceflag."refs/tags/$tag";
2043     runcmd_ordryrun @git, qw(update-ref -m), 'dgit push', lrref(), 'HEAD';
2044
2045     supplementary_message(<<'END');
2046 Push failed, after updating the remote git repository.
2047 If you want to try again, you must use a new version number.
2048 END
2049     if ($we_are_responder) {
2050         my $dryrunsuffix = act_local() ? "" : ".tmp";
2051         responder_receive_files('signed-dsc-changes',
2052                                 "$dscpath$dryrunsuffix",
2053                                 "$changesfile$dryrunsuffix");
2054     } else {
2055         if (act_local()) {
2056             rename "$dscpath.tmp",$dscpath or die "$dscfn $!";
2057         } else {
2058             progress "[new .dsc left in $dscpath.tmp]";
2059         }
2060         sign_changes $changesfile;
2061     }
2062
2063     supplementary_message(<<'END');
2064 Push failed, while uploading package(s) to the archive server.
2065 You can retry the upload of exactly these same files with dput of:
2066   $changesfile
2067 If that .changes file is broken, you will need to use a new version
2068 number for your next attempt at the upload.
2069 END
2070     my $host = access_cfg('upload-host','RETURN-UNDEF');
2071     my @hostarg = defined($host) ? ($host,) : ();
2072     runcmd_ordryrun @dput, @hostarg, $changesfile;
2073     printdone "pushed and uploaded $cversion";
2074
2075     supplementary_message('');
2076     responder_send_command("complete");
2077 }
2078
2079 sub cmd_clone {
2080     parseopts();
2081     notpushing();
2082     my $dstdir;
2083     badusage "-p is not allowed with clone; specify as argument instead"
2084         if defined $package;
2085     if (@ARGV==1) {
2086         ($package) = @ARGV;
2087     } elsif (@ARGV==2 && $ARGV[1] =~ m#^\w#) {
2088         ($package,$isuite) = @ARGV;
2089     } elsif (@ARGV==2 && $ARGV[1] =~ m#^[./]#) {
2090         ($package,$dstdir) = @ARGV;
2091     } elsif (@ARGV==3) {
2092         ($package,$isuite,$dstdir) = @ARGV;
2093     } else {
2094         badusage "incorrect arguments to dgit clone";
2095     }
2096     $dstdir ||= "$package";
2097
2098     if (stat_exists $dstdir) {
2099         fail "$dstdir already exists";
2100     }
2101
2102     my $cwd_remove;
2103     if ($rmonerror && !$dryrun_level) {
2104         $cwd_remove= getcwd();
2105         unshift @end, sub {
2106             return unless defined $cwd_remove;
2107             if (!chdir "$cwd_remove") {
2108                 return if $!==&ENOENT;
2109                 die "chdir $cwd_remove: $!";
2110             }
2111             rmtree($dstdir) or die "remove $dstdir: $!\n";
2112         };
2113     }
2114
2115     clone($dstdir);
2116     $cwd_remove = undef;
2117 }
2118
2119 sub branchsuite () {
2120     my $branch = cmdoutput_errok @git, qw(symbolic-ref HEAD);
2121     if ($branch =~ m#$lbranch_re#o) {
2122         return $1;
2123     } else {
2124         return undef;
2125     }
2126 }
2127
2128 sub fetchpullargs () {
2129     notpushing();
2130     if (!defined $package) {
2131         my $sourcep = parsecontrol('debian/control','debian/control');
2132         $package = getfield $sourcep, 'Source';
2133     }
2134     if (@ARGV==0) {
2135 #       $isuite = branchsuite();  # this doesn't work because dak hates canons
2136         if (!$isuite) {
2137             my $clogp = parsechangelog();
2138             $isuite = getfield $clogp, 'Distribution';
2139         }
2140         canonicalise_suite();
2141         progress "fetching from suite $csuite";
2142     } elsif (@ARGV==1) {
2143         ($isuite) = @ARGV;
2144         canonicalise_suite();
2145     } else {
2146         badusage "incorrect arguments to dgit fetch or dgit pull";
2147     }
2148 }
2149
2150 sub cmd_fetch {
2151     parseopts();
2152     fetchpullargs();
2153     fetch();
2154 }
2155
2156 sub cmd_pull {
2157     parseopts();
2158     fetchpullargs();
2159     pull();
2160 }
2161
2162 sub cmd_push {
2163     parseopts();
2164     pushing();
2165     badusage "-p is not allowed with dgit push" if defined $package;
2166     check_not_dirty();
2167     my $clogp = parsechangelog();
2168     $package = getfield $clogp, 'Source';
2169     my $specsuite;
2170     if (@ARGV==0) {
2171     } elsif (@ARGV==1) {
2172         ($specsuite) = (@ARGV);
2173     } else {
2174         badusage "incorrect arguments to dgit push";
2175     }
2176     $isuite = getfield $clogp, 'Distribution';
2177     if ($new_package) {
2178         local ($package) = $existing_package; # this is a hack
2179         canonicalise_suite();
2180     } else {
2181         canonicalise_suite();
2182     }
2183     if (defined $specsuite &&
2184         $specsuite ne $isuite &&
2185         $specsuite ne $csuite) {
2186             fail "dgit push: changelog specifies $isuite ($csuite)".
2187                 " but command line specifies $specsuite";
2188     }
2189     supplementary_message(<<'END');
2190 Push failed, while checking state of the archive.
2191 You can retry the push, after fixing the problem, if you like.
2192 END
2193     if (check_for_git()) {
2194         git_fetch_us();
2195     }
2196     my $forceflag = '';
2197     if (fetch_from_archive()) {
2198         if (is_fast_fwd(lrref(), 'HEAD')) {
2199             # ok
2200         } elsif (deliberately_not_fast_forward) {
2201             $forceflag = '+';
2202         } else {
2203             fail "dgit push: HEAD is not a descendant".
2204                 " of the archive's version.\n".
2205                 "dgit: To overwrite its contents,".
2206                 " use git merge -s ours ".lrref().".\n".
2207                 "dgit: To rewind history, if permitted by the archive,".
2208                 " use --deliberately-not-fast-forward";
2209         }
2210     } else {
2211         $new_package or
2212             fail "package appears to be new in this suite;".
2213                 " if this is intentional, use --new";
2214     }
2215     dopush($forceflag);
2216 }
2217
2218 #---------- remote commands' implementation ----------
2219
2220 sub cmd_remote_push_build_host {
2221     my ($nrargs) = shift @ARGV;
2222     my (@rargs) = @ARGV[0..$nrargs-1];
2223     @ARGV = @ARGV[$nrargs..$#ARGV];
2224     die unless @rargs;
2225     my ($dir,$vsnwant) = @rargs;
2226     # vsnwant is a comma-separated list; we report which we have
2227     # chosen in our ready response (so other end can tell if they
2228     # offered several)
2229     $debugprefix = ' ';
2230     $we_are_responder = 1;
2231     $us .= " (build host)";
2232
2233     pushing();
2234
2235     open PI, "<&STDIN" or die $!;
2236     open STDIN, "/dev/null" or die $!;
2237     open PO, ">&STDOUT" or die $!;
2238     autoflush PO 1;
2239     open STDOUT, ">&STDERR" or die $!;
2240     autoflush STDOUT 1;
2241
2242     $vsnwant //= 1;
2243     ($protovsn) = grep {
2244         $vsnwant =~ m{^(?:.*,)?$_(?:,.*)?$}
2245     } @rpushprotovsn_support;
2246
2247     fail "build host has dgit rpush protocol versions ".
2248         (join ",", @rpushprotovsn_support).
2249         " but invocation host has $vsnwant"
2250         unless defined $protovsn;
2251
2252     responder_send_command("dgit-remote-push-ready $protovsn");
2253
2254     changedir $dir;
2255     &cmd_push;
2256 }
2257
2258 sub cmd_remote_push_responder { cmd_remote_push_build_host(); }
2259 # ... for compatibility with proto vsn.1 dgit (just so that user gets
2260 #     a good error message)
2261
2262 our $i_tmp;
2263
2264 sub i_cleanup {
2265     local ($@, $?);
2266     my $report = i_child_report();
2267     if (defined $report) {
2268         printdebug "($report)\n";
2269     } elsif ($i_child_pid) {
2270         printdebug "(killing build host child $i_child_pid)\n";
2271         kill 15, $i_child_pid;
2272     }
2273     if (defined $i_tmp && !defined $initiator_tempdir) {
2274         changedir "/";
2275         eval { rmtree $i_tmp; };
2276     }
2277 }
2278
2279 END { i_cleanup(); }
2280
2281 sub i_method {
2282     my ($base,$selector,@args) = @_;
2283     $selector =~ s/\-/_/g;
2284     { no strict qw(refs); &{"${base}_${selector}"}(@args); }
2285 }
2286
2287 sub cmd_rpush {
2288     pushing();
2289     my $host = nextarg;
2290     my $dir;
2291     if ($host =~ m/^((?:[^][]|\[[^][]*\])*)\:/) {
2292         $host = $1;
2293         $dir = $'; #';
2294     } else {
2295         $dir = nextarg;
2296     }
2297     $dir =~ s{^-}{./-};
2298     my @rargs = ($dir);
2299     push @rargs, join ",", @rpushprotovsn_support;
2300     my @rdgit;
2301     push @rdgit, @dgit;
2302     push @rdgit, @ropts;
2303     push @rdgit, qw(remote-push-build-host), (scalar @rargs), @rargs;
2304     push @rdgit, @ARGV;
2305     my @cmd = (@ssh, $host, shellquote @rdgit);
2306     debugcmd "+",@cmd;
2307
2308     if (defined $initiator_tempdir) {
2309         rmtree $initiator_tempdir;
2310         mkdir $initiator_tempdir, 0700 or die "$initiator_tempdir: $!";
2311         $i_tmp = $initiator_tempdir;
2312     } else {
2313         $i_tmp = tempdir();
2314     }
2315     $i_child_pid = open2(\*RO, \*RI, @cmd);
2316     changedir $i_tmp;
2317     ($protovsn) = initiator_expect { m/^dgit-remote-push-ready (\S+)/ };
2318     die "$protovsn ?" unless grep { $_ eq $protovsn } @rpushprotovsn_support;
2319     $supplementary_message = '' unless $protovsn >= 3;
2320     for (;;) {
2321         my ($icmd,$iargs) = initiator_expect {
2322             m/^(\S+)(?: (.*))?$/;
2323             ($1,$2);
2324         };
2325         i_method "i_resp", $icmd, $iargs;
2326     }
2327 }
2328
2329 sub i_resp_progress ($) {
2330     my ($rhs) = @_;
2331     my $msg = protocol_read_bytes \*RO, $rhs;
2332     progress $msg;
2333 }
2334
2335 sub i_resp_supplementary_message ($) {
2336     my ($rhs) = @_;
2337     $supplementary_message = protocol_read_bytes \*RO, $rhs;
2338 }
2339
2340 sub i_resp_complete {
2341     my $pid = $i_child_pid;
2342     $i_child_pid = undef; # prevents killing some other process with same pid
2343     printdebug "waiting for build host child $pid...\n";
2344     my $got = waitpid $pid, 0;
2345     die $! unless $got == $pid;
2346     die "build host child failed $?" if $?;
2347
2348     i_cleanup();
2349     printdebug "all done\n";
2350     exit 0;
2351 }
2352
2353 sub i_resp_file ($) {
2354     my ($keyword) = @_;
2355     my $localname = i_method "i_localname", $keyword;
2356     my $localpath = "$i_tmp/$localname";
2357     stat_exists $localpath and
2358         badproto \*RO, "file $keyword ($localpath) twice";
2359     protocol_receive_file \*RO, $localpath;
2360     i_method "i_file", $keyword;
2361 }
2362
2363 our %i_param;
2364
2365 sub i_resp_param ($) {
2366     $_[0] =~ m/^(\S+) (.*)$/ or badproto \*RO, "bad param spec";
2367     $i_param{$1} = $2;
2368 }
2369
2370 sub i_resp_previously ($) {
2371     $_[0] =~ m#^(refs/tags/\S+)=(\w+)$#
2372         or badproto \*RO, "bad previously spec";
2373     my $r = system qw(git check-ref-format), $1;
2374     die "bad previously ref spec ($r)" if $r;
2375     $previously{$1} = $2;
2376 }
2377
2378 our %i_wanted;
2379
2380 sub i_resp_want ($) {
2381     my ($keyword) = @_;
2382     die "$keyword ?" if $i_wanted{$keyword}++;
2383     my @localpaths = i_method "i_want", $keyword;
2384     printdebug "[[  $keyword @localpaths\n";
2385     foreach my $localpath (@localpaths) {
2386         protocol_send_file \*RI, $localpath;
2387     }
2388     print RI "files-end\n" or die $!;
2389 }
2390
2391 our ($i_clogp, $i_version, $i_tag, $i_dscfn, $i_changesfn);
2392
2393 sub i_localname_parsed_changelog {
2394     return "remote-changelog.822";
2395 }
2396 sub i_file_parsed_changelog {
2397     ($i_clogp, $i_version, $i_tag, $i_dscfn) =
2398         push_parse_changelog "$i_tmp/remote-changelog.822";
2399     die if $i_dscfn =~ m#/|^\W#;
2400 }
2401
2402 sub i_localname_dsc {
2403     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2404     return $i_dscfn;
2405 }
2406 sub i_file_dsc { }
2407
2408 sub i_localname_changes {
2409     defined $i_dscfn or badproto \*RO, "dsc (before parsed-changelog)";
2410     $i_changesfn = $i_dscfn;
2411     $i_changesfn =~ s/\.dsc$/_dgit.changes/ or die;
2412     return $i_changesfn;
2413 }
2414 sub i_file_changes { }
2415
2416 sub i_want_signed_tag {
2417     printdebug Dumper(\%i_param, $i_dscfn);
2418     defined $i_param{'head'} && defined $i_dscfn && defined $i_clogp
2419         && defined $i_param{'csuite'}
2420         or badproto \*RO, "premature desire for signed-tag";
2421     my $head = $i_param{'head'};
2422     die if $head =~ m/[^0-9a-f]/ || $head !~ m/^../;
2423
2424     die unless $i_param{'csuite'} =~ m/^$suite_re$/;
2425     $csuite = $&;
2426     push_parse_dsc $i_dscfn, 'remote dsc', $i_version;
2427
2428     my $tagobjfn =
2429         push_mktag $head, $i_clogp, $i_tag,
2430             $i_dscfn,
2431             $i_changesfn, 'remote changes',
2432             sub { "tag$_[0]"; };
2433
2434     return $tagobjfn;
2435 }
2436
2437 sub i_want_signed_dsc_changes {
2438     rename "$i_dscfn.tmp","$i_dscfn" or die "$i_dscfn $!";
2439     sign_changes $i_changesfn;
2440     return ($i_dscfn, $i_changesfn);
2441 }
2442
2443 #---------- building etc. ----------
2444
2445 our $version;
2446 our $sourcechanges;
2447 our $dscfn;
2448
2449 #----- `3.0 (quilt)' handling -----
2450
2451 our $fakeeditorenv = 'DGIT_FAKE_EDITOR_QUILT';
2452
2453 sub quiltify_dpkg_commit ($$$;$) {
2454     my ($patchname,$author,$msg, $xinfo) = @_;
2455     $xinfo //= '';
2456
2457     mkpath '.git/dgit';
2458     my $descfn = ".git/dgit/quilt-description.tmp";
2459     open O, '>', $descfn or die "$descfn: $!";
2460     $msg =~ s/\s+$//g;
2461     $msg =~ s/\n/\n /g;
2462     $msg =~ s/^\s+$/ ./mg;
2463     print O <<END or die $!;
2464 Description: $msg
2465 Author: $author
2466 $xinfo
2467 ---
2468
2469 END
2470     close O or die $!;
2471
2472     {
2473         local $ENV{'EDITOR'} = cmdoutput qw(realpath --), $0;
2474         local $ENV{'VISUAL'} = $ENV{'EDITOR'};
2475         local $ENV{$fakeeditorenv} = cmdoutput qw(realpath --), $descfn;
2476         runcmd_ordryrun_local @dpkgsource, qw(--commit .), $patchname;
2477     }
2478 }
2479
2480 sub quiltify_trees_differ ($$) {
2481     my ($x,$y) = @_;
2482     # returns 1 iff the two tree objects differ other than in debian/
2483     local $/=undef;
2484     my @cmd = (@git, qw(diff-tree --name-only -z), $x, $y);
2485     my $diffs= cmdoutput @cmd;
2486     foreach my $f (split /\0/, $diffs) {
2487         next if $f eq 'debian';
2488         return 1;
2489     }
2490     return 0;
2491 }
2492
2493 sub quiltify_tree_sentinelfiles ($) {
2494     # lists the `sentinel' files present in the tree
2495     my ($x) = @_;
2496     my $r = cmdoutput @git, qw(ls-tree --name-only), $x,
2497         qw(-- debian/rules debian/control);
2498     $r =~ s/\n/,/g;
2499     return $r;
2500 }
2501
2502 sub quiltify ($$) {
2503     my ($clogp,$target) = @_;
2504
2505     # Quilt patchification algorithm
2506     #
2507     # We search backwards through the history of the main tree's HEAD
2508     # (T) looking for a start commit S whose tree object is identical
2509     # to to the patch tip tree (ie the tree corresponding to the
2510     # current dpkg-committed patch series).  For these purposes
2511     # `identical' disregards anything in debian/ - this wrinkle is
2512     # necessary because dpkg-source treates debian/ specially.
2513     #
2514     # We can only traverse edges where at most one of the ancestors'
2515     # trees differs (in changes outside in debian/).  And we cannot
2516     # handle edges which change .pc/ or debian/patches.  To avoid
2517     # going down a rathole we avoid traversing edges which introduce
2518     # debian/rules or debian/control.  And we set a limit on the
2519     # number of edges we are willing to look at.
2520     #
2521     # If we succeed, we walk forwards again.  For each traversed edge
2522     # PC (with P parent, C child) (starting with P=S and ending with
2523     # C=T) to we do this:
2524     #  - git checkout C
2525     #  - dpkg-source --commit with a patch name and message derived from C
2526     # After traversing PT, we git commit the changes which
2527     # should be contained within debian/patches.
2528
2529     changedir '../fake';
2530     remove_stray_gits();
2531     mktree_in_ud_here();
2532     rmtree '.pc';
2533     runcmd @git, qw(add -Af .);
2534     my $oldtiptree=git_write_tree();
2535     changedir '../work';
2536
2537     # The search for the path S..T is breadth-first.  We maintain a
2538     # todo list containing search nodes.  A search node identifies a
2539     # commit, and looks something like this:
2540     #  $p = {
2541     #      Commit => $git_commit_id,
2542     #      Child => $c,                          # or undef if P=T
2543     #      Whynot => $reason_edge_PC_unsuitable, # in @nots only
2544     #      Nontrivial => true iff $p..$c has relevant changes
2545     #  };
2546
2547     my @todo;
2548     my @nots;
2549     my $sref_S;
2550     my $max_work=100;
2551     my %considered; # saves being exponential on some weird graphs
2552
2553     my $t_sentinels = quiltify_tree_sentinelfiles $target;
2554
2555     my $not = sub {
2556         my ($search,$whynot) = @_;
2557         printdebug " search NOT $search->{Commit} $whynot\n";
2558         $search->{Whynot} = $whynot;
2559         push @nots, $search;
2560         no warnings qw(exiting);
2561         next;
2562     };
2563
2564     push @todo, {
2565         Commit => $target,
2566     };
2567
2568     while (@todo) {
2569         my $c = shift @todo;
2570         next if $considered{$c->{Commit}}++;
2571
2572         $not->($c, "maximum search space exceeded") if --$max_work <= 0;
2573
2574         printdebug "quiltify investigate $c->{Commit}\n";
2575
2576         # are we done?
2577         if (!quiltify_trees_differ $c->{Commit}, $oldtiptree) {
2578             printdebug " search finished hooray!\n";
2579             $sref_S = $c;
2580             last;
2581         }
2582
2583         if ($quilt_mode eq 'nofix') {
2584             fail "quilt fixup required but quilt mode is \`nofix'\n".
2585                 "HEAD commit $c->{Commit} differs from tree implied by ".
2586                 " debian/patches (tree object $oldtiptree)";
2587         }
2588         if ($quilt_mode eq 'smash') {
2589             printdebug " search quitting smash\n";
2590             last;
2591         }
2592
2593         my $c_sentinels = quiltify_tree_sentinelfiles $c->{Commit};
2594         $not->($c, "has $c_sentinels not $t_sentinels")
2595             if $c_sentinels ne $t_sentinels;
2596
2597         my $commitdata = cmdoutput @git, qw(cat-file commit), $c->{Commit};
2598         $commitdata =~ m/\n\n/;
2599         $commitdata =~ $`;
2600         my @parents = ($commitdata =~ m/^parent (\w+)$/gm);
2601         @parents = map { { Commit => $_, Child => $c } } @parents;
2602
2603         $not->($c, "root commit") if !@parents;
2604
2605         foreach my $p (@parents) {
2606             $p->{Nontrivial}= quiltify_trees_differ $p->{Commit},$c->{Commit};
2607         }
2608         my $ndiffers = grep { $_->{Nontrivial} } @parents;
2609         $not->($c, "merge ($ndiffers nontrivial parents)") if $ndiffers > 1;
2610
2611         foreach my $p (@parents) {
2612             printdebug "considering C=$c->{Commit} P=$p->{Commit}\n";
2613
2614             my @cmd= (@git, qw(diff-tree -r --name-only),
2615                       $p->{Commit},$c->{Commit}, qw(-- debian/patches .pc));
2616             my $patchstackchange = cmdoutput @cmd;
2617             if (length $patchstackchange) {
2618                 $patchstackchange =~ s/\n/,/g;
2619                 $not->($p, "changed $patchstackchange");
2620             }
2621
2622             printdebug " search queue P=$p->{Commit} ",
2623                 ($p->{Nontrivial} ? "NT" : "triv"),"\n";
2624             push @todo, $p;
2625         }
2626     }
2627
2628     if (!$sref_S) {
2629         printdebug "quiltify want to smash\n";
2630
2631         my $abbrev = sub {
2632             my $x = $_[0]{Commit};
2633             $x =~ s/(.*?[0-9a-z]{8})[0-9a-z]*$/$1/;
2634             return $x;
2635         };
2636         my $reportnot = sub {
2637             my ($notp) = @_;
2638             my $s = $abbrev->($notp);
2639             my $c = $notp->{Child};
2640             $s .= "..".$abbrev->($c) if $c;
2641             $s .= ": ".$notp->{Whynot};
2642             return $s;
2643         };
2644         if ($quilt_mode eq 'linear') {
2645             print STDERR "$us: quilt fixup cannot be linear.  Stopped at:\n";
2646             foreach my $notp (@nots) {
2647                 print STDERR "$us:  ", $reportnot->($notp), "\n";
2648             }
2649             fail "quilt fixup naive history linearisation failed.\n".
2650  "Use dpkg-source --commit by hand; or, --quilt=smash for one ugly patch";
2651         } elsif ($quilt_mode eq 'smash') {
2652         } elsif ($quilt_mode eq 'auto') {
2653             progress "quilt fixup cannot be linear, smashing...";
2654         } else {
2655             die "$quilt_mode ?";
2656         }
2657
2658         my $time = time;
2659         my $ncommits = 3;
2660         my $msg = cmdoutput @git, qw(log), "-n$ncommits";
2661
2662         quiltify_dpkg_commit "auto-$version-$target-$time",
2663             (getfield $clogp, 'Maintainer'),
2664             "Automatically generated patch ($clogp->{Version})\n".
2665             "Last (up to) $ncommits git changes, FYI:\n\n". $msg;
2666         return;
2667     }
2668
2669     progress "quiltify linearisation planning successful, executing...";
2670
2671     for (my $p = $sref_S;
2672          my $c = $p->{Child};
2673          $p = $p->{Child}) {
2674         printdebug "quiltify traverse $p->{Commit}..$c->{Commit}\n";
2675         next unless $p->{Nontrivial};
2676
2677         my $cc = $c->{Commit};
2678
2679         my $commitdata = cmdoutput @git, qw(cat-file commit), $cc;
2680         $commitdata =~ m/\n\n/ or die "$c ?";
2681         $commitdata = $`;
2682         my $msg = $'; #';
2683         $commitdata =~ m/^author (.*) \d+ [-+0-9]+$/m or die "$cc ?";
2684         my $author = $1;
2685
2686         $msg =~ s/^(.*)\n*/$1\n/ or die "$cc $msg ?";
2687
2688         my $title = $1;
2689         my $patchname = $title;
2690         $patchname =~ s/[.:]$//;
2691         $patchname =~ y/ A-Z/-a-z/;
2692         $patchname =~ y/-a-z0-9_.+=~//cd;
2693         $patchname =~ s/^\W/x-$&/;
2694         $patchname = substr($patchname,0,40);
2695         my $index;
2696         for ($index='';
2697              stat "debian/patches/$patchname$index";
2698              $index++) { }
2699         $!==ENOENT or die "$patchname$index $!";
2700
2701         runcmd @git, qw(checkout -q), $cc;
2702
2703         # We use the tip's changelog so that dpkg-source doesn't
2704         # produce complaining messages from dpkg-parsechangelog.  None
2705         # of the information dpkg-source gets from the changelog is
2706         # actually relevant - it gets put into the original message
2707         # which dpkg-source provides our stunt editor, and then
2708         # overwritten.
2709         runcmd @git, qw(checkout -q), $target, qw(debian/changelog);
2710
2711         quiltify_dpkg_commit "$patchname$index", $author, $msg,
2712             "X-Dgit-Generated: $clogp->{Version} $cc\n";
2713
2714         runcmd @git, qw(checkout -q), $cc, qw(debian/changelog);
2715     }
2716
2717     runcmd @git, qw(checkout -q master);
2718 }
2719
2720 sub build_maybe_quilt_fixup () {
2721     my $format=get_source_format;
2722     return unless madformat $format;
2723     # sigh
2724
2725     check_for_vendor_patches();
2726
2727     # Our objective is:
2728     #  - honour any existing .pc in case it has any strangeness
2729     #  - determine the git commit corresponding to the tip of
2730     #    the patch stack (if there is one)
2731     #  - if there is such a git commit, convert each subsequent
2732     #    git commit into a quilt patch with dpkg-source --commit
2733     #  - otherwise convert all the differences in the tree into
2734     #    a single git commit
2735     #
2736     # To do this we:
2737
2738     # Our git tree doesn't necessarily contain .pc.  (Some versions of
2739     # dgit would include the .pc in the git tree.)  If there isn't
2740     # one, we need to generate one by unpacking the patches that we
2741     # have.
2742     #
2743     # We first look for a .pc in the git tree.  If there is one, we
2744     # will use it.  (This is not the normal case.)
2745     #
2746     # Otherwise need to regenerate .pc so that dpkg-source --commit
2747     # can work.  We do this as follows:
2748     #     1. Collect all relevant .orig from parent directory
2749     #     2. Generate a debian.tar.gz out of
2750     #         debian/{patches,rules,source/format}
2751     #     3. Generate a fake .dsc containing just these fields:
2752     #          Format Source Version Files
2753     #     4. Extract the fake .dsc
2754     #        Now the fake .dsc has a .pc directory.
2755     # (In fact we do this in every case, because in future we will
2756     # want to search for a good base commit for generating patches.)
2757     #
2758     # Then we can actually do the dpkg-source --commit
2759     #     1. Make a new working tree with the same object
2760     #        store as our main tree and check out the main
2761     #        tree's HEAD.
2762     #     2. Copy .pc from the fake's extraction, if necessary
2763     #     3. Run dpkg-source --commit
2764     #     4. If the result has changes to debian/, then
2765     #          - git-add them them
2766     #          - git-add .pc if we had a .pc in-tree
2767     #          - git-commit
2768     #     5. If we had a .pc in-tree, delete it, and git-commit
2769     #     6. Back in the main tree, fast forward to the new HEAD
2770
2771     my $clogp = parsechangelog();
2772     my $headref = git_rev_parse('HEAD');
2773
2774     prep_ud();
2775     changedir $ud;
2776
2777     my $upstreamversion=$version;
2778     $upstreamversion =~ s/-[^-]*$//;
2779
2780     my $fakeversion="$upstreamversion-~~DGITFAKE";
2781
2782     my $fakedsc=new IO::File 'fake.dsc', '>' or die $!;
2783     print $fakedsc <<END or die $!;
2784 Format: 3.0 (quilt)
2785 Source: $package
2786 Version: $fakeversion
2787 Files:
2788 END
2789
2790     my $dscaddfile=sub {
2791         my ($b) = @_;
2792
2793         my $md = new Digest::MD5;
2794
2795         my $fh = new IO::File $b, '<' or die "$b $!";
2796         stat $fh or die $!;
2797         my $size = -s _;
2798
2799         $md->addfile($fh);
2800         print $fakedsc " ".$md->hexdigest." $size $b\n" or die $!;
2801     };
2802
2803     foreach my $f (<../../../../*>) { #/){
2804         my $b=$f; $b =~ s{.*/}{};
2805         next unless is_orig_file $b, srcfn $upstreamversion,'';
2806         link_ltarget $f, $b or die "$b $!";
2807         $dscaddfile->($b);
2808     }
2809
2810     my @files=qw(debian/source/format debian/rules);
2811     foreach my $maybe (qw(debian/patches)) {
2812         next unless stat_exists "../../../$maybe";
2813         push @files, $maybe;
2814     }
2815
2816     my $debtar= srcfn $fakeversion,'.debian.tar.gz';
2817     runcmd qw(env GZIP=-1 tar -zcf), "./$debtar", qw(-C ../../..), @files;
2818
2819     $dscaddfile->($debtar);
2820     close $fakedsc or die $!;
2821
2822     runcmd qw(sh -ec), 'exec dpkg-source --no-check -x fake.dsc >/dev/null';
2823
2824     my $fakexdir= $package.'-'.(stripepoch $upstreamversion);
2825     rename $fakexdir, "fake" or die "$fakexdir $!";
2826
2827     mkdir "work" or die $!;
2828     changedir "work";
2829     mktree_in_ud_here();
2830     runcmd @git, qw(reset --hard), $headref;
2831
2832     my $mustdeletepc=0;
2833     if (stat_exists ".pc") {
2834         -d _ or die;
2835         progress "Tree already contains .pc - will use it then delete it.";
2836         $mustdeletepc=1;
2837     } else {
2838         rename '../fake/.pc','.pc' or die $!;
2839     }
2840
2841     quiltify($clogp,$headref);
2842
2843     if (!open P, '>>', ".pc/applied-patches") {
2844         $!==&ENOENT or die $!;
2845     } else {
2846         close P;
2847     }
2848
2849     commit_quilty_patch();
2850
2851     if ($mustdeletepc) {
2852         runcmd @git, qw(rm -rqf .pc);
2853         commit_admin "Commit removal of .pc (quilt series tracking data)";
2854     }
2855
2856     changedir '../../../..';
2857     runcmd @git, qw(pull --ff-only -q .git/dgit/unpack/work master);
2858 }
2859
2860 sub quilt_fixup_editor () {
2861     my $descfn = $ENV{$fakeeditorenv};
2862     my $editing = $ARGV[$#ARGV];
2863     open I1, '<', $descfn or die "$descfn: $!";
2864     open I2, '<', $editing or die "$editing: $!";
2865     unlink $editing or die "$editing: $!";
2866     open O, '>', $editing or die "$editing: $!";
2867     while (<I1>) { print O or die $!; } I1->error and die $!;
2868     my $copying = 0;
2869     while (<I2>) {
2870         $copying ||= m/^\-\-\- /;
2871         next unless $copying;
2872         print O or die $!;
2873     }
2874     I2->error and die $!;
2875     close O or die $1;
2876     exit 0;
2877 }
2878
2879 #----- other building -----
2880
2881 our $suppress_clean;
2882
2883 sub clean_tree () {
2884     return if $suppress_clean;
2885     if ($cleanmode eq 'dpkg-source') {
2886         runcmd_ordryrun_local @dpkgbuildpackage, qw(-T clean);
2887     } elsif ($cleanmode eq 'dpkg-source-d') {
2888         runcmd_ordryrun_local @dpkgbuildpackage, qw(-d -T clean);
2889     } elsif ($cleanmode eq 'git') {
2890         runcmd_ordryrun_local @git, qw(clean -xdf);
2891     } elsif ($cleanmode eq 'git-ff') {
2892         runcmd_ordryrun_local @git, qw(clean -xdff);
2893     } elsif ($cleanmode eq 'check') {
2894         my $leftovers = cmdoutput @git, qw(clean -xdn);
2895         if (length $leftovers) {
2896             print STDERR $leftovers, "\n" or die $!;
2897             fail "tree contains uncommitted files and --clean=check specified";
2898         }
2899     } elsif ($cleanmode eq 'none') {
2900     } else {
2901         die "$cleanmode ?";
2902     }
2903 }
2904
2905 sub cmd_clean () {
2906     badusage "clean takes no additional arguments" if @ARGV;
2907     notpushing();
2908     clean_tree();
2909 }
2910
2911 sub build_prep () {
2912     notpushing();
2913     badusage "-p is not allowed when building" if defined $package;
2914     check_not_dirty();
2915     clean_tree();
2916     my $clogp = parsechangelog();
2917     $isuite = getfield $clogp, 'Distribution';
2918     $package = getfield $clogp, 'Source';
2919     $version = getfield $clogp, 'Version';
2920     build_maybe_quilt_fixup();
2921 }
2922
2923 sub changesopts_initial () {
2924     my @opts =@changesopts[1..$#changesopts];
2925 }
2926
2927 sub changesopts_version () {
2928     if (!defined $changes_since_version) {
2929         my @vsns = archive_query('archive_query');
2930         my @quirk = access_quirk();
2931         if ($quirk[0] eq 'backports') {
2932             local $isuite = $quirk[2];
2933             local $csuite;
2934             canonicalise_suite();
2935             push @vsns, archive_query('archive_query');
2936         }
2937         if (@vsns) {
2938             @vsns = map { $_->[0] } @vsns;
2939             @vsns = sort { -version_compare($a, $b) } @vsns;
2940             $changes_since_version = $vsns[0];
2941             progress "changelog will contain changes since $vsns[0]";
2942         } else {
2943             $changes_since_version = '_';
2944             progress "package seems new, not specifying -v<version>";
2945         }
2946     }
2947     if ($changes_since_version ne '_') {
2948         return ("-v$changes_since_version");
2949     } else {
2950         return ();
2951     }
2952 }
2953
2954 sub changesopts () {
2955     return (changesopts_initial(), changesopts_version());
2956 }
2957
2958 sub massage_dbp_args ($;$) {
2959     my ($cmd,$xargs) = @_;
2960     if ($cleanmode eq 'dpkg-source') {
2961         $suppress_clean = 1;
2962         return;
2963     }
2964     debugcmd '#massaging#', @$cmd if $debuglevel>1;
2965     my @newcmd = shift @$cmd;
2966     # -nc has the side effect of specifying -b if nothing else specified
2967     push @newcmd, '-nc';
2968     # and some combinations of -S, -b, et al, are errors, rather than
2969     # later simply overriding earlier
2970     push @newcmd, '-F' unless grep { m/^-[bBASF]$/ } (@$cmd, @$xargs);
2971     push @newcmd, @$cmd;
2972     @$cmd = @newcmd;
2973 }
2974
2975 sub cmd_build {
2976     my @dbp = (@dpkgbuildpackage, qw(-us -uc), changesopts_initial(), @ARGV);
2977     massage_dbp_args \@dbp;
2978     build_prep();
2979     push @dbp, changesopts_version();
2980     runcmd_ordryrun_local @dbp;
2981     printdone "build successful\n";
2982 }
2983
2984 sub cmd_gbp_build {
2985     my @dbp = @dpkgbuildpackage;
2986     massage_dbp_args \@dbp, \@ARGV;
2987
2988     my @cmd;
2989     if (length executable_on_path('git-buildpackage')) {
2990         @cmd = qw(git-buildpackage);
2991     } else {
2992         @cmd = qw(gbp buildpackage);
2993     }
2994     push @cmd, (qw(-us -uc --git-no-sign-tags), "--git-builder=@dbp");
2995
2996     if ($cleanmode eq 'dpkg-source') {
2997         $suppress_clean = 1;
2998     } else {
2999         push @cmd, '--git-cleaner=true';
3000     }
3001     build_prep();
3002     unless (grep { m/^--git-debian-branch|^--git-ignore-branch/ } @ARGV) {
3003         canonicalise_suite();
3004         push @cmd, "--git-debian-branch=".lbranch();
3005     }
3006     push @cmd, changesopts();
3007     runcmd_ordryrun_local @cmd, @ARGV;
3008     printdone "build successful\n";
3009 }
3010 sub cmd_git_build { cmd_gbp_build(); } # compatibility with <= 1.0
3011
3012 sub build_source {
3013     if ($cleanmode =~ m/^dpkg-source/) {
3014         # dpkg-source will clean, so we shouldn't
3015         $suppress_clean = 1;
3016     }
3017     build_prep();
3018     $sourcechanges = "${package}_".(stripepoch $version)."_source.changes";
3019     $dscfn = dscfn($version);
3020     if ($cleanmode eq 'dpkg-source') {
3021         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S)),
3022             changesopts();
3023     } elsif ($cleanmode eq 'dpkg-source-d') {
3024         runcmd_ordryrun_local (@dpkgbuildpackage, qw(-us -uc -S -d)),
3025             changesopts();
3026     } else {
3027         my $pwd = must_getcwd();
3028         my $leafdir = basename $pwd;
3029         changedir "..";
3030         runcmd_ordryrun_local @dpkgsource, qw(-b --), $leafdir;
3031         changedir $pwd;
3032         runcmd_ordryrun_local qw(sh -ec),
3033             'exec >$1; shift; exec "$@"','x',
3034             "../$sourcechanges",
3035             @dpkggenchanges, qw(-S), changesopts();
3036     }
3037 }
3038
3039 sub cmd_build_source {
3040     badusage "build-source takes no additional arguments" if @ARGV;
3041     build_source();
3042     printdone "source built, results in $dscfn and $sourcechanges";
3043 }
3044
3045 sub cmd_sbuild {
3046     build_source();
3047     changedir "..";
3048     my $pat = "${package}_".(stripepoch $version)."_*.changes";
3049     if (act_local()) {
3050         stat_exists $dscfn or fail "$dscfn (in parent directory): $!";
3051         stat_exists $sourcechanges
3052             or fail "$sourcechanges (in parent directory): $!";
3053         foreach my $cf (glob $pat) {
3054             next if $cf eq $sourcechanges;
3055             unlink $cf or fail "remove $cf: $!";
3056         }
3057     }
3058     runcmd_ordryrun_local @sbuild, @ARGV, qw(-d), $isuite, $dscfn;
3059     my @changesfiles = glob $pat;
3060     @changesfiles = sort {
3061         ($b =~ m/_source\.changes$/ <=> $a =~ m/_source\.changes$/)
3062             or $a cmp $b
3063     } @changesfiles;
3064     fail "wrong number of different changes files (@changesfiles)"
3065         unless @changesfiles;
3066     runcmd_ordryrun_local @mergechanges, @changesfiles;
3067     my $multichanges = "${package}_".(stripepoch $version)."_multi.changes";
3068     if (act_local()) {
3069         stat_exists $multichanges or fail "$multichanges: $!";
3070     }
3071     printdone "build successful, results in $multichanges\n" or die $!;
3072 }
3073
3074 sub cmd_quilt_fixup {
3075     badusage "incorrect arguments to dgit quilt-fixup" if @ARGV;
3076     my $clogp = parsechangelog();
3077     $version = getfield $clogp, 'Version';
3078     $package = getfield $clogp, 'Source';
3079     build_maybe_quilt_fixup();
3080 }
3081
3082 sub cmd_archive_api_query {
3083     badusage "need only 1 subpath argument" unless @ARGV==1;
3084     my ($subpath) = @ARGV;
3085     my @cmd = archive_api_query_cmd($subpath);
3086     debugcmd ">",@cmd;
3087     exec @cmd or fail "exec curl: $!\n";
3088 }
3089
3090 sub cmd_clone_dgit_repos_server {
3091     badusage "need destination argument" unless @ARGV==1;
3092     my ($destdir) = @ARGV;
3093     $package = '_dgit-repos-server';
3094     my @cmd = (@git, qw(clone), access_giturl(), $destdir);
3095     debugcmd ">",@cmd;
3096     exec @cmd or fail "exec git clone: $!\n";
3097 }
3098
3099 sub cmd_setup_mergechangelogs {
3100     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3101     setup_mergechangelogs(1);
3102 }
3103
3104 sub cmd_setup_useremail {
3105     badusage "no arguments allowed to dgit setup-mergechangelogs" if @ARGV;
3106     setup_useremail(1);
3107 }
3108
3109 sub cmd_setup_new_tree {
3110     badusage "no arguments allowed to dgit setup-tree" if @ARGV;
3111     setup_new_tree();
3112 }
3113
3114 #---------- argument parsing and main program ----------
3115
3116 sub cmd_version {
3117     print "dgit version $our_version\n" or die $!;
3118     exit 0;
3119 }
3120
3121 our (%valopts_long, %valopts_short);
3122 our @rvalopts;
3123
3124 sub defvalopt ($$$$) {
3125     my ($long,$short,$val_re,$how) = @_;
3126     my $oi = { Long => $long, Short => $short, Re => $val_re, How => $how };
3127     $valopts_long{$long} = $oi;
3128     $valopts_short{$short} = $oi;
3129     # $how subref should:
3130     #   do whatever assignemnt or thing it likes with $_[0]
3131     #   if the option should not be passed on to remote, @rvalopts=()
3132     # or $how can be a scalar ref, meaning simply assign the value
3133 }
3134
3135 defvalopt '--since-version', '-v', '[^_]+|_', \$changes_since_version;
3136 defvalopt '--distro',        '-d', '.+',      \$idistro;
3137 defvalopt '',                '-k', '.+',      \$keyid;
3138 defvalopt '--existing-package','', '.*',      \$existing_package;
3139 defvalopt '--build-products-dir','','.*',     \$buildproductsdir;
3140 defvalopt '--clean',       '', $cleanmode_re, \$cleanmode;
3141 defvalopt '--quilt',     '', $quilt_modes_re, \$quilt_mode;
3142
3143 defvalopt '', '-c', '.*=.*', sub { push @git, '-c', @_; };
3144
3145 defvalopt '', '-C', '.+', sub {
3146     ($changesfile) = (@_);
3147     if ($changesfile =~ s#^(.*)/##) {
3148         $buildproductsdir = $1;
3149     }
3150 };
3151
3152 defvalopt '--initiator-tempdir','','.*', sub {
3153     ($initiator_tempdir) = (@_);
3154     $initiator_tempdir =~ m#^/# or
3155         badusage "--initiator-tempdir must be used specify an".
3156         " absolute, not relative, directory."
3157 };
3158
3159 sub parseopts () {
3160     my $om;
3161
3162     if (defined $ENV{'DGIT_SSH'}) {
3163         @ssh = string_to_ssh $ENV{'DGIT_SSH'};
3164     } elsif (defined $ENV{'GIT_SSH'}) {
3165         @ssh = ($ENV{'GIT_SSH'});
3166     }
3167
3168     my $oi;
3169     my $val;
3170     my $valopt = sub {
3171         my ($what) = @_;
3172         @rvalopts = ($_);
3173         if (!defined $val) {
3174             badusage "$what needs a value" unless @ARGV;
3175             $val = shift @ARGV;
3176             push @rvalopts, $val;
3177         }
3178         badusage "bad value \`$val' for $what" unless
3179             $val =~ m/^$oi->{Re}$(?!\n)/s;
3180         my $how = $oi->{How};
3181         if (ref($how) eq 'SCALAR') {
3182             $$how = $val;
3183         } else {
3184             $how->($val);
3185         }
3186         push @ropts, @rvalopts;
3187     };
3188
3189     while (@ARGV) {
3190         last unless $ARGV[0] =~ m/^-/;
3191         $_ = shift @ARGV;
3192         last if m/^--?$/;
3193         if (m/^--/) {
3194             if (m/^--dry-run$/) {
3195                 push @ropts, $_;
3196                 $dryrun_level=2;
3197             } elsif (m/^--damp-run$/) {
3198                 push @ropts, $_;
3199                 $dryrun_level=1;
3200             } elsif (m/^--no-sign$/) {
3201                 push @ropts, $_;
3202                 $sign=0;
3203             } elsif (m/^--help$/) {
3204                 cmd_help();
3205             } elsif (m/^--version$/) {
3206                 cmd_version();
3207             } elsif (m/^--new$/) {
3208                 push @ropts, $_;
3209                 $new_package=1;
3210             } elsif (m/^--([-0-9a-z]+)=(.+)/s &&
3211                      ($om = $opts_opt_map{$1}) &&
3212                      length $om->[0]) {
3213                 push @ropts, $_;
3214                 $om->[0] = $2;
3215             } elsif (m/^--([-0-9a-z]+):(.*)/s &&
3216                      !$opts_opt_cmdonly{$1} &&
3217                      ($om = $opts_opt_map{$1})) {
3218                 push @ropts, $_;
3219                 push @$om, $2;
3220             } elsif (m/^--ignore-dirty$/s) {
3221                 push @ropts, $_;
3222                 $ignoredirty = 1;
3223             } elsif (m/^--no-quilt-fixup$/s) {
3224                 push @ropts, $_;
3225                 $quilt_mode = 'nocheck';
3226             } elsif (m/^--no-rm-on-error$/s) {
3227                 push @ropts, $_;
3228                 $rmonerror = 0;
3229             } elsif (m/^--deliberately-($deliberately_re)$/s) {
3230                 push @ropts, $_;
3231                 push @deliberatelies, $&;
3232             } elsif (m/^(--[-0-9a-z]+)(=|$)/ && ($oi = $valopts_long{$1})) {
3233                 $val = $2 ? $' : undef; #';
3234                 $valopt->($oi->{Long});
3235             } else {
3236                 badusage "unknown long option \`$_'";
3237             }
3238         } else {
3239             while (m/^-./s) {
3240                 if (s/^-n/-/) {
3241                     push @ropts, $&;
3242                     $dryrun_level=2;
3243                 } elsif (s/^-L/-/) {
3244                     push @ropts, $&;
3245                     $dryrun_level=1;
3246                 } elsif (s/^-h/-/) {
3247                     cmd_help();
3248                 } elsif (s/^-D/-/) {
3249                     push @ropts, $&;
3250                     $debuglevel++;
3251                     enabledebug();
3252                 } elsif (s/^-N/-/) {
3253                     push @ropts, $&;
3254                     $new_package=1;
3255                 } elsif (m/^-m/) {
3256                     push @ropts, $&;
3257                     push @changesopts, $_;
3258                     $_ = '';
3259                 } elsif (s/^-wn$//s) {
3260                     push @ropts, $&;
3261                     $cleanmode = 'none';
3262                 } elsif (s/^-wg$//s) {
3263                     push @ropts, $&;
3264                     $cleanmode = 'git';
3265                 } elsif (s/^-wgf$//s) {
3266                     push @ropts, $&;
3267                     $cleanmode = 'git-ff';
3268                 } elsif (s/^-wd$//s) {
3269                     push @ropts, $&;
3270                     $cleanmode = 'dpkg-source';
3271                 } elsif (s/^-wdd$//s) {
3272                     push @ropts, $&;
3273                     $cleanmode = 'dpkg-source-d';
3274                 } elsif (s/^-wc$//s) {
3275                     push @ropts, $&;
3276                     $cleanmode = 'check';
3277                 } elsif (m/^-[a-zA-Z]/ && ($oi = $valopts_short{$&})) {
3278                     $val = $'; #';
3279                     $val = undef unless length $val;
3280                     $valopt->($oi->{Short});
3281                     $_ = '';
3282                 } else {
3283                     badusage "unknown short option \`$_'";
3284                 }
3285             }
3286         }
3287     }
3288 }
3289
3290 sub finalise_opts_opts () {
3291     foreach my $k (keys %opts_opt_map) {
3292         my $om = $opts_opt_map{$k};
3293
3294         my $v = access_cfg("cmd-$k", 'RETURN-UNDEF');
3295         if (defined $v) {
3296             badcfg "cannot set command for $k"
3297                 unless length $om->[0];
3298             $om->[0] = $v;
3299         }
3300
3301         foreach my $c (access_cfg_cfgs("opts-$k")) {
3302             my $vl = $gitcfg{$c};
3303             printdebug "CL $c ",
3304                 ($vl ? join " ", map { shellquote } @$vl : ""),
3305                 "\n" if $debuglevel >= 4;
3306             next unless $vl;
3307             badcfg "cannot configure options for $k"
3308                 if $opts_opt_cmdonly{$k};
3309             my $insertpos = $opts_cfg_insertpos{$k};
3310             @$om = ( @$om[0..$insertpos-1],
3311                      @$vl,
3312                      @$om[$insertpos..$#$om] );
3313         }
3314     }
3315 }
3316
3317 if ($ENV{$fakeeditorenv}) {
3318     git_slurp_config();
3319     quilt_fixup_editor();
3320 }
3321
3322 parseopts();
3323 git_slurp_config();
3324
3325 print STDERR "DRY RUN ONLY\n" if $dryrun_level > 1;
3326 print STDERR "DAMP RUN - WILL MAKE LOCAL (UNSIGNED) CHANGES\n"
3327     if $dryrun_level == 1;
3328 if (!@ARGV) {
3329     print STDERR $helpmsg or die $!;
3330     exit 8;
3331 }
3332 my $cmd = shift @ARGV;
3333 $cmd =~ y/-/_/;
3334
3335 if (!defined $quilt_mode) {
3336     local $access_forpush;
3337     $quilt_mode = cfg('dgit.force.quilt-mode', 'RETURN-UNDEF')
3338         // access_cfg('quilt-mode', 'RETURN-UNDEF')
3339         // 'linear';
3340     $quilt_mode =~ m/^($quilt_modes_re)$/
3341         or badcfg "unknown quilt-mode \`$quilt_mode'";
3342     $quilt_mode = $1;
3343 }
3344
3345 if (!defined $cleanmode) {
3346     local $access_forpush;
3347     $cleanmode = access_cfg('clean-mode', 'RETURN-UNDEF');
3348     $cleanmode //= 'dpkg-source';
3349
3350     badcfg "unknown clean-mode \`$cleanmode'" unless
3351         $cleanmode =~ m/^($cleanmode_re)$(?!\n)/s;
3352 }
3353
3354 my $fn = ${*::}{"cmd_$cmd"};
3355 $fn or badusage "unknown operation $cmd";
3356 $fn->();