topeak-mtx-tortec-expeditionrack-adapter.scad

   1 // -*- C -*-
   2
   3 // brk_*: "bracket", the Topeak MTX bracket
   4 // rack_*: the Tortec rack
   5 // adapt_*: the adapter, ie this file
   6
   7 include <utils.scad>
   8
   9 brk_recess_actual = 5.20;
  10
  11 rack_rail_dia = 10.40 + 0.50;
  12 rack_width_inner = 115.86 + 1.0; // between insides of rails
  13
  14 rear_elevation_nominal = 10.04; // top of rack to bottom of bracket
  15 rear_to_front_distance = 230;
  16
  17 general_gap_y = 1.0;
  18
  19 strap_w = 8.0;
  20 strap_th = 2.5;
  21 strap_barrel_dia = 12;
  22 strap_guide_sz = 2;
  23
  24 main_sz_y = 20;
  25 grasp_sz = 12;
  26 beside_strap_sz = 8;
  27
  28 // calculated
  29
  30 main_sz_z = beside_strap_sz*2 + strap_w;
  31
  32 brk_bottom_y = -brk_recess_actual;
  33 adapt_main_top_y = brk_bottom_y + general_gap_y;
  34
  35 // on LHS, so -ve
  36 rack_rail_x = -(rack_width_inner/2 + rack_rail_dia/2);
  37 rack_rail_outer_x = -(rack_width_inner/2 + rack_rail_dia);
  38
  39 grasp_large_r = (rack_rail_dia + grasp_sz)/2;
  40 grasp_large_x = rack_rail_outer_x + grasp_large_r;
  41
  42 block_x = grasp_large_x + grasp_large_r/2;
  43 block_y_min = adapt_main_top_y - main_sz_y;
  44
  45 strap_barrel_x = rack_width_inner/2 + strap_barrel_dia/2;
  46
  47 module GraspElevation(){
  48   hull(){
  49     translate([ grasp_large_x, adapt_main_top_y - grasp_large_r ])
  50       circle(grasp_large_r);
  51
  52     translate([ grasp_large_x, $rack_rail_y - rack_rail_dia/2 ])
  53       circle(grasp_large_r);
  54
  55     translate([ grasp_large_x, $rack_rail_y + rack_rail_dia/2 ])
  56       circle(grasp_large_r);
  57   }
  58 }
  59
  60 module BlockElevation(){
  61   rectfromto([ +block_x, adapt_main_top_y ],
  62              [ -block_x, block_y_min ]);
  63 }
  64
  65 module GraspFixingElevation(){
  66   intersection(){
  67     union(){
  68       mirror([1,0]) GraspElevation();
  69       translate([ strap_barrel_x, $strap_barrel_y ])
  70         circle(strap_barrel_dia/2 + strap_guide_sz);
  71     }
  72     union(){
  73       rectfromto([0, $rack_rail_y],
  74                  [rack_width_inner, 50]);
  75       intersection(){
  76         translate([ rack_rail_x, $rack_rail_y ])
  77           circle(r = rack_width_inner/2 - rack_rail_x, $fa=1);
  78         polygon([ [ 0, 0 ],
  79                   [ rack_width_inner/2, 0 ],
  80                   [ rack_width_inner/2, $rack_rail_y - rack_rail_dia/2 ],
  81                   [ -block_x, block_y_min ],
  82                   [ 0, block_y_min ]]);
  83       }
  84     }
  85   }
  86 }
  87
  88 module StrapBarrelElevation(){
  89   translate([ strap_barrel_x, $strap_barrel_y ])
  90     circle(strap_barrel_dia/2);
  91 }
  92
  93 module Principal(){
  94   // calculated
  95   $rack_rail_y = brk_bottom_y - $elevation_nominal
  96     - general_gap_y  - rack_rail_dia/2;
  97
  98   $strap_barrel_y = $rack_rail_y + rack_rail_dia/2 + strap_barrel_dia/2;
  99
 100   difference(){
 101     union(){
 102       linextr(0, main_sz_z){
 103         GraspElevation();
 104         BlockElevation();
 105         StrapBarrelElevation();
 106       }
 107
 108       difference(){
 109         linextr(0, main_sz_z){
 110           GraspFixingElevation();
 111         }
 112
 113         translate([0,0, main_sz_z/2]) linextr(-strap_w/2, +strap_w/2) {
 114           translate([ rack_width_inner/2 - strap_th, 0 ])
 115             rectfromto([ 0, -50 ], [ 50, 50 ]);
 116         }
 117       }
 118     }
 119
 120     linextr(-10, main_sz_z+10) {
 121       for (mx=[0,1]) {
 122         mirror([mx,0]) {
 123           translate([ rack_rail_x, $rack_rail_y ]){
 124             hull(){
 125               for (dx = [-rack_rail_dia, 0])
 126                 translate([dx, 0])
 127                   circle(r= rack_rail_dia/2);
 128             }
 129           }
 130         }
 131       }
 132     }
 133   }
 134 }
 135
 136 Principal($elevation_nominal=0);