Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31
  32 BEGIN {
  33     use Exporter   ();
  34     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  35
  36     $VERSION     = 1.00;
  37     @ISA         = qw(Exporter);
  38     @EXPORT      = qw(setup_sigwarn
  39                       debiantags debiantag_old debiantag_new
  40                       server_branch server_ref
  41                       stat_exists link_ltarget
  42                       hashfile
  43                       fail ensuredir executable_on_path
  44                       waitstatusmsg failedcmd_report_cmd failedcmd
  45                       cmdoutput cmdoutput_errok
  46                       git_rev_parse git_get_ref git_for_each_ref
  47                       git_for_each_tag_referring is_fast_fwd
  48                       $package_re $component_re $deliberately_re
  49                       $branchprefix
  50                       initdebug enabledebug enabledebuglevel
  51                       printdebug debugcmd
  52                       $debugprefix *debuglevel *DEBUG
  53                       shellquote printcmd messagequote);
  54     # implicitly uses $main::us
  55     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  56     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  57 }
  58
  59 our @EXPORT_OK;
  60
  61 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  62 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  63 our $deliberately_re = "(?:TEST-)?$package_re";
  64 our $branchprefix = 'dgit';
  65
  66 # policy hook exit status bits
  67 # see dgit-repos-server head comment for documentation
  68 # 1 is reserved in case something fails with `exit 1' and to spot
  69 # dynamic loader, runtime, etc., failures, which report 127 or 255
  70 sub NOFFCHECK () { return 0x2; }
  71 sub FRESHREPO () { return 0x4; }
  72
  73 our $debugprefix;
  74 our $debuglevel = 0;
  75
  76 sub setup_sigwarn () {
  77     our $sigwarn_mainprocess = $$;
  78     $SIG{__WARN__} = sub {
  79         die $_[0] unless getppid == $sigwarn_mainprocess;
  80     };
  81 }
  82
  83 sub initdebug ($) {
  84     ($debugprefix) = @_;
  85     open DEBUG, ">/dev/null" or die $!;
  86 }
  87
  88 sub enabledebug () {
  89     open DEBUG, ">&STDERR" or die $!;
  90     DEBUG->autoflush(1);
  91     $debuglevel ||= 1;
  92 }
  93
  94 sub enabledebuglevel ($) {
  95     my ($newlevel) = @_; # may be undef (eg from env var)
  96     die if $debuglevel;
  97     $newlevel //= 0;
  98     $newlevel += 0;
  99     return unless $newlevel;
 100     $debuglevel = $newlevel;
 101     enabledebug();
 102 }
 103
 104 sub printdebug {
 105     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 106 }
 107
 108 sub messagequote ($) {
 109     local ($_) = @_;
 110     s{\\}{\\\\}g;
 111     s{\n}{\\n}g;
 112     s{\x08}{\\b}g;
 113     s{\t}{\\t}g;
 114     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 115     $_;
 116 }
 117
 118 sub shellquote {
 119     my @out;
 120     local $_;
 121     foreach my $a (@_) {
 122         $_ = $a;
 123         if (!length || m{[^-=_./:0-9a-z]}i) {
 124             s{['\\]}{'\\$&'}g;
 125             push @out, "'$_'";
 126         } else {
 127             push @out, $_;
 128         }
 129     }
 130     return join ' ', @out;
 131 }
 132
 133 sub printcmd {
 134     my $fh = shift @_;
 135     my $intro = shift @_;
 136     print $fh $intro," " or die $!;
 137     print $fh shellquote @_ or die $!;
 138     print $fh "\n" or die $!;
 139 }
 140
 141 sub debugcmd {
 142     my $extraprefix = shift @_;
 143     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 144 }
 145
 146 sub debiantag_old ($$) {
 147     my ($v,$distro) = @_;
 148     $v =~ y/~:/_%/;
 149     return "$distro/$v";
 150 }
 151
 152 sub debiantag_new ($$) {
 153     my ($v,$distro) = @_;
 154     $v =~ y/~:/_%/;
 155     return "archive/$distro/$v";
 156 }
 157
 158 sub debiantags ($$) {
 159     my ($version,$distro) = @_;
 160     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 161 }
 162
 163 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 164 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 165
 166 sub stat_exists ($) {
 167     my ($f) = @_;
 168     return 1 if stat $f;
 169     return 0 if $!==&ENOENT;
 170     die "stat $f: $!";
 171 }
 172
 173 sub _us () {
 174     $::us // ($0 =~ m#[^/]*$#, $&);
 175 }
 176
 177 sub fail {
 178     my $s = "@_\n";
 179     $s =~ s/\n\n$/\n/;
 180     my $prefix = _us().": ";
 181     $s =~ s/^/$prefix/gm;
 182     die $s;
 183 }
 184
 185 sub ensuredir ($) {
 186     my ($dir) = @_; # does not create parents
 187     return if mkdir $dir;
 188     return if $! == EEXIST;
 189     die "mkdir $dir: $!";
 190 }
 191
 192 sub executable_on_path ($) {
 193     my ($program) = @_;
 194     return 1 if $program =~ m{/};
 195     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 196     foreach my $pe (@path) {
 197         my $here = "$pe/$program";
 198         return $here if stat_exists $here && -x _;
 199     }
 200     return undef;
 201 }
 202
 203 our @signames = split / /, $Config{sig_name};
 204
 205 sub waitstatusmsg () {
 206     if (!$?) {
 207         return "terminated, reporting successful completion";
 208     } elsif (!($? & 255)) {
 209         return "failed with error exit status ".WEXITSTATUS($?);
 210     } elsif (WIFSIGNALED($?)) {
 211         my $signum=WTERMSIG($?);
 212         return "died due to fatal signal ".
 213             ($signames[$signum] // "number $signum").
 214             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 215     } else {
 216         return "failed with unknown wait status ".$?;
 217     }
 218 }
 219
 220 sub failedcmd_report_cmd {
 221     my $intro = shift @_;
 222     $intro //= "failed command";
 223     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 224 }
 225
 226 sub failedcmd {
 227     # Expects $!,$? as set by close - see below.
 228     # To use with system(), set $?=-1 first.
 229     #
 230     # Actual behaviour of perl operations:
 231     #   success              $!==0       $?==0       close of piped open
 232     #   program failed       $!==0       $? >0       close of piped open
 233     #   syscall failure      $! >0       $?=-1       close of piped open
 234     #   failure              $! >0       unchanged   close of something else
 235     #   success              trashed     $?==0       system
 236     #   program failed       trashed     $? >0       system
 237     #   syscall failure      $! >0       unchanged   system
 238     failedcmd_report_cmd undef, @_;
 239     if ($? < 0) {
 240         fail "failed to fork/exec: $!";
 241     } elsif ($?) {
 242         fail "subprocess ".waitstatusmsg();
 243     } else {
 244         fail "subprocess produced invalid output";
 245     }
 246 }
 247
 248 sub cmdoutput_errok {
 249     confess Dumper(\@_)." ?" if grep { !defined } @_;
 250     debugcmd "|",@_;
 251     open P, "-|", @_ or die "$_[0] $!";
 252     my $d;
 253     $!=0; $?=0;
 254     { local $/ = undef; $d = <P>; }
 255     die $! if P->error;
 256     if (!close P) { printdebug "=>!$?\n"; return undef; }
 257     chomp $d;
 258     if ($debuglevel > 0) {
 259         $d =~ m/^.*/;
 260         my $dd = $&;
 261         my $more = (length $' ? '...' : ''); #');
 262         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 263         printdebug "=> \`$dd'",$more,"\n";
 264     }
 265     return $d;
 266 }
 267
 268 sub cmdoutput {
 269     my $d = cmdoutput_errok @_;
 270     defined $d or failedcmd @_;
 271     return $d;
 272 }
 273
 274 sub link_ltarget ($$) {
 275     my ($old,$new) = @_;
 276     lstat $old or return undef;
 277     if (-l _) {
 278         $old = cmdoutput qw(realpath  --), $old;
 279     }
 280     link $old, $new or die "link $old $new: $!";
 281 }
 282
 283 sub hashfile ($) {
 284     my ($fn) = @_;
 285     my $h = Digest::SHA->new(256);
 286     $h->addfile($fn);
 287     return $h->hexdigest();
 288 }
 289
 290 sub git_rev_parse ($) {
 291     return cmdoutput qw(git rev-parse), "$_[0]~0";
 292 }
 293
 294 sub git_for_each_ref ($$;$) {
 295     my ($pattern,$func,$gitdir) = @_;
 296     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 297     # $reftail is RHS of ref after refs/[^/]+/
 298     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 299     # $pattern may be an array ref to mean multiple patterns
 300     $pattern = [ $pattern ] unless ref $pattern;
 301     my @cmd = (qw(git for-each-ref), @$pattern);
 302     if (defined $gitdir) {
 303         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 304     }
 305     open GFER, "-|", @cmd or die $!;
 306     debugcmd "|", @cmd;
 307     while (<GFER>) {
 308         chomp or die "$_ ?";
 309         printdebug "|> ", $_, "\n";
 310         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 311         $func->($1,$2,$3,$4);
 312     }
 313     $!=0; $?=0; close GFER or die "$pattern $? $!";
 314 }
 315
 316 sub git_get_ref ($) {
 317     # => '' if no such ref
 318     my ($refname) = @_;
 319     local $_ = $refname;
 320     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 321     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 322 }
 323
 324 sub git_for_each_tag_referring ($$) {
 325     my ($objreferring, $func) = @_;
 326     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 327     printdebug "git_for_each_tag_referring ",
 328         ($objreferring // 'UNDEF'),"\n";
 329     git_for_each_ref('refs/tags', sub {
 330         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 331         return unless $objtype eq 'tag';
 332         my $refobjid = git_rev_parse $tagobjid;
 333         return unless
 334             !defined $objreferring # caller wants them all
 335             or $tagobjid eq $objreferring
 336             or $refobjid eq $objreferring;
 337         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 338     });
 339 }
 340
 341 sub is_fast_fwd ($$) {
 342     my ($ancestor,$child) = @_;
 343     my @cmd = (qw(git merge-base), $ancestor, $child);
 344     my $mb = cmdoutput_errok @cmd;
 345     if (defined $mb) {
 346         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 347     } else {
 348         $?==256 or failedcmd @cmd;
 349         return 0;
 350     }
 351 }
 352
 353 1;