Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11 use Digest::SHA;
  12
  13 BEGIN {
  14     use Exporter   ();
  15     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  16
  17     $VERSION     = 1.00;
  18     @ISA         = qw(Exporter);
  19     @EXPORT      = qw(setup_sigwarn
  20                       debiantag server_branch server_ref
  21                       stat_exists link_ltarget
  22                       hashfile
  23                       fail ensuredir executable_on_path
  24                       waitstatusmsg failedcmd
  25                       cmdoutput cmdoutput_errok
  26                       git_rev_parse git_get_ref git_for_each_ref
  27                       git_for_each_tag_referring is_fast_fwd
  28                       $package_re $component_re $deliberately_re
  29                       $branchprefix
  30                       initdebug enabledebug enabledebuglevel
  31                       printdebug debugcmd
  32                       $debugprefix *debuglevel *DEBUG
  33                       shellquote printcmd messagequote);
  34     # implicitly uses $main::us
  35     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  36     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  37 }
  38
  39 our @EXPORT_OK;
  40
  41 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  42 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  43 our $deliberately_re = "(?:TEST-)?$package_re";
  44 our $branchprefix = 'dgit';
  45
  46 # policy hook exit status bits
  47 # see dgit-repos-server head comment for documentation
  48 # 1 is reserved in case something fails with `exit 1' and to spot
  49 # dynamic loader, runtime, etc., failures, which report 127 or 255
  50 sub NOFFCHECK () { return 0x2; }
  51 sub FRESHREPO () { return 0x4; }
  52
  53 our $debugprefix;
  54 our $debuglevel = 0;
  55
  56 sub setup_sigwarn () {
  57     our $sigwarn_mainprocess = $$;
  58     $SIG{__WARN__} = sub {
  59         die $_[0] unless getppid == $sigwarn_mainprocess;
  60     };
  61 }
  62
  63 sub initdebug ($) {
  64     ($debugprefix) = @_;
  65     open DEBUG, ">/dev/null" or die $!;
  66 }
  67
  68 sub enabledebug () {
  69     open DEBUG, ">&STDERR" or die $!;
  70     DEBUG->autoflush(1);
  71     $debuglevel ||= 1;
  72 }
  73
  74 sub enabledebuglevel ($) {
  75     my ($newlevel) = @_; # may be undef (eg from env var)
  76     die if $debuglevel;
  77     $newlevel //= 0;
  78     $newlevel += 0;
  79     return unless $newlevel;
  80     $debuglevel = $newlevel;
  81     enabledebug();
  82 }
  83
  84 sub printdebug {
  85     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  86 }
  87
  88 sub messagequote ($) {
  89     local ($_) = @_;
  90     s{\\}{\\\\}g;
  91     s{\n}{\\n}g;
  92     s{\x08}{\\b}g;
  93     s{\t}{\\t}g;
  94     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
  95     $_;
  96 }
  97
  98 sub shellquote {
  99     my @out;
 100     local $_;
 101     foreach my $a (@_) {
 102         $_ = $a;
 103         if (!length || m{[^-=_./:0-9a-z]}i) {
 104             s{['\\]}{'\\$&'}g;
 105             push @out, "'$_'";
 106         } else {
 107             push @out, $_;
 108         }
 109     }
 110     return join ' ', @out;
 111 }
 112
 113 sub printcmd {
 114     my $fh = shift @_;
 115     my $intro = shift @_;
 116     print $fh $intro," " or die $!;
 117     print $fh shellquote @_ or die $!;
 118     print $fh "\n" or die $!;
 119 }
 120
 121 sub debugcmd {
 122     my $extraprefix = shift @_;
 123     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 124 }
 125
 126 sub debiantag ($$) {
 127     my ($v,$distro) = @_;
 128     $v =~ y/~:/_%/;
 129     return "$distro/$v";
 130 }
 131
 132 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 133 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 134
 135 sub stat_exists ($) {
 136     my ($f) = @_;
 137     return 1 if stat $f;
 138     return 0 if $!==&ENOENT;
 139     die "stat $f: $!";
 140 }
 141
 142 sub _us () {
 143     $::us // ($0 =~ m#[^/]*$#, $&);
 144 }
 145
 146 sub fail {
 147     my $s = "@_\n";
 148     my $prefix = _us().": ";
 149     $s =~ s/^/$prefix/gm;
 150     die $s;
 151 }
 152
 153 sub ensuredir ($) {
 154     my ($dir) = @_; # does not create parents
 155     return if mkdir $dir;
 156     return if $! == EEXIST;
 157     die "mkdir $dir: $!";
 158 }
 159
 160 sub executable_on_path ($) {
 161     my ($program) = @_;
 162     return 1 if $program =~ m{/};
 163     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 164     foreach my $pe (@path) {
 165         my $here = "$pe/$program";
 166         return $here if stat_exists $here && -x _;
 167     }
 168     return undef;
 169 }
 170
 171 our @signames = split / /, $Config{sig_name};
 172
 173 sub waitstatusmsg () {
 174     if (!$?) {
 175         return "terminated, reporting successful completion";
 176     } elsif (!($? & 255)) {
 177         return "failed with error exit status ".WEXITSTATUS($?);
 178     } elsif (WIFSIGNALED($?)) {
 179         my $signum=WTERMSIG($?);
 180         return "died due to fatal signal ".
 181             ($signames[$signum] // "number $signum").
 182             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 183     } else {
 184         return "failed with unknown wait status ".$?;
 185     }
 186 }
 187
 188 sub failedcmd {
 189     # Expects $!,$? as set by close - see below.
 190     # To use with system(), set $?=-1 first.
 191     #
 192     # Actual behaviour of perl operations:
 193     #   success              $!==0       $?==0       close of piped open
 194     #   program failed       $!==0       $? >0       close of piped open
 195     #   syscall failure      $! >0       $?=-1       close of piped open
 196     #   failure              $! >0       unchanged   close of something else
 197     #   success              trashed     $?==0       system
 198     #   program failed       trashed     $? >0       system
 199     #   syscall failure      $! >0       unchanged   system
 200     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 201     if ($? < 0) {
 202         fail "failed to fork/exec: $!";
 203     } elsif ($?) {
 204         fail "subprocess ".waitstatusmsg();
 205     } else {
 206         fail "subprocess produced invalid output";
 207     }
 208 }
 209
 210 sub cmdoutput_errok {
 211     die Dumper(\@_)." ?" if grep { !defined } @_;
 212     debugcmd "|",@_;
 213     open P, "-|", @_ or die "$_[0] $!";
 214     my $d;
 215     $!=0; $?=0;
 216     { local $/ = undef; $d = <P>; }
 217     die $! if P->error;
 218     if (!close P) { printdebug "=>!$?\n"; return undef; }
 219     chomp $d;
 220     if ($debuglevel > 0) {
 221         $d =~ m/^.*/;
 222         my $dd = $&;
 223         my $more = (length $' ? '...' : ''); #');
 224         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 225         printdebug "=> \`$dd'",$more,"\n";
 226     }
 227     return $d;
 228 }
 229
 230 sub cmdoutput {
 231     my $d = cmdoutput_errok @_;
 232     defined $d or failedcmd @_;
 233     return $d;
 234 }
 235
 236 sub link_ltarget ($$) {
 237     my ($old,$new) = @_;
 238     lstat $old or return undef;
 239     if (-l _) {
 240         $old = cmdoutput qw(realpath  --), $old;
 241     }
 242     link $old, $new or die "link $old $new: $!";
 243 }
 244
 245 sub hashfile ($) {
 246     my ($fn) = @_;
 247     my $h = Digest::SHA->new(256);
 248     $h->addfile($fn);
 249     return $h->hexdigest();
 250 }
 251
 252 sub git_rev_parse ($) {
 253     return cmdoutput qw(git rev-parse), "$_[0]~0";
 254 }
 255
 256 sub git_for_each_ref ($$;$) {
 257     my ($pattern,$func,$gitdir) = @_;
 258     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 259     # $reftail is RHS of ref after refs/[^/]+/
 260     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 261     my @cmd = (qw(git for-each-ref), $pattern);
 262     if (defined $gitdir) {
 263         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 264     }
 265     open GFER, "-|", @cmd or die $!;
 266     debugcmd "|", @cmd;
 267     while (<GFER>) {
 268         chomp or die "$_ ?";
 269         printdebug "|> ", $_, "\n";
 270         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 271         $func->($1,$2,$3,$4);
 272     }
 273     $!=0; $?=0; close GFER or die "$pattern $? $!";
 274 }
 275
 276 sub git_get_ref ($) {
 277     # => '' if no such ref
 278     my ($refname) = @_;
 279     local $_ = $refname;
 280     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 281     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 282 }
 283
 284 sub git_for_each_tag_referring ($$) {
 285     my ($objreferring, $func) = @_;
 286     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 287     printdebug "git_for_each_tag_referring ",
 288         ($objreferring // 'UNDEF'),"\n";
 289     git_for_each_ref('refs/tags', sub {
 290         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 291         return unless $objtype eq 'tag';
 292         my $refobjid = git_rev_parse $tagobjid;
 293         return unless
 294             !defined $objreferring # caller wants them all
 295             or $tagobjid eq $objreferring
 296             or $refobjid eq $objreferring;
 297         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 298     });
 299 }
 300
 301 sub is_fast_fwd ($$) {
 302     my ($ancestor,$child) = @_;
 303     my @cmd = (qw(git merge-base), $ancestor, $child);
 304     my $mb = cmdoutput_errok @cmd;
 305     if (defined $mb) {
 306         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 307     } else {
 308         $?==256 or failedcmd @cmd;
 309         return 0;
 310     }
 311 }
 312
 313 1;