Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11
  12 BEGIN {
  13     use Exporter   ();
  14     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  15
  16     $VERSION     = 1.00;
  17     @ISA         = qw(Exporter);
  18     @EXPORT      = qw(setup_sigwarn
  19                       debiantag server_branch server_ref
  20                       stat_exists link_ltarget
  21                       fail ensuredir executable_on_path
  22                       waitstatusmsg failedcmd
  23                       cmdoutput cmdoutput_errok
  24                       git_rev_parse git_get_ref git_for_each_ref
  25                       git_for_each_tag_referring is_fast_fwd
  26                       $package_re $component_re $deliberately_re
  27                       $branchprefix
  28                       initdebug enabledebug enabledebuglevel
  29                       printdebug debugcmd
  30                       $debugprefix *debuglevel *DEBUG
  31                       shellquote printcmd messagequote);
  32     # implicitly uses $main::us
  33     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  34     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  35 }
  36
  37 our @EXPORT_OK;
  38
  39 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  40 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  41 our $deliberately_re = "(?:TEST-)?$package_re";
  42 our $branchprefix = 'dgit';
  43
  44 # policy hook exit status bits
  45 # see dgit-repos-server head comment for documentation
  46 # 1 is reserved in case something fails with `exit 1' and to spot
  47 # dynamic loader, runtime, etc., failures, which report 127 or 255
  48 sub NOFFCHECK () { return 0x2; }
  49 sub FRESHREPO () { return 0x4; }
  50
  51 our $debugprefix;
  52 our $debuglevel = 0;
  53
  54 sub setup_sigwarn () {
  55     our $sigwarn_mainprocess = $$;
  56     $SIG{__WARN__} = sub {
  57         die $_[0] unless getppid == $sigwarn_mainprocess;
  58     };
  59 }
  60
  61 sub initdebug ($) {
  62     ($debugprefix) = @_;
  63     open DEBUG, ">/dev/null" or die $!;
  64 }
  65
  66 sub enabledebug () {
  67     open DEBUG, ">&STDERR" or die $!;
  68     DEBUG->autoflush(1);
  69     $debuglevel ||= 1;
  70 }
  71
  72 sub enabledebuglevel ($) {
  73     my ($newlevel) = @_; # may be undef (eg from env var)
  74     die if $debuglevel;
  75     $newlevel //= 0;
  76     $newlevel += 0;
  77     return unless $newlevel;
  78     $debuglevel = $newlevel;
  79     enabledebug();
  80 }
  81
  82 sub printdebug {
  83     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  84 }
  85
  86 sub messagequote ($) {
  87     local ($_) = @_;
  88     s{\\}{\\\\}g;
  89     s{\n}{\\n}g;
  90     s{\x08}{\\b}g;
  91     s{\t}{\\t}g;
  92     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  93     $_;
  94 }
  95
  96 sub shellquote {
  97     my @out;
  98     local $_;
  99     foreach my $a (@_) {
 100         $_ = $a;
 101         if (!length || m{[^-=_./:0-9a-z]}i) {
 102             s{['\\]}{'\\$&'}g;
 103             push @out, "'$_'";
 104         } else {
 105             push @out, $_;
 106         }
 107     }
 108     return join ' ', @out;
 109 }
 110
 111 sub printcmd {
 112     my $fh = shift @_;
 113     my $intro = shift @_;
 114     print $fh $intro," " or die $!;
 115     print $fh shellquote @_ or die $!;
 116     print $fh "\n" or die $!;
 117 }
 118
 119 sub debugcmd {
 120     my $extraprefix = shift @_;
 121     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 122 }
 123
 124 sub debiantag ($$) {
 125     my ($v,$distro) = @_;
 126     $v =~ y/~:/_%/;
 127     return "$distro/$v";
 128 }
 129
 130 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 131 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 132
 133 sub stat_exists ($) {
 134     my ($f) = @_;
 135     return 1 if stat $f;
 136     return 0 if $!==&ENOENT;
 137     die "stat $f: $!";
 138 }
 139
 140 sub _us () {
 141     $::us // ($0 =~ m#[^/]*$#, $&);
 142 }
 143
 144 sub fail {
 145     my $s = "@_\n";
 146     my $prefix = _us().": ";
 147     $s =~ s/^/$prefix/gm;
 148     die $s;
 149 }
 150
 151 sub ensuredir ($) {
 152     my ($dir) = @_; # does not create parents
 153     return if mkdir $dir;
 154     return if $! == EEXIST;
 155     die "mkdir $dir: $!";
 156 }
 157
 158 sub executable_on_path ($) {
 159     my ($program) = @_;
 160     return 1 if $program =~ m{/};
 161     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 162     foreach my $pe (@path) {
 163         my $here = "$pe/$program";
 164         return $here if stat_exists $here && -x _;
 165     }
 166     return undef;
 167 }
 168
 169 our @signames = split / /, $Config{sig_name};
 170
 171 sub waitstatusmsg () {
 172     if (!$?) {
 173         return "terminated, reporting successful completion";
 174     } elsif (!($? & 255)) {
 175         return "failed with error exit status ".WEXITSTATUS($?);
 176     } elsif (WIFSIGNALED($?)) {
 177         my $signum=WTERMSIG($?);
 178         return "died due to fatal signal ".
 179             ($signames[$signum] // "number $signum").
 180             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 181     } else {
 182         return "failed with unknown wait status ".$?;
 183     }
 184 }
 185
 186 sub failedcmd {
 187     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 188     if ($!) {
 189         fail "failed to fork/exec: $!";
 190     } elsif ($?) {
 191         fail "subprocess ".waitstatusmsg();
 192     } else {
 193         fail "subprocess produced invalid output";
 194     }
 195 }
 196
 197 sub cmdoutput_errok {
 198     die Dumper(\@_)." ?" if grep { !defined } @_;
 199     debugcmd "|",@_;
 200     open P, "-|", @_ or die "$_[0] $!";
 201     my $d;
 202     $!=0; $?=0;
 203     { local $/ = undef; $d = <P>; }
 204     die $! if P->error;
 205     if (!close P) { printdebug "=>!$?\n"; return undef; }
 206     chomp $d;
 207     if ($debuglevel > 0) {
 208         $d =~ m/^.*/;
 209         my $dd = $&;
 210         my $more = (length $' ? '...' : ''); #');
 211         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 212         printdebug "=> \`$dd'",$more,"\n";
 213     }
 214     return $d;
 215 }
 216
 217 sub cmdoutput {
 218     my $d = cmdoutput_errok @_;
 219     defined $d or failedcmd @_;
 220     return $d;
 221 }
 222
 223 sub link_ltarget ($$) {
 224     my ($old,$new) = @_;
 225     lstat $old or return undef;
 226     if (-l _) {
 227         $old = cmdoutput qw(realpath  --), $old;
 228     }
 229     link $old, $new or die "link $old $new: $!";
 230 }
 231
 232 sub git_rev_parse ($) {
 233     return cmdoutput qw(git rev-parse), "$_[0]~0";
 234 }
 235
 236 sub git_for_each_ref ($$;$) {
 237     my ($pattern,$func,$gitdir) = @_;
 238     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 239     # $reftail is RHS of ref after refs/[^/]+/
 240     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 241     my @cmd = (qw(git for-each-ref), $pattern);
 242     if (defined $gitdir) {
 243         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 244     }
 245     open GFER, "-|", @cmd or die $!;
 246     debugcmd "|", @cmd;
 247     while (<GFER>) {
 248         chomp or die "$_ ?";
 249         printdebug "|> ", $_, "\n";
 250         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 251         $func->($1,$2,$3,$4);
 252     }
 253     $!=0; $?=0; close GFER or die "$pattern $? $!";
 254 }
 255
 256 sub git_get_ref ($) {
 257     # => '' if no such ref
 258     my ($refname) = @_;
 259     local $_ = $refname;
 260     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 261     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 262 }
 263
 264 sub git_for_each_tag_referring ($$) {
 265     my ($objreferring, $func) = @_;
 266     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 267     printdebug "git_for_each_tag_referring ",
 268         ($objreferring // 'UNDEF'),"\n";
 269     git_for_each_ref('refs/tags', sub {
 270         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 271         return unless $objtype eq 'tag';
 272         my $refobjid = git_rev_parse $tagobjid;
 273         return unless
 274             !defined $objreferring # caller wants them all
 275             or $tagobjid eq $objreferring
 276             or $refobjid eq $objreferring;
 277         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 278     });
 279 }
 280
 281 sub is_fast_fwd ($$) {
 282     my ($ancestor,$child) = @_;
 283     my @cmd = (qw(git merge-base), $ancestor, $child);
 284     my $mb = cmdoutput_errok @cmd;
 285     if (defined $mb) {
 286         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 287     } else {
 288         $?==256 or failedcmd @cmd;
 289         return 0;
 290     }
 291 }
 292
 293 1;