poster-tube-lid.scad

   1 // -*- C -*-
   2
   3 // Print, for each end:
   4 //
   5 //   CoverPrint
   6 //   StrapMount
   7 //   CatchAssembly
   8
   9 include <funcs.scad>
  10 include <utils.scad>
  11
  12 coarse = false;
  13 enable_head_cups = false;
  14
  15 main_dia = 71.2 + 0.50 - 2.26;
  16 top_thick_middle = 4;
  17 top_thick_by_oring = 3.0;
  18 top_middle_dr = 11;
  19
  20 main_cnr = 6.0;
  21
  22 min_wall = 3;
  23
  24 rivet_posn = 6.0 + 0.30;
  25 rivet_thick = 1.67;
  26 rivet_width = 4.15 + 1.0;
  27 rivet_tall = 5.51 + 1.49;
  28
  29 over_rivet_wall = 1.0;
  30 side_rivet_gap = 1.5;
  31 inside_rivet_gap = 1.5;
  32
  33 bayo_interf = 0.30;
  34 bayo_behind = 8.5;
  35 bayo_interf_width = 2.0;
  36 bayo_interf_slope = 0.5;
  37
  38 oring_thick = 5.0;
  39 oring_bore = 62.0;
  40
  41 oring_upper_embed_angle = 80;
  42 oring_compress = 0.1; // proportion
  43 oring_compress_more = 0.2;
  44
  45 oring_rm_beside = 8;
  46 oring_rm_scale = 2.0;
  47 oring_rm_angle = 20;
  48
  49 side_taper = 1.0;
  50
  51 bayo_gap = 6.0;
  52
  53 bayo_entry = 1.167;
  54 bayo_inramp = 0.9;
  55
  56 bayo_slice_size = coarse ? 5 : 1;
  57
  58 brace_hole_width = 1.0;
  59 brace_above_below = 1.2;
  60 brace_end_shorter = 0.3;
  61
  62 jig_thick = 1.4;
  63 jig_hole_dia = 3.0;
  64 jig_rim = 5;
  65 jig_mark = 5;
  66
  67 strap_loop_thick = 6;
  68 strap_loop_inside = 10;
  69 strap_loop_strlen = 10;
  70 strap_loop_elevation = 45;
  71
  72 sm_inner_circum = 218 - 1.90 - 1.00 - 0.50;
  73 sm_main_thick = 2.0;
  74 sm_main_width = 20;
  75
  76 sm_bolt_dia = 3.5 + 0.1;
  77 sm_bolt_shaft = 21.0;
  78 sm_bolt_head_dia = 6.94 + 1.0;
  79 sm_bolt_head_thick = 2.14;
  80 sm_bolt_nut_width = 5.89 + 0.25;
  81 sm_bolt_nut_thick = 3.68;
  82 sm_bolt_tighten_allow = 2.0;
  83
  84 sm_bolt_y_clear = 0.75;
  85 sm_bolt_y_over = 0.5;
  86
  87 sm_closure_cnr = 3.0;
  88
  89 wm_thick = 5;
  90 wm_screw_dia = 4.5; // XXX
  91 wm_screwdriver_dia = 6.0; // XXX
  92 wm_screw_around = 4.0; // XXX
  93 wm_screw_slot = 3.5;
  94 wm_screw_head = 7.5; // XXX
  95
  96 wmb_screw_dia = 5;
  97 wmb_screw_around_x = 4; // XXX
  98 wmb_screw_around_z = 6; // XXX
  99 wmb_screw_depth_min = 10;
 100 web_screw_len = 25;
 101 wmb_nut_across = 8; // XXX
 102 wmb_nut_around_min = 2; // XXX
 103 wmb_nut_behind_min = 5;
 104 wmb_nut_th = 4; // XXX
 105 wmb_ring_gap = 1.0;
 106
 107 catch_stalk_h = 4.5;
 108 catch_stalk_len = 50;
 109 catch_tip_th = 4;
 110 catch_head_th = 3;
 111
 112 catch_pin_slop = 0.25; // each side, and above
 113 catch_pin_slop_x_extra = 0.0; // only on one side
 114 catch_stalk_above_gap = 1.5;
 115 catch_stalk_eff_bend_rad = catch_stalk_len * 0.75;
 116
 117 catch_strap_width = 12;
 118 catch_stalk_base_width = 15;
 119
 120 catch_knob_dia = 6;
 121 catch_knob_above_gap = 5;
 122 catch_knob_height = 3.0;
 123
 124 catch_stalk_below_gap = 1.0;
 125 catch_stalk_beside_gap = 2.0;
 126
 127 // calculated
 128
 129 TAU = PI*2;
 130
 131 bayo_entry_x = bayo_entry;
 132 bayo_entry_z = bayo_entry;
 133 bayo_inramp_x = bayo_inramp;
 134 bayo_inramp_z = bayo_inramp;
 135
 136 oring_mid_dia = oring_bore + oring_thick;
 137 oring_outer_dia = oring_mid_dia + oring_thick;
 138
 139 oring_oblate = (1 - oring_compress);
 140
 141 oring_y_rad = oring_thick/2 * oring_oblate;
 142 oring_x_rad = oring_thick/2 / oring_oblate;
 143
 144 by_oring_z = oring_y_rad * (1 + cos(oring_upper_embed_angle));
 145
 146 side_height = rivet_posn + bayo_behind + rivet_thick/2;
 147 side_thick = rivet_tall + over_rivet_wall;
 148
 149 top_z = top_thick_by_oring + oring_y_rad + by_oring_z;
 150
 151 middle_bot_z = top_z - top_thick_middle;
 152
 153 bayo_top_z = bayo_behind + bayo_gap;
 154
 155 bayo_nom_rad = main_dia/2 + side_thick;
 156 bayo_real_rad = main_dia/2 + rivet_tall;
 157
 158 rivet_entry_width = rivet_width + side_rivet_gap;
 159
 160 jig_mark_rad = jig_mark + main_dia/2 + jig_thick;
 161
 162 handling_dia = oring_bore + oring_thick*2 + min_wall*2;
 163 handling_angle = 45;
 164
 165 sm_inner_rad = (sm_inner_circum + sm_bolt_tighten_allow/2) / TAU;
 166 sm_outer_rad = sm_inner_rad + sm_main_thick;
 167
 168 wm_main_width = sm_main_width;
 169 wm_y_min = sqrt( pow(sm_inner_rad, 2) -
 170                  pow(sm_inner_rad - (wm_thick - sm_main_thick), 2) );
 171 wm_y_screw = wm_y_min + wm_screw_around + wm_screw_dia/2;
 172 wm_y_max = wm_y_screw + wm_screw_dia/2 + wm_screw_around;
 173 wm_y_slotc_screw = wm_y_screw + wm_screw_slot/2;
 174 wm_y_slot1_screw = wm_y_screw + wm_screw_slot;
 175 wm_y_slot1_max = wm_y_max + wm_screw_slot;
 176 wm_z_slot0_screw = wm_main_width + wm_screwdriver_dia/2;
 177 wm_z_slotc_screw = wm_z_slot0_screw + wm_screw_slot/2;
 178 wm_z_slot1_screw = wm_z_slot0_screw + wm_screw_slot;
 179 wm_z_max = wm_z_slot1_screw + wm_screw_around;
 180
 181 wmb_mount_cut_rad = sm_outer_rad + wmb_ring_gap;
 182 wmb_nut_rad = wmb_nut_across / cos(30) * 0.5;
 183 wmb_x_screw_plus_around_r = max(
 184                                 wmb_screw_around_x + wmb_screw_dia/2,
 185                                 wmb_nut_around_min + wmb_nut_across/2
 186                                 );
 187 wmb_x_screw = -sm_outer_rad + wmb_x_screw_plus_around_r;
 188 wmb_x_outer = -sm_outer_rad + wmb_x_screw_plus_around_r * 2;
 189 function wmb_screw_thing_y_min(dia) = sqrt(
 190                        pow(wmb_mount_cut_rad, 2) -
 191                        pow(wmb_x_screw + dia/2, 2)
 192                        );
 193 wmb_y_screw_end = wmb_screw_thing_y_min(wmb_screw_dia);
 194 wmb_y_nut_min = wmb_screw_thing_y_min(wmb_nut_across + wmb_nut_around_min*2);
 195 wmb_y_mount_max = max(
 196                       wmb_y_nut_min + wmb_nut_th + wmb_nut_behind_min,
 197                       wmb_y_screw_end + wmb_screw_depth_min
 198                       );
 199 wmb_z_screw = max(
 200                   wmb_screw_around_z + wmb_screw_dia/2,
 201                   wmb_nut_around_min + wmb_nut_rad
 202                   );
 203 wmb_z_max = wmb_z_screw * 2;
 204
 205 smc_pos = [ 0, sm_inner_rad, 0 ];
 206
 207 smc_bolt_nut_dia = sm_bolt_nut_width / cos(30);
 208 smc_bolt_nut_eff_thick = sm_bolt_nut_thick + sm_bolt_tighten_allow;
 209
 210 smc_bolt_y = sm_bolt_dia/2 + sm_bolt_y_clear;
 211 smc_max_y = smc_bolt_y + sm_bolt_y_over
 212   + max(sm_bolt_head_dia/2, smc_bolt_nut_dia/2);
 213 smc_cnr_c_x = sm_bolt_shaft/2 - sm_closure_cnr
 214   + sm_bolt_head_thick/2 + smc_bolt_nut_eff_thick/2;
 215
 216 catch_cr = catch_knob_dia/2 + catch_stalk_beside_gap;
 217 catch_strap_thick = sm_main_thick;
 218
 219 echo("R ", sm_inner_rad, bayo_real_rad, bayo_nom_rad);
 220
 221 $fs= coarse ? 2.5 : 0.5;
 222 $fa= coarse ? 5 : 1;
 223
 224 include <poster-tube-lid-parametric.scad>
 225
 226 // bayonet definition
 227
 228 bayo_a = [ bayo_entry_x, 0 ];
 229 bayo_p = [ 0, bayo_entry_z ];
 230 bayo_n = [ 0, bayo_behind-bayo_inramp_z ];
 231 bayo_m = [ bayo_inramp_x, bayo_behind ];
 232 bayo_l = bayo_m + bayo_interf * [ 1/bayo_interf_slope,  1 ];
 233 bayo_k = bayo_l + [ bayo_interf_width, 0 ];
 234 bayo_j = bayo_k + bayo_interf * [ 1/bayo_interf_slope, -1 ];
 235 bayo_i = bayo_j + [ rivet_width + inside_rivet_gap, 0 ];
 236 bayo_h = [ bayo_i[0], bayo_behind + bayo_gap + bayo_interf ];
 237 bayo_g = [ bayo_m[0] - rivet_width, bayo_h[1] ];
 238
 239 bayo_e = [-bayo_p[0], bayo_p[1]] - [rivet_entry_width,0];
 240 bayo_d = [-bayo_a[0], bayo_a[1]] - [rivet_entry_width,0];
 241 bayo_c = bayo_d + [0,-5];
 242 bayo_b = bayo_a + [0,-5];
 243
 244 bayo_f = [ bayo_e[0], bayo_g[1] + (bayo_e[0] - bayo_g[0]) ];
 245
 246 bayo_polygon = [ bayo_a,
 247                  bayo_b,
 248                  bayo_c,
 249                  bayo_d,
 250                  bayo_e,
 251                  bayo_f,
 252                  bayo_g,
 253                  bayo_h,
 254                  bayo_i,
 255                  bayo_j,
 256                  bayo_k,
 257                  bayo_l,
 258                  bayo_m,
 259                  bayo_n,
 260                  bayo_p ];
 261
 262 echo(bayo_polygon);
 263
 264 // CATCH
 265
 266 cppxC = 0.41 * sm_inner_rad * TAU;
 267
 268 // catch pin
 269
 270 cpp_adj = (bayo_n[0] - bayo_f[0]) * (1 - sm_inner_rad / bayo_nom_rad);
 271 // radius scaling due to nom and actual radius difference in
 272 // bayo entry construction
 273
 274 cppa = bayo_f + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 275 cppb = bayo_g + [1,-1] * catch_pin_slop + [1,0] * cpp_adj;
 276 cppd = [ bayo_n[0]
 277          - catch_pin_slop - catch_pin_slop_x_extra,
 278          -catch_stalk_above_gap ];
 279 cppi = [ cppa[0], cppd[1] ];
 280 cppc = [ cppd[0], cppb[1] ];
 281 cpph = cppd + [0,-1] * catch_stalk_h;
 282 cppe = cppd + [0,-1] * (catch_knob_above_gap + catch_knob_dia/2);
 283 cppf = [ cppa[0], cppe[1] ];
 284 cppg = [ cppa[0], cpph[1] ];
 285 cppB = 0.5 * (cppf + cppe);
 286
 287 echo("RR", sm_inner_rad / bayo_nom_rad);
 288
 289 // catch assembly depression below pin
 290
 291 cppy6 = cppB[1] - (catch_knob_dia/2
 292                    + (cppc[1] - cppd[1])
 293                    + catch_stalk_below_gap);
 294 cpp7 = [ cppB[0], cppy6 + catch_cr ];
 295 cpp11 = cpp7 + [1,0] * catch_cr;
 296 cppy9 = cppy6 + catch_strap_width * 1/3;
 297 cpp9 = [ cpp7[0] + catch_cr * 2, cppy9 ];
 298 cpp8 = cpp9 + [0,-1] * catch_cr;
 299 cpp10 = cpp8 + [-1,0] * catch_cr;
 300 cppC = [ cppxC, cpp9[1] ];
 301 cppD = cppC + [0,-1] * catch_strap_width;
 302
 303 // catch assembly stalk and so on
 304
 305 catch_cr3 = catch_cr + catch_stalk_h;
 306
 307 cppF = [ cppg[0] - catch_stalk_eff_bend_rad, cppd[1] ];
 308 cpp4 = [ cppg[0] - catch_stalk_len, cpph[1] ] + [1,-1] * catch_cr;
 309 cpp5 = [ cpp4[0], cppC[1] + catch_cr ];
 310 cpp2 = cpp5 + [-1,0] * (catch_cr * 2 + catch_stalk_base_width);
 311 cpp2r = cpp2 + [1,0] * catch_cr;
 312 cpp2d = cpp2 + [0,-1] * catch_cr;
 313 cpp3 = [ cpp2[0] + catch_cr + catch_cr3, cppd[1] - catch_cr3 ];
 314 cppA = [ -cppxC, cpp9[1] ];
 315 cppE = [ cppA[0], cppD[1] ];
 316
 317 catch_assembly_dy = -cppy9 + catch_strap_width;
 318
 319
 320 module MainProfile(){
 321   main_cnr_pos = [ side_thick, top_z ] - [1,1]*main_cnr;
 322   difference(){
 323     union(){
 324       translate(main_cnr_pos){
 325         intersection(){
 326           difference(){
 327             circle(r = main_cnr);
 328             circle(r = main_cnr * 0.5);
 329           }
 330           square([10,10]);
 331         }
 332       }
 333       polygon([[ -top_middle_dr,        middle_bot_z      ],
 334                [ -top_middle_dr,        top_z             ],
 335                [ main_cnr_pos[0],       top_z             ],
 336                [ side_thick,            main_cnr_pos[1]   ],
 337                [ side_thick,            -side_height      ],
 338                [ side_taper,            -side_height      ],
 339                [ 0,                     -rivet_posn       ],
 340                [ 0,                     by_oring_z        ],
 341                [ -oring_x_rad,          by_oring_z        ],
 342                ],
 343               convexity=10);
 344     }
 345     translate([ oring_mid_dia/2 - main_dia/2, 0 ])
 346       hull(){
 347       translate([ 0, oring_y_rad ])
 348         scale([ 1/oring_oblate * (oring_compress_more+1) , oring_oblate ])
 349         circle(oring_thick/2);
 350       translate([ 0, oring_y_rad*2 - oring_thick/2 ])
 351         circle(oring_thick/2);
 352     }
 353   }
 354 }
 355
 356 module StrapLoopProfile(){
 357   circle(r = strap_loop_thick/2);
 358 }
 359
 360 module StrapLoop(){ ////toplevel
 361   bigrad = strap_loop_inside/2 + strap_loop_thick/2;
 362   extralen = strap_loop_thick * 5;
 363
 364   intersection(){
 365     rotate([strap_loop_elevation, 0,0]){
 366       for (x= [ -1, +1 ] * bigrad) {
 367         translate([x, -extralen, 0])
 368           rotate([-90,0,0])
 369           linear_extrude(height= extralen + strap_loop_strlen + 0.1,
 370                          convexity=10)
 371           StrapLoopProfile();
 372       }
 373       translate([0, strap_loop_strlen, 0]){
 374         intersection(){
 375           rotate_extrude(convexity=10)
 376             translate([bigrad, 0,0])
 377             StrapLoopProfile();
 378           translate([0,50,0])
 379             cube([100,100,100], center=true);
 380         }
 381       }
 382     }
 383     translate([0, 50, 0])
 384       cube(100, center=true);
 385   }
 386 }
 387
 388 module RotateProjectSlice(offset, slice_size, nom_rad, real_rad){
 389   // nom_rad > real_rad
 390   rotate([0,0, atan2(offset, nom_rad) ]){
 391     intersection(){
 392       translate([-offset, -10, 0])
 393         rotate([90,0,0])
 394         linear_extrude(height= nom_rad*2, convexity=50)
 395         children(0);
 396       translate([0,0, -25])
 397         cylinder(h=50, r= real_rad);
 398       translate([0,0, -25])
 399         linear_extrude(height= 50, convexity=50)
 400         polygon([ [ 0,0 ],
 401                   [ -slice_size, -real_rad*2 ],
 402                   [ +slice_size, -real_rad*2 ] ]);
 403     }
 404   }
 405 }
 406
 407 module RotateProject(x_min, x_max, slice_size, nom_rad, real_rad){
 408   offs = [ for (i=[ x_min :
 409                     slice_size :
 410                     x_max + slice_size ]) i ];
 411   echo (offs);
 412   for (off=offs)
 413     RotateProjectSlice(off, slice_size, nom_rad, real_rad)
 414     children(0);
 415 }
 416
 417 module BayonetCutout(){
 418   RotateProject(bayo_c[0], bayo_i[0], bayo_slice_size,
 419                 bayo_nom_rad,
 420                 bayo_real_rad)
 421     translate([-0.5 * (bayo_a[0] + bayo_d[0]), 0])
 422     polygon(bayo_polygon, convexity=10);
 423 }
 424
 425 module ProfilesDemo(){ ////toplevel
 426   translate([-10,0]) MainProfile();
 427   translate([+10, -side_height]) polygon(bayo_polygon, convexity=10);
 428 }
 429
 430 module LimitForHandling(){ ////toplevel
 431   hull() for (r=[0,180])
 432     rotate([0,0,r]) {
 433       for (rs=[-1,+1]) {
 434         for (xd=[0,1]) {
 435           rotate([0,0, rs * handling_angle/2]) {
 436             translate([rs * xd * main_dia/2 * tan(handling_angle/2),
 437                        main_dia/2 + side_thick - main_cnr,
 438                        top_z - main_cnr]) {
 439               mirror([0,0,1])
 440                 cylinder(r= main_cnr, h=50);
 441               sphere(main_cnr);
 442             }
 443           }
 444         }
 445       }
 446     }
 447   hull() rotate_extrude(convexity=10){
 448     translate([ handling_dia/2 - main_cnr, top_z - main_cnr ]) {
 449       circle(r = main_cnr);
 450       mirror([0,1]) square([ main_cnr, 50 ]);
 451     }
 452   }
 453   //cylinder(r= handling_dia/2, h=20);
 454 }
 455
 456 module Cover(){ ////toplevel
 457   render() difference(){
 458     intersection(){
 459       union(){
 460         rotate_extrude(convexity=10)
 461           translate([main_dia/2, 0])
 462           MainProfile();
 463         translate([0,0, middle_bot_z])
 464           cylinder(h= top_thick_middle, r = main_dia/2 - top_middle_dr + 1);
 465       }
 466       LimitForHandling();
 467     }
 468     for (r=[0,180]){
 469       rotate([0,0, r])
 470         translate([0,0, -side_height])
 471         BayonetCutout();
 472       rotate([0,0, r + asin((-oring_rm_beside) / (main_dia/2))])
 473         translate([0,
 474                    oring_mid_dia/2 + oring_thick/4 * oring_rm_scale,
 475                    oring_y_rad * 1.5])
 476         rotate([-oring_rm_angle, 0, 0])
 477         mirror([0,0,1])
 478         cylinder(r = oring_thick/4 * oring_rm_scale, h=20);
 479     }
 480     for (r=[0 : 60 : 179]) {
 481       rotate([0,0, r]) {
 482         height = top_thick_middle - brace_above_below*2;
 483         translate([0,0, middle_bot_z + brace_above_below + height/2 ])
 484         cube(center=true, [ oring_bore - brace_end_shorter,
 485                             brace_hole_width, height ]);
 486       }
 487     }
 488   }
 489   if (enable_head_cups)
 490     for (r=[0,180])
 491       rotate([0,0,r])
 492         translate([-implheadcup_large_dia * .5 - implheadcup_thick/2,
 493                    -implheadcup_large_dia * .0,
 494                    middle_bot_z + 0.1])
 495         ImplHeadCup();
 496
 497 //  translate(strap_loop_thick * [-0.5, 0, +1])
 498 //    translate([handling_dia/2, 0, -side_height])
 499 //    rotate([0,180,0]) rotate([0,0,90])
 500 //    StrapLoop();
 501 }
 502
 503 module SavingHole(){
 504   translate([0,0, -10])
 505     cylinder(r= main_dia/2 - jig_rim, h=20);
 506 }
 507
 508 module Jig(){ ////toplevel
 509   difference(){
 510     union(){
 511       translate([0,0, -side_height]){
 512         cylinder(r= main_dia/2 + jig_thick, h= side_height + jig_thick);
 513       }
 514       translate([-jig_mark_rad, 0, jig_thick - jig_mark])
 515         cube([jig_mark_rad*2, jig_mark, jig_mark]);
 516     }
 517     translate([0,0, -side_height-1])
 518       cylinder(r= main_dia/2, h= side_height + 1);
 519     SavingHole();
 520     translate([0,0, -rivet_posn])
 521       rotate([90, 0,0])
 522       translate([0,0, -100])
 523       cylinder(r= jig_hole_dia/2, h = 200);
 524   }
 525 }
 526
 527 module CoverPrint(){ ////toplevel
 528   rotate([0,180,0]) Cover();
 529 }
 530
 531 module CoverTest2(){ ////toplevel
 532   difference(){
 533     Cover();
 534     SavingHole();
 535   }
 536 }
 537
 538 module CoverTest1(){ ////toplevel
 539   difference(){
 540     CoverTest2();
 541     difference(){
 542       for (r= [ 40, 147 ]){
 543         rotate([0,0, r]){
 544           translate([0,0, -10]) {
 545             cube([ main_dia*3, main_dia * .53, 18], center=true);
 546           }
 547         }
 548       }
 549 //      translate([ 50, 0, 0 ])
 550 //      cube([ 100,
 551 //             strap_loop_inside + strap_loop_thick*2 + 1,
 552 //             100 ],
 553 //           center=true);
 554     }
 555   }
 556 }
 557
 558 module ImplHeadCupTest(){ ////toplevel
 559   for (r=[0,180])
 560     rotate([0,0,r])
 561       translate([-17,0,0])
 562       ImplHeadCup();
 563 }
 564
 565 module SomeStrap(width, cut_width=0){
 566   // children(0) is to add, (1) subtract
 567   difference(){
 568     union(){
 569       cylinder(r=sm_outer_rad, h=width);
 570       StrapMountProtrusion(smc_cnr_c_x + sm_closure_cnr,
 571                            smc_max_y,
 572                            sm_closure_cnr,
 573                            width);
 574       children(0);
 575     }
 576     translate([0,0,-1])
 577       cylinder(r=sm_inner_rad, h=max(width+2, cut_width));
 578     translate(smc_pos)
 579       StrapMountBolt(10, width);
 580     translate(smc_pos)
 581       cube([ sm_bolt_tighten_allow, 40,100 ], center=true);
 582     children(1);
 583   }
 584 }
 585
 586 module StrapMountBolt(l_delta, strap_width){ ///toplevel
 587   // positioned relative to smc_pos
 588   translate([(smc_bolt_nut_eff_thick - sm_bolt_head_thick)/2,
 589              smc_bolt_y,
 590              strap_width/2]){
 591     translate([ -sm_bolt_shaft/2-1, 0,0 ]){
 592       rotate([0,90,0]) cylinder(r= sm_bolt_dia/2, h= sm_bolt_shaft+2);
 593     }
 594     translate([ -sm_bolt_shaft/2, 0,0 ])
 595       rotate([0,-90,0])
 596       cylinder($fn=6, r=smc_bolt_nut_dia/2,
 597                h=smc_bolt_nut_eff_thick + l_delta);
 598     translate([ sm_bolt_shaft/2, 0,0 ])
 599       rotate([0,90,0])
 600       cylinder(r=sm_bolt_head_dia/2, h=sm_bolt_head_thick + l_delta);
 601   }
 602 }
 603
 604 module StrapMountProtrusion(half_x, max_y, cnr, width){
 605   translate(smc_pos){
 606     linear_extrude(height=width, convexity=10){
 607       hull(){
 608         for (m = [0,1]) mirror([m,0,0]) {
 609           translate([-(half_x - cnr), max_y - cnr])
 610             circle(r=cnr);
 611           translate([-half_x, -sm_inner_rad])
 612             square([1,1]);
 613         }
 614       }
 615     }
 616   }
 617 }
 618
 619 module StrapMount(){ ////toplevel
 620   SomeStrap(sm_main_width){
 621     rotate([0,0,180]){
 622       StrapMountProtrusion(strap_loop_inside/2 + strap_loop_thick,
 623                            strap_loop_thick,
 624                            sm_closure_cnr,
 625                            sm_main_width);
 626       translate(smc_pos +
 627                 [0,0, sm_main_width] +
 628                 strap_loop_thick * [ 0, 0.5, -1.0 ])
 629         StrapLoop();
 630     }
 631     union(){ };
 632   }
 633 }
 634
 635 module WallScrewHoleSlot(){ ////toplevel
 636   ds = [-1,+1] * wm_screw_slot/2;
 637   linextr_x_yz(-(wm_thick + 1), 1) {
 638     hull(){
 639       for (d = ds)
 640         translate([d, 0])
 641           circle(r = wm_screw_dia/2);
 642     }
 643   }
 644   hull(){
 645     for (d = ds){
 646       translate([0, d, 0]){
 647         linextr_x_yz(0, 1)
 648           circle(r = wm_screw_head/2);
 649         linextr_x_yz(-(wm_screw_head - wm_screw_dia)/2, 0)
 650           circle(r = wm_screw_dia/2);
 651       }
 652     }
 653   }
 654 }
 655
 656 module WallMountMounts(){
 657   linextr(0, wm_z_max){
 658     translate([ -sm_outer_rad, 0 ])
 659       rectfromto([ 0, -wm_y_max ],
 660                  [ wm_thick, wm_y_slot1_max ]);
 661   }
 662 }
 663 module WallMountScrewHoles(){
 664   translate([ -sm_outer_rad + wm_thick, 0, wm_z_slotc_screw]) {
 665     translate([ 0, wm_y_slotc_screw, 0 ])
 666       WallScrewHoleSlot();
 667     translate([ 0, -wm_y_slotc_screw, 0 ])
 668       rotate([90,0,0])
 669       WallScrewHoleSlot();
 670   }
 671 }
 672
 673 module WallMount(){ ////toplevel
 674   SomeStrap(sm_main_width, wm_z_max + 2){
 675     WallMountMounts();
 676     WallMountScrewHoles();
 677   }
 678 }
 679
 680 module WallMountBaseMounts(){
 681   linextr(0, wmb_z_max) {
 682     difference(){
 683       rectfromto([ -sm_outer_rad,            -wmb_y_mount_max ],
 684                  [ wmb_x_outer, +wmb_y_mount_max ]);
 685       circle(r = wmb_mount_cut_rad);
 686     }
 687   }
 688 }
 689
 690 // screws, nuts, slots for nuts to go down into
 691 module WallMountBaseScrewsEtc(){ ////toplevel
 692   for (my=[0,1]) {
 693     mirror([0, my, 0]) {
 694       translate([wmb_x_screw, 0, wmb_z_screw]) {
 695         linextr_y_xz(wmb_y_screw_end,
 696                      wmb_y_screw_end + 100) // XXX change 100
 697           circle(r = wmb_screw_dia/2);
 698         linextr_y_xz(wmb_y_nut_min,
 699                      wmb_y_nut_min + wmb_nut_th){
 700           hull(){
 701             rotate(30)
 702               circle(r = wmb_nut_rad, $fn = 6);
 703             translate([0, 100]) // XXX change 100
 704               square(wmb_nut_across, center=true);
 705           }
 706         }
 707       }
 708     }
 709   }
 710 }
 711 /*
 712
 713
 714       linextr(wmb_y_screw_end
 715       linextr(0, 20) {
 716         difference(){
 717           translate([ wmb_x_screw, wmb_y_screw_end ])
 718             rectfromto([ -wmb_screw_dia/2, 0 ],
 719                        [ +wmb_screw_dia/2, wmb_screw_depth ]);
 720         }
 721       }
 722     }
 723   }
 724 }*/
 725
 726
 727 module WallMountForBase(){ ////toplevel
 728   SomeStrap(sm_main_width, wm_z_max + 2){
 729     union(){
 730       WallMountMounts();
 731       WallMountBaseMounts();
 732     }
 733     union(){
 734       WallMountScrewHoles();
 735       WallMountBaseScrewsEtc();
 736     }
 737   }
 738 }
 739
 740 module WallMountForBaseDemo(){ ////toplevel
 741   WallMountForBase();
 742   %WallMountBaseScrewsEtc();
 743 }
 744
 745 module CatchAssemblyCoreProfile(){
 746   difference(){
 747     union(){
 748       hull(){
 749         translate(cpp3) circle(r= catch_cr3);
 750         polygon([ cpp3,
 751                   cpp2r,
 752                   cpp5,
 753                   cpph,
 754                   cppd
 755                   ]);
 756       }
 757       polygon([cppD,
 758                cppC,
 759                cpp9,
 760                cpp10,
 761                cpp11,
 762                cpp4,
 763                cpp2r,
 764                cpp2d,
 765                cppA,
 766                cppE
 767                ]);
 768       translate(cpp8) circle(r= catch_cr);
 769     }
 770     hull(){
 771       translate(cpp4) circle(r= catch_cr);
 772       translate(cpp5) circle(r= catch_cr);
 773       translate(cpp7) circle(r= catch_cr);
 774       polygon([cpp4,
 775                cppg,
 776                cpph,
 777                cpp10,
 778                cpp11,
 779                ]);
 780     }
 781     translate(cpp2) circle(r= catch_cr);
 782   }
 783   // if cpp11 is above cpp10, the subtracted hull above
 784   // can go down too far.  Ensure we do not cut off below cppy6.
 785   polygon([ cppE,
 786             cppD,
 787             cpp9,
 788             [ cpp9[0],            cppy6 ],
 789             [ cpp7[0] - catch_cr, cppy6 ],
 790             cpp2d
 791             ]);
 792 }
 793
 794 module CatchTipProfile(dy){
 795   ddy = [0,dy];
 796   intersection(){
 797     translate(cppF){
 798       difference(){
 799 //      circle(r = dist2d(cppF, cppd));
 800         //circle(r = dist2d(cppF, cppa));
 801       }
 802     }
 803     polygon([ cppa,
 804               cppi + ddy,
 805               cppd + ddy,
 806               cppc,
 807               cppb ]);
 808   }
 809 }
 810
 811 module CatchHeadProfile(){
 812   polygon([ cppd,
 813             cppd,
 814             cppi,
 815             cppf,
 816             cppe,
 817             cpph ]);
 818 }
 819
 820
 821 module CatchCore(){ /////toplevel
 822   linear_extrude(height=catch_strap_thick, convexity=10)
 823     CatchAssemblyCoreProfile();
 824
 825   hull(){
 826     linear_extrude(height=catch_head_th, convexity=10)
 827       CatchTipProfile(0);
 828     linear_extrude(height=catch_tip_th, convexity=10)
 829       CatchTipProfile(catch_tip_th - catch_head_th);
 830   }
 831
 832   linear_extrude(height=catch_head_th, convexity=10)
 833     CatchHeadProfile();
 834
 835   translate(concat(cppB,[0])) hull(){
 836     translate([0,0, catch_knob_height + catch_head_th - catch_knob_dia/2])
 837       sphere(r = catch_knob_dia/2);
 838     cylinder(r = catch_knob_dia/2, h = 0.1);
 839   }
 840 }
 841
 842 module CatchPreDistort(){ /////toplevel
 843   scale(100 / sm_inner_rad)
 844     rotate([90,0,0])
 845     CatchCore();
 846 }
 847
 848 module CatchAssembly(){ /////toplevel
 849   rotate([0,0, -(cppe[0] + cppB[0] + catch_pin_slop) / sm_inner_rad * 360/TAU])
 850     translate([0,0, catch_assembly_dy])
 851     scale(sm_inner_rad / 100)
 852     import(str("poster-tube-lid,CatchPostDistort-fa",
 853                (coarse ? 20 : 3),
 854                ".stl"),
 855            convexity=20);
 856
 857   SomeStrap(catch_strap_width){
 858     union(){ }
 859     union(){
 860       translate([-200, -200, -200])
 861         cube([400, 200, 400]);
 862     }
 863   }
 864 }
 865
 866 module CatchDemo(){ /////toplevel
 867   color("blue") translate([0,0,
 868                            -catch_assembly_dy
 869              ])
 870     CatchAssembly();
 871   translate([0,0,+side_height
 872              ])
 873     Cover();
 874 }
 875
 876 module CatchDemoS(){ /////toplevel
 877   color("blue") translate([0,0,
 878              -catch_assembly_dy
 879              ])
 880     CatchAssembly();
 881   intersection(){
 882     translate([0,0,+side_height
 883                ])
 884       Cover();
 885     mirror([0,1,0]) translate([-250,33,0]) cube([500,500,500]);
 886   }
 887   color("black")
 888     translate([0,-33,0])
 889     cube([6.15, 2,2], center=true);
 890 }
 891
 892 module CatchPinProfileDemo(){ /////toplevel
 893   translate([0, 0 * -bayo_behind,0]) {
 894     echo("G ",
 895          bayo_n[0] - bayo_e[0]);
 896     color("blue") translate([0,0,
 897                              +1,
 898                ]) {
 899       CatchAssemblyCoreProfile();
 900       CatchHeadProfile();
 901     }
 902     translate([0,0,10])
 903       color("red")
 904       CatchTipProfile(0);
 905
 906     polygon(bayo_polygon, convexity=10);
 907
 908     // adhoc show a position
 909     color("purple")
 910     translate(concat(
 911                      cppa,
 912                      10
 913                      )) difference(){ circle(2.5); circle(2.0); }
 914
 915  }
 916 }
 917
 918 //ProfilesDemo();
 919 //BayonetCutout();
 920 //MainProfile();
 921 //Cover();
 922 //Jig();
 923 //CoverTest();