fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 166 noisecancelmic_dia = 4.00;
 167
 168 lhshole_pos = [ phone[1]/2, 4.35 ];
 169
 170 // fingerpushhole_dias = []; xxx what was this
 171 fingerpushhole_dias = [ 15, 18 ];
 172
 173 lanyard_half_dia = 1.15;
 174 lanyard_entry_rel_breadth = 2;
 175 lanyard_channel_len = 8;
 176 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 177 rearspeaker_size   = [  3.76,  7.36 ];
 178
 179 bottomspeaker_size = [ 11.35, 1.40 ] + [1,1] * 1.0;
 180 bottomspeaker_pos = [ 19.45, 4.82 ];
 181
 182 microusb_above = 1.64 - 0.25;
 183 microusb_below = 2.42;
 184 microusb_width = 12.16 + 2.0 + 1.25;
 185
 186 case_th_bottom = 2.5;
 187 case_th_lid = 3.0;
 188 case_th_side = 2.3;
 189 case_th_lip = 1.2;
 190
 191 lid_screen_gap_extra = .66;
 192
 193 case_struts_count = 6;
 194 case_struts_solid_below = 1.00;
 195 case_struts_solid_above = 0.75;
 196 case_struts_width = 0.10;
 197
 198 keeper_th_z = 0.75;
 199 keeper_th_x = 0.75;
 200 keeper_inner_width = 2.75;
 201 keeper_inner_height = 2.75;
 202 keeper_slant_slope = 2; // larger means steeper
 203
 204 keeper_gap_z_top = 0.25;
 205 keeper_gap_z_bot = 0.75;
 206 keeper_gap_x     = 0.25;
 207 keeper_gap_x_holes = 0.75;
 208
 209 keeper_side = 0; // 0 = lhs; 1 = rhs
 210
 211 case_lip = 1.25;
 212
 213 lid_gap_x = 0.25;
 214 lid_gap_z = 0.25;
 215 lid_lip = 1.75;
 216 lid_edgepart_width = 5.0;
 217 lid_buttoncover_thick = 1.3;
 218 lid_buttoncover_reinf = 0.65;
 219
 220 foldover_gap = 0.50;
 221 foldover_lever_gap = 0.50;
 222
 223 // xxx replace hinge screw with nail plan
 224
 225 // properties of the hinge fasteners
 226 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 227 hingescrew_shaft_len = 12;
 228 hingescrew_fasteners_extra_thick = 0.40;
 229 // ^ amount of thread protruding if everything was completely nominal
 230 //   and we are using two nuts
 231 hingescrew_nut_access_dia = 4.72 + 0.50;
 232 // ^ washer is 4.72 dia
 233 //   also, want to get pliers or tiny spanner in to do up locknut
 234 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 235 hingescrew_nut_thick = 1.93;
 236 hingescrew_head_th = 1.38 + 0.75;
 237 hingescrew_head_dia = 3.92;
 238
 239 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 240
 241 lever_cover_th = 0.75;
 242 hingemount_th = 2.5;
 243 hingemount_wd = 4.8725;
 244
 245 $fa = 5;
 246 $fs = 0.1;
 247
 248 button_l_fudge = 4.4;
 249 buttonishleg_default_l_is_fudge = 10;
 250
 251 hinge_base_slope = 1.5; // bigger is steeper
 252
 253 strut_min_at_end = 1.5;
 254
 255 hinge_x_gap = 0.125;
 256 hinge_x_postscrew_gap = 0.75;
 257 hinge_x_arms_gap = 0.35;
 258 hinge_r_arms_gap = 0.55;
 259
 260 // xxx there isn't one of these, speaker is by hinge
 261 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 262
 263 thumbrecess_depth = 1.3;
 264 thumbrecess_width = 16.5;
 265 thumbrecess_topcurve_r = 5.0;
 266
 267 prop_recess_under = 0.50;
 268 prop_recess_slop = 0.200; // each side
 269 prop_end_dia = 0.5;
 270 prop_main_th = 3;
 271 prop_taper_len = 6;
 272 prop_main_width = 4;
 273 prop_side_gap = 0.75; // each side
 274 prop_lidrecess_behind = 0.75;
 275 prop_caserecess_behind = 0.75;
 276 prop_caserecess_taper = 0.45; // one side only
 277 prop_prop_gap = 0.5;
 278 prop_prong_heel_slope = 0.5;
 279
 280 lid_fold_clearance_antislop = 0.5;
 281
 282 $button_leg_only = false;
 283 $suppress_forward_holes = false;
 284
 285 // ---------- calculated ----------
 286
 287 phone_total_thick = phone_edge_thick;
 288
 289 phone_width =  (phone + bumper*2)[0];
 290 phone_height = (phone + bumper*2)[1];
 291
 292 inside_br = [phone_width, -phone_height];
 293
 294 prop_prong_h = prop_main_th;
 295
 296 //echo(camera_pos_tl + bumper,
 297 //     camera_pos_br + bumper);
 298
 299 // ----- could be changed -----
 300 lid_buttoncover_gap = lid_gap_x;
 301 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 302
 303 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 304
 305 //prop_nose_len = case_th_lid - prop_recess_under;
 306 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 307 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 308
 309
 310 //lid_lip_overlap_width xxx bad name = ;
 311 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 312
 313 epp0 = [0,0];
 314 epp1 = [0, -phone_edge_thick];
 315 epp2i = epp1; // conflated for FP4
 316 epp2o = epp2i;
 317 epp3 = epp2i + [10, 0];
 318 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 319 epp4 = epp5 + [-1,0] * case_th_side;
 320
 321 kppe = [0,0];
 322 kppd = kppe + [1,0] * keeper_inner_width;
 323 kppc = kppd + [0,1] * keeper_th_z;
 324 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 325 kppf = kppe - [0,1] * keeper_inner_height;
 326 kppa = [ kppb[0], kppf[1] ];
 327
 328 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 329 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 330
 331 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 332 // exact x posn not very important; must extend past end of keeper
 333
 334 lpp15 = [ lpp14[0],
 335           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 336           + lid_screen_gap_extra ];
 337 // ^ beam theory says to maximise force before contact,
 338 //   the gap below the `beam' (the lid) must be 1/3
 339 //   the thickness (ie the lid thickness) if the beam
 340 //   is solid, or 1/2 if it has a top and bottom only.
 341 //   ours is mostly solid.
 342
 343 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 344              case_th_lip);
 345
 346 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 347 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 348
 349 case_bottom_z = epp2o[1] - case_th_bottom;
 350
 351 // button profile
 352 bppM = epp4 + [0,5];
 353 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 354 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 355 bppS = [ epp1[0], bppR[1] ];
 356 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 357 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 358 bppO = [ bppN[0], bppP[1] ];
 359 bppL = lpp10 + [5,0];
 360 bppK = [ bppL[0], bppN[1] ];
 361 bppJ = [ bppN[0], bppL[1] ];
 362 bppU = [ bppJ[0], lpp12[1] ];
 363 bppV = lpp11;
 364 bppW = lpp10;
 365
 366 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 367
 368 // notification led aperture
 369
 370 nla_r0 = led_aperture/2;
 371 nla_r1 = nla_r0 + led_window_ledge;
 372 nla_r2 = nla_r1 + multicolour_gap;
 373 nla_t =
 374   led_window_style >= 3 ? initial_layer_thick :
 375   led_window_style >= 2 ? led_window_ledge : 0;
 376
 377
 378 // hinge plan
 379 hp_rn = hingescrew_nut_access_dia/2;
 380 hp_r2_min = hp_rn + lever_cover_th;
 381 hp_rs = hingescrew_shaft_dia/2;
 382 hp_r1_min = hp_rs + hingemount_th;
 383
 384 hp_r1 = max(hp_r1_min, hp_r2_min);
 385 hp_r2 = hp_r1;
 386
 387 hppU = lpp13;
 388 hppS = epp2o + [0,-1] * case_th_bottom;
 389 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 390
 391 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 392          0.5 * (hppU + hppS)[1] ];
 393 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 394 hppB = hppT + [0,-1] * hp_k;
 395
 396 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 397 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 398 hppE = [ hppE_x, hppE_y ];
 399
 400 // hinge elevation x coords
 401
 402 hex20 = max(epp2o[0],
 403             phone_cnr_rad,
 404             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 405 hex21 = hex20 + hingemount_wd;
 406 hex22 = hex21 + hinge_x_gap;
 407 hex27 = hex20 + hingescrew_shaft_len;
 408 hex24 = hex27 + hinge_x_postscrew_gap;
 409 hex23 = hex27 - (hingescrew_nut_thick*2
 410                  + hingescrew_fasteners_extra_thick);
 411 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 412
 413 echo(hex20, hex21, hex22, hex23, hex24);
 414 //  6, 10.8725, 10.9975, 13.74, 18.75
 415 module chk(act,exp) {
 416   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 417   else echo("ok", act);
 418 }
 419 chk(hex20, 6);
 420 chk(hex21, 10.8725);
 421 chk(hex22, 10.9975);
 422 chk(hex23, 13.74);
 423 chk(hex24, 18.75);
 424
 425 lid_fold_clearance_skew =
 426   (lpp10[1] - hppB[1]) /
 427   (lpp10[0] - hppB[0]);
 428
 429 echo("SK",lid_fold_clearance_skew);
 430
 431 // thumb recess (used to be "catch" hence cpp*
 432
 433 cppA = epp4 + [thumbrecess_depth, 0];
 434 cppB = [ cppA[0], epp1[1] ];
 435
 436 // lanyard
 437
 438 ly_r = lanyard_half_dia / 2;
 439 ly_rc = ly_r * 2;
 440
 441 ly_theta = 90;
 442 ly_o = epp2i + 3 * ly_r * [0,1];
 443
 444 max_case_bottom_edge_thickness =
 445   case_th_bottom;
 446
 447 ly_q_z = -(ly_rc + ly_r);
 448 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 449
 450 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 451
 452 // prop recess in case
 453
 454 prop_x_pos = phone_width/2;
 455
 456 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 457
 458 prc_r1 = prop_end_dia/2;
 459 prc_r3 = prc_r1 + prop_recess_slop;
 460
 461 prcp2 = [ epp4[0] + prop_buildout_less,
 462           case_bottom_z ];
 463
 464 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 465
 466 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 467           epp2i[1] - prc_r3 - prop_recess_under];
 468
 469 // prop recess in lid
 470
 471 prl_r10 = prop_end_dia/2;
 472 prl_r10o = prl_r10 + prop_recess_slop;
 473
 474 prlp10 = lpp10 + [1,1] * prl_r10o
 475   + [1,0] * prop_lidrecess_behind
 476   + [0,1] * prop_recess_under;
 477
 478 // prop
 479
 480 $prpp10 = [0,0];
 481 $prpp11 = [0, prop_taper_len];
 482
 483 $prp_r10 = prl_r10;
 484
 485 // ---------- modules ----------
 486
 487 module AdhocMultiprintFrame(phase, z0, zs) {
 488   // from z0 to z0 + zs*layer
 489   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 490   xextra = extra + -epp4[0];
 491   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 492   yextra = extra + -epp4[0];
 493   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 494   p0 = [ xrange[0], yrange[0] ];
 495   p1 = [ xrange[1], yrange[1] ];
 496   echo(p0, p1);
 497   translate([0,0, z0])
 498     mirror([0,0, zs<0 ? 1 : 0])
 499     linear_extrude(height= initial_layer_thick)
 500     difference(){
 501       rectfromto(p0 - [1,1] * initial_layer_width,
 502                  p1 + [1,1] * initial_layer_width);
 503       rectfromto(p0, p1);
 504     }
 505 }
 506
 507 module KeeperProfile(slant=0){
 508   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 509   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 510 }
 511
 512 module EdgeProfile(){
 513   difference(){
 514     hull(){
 515       translate(epp3) square(case_th_bottom*2, center=true);
 516       circleat(epp2o, r=case_th_bottom);
 517       circleat(epp1, r=case_th_side);
 518       rectfromto(epp0, epp4);
 519     }
 520     polygon([ epp5 + [0,10],
 521               epp1,
 522               epp3 + [10,0] ]);
 523   }
 524 }
 525
 526 module LanyardLanyardProfile(entry=false){
 527   hull(){
 528     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 529       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 530         circle(r= lanyard_half_dia/2);
 531   }
 532 }
 533
 534 module LanyardCurveChannelProfile(){
 535   translate([0, -ly_r])
 536     LanyardLanyardProfile();
 537 }
 538
 539 module LanyardEntryChannelProfile(){
 540   LanyardLanyardProfile(true);
 541 }
 542
 543 module LanyardMainChannelProfile(){
 544   LanyardCurveChannelProfile();
 545   difference(){
 546     square(center=true, ly_r * [6, 2]);
 547     for (xs=[-1,+1])
 548       translate(ly_r * [3 * xs, -1])
 549         circle(r = ly_r);
 550   }
 551 }
 552
 553 module LanyardEntryOuterProfile(){
 554   circleat([ly_re + ly_r, 0], ly_re);
 555 }
 556
 557 module LanyardEntry(){
 558   q_z = ly_q_z;
 559   oec_y = ly_oec_y;
 560
 561   d_x = -ly_rc;
 562
 563   translate([d_x, 0, q_z]) {
 564     intersection(){
 565       rotate([90,0,0])
 566         rotate_extrude(convexity=10)
 567         rotate(90)
 568         translate([0, -q_z])
 569         LanyardCurveChannelProfile();
 570       translate([0,-10,0])
 571         cube([20,20,20]);
 572     }
 573   }
 574
 575   mirror([0,0,1])
 576     translate([0,0,-1])
 577     linear_extrude(height=20)
 578     rotate(-90)
 579     LanyardEntryChannelProfile();
 580
 581   translate([0, ly_r*2, 0])
 582     rotate([90,0,0])
 583     linear_extrude(height = ly_r*4){
 584     difference(){
 585       rectfromto([d_x, q_z], [ly_r, 0]);
 586       circleat([d_x, q_z], ly_rc);
 587     }
 588   }
 589
 590   translate([0,0,q_z]){
 591     for (my=[0,1])
 592       mirror([0,my,0]){
 593         translate([0, oec_y, 0]){
 594           difference(){
 595             translate(ly_re * [-1,0,-2])
 596               cube(ly_re * [2,1,2]);
 597             rotate_extrude(convexity=10)
 598               LanyardEntryOuterProfile();
 599           }
 600         }
 601       }
 602     difference(){
 603       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 604         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 605       for (mx=[0,1])
 606         mirror([mx,0,0])
 607           rotate([90,0,0])
 608           translate([0,0,-10])
 609           linear_extrude(height=20)
 610           LanyardEntryOuterProfile();
 611     }
 612   }
 613 }
 614
 615 module LanyardCutout(l){
 616   rotate([0,-90,0])
 617     linear_extrude(height=l)
 618     rotate(-90)
 619     LanyardMainChannelProfile();
 620
 621   for (ee=[0,1]){
 622     translate(ee * l * [-1,0])
 623       mirror([ee,0,0])
 624       LanyardEntry();
 625   }
 626 }
 627
 628 module LidEdgeProfile(){
 629   polygon([ lpp10,
 630             lpp11,
 631             lpp12,
 632             lpp13,
 633             lpp13 + [10, 0],
 634             lpp15 + [10, 0],
 635             lpp15,
 636             lpp14,
 637             ]);
 638   intersection(){
 639     circleat(lpp12, r=lp_r12);
 640     rectfromto( lpp12 + [-10,   0],
 641                 lpp12 + [+10, +10] );
 642   }
 643 }
 644
 645 module LidEdgeFoldClearanceProfile(){
 646   translate([-lid_fold_clearance_antislop, 0])
 647     polygon([ lpp10,
 648               lpp11,
 649               lpp11 + [-20,  0],
 650               lpp11 + [-20, 20],
 651               lpp11 + [+20, 20],
 652               lpp10 + [+20,  0] ]);
 653 }
 654
 655 module ButtonCoverProfile(){
 656   intersection(){
 657     polygon(concat([ bppM, bppP, bppO, bppJ ],
 658                    (enable_support && !$button_suppress_over_keeper
 659                     ? [ bppU, bppV, bppW ] : []),
 660                    [ bppL, bppK ]));
 661     hull(){
 662       EdgeProfile();
 663       LidEdgeProfile();
 664     }
 665   }
 666 }
 667
 668 module ButtonPlan(l, deep, cut){
 669   epsilon =
 670     (cut  ? 0 : lid_buttoncover_gap);
 671
 672   delta =
 673     (deep ? lid_buttoncover_overlap : 0);
 674
 675   C = [0,0]; // by definition
 676   T = [ 0, epp4[1] ];
 677   G = T + [0,10];
 678
 679   B0 = C + [0,-1] * button_cutout_depth;
 680   B1 = B0 + [0,1] * epsilon;
 681
 682   r0 = 0.5 * (T[1] - B0[1]);
 683   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 684   H = A + [0,-1] * delta;
 685
 686   D = A + [-2,0] * r0;
 687   F = D + [0,10];
 688
 689   E0 = 0.5 * (D + A);
 690   E1 = E0 + [1,0] * epsilon;
 691
 692   I0 = [ E0[0], H[1] ];
 693   I1 = [ E1[0], H[1] ];
 694
 695   hull(){
 696     for (m=[0,1]) mirror([m,0])
 697       circleat(H, r0 - epsilon);
 698   }
 699   for (m=[0,1]) mirror([m,0]) {
 700     difference(){
 701       polygon([ E1,
 702                 I1,
 703                 H,
 704                 B1,
 705                 G,
 706                 F,
 707                 D
 708                 ]);
 709       circleat(D, r0 + epsilon);
 710     }
 711   }
 712 }
 713
 714 module ButtonCoverReinf(){ ////toplevel
 715   minkowski(){
 716     rotate([90,0,0])
 717       linear_extrude(height=0.01)
 718       intersection(){
 719         ButtonCoverProfile();
 720         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 721           square([100,100]);
 722     }
 723     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 724       circle(r= lid_buttoncover_reinf);
 725       translate([-20,0]) square(40, center=true);
 726     }
 727   }
 728 }
 729
 730 module ThumbRecessCutProfile(){
 731   difference(){
 732     polygon([ cppA + [-10,0],
 733               cppB + [-10,0],
 734               cppB,
 735               cppA ]);
 736     circleat(epp1, r=case_th_side);
 737   }
 738 }
 739
 740 module Flip_rhs(yn=[0,1]) {
 741   for ($rhsflip=yn) {
 742     translate([phone_width/2, 0, 0])
 743       mirror([$rhsflip,0,0])
 744       translate([-phone_width/2, 0, 0])
 745       children();
 746   }
 747 }
 748
 749 module Flip_bot(yn=[0,1]) {
 750   for ($botflip=yn) {
 751     translate([0, -phone_height/2, 0])
 752       mirror([0, $botflip, 0])
 753       translate([0, phone_height/2, 0])
 754       children();
 755   }
 756 }
 757
 758 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 759   // sides
 760   Flip_rhs(){
 761     translate([0, -phone_cnr_rad, 0])
 762       rotate([90,0,0])
 763       linear_extrude(height = phone_height - phone_cnr_rad*2)
 764       children(0);
 765   }
 766   // corners
 767   Flip_rhs() Flip_bot() {
 768     translate([+1,-1] * phone_cnr_rad)
 769       intersection(){
 770         rotate_extrude()
 771           intersection(){
 772             mirror([1,0,0])
 773               translate([-1,0] * phone_cnr_rad)
 774               children(0);
 775             rectfromto([0,-20],[10,20]);
 776           }
 777         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 778           cube([10,10,40]);
 779       }
 780   }
 781   // top and bottom
 782   Flip_bot(){
 783     translate([ phone_width - phone_cnr_rad, 0,0 ])
 784       rotate([90,0,-90])
 785       linear_extrude(height = phone_width - phone_cnr_rad*2)
 786       children(0);
 787   }
 788   // fill
 789   translate([0,0, fill_zstart])
 790     mirror([0,0, fill_downwards])
 791     linear_extrude(height = fill_th)
 792     rectfromto([+1,-1] * phone_cnr_rad,
 793                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 794 }
 795
 796 module CaseAperture(pos, dia, $fn, topbottom=0) {
 797   theta = 180/$fn;
 798   translate([ bumper[0],
 799               -epp2i[0],
 800                0 ])
 801     rotate([0,0, 90*topbottom])
 802     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 803     rotate([-90, theta, 0])
 804     cylinder(r = dia/2 / cos(theta),
 805              h = 60);
 806 }
 807
 808 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 809   // y_ref_sign:
 810   //   +1  measured from top    of actual phone to top    of button
 811   //   -1  measured from bottom of actual phone to bottom of button
 812   //    0  y is centre of button in coordinate system
 813   $button_l= l;
 814   $button_suppress_over_keeper= suppress_over_keeper;
 815   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 816           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 817           y;
 818   //echo(eff_y);
 819   translate([0, eff_y, 0])
 820     children();
 821 }
 822
 823 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 824   $button_leg_only = true;
 825   SideButton(y, y_ref_sign, l) children();
 826 }
 827
 828 module Buttons(){
 829   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 830   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 831   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 832   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 833   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 834   // xxx need hole for whatever that hole is on lhs
 835 }
 836
 837 module Struts(x_start, z_min, th){
 838   // if th is negative, starts at z_min and works towards -ve z
 839   // and object should then be printed other way up
 840   for (i= [1 : 1 : case_struts_count]) {
 841     translate([0,
 842                0,
 843                z_min])
 844       mirror([0,0, th<0 ? 1 : 0])
 845       translate([0,
 846                  -phone_height * i / (case_struts_count+1),
 847                  case_struts_solid_below])
 848       linear_extrude(height= abs(th)
 849                      -(case_struts_solid_below+case_struts_solid_above))
 850       rectfromto([               x_start, -0.5 * case_struts_width ],
 851                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 852   }
 853 }
 854
 855 module OrdinaryRearAperture(rhs,bot, pos){
 856   Flip_rhs(rhs) Flip_bot(bot)
 857     linextr(-20, 20)
 858     mirror([0,1])
 859     translate(pos + bumper)
 860     children();
 861 }
 862
 863 module MicroUSBEtc(){
 864   Flip_bot(1){
 865     rotate([90,0,0])
 866       mirror([0,0,1])
 867       linextr(-epp2i[0], 60)
 868       translate([0.5 * phone_width, 0, 0])
 869       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 870                  [+microusb_width/2, epp0[1] + -microusb_above]);
 871   }
 872 }
 873
 874 module OrdinaryBottomEdgeApertures(){
 875   Flip_bot(1) Flip_rhs(1) {
 876     linextr_y_xz(-epp2i[0], 60)
 877       hull()
 878       for (x= [-1,+1]) {
 879         translate([ -bottomspeaker_pos[0], -bottomspeaker_pos[1] ] +
 880                   [ 0.5 * x * bottomspeaker_size[0] - bottomspeaker_size[1],
 881                     0 ])
 882           rotate(360/16)
 883           circle(r = bottomspeaker_size[1], $fn = 8);
 884       }
 885   }
 886 }
 887
 888 module OrdinaryRearApertures(){
 889   // rear speaker
 890   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 891     rectfromto(-rearspeaker_gap,
 892                rearspeaker_size + rearspeaker_gap);
 893
 894   // finger hole to remove phone
 895   if (len(fingerpushhole_dias))
 896     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 897                                 phone[1]/2 ])
 898     scale(fingerpushhole_dias)
 899     circle(r= 0.5 );
 900 }
 901
 902 module RearCameraAperture(){
 903   Flip_rhs(1)
 904     mirror([0, 0, 1])
 905     linear_extrude(height = 20)
 906     mirror([0, 1, 0])
 907     translate(bumper)
 908     rectfromto(camera_pos_tl, camera_pos_br);
 909 }
 910
 911 module HingeLidProfile(){
 912   hull(){
 913     circleat(hppT, hp_r1);
 914     circleat(lpp12, lp_r12);
 915     polygon([lpp10,
 916              lpp13 + [2,0],
 917              lpp12,
 918              hppT]);
 919   }
 920 }
 921
 922 module HingeBaseProfile(){
 923   difference(){
 924     hull(){
 925       circleat(hppB, hp_r1);
 926       circleat(hppE, hp_r1);
 927       circleat(epp2o, case_th_bottom);
 928       circleat(hppB + [10,0], hp_r1);
 929     }
 930     polygon([epp5, epp1, epp3, bppL]);
 931   }
 932 }
 933
 934 module HingeLeverOuterProfile(){
 935   hull(){
 936     circleat(hppT, hp_r2);
 937     circleat(hppB, hp_r2);
 938   }
 939 }
 940
 941 module HingeLeverInnerProfile(){
 942   for (s = [-1,+1]) {
 943     c = s > 0 ? hppT : hppB;
 944     translate(c)
 945       mirror([0,0, s>0 ? 1 : 0])
 946       rotate(s<0 ? -40 : 0)
 947       hull()
 948       for (x=[-20,20])
 949         for (y=[0, s * 10])
 950           translate([x,y])
 951             circle(hp_rn);
 952   }
 953 }
 954
 955 module HingeLeverNutProfile(){
 956   for (c= [hppB, hppT]) {
 957     translate(c)
 958       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 959   }
 960 }
 961
 962 module Flip_hinge(doflip=1){
 963   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 964   translate(hinge_origin)
 965     rotate([doflip*180,0,0])
 966     translate(-hinge_origin)
 967     children();
 968 }
 969
 970 module HingePortion(x0,x1){
 971   Flip_rhs() Flip_bot(1)
 972     translate([x0,0,0])
 973     mirror([1,0,0])
 974     rotate([90,0,-90])
 975     linear_extrude(height=x1-x0)
 976     children();
 977 }
 978
 979 module ThumbRecessApply(ztop){
 980   width = thumbrecess_width;
 981   w = width + thumbrecess_topcurve_r*2 + 1;
 982   translate([phone_width/2, 0,0]){
 983     difference(){
 984       rotate([90,0,-90])
 985         linextr(-w/2, w/2)
 986         children(0);
 987       translate([0, 50, 0])
 988         rotate([90,0,0])
 989         linear_extrude(height=100){
 990         for (m=[0,1]) mirror([m,0,0]) {
 991           hull(){
 992             translate([w/2, ztop - thumbrecess_topcurve_r])
 993               circle(thumbrecess_topcurve_r);
 994             translate([w/2, -50])
 995               square(thumbrecess_topcurve_r*2, center=true);
 996           }
 997         }
 998       }
 999     }
1000   }
1001 }
1002
1003 module CaseBase(){
1004   AroundEdges(epp3[1], case_th_bottom, 1)
1005     EdgeProfile();
1006 }
1007
1008 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
1009
1010 module PropProfileAssignments(gamma){
1011   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
1012   x = prop_x(gamma);
1013   p = phone_height + prlp10[0] - hppB[0];
1014   b = p + x;
1015
1016   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1017   a = q + x;
1018   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1019   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1020
1021   $prp_theta = 90 - $prp_alpha;
1022   beta = 180 - $prp_alpha - gamma;
1023   psi = 90 - beta;
1024
1025   //echo("abc", a,b,c);
1026
1027   v1 = [ [ cos(psi), -sin(psi) ],    // x
1028          [ sin(psi),  cos(psi) ] ];  // y
1029
1030   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1031
1032   $prp_r1 = prc_r1;
1033   $prp_r11 = prop_main_th/2;
1034
1035   $prpp1 = $prpp7 + [1,0] *
1036     // this is approximate, but will do
1037     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1038   $prpp3 = $prpp1 +
1039     v1[0] * -$prp_r1 +
1040     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1041   $prpp12 = $prpp3 + v1[0] *
1042     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1043   $prp_r8 = prop_main_th;
1044   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1045   $prp_r5 = $prp_r8;
1046   $prpp5 = [ $prpp12[0] - $prp_r5,
1047             $prpp3[1] - prop_prong_h + $prp_r5 ];
1048   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1049          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1050   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1051   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1052
1053   children();
1054 }
1055
1056 module PropProfile(gamma, cut=0, rot=0){
1057   PropProfileAssignments(gamma){
1058
1059     //#circleat($prpp3,1);
1060     //#circleat($prpp12,1);
1061
1062     if (!cut) {
1063       hull(){
1064         translate($prpp8)
1065           intersection(){
1066             circle($prp_r8);
1067             polygon([[-20,-0], [20,20], [0,0]]);
1068           }
1069         rectfromto($prpp6, $prpp9);
1070         translate($prpp5) intersection(){
1071           circle($prp_r5);
1072           polygon([[-10,-10], [0,0], [10,0]]);
1073         }
1074         rectfromto($prpp12 + [0,-0.1], $prpp3);
1075       }
1076       hull(){
1077         circleat($prpp1, $prp_r1);
1078         rectfromto($prpp12 + [0,-0.1], $prpp3);
1079       }
1080     }
1081     // main shaft
1082     rotate([0,0, rot*-$prp_theta]){
1083       hull(){
1084         extra = cut ? prop_recess_slop : 0;
1085         rectfromto($prpp6, $prpp9);
1086         circleat($prpp11, $prp_r11 + extra);
1087         circleat($prpp10, $prp_r10 + extra);
1088       }
1089     }
1090   }
1091 }
1092
1093 module PropAggregateProfile(){
1094   for (angle = prop_angles)
1095     PropProfile(angle, 0,0);
1096 }
1097
1098 module Prop(){ ////toplevel
1099   hw = prop_main_width/2;
1100   linextr(-hw, +hw)
1101     PropAggregateProfile();
1102 }
1103
1104 module Case(){ ////toplevel
1105   difference(){
1106     union(){
1107       CaseBase();
1108
1109       // ledge (fixed keeper)
1110       Flip_rhs(1-keeper_side) intersection(){
1111         rotate([90, 0, 0])
1112           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1113           KeeperProfile(1);
1114
1115         // outline of the whole case, to stop it protruding
1116         translate([0,0, -25])
1117           linear_extrude(height = 50)
1118           hull()
1119           Flip_bot()
1120           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1121       }
1122
1123       // hinge
1124       HingePortion(hex20, hex21) HingeBaseProfile();
1125
1126       // buildout for prop recess
1127       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1128         linextr(case_bottom_z, epp2i[1])
1129         hull() {
1130           for (dxs = [-1,+1])
1131             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1132                        -epp2o[0] ],
1133                      r = epp2o[0] - prcp2[0]);
1134         }
1135     }
1136
1137     // slot for keeper
1138     Flip_rhs(keeper_side)
1139       translate([0, -phone_cnr_rad, 0])
1140       rotate([90, 0, 0])
1141       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1142       minkowski(){
1143         KeeperProfile();
1144         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1145                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1146       }
1147
1148     // front camera
1149     RearCameraAperture();
1150
1151     // struts (invisible, because they're buried in the case)
1152     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1153
1154     Buttons(){
1155       mirror([1,0,0])
1156         rotate([90,0,90]) {
1157           if (!($button_leg_only && enable_support))
1158           intersection(){
1159             translate([0,0,-10])
1160               linear_extrude(height= 20)
1161               ButtonPlan($button_l, 0,1);
1162             if ($button_leg_only)
1163               rotate([-90,90,0])
1164                 translate([phone_width/2, -400, kppe[1]])
1165                 mirror([1-abs($rhsflip - keeper_side),0,0])
1166                 cube([400, 800, 50]);
1167             if (enable_support && !$button_suppress_over_keeper)
1168               rotate([-90,90,0])
1169               translate([-400, -400, kppd[1]])
1170                 mirror([0,0,1])
1171                 cube([800,800,100]);
1172           }
1173           translate([0,0, -bppR[0]])
1174             linear_extrude(height= 20)
1175             ButtonPlan($button_l, 1,1);
1176         }
1177
1178     }
1179
1180     // apertures along top edge
1181     if (!$suppress_forward_holes) {
1182       // CaseAperture(jack_pos, jack_dia, 8);
1183       Flip_rhs(1)
1184         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1185       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1186     }
1187
1188     OrdinaryBottomEdgeApertures();
1189
1190     OrdinaryRearApertures();
1191
1192     MicroUSBEtc();
1193
1194     // gaps for the lid's hinge arms
1195     HingePortion(hex20 - hinge_x_arms_gap,
1196                  hex21 + hinge_x_arms_gap)
1197       minkowski(){
1198         HingeLidProfile();
1199         circle(r= hinge_r_arms_gap, $fn= 8);
1200       }
1201
1202     // screw holes in the hinge arms
1203     HingeScrews();
1204
1205     // thumb recess
1206     ThumbRecessApply(epp4[1])
1207       ThumbRecessCutProfile();
1208
1209     // lanyard
1210     Flip_bot(1)
1211       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1212       rotate([0, ly_theta, 0])
1213       rotate([0,0,90])
1214       LanyardCutout(lanyard_channel_len);
1215
1216     // prop recess
1217     Flip_rhs(1)
1218       translate([prop_x_pos,0,0])
1219       mirror([0,1,0])
1220       rotate([90,0,90])
1221       linextr(-prop_recess_hw, +prop_recess_hw)
1222       hull(){
1223         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1224           circleat(prcp1 + 20*d,
1225                    prc_r3);
1226       }
1227   }
1228 }
1229
1230 module LidAdhocMultiprintFrame(phase){
1231   if (led_window_style >= 3) {
1232     AdhocMultiprintFrame(phase, lpp13[1], -1);
1233   }
1234 }
1235
1236 module LidAroundEdges(){
1237   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1238     children();
1239 }
1240
1241 module Lid(){ ////toplevel
1242   skew_centre = [0, lpp11[0], lpp11[1]];
1243   difference(){
1244     union(){
1245       intersection(){
1246         LidAroundEdges()
1247           LidEdgeProfile();
1248
1249         translate(skew_centre)
1250           multmatrix([[ 1, 0, 0, 0 ],
1251                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1252                       [ 0, 0, 1, 0 ],
1253                       [ 0, 0, 0, 1 ]])
1254           translate(-skew_centre)
1255           LidAroundEdges()
1256           LidEdgeFoldClearanceProfile();
1257       }
1258
1259       // button covers
1260       Buttons(){
1261         intersection(){
1262           rotate([90,0,90])
1263             translate([0,0,-10])
1264             linear_extrude(height= 20)
1265             ButtonPlan($button_l, 1,0);
1266           union(){
1267             rotate([90,0,0])
1268               translate([0,0,-100])
1269               linear_extrude(height= 200)
1270               ButtonCoverProfile();
1271             hull()
1272               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1273                                  - lid_buttoncover_reinf))
1274                 translate([0,y,0])
1275                   ButtonCoverReinf();
1276           }
1277         }
1278       }
1279
1280       // hinge arms
1281       HingePortion(hex20, hex21) {
1282         LidEdgeProfile();
1283         HingeLidProfile();
1284       }
1285     }
1286     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1287
1288     // screw holes in the hinge arms
1289     HingeScrews();
1290
1291     // prop recess
1292     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1293       mirror([0,1,0])
1294       rotate([90,0,90])
1295       linextr(-prop_recess_hw, +prop_recess_hw)
1296       hull()
1297       for (pa = prop_angles)
1298         PropProfile(pa, 1,1);
1299
1300     // notification led aperture
1301     if (led_window_style)
1302       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1303         translate([0,0,-10])
1304           cylinder(r=nla_r0, h=20);
1305         if (led_window_style >= 2)
1306           translate([0,0, -nla_t])
1307             cylinder(r=nla_r2, height=20);
1308       }
1309
1310     }
1311
1312   LidAdhocMultiprintFrame(1);
1313 }
1314
1315 module HingeLever(){ ////toplevel
1316   difference() {
1317     // outer body, positive
1318     HingePortion(hex22, hex22 + phone_width/2)
1319       HingeLeverOuterProfile();
1320
1321     // space for the screws
1322     HingePortion(hex26, hex24)
1323       HingeLeverInnerProfile();
1324
1325     // recesses for the nuts
1326     HingePortion(hex23, hex26+1)
1327       HingeLeverNutProfile();
1328
1329     // bores for the screws
1330     HingeScrews();
1331
1332     // space for the charging cable
1333     MicroUSBEtc();
1334     Flip_hinge() MicroUSBEtc();
1335   }
1336 }
1337
1338 module LidWindow(){ ////toplevel
1339   translate([led_pos[0], -led_pos[1], lpp13[1]])
1340     mirror([0,0,1])
1341     cylinder(r= nla_r1, h=nla_t);
1342   LidAdhocMultiprintFrame(0);
1343 }
1344
1345 module LidWindowPrint(){ ////toplevel
1346   rotate([0,180,0])
1347     LidWindow();
1348 }
1349
1350 module DemoLidWindowSelect(){
1351   translate([led_pos[0], led_pos[1], -100]) {
1352     translate([0, -30, 0]) cube([400, 400, 200]);
1353   }
1354 }
1355
1356 module DemoLidWindow(){ ////toplevel
1357   %Lid();
1358   LidWindow();
1359   translate([0,40,0]){
1360     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1361     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1362   }
1363 }
1364
1365 module HingeLeverPrint(){ ////toplevel
1366   rotate([-90,0,0])
1367     translate([-phone_width/2, phone_height, 0])
1368     HingeLever();
1369 }
1370
1371 module TestSelectLength(){
1372   translate([-30, -200, -20])
1373     cube([30 + 15, 250, 40]);
1374 }
1375
1376 module TestLength(){ ////toplevel
1377   intersection(){
1378     Case();
1379     TestSelectLength();
1380   }
1381 }
1382
1383 module TestLengthRight(){ ////toplevel
1384   intersection(){
1385     Case();
1386     Flip_rhs(1)
1387       TestSelectLength();
1388   }
1389 }
1390
1391 module TestSelectWidth(){
1392   translate([-30, -(phone_height - 25), -20])
1393     mirror([0, 1, 0])
1394     cube([200, 50, 40]);
1395 }
1396
1397 module TestWidth(){ ////toplevel
1398   intersection(){
1399     Case();
1400     TestSelectWidth();
1401   }
1402 }
1403
1404 module TestLidWidthPrint(){ ////toplevel
1405   rotate([0,180.0]) intersection(){
1406     Lid();
1407     TestSelectWidth();
1408   }
1409 }
1410
1411 module TestSelectRearAperture(){
1412   minkowski(){
1413     union() children();
1414     translate([20, 0,0])
1415       cube([42, 2, 1], center=true);
1416   }
1417 }
1418
1419 module TestSelectCamera(){
1420   minkowski(){
1421     TestSelectRearAperture()
1422       RearCameraAperture();
1423     cube([0.1, 50, 0.1]);
1424   }
1425 }
1426
1427 module TestSelectOrdinaryRearApertures(){
1428   TestSelectRearAperture()
1429     OrdinaryRearApertures();
1430 }
1431
1432 module TestCamera(){ ////toplevel
1433   intersection(){
1434     Case();
1435     TestSelectCamera();
1436   }
1437 }
1438
1439 module TestLidByCamera(){ ////toplevel
1440   intersection(){
1441     Lid();
1442     TestSelectCamera();
1443   }
1444 }
1445
1446 module TestLidByCameraPrint(){ ////toplevel
1447   rotate([180,0,0]) TestLidByCamera();
1448 }
1449
1450 module DemoByCamera(){ ////toplevel
1451   color("blue") TestLidByCamera();
1452   color("red")  TestCamera();
1453 }
1454
1455 module OneKeeper(){ ////toplevel
1456   translate([0, -phone_cnr_rad, 0])
1457     rotate([90, 0, 0])
1458     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1459     KeeperProfile();
1460 }
1461
1462 module OneKeeperPrint(){ ////toplevel
1463   rotate([0,180,0])
1464     OneKeeper();
1465 }
1466
1467 module LidPrint(){ ////toplevel
1468   rotate([0,180,0])
1469     Lid();
1470 }
1471
1472 module TestSelectFrame(){
1473   include = [1,-1] * (epp2i[0] + 4);
1474
1475   difference(){
1476     cube(1000, center=true);
1477     translate([0,0, -100])
1478       linear_extrude(height=200)
1479       rectfromto(include,  inside_br - include);
1480   }
1481 }
1482
1483 module TestSelectLidFrame(){
1484   TestSelectFrame();
1485   translate([led_pos[0], -led_pos[1], -50])
1486     cylinder(r= nla_r2+3, h=100);
1487 }
1488
1489 module TestFrameCase(){ ////toplevel
1490   intersection(){
1491     Case();
1492     union(){
1493       TestSelectFrame();
1494       TestSelectCamera();
1495       TestSelectOrdinaryRearApertures();
1496     }
1497   }
1498 }
1499
1500 module TestSelectTopApertures(){
1501   translate([-100, -35, -100])
1502     cube([400, 100, 200]);
1503   LidAdhocMultiprintFrame(0);
1504   LidAdhocMultiprintFrame(1);
1505 }
1506
1507 module TestTopApertures(){ ////toplevel
1508   intersection(){
1509     Case();
1510     TestSelectFrame();
1511     TestSelectTopApertures();
1512   }
1513 }
1514
1515 module TestLidTopAperturesPrint(){ ////toplevel
1516   rotate([0,180,0]) intersection(){
1517     Lid();
1518     TestSelectLidFrame();
1519     TestSelectTopApertures();
1520   }
1521 }
1522
1523 module TestLidWindowTopAperturesPrint(){ ////toplevel
1524   rotate([0,180,0]) intersection(){
1525     LidWindow();
1526     TestSelectTopApertures();
1527   }
1528 }
1529
1530 module TestFrameLidPrint(){ ////toplevel
1531   rotate([0,180,0]) intersection(){
1532     Lid();
1533     TestSelectLidFrame();
1534   }
1535 }
1536
1537 module ButtonPlanForDemo(z, deep, cut){
1538   translate([0,0,z])
1539     ButtonPlan(8, deep, cut);
1540 }
1541
1542 module HingeScrews(){
1543   Flip_rhs() Flip_bot(1){
1544     for (c= [ hppT, hppB ])
1545       translate([ hex20,
1546                   -c[0],
1547                   c[1] ]){
1548         rotate([0,90,0])
1549           translate([0,0,-.2])
1550           cylinder( r= hingescrew_shaft_dia/2,
1551                     h = hingescrew_shaft_len+0.2 );
1552         rotate([0,-90,0])
1553           translate([0,0,+.1])
1554           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1555       }
1556   }
1557 }
1558
1559 module DemoPropAngleSelect(c){
1560   color(c) difference(){
1561     union(){ children(); }
1562     translate([ prop_x_pos, -400, -200 ])
1563       cube([ 400,800,400 ]);
1564   }
1565 }
1566
1567 module DemoPropAngle(ang){
1568   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1569   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1570
1571   translate(hL)
1572     rotate([ang/2,0,0])
1573     translate(-hL)
1574     translate(hC)
1575     rotate([ang/2,0,0])
1576     translate(-hC) {
1577       DemoPropAngleSelect("red") Case();
1578
1579       color("orange")
1580         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1581         PropProfileAssignments(ang) {
1582           echo($prpp1);
1583           rotate([-$prp_theta, 0, 0])
1584           translate([0, $prpp1[0], -$prpp1[1]])
1585           rotate([90,0,-90])
1586           Prop();
1587         }
1588     }
1589
1590   translate([0,0, -hp_k*2])
1591     DemoPropAngleSelect("blue")
1592     Lid();
1593 }
1594
1595 module DemoPropAngles(){ ////toplevel
1596   for (i=[0 : len(prop_angles)-1])
1597     translate(i * [0, -100, 100])
1598     DemoPropAngle(prop_angles[i]);
1599 }
1600
1601 module DemoHingeAngle(ang1,ang2){
1602   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1603   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1604
1605   translate(hL)
1606     rotate([ang2,0,0])
1607     translate(-hL)
1608     translate(hC)
1609     rotate([ang1,0,0])
1610     translate(-hC) {
1611       color("red") Lid();
1612     }
1613
1614   color("blue") intersection(){
1615     Case();
1616     union(){
1617       translate([bppJ[0], -400, -200])
1618         mirror([1,0,0])
1619         cube([400, 800, 400]);
1620       translate([10, -400, -200])
1621         cube([10, 800, 400]);
1622     }
1623   }
1624 }
1625
1626 module DemoHingeAngles(){ ////toplevel
1627   angles = [ 0, 4, 8, 12 ];
1628   echo("angles",angles);
1629   for (i=[0 : len(angles)-1]) {
1630     translate(i * [0, 0, 30]) {
1631       DemoHingeAngle(0,angles[i]);
1632       translate([0, 200, 0])
1633         DemoHingeAngle(angles[i],0);
1634     }
1635   }
1636 }
1637
1638 module DemoSelectAdhocLeftRight(right=0) {
1639   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1640     mirror([1-right, 0,0])
1641     cube([400, 800, 200]);
1642 }
1643
1644 module DemoLeft(){ ////toplevel
1645   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1646   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1647 }
1648
1649 module DemoFrame(){ ////toplevel
1650   color("red") render() TestFrameCase();
1651   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1652   color("black") render() HingeScrews();
1653   %render() HingeLever();
1654 }
1655
1656 module DemoLanyardCutout(){ ////toplevel
1657   LanyardCutout(25);
1658 }
1659
1660 module DemoHingedFrame(){ ///toplevel
1661   color("red") render() TestFrameCase();
1662   translate([0,0, -2*hp_k])
1663   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1664
1665   Flip_hinge(){
1666     color("orange") render() HingeLever();
1667     color("black") render() HingeScrews();
1668   }
1669 }
1670
1671 module DemoHinge(){ ////toplevel
1672   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1673     DemoFrame();
1674     translate([0,0, -hp_k*3])
1675       DemoHingedFrame();
1676   }
1677 }
1678
1679 module DemoProfiles(){ ////toplevel
1680   LidEdgeProfile();
1681   %EdgeProfile();
1682   KeeperProfile();
1683   translate([0,0,-1]) color("black") KeeperProfile(1);
1684   translate(ly_o){
1685     rotate(-ly_theta){
1686       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1687       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1688       translate([0, ly_q_z]){
1689         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1690         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1691       }
1692     }
1693   }
1694   translate([0,0,-5]) color("white") translate(epp2i)
1695     rotate(-ly_theta)
1696     rectfromto([-15, 0],
1697                [+15, -max_case_bottom_edge_thickness]);
1698
1699   translate([0,20]) {
1700     LanyardMainChannelProfile();
1701     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1702     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1703   }
1704
1705   translate([20,0]) {
1706     LidEdgeProfile();
1707     %EdgeProfile();
1708
1709     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1710
1711     color("blue") ButtonCoverProfile();
1712     color("red") {
1713       rectfromto(bppQ, demopoint_QR);
1714       rectfromto(bppR, demopoint_QR);
1715     }
1716   }
1717
1718   translate([-20,0]) {
1719     color("black") ButtonPlanForDemo(-2, 0,1);
1720     color("red" )  ButtonPlanForDemo(-4, 1,1);
1721     color("blue")  ButtonPlanForDemo(-6, 1,0);
1722   }
1723
1724   translate([0, -30]) {
1725     %LidEdgeProfile();
1726     %EdgeProfile();
1727     color("blue") HingeLidProfile();
1728     color("red")  HingeBaseProfile();
1729     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1730   }
1731
1732   for (f=[0,1]) {
1733     translate([-30, -60 + 30*f]) {
1734       translate([0,0,-4]) EdgeProfile();
1735       %translate([0,0,-10]) HingeBaseProfile();
1736       translate([0,-2] * f * hp_k) {
1737         translate([0,0,-4]) LidEdgeProfile();
1738         %translate([0,0,-10]) %HingeLidProfile();
1739       }
1740       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1741         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1742         translate([0,0,0]) color("red") difference(){
1743           HingeLeverOuterProfile();
1744           HingeLeverInnerProfile();
1745         }
1746         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1747       }
1748     }
1749   }
1750
1751   translate([20,-30]) {
1752     %EdgeProfile();
1753     %LidEdgeProfile();
1754     //translate([0,0,1]) ThumbRecessCutProfile();
1755     translate([0,0,+1]) color("red")
1756       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1757   }
1758
1759   translate([40,-30]) {
1760     difference(){
1761       LidEdgeProfile();
1762       translate(prlp10)
1763         PropProfile(10, 1, 0);
1764     }
1765     translate(prlp10)
1766       PropProfile(15, 0);
1767   }
1768   translate([60,-30]) {
1769     PropAggregateProfile();
1770   }
1771 }
1772
1773 //EdgeProfile();
1774 //KeeperProfile();
1775 //CaseBase();
1776 //%Case();
1777 //Keeper();
1778 //LidEdgeProfile();
1779 //KeeperProfile();
1780 //DemoProfiles();
1781 //PropRecess();