Debian/Dgit.pm

   1 # -*- perl -*-
   2
   3 package Debian::Dgit;
   4
   5 use strict;
   6 use warnings;
   7
   8 use POSIX;
   9 use IO::Handle;
  10 use Config;
  11
  12 BEGIN {
  13     use Exporter   ();
  14     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  15
  16     $VERSION     = 1.00;
  17     @ISA         = qw(Exporter);
  18     @EXPORT      = qw(debiantag server_branch server_ref
  19                       stat_exists fail ensuredir waitstatusmsg failedcmd
  20                       cmdoutput cmdoutput_errok
  21                       git_rev_parse git_get_ref git_for_each_ref
  22                       git_for_each_tag_referring is_fast_fwd
  23                       $package_re $component_re $deliberately_re
  24                       $branchprefix
  25                       initdebug enabledebug enabledebuglevel
  26                       printdebug debugcmd
  27                       $debugprefix *debuglevel *DEBUG
  28                       shellquote printcmd);
  29     # implicitly uses $main::us
  30     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  31     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  32 }
  33
  34 our @EXPORT_OK;
  35
  36 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  37 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  38 our $deliberately_re = "(?:TEST-)?$package_re";
  39 our $branchprefix = 'dgit';
  40
  41 # policy hook exit status bits
  42 # see dgit-repos-server head comment for documentation
  43 # 1 is reserved in case something fails with `exit 1' and to spot
  44 # dynamic loader, runtime, etc., failures, which report 127 or 255
  45 sub NOFFCHECK () { return 0x2; }
  46 sub FRESHREPO () { return 0x4; }
  47
  48 our $debugprefix;
  49 our $debuglevel = 0;
  50
  51 sub initdebug ($) {
  52     ($debugprefix) = @_;
  53     open DEBUG, ">/dev/null" or die $!;
  54 }
  55
  56 sub enabledebug () {
  57     open DEBUG, ">&STDERR" or die $!;
  58     DEBUG->autoflush(1);
  59     $debuglevel ||= 1;
  60 }
  61
  62 sub enabledebuglevel ($) {
  63     my ($newlevel) = @_; # may be undef (eg from env var)
  64     die if $debuglevel;
  65     $newlevel //= 0;
  66     $newlevel += 0;
  67     return unless $newlevel;
  68     $debuglevel = $newlevel;
  69     enabledebug();
  70 }
  71
  72 sub printdebug {
  73     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
  74 }
  75
  76 sub shellquote {
  77     my @out;
  78     local $_;
  79     foreach my $a (@_) {
  80         $_ = $a;
  81         if (!length || m{[^-=_./0-9a-z]}i) {
  82             s{['\\]}{'\\$&'}g;
  83             push @out, "'$_'";
  84         } else {
  85             push @out, $_;
  86         }
  87     }
  88     return join ' ', @out;
  89 }
  90
  91 sub printcmd {
  92     my $fh = shift @_;
  93     my $intro = shift @_;
  94     print $fh $intro," " or die $!;
  95     print $fh shellquote @_ or die $!;
  96     print $fh "\n" or die $!;
  97 }
  98
  99 sub debugcmd {
 100     my $extraprefix = shift @_;
 101     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 102 }
 103
 104 sub debiantag ($) {
 105     my ($v) = @_;
 106     $v =~ y/~:/_%/;
 107     return "debian/$v";
 108 }
 109
 110 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 111 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 112
 113 sub stat_exists ($) {
 114     my ($f) = @_;
 115     return 1 if stat $f;
 116     return 0 if $!==&ENOENT;
 117     die "stat $f: $!";
 118 }
 119
 120 sub _us () {
 121     $::us // ($0 =~ m#[^/]*$#, $&);
 122 }
 123
 124 sub fail {
 125     my $s = "@_\n";
 126     my $prefix = _us().": ";
 127     $s =~ s/^/$prefix/gm;
 128     die $s;
 129 }
 130
 131 sub ensuredir ($) {
 132     my ($dir) = @_; # does not create parents
 133     return if mkdir $dir;
 134     return if $! == EEXIST;
 135     die "mkdir $dir: $!";
 136 }
 137
 138 our @signames = split / /, $Config{sig_name};
 139
 140 sub waitstatusmsg () {
 141     if (!$?) {
 142         return "terminated, reporting successful completion";
 143     } elsif (!($? & 255)) {
 144         return "failed with error exit status ".WEXITSTATUS($?);
 145     } elsif (WIFSIGNALED($?)) {
 146         my $signum=WTERMSIG($?);
 147         return "died due to fatal signal ".
 148             ($signames[$signum] // "number $signum").
 149             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 150     } else {
 151         return "failed with unknown wait status ".$?;
 152     }
 153 }
 154
 155 sub failedcmd {
 156     { local ($!); printcmd \*STDERR, _us().": failed command:", @_ or die $!; };
 157     if ($!) {
 158         fail "failed to fork/exec: $!";
 159     } elsif ($?) {
 160         fail "subprocess ".waitstatusmsg();
 161     } else {
 162         fail "subprocess produced invalid output";
 163     }
 164 }
 165
 166 sub cmdoutput_errok {
 167     die Dumper(\@_)." ?" if grep { !defined } @_;
 168     debugcmd "|",@_;
 169     open P, "-|", @_ or die $!;
 170     my $d;
 171     $!=0; $?=0;
 172     { local $/ = undef; $d = <P>; }
 173     die $! if P->error;
 174     if (!close P) { printdebug "=>!$?\n"; return undef; }
 175     chomp $d;
 176     $d =~ m/^.*/;
 177     printdebug "=> \`$&'",(length $' ? '...' : ''),"\n" if $debuglevel>0; #';
 178     return $d;
 179 }
 180
 181 sub cmdoutput {
 182     my $d = cmdoutput_errok @_;
 183     defined $d or failedcmd @_;
 184     return $d;
 185 }
 186
 187 sub git_rev_parse ($) {
 188     return cmdoutput qw(git rev-parse), "$_[0]~0";
 189 }
 190
 191 sub git_for_each_ref ($$;$) {
 192     my ($pattern,$func,$gitdir) = @_;
 193     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 194     # $reftail is RHS of ref after refs/[^/]+/
 195     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 196     my @cmd = (qw(git for-each-ref), $pattern);
 197     if (defined $gitdir) {
 198         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 199     }
 200     open GFER, "-|", @cmd or die $!;
 201     debugcmd "|", @cmd;
 202     while (<GFER>) {
 203         chomp or die "$_ ?";
 204         printdebug "|> ", $_, "\n";
 205         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 206         $func->($1,$2,$3,$4);
 207     }
 208     $!=0; $?=0; close GFER or die "$pattern $? $!";
 209 }
 210
 211 sub git_get_ref ($) {
 212     # => '' if no such ref
 213     my ($refname) = @_;
 214     my $_ = $refname;
 215     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 216     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 217 }
 218
 219 sub git_for_each_tag_referring ($$) {
 220     my ($objreferring, $func) = @_;
 221     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 222     printdebug "git_for_each_tag_referring ",
 223         ($objreferring // 'UNDEF'),"\n";
 224     git_for_each_ref('refs/tags', sub {
 225         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 226         return unless $objtype eq 'tag';
 227         my $refobjid = git_rev_parse $tagobjid;
 228         return unless
 229             !defined $objreferring # caller wants them all
 230             or $tagobjid eq $objreferring
 231             or $refobjid eq $objreferring;
 232         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 233     });
 234 }
 235
 236 sub is_fast_fwd ($$) {
 237     my ($ancestor,$child) = @_;
 238     my @cmd = (qw(git merge-base), $ancestor, $child);
 239     my $mb = cmdoutput_errok @cmd;
 240     if (defined $mb) {
 241         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 242     } else {
 243         $?==256 or failedcmd @cmd;
 244         return 0;
 245     }
 246 }
 247
 248 1;