fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 166 noisecancelmic_dia = 4.00;
 167
 168 lhshole_pos = [ phone[1]/2, 4.35 ];
 169
 170 // fingerpushhole_dias = []; xxx what was this
 171 fingerpushhole_dias = [ 15, 18 ];
 172
 173 lanyard_half_dia = 1.15;
 174 lanyard_entry_rel_breadth = 2;
 175 lanyard_channel_len = 8;
 176 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 177 rearspeaker_size   = [  3.76,  7.36 ];
 178
 179 bottomspeaker_size = [ 11.35, 1.40 ] + [1,1] * 1.0;
 180 bottomspeaker_pos = [ 19.45, 4.82 ];
 181
 182 microusb_above = 1.64 - 0.25;
 183 microusb_below = 2.42;
 184 microusb_width = 12.16 + 2.0 + 1.25;
 185
 186 case_th_bottom = 2.5;
 187 case_th_lid = 3.0;
 188 case_th_side = 2.3;
 189 case_th_lip = 1.2;
 190
 191 lid_screen_gap_extra = .66;
 192
 193 case_struts_count = 6;
 194 case_struts_solid_below = 1.00;
 195 case_struts_solid_above = 0.75;
 196 case_struts_width = 0.10;
 197
 198 keeper_th_z = 0.75;
 199 keeper_th_x = 0.75;
 200 keeper_inner_width = 2.75;
 201 keeper_inner_height = 2.75;
 202 keeper_slant_slope = 2; // larger means steeper
 203
 204 keeper_gap_z_top = 0.25;
 205 keeper_gap_z_bot = 0.75;
 206 keeper_gap_x     = 0.25;
 207 keeper_gap_x_holes = 0.75;
 208
 209 keeper_side = 0; // 0 = lhs; 1 = rhs
 210
 211 case_lip = 1.25;
 212
 213 lid_gap_x = 0.25;
 214 lid_gap_z = 0.25;
 215 lid_lip = 1.75;
 216 lid_edgepart_width = 5.0;
 217 lid_buttoncover_thick = 1.3;
 218 lid_buttoncover_reinf = 0.65;
 219
 220 foldover_gap = 0.50;
 221 foldover_lever_gap = 0.50;
 222
 223 // xxx replace hinge screw with nail plan
 224
 225 // properties of the hinge fasteners
 226 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 227 hingescrew_shaft_len = 12;
 228 hingescrew_fasteners_extra_thick = 0.40;
 229 // ^ amount of thread protruding if everything was completely nominal
 230 //   and we are using two nuts
 231 hingescrew_nut_access_dia = 4.72 + 0.50;
 232 // ^ washer is 4.72 dia
 233 //   also, want to get pliers or tiny spanner in to do up locknut
 234 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 235 hingescrew_nut_thick = 1.93;
 236 hingescrew_head_th = 1.38 + 0.75;
 237 hingescrew_head_dia = 3.92;
 238
 239 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 240
 241 lever_cover_th = 0.75;
 242 hingemount_th = 2.5;
 243 hingemount_wd = 4.8725;
 244
 245 $fa = 5;
 246 $fs = 0.1;
 247
 248 button_l_fudge = 4.4;
 249 buttonishleg_default_l_is_fudge = 10;
 250
 251 hinge_base_slope = 1.5; // bigger is steeper
 252
 253 strut_min_at_end = 1.5;
 254
 255 hinge_x_gap = 0.125;
 256 hinge_x_postscrew_gap = 0.75;
 257 hinge_x_arms_gap = 0.35;
 258 hinge_r_arms_gap = 0.55;
 259
 260 // xxx there isn't one of these, speaker is by hinge
 261 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 262
 263 thumbrecess_depth = 1.3;
 264 thumbrecess_width = 16.5;
 265 thumbrecess_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 $button_leg_only = false;
 283 $suppress_forward_holes = false;
 284
 285 // ---------- calculated ----------
 286
 287 phone_total_thick = phone_edge_thick;
 288
 289 phone_width =  (phone + bumper*2)[0];
 290 phone_height = (phone + bumper*2)[1];
 291
 292 inside_br = [phone_width, -phone_height];
 293
 294 prop_prong_h = prop_main_th;
 295
 296 //echo(camera_pos_tl + bumper,
 297 //     camera_pos_br + bumper);
 298
 299 // ----- could be changed -----
 300 lid_buttoncover_gap = lid_gap_x;
 301 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 302
 303 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 304
 305 //prop_nose_len = case_th_lid - prop_recess_under;
 306 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 307 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 308
 309
 310 //lid_lip_overlap_width xxx bad name = ;
 311 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 312
 313 epp0 = [0,0];
 314 epp1 = [0, -phone_edge_thick];
 315 epp2i = epp1; // conflated for FP4
 316 epp2o = epp2i;
 317 epp3 = epp2i + [10, 0];
 318 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 319 epp4 = epp5 + [-1,0] * case_th_side;
 320
 321 kppe = [0,0];
 322 kppd = kppe + [1,0] * keeper_inner_width;
 323 kppc = kppd + [0,1] * keeper_th_z;
 324 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 325 kppf = kppe - [0,1] * keeper_inner_height;
 326 kppa = [ kppb[0], kppf[1] ];
 327
 328 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 329 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 330
 331 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 332 // exact x posn not very important; must extend past end of keeper
 333
 334 lpp15 = [ lpp14[0],
 335           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 336           + lid_screen_gap_extra ];
 337 // ^ beam theory says to maximise force before contact,
 338 //   the gap below the `beam' (the lid) must be 1/3
 339 //   the thickness (ie the lid thickness) if the beam
 340 //   is solid, or 1/2 if it has a top and bottom only.
 341 //   ours is mostly solid.
 342
 343 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 344              case_th_lip);
 345
 346 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 347 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 348
 349 case_bottom_z = epp2o[1] - case_th_bottom;
 350
 351 // button profile
 352 bppM = epp4 + [0,5];
 353 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 354 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 355 bppS = [ epp1[0], bppR[1] ];
 356 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 357 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 358 bppO = [ bppN[0], bppP[1] ];
 359 bppL = lpp10 + [5,0];
 360 bppK = [ bppL[0], bppN[1] ];
 361 bppJ = [ bppN[0], bppL[1] ];
 362 bppU = [ bppJ[0], lpp12[1] ];
 363 bppV = lpp11;
 364 bppW = lpp10;
 365
 366 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 367
 368 // notification led aperture
 369
 370 nla_r0 = led_aperture/2;
 371 nla_r1 = nla_r0 + led_window_ledge;
 372 nla_r2 = nla_r1 + multicolour_gap;
 373 nla_t =
 374   led_window_style >= 3 ? initial_layer_thick :
 375   led_window_style >= 2 ? led_window_ledge : 0;
 376
 377
 378 // hinge plan
 379 hp_rn = hingescrew_nut_access_dia/2;
 380 hp_r2_min = hp_rn + lever_cover_th;
 381 hp_rs = hingescrew_shaft_dia/2;
 382 hp_r1_min = hp_rs + hingemount_th;
 383
 384 hp_r1 = max(hp_r1_min, hp_r2_min);
 385 hp_r2 = hp_r1;
 386
 387 hppU = lpp13;
 388 hppS = epp2o + [0,-1] * case_th_bottom;
 389 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 390
 391 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 392          0.5 * (hppU + hppS)[1] ];
 393 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 394 hppB = hppT + [0,-1] * hp_k;
 395
 396 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 397 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 398 hppE = [ hppE_x, hppE_y ];
 399
 400 // hinge elevation x coords
 401
 402 hex20 = max(epp2o[0],
 403             phone_cnr_rad,
 404             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 405 hex21 = hex20 + hingemount_wd;
 406 hex22 = hex21 + hinge_x_gap;
 407 hex27 = hex20 + hingescrew_shaft_len;
 408 hex24 = hex27 + hinge_x_postscrew_gap;
 409 hex23 = hex27 - (hingescrew_nut_thick*2
 410                  + hingescrew_fasteners_extra_thick);
 411 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 412
 413 echo(hex20, hex21, hex22, hex23, hex24);
 414 //  6, 10.8725, 10.9975, 13.74, 18.75
 415 module chk(act,exp) {
 416   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 417   else echo("ok", act);
 418 }
 419 chk(hex20, 6);
 420 chk(hex21, 10.8725);
 421 chk(hex22, 10.9975);
 422 chk(hex23, 13.74);
 423 chk(hex24, 18.75);
 424
 425 lid_fold_clearance_skew =
 426   (lpp10[1] - hppB[1]) /
 427   (lpp10[0] - hppB[0]);
 428
 429 echo("SK",lid_fold_clearance_skew);
 430
 431 // thumb recess (used to be "catch" hence cpp*
 432
 433 cppA = epp4 + [thumbrecess_depth, 0];
 434 cppB = [ cppA[0], epp1[1] ];
 435
 436 // lanyard
 437
 438 ly_r = lanyard_half_dia / 2;
 439 ly_rc = ly_r * 2;
 440
 441 ly_theta = 90;
 442 ly_o = epp2i + 3 * ly_r * [0,1];
 443
 444 max_case_bottom_edge_thickness =
 445   case_th_bottom;
 446
 447 ly_q_z = -(ly_rc + ly_r);
 448 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 449
 450 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 451
 452 // prop recess in case
 453
 454 prop_x_pos = phone_width/2;
 455
 456 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 457
 458 prc_r1 = prop_end_dia/2;
 459 prc_r3 = prc_r1 + prop_recess_slop;
 460
 461 prcp2 = [ epp4[0] + prop_buildout_less,
 462           case_bottom_z ];
 463
 464 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 465
 466 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 467           epp2i[1] - prc_r3 - prop_recess_under];
 468
 469 // prop recess in lid
 470
 471 prl_r10 = prop_end_dia/2;
 472 prl_r10o = prl_r10 + prop_recess_slop;
 473
 474 prlp10 = lpp10 + [1,1] * prl_r10o
 475   + [1,0] * prop_lidrecess_behind
 476   + [0,1] * prop_recess_under;
 477
 478 // prop
 479
 480 $prpp10 = [0,0];
 481 $prpp11 = [0, prop_taper_len];
 482
 483 $prp_r10 = prl_r10;
 484
 485 // ---------- modules ----------
 486
 487 module AdhocMultiprintFrame(phase, z0, zs) {
 488   // from z0 to z0 + zs*layer
 489   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 490   xextra = extra + -epp4[0];
 491   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 492   yextra = extra + -epp4[0];
 493   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 494   p0 = [ xrange[0], yrange[0] ];
 495   p1 = [ xrange[1], yrange[1] ];
 496   echo(p0, p1);
 497   translate([0,0, z0])
 498     mirror([0,0, zs<0 ? 1 : 0])
 499     linear_extrude(height= initial_layer_thick)
 500     difference(){
 501       rectfromto(p0 - [1,1] * initial_layer_width,
 502                  p1 + [1,1] * initial_layer_width);
 503       rectfromto(p0, p1);
 504     }
 505 }
 506
 507 module KeeperProfile(slant=0){
 508   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 509   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 510 }
 511
 512 module EdgeProfile(){
 513   difference(){
 514     hull(){
 515       translate(epp3) square(case_th_bottom*2, center=true);
 516       circleat(epp2o, r=case_th_bottom);
 517       circleat(epp1, r=case_th_side);
 518       rectfromto(epp0, epp4);
 519     }
 520     polygon([ epp5 + [0,10],
 521               epp1,
 522               epp3 + [10,0] ]);
 523   }
 524 }
 525
 526 module LanyardLanyardProfile(entry=false){
 527   hull(){
 528     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 529       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 530         circle(r= lanyard_half_dia/2);
 531   }
 532 }
 533
 534 module LanyardCurveChannelProfile(){
 535   translate([0, -ly_r])
 536     LanyardLanyardProfile();
 537 }
 538
 539 module LanyardEntryChannelProfile(){
 540   LanyardLanyardProfile(true);
 541 }
 542
 543 module LanyardMainChannelProfile(){
 544   LanyardCurveChannelProfile();
 545   difference(){
 546     square(center=true, ly_r * [6, 2]);
 547     for (xs=[-1,+1])
 548       translate(ly_r * [3 * xs, -1])
 549         circle(r = ly_r);
 550   }
 551 }
 552
 553 module LanyardEntryOuterProfile(){
 554   circleat([ly_re + ly_r, 0], ly_re);
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = ly_q_z;
 559   oec_y = ly_oec_y;
 560
 561   d_x = -ly_rc;
 562
 563   translate([d_x, 0, q_z]) {
 564     intersection(){
 565       rotate([90,0,0])
 566         rotate_extrude(convexity=10)
 567         rotate(90)
 568         translate([0, -q_z])
 569         LanyardCurveChannelProfile();
 570       translate([0,-10,0])
 571         cube([20,20,20]);
 572     }
 573   }
 574
 575   mirror([0,0,1])
 576     translate([0,0,-1])
 577     linear_extrude(height=20)
 578     rotate(-90)
 579     LanyardEntryChannelProfile();
 580
 581   translate([0, ly_r*2, 0])
 582     rotate([90,0,0])
 583     linear_extrude(height = ly_r*4){
 584     difference(){
 585       rectfromto([d_x, q_z], [ly_r, 0]);
 586       circleat([d_x, q_z], ly_rc);
 587     }
 588   }
 589
 590   translate([0,0,q_z]){
 591     for (my=[0,1])
 592       mirror([0,my,0]){
 593         translate([0, oec_y, 0]){
 594           difference(){
 595             translate(ly_re * [-1,0,-2])
 596               cube(ly_re * [2,1,2]);
 597             rotate_extrude(convexity=10)
 598               LanyardEntryOuterProfile();
 599           }
 600         }
 601       }
 602     difference(){
 603       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 604         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 605       for (mx=[0,1])
 606         mirror([mx,0,0])
 607           rotate([90,0,0])
 608           translate([0,0,-10])
 609           linear_extrude(height=20)
 610           LanyardEntryOuterProfile();
 611     }
 612   }
 613 }
 614
 615 module LanyardCutout(l){
 616   rotate([0,-90,0])
 617     linear_extrude(height=l)
 618     rotate(-90)
 619     LanyardMainChannelProfile();
 620
 621   for (ee=[0,1]){
 622     translate(ee * l * [-1,0])
 623       mirror([ee,0,0])
 624       LanyardEntry();
 625   }
 626 }
 627
 628 module LidEdgeProfile(){
 629   polygon([ lpp10,
 630             lpp11,
 631             lpp12,
 632             lpp13,
 633             lpp13 + [10, 0],
 634             lpp15 + [10, 0],
 635             lpp15,
 636             lpp14,
 637             ]);
 638   intersection(){
 639     circleat(lpp12, r=lp_r12);
 640     rectfromto( lpp12 + [-10,   0],
 641                 lpp12 + [+10, +10] );
 642   }
 643 }
 644
 645 module LidEdgeFoldClearanceProfile(){
 646   translate([-lid_fold_clearance_antislop, 0])
 647     polygon([ lpp10,
 648               lpp11,
 649               lpp11 + [-20,  0],
 650               lpp11 + [-20, 20],
 651               lpp11 + [+20, 20],
 652               lpp10 + [+20,  0] ]);
 653 }
 654
 655 module ButtonCoverProfile(){
 656   intersection(){
 657     polygon(concat([ bppM, bppP, bppO, bppJ ],
 658                    (enable_support && !$button_suppress_over_keeper
 659                     ? [ bppU, bppV, bppW ] : []),
 660                    [ bppL, bppK ]));
 661     hull(){
 662       EdgeProfile();
 663       LidEdgeProfile();
 664     }
 665   }
 666 }
 667
 668 module ButtonPlan(l, deep, cut){
 669   epsilon =
 670     (cut  ? 0 : lid_buttoncover_gap);
 671
 672   delta =
 673     (deep ? lid_buttoncover_overlap : 0);
 674
 675   C = [0,0]; // by definition
 676   T = [ 0, epp4[1] ];
 677   G = T + [0,10];
 678
 679   B0 = C + [0,-1] * button_cutout_depth;
 680   B1 = B0 + [0,1] * epsilon;
 681
 682   r0 = 0.5 * (T[1] - B0[1]);
 683   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 684   H = A + [0,-1] * delta;
 685
 686   D = A + [-2,0] * r0;
 687   F = D + [0,10];
 688
 689   E0 = 0.5 * (D + A);
 690   E1 = E0 + [1,0] * epsilon;
 691
 692   I0 = [ E0[0], H[1] ];
 693   I1 = [ E1[0], H[1] ];
 694
 695   hull(){
 696     for (m=[0,1]) mirror([m,0])
 697       circleat(H, r0 - epsilon);
 698   }
 699   for (m=[0,1]) mirror([m,0]) {
 700     difference(){
 701       polygon([ E1,
 702                 I1,
 703                 H,
 704                 B1,
 705                 G,
 706                 F,
 707                 D
 708                 ]);
 709       circleat(D, r0 + epsilon);
 710     }
 711   }
 712 }
 713
 714 module ButtonCoverReinf(){ ////toplevel
 715   minkowski(){
 716     rotate([90,0,0])
 717       linear_extrude(height=0.01)
 718       intersection(){
 719         ButtonCoverProfile();
 720         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 721           square([100,100]);
 722     }
 723     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 724       circle(r= lid_buttoncover_reinf);
 725       translate([-20,0]) square(40, center=true);
 726     }
 727   }
 728 }
 729
 730 module ThumbRecessCutProfile(){
 731   difference(){
 732     polygon([ cppA + [-10,0],
 733               cppB + [-10,0],
 734               cppB,
 735               cppA ]);
 736     circleat(epp1, r=case_th_side);
 737   }
 738 }
 739
 740 module Flip_rhs(yn=[0,1]) {
 741   for ($rhsflip=yn) {
 742     translate([phone_width/2, 0, 0])
 743       mirror([$rhsflip,0,0])
 744       translate([-phone_width/2, 0, 0])
 745       children();
 746   }
 747 }
 748
 749 module Flip_bot(yn=[0,1]) {
 750   for ($botflip=yn) {
 751     translate([0, -phone_height/2, 0])
 752       mirror([0, $botflip, 0])
 753       translate([0, phone_height/2, 0])
 754       children();
 755   }
 756 }
 757
 758 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 759   // sides
 760   Flip_rhs(){
 761     translate([0, -phone_cnr_rad, 0])
 762       rotate([90,0,0])
 763       linear_extrude(height = phone_height - phone_cnr_rad*2)
 764       children(0);
 765   }
 766   // corners
 767   Flip_rhs() Flip_bot() {
 768     translate([+1,-1] * phone_cnr_rad)
 769       intersection(){
 770         rotate_extrude()
 771           intersection(){
 772             mirror([1,0,0])
 773               translate([-1,0] * phone_cnr_rad)
 774               children(0);
 775             rectfromto([0,-20],[10,20]);
 776           }
 777         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 778           cube([10,10,40]);
 779       }
 780   }
 781   // top and bottom
 782   Flip_bot(){
 783     translate([ phone_width - phone_cnr_rad, 0,0 ])
 784       rotate([90,0,-90])
 785       linear_extrude(height = phone_width - phone_cnr_rad*2)
 786       children(0);
 787   }
 788   // fill
 789   translate([0,0, fill_zstart])
 790     mirror([0,0, fill_downwards])
 791     linear_extrude(height = fill_th)
 792     rectfromto([+1,-1] * phone_cnr_rad,
 793                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 794 }
 795
 796 module CaseAperture(pos, dia, $fn, topbottom=0) {
 797   theta = 180/$fn;
 798   translate([ bumper[0],
 799               -epp2i[0],
 800                0 ])
 801     rotate([0,0, 90*topbottom])
 802     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 803     rotate([-90, theta, 0])
 804     cylinder(r = dia/2 / cos(theta),
 805              h = 60);
 806 }
 807
 808 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 809   // y_ref_sign:
 810   //   +1  measured from top    of actual phone to top    of button
 811   //   -1  measured from bottom of actual phone to bottom of button
 812   //    0  y is centre of button in coordinate system
 813   $button_l= l;
 814   $button_suppress_over_keeper= suppress_over_keeper;
 815   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 816           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 817           y;
 818   //echo(eff_y);
 819   translate([0, eff_y, 0])
 820     children();
 821 }
 822
 823 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 824   $button_leg_only = true;
 825   SideButton(y, y_ref_sign, l) children();
 826 }
 827
 828 module Buttons(){
 829   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 830   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 831   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 832   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 833   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 834   // xxx need hole for whatever that hole is on lhs
 835 }
 836
 837 module Struts(x_start, z_min, th){
 838   // if th is negative, starts at z_min and works towards -ve z
 839   // and object should then be printed other way up
 840   for (i= [1 : 1 : case_struts_count]) {
 841     translate([0,
 842                0,
 843                z_min])
 844       mirror([0,0, th<0 ? 1 : 0])
 845       translate([0,
 846                  -phone_height * i / (case_struts_count+1),
 847                  case_struts_solid_below])
 848       linear_extrude(height= abs(th)
 849                      -(case_struts_solid_below+case_struts_solid_above))
 850       rectfromto([               x_start, -0.5 * case_struts_width ],
 851                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 852   }
 853 }
 854
 855 module OrdinaryRearAperture(rhs,bot, pos){
 856   Flip_rhs(rhs) Flip_bot(bot)
 857     linextr(-20, 20)
 858     mirror([0,1])
 859     translate(pos + bumper)
 860     children();
 861 }
 862
 863 module MicroUSBEtc(){
 864   Flip_bot(1){
 865     rotate([90,0,0])
 866       mirror([0,0,1])
 867       linextr(-epp2i[0], 60)
 868       translate([0.5 * phone_width, 0, 0])
 869       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 870                  [+microusb_width/2, epp0[1] + -microusb_above]);
 871   }
 872   Flip_bot(1) Flip_rhs(1) {
 873     linextr_y_xz(-epp2i[0], 60)
 874       hull()
 875       for (x= [-1,+1]) {
 876         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 877                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 878                     0 ])
 879           rotate(360/16)
 880           circle(r = bottomspeaker_size[1], $fn = 8);
 881       }
 882   }
 883 }
 884
 885 module OrdinaryRearApertures(){
 886   // rear speaker
 887   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 888     rectfromto(-rearspeaker_gap,
 889                rearspeaker_size + rearspeaker_gap);
 890
 891   // finger hole to remove phone
 892   if (len(fingerpushhole_dias))
 893     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 894                                 phone[1]/2 ])
 895     scale(fingerpushhole_dias)
 896     circle(r= 0.5 );
 897 }
 898
 899 module RearCameraAperture(){
 900   Flip_rhs(1)
 901     mirror([0, 0, 1])
 902     linear_extrude(height = 20)
 903     mirror([0, 1, 0])
 904     translate(bumper)
 905     rectfromto(camera_pos_tl, camera_pos_br);
 906 }
 907
 908 module HingeLidProfile(){
 909   hull(){
 910     circleat(hppT, hp_r1);
 911     circleat(lpp12, lp_r12);
 912     polygon([lpp10,
 913              lpp13 + [2,0],
 914              lpp12,
 915              hppT]);
 916   }
 917 }
 918
 919 module HingeBaseProfile(){
 920   difference(){
 921     hull(){
 922       circleat(hppB, hp_r1);
 923       circleat(hppE, hp_r1);
 924       circleat(epp2o, case_th_bottom);
 925       circleat(hppB + [10,0], hp_r1);
 926     }
 927     polygon([epp5, epp1, epp3, bppL]);
 928   }
 929 }
 930
 931 module HingeLeverOuterProfile(){
 932   hull(){
 933     circleat(hppT, hp_r2);
 934     circleat(hppB, hp_r2);
 935   }
 936 }
 937
 938 module HingeLeverInnerProfile(){
 939   for (s = [-1,+1]) {
 940     c = s > 0 ? hppT : hppB;
 941     translate(c)
 942       mirror([0,0, s>0 ? 1 : 0])
 943       rotate(s<0 ? -40 : 0)
 944       hull()
 945       for (x=[-20,20])
 946         for (y=[0, s * 10])
 947           translate([x,y])
 948             circle(hp_rn);
 949   }
 950 }
 951
 952 module HingeLeverNutProfile(){
 953   for (c= [hppB, hppT]) {
 954     translate(c)
 955       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 956   }
 957 }
 958
 959 module Flip_hinge(doflip=1){
 960   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 961   translate(hinge_origin)
 962     rotate([doflip*180,0,0])
 963     translate(-hinge_origin)
 964     children();
 965 }
 966
 967 module HingePortion(x0,x1){
 968   Flip_rhs() Flip_bot(1)
 969     translate([x0,0,0])
 970     mirror([1,0,0])
 971     rotate([90,0,-90])
 972     linear_extrude(height=x1-x0)
 973     children();
 974 }
 975
 976 module ThumbRecessApply(ztop){
 977   width = thumbrecess_width;
 978   w = width + thumbrecess_topcurve_r*2 + 1;
 979   translate([phone_width/2, 0,0]){
 980     difference(){
 981       rotate([90,0,-90])
 982         linextr(-w/2, w/2)
 983         children(0);
 984       translate([0, 50, 0])
 985         rotate([90,0,0])
 986         linear_extrude(height=100){
 987         for (m=[0,1]) mirror([m,0,0]) {
 988           hull(){
 989             translate([w/2, ztop - thumbrecess_topcurve_r])
 990               circle(thumbrecess_topcurve_r);
 991             translate([w/2, -50])
 992               square(thumbrecess_topcurve_r*2, center=true);
 993           }
 994         }
 995       }
 996     }
 997   }
 998 }
 999
