fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 7.37 /* xxx? */ ];   // from rhs
 166 noisecancelmic_dia = 4.00;
 167
 168 // fingerpushhole_dias = []; xxx what was this
 169 fingerpushhole_dias = [ 15, 18 ];
 170
 171 lanyard_half_dia = 1.15;
 172 lanyard_entry_rel_breadth = 2;
 173 lanyard_channel_len = 15;
 174 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 175 rearspeaker_size   = [  3.76,  7.36 ];
 176
 177 microusb_above = 1.64 - 0.25;
 178 microusb_below = 2.42;
 179 microusb_width = 12.16 + 2.0 + 1.25;
 180
 181 case_th_bottom = 2.5;
 182 case_th_lid = 3.0;
 183 case_th_side = 2.3;
 184 case_th_lip = 1.2;
 185
 186 lid_screen_gap_extra = .66;
 187
 188 case_struts_count = 6;
 189 case_struts_solid_below = 1.00;
 190 case_struts_solid_above = 0.75;
 191 case_struts_width = 0.10;
 192
 193 keeper_th_z = 0.75;
 194 keeper_th_x = 0.75;
 195 keeper_inner_width = 2.75;
 196 keeper_inner_height = 2.75;
 197 keeper_slant_slope = 2; // larger means steeper
 198
 199 keeper_gap_z_top = 0.25;
 200 keeper_gap_z_bot = 0.75;
 201 keeper_gap_x     = 0.25;
 202 keeper_gap_x_holes = 0.75;
 203
 204 keeper_side = 0; // 0 = lhs; 1 = rhs
 205
 206 case_lip = 1.25;
 207
 208 lid_gap_x = 0.25;
 209 lid_gap_z = 0.25;
 210 lid_lip = 1.75;
 211 lid_edgepart_width = 5.0;
 212 lid_buttoncover_thick = 1.3;
 213 lid_buttoncover_reinf = 0.65;
 214
 215 foldover_gap = 0.50;
 216 foldover_lever_gap = 0.50;
 217
 218 // xxx replace hinge screw with nail plan
 219
 220 // properties of the hinge fasteners
 221 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 222 hingescrew_shaft_len = 12;
 223 hingescrew_fasteners_extra_thick = 0.40;
 224 // ^ amount of thread protruding if everything was completely nominal
 225 //   and we are using two nuts
 226 hingescrew_nut_access_dia = 4.72 + 0.50;
 227 // ^ washer is 4.72 dia
 228 //   also, want to get pliers or tiny spanner in to do up locknut
 229 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 230 hingescrew_nut_thick = 1.93;
 231 hingescrew_head_th = 1.38 + 0.75;
 232 hingescrew_head_dia = 3.92;
 233
 234 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 235
 236 lever_cover_th = 0.75;
 237 hingemount_th = 2.5;
 238 hingemount_wd = 4.8725;
 239
 240 $fa = 5;
 241 $fs = 0.1;
 242
 243 button_l_fudge = 4.4;
 244 buttonishleg_default_l_is_fudge = 10;
 245
 246 hinge_base_slope = 1.5; // bigger is steeper
 247
 248 strut_min_at_end = 1.5;
 249
 250 hinge_x_gap = 0.125;
 251 hinge_x_postscrew_gap = 0.75;
 252 hinge_x_arms_gap = 0.35;
 253 hinge_r_arms_gap = 0.55;
 254
 255 // xxx there isn't one of these, speaker is by hinge
 256 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 257
 258 thumbrecess_depth = 1.3;
 259 thumbrecess_width = 16.5;
 260 thumbrecess_topcurve_r = 5.0;
 261
 262 prop_recess_under = 0.50;
 263 prop_recess_slop = 0.200; // each side
 264 prop_end_dia = 0.5;
 265 prop_main_th = 3;
 266 prop_taper_len = 6;
 267 prop_main_width = 4;
 268 prop_side_gap = 0.75; // each side
 269 prop_lidrecess_behind = 0.75;
 270 prop_caserecess_behind = 0.75;
 271 prop_caserecess_taper = 0.45; // one side only
 272 prop_prop_gap = 0.5;
 273 prop_prong_heel_slope = 0.5;
 274
 275 lid_fold_clearance_antislop = 0.5;
 276
 277 $button_leg_only = false;
 278 $suppress_forward_holes = false;
 279
 280 // ---------- calculated ----------
 281
 282 phone_total_thick = phone_edge_thick;
 283
 284 phone_width =  (phone + bumper*2)[0];
 285 phone_height = (phone + bumper*2)[1];
 286
 287 inside_br = [phone_width, -phone_height];
 288
 289 prop_prong_h = prop_main_th;
 290
 291 //echo(camera_pos_tl + bumper,
 292 //     camera_pos_br + bumper);
 293
 294 // ----- could be changed -----
 295 lid_buttoncover_gap = lid_gap_x;
 296 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 297
 298 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 299
 300 //prop_nose_len = case_th_lid - prop_recess_under;
 301 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 302 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 303
 304
 305 //lid_lip_overlap_width xxx bad name = ;
 306 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 307
 308 epp0 = [0,0];
 309 epp1 = [0, -phone_edge_thick];
 310 epp2i = epp1; // conflated for FP4
 311 epp2o = epp2i;
 312 epp3 = epp2i + [10, 0];
 313 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 314 epp4 = epp5 + [-1,0] * case_th_side;
 315
 316 kppe = [0,0];
 317 kppd = kppe + [1,0] * keeper_inner_width;
 318 kppc = kppd + [0,1] * keeper_th_z;
 319 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 320 kppf = kppe - [0,1] * keeper_inner_height;
 321 kppa = [ kppb[0], kppf[1] ];
 322
 323 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 324 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 325
 326 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 327 // exact x posn not very important; must extend past end of keeper
 328
 329 lpp15 = [ lpp14[0],
 330           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 331           + lid_screen_gap_extra ];
 332 // ^ beam theory says to maximise force before contact,
 333 //   the gap below the `beam' (the lid) must be 1/3
 334 //   the thickness (ie the lid thickness) if the beam
 335 //   is solid, or 1/2 if it has a top and bottom only.
 336 //   ours is mostly solid.
 337
 338 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 339              case_th_lip);
 340
 341 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 342 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 343
 344 case_bottom_z = epp2o[1] - case_th_bottom;
 345
 346 // button profile
 347 bppM = epp4 + [0,5];
 348 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 349 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 350 bppS = [ epp1[0], bppR[1] ];
 351 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 352 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 353 bppO = [ bppN[0], bppP[1] ];
 354 bppL = lpp10 + [5,0];
 355 bppK = [ bppL[0], bppN[1] ];
 356 bppJ = [ bppN[0], bppL[1] ];
 357 bppU = [ bppJ[0], lpp12[1] ];
 358 bppV = lpp11;
 359 bppW = lpp10;
 360
 361 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 362
 363 // notification led aperture
 364
 365 nla_r0 = led_aperture/2;
 366 nla_r1 = nla_r0 + led_window_ledge;
 367 nla_r2 = nla_r1 + multicolour_gap;
 368 nla_t =
 369   led_window_style >= 3 ? initial_layer_thick :
 370   led_window_style >= 2 ? led_window_ledge : 0;
 371
 372
 373 // hinge plan
 374 hp_rn = hingescrew_nut_access_dia/2;
 375 hp_r2_min = hp_rn + lever_cover_th;
 376 hp_rs = hingescrew_shaft_dia/2;
 377 hp_r1_min = hp_rs + hingemount_th;
 378
 379 hp_r1 = max(hp_r1_min, hp_r2_min);
 380 hp_r2 = hp_r1;
 381
 382 hppU = lpp13;
 383 hppS = epp2o + [0,-1] * case_th_bottom;
 384 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 385
 386 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 387          0.5 * (hppU + hppS)[1] ];
 388 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 389 hppB = hppT + [0,-1] * hp_k;
 390
 391 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 392 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 393 hppE = [ hppE_x, hppE_y ];
 394
 395 // hinge elevation x coords
 396
 397 hex20 = max(epp2o[0],
 398             phone_cnr_rad,
 399             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 400 hex21 = hex20 + hingemount_wd;
 401 hex22 = hex21 + hinge_x_gap;
 402 hex27 = hex20 + hingescrew_shaft_len;
 403 hex24 = hex27 + hinge_x_postscrew_gap;
 404 hex23 = hex27 - (hingescrew_nut_thick*2
 405                  + hingescrew_fasteners_extra_thick);
 406 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 407
 408 echo(hex20, hex21, hex22, hex23, hex24);
 409 //  6, 10.8725, 10.9975, 13.74, 18.75
 410 module chk(act,exp) {
 411   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 412   else echo("ok", act);
 413 }
 414 chk(hex20, 6);
 415 chk(hex21, 10.8725);
 416 chk(hex22, 10.9975);
 417 chk(hex23, 13.74);
 418 chk(hex24, 18.75);
 419
 420 lid_fold_clearance_skew =
 421   (lpp10[1] - hppB[1]) /
 422   (lpp10[0] - hppB[0]);
 423
 424 echo("SK",lid_fold_clearance_skew);
 425
 426 // thumb recess (used to be "catch" hence cpp*
 427
 428 cppA = epp4 + [thumbrecess_depth, 0];
 429 cppB = [ cppA[0], epp1[1] ];
 430
 431 // lanyard
 432
 433 ly_r = lanyard_half_dia / 2;
 434 ly_rc = ly_r * 2;
 435
 436 ly_theta = 90;
 437 ly_o = epp2i + 3 * ly_r * [0,1];
 438
 439 max_case_bottom_edge_thickness =
 440   case_th_bottom;
 441
 442 ly_q_z = -(ly_rc + ly_r);
 443 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 444
 445 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 446
 447 // prop recess in case
 448
 449 prop_x_pos = phone_width/2;
 450
 451 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 452
 453 prc_r1 = prop_end_dia/2;
 454 prc_r3 = prc_r1 + prop_recess_slop;
 455
 456 prcp2 = [ epp4[0] + prop_buildout_less,
 457           case_bottom_z ];
 458
 459 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 460
 461 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 462           epp2i[1] - prc_r3 - prop_recess_under];
 463
 464 // prop recess in lid
 465
 466 prl_r10 = prop_end_dia/2;
 467 prl_r10o = prl_r10 + prop_recess_slop;
 468
 469 prlp10 = lpp10 + [1,1] * prl_r10o
 470   + [1,0] * prop_lidrecess_behind
 471   + [0,1] * prop_recess_under;
 472
 473 // prop
 474
 475 $prpp10 = [0,0];
 476 $prpp11 = [0, prop_taper_len];
 477
 478 $prp_r10 = prl_r10;
 479
 480 // ---------- modules ----------
 481
 482 module AdhocMultiprintFrame(phase, z0, zs) {
 483   // from z0 to z0 + zs*layer
 484   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 485   xextra = extra + -epp4[0];
 486   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 487   yextra = extra + -epp4[0];
 488   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 489   p0 = [ xrange[0], yrange[0] ];
 490   p1 = [ xrange[1], yrange[1] ];
 491   echo(p0, p1);
 492   translate([0,0, z0])
 493     mirror([0,0, zs<0 ? 1 : 0])
 494     linear_extrude(height= initial_layer_thick)
 495     difference(){
 496       rectfromto(p0 - [1,1] * initial_layer_width,
 497                  p1 + [1,1] * initial_layer_width);
 498       rectfromto(p0, p1);
 499     }
 500 }
 501
 502 module KeeperProfile(slant=0){
 503   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 504   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 505 }
 506
 507 module EdgeProfile(){
 508   difference(){
 509     hull(){
 510       translate(epp3) square(case_th_bottom*2, center=true);
 511       circleat(epp2o, r=case_th_bottom);
 512       circleat(epp1, r=case_th_side);
 513       rectfromto(epp0, epp4);
 514     }
 515     polygon([ epp5 + [0,10],
 516               epp1,
 517               epp3 + [10,0] ]);
 518   }
 519 }
 520
 521 module LanyardLanyardProfile(entry=false){
 522   hull(){
 523     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 524       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 525         circle(r= lanyard_half_dia/2);
 526   }
 527 }
 528
 529 module LanyardCurveChannelProfile(){
 530   translate([0, -ly_r])
 531     LanyardLanyardProfile();
 532 }
 533
 534 module LanyardEntryChannelProfile(){
 535   LanyardLanyardProfile(true);
 536 }
 537
 538 module LanyardMainChannelProfile(){
 539   LanyardCurveChannelProfile();
 540   difference(){
 541     square(center=true, ly_r * [6, 2]);
 542     for (xs=[-1,+1])
 543       translate(ly_r * [3 * xs, -1])
 544         circle(r = ly_r);
 545   }
 546 }
 547
 548 module LanyardEntryOuterProfile(){
 549   circleat([ly_re + ly_r, 0], ly_re);
 550 }
 551
 552 module LanyardEntry(){
 553   q_z = ly_q_z;
 554   oec_y = ly_oec_y;
 555
 556   d_x = -ly_rc;
 557
 558   translate([d_x, 0, q_z]) {
 559     intersection(){
 560       rotate([90,0,0])
 561         rotate_extrude(convexity=10)
 562         rotate(90)
 563         translate([0, -q_z])
 564         LanyardCurveChannelProfile();
 565       translate([0,-10,0])
 566         cube([20,20,20]);
 567     }
 568   }
 569
 570   mirror([0,0,1])
 571     translate([0,0,-1])
 572     linear_extrude(height=20)
 573     rotate(-90)
 574     LanyardEntryChannelProfile();
 575
 576   translate([0, ly_r*2, 0])
 577     rotate([90,0,0])
 578     linear_extrude(height = ly_r*4){
 579     difference(){
 580       rectfromto([d_x, q_z], [ly_r, 0]);
 581       circleat([d_x, q_z], ly_rc);
 582     }
 583   }
 584
 585   translate([0,0,q_z]){
 586     for (my=[0,1])
 587       mirror([0,my,0]){
 588         translate([0, oec_y, 0]){
 589           difference(){
 590             translate(ly_re * [-1,0,-2])
 591               cube(ly_re * [2,1,2]);
 592             rotate_extrude(convexity=10)
 593               LanyardEntryOuterProfile();
 594           }
 595         }
 596       }
 597     difference(){
 598       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 599         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 600       for (mx=[0,1])
 601         mirror([mx,0,0])
 602           rotate([90,0,0])
 603           translate([0,0,-10])
 604           linear_extrude(height=20)
 605           LanyardEntryOuterProfile();
 606     }
 607   }
 608 }
 609
 610 module LanyardCutout(l){
 611   rotate([0,-90,0])
 612     linear_extrude(height=l)
 613     rotate(-90)
 614     LanyardMainChannelProfile();
 615
 616   for (ee=[0,1]){
 617     translate(ee * l * [-1,0])
 618       mirror([ee,0,0])
 619       LanyardEntry();
 620   }
 621 }
 622
 623 module LidEdgeProfile(){
 624   polygon([ lpp10,
 625             lpp11,
 626             lpp12,
 627             lpp13,
 628             lpp13 + [10, 0],
 629             lpp15 + [10, 0],
 630             lpp15,
 631             lpp14,
 632             ]);
 633   intersection(){
 634     circleat(lpp12, r=lp_r12);
 635     rectfromto( lpp12 + [-10,   0],
 636                 lpp12 + [+10, +10] );
 637   }
 638 }
 639
 640 module LidEdgeFoldClearanceProfile(){
 641   translate([-lid_fold_clearance_antislop, 0])
 642     polygon([ lpp10,
 643               lpp11,
 644               lpp11 + [-20,  0],
 645               lpp11 + [-20, 20],
 646               lpp11 + [+20, 20],
 647               lpp10 + [+20,  0] ]);
 648 }
 649
 650 module ButtonCoverProfile(){
 651   intersection(){
 652     polygon(concat([ bppM, bppP, bppO, bppJ ],
 653                    (enable_support && !$button_suppress_over_keeper
 654                     ? [ bppU, bppV, bppW ] : []),
 655                    [ bppL, bppK ]));
 656     hull(){
 657       EdgeProfile();
 658       LidEdgeProfile();
 659     }
 660   }
 661 }
 662
 663 module ButtonPlan(l, deep, cut){
 664   epsilon =
 665     (cut  ? 0 : lid_buttoncover_gap);
 666
 667   delta =
 668     (deep ? lid_buttoncover_overlap : 0);
 669
 670   C = [0,0]; // by definition
 671   T = [ 0, epp4[1] ];
 672   G = T + [0,10];
 673
 674   B0 = C + [0,-1] * button_cutout_depth;
 675   B1 = B0 + [0,1] * epsilon;
 676
 677   r0 = 0.5 * (T[1] - B0[1]);
 678   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 679   H = A + [0,-1] * delta;
 680
 681   D = A + [-2,0] * r0;
 682   F = D + [0,10];
 683
 684   E0 = 0.5 * (D + A);
 685   E1 = E0 + [1,0] * epsilon;
 686
 687   I0 = [ E0[0], H[1] ];
 688   I1 = [ E1[0], H[1] ];
 689
 690   hull(){
 691     for (m=[0,1]) mirror([m,0])
 692       circleat(H, r0 - epsilon);
 693   }
 694   for (m=[0,1]) mirror([m,0]) {
 695     difference(){
 696       polygon([ E1,
 697                 I1,
 698                 H,
 699                 B1,
 700                 G,
 701                 F,
 702                 D
 703                 ]);
 704       circleat(D, r0 + epsilon);
 705     }
 706   }
 707 }
 708
 709 module ButtonCoverReinf(){ ////toplevel
 710   minkowski(){
 711     rotate([90,0,0])
 712       linear_extrude(height=0.01)
 713       intersection(){
 714         ButtonCoverProfile();
 715         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 716           square([100,100]);
 717     }
 718     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 719       circle(r= lid_buttoncover_reinf);
 720       translate([-20,0]) square(40, center=true);
 721     }
 722   }
 723 }
 724
 725 module ThumbRecessCutProfile(){
 726   difference(){
 727     polygon([ cppA + [-10,0],
 728               cppB + [-10,0],
 729               cppB,
 730               cppA ]);
 731     circleat(epp1, r=case_th_side);
 732   }
 733 }
 734
 735 module Flip_rhs(yn=[0,1]) {
 736   for ($rhsflip=yn) {
 737     translate([phone_width/2, 0, 0])
 738       mirror([$rhsflip,0,0])
 739       translate([-phone_width/2, 0, 0])
 740       children();
 741   }
 742 }
 743
 744 module Flip_bot(yn=[0,1]) {
 745   for ($botflip=yn) {
 746     translate([0, -phone_height/2, 0])
 747       mirror([0, $botflip, 0])
 748       translate([0, phone_height/2, 0])
 749       children();
 750   }
 751 }
 752
 753 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 754   // sides
 755   Flip_rhs(){
 756     translate([0, -phone_cnr_rad, 0])
 757       rotate([90,0,0])
 758       linear_extrude(height = phone_height - phone_cnr_rad*2)
 759       children(0);
 760   }
 761   // corners
 762   Flip_rhs() Flip_bot() {
 763     translate([+1,-1] * phone_cnr_rad)
 764       intersection(){
 765         rotate_extrude()
 766           intersection(){
 767             mirror([1,0,0])
 768               translate([-1,0] * phone_cnr_rad)
 769               children(0);
 770             rectfromto([0,-20],[10,20]);
 771           }
 772         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 773           cube([10,10,40]);
 774       }
 775   }
 776   // top and bottom
 777   Flip_bot(){
 778     translate([ phone_width - phone_cnr_rad, 0,0 ])
 779       rotate([90,0,-90])
 780       linear_extrude(height = phone_width - phone_cnr_rad*2)
 781       children(0);
 782   }
 783   // fill
 784   translate([0,0, fill_zstart])
 785     mirror([0,0, fill_downwards])
 786     linear_extrude(height = fill_th)
 787     rectfromto([+1,-1] * phone_cnr_rad,
 788                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 789 }
 790
 791 module CaseAperture(pos, dia, $fn) {
 792   theta = 180/$fn;
 793   translate([ pos[0] + bumper[0],
 794               -epp2i[0],
 795               -pos[1] ])
 796     rotate([-90, theta, 0])
 797     cylinder(r = dia/2 / cos(theta),
 798              h = 60);
 799 }
 800
 801 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 802   // y_ref_sign:
 803   //   +1  measured from top    of actual phone to top    of button
 804   //   -1  measured from bottom of actual phone to bottom of button
 805   //    0  y is centre of button in coordinate system
 806   $button_l= l;
 807   $button_suppress_over_keeper= suppress_over_keeper;
 808   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 809           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 810           y;
 811   //echo(eff_y);
 812   translate([0, eff_y, 0])
 813     children();
 814 }
 815
 816 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 817   $button_leg_only = true;
 818   SideButton(y, y_ref_sign, l) children();
 819 }
 820
 821 module Buttons(){
 822   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 823   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 824   Flip_rhs(   ) LidButtonishLeg(14, -1) children();
 825   Flip_rhs(0)   LidButtonishLeg(14, +1) children();
 826   // xxx need hole for whatever that hole is on lhs
 827 }
 828
 829 module Struts(x_start, z_min, th){
 830   // if th is negative, starts at z_min and works towards -ve z
 831   // and object should then be printed other way up
 832   for (i= [1 : 1 : case_struts_count]) {
 833     translate([0,
 834                0,
 835                z_min])
 836       mirror([0,0, th<0 ? 1 : 0])
 837       translate([0,
 838                  -phone_height * i / (case_struts_count+1),
 839                  case_struts_solid_below])
 840       linear_extrude(height= abs(th)
 841                      -(case_struts_solid_below+case_struts_solid_above))
 842       rectfromto([               x_start, -0.5 * case_struts_width ],
 843                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 844   }
 845 }
 846
 847 module OrdinaryRearAperture(rhs,bot, pos){
 848   Flip_rhs(rhs) Flip_bot(bot)
 849     linextr(-20, 20)
 850     mirror([0,1])
 851     translate(pos + bumper)
 852     children();
 853 }
 854
 855 module MicroUSB(){
 856   Flip_bot(1){
 857     rotate([90,0,0])
 858       mirror([0,0,1])
 859       linextr(-epp2i[0], 60)
 860       translate([0.5 * phone_width, 0, 0])
 861       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 862                  [+microusb_width/2, epp0[1] + -microusb_above]);
 863   }
 864 }
 865
 866 module OrdinaryRearApertures(){
 867   // rear speaker
 868   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 869     rectfromto(-rearspeaker_gap,
 870                rearspeaker_size + rearspeaker_gap);
 871
 872   // finger hole to remove phone
 873   if (len(fingerpushhole_dias))
 874     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 875                                 phone[1]/2 ])
 876     scale(fingerpushhole_dias)
 877     circle(r= 0.5 );
 878 }
 879
 880 module RearCameraAperture(){
 881   Flip_rhs(1)
 882     mirror([0, 0, 1])
 883     linear_extrude(height = 20)
 884     mirror([0, 1, 0])
 885     translate(bumper)
 886     rectfromto(camera_pos_tl, camera_pos_br);
 887 }
 888
 889 module HingeLidProfile(){
 890   hull(){
 891     circleat(hppT, hp_r1);
 892     circleat(lpp12, lp_r12);
 893     polygon([lpp10,
 894              lpp13 + [2,0],
 895              lpp12,
 896              hppT]);
 897   }
 898 }
 899
 900 module HingeBaseProfile(){
 901   difference(){
 902     hull(){
 903       circleat(hppB, hp_r1);
 904       circleat(hppE, hp_r1);
 905       circleat(epp2o, case_th_bottom);
 906       circleat(hppB + [10,0], hp_r1);
 907     }
 908     polygon([epp5, epp1, epp3, bppL]);
 909   }
 910 }
 911
 912 module HingeLeverOuterProfile(){
 913   hull(){
 914     circleat(hppT, hp_r2);
 915     circleat(hppB, hp_r2);
 916   }
 917 }
 918
 919 module HingeLeverInnerProfile(){
 920   for (s = [-1,+1]) {
 921     c = s > 0 ? hppT : hppB;
 922     translate(c)
 923       mirror([0,0,s>0])
 924       rotate(s<0 ? -40 : 0)
 925       hull()
 926       for (x=[-20,20])
 927         for (y=[0, s * 10])
 928           translate([x,y])
 929             circle(hp_rn);
 930   }
 931 }
 932
 933 module HingeLeverNutProfile(){
 934   for (c= [hppB, hppT]) {
 935     translate(c)
 936       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 937   }
 938 }
 939
 940 module Flip_hinge(doflip=1){
 941   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 942   translate(hinge_origin)
 943     rotate([doflip*180,0,0])
 944     translate(-hinge_origin)
 945     children();
 946 }
 947
 948 module HingePortion(x0,x1){
 949   Flip_rhs() Flip_bot(1)
 950     translate([x0,0,0])
 951     mirror([1,0,0])
 952     rotate([90,0,-90])
 953     linear_extrude(height=x1-x0)
 954     children();
 955 }
 956
 957 module ThumbRecessApply(ztop){
 958   width = thumbrecess_width;
 959   w = width + thumbrecess_topcurve_r*2 + 1;
 960   translate([phone_width/2, 0,0]){
 961     difference(){
 962       rotate([90,0,-90])
 963         linextr(-w/2, w/2)
 964         children(0);
 965       translate([0, 50, 0])
 966         rotate([90,0,0])
 967         linear_extrude(height=100){
 968         for (m=[0,1]) mirror([m,0,0]) {
 969           hull(){
 970             translate([w/2, ztop - thumbrecess_topcurve_r])
 971               circle(thumbrecess_topcurve_r);
 972             translate([w/2, -50])
 973               square(thumbrecess_topcurve_r*2, center=true);
 974           }
 975         }
 976       }
 977     }
 978   }
 979 }
 980
 981 module CaseBase(){
 982   AroundEdges(epp3[1], case_th_bottom, 1)
 983     EdgeProfile();
 984 }
 985
 986 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 987
 988 module PropProfileAssignments(gamma){
 989   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 990   x = prop_x(gamma);
 991   p = phone_height + prlp10[0] - hppB[0];
 992   b = p + x;
 993
 994   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
 995   a = q + x;
 996   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
 997   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
 998
 999   $prp_theta = 90 - $prp_alpha;
1000   beta = 180 - $prp_alpha - gamma;
1001   psi = 90 - beta;
1002
1003   //echo("abc", a,b,c);
1004
1005   v1 = [ [ cos(psi), -sin(psi) ],    // x
1006          [ sin(psi),  cos(psi) ] ];  // y
1007
1008   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1009
1010   $prp_r1 = prc_r1;
1011   $prp_r11 = prop_main_th/2;
1012
1013   $prpp1 = $prpp7 + [1,0] *
1014     // this is approximate, but will do
1015     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1016   $prpp3 = $prpp1 +
1017     v1[0] * -$prp_r1 +
1018     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1019   $prpp12 = $prpp3 + v1[0] *
1020     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1021   $prp_r8 = prop_main_th;
1022   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1023   $prp_r5 = $prp_r8;
1024   $prpp5 = [ $prpp12[0] - $prp_r5,
1025             $prpp3[1] - prop_prong_h + $prp_r5 ];
1026   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1027          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1028   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1029   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1030
1031   children();
1032 }
1033
1034 module PropProfile(gamma, cut=0, rot=0){
1035   PropProfileAssignments(gamma){
1036
1037     //#circleat($prpp3,1);
1038     //#circleat($prpp12,1);
1039
1040     if (!cut) {
1041       hull(){
1042         translate($prpp8)
1043           intersection(){
1044             circle($prp_r8);
1045             polygon([[-20,-0], [20,20], [0,0]]);
1046           }
1047         rectfromto($prpp6, $prpp9);
1048         translate($prpp5) intersection(){
1049           circle($prp_r5);
1050           polygon([[-10,-10], [0,0], [10,0]]);
1051         }
1052         rectfromto($prpp12 + [0,-0.1], $prpp3);
1053       }
1054       hull(){
1055         circleat($prpp1, $prp_r1);
1056         rectfromto($prpp12 + [0,-0.1], $prpp3);
1057       }
1058     }
1059     // main shaft
1060     rotate([0,0, rot*-$prp_theta]){
1061       hull(){
1062         extra = cut ? prop_recess_slop : 0;
1063         rectfromto($prpp6, $prpp9);
1064         circleat($prpp11, $prp_r11 + extra);
1065         circleat($prpp10, $prp_r10 + extra);
1066       }
1067     }
1068   }
1069 }
1070
1071 module PropAggregateProfile(){
1072   for (angle = prop_angles)
1073     PropProfile(angle, 0,0);
1074 }
1075
1076 module Prop(){ ////toplevel
1077   hw = prop_main_width/2;
1078   linextr(-hw, +hw)
1079     PropAggregateProfile();
1080 }
1081
1082 module Case(){ ////toplevel
1083   difference(){
1084     union(){
1085       CaseBase();
1086
1087       // ledge (fixed keeper)
1088       Flip_rhs(1-keeper_side) intersection(){
1089         rotate([90, 0, 0])
1090           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1091           KeeperProfile(1);
1092
1093         // outline of the whole case, to stop it protruding
1094         translate([0,0, -25])
1095           linear_extrude(height = 50)
1096           hull()
1097           Flip_bot()
1098           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1099       }
1100
1101       // hinge
1102       HingePortion(hex20, hex21) HingeBaseProfile();
1103
1104       // buildout for prop recess
1105       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1106         linextr(case_bottom_z, epp2i[1])
1107         hull() {
1108           for (dxs = [-1,+1])
1109             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1110                        -epp2o[0] ],
1111                      r = epp2o[0] - prcp2[0]);
1112         }
1113     }
1114
1115     // slot for keeper
1116     Flip_rhs(keeper_side)
1117       translate([0, -phone_cnr_rad, 0])
1118       rotate([90, 0, 0])
1119       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1120       minkowski(){
1121         KeeperProfile();
1122         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1123                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1124       }
1125
1126     // front camera
1127     RearCameraAperture();
1128
1129     // struts (invisible, because they're buried in the case)
1130     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1131
1132     Buttons(){
1133       mirror([1,0,0])
1134         rotate([90,0,90]) {
1135           if (!($button_leg_only && enable_support))
1136           intersection(){
1137             translate([0,0,-10])
1138               linear_extrude(height= 20)
1139               ButtonPlan($button_l, 0,1);
1140             if ($button_leg_only)
1141               rotate([-90,90,0])
1142                 translate([phone_width/2, -400, kppe[1]])
1143                 mirror([1-abs($rhsflip - keeper_side),0,0])
1144                 cube([400, 800, 50]);
1145             if (enable_support && !$button_suppress_over_keeper)
1146               rotate([-90,90,0])
1147               translate([-400, -400, kppd[1]])
1148                 mirror([0,0,1])
1149                 cube([800,800,100]);
1150           }
1151           translate([0,0, -bppR[0]])
1152             linear_extrude(height= 20)
1153             ButtonPlan($button_l, 1,1);
1154         }
1155
1156     }
1157
1158     // apertures along top edge
1159     if (!$suppress_forward_holes) {
1160       // CaseAperture(jack_pos, jack_dia, 8);
1161       Flip_rhs(1)
1162         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1163     }
1164
1165     OrdinaryRearApertures();
1166
1167     MicroUSB();
1168
1169     // gaps for the lid's hinge arms
1170     HingePortion(hex20 - hinge_x_arms_gap,
1171                  hex21 + hinge_x_arms_gap)
1172       minkowski(){
1173         HingeLidProfile();
1174         circle(r= hinge_r_arms_gap, $fn= 8);
1175       }
1176
1177     // screw holes in the hinge arms
1178     HingeScrews();
1179
1180     // thumb recess
1181     ThumbRecessApply(epp4[1])
1182       ThumbRecessCutProfile();
1183
1184     // lanyard
1185     Flip_bot(1)
1186       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1187       rotate([0, ly_theta, 0])
1188       rotate([0,0,90])
1189       LanyardCutout(lanyard_channel_len);
1190
1191     // prop recess
1192     Flip_rhs(1)
1193       translate([prop_x_pos,0,0])
1194       mirror([0,1,0])
1195       rotate([90,0,90])
1196       linextr(-prop_recess_hw, +prop_recess_hw)
1197       hull(){
1198         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1199           circleat(prcp1 + 20*d,
1200                    prc_r3);
1201       }
1202   }
1203 }
1204
1205 module LidAdhocMultiprintFrame(phase){
1206   if (led_window_style >= 3) {
1207     AdhocMultiprintFrame(phase, lpp13[1], -1);
1208   }
1209 }
1210
1211 module LidAroundEdges(){
1212   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1213     children();
1214 }
1215
1216 module Lid(){ ////toplevel
1217   skew_centre = [0, lpp11[0], lpp11[1]];
1218   difference(){
1219     union(){
1220       intersection(){
1221         LidAroundEdges()
1222           LidEdgeProfile();
1223
1224         translate(skew_centre)
1225           multmatrix([[ 1, 0, 0, 0 ],
1226                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1227                       [ 0, 0, 1, 0 ],
1228                       [ 0, 0, 0, 1 ]])
1229           translate(-skew_centre)
1230           LidAroundEdges()
1231           LidEdgeFoldClearanceProfile();
1232       }
1233
1234       // button covers
1235       Buttons(){
1236         intersection(){
1237           rotate([90,0,90])
1238             translate([0,0,-10])
1239             linear_extrude(height= 20)
1240             ButtonPlan($button_l, 1,0);
1241           union(){
1242             rotate([90,0,0])
1243               translate([0,0,-100])
1244               linear_extrude(height= 200)
1245               ButtonCoverProfile();
1246             hull()
1247               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1248                                  - lid_buttoncover_reinf))
1249                 translate([0,y,0])
1250                   ButtonCoverReinf();
1251           }
1252         }
1253       }
1254
1255       // hinge arms
1256       HingePortion(hex20, hex21) {
1257         LidEdgeProfile();
1258         HingeLidProfile();
1259       }
1260     }
1261     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1262
1263     // screw holes in the hinge arms
1264     HingeScrews();
1265
1266     // prop recess
1267     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1268       mirror([0,1,0])
1269       rotate([90,0,90])
1270       linextr(-prop_recess_hw, +prop_recess_hw)
1271       hull()
1272       for (pa = prop_angles)
1273         PropProfile(pa, 1,1);
1274
1275     // notification led aperture
1276     if (led_window_style)
1277       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1278         translate([0,0,-10])
1279           cylinder(r=nla_r0, h=20);
1280         if (led_window_style >= 2)
1281           translate([0,0, -nla_t])
1282             cylinder(r=nla_r2, height=20);
1283       }
1284
1285     }
1286
1287   LidAdhocMultiprintFrame(1);
1288 }
1289
1290 module HingeLever(){ ////toplevel
1291   difference() {
1292     // outer body, positive
1293     HingePortion(hex22, hex22 + phone_width/2)
1294       HingeLeverOuterProfile();
1295
1296     // space for the screws
1297     HingePortion(hex26, hex24)
1298       HingeLeverInnerProfile();
1299
1300     // recesses for the nuts
1301     HingePortion(hex23, hex26+1)
1302       HingeLeverNutProfile();
1303
1304     // bores for the screws
1305     HingeScrews();
1306
1307     // space for the charging cable
1308     MicroUSB();
1309     Flip_hinge() MicroUSB();
1310   }
1311 }
1312
1313 module LidWindow(){ ////toplevel
1314   translate([led_pos[0], -led_pos[1], lpp13[1]])
1315     mirror([0,0,1])
1316     cylinder(r= nla_r1, h=nla_t);
1317   LidAdhocMultiprintFrame(0);
1318 }
1319
1320 module LidWindowPrint(){ ////toplevel
1321   rotate([0,180,0])
1322     LidWindow();
1323 }
1324
1325 module DemoLidWindowSelect(){
1326   translate([led_pos[0], led_pos[1], -100]) {
1327     translate([0, -30, 0]) cube([400, 400, 200]);
1328   }
1329 }
1330
1331 module DemoLidWindow(){ ////toplevel
1332   %Lid();
1333   LidWindow();
1334   translate([0,40,0]){
1335     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1336     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1337   }
1338 }
1339
1340 module HingeLeverPrint(){ ////toplevel
1341   rotate([-90,0,0])
1342     translate([-phone_width/2, phone_height, 0])
1343     HingeLever();
1344 }
1345
1346 module TestSelectLength(){
1347   translate([-30, -200, -20])
1348     cube([30 + 15, 250, 40]);
1349 }
1350
1351 module TestLength(){ ////toplevel
1352   intersection(){
1353     Case();
1354     TestSelectLength();
1355   }
1356 }
1357
1358 module TestLengthRight(){ ////toplevel
1359   intersection(){
1360     Case();
1361     Flip_rhs(1)
1362       TestSelectLength();
1363   }
1364 }
1365
1366 module TestSelectWidth(){
1367   translate([-30, -(phone_height - 25), -20])
1368     mirror([0, 1, 0])
1369     cube([200, 50, 40]);
1370 }
1371
1372 module TestWidth(){ ////toplevel
1373   intersection(){
1374     Case();
1375     TestSelectWidth();
1376   }
1377 }
1378
1379 module TestLidWidthPrint(){ ////toplevel
1380   rotate([0,180.0]) intersection(){
1381     Lid();
1382     TestSelectWidth();
1383   }
1384 }
1385
1386 module TestSelectRearAperture(){
1387   minkowski(){
1388     union() children();
1389     translate([20, 0,0])
1390       cube([42, 2, 1], center=true);
1391   }
1392 }
1393
1394 module TestSelectCamera(){
1395   minkowski(){
1396     TestSelectRearAperture()
1397       RearCameraAperture();
1398     cube([0.1, 50, 0.1]);
1399   }
1400 }
1401
1402 module TestSelectOrdinaryRearApertures(){
1403   TestSelectRearAperture()
1404     OrdinaryRearApertures();
1405 }
1406
1407 module TestCamera(){ ////toplevel
1408   intersection(){
1409     Case();
1410     TestSelectCamera();
1411   }
1412 }
1413
1414 module TestLidByCamera(){ ////toplevel
1415   intersection(){
1416     Lid();
1417     TestSelectCamera();
1418   }
1419 }
1420
1421 module TestLidByCameraPrint(){ ////toplevel
1422   rotate([180,0,0]) TestLidByCamera();
1423 }
1424
1425 module DemoByCamera(){ ////toplevel
1426   color("blue") TestLidByCamera();
1427   color("red")  TestCamera();
1428 }
1429
1430 module OneKeeper(){ ////toplevel
1431   translate([0, -phone_cnr_rad, 0])
1432     rotate([90, 0, 0])
1433     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1434     KeeperProfile();
1435 }
1436
1437 module OneKeeperPrint(){ ////toplevel
1438   rotate([0,180,0])
1439     OneKeeper();
1440 }
1441
1442 module LidPrint(){ ////toplevel
1443   rotate([0,180,0])
1444     Lid();
1445 }
1446
1447 module TestSelectFrame(){
1448   include = [1,-1] * (epp2i[0] + 4);
1449
1450   difference(){
1451     cube(1000, center=true);
1452     translate([0,0, -100])
1453       linear_extrude(height=200)
1454       rectfromto(include,  inside_br - include);
1455   }
1456 }
1457
1458 module TestSelectLidFrame(){
1459   TestSelectFrame();
1460   translate([led_pos[0], -led_pos[1], -50])
1461     cylinder(r= nla_r2+3, h=100);
1462 }
1463
1464 module TestFrameCase(){ ////toplevel
1465   intersection(){
1466     Case();
1467     union(){
1468       TestSelectFrame();
1469       TestSelectCamera();
1470       TestSelectOrdinaryRearApertures();
1471     }
1472   }
1473 }
1474
1475 module TestSelectTopApertures(){
1476   translate([-100, -35, -100])
1477     cube([400, 100, 200]);
1478   LidAdhocMultiprintFrame(0);
1479   LidAdhocMultiprintFrame(1);
1480 }
1481
1482 module TestTopApertures(){ ////toplevel
1483   intersection(){
1484     Case();
1485     TestSelectFrame();
1486     TestSelectTopApertures();
1487   }
1488 }
1489
1490 module TestLidTopAperturesPrint(){ ////toplevel
1491   rotate([0,180,0]) intersection(){
1492     Lid();
1493     TestSelectLidFrame();
1494     TestSelectTopApertures();
1495   }
1496 }
1497
1498 module TestLidWindowTopAperturesPrint(){ ////toplevel
1499   rotate([0,180,0]) intersection(){
1500     LidWindow();
1501     TestSelectTopApertures();
1502   }
1503 }
1504
1505 module TestFrameLidPrint(){ ////toplevel
1506   rotate([0,180,0]) intersection(){
1507     Lid();
1508     TestSelectLidFrame();
1509   }
1510 }
1511
1512 module ButtonPlanForDemo(z, deep, cut){
1513   translate([0,0,z])
1514     ButtonPlan(8, deep, cut);
1515 }
1516
1517 module HingeScrews(){
1518   Flip_rhs() Flip_bot(1){
1519     for (c= [ hppT, hppB ])
1520       translate([ hex20,
1521                   -c[0],
1522                   c[1] ]){
1523         rotate([0,90,0])
1524           translate([0,0,-.2])
1525           cylinder( r= hingescrew_shaft_dia/2,
1526                     h = hingescrew_shaft_len+0.2 );
1527         rotate([0,-90,0])
1528           translate([0,0,+.1])
1529           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1530       }
1531   }
1532 }
1533
1534 module DemoPropAngleSelect(c){
1535   color(c) difference(){
1536     union(){ children(); }
1537     translate([ prop_x_pos, -400, -200 ])
1538       cube([ 400,800,400 ]);
1539   }
1540 }
1541
1542 module DemoPropAngle(ang){
1543   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1544   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1545
1546   translate(hL)
1547     rotate([ang/2,0,0])
1548     translate(-hL)
1549     translate(hC)
1550     rotate([ang/2,0,0])
1551     translate(-hC) {
1552       DemoPropAngleSelect("red") Case();
1553
1554       color("orange")
1555         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1556         PropProfileAssignments(ang) {
1557           echo($prpp1);
1558           rotate([-$prp_theta, 0, 0])
1559           translate([0, $prpp1[0], -$prpp1[1]])
1560           rotate([90,0,-90])
1561           Prop();
1562         }
1563     }
1564
1565   translate([0,0, -hp_k*2])
1566     DemoPropAngleSelect("blue")
1567     Lid();
1568 }
1569
1570 module DemoPropAngles(){ ////toplevel
1571   for (i=[0 : len(prop_angles)-1])
1572     translate(i * [0, -100, 100])
1573     DemoPropAngle(prop_angles[i]);
1574 }
1575
1576 module DemoHingeAngle(ang1,ang2){
1577   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1578   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1579
1580   translate(hL)
1581     rotate([ang2,0,0])
1582     translate(-hL)
1583     translate(hC)
1584     rotate([ang1,0,0])
1585     translate(-hC) {
1586       color("red") Lid();
1587     }
1588
1589   color("blue") intersection(){
1590     Case();
1591     union(){
1592       translate([bppJ[0], -400, -200])
1593         mirror([1,0,0])
1594         cube([400, 800, 400]);
1595       translate([10, -400, -200])
1596         cube([10, 800, 400]);
1597     }
1598   }
1599 }
1600
1601 module DemoHingeAngles(){ ////toplevel
1602   angles = [ 0, 4, 8, 12 ];
1603   echo("angles",angles);
1604   for (i=[0 : len(angles)-1]) {
1605     translate(i * [0, 0, 30]) {
1606       DemoHingeAngle(0,angles[i]);
1607       translate([0, 200, 0])
1608         DemoHingeAngle(angles[i],0);
1609     }
1610   }
1611 }
1612
1613 module DemoSelectAdhocLeftRight(right=0) {
1614   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1615     mirror([1-right, 0,0])
1616     cube([400, 800, 200]);
1617 }
1618
1619 module DemoLeft(){ ////toplevel
1620   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1621   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1622 }
1623
1624 module DemoFrame(){ ////toplevel
1625   color("red") render() TestFrameCase();
1626   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1627   color("black") render() HingeScrews();
1628   %render() HingeLever();
1629 }
1630
1631 module DemoLanyardCutout(){ ////toplevel
1632   LanyardCutout(25);
1633 }
1634
1635 module DemoHingedFrame(){ ///toplevel
1636   color("red") TestFrameCase();
1637   translate([0,0, -2*hp_k])
1638   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1639
1640   Flip_hinge(){
1641     color("orange") HingeLever();
1642     color("black") HingeScrews();
1643   }
1644 }
1645
1646 module DemoHinge(){ ////toplevel
1647   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1648     DemoFrame();
1649     translate([0,0, -hp_k*3])
1650       DemoHingedFrame();
1651   }
1652 }
1653
1654 module DemoProfiles(){ ////toplevel
1655   LidEdgeProfile();
1656   %EdgeProfile();
1657   KeeperProfile();
1658   translate([0,0,-1]) color("black") KeeperProfile(1);
1659   translate(ly_o){
1660     rotate(-ly_theta){
1661       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1662       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1663       translate([0, ly_q_z]){
1664         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1665         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1666       }
1667     }
1668   }
1669   translate([0,0,-5]) color("white") translate(epp2i)
1670     rotate(-ly_theta)
1671     rectfromto([-15, 0],
1672                [+15, -max_case_bottom_edge_thickness]);
1673
1674   translate([0,20]) {
1675     LanyardMainChannelProfile();
1676     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1677     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1678   }
1679
1680   translate([20,0]) {
1681     LidEdgeProfile();
1682     %EdgeProfile();
1683
1684     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1685
1686     color("blue") ButtonCoverProfile();
1687     color("red") {
1688       rectfromto(bppQ, demopoint_QR);
1689       rectfromto(bppR, demopoint_QR);
1690     }
1691   }
1692
1693   translate([-20,0]) {
1694     color("black") ButtonPlanForDemo(-2, 0,1);
1695     color("red" )  ButtonPlanForDemo(-4, 1,1);
1696     color("blue")  ButtonPlanForDemo(-6, 1,0);
1697   }
1698
1699   translate([0, -30]) {
1700     %LidEdgeProfile();
1701     %EdgeProfile();
1702     color("blue") HingeLidProfile();
1703     color("red")  HingeBaseProfile();
1704     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1705   }
1706
1707   for (f=[0,1]) {
1708     translate([-30, -60 + 30*f]) {
1709       translate([0,0,-4]) EdgeProfile();
1710       %translate([0,0,-10]) HingeBaseProfile();
1711       translate([0,-2] * f * hp_k) {
1712         translate([0,0,-4]) LidEdgeProfile();
1713         %translate([0,0,-10]) %HingeLidProfile();
1714       }
1715       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1716         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1717         translate([0,0,0]) color("red") difference(){
1718           HingeLeverOuterProfile();
1719           HingeLeverInnerProfile();
1720         }
1721         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1722       }
1723     }
1724   }
1725
1726   translate([20,-30]) {
1727     %EdgeProfile();
1728     %LidEdgeProfile();
1729     //translate([0,0,1]) ThumbRecessCutProfile();
1730     translate([0,0,+1]) color("red")
1731       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1732   }
1733
1734   translate([40,-30]) {
1735     difference(){
1736       LidEdgeProfile();
1737       translate(prlp10)
1738         PropProfile(10, 1, 0);
1739     }
1740     translate(prlp10)
1741       PropProfile(15, 0);
1742   }
1743   translate([60,-30]) {
1744     PropAggregateProfile();
1745   }
1746 }
1747
1748 //EdgeProfile();
1749 //KeeperProfile();
1750 //CaseBase();
1751 //%Case();
1752 //Keeper();
1753 //LidEdgeProfile();
1754 //KeeperProfile();
1755 //DemoProfiles();
1756 //PropRecess();