+GPERF_TEST="$(echo foo,bar | ${GPERF} -L ANSI-C)"
+save_CFLAGS="$CFLAGS"
+CFLAGS="$CFLAGS -Wno-error"
+AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM([
+ #include <string.h>
+ const char * in_word_set(const char *, size_t);
+ $GPERF_TEST]
+ )],
+ [GPERF_LEN_TYPE=size_t],
+ [AC_COMPILE_IFELSE(
+ [AC_LANG_PROGRAM([
+ #include <string.h>
+ const char * in_word_set(const char *, unsigned);
+ $GPERF_TEST]
+ )],
+ [GPERF_LEN_TYPE=unsigned],
+ [AC_MSG_ERROR([** unable to determine gperf len type])]
+ )]
+)
+CFLAGS="$save_CFLAGS"
+
+AC_DEFINE_UNQUOTED([GPERF_LEN_TYPE], [$GPERF_LEN_TYPE], [gperf len type])
+
+# ------------------------------------------------------------------------------
+# we use python to build the man page index
+have_python=no
+AC_ARG_WITH([python],
+ [AS_HELP_STRING([--without-python], [Disable building the man page index (default: test)])])
+
+have_lxml=no
+AS_IF([test "x$with_python" != "xno"], [
+ AM_PATH_PYTHON(,, [:])
+ AS_IF([test "x$PYTHON" != "x:"], [
+ AC_MSG_CHECKING([for python lxml module])
+ AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
+ AC_MSG_RESULT([$have_lxml])
+ AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
+ [AC_MSG_WARN([*** python support requires python-lxml module installed])])
+ ])
+])
+AS_IF([test "$have_python" != "yes"], [
+ AS_IF([test "$with_python" = "yes"],
+ [AC_MSG_ERROR([*** python support requested but python support not found])])
+ AS_IF([test "$with_python" != "no"],
+ [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
+])
+
+AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
+