badcommit-fixup

   1 #!/usr/bin/perl -w
   2
   3 # usage:
   4 #   .../badcommit-fixup --test
   5 #   .../badcommit-fixup --real
   6
   7 use strict;
   8
   9 use POSIX;
  10 use IPC::Open2;
  11 use Data::Dumper;
  12
  13 my $real;
  14
  15 foreach my $a (@ARGV) {
  16     if ($a eq '--test') {
  17         $real = 0;
  18     } elsif ($a eq '--real') {
  19         $real = 1;
  20     } else {
  21         die "$a ?";
  22     }
  23 }
  24
  25 die unless defined $real;
  26
  27 my $gcfpid = open2 \*GCFO, \*GCFI, 'git cat-file --batch' or die $!;
  28
  29 our %count;
  30
  31 no warnings qw(recursion);
  32
  33 sub runcmd {
  34     system @_ and die "@_ $! $?";
  35 }
  36
  37 $!=0; $?=0;
  38 my $bare = `git rev-parse --is-bare-repository`;
  39 die "$? $!" if $?;
  40 chomp $bare or die;
  41
  42 sub getobj ($$) {
  43     my ($obj, $type) = @_;
  44     print GCFI $obj, "\n" or die $!;
  45     my $x = <GCFO>;
  46     my ($gtype, $gsize) = $x =~ m/^\w+ (\w+) (\d+)\n/ or die "$obj ?";
  47     $gtype eq $type or die "$obj $gtype != $type ?";
  48     my $gdata;
  49     (read GCFO, $gdata, $gsize) == $gsize or die "$obj $!";
  50     $x = <GCFO>;
  51     $x eq "\n" or die "$obj ($_) $!";
  52     $count{inspected}++;
  53     return $gdata;
  54 }
  55
  56 sub hashobj ($$) {
  57     my ($data,$type) = @_;
  58     my $gwopid = open2 \*GWO, \*GWI,
  59         "git hash-object -w -t $type --stdin"
  60         or die $!;
  61     print GWI $data or die $!;
  62     close GWI or die $!;
  63     $_ = <GWO>;
  64     close GWO or die $!;
  65     waitpid $gwopid,0 == $gwopid or die $!;
  66     die $? if $?;
  67     m/^(\w+)\n/ or die "$_ ?";
  68     $count{"rewritten $type"}++;
  69     return $1;
  70 }
  71
  72 our %memo;
  73
  74 sub rewrite_commit ($);
  75 sub rewrite_commit ($) {
  76     my ($obj) = @_;
  77     my $m = \ $memo{$obj};
  78     return $$m if defined $$m;
  79     my $olddata = getobj $obj, 'commit';
  80     $olddata =~ m/(?<=\n)(?=\n)/ or die "$obj ?";
  81     my $msg = $';
  82     local $_ = $`;
  83     s{^(parent )(\w+)$}{ $1 . rewrite_commit($2) }gme;
  84     $count{'fix overwrite'} += s{^commiter }{committer }gm;
  85     if (!m{^author }m && !m{^committer }m) {
  86         m{^parent (\w+)}m or die "$obj ?";
  87         my $parent = getobj $1, 'commit';
  88         $parent =~ m/^(?:.+\n)+(author .*\ncommitter .*\n)/;
  89         m/\n$/ or die "$obj ?";
  90         $_ .= $1;
  91         $count{'fix import'}++;
  92     }
  93     my $newdata = $_.$msg;
  94     my $newobj;
  95     if ($newdata eq $olddata) {
  96         $newobj = $obj;
  97         $count{unchanged}++;
  98     } else {
  99         $newobj = hashobj $newdata, 'commit';
 100     }
 101     $$m= $newobj;
 102     return $newobj;
 103 }
 104
 105 sub rewrite_commit_adddummy ($$$) {
 106     my ($ref, $veryold, $old) = @_;
 107
 108     die "$bare ?" unless $bare eq 'true';
 109
 110     my $td = 'dgit-broken-fixup.tmp';
 111     runcmd qw(rm -rf), $td;
 112     mkdir $td, 0700 or die "$td $!";
 113     chdir $td or die $!;
 114     runcmd qw(git init -q);
 115     runcmd qw(git config gc.auto 0);
 116     runcmd qw(rm -rf .git/objects);
 117     symlink "../../objects", ".git/objects" or die $!;
 118     runcmd qw(git checkout -q), $old;
 119
 120     open C, "debian/changelog" or die $!;
 121     my $clog = do {
 122         local $/ = undef;
 123         <C>;
 124     };
 125     C->error and die $!;
 126     close C or die $!;
 127     defined $clog or die $!;
 128
 129     $!=0; $?=0;
 130     my $v = `dpkg-parsechangelog`;
 131     die "$ref $veryold $old $? $!" if $?;
 132     $v =~ m/^Source: (\S+)$/m or die "$ref $veryold $old ?";
 133     my $pkg = $1;
 134     $v =~ m/^Version: (\S+)$/m or die "$ref $veryold $old ?";
 135     my $vsn = $1;
 136     $vsn .= "+~dgitfix";
 137
 138     open C, ">", "debian/changelog" or die $!;
 139     print C <<END;
 140 $pkg ($vsn) UNRELEASED; urgency=low
 141
 142   * Additional commit, with slightly incremented version number,
 143     to override bad commits generated by dgit due to #849041.
 144   * No changes to the package.
 145   * Not uploaded anywhere.
 146
 147  -- Ian Jackson <ijackson\@chiark.greenend.org.uk>  Thu, 05 Jan 2017 17:58:21 +0000
 148
 149 END
 150     print C $clog or die $!;
 151     close C or die $!;
 152
 153     runcmd qw(git commit -q),
 154         '--author=Ian Jackson <ijackson@chiark.greenend.org.uk>',
 155         qw(-m), 'Dummy changelog entry to work around #849041 fallout',
 156         qw(debian/changelog);
 157
 158     $!=0; $?=0;
 159     my $new = `git rev-parse HEAD`;
 160     die "$? $!" if $?;
 161     chomp $new or die;
 162
 163     chdir '..' or die $!;
 164     runcmd qw(rm -rf), $td;
 165
 166     $count{dummyadded}++;
 167
 168     return $new;
 169 }
 170
 171 sub rewrite_tag ($) {
 172     my ($obj) = @_;
 173     $_ = getobj $obj, 'tag';
 174     m/^type (\w+)\n/m or die "$obj ?";
 175     if ($1 ne 'commit') {
 176         $count{"oddtags $1"}++;
 177         return $obj;
 178     }
 179     m/^object (\w+)\n/m or die "$obj ?";
 180     my $oldref = $1;
 181     my $newref = rewrite_commit $oldref;
 182     if ($oldref eq $newref) {
 183         return $obj;
 184     }
 185     s/^(object )\w+$/ $1.$newref /me or die "$obj ($_) ?";
 186     s/^-----BEGIN PGP SIGNATURE-----\n.*^-----END PGP SIGNATURE-----\n$//sm;
 187     return hashobj $_, 'tag';
 188 }
 189
 190 $!=0; $?=0;
 191 my $refs=`git for-each-ref`;
 192 die "$? $!" if $?;
 193
 194 chomp $refs;
 195
 196 our @updates;
 197
 198 foreach my $rline (split /\n/, $refs) {
 199     my ($obj, $type, $refname) =
 200         $rline =~ m/^(\w+)\s+(\w+)\s+(\S.*)/
 201         or die "$_ ?";
 202     my $rewrite;
 203     if ($type eq 'commit') {
 204         $rewrite = rewrite_commit($obj);
 205         if ($refname =~ m{^refs/dgit/[^/]+$} &&
 206            $rewrite ne $obj) {
 207             $rewrite = rewrite_commit_adddummy $refname, $obj, $rewrite;
 208         }
 209     } elsif ($type eq 'tag') {
 210         $rewrite = rewrite_tag($obj);
 211     } else {
 212         warn "ref $refname refers to $type\n";
 213         next;
 214     }
 215     next if $rewrite eq $obj;
 216     push @updates, [ $refname, $obj, $rewrite ];
 217 }
 218
 219 our $worktree;
 220
 221 #print Dumper(\@updates);
 222
 223 open U, "|git update-ref -m 'dgit bad commit fixup' --stdin" or die $!;
 224
 225 if ($real && $bare eq 'false') {
 226     print "detaching your HEAD\n" or die $!;
 227     runcmd 'git checkout --detach';
 228 }
 229
 230 for my $up (@updates) {
 231     my ($ref, $old, $new) = @$up;
 232     my $otherref = $ref;
 233     $otherref =~ s{^refs/}{};
 234     if ($real) {
 235         print U <<END or die $!;
 236 create refs/dgit-badcommit/$otherref $old
 237 update $ref $new $old
 238 END
 239     } else {
 240         print U <<END or die $!;
 241 update refs/dgit-badfixuptest/$otherref $new
 242 END
 243     }
 244 }
 245
 246 $?=0; $!=0;
 247 close U or die "$? $!";
 248 die $? if $?;
 249
 250 print Dumper(\%count);
 251
 252 if ($real) {
 253     print "old values saved in refs/dgit-badcommit/\n" or die $!;
 254 } else {
 255     print "testing output saved in refs/dgit-badfixuptest/\n" or die $!;
 256 }