Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31 use IPC::Open2;
  32
  33 BEGIN {
  34     use Exporter   ();
  35     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  36
  37     $VERSION     = 1.00;
  38     @ISA         = qw(Exporter);
  39     @EXPORT      = qw(setup_sigwarn forkcheck_setup forkcheck_mainprocess
  40                       dep14_version_mangle
  41                       debiantags debiantag_old debiantag_new
  42                       server_branch server_ref
  43                       stat_exists link_ltarget
  44                       hashfile
  45                       fail ensuredir executable_on_path
  46                       waitstatusmsg failedcmd_waitstatus
  47                       failedcmd_report_cmd failedcmd
  48                       runcmd cmdoutput cmdoutput_errok
  49                       git_rev_parse git_cat_file
  50                       git_get_ref git_for_each_ref
  51                       git_for_each_tag_referring is_fast_fwd
  52                       $package_re $component_re $deliberately_re
  53                       $distro_re $versiontag_re $series_filename_re
  54                       $branchprefix
  55                       initdebug enabledebug enabledebuglevel
  56                       printdebug debugcmd
  57                       $debugprefix *debuglevel *DEBUG
  58                       shellquote printcmd messagequote);
  59     # implicitly uses $main::us
  60     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO NOCOMMITCHECK)] );
  61     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  62 }
  63
  64 our @EXPORT_OK;
  65
  66 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  67 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  68 our $deliberately_re = "(?:TEST-)?$package_re";
  69 our $distro_re = $component_re;
  70 our $versiontag_re = qr{[-+.\%_0-9a-zA-Z/]+};
  71 our $branchprefix = 'dgit';
  72 our $series_filename_re = qr{(?:^|\.)series(?!\n)$}s;
  73
  74 # policy hook exit status bits
  75 # see dgit-repos-server head comment for documentation
  76 # 1 is reserved in case something fails with `exit 1' and to spot
  77 # dynamic loader, runtime, etc., failures, which report 127 or 255
  78 sub NOFFCHECK () { return 0x2; }
  79 sub FRESHREPO () { return 0x4; }
  80 sub NOCOMMITCHECK () { return 0x8; }
  81
  82 our $debugprefix;
  83 our $debuglevel = 0;
  84
  85 our $forkcheck_mainprocess;
  86
  87 sub forkcheck_setup () {
  88     $forkcheck_mainprocess = $$;
  89 }
  90
  91 sub forkcheck_mainprocess () {
  92     # You must have called forkcheck_setup or setup_sigwarn already
  93     getppid != $forkcheck_mainprocess;
  94 }
  95
  96 sub setup_sigwarn () {
  97     forkcheck_setup();
  98     $SIG{__WARN__} = sub {
  99         die $_[0] if forkcheck_mainprocess;
 100     };
 101 }
 102
 103 sub initdebug ($) {
 104     ($debugprefix) = @_;
 105     open DEBUG, ">/dev/null" or die $!;
 106 }
 107
 108 sub enabledebug () {
 109     open DEBUG, ">&STDERR" or die $!;
 110     DEBUG->autoflush(1);
 111     $debuglevel ||= 1;
 112 }
 113
 114 sub enabledebuglevel ($) {
 115     my ($newlevel) = @_; # may be undef (eg from env var)
 116     die if $debuglevel;
 117     $newlevel //= 0;
 118     $newlevel += 0;
 119     return unless $newlevel;
 120     $debuglevel = $newlevel;
 121     enabledebug();
 122 }
 123
 124 sub printdebug {
 125     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 126 }
 127
 128 sub messagequote ($) {
 129     local ($_) = @_;
 130     s{\\}{\\\\}g;
 131     s{\n}{\\n}g;
 132     s{\x08}{\\b}g;
 133     s{\t}{\\t}g;
 134     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 135     $_;
 136 }
 137
 138 sub shellquote {
 139     my @out;
 140     local $_;
 141     defined or confess 'internal error' foreach @_;
 142     foreach my $a (@_) {
 143         $_ = $a;
 144         if (!length || m{[^-=_./:0-9a-z]}i) {
 145             s{['\\]}{'\\$&'}g;
 146             push @out, "'$_'";
 147         } else {
 148             push @out, $_;
 149         }
 150     }
 151     return join ' ', @out;
 152 }
 153
 154 sub printcmd {
 155     my $fh = shift @_;
 156     my $intro = shift @_;
 157     print $fh $intro," " or die $!;
 158     print $fh shellquote @_ or die $!;
 159     print $fh "\n" or die $!;
 160 }
 161
 162 sub debugcmd {
 163     my $extraprefix = shift @_;
 164     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 165 }
 166
 167 sub dep14_version_mangle ($) {
 168     my ($v) = @_;
 169     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 170     $v =~ y/~:/_%/;
 171     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 172     return $v;
 173 }
 174
 175 sub debiantag_old ($$) {
 176     my ($v,$distro) = @_;
 177     return "$distro/". dep14_version_mangle $v;
 178 }
 179
 180 sub debiantag_new ($$) {
 181     my ($v,$distro) = @_;
 182     return "archive/$distro/".dep14_version_mangle $v;
 183 }
 184
 185 sub debiantags ($$) {
 186     my ($version,$distro) = @_;
 187     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 188 }
 189
 190 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 191 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 192
 193 sub stat_exists ($) {
 194     my ($f) = @_;
 195     return 1 if stat $f;
 196     return 0 if $!==&ENOENT;
 197     die "stat $f: $!";
 198 }
 199
 200 sub _us () {
 201     $::us // ($0 =~ m#[^/]*$#, $&);
 202 }
 203
 204 sub fail {
 205     my $s = "@_\n";
 206     $s =~ s/\n\n$/\n/;
 207     my $prefix = _us().": ";
 208     $s =~ s/^/$prefix/gm;
 209     die $s;
 210 }
 211
 212 sub ensuredir ($) {
 213     my ($dir) = @_; # does not create parents
 214     return if mkdir $dir;
 215     return if $! == EEXIST;
 216     die "mkdir $dir: $!";
 217 }
 218
 219 sub executable_on_path ($) {
 220     my ($program) = @_;
 221     return 1 if $program =~ m{/};
 222     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 223     foreach my $pe (@path) {
 224         my $here = "$pe/$program";
 225         return $here if stat_exists $here && -x _;
 226     }
 227     return undef;
 228 }
 229
 230 our @signames = split / /, $Config{sig_name};
 231
 232 sub waitstatusmsg () {
 233     if (!$?) {
 234         return "terminated, reporting successful completion";
 235     } elsif (!($? & 255)) {
 236         return "failed with error exit status ".WEXITSTATUS($?);
 237     } elsif (WIFSIGNALED($?)) {
 238         my $signum=WTERMSIG($?);
 239         return "died due to fatal signal ".
 240             ($signames[$signum] // "number $signum").
 241             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 242     } else {
 243         return "failed with unknown wait status ".$?;
 244     }
 245 }
 246
 247 sub failedcmd_report_cmd {
 248     my $intro = shift @_;
 249     $intro //= "failed command";
 250     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 251 }
 252
 253 sub failedcmd_waitstatus {
 254     if ($? < 0) {
 255         return "failed to fork/exec: $!";
 256     } elsif ($?) {
 257         return "subprocess ".waitstatusmsg();
 258     } else {
 259         return "subprocess produced invalid output";
 260     }
 261 }
 262
 263 sub failedcmd {
 264     # Expects $!,$? as set by close - see below.
 265     # To use with system(), set $?=-1 first.
 266     #
 267     # Actual behaviour of perl operations:
 268     #   success              $!==0       $?==0       close of piped open
 269     #   program failed       $!==0       $? >0       close of piped open
 270     #   syscall failure      $! >0       $?=-1       close of piped open
 271     #   failure              $! >0       unchanged   close of something else
 272     #   success              trashed     $?==0       system
 273     #   program failed       trashed     $? >0       system
 274     #   syscall failure      $! >0       unchanged   system
 275     failedcmd_report_cmd undef, @_;
 276     fail failedcmd_waitstatus();
 277 }
 278
 279 sub runcmd {
 280     debugcmd "+",@_;
 281     $!=0; $?=-1;
 282     failedcmd @_ if system @_;
 283 }
 284
 285 sub cmdoutput_errok {
 286     confess Dumper(\@_)." ?" if grep { !defined } @_;
 287     debugcmd "|",@_;
 288     open P, "-|", @_ or die "$_[0] $!";
 289     my $d;
 290     $!=0; $?=0;
 291     { local $/ = undef; $d = <P>; }
 292     die $! if P->error;
 293     if (!close P) { printdebug "=>!$?\n"; return undef; }
 294     chomp $d;
 295     if ($debuglevel > 0) {
 296         $d =~ m/^.*/;
 297         my $dd = $&;
 298         my $more = (length $' ? '...' : ''); #');
 299         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 300         printdebug "=> \`$dd'",$more,"\n";
 301     }
 302     return $d;
 303 }
 304
 305 sub cmdoutput {
 306     my $d = cmdoutput_errok @_;
 307     defined $d or failedcmd @_;
 308     return $d;
 309 }
 310
 311 sub link_ltarget ($$) {
 312     my ($old,$new) = @_;
 313     lstat $old or return undef;
 314     if (-l _) {
 315         $old = cmdoutput qw(realpath  --), $old;
 316     }
 317     my $r = link $old, $new;
 318     $r = symlink $old, $new if !$r && $!==EXDEV;
 319     $r or die "(sym)link $old $new: $!";
 320 }
 321
 322 sub hashfile ($) {
 323     my ($fn) = @_;
 324     my $h = Digest::SHA->new(256);
 325     $h->addfile($fn);
 326     return $h->hexdigest();
 327 }
 328
 329 sub git_rev_parse ($) {
 330     return cmdoutput qw(git rev-parse), "$_[0]~0";
 331 }
 332
 333 sub git_cat_file ($) {
 334     my ($objname) = @_;
 335     # => ($type, $data) or ('missing', undef)
 336     # in scalar context, just the data
 337     our ($gcf_pid, $gcf_i, $gcf_o);
 338     if (!$gcf_pid) {
 339         my @cmd = qw(git cat-file --batch);
 340         debugcmd "GCF|", @cmd;
 341         $gcf_pid = open2 $gcf_o, $gcf_i, @cmd or die $!;
 342     }
 343     printdebug "GCF>| ", $objname, "\n";
 344     print $gcf_i $objname, "\n" or die $!;
 345     my $x = <$gcf_o>;
 346     printdebug "GCF<| ", $x;
 347     if ($x =~ m/ (missing)$/) { return ($1, undef); }
 348     my ($type, $size) = $x =~ m/^.* (\w+) (\d+)\n/ or die "$objname ?";
 349     my $data;
 350     (read $gcf_o, $data, $size) == $size or die "$objname $!";
 351     $x = <$gcf_o>;
 352     $x eq "\n" or die "$objname ($_) $!";
 353     return ($type, $data);
 354 }
 355
 356 sub git_for_each_ref ($$;$) {
 357     my ($pattern,$func,$gitdir) = @_;
 358     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 359     # $reftail is RHS of ref after refs/[^/]+/
 360     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 361     # $pattern may be an array ref to mean multiple patterns
 362     $pattern = [ $pattern ] unless ref $pattern;
 363     my @cmd = (qw(git for-each-ref), @$pattern);
 364     if (defined $gitdir) {
 365         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 366     }
 367     open GFER, "-|", @cmd or die $!;
 368     debugcmd "|", @cmd;
 369     while (<GFER>) {
 370         chomp or die "$_ ?";
 371         printdebug "|> ", $_, "\n";
 372         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 373         $func->($1,$2,$3,$4);
 374     }
 375     $!=0; $?=0; close GFER or die "$pattern $? $!";
 376 }
 377
 378 sub git_get_ref ($) {
 379     # => '' if no such ref
 380     my ($refname) = @_;
 381     local $_ = $refname;
 382     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 383     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 384 }
 385
 386 sub git_for_each_tag_referring ($$) {
 387     my ($objreferring, $func) = @_;
 388     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 389     printdebug "git_for_each_tag_referring ",
 390         ($objreferring // 'UNDEF'),"\n";
 391     git_for_each_ref('refs/tags', sub {
 392         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 393         return unless $objtype eq 'tag';
 394         my $refobjid = git_rev_parse $tagobjid;
 395         return unless
 396             !defined $objreferring # caller wants them all
 397             or $tagobjid eq $objreferring
 398             or $refobjid eq $objreferring;
 399         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 400     });
 401 }
 402
 403 sub is_fast_fwd ($$) {
 404     my ($ancestor,$child) = @_;
 405     my @cmd = (qw(git merge-base), $ancestor, $child);
 406     my $mb = cmdoutput_errok @cmd;
 407     if (defined $mb) {
 408         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 409     } else {
 410         $?==256 or failedcmd @cmd;
 411         return 0;
 412     }
 413 }
 414
 415 1;