topeak-mtx-tortec-expeditionrack-adapter.scad

   1 // -*- C -*-
   2
   3 // brk_*: "bracket", the Topeak MTX bracket
   4 // rack_*: the Tortec rack
   5 // adapt_*: the adapter, ie this file
   6
   7 include <utils.scad>
   8
   9 // strength factor, set to 1 for real prints
  10 //$strf = 0.25;
  11 $strf = 1;
  12
  13 brk_recess_actual = 5.20;
  14
  15 rack_rail_dia = 10.40 + 0.50;
  16 rack_width_inner = 115.86 + 1.0; // between insides of rails
  17
  18 rear_elevation_nominal = 10.04; // top of rack to bottom of bracket
  19 rear_to_front_distance = 230;
  20
  21 general_gap_y = 1.0;
  22
  23 strap_w = 8.0 + 1.0;
  24 strap_th = 2.5;
  25 strap_barrel_dia = 14;
  26 strap_guide_sz = 1;
  27
  28 brk_block_xw = 68.5;
  29 brk_block_z = 14.55 - 0.75;
  30
  31 brk_bolt_dia = 4.0 + 0.5;
  32 brk_nearbolt_recess_dia = 8.86 + 1.5;
  33 brk_nearbolt_recess_depth = 1.09 + 0.25;
  34
  35 brk_bolt_eff_len = 11.78 - 1.0; // inside of recess, to end of bolt
  36 brk_bolt_len_slop = 2.0;;
  37 brk_bolt_nut_th = 3.89;
  38 brk_bolt_nut_across_flats = 7.86 + 0.50;
  39
  40 brk_overall_w = 90.07;
  41
  42 fit_slope_len = 5;
  43
  44 main_sz_y = $strf * 20;
  45 grasp_sz = $strf * 12;
  46 beside_strap_sz = $strf * 8;
  47
  48 $fa=10;
  49 $fs=1;
  50
  51 // calculated
  52
  53 main_sz_z = beside_strap_sz*2 + strap_w;
  54
  55 brk_bottom_y = -brk_recess_actual;
  56 adapt_main_top_y = brk_bottom_y + general_gap_y;
  57
  58 // on LHS, so -ve
  59 rack_rail_x = -(rack_width_inner/2 + rack_rail_dia/2);
  60 rack_rail_outer_x = -(rack_width_inner/2 + rack_rail_dia);
  61
  62 grasp_large_r = (rack_rail_dia + grasp_sz)/2;
  63 grasp_large_x = rack_rail_outer_x + grasp_large_r;
  64
  65 block_x = grasp_large_x + grasp_large_r/2;
  66 block_y_min = adapt_main_top_y - main_sz_y;
  67
  68 strap_barrel_x = rack_width_inner/2 + strap_barrel_dia/2;
  69
  70 rack_shear_ratio = rear_elevation_nominal / rear_to_front_distance;
  71
  72 brk_bolt_nut_top_y = -brk_nearbolt_recess_depth
  73   - brk_bolt_eff_len + brk_bolt_nut_th + brk_bolt_len_slop;
  74
  75 brk_bolt_nut_r = brk_bolt_nut_across_flats/2 / cos(360/12);
  76
  77 module GraspElevation(){
  78   hull(){
  79     translate([ grasp_large_x, adapt_main_top_y - grasp_large_r ])
  80       circle(grasp_large_r);
  81
  82     translate([ grasp_large_x, $rack_rail_y - rack_rail_dia/2 ])
  83       circle(grasp_large_r);
  84
  85     translate([ grasp_large_x, $rack_rail_y + rack_rail_dia/2 ])
  86       circle(grasp_large_r);
  87   }
  88 }
  89
  90 module BlockElevation(){
  91   hull(){
  92     rectfromto([ +block_x, adapt_main_top_y ],
  93                [ -block_x, block_y_min ]);
  94   }
  95 }
  96
  97 module MainExtrude(){
  98   linextr(0, main_sz_z)
  99     children();
 100 }
 101 module RackShear(){
 102   s = rack_shear_ratio;
 103   multmatrix([ [ 1, 0,  0, 0 ],
 104                [ 0, 1, s , 0 ],
 105                [ 0, 0,  1, 0 ],
 106                [ 0, 0,  0, 1 ] ])
 107     children();
 108 }
 109
 110 module GraspFixingElevation(){
 111   intersection(){
 112     union(){
 113       mirror([1,0]) GraspElevation();
 114       translate([ strap_barrel_x, $strap_barrel_y ])
 115         circle(strap_barrel_dia/2 + strap_guide_sz);
 116     }
 117     union(){
 118       rectfromto([0, $rack_rail_y],
 119                  [rack_width_inner, 50]);
 120       intersection(){
 121         translate([ rack_rail_x, $rack_rail_y ])
 122           circle(r = rack_width_inner/2 - rack_rail_x);
 123         polygon([ [ 0, 0 ],
 124                   [ rack_width_inner/2, 0 ],
 125                   $rail_fixing_fit_corner,
 126                   $rail_fixing_fit_corner + [-1,-1] * fit_slope_len,
 127                   [ -block_x, block_y_min ],
 128                   [ 0, block_y_min ]]);
 129       }
 130     }
 131   }
 132 }
 133
 134 module StrapBarrelElevation(){
 135   translate([ strap_barrel_x, $strap_barrel_y ])
 136     circle(strap_barrel_dia/2);
 137 }
 138
 139 // Bracket support block, goes up inside bracket
 140 // Z origin is bolt hole
 141 module BrkBlock(){
 142   linextr( -brk_block_z/2,
 143            +brk_block_z/2 ) {
 144     rectfromto([ -brk_block_xw/2, adapt_main_top_y - 0.1 ],
 145                [ +brk_block_xw/2, 0 ]);
 146   }
 147 }
 148
 149 // Z origin is bolt hole
 150 module BoltHole(){
 151   linextr_y_xz( -100, 10 )
 152     circle(brk_bolt_dia/2);
 153
 154   linextr_y_xz( -brk_nearbolt_recess_depth, 10)
 155     circle(brk_nearbolt_recess_dia/2);
 156
 157   linextr_y_xz( -100, brk_bolt_nut_top_y ) {
 158     circle( r= brk_bolt_nut_r, $fn = 6 );
 159     translate([ 0, brk_bolt_nut_across_flats/2 ])
 160       circle( r=brk_bolt_nut_r/2, $fn = 4);
 161   }
 162 }
 163
 164 module Principal(){
 165   // calculated
 166   $rack_rail_y = brk_bottom_y - $elevation_nominal
 167     - general_gap_y  - rack_rail_dia/2;
 168
 169   $strap_barrel_y = $rack_rail_y + rack_rail_dia/2 + strap_barrel_dia/2;
 170
 171   $rail_fixing_fit_corner = [
 172     rack_width_inner/2,
 173     $rack_rail_y - rack_rail_dia/2
 174   ];
 175
 176   difference(){
 177     union(){
 178       MainExtrude(){
 179         GraspElevation();
 180         BlockElevation();
 181       }
 182       RackShear() MainExtrude(){
 183         StrapBarrelElevation();
 184       }
 185       translate([ 0,0, brk_block_z/2]) BrkBlock();
 186
 187       difference(){
 188         RackShear() MainExtrude(){
 189           GraspFixingElevation();
 190         }
 191
 192         translate([0,0, main_sz_z/2]) linextr(-strap_w/2, +strap_w/2) {
 193           translate([ rack_width_inner/2 - strap_th, 0 ])
 194             rectfromto([ 0, -50 ], [ 50, 50 ]);
 195         }
 196       }
 197     }
 198
 199     RackShear() linextr(-10, main_sz_z+10) {
 200       for (mx=[0,1]) {
 201         mirror([mx,0]) {
 202           translate([ rack_rail_x, $rack_rail_y ]){
 203             hull(){
 204               for (dx = [-rack_rail_dia, 0])
 205                 translate([dx, 0])
 206                   circle(r= rack_rail_dia/2);
 207             }
 208           }
 209         }
 210       }
 211     }
 212
 213     translate([ 0,0, brk_block_z/2]) BoltHole();
 214   }
 215 }
 216
 217 module Front(){ ////toplevel
 218   Principal($elevation_nominal=0);
 219 }
 220
 221 module Rear(){ ////toplevel
 222   Principal($elevation_nominal=rear_elevation_nominal);
 223 }
 224
 225 module Demo(){ ////toplevel
 226   rotate([90, 0, 0]){
 227
 228     Rear();
 229
 230     color("blue")
 231       translate([ 0, -2, -4 ])
 232       square(center=true, [ brk_overall_w, 1 ]);
 233
 234   }
 235 }