Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10
  11 BEGIN {
  12     use Exporter   ();
  13     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  14
  15     $VERSION     = 1.00;
  16     @ISA         = qw(Exporter);
  17     @EXPORT      = qw(debiantag server_branch server_ref
  18                       stat_exists git_for_each_ref
  19                       $package_re $component_re $branchprefix
  20                       initdebug enabledebug enabledebuglevel
  21                       printdebug debugcmd
  22                       $debugprefix *debuglevel *DEBUG
  23                       shellquote printcmd);
  24     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  25     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  26 }
  27
  28 our @EXPORT_OK;
  29
  30 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  31 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  32 our $branchprefix = 'dgit';
  33
  34 # policy hook exit status bits
  35 # see dgit-repos-server head comment for documentation
  36 # 1 is reserved in case something fails with `exit 1'
  37 sub NOFFCHECK () { return 0x2; }
  38 sub FRESHREPO () { return 0x4; }
  39 # 0x80 is reserved
  40
  41 sub debiantag ($) {
  42     my ($v) = @_;
  43     $v =~ y/~:/_%/;
  44     return "debian/$v";
  45 }
  46
  47 sub server_branch ($) { return "$branchprefix/$_[0]"; }
  48 sub server_ref ($) { return "refs/".server_branch($_[0]); }
  49
  50 sub stat_exists ($) {
  51     my ($f) = @_;
  52     return 1 if stat $f;
  53     return 0 if $!==&ENOENT;
  54     die "stat $f: $!";
  55 }
  56
  57 sub git_for_each_ref ($$) {
  58     my ($pattern,$func) = @_;
  59     # calls $func->($objid,$objtype,$fullrefname,$reftail);
  60     # $reftail is RHS of ref after refs/\w+/
  61     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
  62     open GFER, "-|", qw(git for-each-ref), $pattern or die $!;
  63     while (<GFER>) {
  64         m#^(\w+)\s+(\w+)\s+(refs/\w+/(\S+))\s# or die "$_ ?";
  65         $func->($1,$2,$3,$4);
  66     }
  67     $!=0; $?=0; close GFER or die "$pattern $? $!";
  68 }
  69
  70 sub git_for_each_tag_referring ($$) {
  71     my ($objreferring, $func) = @_;
  72     # calls $func->($objid,$fullrefname,$tagname);
  73     git_for_each_ref('refs/tags', sub {
  74         my ($objid,$objtype,$fullrefname,$tagname) = @_;
  75         next unless $objtype eq 'tag';
  76         next if defined $objreferring and $objid ne $objreferring;
  77         $func->($objid,$fullrefname,$tagname);
  78     });
  79 }
  80
  81 our $debugprefix;
  82 our $debuglevel = 0;
  83
  84 sub initdebug ($) {
  85     ($debugprefix) = @_;
  86     open DEBUG, ">/dev/null" or die $!;
  87 }
  88
  89 sub enabledebug () {
  90     open DEBUG, ">&STDERR" or die $!;
  91     DEBUG->autoflush(1);
  92     $debuglevel ||= 1;
  93 }
  94
  95 sub enabledebuglevel ($) {
  96     my ($newlevel) = @_; # may be undef (eg from env var)
  97     die if $debuglevel;
  98     $newlevel //= 0;
  99     $newlevel += 0;
 100     return unless $newlevel;
 101     $debuglevel = $newlevel;
 102     enabledebug();
 103 }
 104
 105 sub printdebug {
 106     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 107 }
 108
 109 sub shellquote {
 110     my @out;
 111     local $_;
 112     foreach my $a (@_) {
 113         $_ = $a;
 114         if (!length || m{[^-=_./0-9a-z]}i) {
 115             s{['\\]}{'\\$&'}g;
 116             push @out, "'$_'";
 117         } else {
 118             push @out, $_;
 119         }
 120     }
 121     return join ' ', @out;
 122 }
 123
 124 sub printcmd {
 125     my $fh = shift @_;
 126     my $intro = shift @_;
 127     print $fh $intro," " or die $!;
 128     print $fh shellquote @_ or die $!;
 129     print $fh "\n" or die $!;
 130 }
 131
 132 sub debugcmd {
 133     my $extraprefix = shift @_;
 134     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 135 }
 136
 137 1;