Debian/Dgit.pm

   1 # -*- perl -*-
   2 # dgit
   3 # Debian::Dgit: functions common to dgit and its helpers and servers
   4 #
   5 # Copyright (C) 2015-2016  Ian Jackson
   6 #
   7 #    This program is free software; you can redistribute it and/or modify
   8 #    it under the terms of the GNU General Public License as published by
   9 #    the Free Software Foundation; either version 3 of the License, or
  10 #    (at your option) any later version.
  11 #
  12 #    This program is distributed in the hope that it will be useful,
  13 #    but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #    GNU General Public License for more details.
  16 #
  17 #    You should have received a copy of the GNU General Public License
  18 #    along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 package Debian::Dgit;
  21
  22 use strict;
  23 use warnings;
  24
  25 use Carp;
  26 use POSIX;
  27 use IO::Handle;
  28 use Config;
  29 use Digest::SHA;
  30 use Data::Dumper;
  31
  32 BEGIN {
  33     use Exporter   ();
  34     our ($VERSION, @ISA, @EXPORT, @EXPORT_OK, %EXPORT_TAGS);
  35
  36     $VERSION     = 1.00;
  37     @ISA         = qw(Exporter);
  38     @EXPORT      = qw(setup_sigwarn
  39                       dep14_version_mangle
  40                       debiantags debiantag_old debiantag_new
  41                       server_branch server_ref
  42                       stat_exists link_ltarget
  43                       hashfile
  44                       fail ensuredir executable_on_path
  45                       waitstatusmsg failedcmd_waitstatus
  46                       failedcmd_report_cmd failedcmd
  47                       cmdoutput cmdoutput_errok
  48                       git_rev_parse git_get_ref git_for_each_ref
  49                       git_for_each_tag_referring is_fast_fwd
  50                       $package_re $component_re $deliberately_re
  51                       $branchprefix
  52                       initdebug enabledebug enabledebuglevel
  53                       printdebug debugcmd
  54                       $debugprefix *debuglevel *DEBUG
  55                       shellquote printcmd messagequote);
  56     # implicitly uses $main::us
  57     %EXPORT_TAGS = ( policyflags => [qw(NOFFCHECK FRESHREPO)] );
  58     @EXPORT_OK   = @{ $EXPORT_TAGS{policyflags} };
  59 }
  60
  61 our @EXPORT_OK;
  62
  63 our $package_re = '[0-9a-z][-+.0-9a-z]*';
  64 our $component_re = '[0-9a-zA-Z][-+.0-9a-zA-Z]*';
  65 our $deliberately_re = "(?:TEST-)?$package_re";
  66 our $branchprefix = 'dgit';
  67
  68 # policy hook exit status bits
  69 # see dgit-repos-server head comment for documentation
  70 # 1 is reserved in case something fails with `exit 1' and to spot
  71 # dynamic loader, runtime, etc., failures, which report 127 or 255
  72 sub NOFFCHECK () { return 0x2; }
  73 sub FRESHREPO () { return 0x4; }
  74
  75 our $debugprefix;
  76 our $debuglevel = 0;
  77
  78 sub setup_sigwarn () {
  79     our $sigwarn_mainprocess = $$;
  80     $SIG{__WARN__} = sub {
  81         die $_[0] unless getppid == $sigwarn_mainprocess;
  82     };
  83 }
  84
  85 sub initdebug ($) {
  86     ($debugprefix) = @_;
  87     open DEBUG, ">/dev/null" or die $!;
  88 }
  89
  90 sub enabledebug () {
  91     open DEBUG, ">&STDERR" or die $!;
  92     DEBUG->autoflush(1);
  93     $debuglevel ||= 1;
  94 }
  95
  96 sub enabledebuglevel ($) {
  97     my ($newlevel) = @_; # may be undef (eg from env var)
  98     die if $debuglevel;
  99     $newlevel //= 0;
 100     $newlevel += 0;
 101     return unless $newlevel;
 102     $debuglevel = $newlevel;
 103     enabledebug();
 104 }
 105
 106 sub printdebug {
 107     print DEBUG $debugprefix, @_ or die $! if $debuglevel>0;
 108 }
 109
 110 sub messagequote ($) {
 111     local ($_) = @_;
 112     s{\\}{\\\\}g;
 113     s{\n}{\\n}g;
 114     s{\x08}{\\b}g;
 115     s{\t}{\\t}g;
 116     s{[\000-\037\177]}{ sprintf "\\x%02x", ord $& }ge;
 117     $_;
 118 }
 119
 120 sub shellquote {
 121     my @out;
 122     local $_;
 123     foreach my $a (@_) {
 124         $_ = $a;
 125         if (!length || m{[^-=_./:0-9a-z]}i) {
 126             s{['\\]}{'\\$&'}g;
 127             push @out, "'$_'";
 128         } else {
 129             push @out, $_;
 130         }
 131     }
 132     return join ' ', @out;
 133 }
 134
 135 sub printcmd {
 136     my $fh = shift @_;
 137     my $intro = shift @_;
 138     print $fh $intro," " or die $!;
 139     print $fh shellquote @_ or die $!;
 140     print $fh "\n" or die $!;
 141 }
 142
 143 sub debugcmd {
 144     my $extraprefix = shift @_;
 145     printcmd(\*DEBUG,$debugprefix.$extraprefix,@_) if $debuglevel>0;
 146 }
 147
 148 sub dep14_version_mangle ($) {
 149     my ($v) = @_;
 150     # DEP-14 patch proposed 2016-11-09  "Version Mangling"
 151     $v =~ y/~:/_%/;
 152     $v =~ s/\.(?=\.|$|lock$)/.#/g;
 153     return $v;
 154 }
 155
 156 sub debiantag_old ($$) {
 157     my ($v,$distro) = @_;
 158     return "$distro/". dep14_version_mangle $v;
 159 }
 160
 161 sub debiantag_new ($$) {
 162     my ($v,$distro) = @_;
 163     return "archive/$distro/".dep14_version_mangle $v;
 164 }
 165
 166 sub debiantags ($$) {
 167     my ($version,$distro) = @_;
 168     map { $_->($version, $distro) } (\&debiantag_new, \&debiantag_old);
 169 }
 170
 171 sub server_branch ($) { return "$branchprefix/$_[0]"; }
 172 sub server_ref ($) { return "refs/".server_branch($_[0]); }
 173
 174 sub stat_exists ($) {
 175     my ($f) = @_;
 176     return 1 if stat $f;
 177     return 0 if $!==&ENOENT;
 178     die "stat $f: $!";
 179 }
 180
 181 sub _us () {
 182     $::us // ($0 =~ m#[^/]*$#, $&);
 183 }
 184
 185 sub fail {
 186     my $s = "@_\n";
 187     $s =~ s/\n\n$/\n/;
 188     my $prefix = _us().": ";
 189     $s =~ s/^/$prefix/gm;
 190     die $s;
 191 }
 192
 193 sub ensuredir ($) {
 194     my ($dir) = @_; # does not create parents
 195     return if mkdir $dir;
 196     return if $! == EEXIST;
 197     die "mkdir $dir: $!";
 198 }
 199
 200 sub executable_on_path ($) {
 201     my ($program) = @_;
 202     return 1 if $program =~ m{/};
 203     my @path = split /:/, ($ENV{PATH} // "/usr/local/bin:/bin:/usr/bin");
 204     foreach my $pe (@path) {
 205         my $here = "$pe/$program";
 206         return $here if stat_exists $here && -x _;
 207     }
 208     return undef;
 209 }
 210
 211 our @signames = split / /, $Config{sig_name};
 212
 213 sub waitstatusmsg () {
 214     if (!$?) {
 215         return "terminated, reporting successful completion";
 216     } elsif (!($? & 255)) {
 217         return "failed with error exit status ".WEXITSTATUS($?);
 218     } elsif (WIFSIGNALED($?)) {
 219         my $signum=WTERMSIG($?);
 220         return "died due to fatal signal ".
 221             ($signames[$signum] // "number $signum").
 222             ($? & 128 ? " (core dumped)" : ""); # POSIX(3pm) has no WCOREDUMP
 223     } else {
 224         return "failed with unknown wait status ".$?;
 225     }
 226 }
 227
 228 sub failedcmd_report_cmd {
 229     my $intro = shift @_;
 230     $intro //= "failed command";
 231     { local ($!); printcmd \*STDERR, _us().": $intro:", @_ or die $!; };
 232 }
 233
 234 sub failedcmd_waitstatus {
 235     if ($? < 0) {
 236         return "failed to fork/exec: $!";
 237     } elsif ($?) {
 238         return "subprocess ".waitstatusmsg();
 239     } else {
 240         return "subprocess produced invalid output";
 241     }
 242 }
 243
 244 sub failedcmd {
 245     # Expects $!,$? as set by close - see below.
 246     # To use with system(), set $?=-1 first.
 247     #
 248     # Actual behaviour of perl operations:
 249     #   success              $!==0       $?==0       close of piped open
 250     #   program failed       $!==0       $? >0       close of piped open
 251     #   syscall failure      $! >0       $?=-1       close of piped open
 252     #   failure              $! >0       unchanged   close of something else
 253     #   success              trashed     $?==0       system
 254     #   program failed       trashed     $? >0       system
 255     #   syscall failure      $! >0       unchanged   system
 256     failedcmd_report_cmd undef, @_;
 257     fail failedcmd_waitstatus();
 258 }
 259
 260 sub cmdoutput_errok {
 261     confess Dumper(\@_)." ?" if grep { !defined } @_;
 262     debugcmd "|",@_;
 263     open P, "-|", @_ or die "$_[0] $!";
 264     my $d;
 265     $!=0; $?=0;
 266     { local $/ = undef; $d = <P>; }
 267     die $! if P->error;
 268     if (!close P) { printdebug "=>!$?\n"; return undef; }
 269     chomp $d;
 270     if ($debuglevel > 0) {
 271         $d =~ m/^.*/;
 272         my $dd = $&;
 273         my $more = (length $' ? '...' : ''); #');
 274         $dd =~ s{[^\n -~]|\\}{ sprintf "\\x%02x", ord $& }ge;
 275         printdebug "=> \`$dd'",$more,"\n";
 276     }
 277     return $d;
 278 }
 279
 280 sub cmdoutput {
 281     my $d = cmdoutput_errok @_;
 282     defined $d or failedcmd @_;
 283     return $d;
 284 }
 285
 286 sub link_ltarget ($$) {
 287     my ($old,$new) = @_;
 288     lstat $old or return undef;
 289     if (-l _) {
 290         $old = cmdoutput qw(realpath  --), $old;
 291     }
 292     link $old, $new or die "link $old $new: $!";
 293 }
 294
 295 sub hashfile ($) {
 296     my ($fn) = @_;
 297     my $h = Digest::SHA->new(256);
 298     $h->addfile($fn);
 299     return $h->hexdigest();
 300 }
 301
 302 sub git_rev_parse ($) {
 303     return cmdoutput qw(git rev-parse), "$_[0]~0";
 304 }
 305
 306 sub git_for_each_ref ($$;$) {
 307     my ($pattern,$func,$gitdir) = @_;
 308     # calls $func->($objid,$objtype,$fullrefname,$reftail);
 309     # $reftail is RHS of ref after refs/[^/]+/
 310     # breaks if $pattern matches any ref `refs/blah' where blah has no `/'
 311     # $pattern may be an array ref to mean multiple patterns
 312     $pattern = [ $pattern ] unless ref $pattern;
 313     my @cmd = (qw(git for-each-ref), @$pattern);
 314     if (defined $gitdir) {
 315         @cmd = ('sh','-ec','cd "$1"; shift; exec "$@"','x', $gitdir, @cmd);
 316     }
 317     open GFER, "-|", @cmd or die $!;
 318     debugcmd "|", @cmd;
 319     while (<GFER>) {
 320         chomp or die "$_ ?";
 321         printdebug "|> ", $_, "\n";
 322         m#^(\w+)\s+(\w+)\s+(refs/[^/]+/(\S+))$# or die "$_ ?";
 323         $func->($1,$2,$3,$4);
 324     }
 325     $!=0; $?=0; close GFER or die "$pattern $? $!";
 326 }
 327
 328 sub git_get_ref ($) {
 329     # => '' if no such ref
 330     my ($refname) = @_;
 331     local $_ = $refname;
 332     s{^refs/}{[r]efs/} or die "$refname $_ ?";
 333     return cmdoutput qw(git for-each-ref --format=%(objectname)), $_;
 334 }
 335
 336 sub git_for_each_tag_referring ($$) {
 337     my ($objreferring, $func) = @_;
 338     # calls $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 339     printdebug "git_for_each_tag_referring ",
 340         ($objreferring // 'UNDEF'),"\n";
 341     git_for_each_ref('refs/tags', sub {
 342         my ($tagobjid,$objtype,$fullrefname,$tagname) = @_;
 343         return unless $objtype eq 'tag';
 344         my $refobjid = git_rev_parse $tagobjid;
 345         return unless
 346             !defined $objreferring # caller wants them all
 347             or $tagobjid eq $objreferring
 348             or $refobjid eq $objreferring;
 349         $func->($tagobjid,$refobjid,$fullrefname,$tagname);
 350     });
 351 }
 352
 353 sub is_fast_fwd ($$) {
 354     my ($ancestor,$child) = @_;
 355     my @cmd = (qw(git merge-base), $ancestor, $child);
 356     my $mb = cmdoutput_errok @cmd;
 357     if (defined $mb) {
 358         return git_rev_parse($mb) eq git_rev_parse($ancestor);
 359     } else {
 360         $?==256 or failedcmd @cmd;
 361         return 0;
 362     }
 363 }
 364
 365 1;