1000 module CaseBase(){
1001   AroundEdges(epp3[1], case_th_bottom, 1)
1002     EdgeProfile();
1003 }
1004
1005 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1006
1007 module PropProfileAssignments(gamma){
1008   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1009   x = prop_x(gamma);
1010   p = phone_height + prlp10[0] - hppB[0];
1011   b = p + x;
1012
1013   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1014   a = q + x;
1015   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1016   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1017
1018   $prp_theta = 90 - $prp_alpha;
1019   beta = 180 - $prp_alpha - gamma;
1020   psi = 90 - beta;
1021
1022   //echo("abc", a,b,c);
1023
1024   v1 = [ [ cos(psi), -sin(psi) ],    // x
1025          [ sin(psi),  cos(psi) ] ];  // y
1026
1027   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1028
1029   $prp_r1 = prc_r1;
1030   $prp_r11 = prop_main_th/2;
1031
1032   $prpp1 = $prpp7 + [1,0] *
1033     // this is approximate, but will do
1034     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1035   $prpp3 = $prpp1 +
1036     v1[0] * -$prp_r1 +
1037     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1038   $prpp12 = $prpp3 + v1[0] *
1039     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1040   $prp_r8 = prop_main_th;
1041   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1042   $prp_r5 = $prp_r8;
1043   $prpp5 = [ $prpp12[0] - $prp_r5,
1044             $prpp3[1] - prop_prong_h + $prp_r5 ];
1045   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1046          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1047   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1048   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1049
1050   children();
1051 }
1052
1053 module PropProfile(gamma, cut=0, rot=0){
1054   PropProfileAssignments(gamma){
1055
1056     //#circleat($prpp3,1);
1057     //#circleat($prpp12,1);
1058
1059     if (!cut) {
1060       hull(){
1061         translate($prpp8)
1062           intersection(){
1063             circle($prp_r8);
1064             polygon([[-20,-0], [20,20], [0,0]]);
1065           }
1066         rectfromto($prpp6, $prpp9);
1067         translate($prpp5) intersection(){
1068           circle($prp_r5);
1069           polygon([[-10,-10], [0,0], [10,0]]);
1070         }
1071         rectfromto($prpp12 + [0,-0.1], $prpp3);
1072       }
1073       hull(){
1074         circleat($prpp1, $prp_r1);
1075         rectfromto($prpp12 + [0,-0.1], $prpp3);
1076       }
1077     }
1078     // main shaft
1079     rotate([0,0, rot*-$prp_theta]){
1080       hull(){
1081         extra = cut ? prop_recess_slop : 0;
1082         rectfromto($prpp6, $prpp9);
1083         circleat($prpp11, $prp_r11 + extra);
1084         circleat($prpp10, $prp_r10 + extra);
1085       }
1086     }
1087   }
1088 }
1089
1090 module PropAggregateProfile(){
1091   for (angle = prop_angles)
1092     PropProfile(angle, 0,0);
1093 }
1094
1095 module Prop(){ ////toplevel
1096   hw = prop_main_width/2;
1097   linextr(-hw, +hw)
1098     PropAggregateProfile();
1099 }
1100
1101 module Case(){ ////toplevel
1102   difference(){
1103     union(){
1104       CaseBase();
1105
1106       // ledge (fixed keeper)
1107       Flip_rhs(1-keeper_side) intersection(){
1108         rotate([90, 0, 0])
1109           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1110           KeeperProfile(1);
1111
1112         // outline of the whole case, to stop it protruding
1113         translate([0,0, -25])
1114           linear_extrude(height = 50)
1115           hull()
1116           Flip_bot()
1117           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1118       }
1119
1120       // hinge
1121       HingePortion(hex20, hex21) HingeBaseProfile();
1122
1123       // buildout for prop recess
1124       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1125         linextr(case_bottom_z, epp2i[1])
1126         hull() {
1127           for (dxs = [-1,+1])
1128             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1129                        -epp2o[0] ],
1130                      r = epp2o[0] - prcp2[0]);
1131         }
1132     }
1133
1134     // slot for keeper
1135     Flip_rhs(keeper_side)
1136       translate([0, -phone_cnr_rad, 0])
1137       rotate([90, 0, 0])
1138       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1139       minkowski(){
1140         KeeperProfile();
1141         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1142                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1143       }
1144
1145     // front camera
1146     RearCameraAperture();
1147
1148     // struts (invisible, because they're buried in the case)
1149     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1150
1151     Buttons(){
1152       mirror([1,0,0])
1153         rotate([90,0,90]) {
1154           if (!($button_leg_only && enable_support))
1155           intersection(){
1156             translate([0,0,-10])
1157               linear_extrude(height= 20)
1158               ButtonPlan($button_l, 0,1);
1159             if ($button_leg_only)
1160               rotate([-90,90,0])
1161                 translate([phone_width/2, -400, kppe[1]])
1162                 mirror([1-abs($rhsflip - keeper_side),0,0])
1163                 cube([400, 800, 50]);
1164             if (enable_support && !$button_suppress_over_keeper)
1165               rotate([-90,90,0])
1166               translate([-400, -400, kppd[1]])
1167                 mirror([0,0,1])
1168                 cube([800,800,100]);
1169           }
1170           translate([0,0, -bppR[0]])
1171             linear_extrude(height= 20)
1172             ButtonPlan($button_l, 1,1);
1173         }
1174
1175     }
1176
1177     // apertures along top edge
1178     if (!$suppress_forward_holes) {
1179       // CaseAperture(jack_pos, jack_dia, 8);
1180       Flip_rhs(1)
1181         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1182       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1183     }
1184
1185     OrdinaryRearApertures();
1186
1187     MicroUSBEtc();
1188
1189     // gaps for the lid's hinge arms
1190     HingePortion(hex20 - hinge_x_arms_gap,
1191                  hex21 + hinge_x_arms_gap)
1192       minkowski(){
1193         HingeLidProfile();
1194         circle(r= hinge_r_arms_gap, $fn= 8);
1195       }
1196
1197     // screw holes in the hinge arms
1198     HingeScrews();
1199
1200     // thumb recess
1201     ThumbRecessApply(epp4[1])
1202       ThumbRecessCutProfile();
1203
1204     // lanyard
1205     Flip_bot(1)
1206       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1207       rotate([0, ly_theta, 0])
1208       rotate([0,0,90])
1209       LanyardCutout(lanyard_channel_len);
1210
1211     // prop recess
1212     Flip_rhs(1)
1213       translate([prop_x_pos,0,0])
1214       mirror([0,1,0])
1215       rotate([90,0,90])
1216       linextr(-prop_recess_hw, +prop_recess_hw)
1217       hull(){
1218         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1219           circleat(prcp1 + 20*d,
1220                    prc_r3);
1221       }
1222   }
1223 }
1224
1225 module LidAdhocMultiprintFrame(phase){
1226   if (led_window_style >= 3) {
1227     AdhocMultiprintFrame(phase, lpp13[1], -1);
1228   }
1229 }
1230
1231 module LidAroundEdges(){
1232   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1233     children();
1234 }
1235
1236 module Lid(){ ////toplevel
1237   skew_centre = [0, lpp11[0], lpp11[1]];
1238   difference(){
1239     union(){
1240       intersection(){
1241         LidAroundEdges()
1242           LidEdgeProfile();
1243
1244         translate(skew_centre)
1245           multmatrix([[ 1, 0, 0, 0 ],
1246                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1247                       [ 0, 0, 1, 0 ],
1248                       [ 0, 0, 0, 1 ]])
1249           translate(-skew_centre)
1250           LidAroundEdges()
1251           LidEdgeFoldClearanceProfile();
1252       }
1253
1254       // button covers
1255       Buttons(){
1256         intersection(){
1257           rotate([90,0,90])
1258             translate([0,0,-10])
1259             linear_extrude(height= 20)
1260             ButtonPlan($button_l, 1,0);
1261           union(){
1262             rotate([90,0,0])
1263               translate([0,0,-100])
1264               linear_extrude(height= 200)
1265               ButtonCoverProfile();
1266             hull()
1267               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1268                                  - lid_buttoncover_reinf))
1269                 translate([0,y,0])
1270                   ButtonCoverReinf();
1271           }
1272         }
1273       }
1274
1275       // hinge arms
1276       HingePortion(hex20, hex21) {
1277         LidEdgeProfile();
1278         HingeLidProfile();
1279       }
1280     }
1281     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1282
1283     // screw holes in the hinge arms
1284     HingeScrews();
1285
1286     // prop recess
1287     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1288       mirror([0,1,0])
1289       rotate([90,0,90])
1290       linextr(-prop_recess_hw, +prop_recess_hw)
1291       hull()
1292       for (pa = prop_angles)
1293         PropProfile(pa, 1,1);
1294
1295     // notification led aperture
1296     if (led_window_style)
1297       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1298         translate([0,0,-10])
1299           cylinder(r=nla_r0, h=20);
1300         if (led_window_style >= 2)
1301           translate([0,0, -nla_t])
1302             cylinder(r=nla_r2, height=20);
1303       }
1304
1305     }
1306
1307   LidAdhocMultiprintFrame(1);
1308 }
1309
1310 module HingeLever(){ ////toplevel
1311   difference() {
1312     // outer body, positive
1313     HingePortion(hex22, hex22 + phone_width/2)
1314       HingeLeverOuterProfile();
1315
1316     // space for the screws
1317     HingePortion(hex26, hex24)
1318       HingeLeverInnerProfile();
1319
1320     // recesses for the nuts
1321     HingePortion(hex23, hex26+1)
1322       HingeLeverNutProfile();
1323
1324     // bores for the screws
1325     HingeScrews();
1326
1327     // space for the charging cable
1328     MicroUSBEtc();
1329     Flip_hinge() MicroUSBEtc();
1330   }
1331 }
1332
1333 module LidWindow(){ ////toplevel
1334   translate([led_pos[0], -led_pos[1], lpp13[1]])
1335     mirror([0,0,1])
1336     cylinder(r= nla_r1, h=nla_t);
1337   LidAdhocMultiprintFrame(0);
1338 }
1339
1340 module LidWindowPrint(){ ////toplevel
1341   rotate([0,180,0])
1342     LidWindow();
1343 }
1344
1345 module DemoLidWindowSelect(){
1346   translate([led_pos[0], led_pos[1], -100]) {
1347     translate([0, -30, 0]) cube([400, 400, 200]);
1348   }
1349 }
1350
1351 module DemoLidWindow(){ ////toplevel
1352   %Lid();
1353   LidWindow();
1354   translate([0,40,0]){
1355     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1356     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1357   }
1358 }
1359
1360 module HingeLeverPrint(){ ////toplevel
1361   rotate([-90,0,0])
1362     translate([-phone_width/2, phone_height, 0])
1363     HingeLever();
1364 }
1365
1366 module TestSelectLength(){
1367   translate([-30, -200, -20])
1368     cube([30 + 15, 250, 40]);
1369 }
1370
1371 module TestLength(){ ////toplevel
1372   intersection(){
1373     Case();
1374     TestSelectLength();
1375   }
1376 }
1377
1378 module TestLengthRight(){ ////toplevel
1379   intersection(){
1380     Case();
1381     Flip_rhs(1)
1382       TestSelectLength();
1383   }
1384 }
1385
1386 module TestSelectWidth(){
1387   translate([-30, -(phone_height - 25), -20])
1388     mirror([0, 1, 0])
1389     cube([200, 50, 40]);
1390 }
1391
1392 module TestWidth(){ ////toplevel
1393   intersection(){
1394     Case();
1395     TestSelectWidth();
1396   }
1397 }
1398
1399 module TestLidWidthPrint(){ ////toplevel
1400   rotate([0,180.0]) intersection(){
1401     Lid();
1402     TestSelectWidth();
1403   }
1404 }
1405
1406 module TestSelectRearAperture(){
1407   minkowski(){
1408     union() children();
1409     translate([20, 0,0])
1410       cube([42, 2, 1], center=true);
1411   }
1412 }
1413
1414 module TestSelectCamera(){
1415   minkowski(){
1416     TestSelectRearAperture()
1417       RearCameraAperture();
1418     cube([0.1, 50, 0.1]);
1419   }
1420 }
1421
1422 module TestSelectOrdinaryRearApertures(){
1423   TestSelectRearAperture()
1424     OrdinaryRearApertures();
1425 }
1426
1427 module TestCamera(){ ////toplevel
1428   intersection(){
1429     Case();
1430     TestSelectCamera();
1431   }
1432 }
1433
1434 module TestLidByCamera(){ ////toplevel
1435   intersection(){
1436     Lid();
1437     TestSelectCamera();
1438   }
1439 }
1440
1441 module TestLidByCameraPrint(){ ////toplevel
1442   rotate([180,0,0]) TestLidByCamera();
1443 }
1444
1445 module DemoByCamera(){ ////toplevel
1446   color("blue") TestLidByCamera();
1447   color("red")  TestCamera();
1448 }
1449
1450 module OneKeeper(){ ////toplevel
1451   translate([0, -phone_cnr_rad, 0])
1452     rotate([90, 0, 0])
1453     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1454     KeeperProfile();
1455 }
1456
1457 module OneKeeperPrint(){ ////toplevel
1458   rotate([0,180,0])
1459     OneKeeper();
1460 }
1461
1462 module LidPrint(){ ////toplevel
1463   rotate([0,180,0])
1464     Lid();
1465 }
1466
1467 module TestSelectFrame(){
1468   include = [1,-1] * (epp2i[0] + 4);
1469
1470   difference(){
1471     cube(1000, center=true);
1472     translate([0,0, -100])
1473       linear_extrude(height=200)
1474       rectfromto(include,  inside_br - include);
1475   }
1476 }
1477
1478 module TestSelectLidFrame(){
1479   TestSelectFrame();
1480   translate([led_pos[0], -led_pos[1], -50])
1481     cylinder(r= nla_r2+3, h=100);
1482 }
1483
1484 module TestFrameCase(){ ////toplevel
1485   intersection(){
1486     Case();
1487     union(){
1488       TestSelectFrame();
1489       TestSelectCamera();
1490       TestSelectOrdinaryRearApertures();
1491     }
1492   }
1493 }
1494
1495 module TestSelectTopApertures(){
1496   translate([-100, -35, -100])
1497     cube([400, 100, 200]);
1498   LidAdhocMultiprintFrame(0);
1499   LidAdhocMultiprintFrame(1);
1500 }
1501
1502 module TestTopApertures(){ ////toplevel
1503   intersection(){
1504     Case();
1505     TestSelectFrame();
1506     TestSelectTopApertures();
1507   }
1508 }
1509
1510 module TestLidTopAperturesPrint(){ ////toplevel
1511   rotate([0,180,0]) intersection(){
1512     Lid();
1513     TestSelectLidFrame();
1514     TestSelectTopApertures();
1515   }
1516 }
1517
1518 module TestLidWindowTopAperturesPrint(){ ////toplevel
1519   rotate([0,180,0]) intersection(){
1520     LidWindow();
1521     TestSelectTopApertures();
1522   }
1523 }
1524
1525 module TestFrameLidPrint(){ ////toplevel
1526   rotate([0,180,0]) intersection(){
1527     Lid();
1528     TestSelectLidFrame();
1529   }
1530 }
1531
1532 module ButtonPlanForDemo(z, deep, cut){
1533   translate([0,0,z])
1534     ButtonPlan(8, deep, cut);
1535 }
1536
1537 module HingeScrews(){
1538   Flip_rhs() Flip_bot(1){
1539     for (c= [ hppT, hppB ])
1540       translate([ hex20,
1541                   -c[0],
1542                   c[1] ]){
1543         rotate([0,90,0])
1544           translate([0,0,-.2])
1545           cylinder( r= hingescrew_shaft_dia/2,
1546                     h = hingescrew_shaft_len+0.2 );
1547         rotate([0,-90,0])
1548           translate([0,0,+.1])
1549           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1550       }
1551   }
1552 }
1553
1554 module DemoPropAngleSelect(c){
1555   color(c) difference(){
1556     union(){ children(); }
1557     translate([ prop_x_pos, -400, -200 ])
1558       cube([ 400,800,400 ]);
1559   }
1560 }
1561
1562 module DemoPropAngle(ang){
1563   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1564   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1565
1566   translate(hL)
1567     rotate([ang/2,0,0])
1568     translate(-hL)
1569     translate(hC)
1570     rotate([ang/2,0,0])
1571     translate(-hC) {
1572       DemoPropAngleSelect("red") Case();
1573
1574       color("orange")
1575         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1576         PropProfileAssignments(ang) {
1577           echo($prpp1);
1578           rotate([-$prp_theta, 0, 0])
1579           translate([0, $prpp1[0], -$prpp1[1]])
1580           rotate([90,0,-90])
1581           Prop();
1582         }
1583     }
1584
1585   translate([0,0, -hp_k*2])
1586     DemoPropAngleSelect("blue")
1587     Lid();
1588 }
1589
1590 module DemoPropAngles(){ ////toplevel
1591   for (i=[0 : len(prop_angles)-1])
1592     translate(i * [0, -100, 100])
1593     DemoPropAngle(prop_angles[i]);
1594 }
1595
1596 module DemoHingeAngle(ang1,ang2){
1597   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1598   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1599
1600   translate(hL)
1601     rotate([ang2,0,0])
1602     translate(-hL)
1603     translate(hC)
1604     rotate([ang1,0,0])
1605     translate(-hC) {
1606       color("red") Lid();
1607     }
1608
1609   color("blue") intersection(){
1610     Case();
1611     union(){
1612       translate([bppJ[0], -400, -200])
1613         mirror([1,0,0])
1614         cube([400, 800, 400]);
1615       translate([10, -400, -200])
1616         cube([10, 800, 400]);
1617     }
1618   }
1619 }
1620
1621 module DemoHingeAngles(){ ////toplevel
1622   angles = [ 0, 4, 8, 12 ];
1623   echo("angles",angles);
1624   for (i=[0 : len(angles)-1]) {
1625     translate(i * [0, 0, 30]) {
1626       DemoHingeAngle(0,angles[i]);
1627       translate([0, 200, 0])
1628         DemoHingeAngle(angles[i],0);
1629     }
1630   }
1631 }
1632
1633 module DemoSelectAdhocLeftRight(right=0) {
1634   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1635     mirror([1-right, 0,0])
1636     cube([400, 800, 200]);
1637 }
1638
1639 module DemoLeft(){ ////toplevel
1640   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1641   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1642 }
1643
1644 module DemoFrame(){ ////toplevel
1645   color("red") render() TestFrameCase();
1646   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1647   color("black") render() HingeScrews();
1648   %render() HingeLever();
1649 }
1650
1651 module DemoLanyardCutout(){ ////toplevel
1652   LanyardCutout(25);
1653 }
1654
1655 module DemoHingedFrame(){ ///toplevel
1656   color("red") TestFrameCase();
1657   translate([0,0, -2*hp_k])
1658   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1659
1660   Flip_hinge(){
1661     color("orange") HingeLever();
1662     color("black") HingeScrews();
1663   }
1664 }
1665
1666 module DemoHinge(){ ////toplevel
1667   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1668     DemoFrame();
1669     translate([0,0, -hp_k*3])
1670       DemoHingedFrame();
1671   }
1672 }
1673
1674 module DemoProfiles(){ ////toplevel
1675   LidEdgeProfile();
1676   %EdgeProfile();
1677   KeeperProfile();
1678   translate([0,0,-1]) color("black") KeeperProfile(1);
1679   translate(ly_o){
1680     rotate(-ly_theta){
1681       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1682       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1683       translate([0, ly_q_z]){
1684         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1685         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1686       }
1687     }
1688   }
1689   translate([0,0,-5]) color("white") translate(epp2i)
1690     rotate(-ly_theta)
1691     rectfromto([-15, 0],
1692                [+15, -max_case_bottom_edge_thickness]);
1693
1694   translate([0,20]) {
1695     LanyardMainChannelProfile();
1696     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1697     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1698   }
1699
1700   translate([20,0]) {
1701     LidEdgeProfile();
1702     %EdgeProfile();
1703
1704     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1705
1706     color("blue") ButtonCoverProfile();
1707     color("red") {
1708       rectfromto(bppQ, demopoint_QR);
1709       rectfromto(bppR, demopoint_QR);
1710     }
1711   }
1712
1713   translate([-20,0]) {
1714     color("black") ButtonPlanForDemo(-2, 0,1);
1715     color("red" )  ButtonPlanForDemo(-4, 1,1);
1716     color("blue")  ButtonPlanForDemo(-6, 1,0);
1717   }
1718
1719   translate([0, -30]) {
1720     %LidEdgeProfile();
1721     %EdgeProfile();
1722     color("blue") HingeLidProfile();
1723     color("red")  HingeBaseProfile();
1724     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1725   }
1726
1727   for (f=[0,1]) {
1728     translate([-30, -60 + 30*f]) {
1729       translate([0,0,-4]) EdgeProfile();
1730       %translate([0,0,-10]) HingeBaseProfile();
1731       translate([0,-2] * f * hp_k) {
1732         translate([0,0,-4]) LidEdgeProfile();
1733         %translate([0,0,-10]) %HingeLidProfile();
1734       }
1735       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1736         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1737         translate([0,0,0]) color("red") difference(){
1738           HingeLeverOuterProfile();
1739           HingeLeverInnerProfile();
1740         }
1741         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1742       }
1743     }
1744   }
1745
1746   translate([20,-30]) {
1747     %EdgeProfile();
1748     %LidEdgeProfile();
1749     //translate([0,0,1]) ThumbRecessCutProfile();
1750     translate([0,0,+1]) color("red")
1751       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1752   }
1753
1754   translate([40,-30]) {
1755     difference(){
1756       LidEdgeProfile();
1757       translate(prlp10)
1758         PropProfile(10, 1, 0);
1759     }
1760     translate(prlp10)
1761       PropProfile(15, 0);
1762   }
1763   translate([60,-30]) {
1764     PropAggregateProfile();
1765   }
1766 }
1767
1768 //EdgeProfile();
1769 //KeeperProfile();
1770 //CaseBase();
1771 //%Case();
1772 //Keeper();
1773 //LidEdgeProfile();
1774 //KeeperProfile();
1775 //DemoProfiles();
1776 //PropRecess();