// -*- C -*-

module RecessScrewCutout_RecessCylinder(recessdia,zbelow, h){
  translate([0,0,-zbelow]) cylinder(r=recessdia/2, h=h+1, $fn=40);
}

RecessedScrewCutout_defaultrecessdepth_flat = -0.30;
RecessedScrewCutout_defaultrecessdepth_hex = -0.60;

function RecessedScrewCutout_recessdepth(recessdia,
        recessdepth_arg=RecessedScrewCutout_defaultrecessdepth_flat) =
  recessdepth_arg >= 0 ? recessdepth_arg : -recessdepth_arg * recessdia;

function RecessedScrewCutout_totaldepth(recessdia,
        recessdepth_arg=RecessedScrewCutout_defaultrecessdepth_flat) =
  RecessedScrewCutout_recessdepth(recessdia, recessdepth_arg) +
  + 0.5*recessdia + 0.1;

module RecessedScrewCutout(shaftdia, recessdia, shaftlen,
        zbelow=1,
        recessdepth_arg=RecessedScrewCutout_defaultrecessdepth_flat) {
  // pass recessdepth_arg=-1 for the default for flat heads
  // pass recessdepth_arg=-1 for the default for flat heads
  recessdepth = RecessedScrewCutout_recessdepth(recessdia, recessdepth_arg);
  recesstopz = RecessedScrewCutout_totaldepth(recessdia, recessdepth_arg);

  translate([0,0,-zbelow]) cylinder(r=shaftdia/2, h=shaftlen+zbelow, $fn=20);
  RecessScrewCutout_RecessCylinder(recessdia,zbelow, recessdepth);
  intersection(){
    cube([recessdia + 1, shaftdia + 0.1, recesstopz*2 + 1], center=true);
    translate([0, -recessdia, recesstopz])
      rotate([0,135,0]) cube([recessdia, recessdia*2, 10]);
    RecessScrewCutout_RecessCylinder(recessdia,zbelow, recesstopz+1);
  }
}

//        shaftdia  recessdia
tests = [[2 + 0.5,   4 + 1.0 ],   // shaft came out ~1.0
	 [3 + 0.5,   6 + 1.0 ],   // shaft came out ~2.0
	 [4 + 0.5,   8 + 1.0 ],   // shaft came out ~3.3
	 [5 + 0.5,  10 + 1.0 ],   // shaft came out ~4.5
	 [6 + 0.5,  12 + 1.0 ]];  // shaft came out ~5.4

module OneTest(t){
  blocksz = t[1] + 7;
  h = RecessedScrewCutout_totaldepth(t[1]) + 3;
  difference(){
    translate([-blocksz/2, -blocksz/2, 0])
      cube([blocksz, blocksz, h]);
    RecessedScrewCutout(t[0],t[1], h+1);
  }
}

function Test_x(i) = i<=0 ? 0 :
  Test_x(i-1) + tests[i-1][1]*0.5 + tests[i][1]*0.5 + 4.5;

module Tests(){
  for (i = [0:len(tests)-1]) {
    echo(i, Test_x(i));
    translate([Test_x(i), 0, 0])
      OneTest(tests[i]);
  }
}

//OneTest(tests[1]);
Tests();
//Hole();
//Holes();