+ my ($tip,$breakwater) = walk $old;
+ update_head_postlaunder $old, $tip, 'launder for rebase';
+ @ARGV = qw(-i) unless @ARGV; # make configurable
+ runcmd @git, qw(rebase), @ARGV, $breakwater;
+}
+
+sub cmd_analyse () {
+ die if ($ARGV[0]//'') =~ m/^-/;
+ badusage "too many arguments to analyse" if @ARGV>1;
+ my ($old) = @ARGV;
+ if (defined $old) {
+ $old = git_rev_parse $old;
+ } else {
+ $old = get_head();
+ }
+ my ($dummy,$breakwater) = walk $old, 1,*STDOUT;
+ STDOUT->error and die $!;
+}
+
+sub cmd_new_upstream_v0 () {
+ # tree should be clean and this is not checked
+ # automatically and unconditionally launders before rebasing
+ # if rebase --abort is used, laundering has still been done
+
+ my %pieces;
+
+ badusage "need NEW-VERSION UPS-COMMITTISH" unless @ARGV >= 2;
+
+ # parse args - low commitment
+ my $new_version = (new Dpkg::Version scalar(shift @ARGV), check => 1);
+ my $new_upstream_version = $new_version->version();
+
+ my $new_upstream = git_rev_parse shift @ARGV;
+
+ my $piece = sub {
+ my ($n, @x) = @_; # may be ''
+ my $pc = $pieces{$n} //= {
+ Name => $n,
+ Desc => ($n ? "upstream piece \`$n'" : "upstream (main piece"),
+ };
+ while (my $k = shift @x) { $pc->{$k} = shift @x; }
+ $pc;
+ };
+
+ my @newpieces;
+ my $newpiece = sub {
+ my ($n, @x) = @_; # may be ''
+ my $pc = $piece->($n, @x, NewIx => (scalar @newpieces));
+ push @newpieces, $pc;
+ };
+
+ $newpiece->('',
+ OldIx => 0,
+ New => $new_upstream,
+ );
+ while (@ARGV && $ARGV[0] !~ m{^-}) {
+ my $n = shift @ARGV;
+
+ badusage "for each EXTRA-UPS-NAME need EXTRA-UPS-COMMITISH"
+ unless @ARGV && $ARGV[0] !~ m{^-};
+
+ my $c = git_rev_parse shift @ARGV;
+ die unless $n =~ m/^$extra_orig_namepart_re$/;
+ $newpiece->($n, New => $c);
+ }
+
+ # now we need to investigate the branch this generates the
+ # laundered version but we don't switch to it yet
+ my $old_head = get_head();
+ my ($old_laundered_tip,$old_bw,$old_upstream_update) = walk $old_head;
+
+ my $old_bw_cl = classify $old_bw;
+ my $old_upstream_update_cl = classify $old_upstream_update;
+ confess unless $old_upstream_update_cl->{OrigParents};
+ my $old_upstream = parsecommit
+ $old_upstream_update_cl->{OrigParents}[0]{CommitId};
+
+ $piece->('', Old => $old_upstream->{CommitId});
+
+ if ($old_upstream->{Msg} =~ m{^\[git-debrebase }m) {
+ if ($old_upstream->{Msg} =~
+ m{^\[git-debrebase (?:\w*-)?upstream combine \.((?: $extra_orig_namepart_re)+)\]}
+ ) {
+ my @oldpieces = ('', split / /, $1);
+ my $parentix = -1 + scalar @{ $old_upstream->{Parents} };
+ foreach my $i (0..$#oldpieces) {
+ my $n = $oldpieces[$i];
+ $piece->($n, Old => $old_upstream->{CommitId}.'^'.$parentix);
+ }
+ } else {
+ fproblem "previous upstream $old_upstream->{CommitId} is from".
+ " git-debrebase but not an \`upstream combine' commit";
+ }
+ }
+
+ foreach my $pc (values %pieces) {
+ if (!$pc->{Old}) {
+ fproblem "introducing upstream piece \`$pc->{Name}'";
+ } elsif (!$pc->{New}) {
+ fproblem "dropping upstream piece \`$pc->{Name}'";
+ } elsif (!is_fast_fwd $pc->{Old}, $pc->{New}) {
+ fproblem "not fast forward: $pc->{Name} $pc->{Old}..$pc->{New}";
+ }
+ }
+
+ printdebug "%pieces = ", (dd \%pieces), "\n";
+ printdebug "\@newpieces = ", (dd \@newpieces), "\n";
+
+ fproblems_maybe_bail();
+
+ my $new_bw;
+
+ fresh_workarea();
+ in_workarea sub {
+ my @upstream_merge_parents;
+
+ if (!$problems) {
+ push @upstream_merge_parents, $old_upstream->{CommitId};
+ }
+
+ foreach my $pc (@newpieces) { # always has '' first
+ if ($pc->{Name}) {
+ read_tree_subdir $pc->{Name}, $pc->{New};
+ } else {
+ runcmd @git, qw(read-tree), $pc->{New};
+ }
+ push @upstream_merge_parents, $pc->{New};
+ }
+
+ # index now contains the new upstream
+
+ if (@newpieces > 1) {
+ # need to make the upstream subtree merge commit
+ $new_upstream = make_commit \@upstream_merge_parents,
+ [ "Combine upstreams for $new_upstream_version",
+ ("[git-debrebase new-upstream combine . ".
+ (join " ", map { $_->{Name} } @newpieces[1..$#newpieces]).
+ "]"),
+ ];
+ }
+
+ # $new_upstream is either the single upstream commit, or the
+ # combined commit we just made. Either way it will be the
+ # "upstream" parent of the breakwater special merge.
+
+ read_tree_subdir 'debian', "$old_bw:debian";
+
+ # index now contains the breakwater merge contents
+ $new_bw = make_commit [ $old_bw, $new_upstream ],
+ [ "Update to upstream $new_upstream_version",
+ "[git-debrebase new-upstream breakwater $new_upstream_version]",
+ ];
+
+ # Now we have to add a changelog stanza so the Debian version
+ # is right.
+ die if unlink "debian";
+ die $! unless $!==ENOENT or $!==ENOTEMPTY;
+ unlink "debian/changelog" or $!==ENOENT or die $!;
+ mkdir "debian" or die $!;
+ open CN, ">", "debian/changelog" or die $!;
+ my $oldclog = git_cat_file ":debian/changelog";
+ $oldclog =~ m/^($package_re) \(\S+\) / or
+ fail "cannot parse old changelog to get package name";
+ my $p = $1;
+ print CN <<END, $oldclog or die $!;
+$p ($new_version) UNRELEASED; urgency=medium
+
+ * Update to new upstream version $new_upstream_version.
+
+ --
+
+END
+ close CN or die $!;
+ runcmd @git, qw(update-index --add --replace), 'debian/changelog';
+
+ # Now we have the final new breakwater branch in the index
+ $new_bw = make_commit [ $new_bw ],
+ [ "Update changelog for new upstream $new_upstream_version",
+ "[git-debrebase new-upstream changelog $new_upstream_version]",
+ ];
+ };
+
+ # we have constructed the new breakwater. we now need to commit to
+ # the laundering output, because git-rebase can't easily be made
+ # to make a replay list which is based on some other branch
+
+ update_head_postlaunder $old_head, $old_laundered_tip,
+ 'launder for new upstream';
+
+ my @cmd = (@git, qw(rebase --onto), $new_bw, $old_bw, @ARGV);
+ runcmd @cmd;
+ # now it's for the user to sort out