man/custom-html.xsl

   1 <?xml version='1.0'?> <!--*-nxml-*-->
   2
   3 <!--
   4   This file is part of systemd.
   5
   6   Copyright 2011 Lennart Poettering
   7
   8   systemd is free software; you can redistribute it and/or modify it
   9   under the terms of the GNU Lesser General Public License as published by
  10   the Free Software Foundation; either version 2.1 of the License, or
  11   (at your option) any later version.
  12
  13   systemd is distributed in the hope that it will be useful, but
  14   WITHOUT ANY WARRANTY; without even the implied warranty of
  15   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  16   Lesser General Public License for more details.
  17
  18   You should have received a copy of the GNU Lesser General Public License
  19   along with systemd; If not, see <http://www.gnu.org/licenses/>.
  20 -->
  21
  22 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  23
  24 <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/html/docbook.xsl"/>
  25
  26 <!-- translate man page references to links to html pages -->
  27 <xsl:template match="citerefentry">
  28   <a>
  29     <xsl:attribute name="href">
  30       <xsl:value-of select="refentrytitle"/><xsl:text>.html</xsl:text>
  31     </xsl:attribute>
  32     <xsl:call-template name="inline.charseq"/>
  33   </a>
  34 </xsl:template>
  35
  36 <xsl:template match="refsect1/title|refsect1/info/title">
  37   <!-- the ID is output in the block.object call for refsect1 -->
  38   <h2>
  39     <xsl:attribute name="id">
  40       <xsl:call-template name="inline.charseq"/>
  41     </xsl:attribute>
  42     <xsl:apply-templates/>
  43     <a>
  44       <xsl:attribute name="class">
  45         <xsl:text>headerlink</xsl:text>
  46       </xsl:attribute>
  47       <xsl:attribute name="title">
  48         <xsl:text>Permalink to this headline</xsl:text>
  49       </xsl:attribute>
  50       <xsl:attribute name="href">
  51         <xsl:text>#</xsl:text>
  52         <xsl:call-template name="inline.charseq"/>
  53       </xsl:attribute>
  54       <xsl:text>¶</xsl:text>
  55     </a>
  56   </h2>
  57 </xsl:template>
  58
  59 <xsl:template match="refsect2/title|refsect2/info/title">
  60   <h3>
  61     <xsl:attribute name="id">
  62       <xsl:call-template name="inline.charseq"/>
  63     </xsl:attribute>
  64     <xsl:apply-templates/>
  65     <a>
  66       <xsl:attribute name="class">
  67         <xsl:text>headerlink</xsl:text>
  68       </xsl:attribute>
  69       <xsl:attribute name="title">
  70         <xsl:text>Permalink to this headline</xsl:text>
  71       </xsl:attribute>
  72       <xsl:attribute name="href">
  73         <xsl:text>#</xsl:text>
  74         <xsl:call-template name="inline.charseq"/>
  75       </xsl:attribute>
  76       <xsl:text>¶</xsl:text>
  77     </a>
  78   </h3>
  79 </xsl:template>
  80
  81 <xsl:template match="varlistentry">
  82   <dt>
  83     <xsl:attribute name="id">
  84       <xsl:call-template name="inline.charseq">
  85         <xsl:with-param name="content">
  86           <xsl:copy-of select="term[position()=1]" />
  87         </xsl:with-param>
  88       </xsl:call-template>
  89     </xsl:attribute>
  90     <xsl:apply-templates select="term"/>
  91     <a>
  92       <xsl:attribute name="class">
  93         <xsl:text>headerlink</xsl:text>
  94       </xsl:attribute>
  95       <xsl:attribute name="title">
  96         <xsl:text>Permalink to this term</xsl:text>
  97       </xsl:attribute>
  98       <xsl:attribute name="href">
  99         <!--        <xsl:call-template name="href.target.uri" /> -->
 100         <xsl:text>#</xsl:text>
 101         <xsl:call-template name="inline.charseq">
 102           <xsl:with-param name="content">
 103             <xsl:copy-of select="term[position()=1]" />
 104           </xsl:with-param>
 105         </xsl:call-template>
 106       </xsl:attribute>
 107       <xsl:text>¶</xsl:text>
 108     </a>
 109   </dt>
 110   <dd>
 111     <xsl:apply-templates select="listitem"/>
 112   </dd>
 113 </xsl:template>
 114
 115
 116 <!-- add Index link at top of page -->
 117 <xsl:template name="user.header.content">
 118   <style>
 119     a.headerlink {
 120       color: #c60f0f;
 121       font-size: 0.8em;
 122       padding: 0 4px 0 4px;
 123       text-decoration: none;
 124       visibility: hidden;
 125     }
 126
 127     a.headerlink:hover {
 128       background-color: #c60f0f;
 129       color: white;
 130     }
 131
 132     h1:hover > a.headerlink, h2:hover > a.headerlink, h3:hover > a.headerlink, dt:hover > a.headerlink {
 133       visibility: visible;
 134     }
 135   </style>
 136
 137   <a>
 138     <xsl:attribute name="href">
 139       <xsl:text>index.html</xsl:text>
 140     </xsl:attribute>
 141     <xsl:text>Index </xsl:text>
 142   </a>·
 143   <a>
 144     <xsl:attribute name="href">
 145       <xsl:text>systemd.directives.html</xsl:text>
 146     </xsl:attribute>
 147     <xsl:text>Directives </xsl:text>
 148   </a>·
 149   <a>
 150     <xsl:attribute name="href">
 151       <xsl:text>../python-systemd/index.html</xsl:text>
 152     </xsl:attribute>
 153     <xsl:text>Python </xsl:text>
 154   </a>·
 155   <a>
 156     <xsl:attribute name="href">
 157       <xsl:text>../libudev/index.html</xsl:text>
 158     </xsl:attribute>
 159     <xsl:text>libudev </xsl:text>
 160   </a>·
 161   <a>
 162     <xsl:attribute name="href">
 163       <xsl:text>../libudev/index.html</xsl:text>
 164     </xsl:attribute>
 165     <xsl:text>gudev </xsl:text>
 166   </a>
 167
 168   <span style="float:right">
 169     <xsl:text>systemd </xsl:text>
 170     <xsl:value-of select="$systemd.version"/>
 171   </span>
 172   <hr/>
 173 </xsl:template>
 174
 175 <xsl:template match="literal">
 176   <xsl:text>"</xsl:text>
 177   <xsl:call-template name="inline.monoseq"/>
 178   <xsl:text>"</xsl:text>
 179 </xsl:template>
 180
 181 <!-- Switch things to UTF-8, ISO-8859-1 is soo yesteryear -->
 182 <xsl:output method="html" encoding="UTF-8" indent="no"/>
 183
 184 </xsl:stylesheet>