fairphone4-case.scad

   1 // -*- C -*-
   2
   3 // Hard case for Fairphone 2
   4 //
   5 //  Copyright 2018 Ian Jackson.  There is NO WARRANTY.
   6 //  See below for full licensing and disclaimer.
   7 //
   8 // Instructions
   9 //
  10 //  1. You will want to git clone this repository.
  11 //
  12 //  2. Decide about the notification LED aperture. See the variable
  13 //     led_window_style, below.  The default here is "ad-hoc
  14 //     multi-colour", which can produces a translucent (clear-ish)
  15 //     window set into the lid, even on a single-nozzle printer.
  16 //     See "Ad-hoc multi-colour", below.
  17 //
  18 //  3. use "make" to generate the necessary files:
  19 //
  20 //     make -j8 fairphone-case.auto.scads `for f in   \
  21 //        HingePrint        \
  22 //        LidWindowPrint    \
  23 //        LidPrint          \
  24 //        OneKeeperPrint    \
  25 //        Case              \
  26 //     ; do echo fairphone-case,$f.auto.stl; done`
  27 //
  28 //  4. Print them.  Case and OneKeeperPrint should probably be
  29 //     the same colour.
  30 //
  31 //     For Lid and LidWindowPrint, if you are doing ad-hoc
  32 //     multi-colour:
  33 //        i.   Set up for clear filament
  34 //        ii.  Print LidWindowPrint.  Wait for it to finish.
  35 //             It won't take long.  As soon as it finishes, tell
  36 //             your printer to warm up (so that in fact it does
  37 //             not cool down).
  38 //        iii. Leaving the output so far on the printbed, reload
  39 //             your printer with the main lid colour.
  40 //        iv.  Print LidPrint.  You can let this go unattended.
  41 //
  42 //  5. Assemble the hinge.  You will need 4x M2 12mm machine screws
  43 //     and 8x M2 full nuts.
  44 //
  45 //     Make sure you get the hinge the right way round.  If you're not
  46 //     sure, run
  47 //         openscad fairphone-case,DemoHinge.auto.scad
  48 //     to see an assembly diagram.
  49 //
  50 //     The nuts recess into the hinge.  You will want very fine
  51 //     pliers.  As you screw each screw in, add the second nut when
  52 //     the screw thread emerges from the first - this will be a
  53 //     locknut.  Screw each screw to an appropriate tightness for the
  54 //     hinge stiffness.  You want the lid-side hinge to be stiffer as
  55 //     that makes closing the case work better.
  56 //
  57 //     When you have the stiffness right, tighten the locknuts onto
  58 //     each first nut.
  59 //
  60 //  6. In use:
  61 //
  62 //      - To put the phone in, drop its RH side into the RH side of
  63 //        the case.  Then feed the keeper through the small hole.
  64 //        Feed it right through.
  65 //
  66 //      - The optional prop can be used to prop the phone up (in
  67 //        portrait orientation only right now).  See
  68 //            openscad fairphone-case,DemoPropAngles.auto.scad
  69 //
  70 // Ad-hoc multi-colour
  71 //
  72 //  This file is set up to let you make a translucent window using a
  73 //  single-extruder printer, using a "two print run" technique.  This
  74 //  works well with our Lulzbot TAZ 5 and Aleph Objects' version of
  75 //  Cura.  If you are using a different printer, you may need to
  76 //  adjust the parameters or try a different technique.  In particular,
  77 //      initial_layer_thick
  78 //         set so that the window is one layer thick
  79 //      initial_layer_width
  80 //         set so that the slicer draws a rectangle around the whole
  81 //         object, rather than putting a "skirt" or anything inside
  82 //
  83 //  If you have a dual-extruder printer, you can set led_window_style
  84 //  to 2 and do a single print of LidPrint and LidWindowPrint.
  85 //
  86 //  Alternatively you can set it to 1 (just a hole) or 0 (no hole).
  87 //
  88 //  Thanks to Clare Boothby for the ad-hoc multi-colour technique (and
  89 //  the parameters for our Lulzbot TAZ 5 and Aleph Objects's Cura).
  90 //
  91 // Other phones
  92 //
  93 //  It might well be possible to adapt this file for other phones.
  94 //  If you do, let me know how you get on.
  95 //
  96 //
  97 // AUTHORSHIP, COPYRIGHT, LICENCE, AND LACK OF WARRANTY
  98 //
  99 //   Copyright (C)2018 Ian Jackson.
 100 //
 101 //    This program for generating a 3D model is free software: you can
 102 //    redistribute it and/or modify it under the terms of the GNU
 103 //    General Public License as published by the Free Software
 104 //    Foundation, either version 3 of the License, or (at your option)
 105 //    any later version.
 106 //
 107 //    This program is distributed in the hope that it will be useful,
 108 //    but WITHOUT ANY WARRANTY; without even the implied warranty of
 109 //    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 110 //    GNU General Public License for more details.
 111 //
 112 //    You should have received a copy of the GNU General Public
 113 //    License along with this program.  If not, see
 114 //    <http://www.gnu.org/licenses/>.
 115 //
 116 //  In particular DO NOT BLAME ME IF THIS CASE DOES NOT ADEQUATELY
 117 //  PROTECT YOUR PHONE !  It is your responsibility to decide whether
 118 //  this case will meet your needs.
 119
 120 include <utils.scad>
 121 include <funcs.scad>
 122
 123 phone = [ 75.86, 162.0 ];
 124
 125 prop_buildout_less = 3;
 126
 127 prop_angles = [ 15, 30, 45, 60 ];
 128
 129 bumper = [ 0.250, -0.025 ];
 130 // ^ One side.  Overall size is increased by twice this.
 131 // If no bumpers, is the gap around the phone.
 132
 133 enable_support = 1;
 134
 135 led_window_style = 0;
 136 // 0: no window
 137 // 1: simply an opening
 138 // 2: opening with separate cover model, for printing in clear (two colour)
 139 // 3: like 2 but one-layer window for ad-hoc multi-colour
 140
 141 initial_layer_thick = 0.400; // ^ needed for mode 3 only
 142 initial_layer_width = 0.750; // ^ needed for mode 3 only
 143 multicolour_gap = 0.15; // each side
 144
 145 phone_cnr_rad = 7.0; // actuall 8.mumble, but smaller is fine
 146 phone_rim_depth = 0.01; // includes allowance for a screen protector
 147
 148 button_cutout_depth = 9;
 149
 150 phone_edge_thick = 11.25;
 151
 152 // xxx this is all wrong
 153 camera_pos_tl = [  6.450, 12.750 ]; // measured from tl corner
 154 camera_pos_br = [ 22.300, 37.600 ]; // tl/br as seen from back
 155
 156 // this is disabled, FP4 doesn't have one
 157 jack_pos = [ 13.83, 8.485 ];
 158 jack_dia = 10.64 + .5; // some jack I had lying around
 159
 160 // this led stuff, is irrelevant, we have disabled it as it doesn't have one
 161 led_pos = [ 13.98, 10.00 ];
 162 led_aperture = 9;
 163 led_window_ledge = 0.75; // each side
 164
 165 noisecancelmic_pos = [ 15.08, 4.35 ];   // from rhs, from top edge
 166 noisecancelmic_dia = 4.00;
 167
 168 lhshole_pos = [ phone[1]/2, 4.35 ];
 169
 170 // fingerpushhole_dias = []; xxx what was this
 171 fingerpushhole_dias = [ 15, 18 ];
 172
 173 lanyard_half_dia = 1.15;
 174 lanyard_entry_rel_breadth = 2;
 175 lanyard_channel_len = 8;
 176 rearspeaker_pos_bl = [ 12.64, 18.72 ];
 177 rearspeaker_size   = [  3.76,  7.36 ];
 178
 179 microusb_above = 1.64 - 0.25;
 180 microusb_below = 2.42;
 181 microusb_width = 12.16 + 2.0 + 1.25;
 182
 183 case_th_bottom = 2.5;
 184 case_th_lid = 3.0;
 185 case_th_side = 2.3;
 186 case_th_lip = 1.2;
 187
 188 lid_screen_gap_extra = .66;
 189
 190 case_struts_count = 6;
 191 case_struts_solid_below = 1.00;
 192 case_struts_solid_above = 0.75;
 193 case_struts_width = 0.10;
 194
 195 keeper_th_z = 0.75;
 196 keeper_th_x = 0.75;
 197 keeper_inner_width = 2.75;
 198 keeper_inner_height = 2.75;
 199 keeper_slant_slope = 2; // larger means steeper
 200
 201 keeper_gap_z_top = 0.25;
 202 keeper_gap_z_bot = 0.75;
 203 keeper_gap_x     = 0.25;
 204 keeper_gap_x_holes = 0.75;
 205
 206 keeper_side = 0; // 0 = lhs; 1 = rhs
 207
 208 case_lip = 1.25;
 209
 210 lid_gap_x = 0.25;
 211 lid_gap_z = 0.25;
 212 lid_lip = 1.75;
 213 lid_edgepart_width = 5.0;
 214 lid_buttoncover_thick = 1.3;
 215 lid_buttoncover_reinf = 0.65;
 216
 217 foldover_gap = 0.50;
 218 foldover_lever_gap = 0.50;
 219
 220 // xxx replace hinge screw with nail plan
 221
 222 // properties of the hinge fasteners
 223 hingescrew_shaft_dia = 2.0 + 0.25; // M2 x 12mm machine screw
 224 hingescrew_shaft_len = 12;
 225 hingescrew_fasteners_extra_thick = 0.40;
 226 // ^ amount of thread protruding if everything was completely nominal
 227 //   and we are using two nuts
 228 hingescrew_nut_access_dia = 4.72 + 0.50;
 229 // ^ washer is 4.72 dia
 230 //   also, want to get pliers or tiny spanner in to do up locknut
 231 hingescrew_nut_across = 3.92 + 0.25; // incl. slop around recess slop
 232 hingescrew_nut_thick = 1.93;
 233 hingescrew_head_th = 1.38 + 0.75;
 234 hingescrew_head_dia = 3.92;
 235
 236 hingescrew_nut_recess_portion = 2/3; // portion of nut in recess
 237
 238 lever_cover_th = 0.75;
 239 hingemount_th = 2.5;
 240 hingemount_wd = 4.8725;
 241
 242 $fa = 5;
 243 $fs = 0.1;
 244
 245 button_l_fudge = 4.4;
 246 buttonishleg_default_l_is_fudge = 10;
 247
 248 hinge_base_slope = 1.5; // bigger is steeper
 249
 250 strut_min_at_end = 1.5;
 251
 252 hinge_x_gap = 0.125;
 253 hinge_x_postscrew_gap = 0.75;
 254 hinge_x_arms_gap = 0.35;
 255 hinge_r_arms_gap = 0.55;
 256
 257 // xxx there isn't one of these, speaker is by hinge
 258 rearspeaker_gap    = [ 2.0, 2.0 ]; // each side
 259
 260 thumbrecess_depth = 1.3;
 261 thumbrecess_width = 16.5;
 262 thumbrecess_topcurve_r = 5.0;
 263
 264 prop_recess_under = 0.50;
 265 prop_recess_slop = 0.200; // each side
 266 prop_end_dia = 0.5;
 267 prop_main_th = 3;
 268 prop_taper_len = 6;
 269 prop_main_width = 4;
 270 prop_side_gap = 0.75; // each side
 271 prop_lidrecess_behind = 0.75;
 272 prop_caserecess_behind = 0.75;
 273 prop_caserecess_taper = 0.45; // one side only
 274 prop_prop_gap = 0.5;
 275 prop_prong_heel_slope = 0.5;
 276
 277 lid_fold_clearance_antislop = 0.5;
 278
 279 $button_leg_only = false;
 280 $suppress_forward_holes = false;
 281
 282 // ---------- calculated ----------
 283
 284 phone_total_thick = phone_edge_thick;
 285
 286 phone_width =  (phone + bumper*2)[0];
 287 phone_height = (phone + bumper*2)[1];
 288
 289 inside_br = [phone_width, -phone_height];
 290
 291 prop_prong_h = prop_main_th;
 292
 293 //echo(camera_pos_tl + bumper,
 294 //     camera_pos_br + bumper);
 295
 296 // ----- could be changed -----
 297 lid_buttoncover_gap = lid_gap_x;
 298 lid_buttoncover_overlap = case_th_lip + keeper_gap_z_top;
 299
 300 //prop_lidrecess_depth = case_th_lid - prop_recess_under;
 301
 302 //prop_nose_len = case_th_lid - prop_recess_under;
 303 //prop_recess_slope = tan(prop_max_angle); // bigger means steeper
 304 //prop_recess_width = prop_main_th / cos(prop_max_angle) + prop_backfwd_gap;
 305
 306
 307 //lid_lip_overlap_width xxx bad name = ;
 308 //lid_lip_inner_slope = [ 5, 5 ]; // xxx
 309
 310 epp0 = [0,0];
 311 epp1 = [0, -phone_edge_thick];
 312 epp2i = epp1; // conflated for FP4
 313 epp2o = epp2i;
 314 epp3 = epp2i + [10, 0];
 315 epp5 = epp0 + [0,1] * (keeper_th_z + keeper_gap_z_top + case_lip);
 316 epp4 = epp5 + [-1,0] * case_th_side;
 317
 318 kppe = [0,0];
 319 kppd = kppe + [1,0] * keeper_inner_width;
 320 kppc = kppd + [0,1] * keeper_th_z;
 321 kppb = [ kppe[0] - keeper_th_x, kppc[1] ];
 322 kppf = kppe - [0,1] * keeper_inner_height;
 323 kppa = [ kppb[0], kppf[1] ];
 324
 325 lpp10 = [ epp5[0] + lid_gap_x, kppc[1] + lid_gap_z ];
 326 lpp11 = [ lpp10[0],            epp5[1] + lid_gap_z ];
 327
 328 lpp14 = lpp10 + [1,0] * max(keeper_inner_width, lid_edgepart_width);
 329 // exact x posn not very important; must extend past end of keeper
 330
 331 lpp15 = [ lpp14[0],
 332           epp0[1] - phone_rim_depth + 1/2.5 * case_th_lid
 333           + lid_screen_gap_extra ];
 334 // ^ beam theory says to maximise force before contact,
 335 //   the gap below the `beam' (the lid) must be 1/3
 336 //   the thickness (ie the lid thickness) if the beam
 337 //   is solid, or 1/2 if it has a top and bottom only.
 338 //   ours is mostly solid.
 339
 340 lp_r12 = max(case_th_lid - (lpp11[1] - lpp15[1]),
 341              case_th_lip);
 342
 343 lpp12 = [ epp4[0] + lp_r12,    lpp11[1] ];
 344 lpp13 = [ lpp12[0],            lpp12[1] + lp_r12 ];
 345
 346 case_bottom_z = epp2o[1] - case_th_bottom;
 347
 348 // button profile
 349 bppM = epp4 + [0,5];
 350 bppN = [ bppM[0] + lid_buttoncover_thick, bppM[1] ];
 351 bppR = [ bppN[0] + lid_buttoncover_gap, -button_cutout_depth ];
 352 bppS = [ epp1[0], bppR[1] ];
 353 bppQ = [ bppM[0], bppR[1] - lid_buttoncover_overlap ];
 354 bppP = bppQ + [0,1] * lid_buttoncover_gap;
 355 bppO = [ bppN[0], bppP[1] ];
 356 bppL = lpp10 + [5,0];
 357 bppK = [ bppL[0], bppN[1] ];
 358 bppJ = [ bppN[0], bppL[1] ];
 359 bppU = [ bppJ[0], lpp12[1] ];
 360 bppV = lpp11;
 361 bppW = lpp10;
 362
 363 echo("BUTTON COVER TH", bppO[0] - bppP[0]);
 364
 365 // notification led aperture
 366
 367 nla_r0 = led_aperture/2;
 368 nla_r1 = nla_r0 + led_window_ledge;
 369 nla_r2 = nla_r1 + multicolour_gap;
 370 nla_t =
 371   led_window_style >= 3 ? initial_layer_thick :
 372   led_window_style >= 2 ? led_window_ledge : 0;
 373
 374
 375 // hinge plan
 376 hp_rn = hingescrew_nut_access_dia/2;
 377 hp_r2_min = hp_rn + lever_cover_th;
 378 hp_rs = hingescrew_shaft_dia/2;
 379 hp_r1_min = hp_rs + hingemount_th;
 380
 381 hp_r1 = max(hp_r1_min, hp_r2_min);
 382 hp_r2 = hp_r1;
 383
 384 hppU = lpp13;
 385 hppS = epp2o + [0,-1] * case_th_bottom;
 386 hp_k = 0.5 * (hppU[1] - hppS[1] + foldover_gap);
 387
 388 hppM = [ epp4[0] - foldover_lever_gap - hp_r2,
 389          0.5 * (hppU + hppS)[1] ];
 390 hppT = [ hppM[0], hppU[1] - hp_r1 ];
 391 hppB = hppT + [0,-1] * hp_k;
 392
 393 hppE_y = epp2o[1] - case_th_bottom + hp_r1;
 394 hppE_x = hppB[0] + (hppB[1] - hppE_y) * hinge_base_slope;
 395 hppE = [ hppE_x, hppE_y ];
 396
 397 // hinge elevation x coords
 398
 399 hex20 = max(epp2o[0],
 400             phone_cnr_rad,
 401             kppd[0] + hingescrew_head_th + keeper_gap_x_holes);
 402 hex21 = hex20 + hingemount_wd;
 403 hex22 = hex21 + hinge_x_gap;
 404 hex27 = hex20 + hingescrew_shaft_len;
 405 hex24 = hex27 + hinge_x_postscrew_gap;
 406 hex23 = hex27 - (hingescrew_nut_thick*2
 407                  + hingescrew_fasteners_extra_thick);
 408 hex26 = hex23 + hingescrew_nut_thick * 2/3;
 409
 410 echo(hex20, hex21, hex22, hex23, hex24);
 411 //  6, 10.8725, 10.9975, 13.74, 18.75
 412 module chk(act,exp) {
 413   if (abs(act-exp) > 1e-9) echo("WRONG", act, exp);
 414   else echo("ok", act);
 415 }
 416 chk(hex20, 6);
 417 chk(hex21, 10.8725);
 418 chk(hex22, 10.9975);
 419 chk(hex23, 13.74);
 420 chk(hex24, 18.75);
 421
 422 lid_fold_clearance_skew =
 423   (lpp10[1] - hppB[1]) /
 424   (lpp10[0] - hppB[0]);
 425
 426 echo("SK",lid_fold_clearance_skew);
 427
 428 // thumb recess (used to be "catch" hence cpp*
 429
 430 cppA = epp4 + [thumbrecess_depth, 0];
 431 cppB = [ cppA[0], epp1[1] ];
 432
 433 // lanyard
 434
 435 ly_r = lanyard_half_dia / 2;
 436 ly_rc = ly_r * 2;
 437
 438 ly_theta = 90;
 439 ly_o = epp2i + 3 * ly_r * [0,1];
 440
 441 max_case_bottom_edge_thickness =
 442   case_th_bottom;
 443
 444 ly_q_z = -(ly_rc + ly_r);
 445 ly_re = max_case_bottom_edge_thickness - (-ly_q_z);
 446
 447 ly_oec_y = lanyard_entry_rel_breadth * ly_r;
 448
 449 // prop recess in case
 450
 451 prop_x_pos = phone_width/2;
 452
 453 prop_recess_hw = 0.5 * prop_main_width + prop_side_gap;
 454
 455 prc_r1 = prop_end_dia/2;
 456 prc_r3 = prc_r1 + prop_recess_slop;
 457
 458 prcp2 = [ epp4[0] + prop_buildout_less,
 459           case_bottom_z ];
 460
 461 prop_caserecess_buildout_r = -1; // prcp2[0] - epp2o[0];
 462
 463 prcp1 = [ epp2o[0] + prc_r3 + prop_caserecess_behind,
 464           epp2i[1] - prc_r3 - prop_recess_under];
 465
 466 // prop recess in lid
 467
 468 prl_r10 = prop_end_dia/2;
 469 prl_r10o = prl_r10 + prop_recess_slop;
 470
 471 prlp10 = lpp10 + [1,1] * prl_r10o
 472   + [1,0] * prop_lidrecess_behind
 473   + [0,1] * prop_recess_under;
 474
 475 // prop
 476
 477 $prpp10 = [0,0];
 478 $prpp11 = [0, prop_taper_len];
 479
 480 $prp_r10 = prl_r10;
 481
 482 // ---------- modules ----------
 483
 484 module AdhocMultiprintFrame(phase, z0, zs) {
 485   // from z0 to z0 + zs*layer
 486   extra = phase * (initial_layer_width + multicolour_gap) + 5;
 487   xextra = extra + -epp4[0];
 488   xrange = [ 0, phone_width ] + [-1,+1] * xextra;
 489   yextra = extra + -epp4[0];
 490   yrange = [ -phone_height + +hppB[0] - hp_r2, 0 ] + [-1,+1] * yextra;
 491   p0 = [ xrange[0], yrange[0] ];
 492   p1 = [ xrange[1], yrange[1] ];
 493   echo(p0, p1);
 494   translate([0,0, z0])
 495     mirror([0,0, zs<0 ? 1 : 0])
 496     linear_extrude(height= initial_layer_thick)
 497     difference(){
 498       rectfromto(p0 - [1,1] * initial_layer_width,
 499                  p1 + [1,1] * initial_layer_width);
 500       rectfromto(p0, p1);
 501     }
 502 }
 503
 504 module KeeperProfile(slant=0){
 505   use_e = kppe + [0,-1] * slant * keeper_inner_width / keeper_slant_slope;
 506   polygon([use_e, kppd, kppc, kppb, kppa, kppf]);
 507 }
 508
 509 module EdgeProfile(){
 510   difference(){
 511     hull(){
 512       translate(epp3) square(case_th_bottom*2, center=true);
 513       circleat(epp2o, r=case_th_bottom);
 514       circleat(epp1, r=case_th_side);
 515       rectfromto(epp0, epp4);
 516     }
 517     polygon([ epp5 + [0,10],
 518               epp1,
 519               epp3 + [10,0] ]);
 520   }
 521 }
 522
 523 module LanyardLanyardProfile(entry=false){
 524   hull(){
 525     for (xs=[-1,+1] * (entry ? lanyard_entry_rel_breadth : 1))
 526       translate(xs * 0.5 * lanyard_half_dia * [1,0])
 527         circle(r= lanyard_half_dia/2);
 528   }
 529 }
 530
 531 module LanyardCurveChannelProfile(){
 532   translate([0, -ly_r])
 533     LanyardLanyardProfile();
 534 }
 535
 536 module LanyardEntryChannelProfile(){
 537   LanyardLanyardProfile(true);
 538 }
 539
 540 module LanyardMainChannelProfile(){
 541   LanyardCurveChannelProfile();
 542   difference(){
 543     square(center=true, ly_r * [6, 2]);
 544     for (xs=[-1,+1])
 545       translate(ly_r * [3 * xs, -1])
 546         circle(r = ly_r);
 547   }
 548 }
 549
 550 module LanyardEntryOuterProfile(){
 551   circleat([ly_re + ly_r, 0], ly_re);
 552 }
 553
 554 module LanyardEntry(){
 555   q_z = ly_q_z;
 556   oec_y = ly_oec_y;
 557
 558   d_x = -ly_rc;
 559
 560   translate([d_x, 0, q_z]) {
 561     intersection(){
 562       rotate([90,0,0])
 563         rotate_extrude(convexity=10)
 564         rotate(90)
 565         translate([0, -q_z])
 566         LanyardCurveChannelProfile();
 567       translate([0,-10,0])
 568         cube([20,20,20]);
 569     }
 570   }
 571
 572   mirror([0,0,1])
 573     translate([0,0,-1])
 574     linear_extrude(height=20)
 575     rotate(-90)
 576     LanyardEntryChannelProfile();
 577
 578   translate([0, ly_r*2, 0])
 579     rotate([90,0,0])
 580     linear_extrude(height = ly_r*4){
 581     difference(){
 582       rectfromto([d_x, q_z], [ly_r, 0]);
 583       circleat([d_x, q_z], ly_rc);
 584     }
 585   }
 586
 587   translate([0,0,q_z]){
 588     for (my=[0,1])
 589       mirror([0,my,0]){
 590         translate([0, oec_y, 0]){
 591           difference(){
 592             translate(ly_re * [-1,0,-2])
 593               cube(ly_re * [2,1,2]);
 594             rotate_extrude(convexity=10)
 595               LanyardEntryOuterProfile();
 596           }
 597         }
 598       }
 599     difference(){
 600       translate([-ly_re, -(oec_y + 0.01), -2*ly_re])
 601         cube([ly_re*2, 2*(oec_y + 0.01), 2*ly_re]);
 602       for (mx=[0,1])
 603         mirror([mx,0,0])
 604           rotate([90,0,0])
 605           translate([0,0,-10])
 606           linear_extrude(height=20)
 607           LanyardEntryOuterProfile();
 608     }
 609   }
 610 }
 611
 612 module LanyardCutout(l){
 613   rotate([0,-90,0])
 614     linear_extrude(height=l)
 615     rotate(-90)
 616     LanyardMainChannelProfile();
 617
 618   for (ee=[0,1]){
 619     translate(ee * l * [-1,0])
 620       mirror([ee,0,0])
 621       LanyardEntry();
 622   }
 623 }
 624
 625 module LidEdgeProfile(){
 626   polygon([ lpp10,
 627             lpp11,
 628             lpp12,
 629             lpp13,
 630             lpp13 + [10, 0],
 631             lpp15 + [10, 0],
 632             lpp15,
 633             lpp14,
 634             ]);
 635   intersection(){
 636     circleat(lpp12, r=lp_r12);
 637     rectfromto( lpp12 + [-10,   0],
 638                 lpp12 + [+10, +10] );
 639   }
 640 }
 641
 642 module LidEdgeFoldClearanceProfile(){
 643   translate([-lid_fold_clearance_antislop, 0])
 644     polygon([ lpp10,
 645               lpp11,
 646               lpp11 + [-20,  0],
 647               lpp11 + [-20, 20],
 648               lpp11 + [+20, 20],
 649               lpp10 + [+20,  0] ]);
 650 }
 651
 652 module ButtonCoverProfile(){
 653   intersection(){
 654     polygon(concat([ bppM, bppP, bppO, bppJ ],
 655                    (enable_support && !$button_suppress_over_keeper
 656                     ? [ bppU, bppV, bppW ] : []),
 657                    [ bppL, bppK ]));
 658     hull(){
 659       EdgeProfile();
 660       LidEdgeProfile();
 661     }
 662   }
 663 }
 664
 665 module ButtonPlan(l, deep, cut){
 666   epsilon =
 667     (cut  ? 0 : lid_buttoncover_gap);
 668
 669   delta =
 670     (deep ? lid_buttoncover_overlap : 0);
 671
 672   C = [0,0]; // by definition
 673   T = [ 0, epp4[1] ];
 674   G = T + [0,10];
 675
 676   B0 = C + [0,-1] * button_cutout_depth;
 677   B1 = B0 + [0,1] * epsilon;
 678
 679   r0 = 0.5 * (T[1] - B0[1]);
 680   A = [  -(l + button_l_fudge)/2 + r0, 0.5 * (T[1] + B0[1]) ];
 681   H = A + [0,-1] * delta;
 682
 683   D = A + [-2,0] * r0;
 684   F = D + [0,10];
 685
 686   E0 = 0.5 * (D + A);
 687   E1 = E0 + [1,0] * epsilon;
 688
 689   I0 = [ E0[0], H[1] ];
 690   I1 = [ E1[0], H[1] ];
 691
 692   hull(){
 693     for (m=[0,1]) mirror([m,0])
 694       circleat(H, r0 - epsilon);
 695   }
 696   for (m=[0,1]) mirror([m,0]) {
 697     difference(){
 698       polygon([ E1,
 699                 I1,
 700                 H,
 701                 B1,
 702                 G,
 703                 F,
 704                 D
 705                 ]);
 706       circleat(D, r0 + epsilon);
 707     }
 708   }
 709 }
 710
 711 module ButtonCoverReinf(){ ////toplevel
 712   minkowski(){
 713     rotate([90,0,0])
 714       linear_extrude(height=0.01)
 715       intersection(){
 716         ButtonCoverProfile();
 717         translate([bppJ[0] + 0.1, -50]) mirror([1,0])
 718           square([100,100]);
 719     }
 720     mirror([0,0,1]) linear_extrude(height=0.01) intersection(){
 721       circle(r= lid_buttoncover_reinf);
 722       translate([-20,0]) square(40, center=true);
 723     }
 724   }
 725 }
 726
 727 module ThumbRecessCutProfile(){
 728   difference(){
 729     polygon([ cppA + [-10,0],
 730               cppB + [-10,0],
 731               cppB,
 732               cppA ]);
 733     circleat(epp1, r=case_th_side);
 734   }
 735 }
 736
 737 module Flip_rhs(yn=[0,1]) {
 738   for ($rhsflip=yn) {
 739     translate([phone_width/2, 0, 0])
 740       mirror([$rhsflip,0,0])
 741       translate([-phone_width/2, 0, 0])
 742       children();
 743   }
 744 }
 745
 746 module Flip_bot(yn=[0,1]) {
 747   for ($botflip=yn) {
 748     translate([0, -phone_height/2, 0])
 749       mirror([0, $botflip, 0])
 750       translate([0, phone_height/2, 0])
 751       children();
 752   }
 753 }
 754
 755 module AroundEdges(fill_zstart, fill_th, fill_downwards=0){
 756   // sides
 757   Flip_rhs(){
 758     translate([0, -phone_cnr_rad, 0])
 759       rotate([90,0,0])
 760       linear_extrude(height = phone_height - phone_cnr_rad*2)
 761       children(0);
 762   }
 763   // corners
 764   Flip_rhs() Flip_bot() {
 765     translate([+1,-1] * phone_cnr_rad)
 766       intersection(){
 767         rotate_extrude()
 768           intersection(){
 769             mirror([1,0,0])
 770               translate([-1,0] * phone_cnr_rad)
 771               children(0);
 772             rectfromto([0,-20],[10,20]);
 773           }
 774         translate([-10, 0, -20] + 0.01 * [+1,-1, 0] )
 775           cube([10,10,40]);
 776       }
 777   }
 778   // top and bottom
 779   Flip_bot(){
 780     translate([ phone_width - phone_cnr_rad, 0,0 ])
 781       rotate([90,0,-90])
 782       linear_extrude(height = phone_width - phone_cnr_rad*2)
 783       children(0);
 784   }
 785   // fill
 786   translate([0,0, fill_zstart])
 787     mirror([0,0, fill_downwards])
 788     linear_extrude(height = fill_th)
 789     rectfromto([+1,-1] * phone_cnr_rad,
 790                [phone_width, -phone_height] + [-1,+1] * phone_cnr_rad);
 791 }
 792
 793 module CaseAperture(pos, dia, $fn, topbottom=0) {
 794   theta = 180/$fn;
 795   translate([ bumper[0],
 796               -epp2i[0],
 797                0 ])
 798     rotate([0,0, 90*topbottom])
 799     translate([ pos[0] * (topbottom>0 ? -1 : +1), 0, -pos[1] ])
 800     rotate([-90, theta, 0])
 801     cylinder(r = dia/2 / cos(theta),
 802              h = 60);
 803 }
 804
 805 module SideButton(y, y_ref_sign, l, suppress_over_keeper=0){
 806   // y_ref_sign:
 807   //   +1  measured from top    of actual phone to top    of button
 808   //   -1  measured from bottom of actual phone to bottom of button
 809   //    0  y is centre of button in coordinate system
 810   $button_l= l;
 811   $button_suppress_over_keeper= suppress_over_keeper;
 812   eff_y = y_ref_sign > 0 ?         -bumper [1] -y -l/2 :
 813           y_ref_sign < 0 ? (-phone -bumper)[1] +y +l/2 :
 814           y;
 815   //echo(eff_y);
 816   translate([0, eff_y, 0])
 817     children();
 818 }
 819
 820 module LidButtonishLeg(y, y_ref_sign, l=buttonishleg_default_l_is_fudge) {
 821   $button_leg_only = true;
 822   SideButton(y, y_ref_sign, l) children();
 823 }
 824
 825 module Buttons(){
 826   Flip_rhs(1) SideButton(30.320, +1, 22.960  ) children(); // volume
 827   Flip_rhs(1) SideButton(64.220, +1, 14.500  ) children(); // power
 828   Flip_rhs(1) LidButtonishLeg(14, -1) children();
 829   Flip_rhs(0) LidButtonishLeg(21, -1) children();
 830   Flip_rhs(0) LidButtonishLeg(14, +1) children();
 831   // xxx need hole for whatever that hole is on lhs
 832 }
 833
 834 module Struts(x_start, z_min, th){
 835   // if th is negative, starts at z_min and works towards -ve z
 836   // and object should then be printed other way up
 837   for (i= [1 : 1 : case_struts_count]) {
 838     translate([0,
 839                0,
 840                z_min])
 841       mirror([0,0, th<0 ? 1 : 0])
 842       translate([0,
 843                  -phone_height * i / (case_struts_count+1),
 844                  case_struts_solid_below])
 845       linear_extrude(height= abs(th)
 846                      -(case_struts_solid_below+case_struts_solid_above))
 847       rectfromto([               x_start, -0.5 * case_struts_width ],
 848                  [ phone_width - x_start, +0.5 * case_struts_width ]);
 849   }
 850 }
 851
 852 module OrdinaryRearAperture(rhs,bot, pos){
 853   Flip_rhs(rhs) Flip_bot(bot)
 854     linextr(-20, 20)
 855     mirror([0,1])
 856     translate(pos + bumper)
 857     children();
 858 }
 859
 860 module MicroUSB(){
 861   Flip_bot(1){
 862     rotate([90,0,0])
 863       mirror([0,0,1])
 864       linextr(-epp2i[0], 60)
 865       translate([0.5 * phone_width, 0, 0])
 866       rectfromto([-microusb_width/2, epp2i[1] + microusb_below],
 867                  [+microusb_width/2, epp0[1] + -microusb_above]);
 868   }
 869 }
 870
 871 module OrdinaryRearApertures(){
 872   // rear speaker
 873   OrdinaryRearAperture(1,1, rearspeaker_pos_bl)
 874     rectfromto(-rearspeaker_gap,
 875                rearspeaker_size + rearspeaker_gap);
 876
 877   // finger hole to remove phone
 878   if (len(fingerpushhole_dias))
 879     OrdinaryRearAperture(1,0, [ fingerpushhole_dias[0]/2 + epp2i[0],
 880                                 phone[1]/2 ])
 881     scale(fingerpushhole_dias)
 882     circle(r= 0.5 );
 883 }
 884
 885 module RearCameraAperture(){
 886   Flip_rhs(1)
 887     mirror([0, 0, 1])
 888     linear_extrude(height = 20)
 889     mirror([0, 1, 0])
 890     translate(bumper)
 891     rectfromto(camera_pos_tl, camera_pos_br);
 892 }
 893
 894 module HingeLidProfile(){
 895   hull(){
 896     circleat(hppT, hp_r1);
 897     circleat(lpp12, lp_r12);
 898     polygon([lpp10,
 899              lpp13 + [2,0],
 900              lpp12,
 901              hppT]);
 902   }
 903 }
 904
 905 module HingeBaseProfile(){
 906   difference(){
 907     hull(){
 908       circleat(hppB, hp_r1);
 909       circleat(hppE, hp_r1);
 910       circleat(epp2o, case_th_bottom);
 911       circleat(hppB + [10,0], hp_r1);
 912     }
 913     polygon([epp5, epp1, epp3, bppL]);
 914   }
 915 }
 916
 917 module HingeLeverOuterProfile(){
 918   hull(){
 919     circleat(hppT, hp_r2);
 920     circleat(hppB, hp_r2);
 921   }
 922 }
 923
 924 module HingeLeverInnerProfile(){
 925   for (s = [-1,+1]) {
 926     c = s > 0 ? hppT : hppB;
 927     translate(c)
 928       mirror([0,0, s>0 ? 1 : 0])
 929       rotate(s<0 ? -40 : 0)
 930       hull()
 931       for (x=[-20,20])
 932         for (y=[0, s * 10])
 933           translate([x,y])
 934             circle(hp_rn);
 935   }
 936 }
 937
 938 module HingeLeverNutProfile(){
 939   for (c= [hppB, hppT]) {
 940     translate(c)
 941       circle($fn=6, r= 0.5 * hingescrew_nut_across / cos(30));
 942   }
 943 }
 944
 945 module Flip_hinge(doflip=1){
 946   hinge_origin = [0, -(phone_height - hppB[0]), hppB[1]];
 947   translate(hinge_origin)
 948     rotate([doflip*180,0,0])
 949     translate(-hinge_origin)
 950     children();
 951 }
 952
 953 module HingePortion(x0,x1){
 954   Flip_rhs() Flip_bot(1)
 955     translate([x0,0,0])
 956     mirror([1,0,0])
 957     rotate([90,0,-90])
 958     linear_extrude(height=x1-x0)
 959     children();
 960 }
 961
 962 module ThumbRecessApply(ztop){
 963   width = thumbrecess_width;
 964   w = width + thumbrecess_topcurve_r*2 + 1;
 965   translate([phone_width/2, 0,0]){
 966     difference(){
 967       rotate([90,0,-90])
 968         linextr(-w/2, w/2)
 969         children(0);
 970       translate([0, 50, 0])
 971         rotate([90,0,0])
 972         linear_extrude(height=100){
 973         for (m=[0,1]) mirror([m,0,0]) {
 974           hull(){
 975             translate([w/2, ztop - thumbrecess_topcurve_r])
 976               circle(thumbrecess_topcurve_r);
 977             translate([w/2, -50])
 978               square(thumbrecess_topcurve_r*2, center=true);
 979           }
 980         }
 981       }
 982     }
 983   }
 984 }
 985
 986 module CaseBase(){
 987   AroundEdges(epp3[1], case_th_bottom, 1)
 988     EdgeProfile();
 989 }
 990
 991 function prop_x(gamma) = hp_k / (2 * sin(gamma/2)) - hppT[0];
 992
 993 module PropProfileAssignments(gamma){
 994   // https://en.wikipedia.org/wiki/Solution_of_triangles#Two_sides_and_the_included_angle_given_(SAS)
 995   x = prop_x(gamma);
 996   p = phone_height + prlp10[0] - hppB[0];
 997   b = p + x;
 998
 999   q = phone_height - hppT[0] - prcp1[0]; // $prpp7[0] is 0 by definition
1000   a = q + x;
1001   c = sqrt(a*a + b*b - 2*a*b*cos(gamma));
1002   $prp_alpha = acos( (b*b + c*c - a*a) / (2*b*c) );
1003
1004   $prp_theta = 90 - $prp_alpha;
1005   beta = 180 - $prp_alpha - gamma;
1006   psi = 90 - beta;
1007
1008   //echo("abc", a,b,c);
1009
1010   v1 = [ [ cos(psi), -sin(psi) ],    // x
1011          [ sin(psi),  cos(psi) ] ];  // y
1012
1013   $prpp7 = [0, c + (lpp13[1] - $prpp10[1] - hp_k) ];
1014
1015   $prp_r1 = prc_r1;
1016   $prp_r11 = prop_main_th/2;
1017
1018   $prpp1 = $prpp7 + [1,0] *
1019     // this is approximate, but will do
1020     (prop_main_th/2 + prop_prop_gap + prcp1[0] - cppA[0]);
1021   $prpp3 = $prpp1 +
1022     v1[0] * -$prp_r1 +
1023     v1[1] * ((prcp2[1] - prcp1[1]) - prop_prop_gap);
1024   $prpp12 = $prpp3 + v1[0] *
1025     (prop_end_dia + prop_caserecess_taper * ($prpp1[1] - $prpp3[1]));
1026   $prp_r8 = prop_main_th;
1027   $prpp4 = [ prop_main_th/2, $prpp3[1] ];
1028   $prp_r5 = $prp_r8;
1029   $prpp5 = [ $prpp12[0] - $prp_r5,
1030             $prpp3[1] - prop_prong_h + $prp_r5 ];
1031   $prpp6 = $prpp4 + [0,-1] * (prop_prong_h +
1032          prop_prong_heel_slope * ($prpp5[0] - $prpp4[0]));
1033   $prpp8 = $prpp4 + [0,-1] * $prp_r8;
1034   $prpp9 = $prpp8 + [-1,0] * $prp_r8;
1035
1036   children();
1037 }
1038
1039 module PropProfile(gamma, cut=0, rot=0){
1040   PropProfileAssignments(gamma){
1041
1042     //#circleat($prpp3,1);
1043     //#circleat($prpp12,1);
1044
1045     if (!cut) {
1046       hull(){
1047         translate($prpp8)
1048           intersection(){
1049             circle($prp_r8);
1050             polygon([[-20,-0], [20,20], [0,0]]);
1051           }
1052         rectfromto($prpp6, $prpp9);
1053         translate($prpp5) intersection(){
1054           circle($prp_r5);
1055           polygon([[-10,-10], [0,0], [10,0]]);
1056         }
1057         rectfromto($prpp12 + [0,-0.1], $prpp3);
1058       }
1059       hull(){
1060         circleat($prpp1, $prp_r1);
1061         rectfromto($prpp12 + [0,-0.1], $prpp3);
1062       }
1063     }
1064     // main shaft
1065     rotate([0,0, rot*-$prp_theta]){
1066       hull(){
1067         extra = cut ? prop_recess_slop : 0;
1068         rectfromto($prpp6, $prpp9);
1069         circleat($prpp11, $prp_r11 + extra);
1070         circleat($prpp10, $prp_r10 + extra);
1071       }
1072     }
1073   }
1074 }
1075
1076 module PropAggregateProfile(){
1077   for (angle = prop_angles)
1078     PropProfile(angle, 0,0);
1079 }
1080
1081 module Prop(){ ////toplevel
1082   hw = prop_main_width/2;
1083   linextr(-hw, +hw)
1084     PropAggregateProfile();
1085 }
1086
1087 module Case(){ ////toplevel
1088   difference(){
1089     union(){
1090       CaseBase();
1091
1092       // ledge (fixed keeper)
1093       Flip_rhs(1-keeper_side) intersection(){
1094         rotate([90, 0, 0])
1095           linear_extrude(height = phone_height + phone_cnr_rad * 2)
1096           KeeperProfile(1);
1097
1098         // outline of the whole case, to stop it protruding
1099         translate([0,0, -25])
1100           linear_extrude(height = 50)
1101           hull()
1102           Flip_bot()
1103           circleat([+1,-1] * phone_cnr_rad, phone_cnr_rad + case_th_side/2);
1104       }
1105
1106       // hinge
1107       HingePortion(hex20, hex21) HingeBaseProfile();
1108
1109       // buildout for prop recess
1110       if (prop_caserecess_buildout_r > 0) Flip_rhs(1)
1111         linextr(case_bottom_z, epp2i[1])
1112         hull() {
1113           for (dxs = [-1,+1])
1114             circleat([ prop_x_pos + dxs * prop_caserecess_buildout_r,
1115                        -epp2o[0] ],
1116                      r = epp2o[0] - prcp2[0]);
1117         }
1118     }
1119
1120     // slot for keeper
1121     Flip_rhs(keeper_side)
1122       translate([0, -phone_cnr_rad, 0])
1123       rotate([90, 0, 0])
1124       linear_extrude(height = phone_height + phone_cnr_rad * 2)
1125       minkowski(){
1126         KeeperProfile();
1127         rectfromto([ -keeper_gap_x,    -keeper_gap_z_bot ],
1128                    [ keeper_gap_x_holes,    +keeper_gap_z_top ]);
1129       }
1130
1131     // front camera
1132     RearCameraAperture();
1133
1134     // struts (invisible, because they're buried in the case)
1135     Struts(epp2i[0], epp2i[1] - case_th_bottom, case_th_bottom);
1136
1137     Buttons(){
1138       mirror([1,0,0])
1139         rotate([90,0,90]) {
1140           if (!($button_leg_only && enable_support))
1141           intersection(){
1142             translate([0,0,-10])
1143               linear_extrude(height= 20)
1144               ButtonPlan($button_l, 0,1);
1145             if ($button_leg_only)
1146               rotate([-90,90,0])
1147                 translate([phone_width/2, -400, kppe[1]])
1148                 mirror([1-abs($rhsflip - keeper_side),0,0])
1149                 cube([400, 800, 50]);
1150             if (enable_support && !$button_suppress_over_keeper)
1151               rotate([-90,90,0])
1152               translate([-400, -400, kppd[1]])
1153                 mirror([0,0,1])
1154                 cube([800,800,100]);
1155           }
1156           translate([0,0, -bppR[0]])
1157             linear_extrude(height= 20)
1158             ButtonPlan($button_l, 1,1);
1159         }
1160
1161     }
1162
1163     // apertures along top edge
1164     if (!$suppress_forward_holes) {
1165       // CaseAperture(jack_pos, jack_dia, 8);
1166       Flip_rhs(1)
1167         CaseAperture(noisecancelmic_pos, noisecancelmic_dia, 8);
1168       CaseAperture(lhshole_pos, noisecancelmic_dia, 8, 1);
1169     }
1170
1171     OrdinaryRearApertures();
1172
1173     MicroUSB();
1174
1175     // gaps for the lid's hinge arms
1176     HingePortion(hex20 - hinge_x_arms_gap,
1177                  hex21 + hinge_x_arms_gap)
1178       minkowski(){
1179         HingeLidProfile();
1180         circle(r= hinge_r_arms_gap, $fn= 8);
1181       }
1182
1183     // screw holes in the hinge arms
1184     HingeScrews();
1185
1186     // thumb recess
1187     ThumbRecessApply(epp4[1])
1188       ThumbRecessCutProfile();
1189
1190     // lanyard
1191     Flip_bot(1)
1192       translate([ly_o[0], -(phone_cnr_rad + ly_re), ly_o[1]])
1193       rotate([0, ly_theta, 0])
1194       rotate([0,0,90])
1195       LanyardCutout(lanyard_channel_len);
1196
1197     // prop recess
1198     Flip_rhs(1)
1199       translate([prop_x_pos,0,0])
1200       mirror([0,1,0])
1201       rotate([90,0,90])
1202       linextr(-prop_recess_hw, +prop_recess_hw)
1203       hull(){
1204         for (d=[ [0,0], [0,-1], [+1,-1/prop_caserecess_taper] ])
1205           circleat(prcp1 + 20*d,
1206                    prc_r3);
1207       }
1208   }
1209 }
1210
1211 module LidAdhocMultiprintFrame(phase){
1212   if (led_window_style >= 3) {
1213     AdhocMultiprintFrame(phase, lpp13[1], -1);
1214   }
1215 }
1216
1217 module LidAroundEdges(){
1218   AroundEdges(lpp15[1], lpp13[1] - lpp15[1], 0)
1219     children();
1220 }
1221
1222 module Lid(){ ////toplevel
1223   skew_centre = [0, lpp11[0], lpp11[1]];
1224   difference(){
1225     union(){
1226       intersection(){
1227         LidAroundEdges()
1228           LidEdgeProfile();
1229
1230         translate(skew_centre)
1231           multmatrix([[ 1, 0, 0, 0 ],
1232                       [ 0, 1, -lid_fold_clearance_skew, 0 ],
1233                       [ 0, 0, 1, 0 ],
1234                       [ 0, 0, 0, 1 ]])
1235           translate(-skew_centre)
1236           LidAroundEdges()
1237           LidEdgeFoldClearanceProfile();
1238       }
1239
1240       // button covers
1241       Buttons(){
1242         intersection(){
1243           rotate([90,0,90])
1244             translate([0,0,-10])
1245             linear_extrude(height= 20)
1246             ButtonPlan($button_l, 1,0);
1247           union(){
1248             rotate([90,0,0])
1249               translate([0,0,-100])
1250               linear_extrude(height= 200)
1251               ButtonCoverProfile();
1252             hull()
1253               for (y= [-1,+1] * (($button_l + button_l_fudge)/2
1254                                  - lid_buttoncover_reinf))
1255                 translate([0,y,0])
1256                   ButtonCoverReinf();
1257           }
1258         }
1259       }
1260
1261       // hinge arms
1262       HingePortion(hex20, hex21) {
1263         LidEdgeProfile();
1264         HingeLidProfile();
1265       }
1266     }
1267     Struts(lpp10[0] + strut_min_at_end, lpp13[1], -case_th_lid);
1268
1269     // screw holes in the hinge arms
1270     HingeScrews();
1271
1272     // prop recess
1273     translate([prop_x_pos, -prlp10[0], prlp10[1]])
1274       mirror([0,1,0])
1275       rotate([90,0,90])
1276       linextr(-prop_recess_hw, +prop_recess_hw)
1277       hull()
1278       for (pa = prop_angles)
1279         PropProfile(pa, 1,1);
1280
1281     // notification led aperture
1282     if (led_window_style)
1283       translate([led_pos[0], -led_pos[1], lpp13[1]]) {
1284         translate([0,0,-10])
1285           cylinder(r=nla_r0, h=20);
1286         if (led_window_style >= 2)
1287           translate([0,0, -nla_t])
1288             cylinder(r=nla_r2, height=20);
1289       }
1290
1291     }
1292
1293   LidAdhocMultiprintFrame(1);
1294 }
1295
1296 module HingeLever(){ ////toplevel
1297   difference() {
1298     // outer body, positive
1299     HingePortion(hex22, hex22 + phone_width/2)
1300       HingeLeverOuterProfile();
1301
1302     // space for the screws
1303     HingePortion(hex26, hex24)
1304       HingeLeverInnerProfile();
1305
1306     // recesses for the nuts
1307     HingePortion(hex23, hex26+1)
1308       HingeLeverNutProfile();
1309
1310     // bores for the screws
1311     HingeScrews();
1312
1313     // space for the charging cable
1314     MicroUSB();
1315     Flip_hinge() MicroUSB();
1316   }
1317 }
1318
1319 module LidWindow(){ ////toplevel
1320   translate([led_pos[0], -led_pos[1], lpp13[1]])
1321     mirror([0,0,1])
1322     cylinder(r= nla_r1, h=nla_t);
1323   LidAdhocMultiprintFrame(0);
1324 }
1325
1326 module LidWindowPrint(){ ////toplevel
1327   rotate([0,180,0])
1328     LidWindow();
1329 }
1330
1331 module DemoLidWindowSelect(){
1332   translate([led_pos[0], led_pos[1], -100]) {
1333     translate([0, -30, 0]) cube([400, 400, 200]);
1334   }
1335 }
1336
1337 module DemoLidWindow(){ ////toplevel
1338   %Lid();
1339   LidWindow();
1340   translate([0,40,0]){
1341     color("blue") intersection(){ Lid(); DemoLidWindowSelect(); }
1342     color("red") intersection(){ LidWindow(); DemoLidWindowSelect(); }
1343   }
1344 }
1345
1346 module HingeLeverPrint(){ ////toplevel
1347   rotate([-90,0,0])
1348     translate([-phone_width/2, phone_height, 0])
1349     HingeLever();
1350 }
1351
1352 module TestSelectLength(){
1353   translate([-30, -200, -20])
1354     cube([30 + 15, 250, 40]);
1355 }
1356
1357 module TestLength(){ ////toplevel
1358   intersection(){
1359     Case();
1360     TestSelectLength();
1361   }
1362 }
1363
1364 module TestLengthRight(){ ////toplevel
1365   intersection(){
1366     Case();
1367     Flip_rhs(1)
1368       TestSelectLength();
1369   }
1370 }
1371
1372 module TestSelectWidth(){
1373   translate([-30, -(phone_height - 25), -20])
1374     mirror([0, 1, 0])
1375     cube([200, 50, 40]);
1376 }
1377
1378 module TestWidth(){ ////toplevel
1379   intersection(){
1380     Case();
1381     TestSelectWidth();
1382   }
1383 }
1384
1385 module TestLidWidthPrint(){ ////toplevel
1386   rotate([0,180.0]) intersection(){
1387     Lid();
1388     TestSelectWidth();
1389   }
1390 }
1391
1392 module TestSelectRearAperture(){
1393   minkowski(){
1394     union() children();
1395     translate([20, 0,0])
1396       cube([42, 2, 1], center=true);
1397   }
1398 }
1399
1400 module TestSelectCamera(){
1401   minkowski(){
1402     TestSelectRearAperture()
1403       RearCameraAperture();
1404     cube([0.1, 50, 0.1]);
1405   }
1406 }
1407
1408 module TestSelectOrdinaryRearApertures(){
1409   TestSelectRearAperture()
1410     OrdinaryRearApertures();
1411 }
1412
1413 module TestCamera(){ ////toplevel
1414   intersection(){
1415     Case();
1416     TestSelectCamera();
1417   }
1418 }
1419
1420 module TestLidByCamera(){ ////toplevel
1421   intersection(){
1422     Lid();
1423     TestSelectCamera();
1424   }
1425 }
1426
1427 module TestLidByCameraPrint(){ ////toplevel
1428   rotate([180,0,0]) TestLidByCamera();
1429 }
1430
1431 module DemoByCamera(){ ////toplevel
1432   color("blue") TestLidByCamera();
1433   color("red")  TestCamera();
1434 }
1435
1436 module OneKeeper(){ ////toplevel
1437   translate([0, -phone_cnr_rad, 0])
1438     rotate([90, 0, 0])
1439     linear_extrude(height = phone_height - phone_cnr_rad * 2)
1440     KeeperProfile();
1441 }
1442
1443 module OneKeeperPrint(){ ////toplevel
1444   rotate([0,180,0])
1445     OneKeeper();
1446 }
1447
1448 module LidPrint(){ ////toplevel
1449   rotate([0,180,0])
1450     Lid();
1451 }
1452
1453 module TestSelectFrame(){
1454   include = [1,-1] * (epp2i[0] + 4);
1455
1456   difference(){
1457     cube(1000, center=true);
1458     translate([0,0, -100])
1459       linear_extrude(height=200)
1460       rectfromto(include,  inside_br - include);
1461   }
1462 }
1463
1464 module TestSelectLidFrame(){
1465   TestSelectFrame();
1466   translate([led_pos[0], -led_pos[1], -50])
1467     cylinder(r= nla_r2+3, h=100);
1468 }
1469
1470 module TestFrameCase(){ ////toplevel
1471   intersection(){
1472     Case();
1473     union(){
1474       TestSelectFrame();
1475       TestSelectCamera();
1476       TestSelectOrdinaryRearApertures();
1477     }
1478   }
1479 }
1480
1481 module TestSelectTopApertures(){
1482   translate([-100, -35, -100])
1483     cube([400, 100, 200]);
1484   LidAdhocMultiprintFrame(0);
1485   LidAdhocMultiprintFrame(1);
1486 }
1487
1488 module TestTopApertures(){ ////toplevel
1489   intersection(){
1490     Case();
1491     TestSelectFrame();
1492     TestSelectTopApertures();
1493   }
1494 }
1495
1496 module TestLidTopAperturesPrint(){ ////toplevel
1497   rotate([0,180,0]) intersection(){
1498     Lid();
1499     TestSelectLidFrame();
1500     TestSelectTopApertures();
1501   }
1502 }
1503
1504 module TestLidWindowTopAperturesPrint(){ ////toplevel
1505   rotate([0,180,0]) intersection(){
1506     LidWindow();
1507     TestSelectTopApertures();
1508   }
1509 }
1510
1511 module TestFrameLidPrint(){ ////toplevel
1512   rotate([0,180,0]) intersection(){
1513     Lid();
1514     TestSelectLidFrame();
1515   }
1516 }
1517
1518 module ButtonPlanForDemo(z, deep, cut){
1519   translate([0,0,z])
1520     ButtonPlan(8, deep, cut);
1521 }
1522
1523 module HingeScrews(){
1524   Flip_rhs() Flip_bot(1){
1525     for (c= [ hppT, hppB ])
1526       translate([ hex20,
1527                   -c[0],
1528                   c[1] ]){
1529         rotate([0,90,0])
1530           translate([0,0,-.2])
1531           cylinder( r= hingescrew_shaft_dia/2,
1532                     h = hingescrew_shaft_len+0.2 );
1533         rotate([0,-90,0])
1534           translate([0,0,+.1])
1535           cylinder( r= hingescrew_head_dia/2, h = hingescrew_head_th );
1536       }
1537   }
1538 }
1539
1540 module DemoPropAngleSelect(c){
1541   color(c) difference(){
1542     union(){ children(); }
1543     translate([ prop_x_pos, -400, -200 ])
1544       cube([ 400,800,400 ]);
1545   }
1546 }
1547
1548 module DemoPropAngle(ang){
1549   hL = [0, -(phone_height - hppT[0]), hppT[1] - hp_k*2];
1550   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1551
1552   translate(hL)
1553     rotate([ang/2,0,0])
1554     translate(-hL)
1555     translate(hC)
1556     rotate([ang/2,0,0])
1557     translate(-hC) {
1558       DemoPropAngleSelect("red") Case();
1559
1560       color("orange")
1561         translate([prop_x_pos, -prcp1[0], prcp1[1]])
1562         PropProfileAssignments(ang) {
1563           echo($prpp1);
1564           rotate([-$prp_theta, 0, 0])
1565           translate([0, $prpp1[0], -$prpp1[1]])
1566           rotate([90,0,-90])
1567           Prop();
1568         }
1569     }
1570
1571   translate([0,0, -hp_k*2])
1572     DemoPropAngleSelect("blue")
1573     Lid();
1574 }
1575
1576 module DemoPropAngles(){ ////toplevel
1577   for (i=[0 : len(prop_angles)-1])
1578     translate(i * [0, -100, 100])
1579     DemoPropAngle(prop_angles[i]);
1580 }
1581
1582 module DemoHingeAngle(ang1,ang2){
1583   hL = [0, -(phone_height - hppT[0]), hppT[1]];
1584   hC = [0, -(phone_height - hppB[0]), hppB[1]];
1585
1586   translate(hL)
1587     rotate([ang2,0,0])
1588     translate(-hL)
1589     translate(hC)
1590     rotate([ang1,0,0])
1591     translate(-hC) {
1592       color("red") Lid();
1593     }
1594
1595   color("blue") intersection(){
1596     Case();
1597     union(){
1598       translate([bppJ[0], -400, -200])
1599         mirror([1,0,0])
1600         cube([400, 800, 400]);
1601       translate([10, -400, -200])
1602         cube([10, 800, 400]);
1603     }
1604   }
1605 }
1606
1607 module DemoHingeAngles(){ ////toplevel
1608   angles = [ 0, 4, 8, 12 ];
1609   echo("angles",angles);
1610   for (i=[0 : len(angles)-1]) {
1611     translate(i * [0, 0, 30]) {
1612       DemoHingeAngle(0,angles[i]);
1613       translate([0, 200, 0])
1614         DemoHingeAngle(angles[i],0);
1615     }
1616   }
1617 }
1618
1619 module DemoSelectAdhocLeftRight(right=0) {
1620   translate([phone_width/2, -400, -100]) // , -15, -100  to cross-section
1621     mirror([1-right, 0,0])
1622     cube([400, 800, 200]);
1623 }
1624
1625 module DemoLeft(){ ////toplevel
1626   color("red")  intersection(){ Case(); DemoSelectAdhocLeftRight(); }
1627   color("blue") intersection(){ Lid();  DemoSelectAdhocLeftRight(); }
1628 }
1629
1630 module DemoFrame(){ ////toplevel
1631   color("red") render() TestFrameCase();
1632   color("blue") render() intersection(){ Lid(); TestSelectLidFrame(); }
1633   color("black") render() HingeScrews();
1634   %render() HingeLever();
1635 }
1636
1637 module DemoLanyardCutout(){ ////toplevel
1638   LanyardCutout(25);
1639 }
1640
1641 module DemoHingedFrame(){ ///toplevel
1642   color("red") TestFrameCase();
1643   translate([0,0, -2*hp_k])
1644   color("blue") intersection(){ Lid(); TestSelectLidFrame(); }
1645
1646   Flip_hinge(){
1647     color("orange") HingeLever();
1648     color("black") HingeScrews();
1649   }
1650 }
1651
1652 module DemoHinge(){ ////toplevel
1653   translate([ -0.5*phone_width, phone_height, hp_k*3 ]) {
1654     DemoFrame();
1655     translate([0,0, -hp_k*3])
1656       DemoHingedFrame();
1657   }
1658 }
1659
1660 module DemoProfiles(){ ////toplevel
1661   LidEdgeProfile();
1662   %EdgeProfile();
1663   KeeperProfile();
1664   translate([0,0,-1]) color("black") KeeperProfile(1);
1665   translate(ly_o){
1666     rotate(-ly_theta){
1667       translate([0,0,+1]) color("purple") LanyardMainChannelProfile();
1668       translate([0,0,+2]) color("red") LanyardCurveChannelProfile();
1669       translate([0, ly_q_z]){
1670         translate([0,0,-1]) color("blue") LanyardEntryChannelProfile();
1671         translate([ly_oec_y,0,-2]) color("black") LanyardEntryOuterProfile();
1672       }
1673     }
1674   }
1675   translate([0,0,-5]) color("white") translate(epp2i)
1676     rotate(-ly_theta)
1677     rectfromto([-15, 0],
1678                [+15, -max_case_bottom_edge_thickness]);
1679
1680   translate([0,20]) {
1681     LanyardMainChannelProfile();
1682     translate([0,0,1]) color("purple") LanyardCurveChannelProfile();
1683     translate([0,0,-1]) color("red") LanyardEntryChannelProfile();
1684   }
1685
1686   translate([20,0]) {
1687     LidEdgeProfile();
1688     %EdgeProfile();
1689
1690     demopoint_QR = [ bppS[0], bppQ[1] - 0.1];
1691
1692     color("blue") ButtonCoverProfile();
1693     color("red") {
1694       rectfromto(bppQ, demopoint_QR);
1695       rectfromto(bppR, demopoint_QR);
1696     }
1697   }
1698
1699   translate([-20,0]) {
1700     color("black") ButtonPlanForDemo(-2, 0,1);
1701     color("red" )  ButtonPlanForDemo(-4, 1,1);
1702     color("blue")  ButtonPlanForDemo(-6, 1,0);
1703   }
1704
1705   translate([0, -30]) {
1706     %LidEdgeProfile();
1707     %EdgeProfile();
1708     color("blue") HingeLidProfile();
1709     color("red")  HingeBaseProfile();
1710     color("black") translate([0,0,-2]) HingeLeverOuterProfile();
1711   }
1712
1713   for (f=[0,1]) {
1714     translate([-30, -60 + 30*f]) {
1715       translate([0,0,-4]) EdgeProfile();
1716       %translate([0,0,-10]) HingeBaseProfile();
1717       translate([0,-2] * f * hp_k) {
1718         translate([0,0,-4]) LidEdgeProfile();
1719         %translate([0,0,-10]) %HingeLidProfile();
1720       }
1721       translate(+hppB) rotate([0,0,180*f]) translate(-hppB) {
1722         translate([0,0,-2]) color("black") HingeLeverOuterProfile();
1723         translate([0,0,0]) color("red") difference(){
1724           HingeLeverOuterProfile();
1725           HingeLeverInnerProfile();
1726         }
1727         translate([0,0,3]) color("yellow") HingeLeverNutProfile();
1728       }
1729     }
1730   }
1731
1732   translate([20,-30]) {
1733     %EdgeProfile();
1734     %LidEdgeProfile();
1735     //translate([0,0,1]) ThumbRecessCutProfile();
1736     translate([0,0,+1]) color("red")
1737       difference(){ EdgeProfile(); ThumbRecessCutProfile(); }
1738   }
1739
1740   translate([40,-30]) {
1741     difference(){
1742       LidEdgeProfile();
1743       translate(prlp10)
1744         PropProfile(10, 1, 0);
1745     }
1746     translate(prlp10)
1747       PropProfile(15, 0);
1748   }
1749   translate([60,-30]) {
1750     PropAggregateProfile();
1751   }
1752 }
1753
1754 //EdgeProfile();
1755 //KeeperProfile();
1756 //CaseBase();
1757 //%Case();
1758 //Keeper();
1759 //LidEdgeProfile();
1760 //KeeperProfile();
1761 //DemoProfiles();
1762 //PropRecess();